| 1 | MODULE limsbc |
|---|
| 2 | !!====================================================================== |
|---|
| 3 | !! *** MODULE limsbc *** |
|---|
| 4 | !! computation of the flux at the sea ice/ocean interface |
|---|
| 5 | !!====================================================================== |
|---|
| 6 | !! History : - ! 2006-07 (M. Vancoppelle) LIM3 original code |
|---|
| 7 | !! 3.0 ! 2008-03 (C. Tallandier) surface module |
|---|
| 8 | !! - ! 2008-04 (C. Tallandier) split in 2 + new ice-ocean coupling |
|---|
| 9 | !! 3.3 ! 2010-05 (G. Madec) decrease ocean & ice reference salinities in the Baltic sea |
|---|
| 10 | !! ! + simplification of the ice-ocean stress calculation |
|---|
| 11 | !! 3.4 ! 2011-02 (G. Madec) dynamical allocation |
|---|
| 12 | !! - ! 2012 (D. Iovino) salt flux change |
|---|
| 13 | !! - ! 2012-05 (C. Rousset) add penetration solar flux |
|---|
| 14 | !! 3.5 ! 2012-10 (A. Coward, G. Madec) salt fluxes ; ice+snow mass |
|---|
| 15 | !!---------------------------------------------------------------------- |
|---|
| 16 | #if defined key_lim3 |
|---|
| 17 | !!---------------------------------------------------------------------- |
|---|
| 18 | !! 'key_lim3' LIM 3.0 sea-ice model |
|---|
| 19 | !!---------------------------------------------------------------------- |
|---|
| 20 | !! lim_sbc_alloc : allocate the limsbc arrays |
|---|
| 21 | !! lim_sbc_init : initialisation |
|---|
| 22 | !! lim_sbc_flx : updates mass, heat and salt fluxes at the ocean surface |
|---|
| 23 | !! lim_sbc_tau : update i- and j-stresses, and its modulus at the ocean surface |
|---|
| 24 | !!---------------------------------------------------------------------- |
|---|
| 25 | USE par_oce ! ocean parameters |
|---|
| 26 | USE oce , ONLY : sshn, sshb, snwice_mass, snwice_mass_b, snwice_fmass |
|---|
| 27 | USE phycst ! physical constants |
|---|
| 28 | USE dom_oce ! ocean domain |
|---|
| 29 | USE ice ! LIM sea-ice variables |
|---|
| 30 | USE sbc_ice ! Surface boundary condition: sea-ice fields |
|---|
| 31 | USE sbc_oce ! Surface boundary condition: ocean fields |
|---|
| 32 | USE sbccpl ! Surface boundary condition: coupled interface |
|---|
| 33 | USE albedo ! albedo parameters |
|---|
| 34 | USE traqsr ! add penetration of solar flux in the calculation of heat budget |
|---|
| 35 | USE domvvl ! Variable volume |
|---|
| 36 | USE limctl ! |
|---|
| 37 | USE limcons ! |
|---|
| 38 | USE bdy_oce , ONLY: ln_bdy |
|---|
| 39 | ! |
|---|
| 40 | USE in_out_manager ! I/O manager |
|---|
| 41 | USE iom ! xIO server |
|---|
| 42 | USE lbclnk ! ocean lateral boundary condition - MPP exchanges |
|---|
| 43 | USE lib_mpp ! MPP library |
|---|
| 44 | USE wrk_nemo ! work arrays |
|---|
| 45 | USE lib_fortran ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) |
|---|
| 46 | |
|---|
| 47 | IMPLICIT NONE |
|---|
| 48 | PRIVATE |
|---|
| 49 | |
|---|
| 50 | PUBLIC lim_sbc_init ! called by sbc_lim_init |
|---|
| 51 | PUBLIC lim_sbc_flx ! called by sbc_ice_lim |
|---|
| 52 | PUBLIC lim_sbc_tau ! called by sbc_ice_lim |
|---|
| 53 | |
|---|
| 54 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) :: utau_oce, vtau_oce ! air-ocean surface i- & j-stress [N/m2] |
|---|
| 55 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) :: tmod_io ! modulus of the ice-ocean velocity [m/s] |
|---|
| 56 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) :: soce_0 , sice_0 ! cst SSS and ice salinity (levitating sea-ice) |
|---|
| 57 | |
|---|
| 58 | !! * Substitutions |
|---|
| 59 | # include "vectopt_loop_substitute.h90" |
|---|
| 60 | !!---------------------------------------------------------------------- |
|---|
| 61 | !! NEMO/LIM3 4.0 , UCL - NEMO Consortium (2011) |
|---|
| 62 | !! $Id$ |
|---|
| 63 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
|---|
| 64 | !!---------------------------------------------------------------------- |
|---|
| 65 | CONTAINS |
|---|
| 66 | |
|---|
| 67 | INTEGER FUNCTION lim_sbc_alloc() |
|---|
| 68 | !!------------------------------------------------------------------- |
|---|
| 69 | !! *** ROUTINE lim_sbc_alloc *** |
|---|
| 70 | !!------------------------------------------------------------------- |
|---|
| 71 | ALLOCATE( soce_0(jpi,jpj) , utau_oce(jpi,jpj) , & |
|---|
| 72 | & sice_0(jpi,jpj) , vtau_oce(jpi,jpj) , tmod_io(jpi,jpj), STAT=lim_sbc_alloc) |
|---|
| 73 | ! |
|---|
| 74 | IF( lk_mpp ) CALL mpp_sum( lim_sbc_alloc ) |
|---|
| 75 | IF( lim_sbc_alloc /= 0 ) CALL ctl_warn('lim_sbc_alloc: failed to allocate arrays') |
|---|
| 76 | END FUNCTION lim_sbc_alloc |
|---|
| 77 | |
|---|
| 78 | |
|---|
| 79 | SUBROUTINE lim_sbc_flx( kt ) |
|---|
| 80 | !!------------------------------------------------------------------- |
|---|
| 81 | !! *** ROUTINE lim_sbc_flx *** |
|---|
| 82 | !! |
|---|
| 83 | !! ** Purpose : Update the surface ocean boundary condition for heat |
|---|
| 84 | !! salt and mass over areas where sea-ice is non-zero |
|---|
| 85 | !! |
|---|
| 86 | !! ** Action : - computes the heat and freshwater/salt fluxes |
|---|
| 87 | !! at the ice-ocean interface. |
|---|
| 88 | !! - Update the ocean sbc |
|---|
| 89 | !! |
|---|
| 90 | !! ** Outputs : - qsr : sea heat flux: solar |
|---|
| 91 | !! - qns : sea heat flux: non solar |
|---|
| 92 | !! - emp : freshwater budget: volume flux |
|---|
| 93 | !! - sfx : salt flux |
|---|
| 94 | !! - fr_i : ice fraction |
|---|
| 95 | !! - tn_ice : sea-ice surface temperature |
|---|
| 96 | !! - alb_ice : sea-ice albedo (recomputed only for coupled mode) |
|---|
| 97 | !! |
|---|
| 98 | !! References : Goosse, H. et al. 1996, Bul. Soc. Roy. Sc. Liege, 65, 87-90. |
|---|
| 99 | !! Tartinville et al. 2001 Ocean Modelling, 3, 95-108. |
|---|
| 100 | !! These refs are now obsolete since everything has been revised |
|---|
| 101 | !! The ref should be Rousset et al., 2015 |
|---|
| 102 | !!--------------------------------------------------------------------- |
|---|
| 103 | INTEGER, INTENT(in) :: kt ! number of iteration |
|---|
| 104 | ! |
|---|
| 105 | INTEGER :: ji, jj, jl, jk ! dummy loop indices |
|---|
| 106 | REAL(wp) :: zqmass ! Heat flux associated with mass exchange ice->ocean (W.m-2) |
|---|
| 107 | REAL(wp) :: zqsr ! New solar flux received by the ocean |
|---|
| 108 | REAL(wp), POINTER, DIMENSION(:,:,:) :: zalb_cs, zalb_os ! 3D workspace |
|---|
| 109 | REAL(wp), POINTER, DIMENSION(:,:) :: zalb ! 2D workspace |
|---|
| 110 | !!--------------------------------------------------------------------- |
|---|
| 111 | |
|---|
| 112 | ! --- case we bypass ice thermodynamics --- ! |
|---|
| 113 | IF( .NOT. ln_limthd ) THEN ! we suppose ice is impermeable => ocean is isolated from atmosphere |
|---|
| 114 | hfx_in (:,:) = pfrld(:,:) * ( qns_oce(:,:) + qsr_oce(:,:) ) + qemp_oce(:,:) |
|---|
| 115 | hfx_out (:,:) = pfrld(:,:) * qns_oce(:,:) + qemp_oce(:,:) |
|---|
| 116 | ftr_ice (:,:,:) = 0._wp |
|---|
| 117 | emp_ice (:,:) = 0._wp |
|---|
| 118 | qemp_ice (:,:) = 0._wp |
|---|
| 119 | qevap_ice(:,:,:) = 0._wp |
|---|
| 120 | ENDIF |
|---|
| 121 | |
|---|
| 122 | ! albedo output |
|---|
| 123 | CALL wrk_alloc( jpi,jpj, zalb ) |
|---|
| 124 | |
|---|
| 125 | zalb(:,:) = 0._wp |
|---|
| 126 | WHERE ( at_i_b <= epsi06 ) ; zalb(:,:) = 0.066_wp |
|---|
| 127 | ELSEWHERE ; zalb(:,:) = SUM( alb_ice * a_i_b, dim=3 ) / at_i_b |
|---|
| 128 | END WHERE |
|---|
| 129 | IF( iom_use('alb_ice' ) ) CALL iom_put( "alb_ice" , zalb(:,:) ) ! ice albedo output |
|---|
| 130 | |
|---|
| 131 | zalb(:,:) = SUM( alb_ice * a_i_b, dim=3 ) + 0.066_wp * ( 1._wp - at_i_b ) |
|---|
| 132 | IF( iom_use('albedo' ) ) CALL iom_put( "albedo" , zalb(:,:) ) ! surface albedo output |
|---|
| 133 | |
|---|
| 134 | CALL wrk_dealloc( jpi,jpj, zalb ) |
|---|
| 135 | |
|---|
| 136 | DO jj = 1, jpj |
|---|
| 137 | DO ji = 1, jpi |
|---|
| 138 | |
|---|
| 139 | !------------------------------------------! |
|---|
| 140 | ! heat flux at the ocean surface ! |
|---|
| 141 | !------------------------------------------! |
|---|
| 142 | ! Solar heat flux reaching the ocean = zqsr (W.m-2) |
|---|
| 143 | !--------------------------------------------------- |
|---|
| 144 | zqsr = qsr_tot(ji,jj) |
|---|
| 145 | DO jl = 1, jpl |
|---|
| 146 | zqsr = zqsr - a_i_b(ji,jj,jl) * ( qsr_ice(ji,jj,jl) - ftr_ice(ji,jj,jl) ) |
|---|
| 147 | END DO |
|---|
| 148 | |
|---|
| 149 | ! Total heat flux reaching the ocean = hfx_out (W.m-2) |
|---|
| 150 | !--------------------------------------------------- |
|---|
| 151 | zqmass = hfx_thd(ji,jj) + hfx_dyn(ji,jj) + hfx_res(ji,jj) ! heat flux from snow is 0 (T=0 degC) |
|---|
| 152 | hfx_out(ji,jj) = hfx_out(ji,jj) + zqmass + zqsr |
|---|
| 153 | |
|---|
| 154 | ! Add the residual from heat diffusion equation and sublimation (W.m-2) |
|---|
| 155 | !---------------------------------------------------------------------- |
|---|
| 156 | hfx_out(ji,jj) = hfx_out(ji,jj) + hfx_err_dif(ji,jj) + & |
|---|
| 157 | & ( hfx_sub(ji,jj) - SUM( qevap_ice(ji,jj,:) * a_i_b(ji,jj,:) ) ) |
|---|
| 158 | |
|---|
| 159 | ! New qsr and qns used to compute the oceanic heat flux at the next time step |
|---|
| 160 | !---------------------------------------------------------------------------- |
|---|
| 161 | qsr(ji,jj) = zqsr |
|---|
| 162 | qns(ji,jj) = hfx_out(ji,jj) - zqsr |
|---|
| 163 | |
|---|
| 164 | !------------------------------------------! |
|---|
| 165 | ! mass flux at the ocean surface ! |
|---|
| 166 | !------------------------------------------! |
|---|
| 167 | ! case of realistic freshwater flux (Tartinville et al., 2001) (presently ACTIVATED) |
|---|
| 168 | ! ------------------------------------------------------------------------------------- |
|---|
| 169 | ! The idea of this approach is that the system that we consider is the ICE-OCEAN system |
|---|
| 170 | ! Thus FW flux = External ( E-P+snow melt) |
|---|
| 171 | ! Salt flux = Exchanges in the ice-ocean system then converted into FW |
|---|
| 172 | ! Associated to Ice formation AND Ice melting |
|---|
| 173 | ! Even if i see Ice melting as a FW and SALT flux |
|---|
| 174 | ! |
|---|
| 175 | ! mass flux from ice/ocean |
|---|
| 176 | wfx_ice(ji,jj) = wfx_bog(ji,jj) + wfx_bom(ji,jj) + wfx_sum(ji,jj) + wfx_sni(ji,jj) & |
|---|
| 177 | + wfx_opw(ji,jj) + wfx_dyn(ji,jj) + wfx_res(ji,jj) + wfx_lam(ji,jj) |
|---|
| 178 | |
|---|
| 179 | IF ( ln_pnd_fw ) & |
|---|
| 180 | wfx_ice(ji,jj) = wfx_ice(ji,jj) + wfx_pnd(ji,jj) |
|---|
| 181 | |
|---|
| 182 | ! add the snow melt water to snow mass flux to the ocean |
|---|
| 183 | wfx_snw(:,:) = wfx_snw(:,:) + wfx_snw_sum(:,:) |
|---|
| 184 | |
|---|
| 185 | ! mass flux at the ocean/ice interface |
|---|
| 186 | fmmflx(ji,jj) = - ( wfx_ice(ji,jj) + wfx_snw(ji,jj) + wfx_err_sub(ji,jj) ) ! F/M mass flux save at least for biogeochemical model |
|---|
| 187 | emp(ji,jj) = emp_oce(ji,jj) - wfx_ice(ji,jj) - wfx_snw(ji,jj) - wfx_err_sub(ji,jj) ! mass flux + F/M mass flux (always ice/ocean mass exchange) |
|---|
| 188 | END DO |
|---|
| 189 | END DO |
|---|
| 190 | |
|---|
| 191 | !------------------------------------------! |
|---|
| 192 | ! salt flux at the ocean surface ! |
|---|
| 193 | !------------------------------------------! |
|---|
| 194 | sfx(:,:) = sfx_bog(:,:) + sfx_bom(:,:) + sfx_sum(:,:) + sfx_sni(:,:) + sfx_opw(:,:) & |
|---|
| 195 | & + sfx_res(:,:) + sfx_dyn(:,:) + sfx_bri(:,:) + sfx_sub(:,:) + sfx_lam(:,:) |
|---|
| 196 | |
|---|
| 197 | !-------------------------------------------------------------! |
|---|
| 198 | ! mass of snow and ice per unit area for embedded sea-ice ! |
|---|
| 199 | !-------------------------------------------------------------! |
|---|
| 200 | IF( nn_ice_embd /= 0 ) THEN |
|---|
| 201 | ! save mass from the previous ice time step |
|---|
| 202 | snwice_mass_b(:,:) = snwice_mass(:,:) |
|---|
| 203 | ! new mass per unit area |
|---|
| 204 | snwice_mass (:,:) = tmask(:,:,1) * ( rhosn * vt_s(:,:) + rhoic * vt_i(:,:) ) |
|---|
| 205 | ! time evolution of snow+ice mass |
|---|
| 206 | snwice_fmass (:,:) = ( snwice_mass(:,:) - snwice_mass_b(:,:) ) * r1_rdtice |
|---|
| 207 | ENDIF |
|---|
| 208 | |
|---|
| 209 | !-----------------------------------------------! |
|---|
| 210 | ! Storing the transmitted variables ! |
|---|
| 211 | !-----------------------------------------------! |
|---|
| 212 | fr_i (:,:) = at_i(:,:) ! Sea-ice fraction |
|---|
| 213 | tn_ice(:,:,:) = t_su(:,:,:) ! Ice surface temperature |
|---|
| 214 | |
|---|
| 215 | !------------------------------------------------------------------------! |
|---|
| 216 | ! Snow/ice albedo (only if sent to coupler, useless in forced mode) ! |
|---|
| 217 | !------------------------------------------------------------------------! |
|---|
| 218 | CALL wrk_alloc( jpi,jpj,jpl, zalb_cs, zalb_os ) |
|---|
| 219 | CALL albedo_ice( t_su, ht_i, ht_s, a_ip_frac, h_ip, ln_pnd_rad, zalb_cs, zalb_os ) ! cloud-sky and overcast-sky ice albedos |
|---|
| 220 | |
|---|
| 221 | alb_ice(:,:,:) = ( 1. - cldf_ice ) * zalb_cs(:,:,:) + cldf_ice * zalb_os(:,:,:) |
|---|
| 222 | CALL wrk_dealloc( jpi,jpj,jpl, zalb_cs, zalb_os ) |
|---|
| 223 | |
|---|
| 224 | ! conservation test |
|---|
| 225 | IF( ln_limdiachk .AND. .NOT. ln_bdy) CALL lim_cons_final( 'limsbc' ) |
|---|
| 226 | |
|---|
| 227 | ! control prints |
|---|
| 228 | IF( ln_limctl ) CALL lim_prt( kt, iiceprt, jiceprt, 3, ' - Final state lim_sbc - ' ) |
|---|
| 229 | IF( ln_ctl ) CALL lim_prt3D( 'limsbc' ) |
|---|
| 230 | |
|---|
| 231 | END SUBROUTINE lim_sbc_flx |
|---|
| 232 | |
|---|
| 233 | |
|---|
| 234 | SUBROUTINE lim_sbc_tau( kt , pu_oce, pv_oce ) |
|---|
| 235 | !!------------------------------------------------------------------- |
|---|
| 236 | !! *** ROUTINE lim_sbc_tau *** |
|---|
| 237 | !! |
|---|
| 238 | !! ** Purpose : Update the ocean surface stresses due to the ice |
|---|
| 239 | !! |
|---|
| 240 | !! ** Action : * at each ice time step (every nn_fsbc time step): |
|---|
| 241 | !! - compute the modulus of ice-ocean relative velocity |
|---|
| 242 | !! (*rho*Cd) at T-point (C-grid) or I-point (B-grid) |
|---|
| 243 | !! tmod_io = rhoco * | U_ice-U_oce | |
|---|
| 244 | !! - update the modulus of stress at ocean surface |
|---|
| 245 | !! taum = frld * taum + (1-frld) * tmod_io * | U_ice-U_oce | |
|---|
| 246 | !! * at each ocean time step (every kt): |
|---|
| 247 | !! compute linearized ice-ocean stresses as |
|---|
| 248 | !! Utau = tmod_io * | U_ice - pU_oce | |
|---|
| 249 | !! using instantaneous current ocean velocity (usually before) |
|---|
| 250 | !! |
|---|
| 251 | !! NB: - ice-ocean rotation angle no more allowed |
|---|
| 252 | !! - here we make an approximation: taum is only computed every ice time step |
|---|
| 253 | !! This avoids mutiple average to pass from T -> U,V grids and next from U,V grids |
|---|
| 254 | !! to T grid. taum is used in TKE and GLS, which should not be too sensitive to this approximaton... |
|---|
| 255 | !! |
|---|
| 256 | !! ** Outputs : - utau, vtau : surface ocean i- and j-stress (u- & v-pts) updated with ice-ocean fluxes |
|---|
| 257 | !! - taum : modulus of the surface ocean stress (T-point) updated with ice-ocean fluxes |
|---|
| 258 | !!--------------------------------------------------------------------- |
|---|
| 259 | INTEGER , INTENT(in) :: kt ! ocean time-step index |
|---|
| 260 | REAL(wp), DIMENSION(jpi,jpj), INTENT(in) :: pu_oce, pv_oce ! surface ocean currents |
|---|
| 261 | ! |
|---|
| 262 | INTEGER :: ji, jj ! dummy loop indices |
|---|
| 263 | REAL(wp) :: zat_u, zutau_ice, zu_t, zmodt ! local scalar |
|---|
| 264 | REAL(wp) :: zat_v, zvtau_ice, zv_t, zrhoco ! - - |
|---|
| 265 | !!--------------------------------------------------------------------- |
|---|
| 266 | zrhoco = rau0 * rn_cio |
|---|
| 267 | ! |
|---|
| 268 | IF( MOD( kt-1, nn_fsbc ) == 0 ) THEN !== Ice time-step only ==! (i.e. surface module time-step) |
|---|
| 269 | DO jj = 2, jpjm1 !* update the modulus of stress at ocean surface (T-point) |
|---|
| 270 | DO ji = fs_2, fs_jpim1 |
|---|
| 271 | ! ! 2*(U_ice-U_oce) at T-point |
|---|
| 272 | zu_t = u_ice(ji,jj) + u_ice(ji-1,jj) - u_oce(ji,jj) - u_oce(ji-1,jj) |
|---|
| 273 | zv_t = v_ice(ji,jj) + v_ice(ji,jj-1) - v_oce(ji,jj) - v_oce(ji,jj-1) |
|---|
| 274 | ! ! |U_ice-U_oce|^2 |
|---|
| 275 | zmodt = 0.25_wp * ( zu_t * zu_t + zv_t * zv_t ) |
|---|
| 276 | ! ! update the ocean stress modulus |
|---|
| 277 | taum(ji,jj) = ( 1._wp - at_i(ji,jj) ) * taum(ji,jj) + at_i(ji,jj) * zrhoco * zmodt |
|---|
| 278 | tmod_io(ji,jj) = zrhoco * SQRT( zmodt ) ! rhoco * |U_ice-U_oce| at T-point |
|---|
| 279 | END DO |
|---|
| 280 | END DO |
|---|
| 281 | CALL lbc_lnk_multi( taum, 'T', 1., tmod_io, 'T', 1. ) |
|---|
| 282 | ! |
|---|
| 283 | utau_oce(:,:) = utau(:,:) !* save the air-ocean stresses at ice time-step |
|---|
| 284 | vtau_oce(:,:) = vtau(:,:) |
|---|
| 285 | ! |
|---|
| 286 | ENDIF |
|---|
| 287 | ! |
|---|
| 288 | ! !== every ocean time-step ==! |
|---|
| 289 | ! |
|---|
| 290 | DO jj = 2, jpjm1 !* update the stress WITHOUT a ice-ocean rotation angle |
|---|
| 291 | DO ji = fs_2, fs_jpim1 ! Vect. Opt. |
|---|
| 292 | zat_u = ( at_i(ji,jj) + at_i(ji+1,jj) ) * 0.5_wp ! ice area at u and V-points |
|---|
| 293 | zat_v = ( at_i(ji,jj) + at_i(ji,jj+1) ) * 0.5_wp |
|---|
| 294 | ! ! linearized quadratic drag formulation |
|---|
| 295 | zutau_ice = 0.5_wp * ( tmod_io(ji,jj) + tmod_io(ji+1,jj) ) * ( u_ice(ji,jj) - pu_oce(ji,jj) ) |
|---|
| 296 | zvtau_ice = 0.5_wp * ( tmod_io(ji,jj) + tmod_io(ji,jj+1) ) * ( v_ice(ji,jj) - pv_oce(ji,jj) ) |
|---|
| 297 | ! ! stresses at the ocean surface |
|---|
| 298 | utau(ji,jj) = ( 1._wp - zat_u ) * utau_oce(ji,jj) + zat_u * zutau_ice |
|---|
| 299 | vtau(ji,jj) = ( 1._wp - zat_v ) * vtau_oce(ji,jj) + zat_v * zvtau_ice |
|---|
| 300 | END DO |
|---|
| 301 | END DO |
|---|
| 302 | CALL lbc_lnk_multi( utau, 'U', -1., vtau, 'V', -1. ) ! lateral boundary condition |
|---|
| 303 | ! |
|---|
| 304 | ! |
|---|
| 305 | END SUBROUTINE lim_sbc_tau |
|---|
| 306 | |
|---|
| 307 | |
|---|
| 308 | SUBROUTINE lim_sbc_init |
|---|
| 309 | !!------------------------------------------------------------------- |
|---|
| 310 | !! *** ROUTINE lim_sbc_init *** |
|---|
| 311 | !! |
|---|
| 312 | !! ** Purpose : Preparation of the file ice_evolu for the output of |
|---|
| 313 | !! the temporal evolution of key variables |
|---|
| 314 | !! |
|---|
| 315 | !! ** input : Namelist namicedia |
|---|
| 316 | !!------------------------------------------------------------------- |
|---|
| 317 | INTEGER :: ji, jj, jk ! dummy loop indices |
|---|
| 318 | REAL(wp) :: zcoefu, zcoefv, zcoeff ! local scalar |
|---|
| 319 | !!------------------------------------------------------------------- |
|---|
| 320 | ! |
|---|
| 321 | IF(lwp) WRITE(numout,*) |
|---|
| 322 | IF(lwp) WRITE(numout,*) 'lim_sbc_init : LIM-3 sea-ice - surface boundary condition' |
|---|
| 323 | IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~~ ' |
|---|
| 324 | |
|---|
| 325 | ! ! allocate lim_sbc array |
|---|
| 326 | IF( lim_sbc_alloc() /= 0 ) CALL ctl_stop( 'STOP', 'lim_sbc_init : unable to allocate standard arrays' ) |
|---|
| 327 | ! |
|---|
| 328 | soce_0(:,:) = soce ! constant SSS and ice salinity used in levitating sea-ice case |
|---|
| 329 | sice_0(:,:) = sice |
|---|
| 330 | ! ! decrease ocean & ice reference salinities in the Baltic Sea area |
|---|
| 331 | WHERE( 14._wp <= glamt(:,:) .AND. glamt(:,:) <= 32._wp .AND. & |
|---|
| 332 | & 54._wp <= gphit(:,:) .AND. gphit(:,:) <= 66._wp ) |
|---|
| 333 | soce_0(:,:) = 4._wp |
|---|
| 334 | sice_0(:,:) = 2._wp |
|---|
| 335 | END WHERE |
|---|
| 336 | ! |
|---|
| 337 | IF( .NOT. ln_rstart ) THEN |
|---|
| 338 | ! ! embedded sea ice |
|---|
| 339 | IF( nn_ice_embd /= 0 ) THEN ! mass exchanges between ice and ocean (case 1 or 2) set the snow+ice mass |
|---|
| 340 | snwice_mass (:,:) = tmask(:,:,1) * ( rhosn * vt_s(:,:) + rhoic * vt_i(:,:) ) |
|---|
| 341 | snwice_mass_b(:,:) = snwice_mass(:,:) |
|---|
| 342 | ELSE |
|---|
| 343 | snwice_mass (:,:) = 0._wp ! no mass exchanges |
|---|
| 344 | snwice_mass_b(:,:) = 0._wp ! no mass exchanges |
|---|
| 345 | ENDIF |
|---|
| 346 | IF( nn_ice_embd == 2 ) THEN ! full embedment (case 2) deplete the initial ssh below sea-ice area |
|---|
| 347 | sshn(:,:) = sshn(:,:) - snwice_mass(:,:) * r1_rau0 |
|---|
| 348 | sshb(:,:) = sshb(:,:) - snwice_mass(:,:) * r1_rau0 |
|---|
| 349 | |
|---|
| 350 | !!gm I really don't like this stuff here... Find a way to put that elsewhere or differently |
|---|
| 351 | !!gm |
|---|
| 352 | IF( .NOT.ln_linssh ) THEN |
|---|
| 353 | DO jk = 1,jpkm1 ! adjust initial vertical scale factors |
|---|
| 354 | e3t_n(:,:,jk) = e3t_0(:,:,jk)*( 1._wp + sshn(:,:)*tmask(:,:,1)/(ht_0(:,:) + 1.0 - tmask(:,:,1)) ) |
|---|
| 355 | e3t_b(:,:,jk) = e3t_0(:,:,jk)*( 1._wp + sshb(:,:)*tmask(:,:,1)/(ht_0(:,:) + 1.0 - tmask(:,:,1)) ) |
|---|
| 356 | END DO |
|---|
| 357 | e3t_a(:,:,:) = e3t_b(:,:,:) |
|---|
| 358 | ! Reconstruction of all vertical scale factors at now and before time-steps |
|---|
| 359 | ! ========================================================================= |
|---|
| 360 | ! Horizontal scale factor interpolations |
|---|
| 361 | ! -------------------------------------- |
|---|
| 362 | CALL dom_vvl_interpol( e3t_b(:,:,:), e3u_b(:,:,:), 'U' ) |
|---|
| 363 | CALL dom_vvl_interpol( e3t_b(:,:,:), e3v_b(:,:,:), 'V' ) |
|---|
| 364 | CALL dom_vvl_interpol( e3t_n(:,:,:), e3u_n(:,:,:), 'U' ) |
|---|
| 365 | CALL dom_vvl_interpol( e3t_n(:,:,:), e3v_n(:,:,:), 'V' ) |
|---|
| 366 | CALL dom_vvl_interpol( e3u_n(:,:,:), e3f_n(:,:,:), 'F' ) |
|---|
| 367 | ! Vertical scale factor interpolations |
|---|
| 368 | ! ------------------------------------ |
|---|
| 369 | CALL dom_vvl_interpol( e3t_n(:,:,:), e3w_n (:,:,:), 'W' ) |
|---|
| 370 | CALL dom_vvl_interpol( e3u_n(:,:,:), e3uw_n(:,:,:), 'UW' ) |
|---|
| 371 | CALL dom_vvl_interpol( e3v_n(:,:,:), e3vw_n(:,:,:), 'VW' ) |
|---|
| 372 | CALL dom_vvl_interpol( e3u_b(:,:,:), e3uw_b(:,:,:), 'UW' ) |
|---|
| 373 | CALL dom_vvl_interpol( e3v_b(:,:,:), e3vw_b(:,:,:), 'VW' ) |
|---|
| 374 | ! t- and w- points depth |
|---|
| 375 | ! ---------------------- |
|---|
| 376 | !!gm not sure of that.... |
|---|
| 377 | gdept_n(:,:,1) = 0.5_wp * e3w_n(:,:,1) |
|---|
| 378 | gdepw_n(:,:,1) = 0.0_wp |
|---|
| 379 | gde3w_n(:,:,1) = gdept_n(:,:,1) - sshn(:,:) |
|---|
| 380 | DO jk = 2, jpk |
|---|
| 381 | gdept_n(:,:,jk) = gdept_n(:,:,jk-1) + e3w_n(:,:,jk) |
|---|
| 382 | gdepw_n(:,:,jk) = gdepw_n(:,:,jk-1) + e3t_n(:,:,jk-1) |
|---|
| 383 | gde3w_n(:,:,jk) = gdept_n(:,:,jk ) - sshn (:,:) |
|---|
| 384 | END DO |
|---|
| 385 | ENDIF |
|---|
| 386 | ENDIF |
|---|
| 387 | ENDIF ! .NOT. ln_rstart |
|---|
| 388 | ! |
|---|
| 389 | END SUBROUTINE lim_sbc_init |
|---|
| 390 | |
|---|
| 391 | #else |
|---|
| 392 | !!---------------------------------------------------------------------- |
|---|
| 393 | !! Default option : Dummy module NO LIM 3.0 sea-ice model |
|---|
| 394 | !!---------------------------------------------------------------------- |
|---|
| 395 | CONTAINS |
|---|
| 396 | SUBROUTINE lim_sbc ! Dummy routine |
|---|
| 397 | END SUBROUTINE lim_sbc |
|---|
| 398 | #endif |
|---|
| 399 | |
|---|
| 400 | !!====================================================================== |
|---|
| 401 | END MODULE limsbc |
|---|
