source: branches/2017/dev_r8183_ICEMODEL/NEMOGCM/NEMO/LIM_SRC_3/iceadv.F90 @ 8516

Last change on this file since 8516 was 8516, checked in by clem, 3 years ago

changes in style - part5 - I think I can see the end of the tunnel

File size: 12.4 KB
Line 
1MODULE iceadv
2   !!======================================================================
3   !!                       ***  MODULE iceadv   ***
4   !! LIM transport ice model : sea-ice advection/diffusion
5   !!======================================================================
6   !! History : LIM-2 ! 2000-01 (M.A. Morales Maqueda, H. Goosse, and T. Fichefet)  Original code
7   !!            3.0  ! 2005-11 (M. Vancoppenolle)   Multi-layer sea ice, salinity variations
8   !!            4.0  ! 2011-02 (G. Madec) dynamical allocation
9   !!----------------------------------------------------------------------
10#if defined key_lim3
11   !!----------------------------------------------------------------------
12   !!   'key_lim3'                                       LIM3 sea-ice model
13   !!----------------------------------------------------------------------
14   !!   ice_adv       : advection/diffusion process of sea ice
15   !!----------------------------------------------------------------------
16   USE phycst         ! physical constant
17   USE dom_oce        ! ocean domain
18   USE sbc_oce , ONLY : nn_fsbc   ! frequency of sea-ice call
19   USE ice            ! sea-ice: variables
20   USE icevar         ! sea-ice: operations
21   USE iceadv_prather ! sea-ice: advection scheme (Prather)
22   USE iceadv_umx     ! sea-ice: advection scheme (ultimate-macho)
23   USE icectl         ! sea-ice: control prints
24   !
25   USE in_out_manager ! I/O manager
26   USE lbclnk         ! lateral boundary conditions -- MPP exchanges
27   USE lib_mpp        ! MPP library
28   USE prtctl         ! Print control
29   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) 
30   USE timing         ! Timing
31   USE iom            !
32
33   IMPLICIT NONE
34   PRIVATE
35
36   PUBLIC   ice_adv        ! called by icestp
37   PUBLIC   ice_adv_init   ! called by icestp
38
39   !! * Substitution
40#  include "vectopt_loop_substitute.h90"
41   !!----------------------------------------------------------------------
42   !! NEMO/ICE 4.0 , NEMO Consortium (2017)
43   !! $Id: iceadv.F90 8373 2017-07-25 17:44:54Z clem $
44   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
45   !!----------------------------------------------------------------------
46CONTAINS
47
48   SUBROUTINE ice_adv( kt ) 
49      !!----------------------------------------------------------------------
50      !!                   ***  ROUTINE ice_adv ***
51      !!                   
52      !! ** purpose : advection of sea ice
53      !!
54      !! ** method  : variables included in the process are scalar,   
55      !!     other values are considered as second order.
56      !!     For advection, one can choose between
57      !!     a) an Ultimate-Macho scheme (whose order is defined by nn_UMx) => ln_adv_UMx
58      !!     b) and a second order Prather scheme => ln_adv_Pra
59      !!
60      !! ** action :
61      !!----------------------------------------------------------------------
62      INTEGER, INTENT(in) ::   kt   ! number of iteration
63      !
64      INTEGER  ::   ji, jj, jk, jl, jt      ! dummy loop indices
65      INTEGER  ::   initad                  ! number of sub-timestep for the advection
66      REAL(wp) ::   zcfl , zusnit           !   -      -
67      CHARACTER(len=80) :: cltmp
68      !
69      REAL(wp) ::    zvi_b, zsmv_b, zei_b, zfs_b, zfw_b, zft_b
70      REAL(wp) ::    zdv
71      REAL(wp), DIMENSION(jpi,jpj)           ::   zatold, zeiold, zesold, zsmvold 
72      REAL(wp), DIMENSION(jpi,jpj,jpl)       ::   zhimax, zviold, zvsold
73      !!---------------------------------------------------------------------
74      IF( nn_timing == 1 )  CALL timing_start('iceadv')
75 
76      IF( kt == nit000 .AND. lwp ) THEN
77         WRITE(numout,*)
78         WRITE(numout,*) 'ice_adv: sea-ice advection'
79         WRITE(numout,*) '~~~~~~~'
80      ENDIF
81     
82      CALL ice_var_agg( 1 ) ! integrated values + ato_i
83
84      ! conservation test
85      IF( ln_icediachk )   CALL ice_cons_hsm(0, 'iceadv', zvi_b, zsmv_b, zei_b, zfw_b, zfs_b, zft_b)
86     
87      ! store old values for diag
88      zviold (:,:,:) = v_i(:,:,:)
89      zvsold (:,:,:) = v_s(:,:,:)
90      zsmvold(:,:)   = SUM( smv_i(:,:,:), dim=3 )
91      zeiold (:,:)   = et_i(:,:)
92      zesold (:,:)   = et_s(:,:)
93
94      ! Thickness correction init.
95      zatold(:,:) = at_i
96      WHERE( a_i(:,:,:) >= epsi20 )
97         ht_i(:,:,:) = v_i(:,:,:) / a_i(:,:,:)
98         ht_s(:,:,:) = v_s(:,:,:) / a_i(:,:,:)
99      ELSEWHERE
100         ht_i(:,:,:) = 0._wp
101         ht_s(:,:,:) = 0._wp         
102      END WHERE
103         
104      ! Record max of the surrounding ice thicknesses for correction in case advection creates ice too thick
105      zhimax(:,:,:) = ht_i(:,:,:) + ht_s(:,:,:)
106      DO jl = 1, jpl
107         DO jj = 2, jpjm1
108            DO ji = 2, jpim1
109!!gm use of MAXVAL here is very probably less efficient than expending the 9 values
110               zhimax(ji,jj,jl) = MAX( epsi20, MAXVAL( ht_i(ji-1:ji+1,jj-1:jj+1,jl) + ht_s(ji-1:ji+1,jj-1:jj+1,jl) ) )
111            END DO
112         END DO
113      END DO
114      CALL lbc_lnk( zhimax(:,:,:), 'T', 1. )
115     
116      !----------
117      ! Advection
118      !----------
119      IF( ln_adv_UMx ) THEN                    !-- ULTIMATE-MACHO scheme
120         CALL ice_adv_umx( kt, u_ice, v_ice,  &
121            &              ato_i, v_i, v_s, smv_i, oa_i, a_i, a_ip, v_ip, e_s, e_i )
122         
123      ELSEIF( ln_adv_Pra ) THEN                !-- PRATHER scheme
124         CALL ice_adv_prather( kt, u_ice, v_ice,  &
125            &                  ato_i, v_i, v_s, smv_i, oa_i, a_i, a_ip, v_ip, e_s, e_i )
126         
127      ENDIF
128
129      ! total ice fraction
130      at_i(:,:) = a_i(:,:,1)
131      DO jl = 2, jpl
132         at_i(:,:) = at_i(:,:) + a_i(:,:,jl)
133      END DO
134     
135      !------------
136      ! diagnostics
137      !------------
138      DO jj = 1, jpj
139         DO ji = 1, jpi
140            diag_trp_ei (ji,jj) = ( SUM( e_i  (ji,jj,1:nlay_i,:) ) -  zeiold(ji,jj) ) * r1_rdtice
141            diag_trp_es (ji,jj) = ( SUM( e_s  (ji,jj,1:nlay_s,:) ) -  zesold(ji,jj) ) * r1_rdtice
142            diag_trp_smv(ji,jj) = ( SUM( smv_i(ji,jj,:)          ) - zsmvold(ji,jj) ) * r1_rdtice
143            diag_trp_vi (ji,jj) =   SUM(   v_i(ji,jj,:)            -  zviold(ji,jj,:) ) * r1_rdtice
144            diag_trp_vs (ji,jj) =   SUM(   v_s(ji,jj,:)            -  zvsold(ji,jj,:) ) * r1_rdtice
145         END DO
146      END DO
147      IF( iom_use('icetrp') )   CALL iom_put( "icetrp" , diag_trp_vi * rday  )         ! ice volume transport
148      IF( iom_use('snwtrp') )   CALL iom_put( "snwtrp" , diag_trp_vs * rday  )         ! snw volume transport
149      IF( iom_use('saltrp') )   CALL iom_put( "saltrp" , diag_trp_smv * rday * rhoic ) ! salt content transport
150      IF( iom_use('deitrp') )   CALL iom_put( "deitrp" , diag_trp_ei         )         ! advected ice enthalpy (W/m2)
151      IF( iom_use('destrp') )   CALL iom_put( "destrp" , diag_trp_es         )         ! advected snw enthalpy (W/m2)
152     
153      !--------------------------------------
154      ! Thickness correction in case too high
155      !--------------------------------------
156      IF( nn_icedyn == 2 ) THEN
157         !
158         CALL ice_var_zapsmall                       !-- zap small areas
159         !
160         DO jl = 1, jpl
161            DO jj = 1, jpj
162               DO ji = 1, jpi
163                  IF ( v_i(ji,jj,jl) > 0._wp ) THEN  !-- bound to zhimax
164                     !
165                     ht_i  (ji,jj,jl) = v_i (ji,jj,jl) / a_i(ji,jj,jl)
166                     ht_s  (ji,jj,jl) = v_s (ji,jj,jl) / a_i(ji,jj,jl)
167                     zdv = v_i(ji,jj,jl) + v_s(ji,jj,jl) - zviold(ji,jj,jl) - zvsold(ji,jj,jl) 
168                     !
169                     IF ( ( zdv >  0.0 .AND. (ht_i(ji,jj,jl)+ht_s(ji,jj,jl)) > zhimax(ji,jj,jl) .AND. zatold(ji,jj) < 0.80 ) .OR. &
170                        & ( zdv <= 0.0 .AND. (ht_i(ji,jj,jl)+ht_s(ji,jj,jl)) > zhimax(ji,jj,jl) ) ) THEN
171                        a_i (ji,jj,jl) = ( v_i(ji,jj,jl) + v_s(ji,jj,jl) ) / zhimax(ji,jj,jl)
172                        ht_i(ji,jj,jl) =   v_i(ji,jj,jl) / a_i(ji,jj,jl)
173                     ENDIF
174                     !
175                  ENDIF
176               END DO
177            END DO
178         END DO
179                 
180         WHERE( ht_i(:,:,jpl) > hi_max(jpl) )        !-- bound ht_i to hi_max (99 m)
181            ht_i(:,:,jpl) = hi_max(jpl)
182            a_i (:,:,jpl) = v_i(:,:,jpl) / hi_max(jpl)
183         END WHERE
184
185         IF ( nn_pnd_scheme > 0 ) THEN               !-- correct pond fraction to avoid a_ip > a_i
186            WHERE( a_ip(:,:,:) > a_i(:,:,:) )   a_ip(:,:,:) = a_i(:,:,:)
187         ENDIF
188         !
189      ENDIF
190         
191      !------------------------------------------------------------
192      ! Impose a_i < amax if no ridging/rafting or in mono-category
193      !------------------------------------------------------------
194      IF( l_piling ) THEN                            !-- simple conservative piling, comparable with 1-cat models
195         at_i(:,:) = SUM( a_i(:,:,:), dim=3 )
196         DO jl = 1, jpl
197            WHERE( at_i(:,:) > epsi20 )
198               a_i(:,:,jl) = a_i(:,:,jl) * (  1._wp + MIN( rn_amax_2d(:,:) - at_i(:,:) , 0._wp ) / at_i(:,:)  )
199            END WHERE
200         END DO
201      ENDIF
202     
203      ! agglomerate variables
204      vt_i(:,:) = SUM( v_i(:,:,:), dim=3 )
205      vt_s(:,:) = SUM( v_s(:,:,:), dim=3 )
206      at_i(:,:) = SUM( a_i(:,:,:), dim=3 )
207
208      ! MV MP 2016 (remove once we get rid of a_i_frac and ht_i)
209      IF ( nn_pnd_scheme > 0 ) THEN
210          at_ip(:,:) = SUM( a_ip(:,:,:), dim = 3 )
211          vt_ip(:,:) = SUM( v_ip(:,:,:), dim = 3 )
212      ENDIF
213      ! END MP 2016
214     
215      ! open water = 1 if at_i=0
216      WHERE( at_i == 0._wp ) ato_i = 1._wp 
217     
218      ! conservation test
219      IF( ln_icediachk )   CALL ice_cons_hsm(1, 'iceadv', zvi_b, zsmv_b, zei_b, zfw_b, zfs_b, zft_b)
220       
221      ! --------------
222      ! control prints
223      ! --------------
224      IF( ln_icectl )   CALL ice_prt( kt, iiceprt, jiceprt,-1, ' - ice dyn & trp - ' )
225      !
226      IF( nn_timing == 1 )  CALL timing_stop('iceadv')
227      !
228   END SUBROUTINE ice_adv
229
230
231   SUBROUTINE ice_adv_init
232      !!-------------------------------------------------------------------
233      !!                  ***  ROUTINE ice_adv_init  ***
234      !!
235      !! ** Purpose : Physical constants and parameters linked to the ice
236      !!      dynamics
237      !!
238      !! ** Method  :  Read the namice_adv namelist and check the ice-dynamic
239      !!       parameter values called at the first timestep (nit000)
240      !!
241      !! ** input   :   Namelist namice_adv
242      !!-------------------------------------------------------------------
243      INTEGER ::   ios   ! Local integer output status for namelist read
244      !!
245      NAMELIST/namice_adv/ ln_adv_Pra, ln_adv_UMx, nn_UMx
246      !!-------------------------------------------------------------------
247      !
248      REWIND( numnam_ice_ref )         ! Namelist namice_adv in reference namelist : Ice dynamics
249      READ  ( numnam_ice_ref, namice_adv, IOSTAT = ios, ERR = 901)
250901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namice_adv in reference namelist', lwp )
251      !
252      REWIND( numnam_ice_cfg )         ! Namelist namice_adv in configuration namelist : Ice dynamics
253      READ  ( numnam_ice_cfg, namice_adv, IOSTAT = ios, ERR = 902 )
254902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namice_adv in configuration namelist', lwp )
255      IF(lwm) WRITE ( numoni, namice_adv )
256      !
257      IF(lwp) THEN                     ! control print
258         WRITE(numout,*)
259         WRITE(numout,*) 'ice_adv_init: ice parameters for ice dynamics '
260         WRITE(numout,*) '~~~~~~~~~~~~'
261         WRITE(numout,*) '   Namelist namice_adv'
262         WRITE(numout,*) '      advection scheme for ice transport (limtrp)'
263         WRITE(numout,*) '         type of advection scheme (Prather)                     ln_adv_Pra = ', ln_adv_Pra 
264         WRITE(numout,*) '         type of advection scheme (Ulimate-Macho)               ln_adv_UMx = ', ln_adv_UMx 
265         WRITE(numout,*) '            order of the Ultimate-Macho scheme                      nn_UMx = ', nn_UMx
266      ENDIF
267      !
268      IF ( ( ln_adv_Pra .AND. ln_adv_UMx ) .OR. ( .NOT.ln_adv_Pra .AND. .NOT.ln_adv_UMx ) ) THEN
269         CALL ctl_stop( 'ice_adv_init: choose one and only one ice advection scheme (ln_adv_Pra or ln_adv_UMx)' )
270      ENDIF
271      !
272   END SUBROUTINE ice_adv_init
273
274#else
275   !!----------------------------------------------------------------------
276   !!   Default option         Empty Module                No sea-ice model
277   !!----------------------------------------------------------------------
278#endif
279
280   !!======================================================================
281END MODULE iceadv
282
Note: See TracBrowser for help on using the repository browser.