New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
limthd.F90 in branches/2017/dev_r8183_ICEMODEL/NEMOGCM/NEMO/LIM_SRC_3 – NEMO

source: branches/2017/dev_r8183_ICEMODEL/NEMOGCM/NEMO/LIM_SRC_3/limthd.F90 @ 8239

Last change on this file since 8239 was 8239, checked in by clem, 7 years ago

merge with v3_6_CMIP6_ice_diagnostics@r8238
  • Property svn:keywords set to Id
File size: 35.9 KB
Line 
1MODULE limthd
2   !!======================================================================
3   !!                  ***  MODULE limthd   ***
4   !!  LIM-3 :   ice thermodynamic
5   !!======================================================================
6   !! History :  LIM  ! 2000-01 (M.A. Morales Maqueda, H. Goosse, T. Fichefet) LIM-1
7   !!            2.0  ! 2002-07 (C. Ethe, G. Madec)  LIM-2 (F90 rewriting)
8   !!            3.0  ! 2005-11 (M. Vancoppenolle)  LIM-3 : Multi-layer thermodynamics + salinity variations
9   !!             -   ! 2007-04 (M. Vancoppenolle) add lim_thd_glohec, lim_thd_con_dh and lim_thd_con_dif
10   !!            3.2  ! 2009-07 (M. Vancoppenolle, Y. Aksenov, G. Madec) bug correction in wfx_snw
11   !!            3.3  ! 2010-11 (G. Madec) corrected snow melting heat (due to factor betas)
12   !!            4.0  ! 2011-02 (G. Madec) dynamical allocation
13   !!             -   ! 2012-05 (C. Rousset) add penetration solar flux
14   !!----------------------------------------------------------------------
15#if defined key_lim3
16   !!----------------------------------------------------------------------
17   !!   'key_lim3'                                      LIM3 sea-ice model
18   !!----------------------------------------------------------------------
19   !!   lim_thd       : thermodynamic of sea ice
20   !!   lim_thd_init  : initialisation of sea-ice thermodynamic
21   !!----------------------------------------------------------------------
22   USE phycst         ! physical constants
23   USE dom_oce        ! ocean space and time domain variables
24   USE ice            ! sea-ice variables
25   USE sbc_oce        ! Surface boundary condition: ocean fields
26   USE sbc_ice        ! Surface boundary condition: ice fields
27   USE thd_ice        ! thermodynamic sea-ice variables
28   USE limthd_dif     ! vertical diffusion
29   USE limthd_dh      ! ice-snow growth and melt
30   USE limthd_da      ! lateral melting
31   USE limthd_sal     ! ice salinity
32   USE limthd_ent     ! ice enthalpy redistribution
33   USE limthd_lac     ! lateral accretion
34   USE limitd_th      ! remapping thickness distribution
35   USE limtab         ! 1D <==> 2D transformation
36   USE limvar         !
37   USE limcons        ! conservation tests
38   USE limctl         ! control print
39   !
40   USE in_out_manager ! I/O manager
41   USE lbclnk         ! lateral boundary condition - MPP links
42   USE lib_mpp        ! MPP library
43   USE wrk_nemo       ! work arrays
44   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) 
45   USE timing         ! Timing
46
47   IMPLICIT NONE
48   PRIVATE
49
50   PUBLIC   lim_thd         ! called by limstp module
51   PUBLIC   lim_thd_init    ! called by sbc_lim_init
52
53   !! * Substitutions
54#  include "vectopt_loop_substitute.h90"
55   !!----------------------------------------------------------------------
56   !! NEMO/LIM3 3.3 , UCL - NEMO Consortium (2010)
57   !! $Id$
58   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
59   !!----------------------------------------------------------------------
60CONTAINS
61
62   SUBROUTINE lim_thd( kt )
63      !!-------------------------------------------------------------------
64      !!                ***  ROUTINE lim_thd  ***       
65      !! 
66      !! ** Purpose : This routine manages ice thermodynamics
67      !!         
68      !! ** Action : - Initialisation of some variables
69      !!             - Some preliminary computation (oceanic heat flux
70      !!               at the ice base, snow acc.,heat budget of the leads)
71      !!             - selection of the icy points and put them in an array
72      !!             - call lim_thd_dif  for vertical heat diffusion
73      !!             - call lim_thd_dh   for vertical ice growth and melt
74      !!             - call lim_thd_ent  for enthalpy remapping
75      !!             - call lim_thd_sal  for ice desalination
76      !!             - call lim_thd_temp to  retrieve temperature from ice enthalpy
77      !!             - back to the geographic grid
78      !!     
79      !! ** References :
80      !!---------------------------------------------------------------------
81      INTEGER, INTENT(in) :: kt    ! number of iteration
82      !
83      INTEGER  :: ji, jj, jk, jl   ! dummy loop indices
84      INTEGER  :: nbpb             ! nb of icy pts for vertical thermo calculations
85      REAL(wp) :: zfric_u, zqld, zqfr, zqfr_neg
86      REAL(wp) :: zvi_b, zsmv_b, zei_b, zfs_b, zfw_b, zft_b 
87      REAL(wp), PARAMETER :: zfric_umin = 0._wp           ! lower bound for the friction velocity (cice value=5.e-04)
88      REAL(wp), PARAMETER :: zch        = 0.0057_wp       ! heat transfer coefficient
89      REAL(wp), POINTER, DIMENSION(:,:) ::   zu_io, zv_io, zfric   ! ice-ocean velocity (m/s) and frictional velocity (m2/s2)
90      !
91      !!-------------------------------------------------------------------
92
93      IF( nn_timing == 1 )   CALL timing_start('limthd')
94
95      CALL wrk_alloc( jpi,jpj, zu_io, zv_io, zfric )
96
97      IF( kt == nit000 .AND. lwp ) THEN
98         WRITE(numout,*)'' 
99         WRITE(numout,*)' lim_thd '
100         WRITE(numout,*)' ~~~~~~~~'
101      ENDIF
102     
103      ! conservation test
104      IF( ln_limdiachk ) CALL lim_cons_hsm(0, 'limthd', zvi_b, zsmv_b, zei_b, zfw_b, zfs_b, zft_b)
105
106      CALL lim_var_glo2eqv
107
108      !---------------------------------------------!
109      ! computation of friction velocity at T points
110      !---------------------------------------------!
111      IF( ln_limdyn ) THEN
112         zu_io(:,:) = u_ice(:,:) - ssu_m(:,:)
113         zv_io(:,:) = v_ice(:,:) - ssv_m(:,:)
114         DO jj = 2, jpjm1 
115            DO ji = fs_2, fs_jpim1
116               zfric(ji,jj) = rn_cio * ( 0.5_wp *  &
117                  &                    (  zu_io(ji,jj) * zu_io(ji,jj) + zu_io(ji-1,jj) * zu_io(ji-1,jj)   &
118                  &                     + zv_io(ji,jj) * zv_io(ji,jj) + zv_io(ji,jj-1) * zv_io(ji,jj-1) ) ) * tmask(ji,jj,1)
119            END DO
120         END DO
121      ELSE      !  if no ice dynamics => transmit directly the atmospheric stress to the ocean
122         DO jj = 2, jpjm1
123            DO ji = fs_2, fs_jpim1
124               zfric(ji,jj) = r1_rau0 * SQRT( 0.5_wp *  &
125                  &                         (  utau(ji,jj) * utau(ji,jj) + utau(ji-1,jj) * utau(ji-1,jj)   &
126                  &                          + vtau(ji,jj) * vtau(ji,jj) + vtau(ji,jj-1) * vtau(ji,jj-1) ) ) * tmask(ji,jj,1)
127            END DO
128         END DO
129      ENDIF
130      CALL lbc_lnk( zfric, 'T',  1. )
131      !
132      !----------------------------------!
133      ! Initialization and units change
134      !----------------------------------!
135      ftr_ice(:,:,:) = 0._wp  ! part of solar radiation transmitted through the ice
136
137      ! Change the units of heat content; from J/m2 to J/m3
138      DO jl = 1, jpl
139         DO jk = 1, nlay_i
140            DO jj = 1, jpj
141               DO ji = 1, jpi
142                  rswitch = MAX(  0._wp , SIGN( 1._wp , v_i(ji,jj,jl) - epsi20 )  )
143                  !Energy of melting q(S,T) [J.m-3]
144                  e_i(ji,jj,jk,jl) = rswitch * e_i(ji,jj,jk,jl) / MAX( v_i(ji,jj,jl) , epsi20 ) * REAL( nlay_i )
145               END DO
146            END DO
147         END DO
148         DO jk = 1, nlay_s
149            DO jj = 1, jpj
150               DO ji = 1, jpi
151                  rswitch = MAX(  0._wp , SIGN( 1._wp , v_s(ji,jj,jl) - epsi20 )  )
152                  !Energy of melting q(S,T) [J.m-3]
153                  e_s(ji,jj,jk,jl) = rswitch * e_s(ji,jj,jk,jl) / MAX( v_s(ji,jj,jl) , epsi20 ) * REAL( nlay_s )
154               END DO
155            END DO
156         END DO
157      END DO
158
159      !--------------------------------------------------------------------!
160      ! Partial computation of forcing for the thermodynamic sea ice model
161      !--------------------------------------------------------------------!
162      DO jj = 1, jpj
163         DO ji = 1, jpi
164            rswitch  = tmask(ji,jj,1) * MAX( 0._wp , SIGN( 1._wp , at_i(ji,jj) - epsi10 ) ) ! 0 if no ice
165            !
166            !           !  solar irradiance transmission at the mixed layer bottom and used in the lead heat budget
167            !           !  practically no "direct lateral ablation"
168            !           
169            !           !  net downward heat flux from the ice to the ocean, expressed as a function of ocean
170            !           !  temperature and turbulent mixing (McPhee, 1992)
171            !
172            ! --- Energy received in the lead, zqld is defined everywhere (J.m-2) --- !
173            zqld =  tmask(ji,jj,1) * rdt_ice *  &
174               &    ( pfrld(ji,jj) * qsr_oce(ji,jj) * frq_m(ji,jj) + pfrld(ji,jj) * qns_oce(ji,jj) + qemp_oce(ji,jj) )
175
176            ! --- Energy needed to bring ocean surface layer until its freezing (<0, J.m-2) --- !
177            ! includes supercooling potential energy (>0) or "above-freezing" energy (<0)
178            zqfr = tmask(ji,jj,1) * rau0 * rcp * e3t_m(ji,jj) * ( t_bo(ji,jj) - ( sst_m(ji,jj) + rt0 ) )
179
180            ! --- Above-freezing sensible heat content (J/m2 grid)
181            zqfr_neg = tmask(ji,jj,1) * rau0 * rcp * e3t_m(ji,jj) * MIN( ( t_bo(ji,jj) - ( sst_m(ji,jj) + rt0 ) ), 0._wp )
182
183            ! --- Sensible ocean-to-ice heat flux (W/m2)
184            zfric_u      = MAX( SQRT( zfric(ji,jj) ), zfric_umin ) 
185            fhtur(ji,jj) = rswitch * rau0 * rcp * zch  * zfric_u * ( ( sst_m(ji,jj) + rt0 ) - t_bo(ji,jj) ) ! W.m-2
186
187            fhtur(ji,jj) = rswitch * MIN( fhtur(ji,jj), - zqfr_neg * r1_rdtice / MAX( at_i(ji,jj), epsi10 ) )
188            ! upper bound for fhtur: the heat retrieved from the ocean must be smaller than the heat necessary to reach
189            !                        the freezing point, so that we do not have SST < T_freeze
190            !                        This implies: - ( fhtur(ji,jj) * at_i(ji,jj) * rtdice ) - zqfr >= 0
191
192            !-- Energy Budget of the leads (J.m-2), source of lateral accretion. Must be < 0 to form ice
193            qlead(ji,jj) = MIN( 0._wp , zqld - ( fhtur(ji,jj) * at_i(ji,jj) * rdt_ice ) - zqfr )
194
195            ! If there is ice and leads are warming, then transfer energy from the lead budget and use it for bottom melting
196            IF( zqld > 0._wp ) THEN
197               fhld (ji,jj) = rswitch * zqld * r1_rdtice / MAX( at_i(ji,jj), epsi10 ) ! divided by at_i since this is (re)multiplied by a_i in limthd_dh.F90
198               qlead(ji,jj) = 0._wp
199            ELSE
200               fhld (ji,jj) = 0._wp
201            ENDIF
202            !
203            ! Net heat flux on top of the ice-ocean [W.m-2]
204            ! ---------------------------------------------
205            hfx_in(ji,jj) = qns_tot(ji,jj) + qsr_tot(ji,jj) 
206         END DO
207      END DO
208     
209      ! In case we bypass open-water ice formation
210      IF( .NOT. ln_limdO )  qlead(:,:) = 0._wp
211      ! In case we bypass growing/melting from top and bottom: we suppose ice is impermeable => ocean is isolated from atmosphere
212      IF( .NOT. ln_limdH )  hfx_in(:,:) = pfrld(:,:) * ( qns_oce(:,:) + qsr_oce(:,:) ) + qemp_oce(:,:)
213      IF( .NOT. ln_limdH )  fhtur (:,:) = 0._wp  ;  fhld  (:,:) = 0._wp
214
215      ! ---------------------------------------------------------------------
216      ! Net heat flux on top of the ocean after ice thermo (1st step) [W.m-2]
217      ! ---------------------------------------------------------------------
218      !     First  step here              :  non solar + precip - qlead - qturb
219      !     Second step in limthd_dh      :  heat remaining if total melt (zq_rema)
220      !     Third  step in limsbc         :  heat from ice-ocean mass exchange (zf_mass) + solar
221      DO jj = 1, jpj
222         DO ji = 1, jpi
223            hfx_out(ji,jj) =   pfrld(ji,jj) * qns_oce(ji,jj) + qemp_oce(ji,jj)  &  ! Non solar heat flux received by the ocean               
224               &             - qlead(ji,jj) * r1_rdtice                         &  ! heat flux taken from the ocean where there is open water ice formation
225               &             - at_i(ji,jj) * fhtur(ji,jj)                       &  ! heat flux taken by turbulence
226               &             - at_i(ji,jj) *  fhld(ji,jj)                          ! heat flux taken during bottom growth/melt
227                                                                                   !    (fhld should be 0 while bott growth)
228         END DO
229      END DO
230
231      !------------------------------------------------------------------------------!
232      ! Thermodynamic computation (only on grid points covered by ice)
233      !------------------------------------------------------------------------------!
234
235      DO jl = 1, jpl      !loop over ice categories
236
237         ! select ice covered grid points
238         nbpb = 0
239         DO jj = 1, jpj
240            DO ji = 1, jpi
241               IF ( a_i(ji,jj,jl) > epsi10 ) THEN     
242                  nbpb      = nbpb  + 1
243                  npb(nbpb) = (jj - 1) * jpi + ji
244               ENDIF
245            END DO
246         END DO
247
248         ! debug point to follow
249         jiindex_1d = 0
250         IF( ln_limctl ) THEN
251            DO ji = mi0(iiceprt), mi1(iiceprt)
252               DO jj = mj0(jiceprt), mj1(jiceprt)
253                  jiindex_1d = (jj - 1) * jpi + ji
254                  WRITE(numout,*) ' lim_thd : Category no : ', jl 
255               END DO
256            END DO
257         ENDIF
258
259         IF( lk_mpp )         CALL mpp_ini_ice( nbpb , numout )
260
261         IF( nbpb > 0 ) THEN  ! If there is no ice, do nothing.
262            !                                                               
263            s_i_new   (:) = 0._wp ; dh_s_tot (:) = 0._wp                     ! --- some init --- !
264            dh_i_surf (:) = 0._wp ; dh_i_bott(:) = 0._wp
265            dh_snowice(:) = 0._wp ; dh_i_sub (:) = 0._wp
266
267                              CALL lim_thd_1d2d( nbpb, jl, 1 )               ! --- Move to 1D arrays --- !
268            !
269            IF( ln_limdH )    CALL lim_thd_dif( 1, nbpb )                    ! --- Ice/Snow Temperature profile --- !
270            !
271            IF( ln_limdH )    CALL lim_thd_dh( 1, nbpb )                     ! --- Ice/Snow thickness --- !   
272            !
273            IF( ln_limdH )    CALL lim_thd_ent( 1, nbpb, q_i_1d(1:nbpb,:) )  ! --- Ice enthalpy remapping --- !
274            !
275                              CALL lim_thd_sal( 1, nbpb )                    ! --- Ice salinity --- !   
276            !
277                              CALL lim_thd_temp( 1, nbpb )                   ! --- temperature update --- !
278            !
279            IF( ln_limdH ) THEN
280               IF ( ( nn_monocat == 1 .OR. nn_monocat == 4 ) .AND. jpl == 1 ) THEN
281                              CALL lim_thd_lam( 1, nbpb )                    ! --- extra lateral melting if monocat --- !
282               END IF
283            END IF
284            !
285                              CALL lim_thd_1d2d( nbpb, jl, 2 )               ! --- Move to 2D arrays --- !
286            !
287            IF( lk_mpp )      CALL mpp_comm_free( ncomm_ice ) !RB necessary ??
288         ENDIF
289         !
290      END DO !jl
291
292      IF( ln_limdA)           CALL lim_thd_da                                ! --- lateral melting --- !
293
294      ! Enthalpies are global variables we have to readjust the units (heat content in J/m2)
295      DO jl = 1, jpl
296         DO jk = 1, nlay_i
297            e_i(:,:,jk,jl) = e_i(:,:,jk,jl) * a_i(:,:,jl) * ht_i(:,:,jl) * r1_nlay_i
298         END DO
299         DO jk = 1, nlay_s
300            e_s(:,:,jk,jl) = e_s(:,:,jk,jl) * a_i(:,:,jl) * ht_s(:,:,jl) * r1_nlay_s
301         END DO
302      END DO
303 
304      ! Change thickness to volume
305      v_i(:,:,:)   = ht_i(:,:,:) * a_i(:,:,:)
306      v_s(:,:,:)   = ht_s(:,:,:) * a_i(:,:,:)
307      smv_i(:,:,:) = sm_i(:,:,:) * v_i(:,:,:)
308
309      ! update ice age (in case a_i changed, i.e. becomes 0 or lateral melting in monocat)
310      DO jl  = 1, jpl
311         DO jj = 1, jpj
312            DO ji = 1, jpi
313               rswitch = MAX( 0._wp , SIGN( 1._wp, a_i_b(ji,jj,jl) - epsi10 ) )
314               oa_i(ji,jj,jl) = rswitch * oa_i(ji,jj,jl) * a_i(ji,jj,jl) / MAX( a_i_b(ji,jj,jl), epsi10 )
315            END DO
316         END DO
317      END DO
318
319      CALL lim_var_zapsmall
320
321      ! control checks
322      IF( ln_limctl )    CALL lim_prt( kt, iiceprt, jiceprt, 1, ' - ice thermodyn. - ' )   ! control print
323      !
324      IF( ln_limdiachk ) CALL lim_cons_hsm(1, 'limthd', zvi_b, zsmv_b, zei_b, zfw_b, zfs_b, zft_b)
325
326      !------------------------------------------------!
327      !  Transport ice between thickness categories
328      !------------------------------------------------!
329      ! Given thermodynamic growth rates, transport ice between thickness categories.
330      IF( ln_limdiachk ) CALL lim_cons_hsm(0, 'limitd_th_rem', zvi_b, zsmv_b, zei_b, zfw_b, zfs_b, zft_b)
331
332      IF( jpl > 1 )      CALL lim_itd_th_rem( 1, jpl, kt )
333
334      IF( ln_limdiachk ) CALL lim_cons_hsm(1, 'limitd_th_rem', zvi_b, zsmv_b, zei_b, zfw_b, zfs_b, zft_b)
335
336      !------------------------------------------------!
337      !  Add frazil ice growing in leads
338      !------------------------------------------------!
339      IF( ln_limdiachk ) CALL lim_cons_hsm(0, 'limthd_lac', zvi_b, zsmv_b, zei_b, zfw_b, zfs_b, zft_b)
340
341      IF( ln_limdO )     CALL lim_thd_lac
342     
343      ! conservation test
344      IF( ln_limdiachk ) CALL lim_cons_hsm(1, 'limthd_lac', zvi_b, zsmv_b, zei_b, zfw_b, zfs_b, zft_b)
345
346      ! Control print
347      IF( ln_ctl )       CALL lim_prt3D( 'limthd' )
348      !
349      CALL wrk_dealloc( jpi,jpj, zu_io, zv_io, zfric )
350      !
351      IF( nn_timing == 1 )  CALL timing_stop('limthd')
352
353   END SUBROUTINE lim_thd 
354
355 
356   SUBROUTINE lim_thd_temp( kideb, kiut )
357      !!-----------------------------------------------------------------------
358      !!                   ***  ROUTINE lim_thd_temp ***
359      !!                 
360      !! ** Purpose :   Computes sea ice temperature (Kelvin) from enthalpy
361      !!
362      !! ** Method  :   Formula (Bitz and Lipscomb, 1999)
363      !!-------------------------------------------------------------------
364      INTEGER, INTENT(in) ::   kideb, kiut   ! bounds for the spatial loop
365      !
366      INTEGER  ::   ji, jk   ! dummy loop indices
367      REAL(wp) ::   ztmelts, zaaa, zbbb, zccc, zdiscrim  ! local scalar
368      !!-------------------------------------------------------------------
369      ! Recover ice temperature
370      DO jk = 1, nlay_i
371         DO ji = kideb, kiut
372            ztmelts       =  -tmut * s_i_1d(ji,jk) + rt0
373            ! Conversion q(S,T) -> T (second order equation)
374            zaaa          =  cpic
375            zbbb          =  ( rcp - cpic ) * ( ztmelts - rt0 ) + q_i_1d(ji,jk) * r1_rhoic - lfus
376            zccc          =  lfus * ( ztmelts - rt0 )
377            zdiscrim      =  SQRT( MAX( zbbb * zbbb - 4._wp * zaaa * zccc, 0._wp ) )
378            t_i_1d(ji,jk) =  rt0 - ( zbbb + zdiscrim ) / ( 2._wp * zaaa )
379           
380            ! mask temperature
381            rswitch       =  1._wp - MAX( 0._wp , SIGN( 1._wp , - ht_i_1d(ji) ) ) 
382            t_i_1d(ji,jk) =  rswitch * t_i_1d(ji,jk) + ( 1._wp - rswitch ) * rt0
383         END DO
384      END DO 
385      !
386   END SUBROUTINE lim_thd_temp
387
388
389   SUBROUTINE lim_thd_lam( kideb, kiut )
390      !!-----------------------------------------------------------------------
391      !!                   ***  ROUTINE lim_thd_lam ***
392      !!                 
393      !! ** Purpose :   Lateral melting in case monocategory
394      !!                          ( dA = A/2h dh )
395      !!-----------------------------------------------------------------------
396      INTEGER, INTENT(in) ::   kideb, kiut        ! bounds for the spatial loop
397      !
398      INTEGER  ::   ji                 ! dummy loop indices
399      REAL(wp) ::   zhi_bef            ! ice thickness before thermo
400      REAL(wp) ::   zdh_mel, zda_mel   ! net melting
401      REAL(wp) ::   zvi, zvs           ! ice/snow volumes
402      !!-----------------------------------------------------------------------
403      !
404      DO ji = kideb, kiut
405         zdh_mel = MIN( 0._wp, dh_i_surf(ji) + dh_i_bott(ji) + dh_snowice(ji) + dh_i_sub(ji) )
406         IF( zdh_mel < 0._wp .AND. a_i_1d(ji) > 0._wp )  THEN
407            zvi          = a_i_1d(ji) * ht_i_1d(ji)
408            zvs          = a_i_1d(ji) * ht_s_1d(ji)
409            ! lateral melting = concentration change
410            zhi_bef     = ht_i_1d(ji) - zdh_mel
411            rswitch     = MAX( 0._wp , SIGN( 1._wp , zhi_bef - epsi20 ) )
412            zda_mel     = rswitch * a_i_1d(ji) * zdh_mel / ( 2._wp * MAX( zhi_bef, epsi20 ) )
413            a_i_1d(ji)  = MAX( epsi20, a_i_1d(ji) + zda_mel ) 
414            ! adjust thickness
415            ht_i_1d(ji) = zvi / a_i_1d(ji)           
416            ht_s_1d(ji) = zvs / a_i_1d(ji)           
417            ! retrieve total concentration
418            at_i_1d(ji) = a_i_1d(ji)
419         END IF
420      END DO
421      !
422   END SUBROUTINE lim_thd_lam
423
424
425   SUBROUTINE lim_thd_1d2d( nbpb, jl, kn )
426      !!-----------------------------------------------------------------------
427      !!                   ***  ROUTINE lim_thd_1d2d ***
428      !!                 
429      !! ** Purpose :   move arrays from 1d to 2d and the reverse
430      !!-----------------------------------------------------------------------
431      INTEGER, INTENT(in) ::   kn       ! 1= from 2D to 1D   ;   2= from 1D to 2D
432      INTEGER, INTENT(in) ::   nbpb     ! size of 1D arrays
433      INTEGER, INTENT(in) ::   jl       ! ice cat
434      !
435      INTEGER             ::   jk       ! dummy loop indices
436      !!-----------------------------------------------------------------------
437      !
438      SELECT CASE( kn )
439      !
440      CASE( 1 )            ! from 2D to 1D
441         !
442         CALL tab_2d_1d( nbpb, at_i_1d     (1:nbpb), at_i            , jpi, jpj, npb(1:nbpb) )
443         CALL tab_2d_1d( nbpb, a_i_1d      (1:nbpb), a_i(:,:,jl)     , jpi, jpj, npb(1:nbpb) )
444         CALL tab_2d_1d( nbpb, ht_i_1d     (1:nbpb), ht_i(:,:,jl)    , jpi, jpj, npb(1:nbpb) )
445         CALL tab_2d_1d( nbpb, ht_s_1d     (1:nbpb), ht_s(:,:,jl)    , jpi, jpj, npb(1:nbpb) )
446         !
447         CALL tab_2d_1d( nbpb, t_su_1d     (1:nbpb), t_su(:,:,jl)    , jpi, jpj, npb(1:nbpb) )
448         CALL tab_2d_1d( nbpb, sm_i_1d     (1:nbpb), sm_i(:,:,jl)    , jpi, jpj, npb(1:nbpb) )
449         DO jk = 1, nlay_s
450            CALL tab_2d_1d( nbpb, t_s_1d(1:nbpb,jk), t_s(:,:,jk,jl)  , jpi, jpj, npb(1:nbpb) )
451            CALL tab_2d_1d( nbpb, q_s_1d(1:nbpb,jk), e_s(:,:,jk,jl)  , jpi, jpj, npb(1:nbpb) )
452         END DO
453         DO jk = 1, nlay_i
454            CALL tab_2d_1d( nbpb, t_i_1d(1:nbpb,jk), t_i(:,:,jk,jl)  , jpi, jpj, npb(1:nbpb) )
455            CALL tab_2d_1d( nbpb, q_i_1d(1:nbpb,jk), e_i(:,:,jk,jl)  , jpi, jpj, npb(1:nbpb) )
456            CALL tab_2d_1d( nbpb, s_i_1d(1:nbpb,jk), s_i(:,:,jk,jl)  , jpi, jpj, npb(1:nbpb) )
457         END DO
458         !
459         CALL tab_2d_1d( nbpb, qprec_ice_1d(1:nbpb), qprec_ice(:,:) , jpi, jpj, npb(1:nbpb) )
460         CALL tab_2d_1d( nbpb, qevap_ice_1d(1:nbpb), qevap_ice(:,:,jl) , jpi, jpj, npb(1:nbpb) )
461         CALL tab_2d_1d( nbpb, qsr_ice_1d (1:nbpb), qsr_ice(:,:,jl) , jpi, jpj, npb(1:nbpb) )
462         CALL tab_2d_1d( nbpb, fr1_i0_1d  (1:nbpb), fr1_i0          , jpi, jpj, npb(1:nbpb) )
463         CALL tab_2d_1d( nbpb, fr2_i0_1d  (1:nbpb), fr2_i0          , jpi, jpj, npb(1:nbpb) )
464         CALL tab_2d_1d( nbpb, qns_ice_1d (1:nbpb), qns_ice(:,:,jl) , jpi, jpj, npb(1:nbpb) )
465         CALL tab_2d_1d( nbpb, ftr_ice_1d (1:nbpb), ftr_ice(:,:,jl) , jpi, jpj, npb(1:nbpb) )
466         CALL tab_2d_1d( nbpb, evap_ice_1d (1:nbpb), evap_ice(:,:,jl), jpi, jpj, npb(1:nbpb) )
467         CALL tab_2d_1d( nbpb, dqns_ice_1d(1:nbpb), dqns_ice(:,:,jl), jpi, jpj, npb(1:nbpb) )
468         CALL tab_2d_1d( nbpb, t_bo_1d     (1:nbpb), t_bo            , jpi, jpj, npb(1:nbpb) )
469         CALL tab_2d_1d( nbpb, sprecip_1d (1:nbpb), sprecip         , jpi, jpj, npb(1:nbpb) ) 
470         CALL tab_2d_1d( nbpb, fhtur_1d   (1:nbpb), fhtur           , jpi, jpj, npb(1:nbpb) )
471         CALL tab_2d_1d( nbpb, qlead_1d   (1:nbpb), qlead           , jpi, jpj, npb(1:nbpb) )
472         CALL tab_2d_1d( nbpb, fhld_1d    (1:nbpb), fhld            , jpi, jpj, npb(1:nbpb) )
473         !
474         CALL tab_2d_1d( nbpb, wfx_snw_1d (1:nbpb), wfx_snw         , jpi, jpj, npb(1:nbpb) )
475         CALL tab_2d_1d( nbpb, wfx_snw_sum_1d(1:nbpb), wfx_snw_sum  , jpi, jpj, npb(1:nbpb) )
476         CALL tab_2d_1d( nbpb, wfx_sub_1d (1:nbpb), wfx_sub         , jpi, jpj, npb(1:nbpb) )
477         CALL tab_2d_1d( nbpb, wfx_snw_sub_1d(1:nbpb), wfx_snw_sub  , jpi, jpj, npb(1:nbpb) )
478         CALL tab_2d_1d( nbpb, wfx_ice_sub_1d(1:nbpb), wfx_ice_sub  , jpi, jpj, npb(1:nbpb) )
479         !
480         CALL tab_2d_1d( nbpb, wfx_bog_1d (1:nbpb), wfx_bog         , jpi, jpj, npb(1:nbpb) )
481         CALL tab_2d_1d( nbpb, wfx_bom_1d (1:nbpb), wfx_bom         , jpi, jpj, npb(1:nbpb) )
482         CALL tab_2d_1d( nbpb, wfx_sum_1d (1:nbpb), wfx_sum         , jpi, jpj, npb(1:nbpb) )
483         CALL tab_2d_1d( nbpb, wfx_sni_1d (1:nbpb), wfx_sni         , jpi, jpj, npb(1:nbpb) )
484         CALL tab_2d_1d( nbpb, wfx_res_1d (1:nbpb), wfx_res         , jpi, jpj, npb(1:nbpb) )
485         CALL tab_2d_1d( nbpb, wfx_spr_1d (1:nbpb), wfx_spr         , jpi, jpj, npb(1:nbpb) )
486         !
487         CALL tab_2d_1d( nbpb, sfx_bog_1d (1:nbpb), sfx_bog         , jpi, jpj, npb(1:nbpb) )
488         CALL tab_2d_1d( nbpb, sfx_bom_1d (1:nbpb), sfx_bom         , jpi, jpj, npb(1:nbpb) )
489         CALL tab_2d_1d( nbpb, sfx_sum_1d (1:nbpb), sfx_sum         , jpi, jpj, npb(1:nbpb) )
490         CALL tab_2d_1d( nbpb, sfx_sni_1d (1:nbpb), sfx_sni         , jpi, jpj, npb(1:nbpb) )
491         CALL tab_2d_1d( nbpb, sfx_bri_1d (1:nbpb), sfx_bri         , jpi, jpj, npb(1:nbpb) )
492         CALL tab_2d_1d( nbpb, sfx_res_1d (1:nbpb), sfx_res         , jpi, jpj, npb(1:nbpb) )
493         CALL tab_2d_1d( nbpb, sfx_sub_1d (1:nbpb), sfx_sub         , jpi, jpj,npb(1:nbpb) )
494         !
495         CALL tab_2d_1d( nbpb, hfx_thd_1d (1:nbpb), hfx_thd         , jpi, jpj, npb(1:nbpb) )
496         CALL tab_2d_1d( nbpb, hfx_spr_1d (1:nbpb), hfx_spr         , jpi, jpj, npb(1:nbpb) )
497         CALL tab_2d_1d( nbpb, hfx_sum_1d (1:nbpb), hfx_sum         , jpi, jpj, npb(1:nbpb) )
498         CALL tab_2d_1d( nbpb, hfx_bom_1d (1:nbpb), hfx_bom         , jpi, jpj, npb(1:nbpb) )
499         CALL tab_2d_1d( nbpb, hfx_bog_1d (1:nbpb), hfx_bog         , jpi, jpj, npb(1:nbpb) )
500         CALL tab_2d_1d( nbpb, hfx_dif_1d (1:nbpb), hfx_dif         , jpi, jpj, npb(1:nbpb) )
501         CALL tab_2d_1d( nbpb, hfx_opw_1d (1:nbpb), hfx_opw         , jpi, jpj, npb(1:nbpb) )
502         CALL tab_2d_1d( nbpb, hfx_snw_1d (1:nbpb), hfx_snw         , jpi, jpj, npb(1:nbpb) )
503         CALL tab_2d_1d( nbpb, hfx_sub_1d (1:nbpb), hfx_sub         , jpi, jpj, npb(1:nbpb) )
504         CALL tab_2d_1d( nbpb, hfx_err_1d (1:nbpb), hfx_err         , jpi, jpj, npb(1:nbpb) )
505         CALL tab_2d_1d( nbpb, hfx_res_1d (1:nbpb), hfx_res         , jpi, jpj, npb(1:nbpb) )
506         CALL tab_2d_1d( nbpb, hfx_err_dif_1d (1:nbpb), hfx_err_dif , jpi, jpj, npb(1:nbpb) )
507         CALL tab_2d_1d( nbpb, hfx_err_rem_1d (1:nbpb), hfx_err_rem , jpi, jpj, npb(1:nbpb) )
508         !
509         ! SIMIP diagnostics
510         CALL tab_2d_1d( nbpb, diag_fc_bo_1d   (1:nbpb), diag_fc_bo  , jpi, jpj, npb(1:nbpb) )
511         CALL tab_2d_1d( nbpb, diag_fc_su_1d   (1:nbpb), diag_fc_su  , jpi, jpj, npb(1:nbpb) )
512         !
513      CASE( 2 )            ! from 1D to 2D
514         !
515         CALL tab_1d_2d( nbpb, at_i          , npb, at_i_1d    (1:nbpb)   , jpi, jpj )
516         CALL tab_1d_2d( nbpb, ht_i(:,:,jl)  , npb, ht_i_1d    (1:nbpb)   , jpi, jpj )
517         CALL tab_1d_2d( nbpb, ht_s(:,:,jl)  , npb, ht_s_1d    (1:nbpb)   , jpi, jpj )
518         CALL tab_1d_2d( nbpb, a_i (:,:,jl)  , npb, a_i_1d     (1:nbpb)   , jpi, jpj )
519         CALL tab_1d_2d( nbpb, t_su(:,:,jl)  , npb, t_su_1d    (1:nbpb)   , jpi, jpj )
520         CALL tab_1d_2d( nbpb, sm_i(:,:,jl)  , npb, sm_i_1d    (1:nbpb)   , jpi, jpj )
521         DO jk = 1, nlay_s
522            CALL tab_1d_2d( nbpb, t_s(:,:,jk,jl), npb, t_s_1d     (1:nbpb,jk), jpi, jpj)
523            CALL tab_1d_2d( nbpb, e_s(:,:,jk,jl), npb, q_s_1d     (1:nbpb,jk), jpi, jpj)
524         END DO
525         DO jk = 1, nlay_i
526            CALL tab_1d_2d( nbpb, t_i(:,:,jk,jl), npb, t_i_1d     (1:nbpb,jk), jpi, jpj)
527            CALL tab_1d_2d( nbpb, e_i(:,:,jk,jl), npb, q_i_1d     (1:nbpb,jk), jpi, jpj)
528            CALL tab_1d_2d( nbpb, s_i(:,:,jk,jl), npb, s_i_1d     (1:nbpb,jk), jpi, jpj)
529         END DO
530         CALL tab_1d_2d( nbpb, qlead         , npb, qlead_1d  (1:nbpb)   , jpi, jpj )
531         !
532         CALL tab_1d_2d( nbpb, wfx_snw       , npb, wfx_snw_1d(1:nbpb)   , jpi, jpj )
533         CALL tab_1d_2d( nbpb, wfx_snw_sum   , npb, wfx_snw_sum_1d(1:nbpb),jpi, jpj )
534         CALL tab_1d_2d( nbpb, wfx_sub       , npb, wfx_sub_1d(1:nbpb)   , jpi, jpj )
535         CALL tab_1d_2d( nbpb, wfx_snw_sub   , npb, wfx_snw_sub_1d(1:nbpb), jpi, jpj )
536         CALL tab_1d_2d( nbpb, wfx_ice_sub   , npb, wfx_ice_sub_1d(1:nbpb), jpi, jpj )
537         !
538         CALL tab_1d_2d( nbpb, wfx_bog       , npb, wfx_bog_1d(1:nbpb)   , jpi, jpj )
539         CALL tab_1d_2d( nbpb, wfx_bom       , npb, wfx_bom_1d(1:nbpb)   , jpi, jpj )
540         CALL tab_1d_2d( nbpb, wfx_sum       , npb, wfx_sum_1d(1:nbpb)   , jpi, jpj )
541         CALL tab_1d_2d( nbpb, wfx_sni       , npb, wfx_sni_1d(1:nbpb)   , jpi, jpj )
542         CALL tab_1d_2d( nbpb, wfx_res       , npb, wfx_res_1d(1:nbpb)   , jpi, jpj )
543         CALL tab_1d_2d( nbpb, wfx_spr       , npb, wfx_spr_1d(1:nbpb)   , jpi, jpj )
544         !
545         CALL tab_1d_2d( nbpb, sfx_bog       , npb, sfx_bog_1d(1:nbpb)   , jpi, jpj )
546         CALL tab_1d_2d( nbpb, sfx_bom       , npb, sfx_bom_1d(1:nbpb)   , jpi, jpj )
547         CALL tab_1d_2d( nbpb, sfx_sum       , npb, sfx_sum_1d(1:nbpb)   , jpi, jpj )
548         CALL tab_1d_2d( nbpb, sfx_sni       , npb, sfx_sni_1d(1:nbpb)   , jpi, jpj )
549         CALL tab_1d_2d( nbpb, sfx_res       , npb, sfx_res_1d(1:nbpb)   , jpi, jpj )
550         CALL tab_1d_2d( nbpb, sfx_bri       , npb, sfx_bri_1d(1:nbpb)   , jpi, jpj )
551         CALL tab_1d_2d( nbpb, sfx_sub       , npb, sfx_sub_1d(1:nbpb)   , jpi, jpj )       
552         !
553         CALL tab_1d_2d( nbpb, hfx_thd       , npb, hfx_thd_1d(1:nbpb)   , jpi, jpj )
554         CALL tab_1d_2d( nbpb, hfx_spr       , npb, hfx_spr_1d(1:nbpb)   , jpi, jpj )
555         CALL tab_1d_2d( nbpb, hfx_sum       , npb, hfx_sum_1d(1:nbpb)   , jpi, jpj )
556         CALL tab_1d_2d( nbpb, hfx_bom       , npb, hfx_bom_1d(1:nbpb)   , jpi, jpj )
557         CALL tab_1d_2d( nbpb, hfx_bog       , npb, hfx_bog_1d(1:nbpb)   , jpi, jpj )
558         CALL tab_1d_2d( nbpb, hfx_dif       , npb, hfx_dif_1d(1:nbpb)   , jpi, jpj )
559         CALL tab_1d_2d( nbpb, hfx_opw       , npb, hfx_opw_1d(1:nbpb)   , jpi, jpj )
560         CALL tab_1d_2d( nbpb, hfx_snw       , npb, hfx_snw_1d(1:nbpb)   , jpi, jpj )
561         CALL tab_1d_2d( nbpb, hfx_sub       , npb, hfx_sub_1d(1:nbpb)   , jpi, jpj )
562         CALL tab_1d_2d( nbpb, hfx_err       , npb, hfx_err_1d(1:nbpb)   , jpi, jpj )
563         CALL tab_1d_2d( nbpb, hfx_res       , npb, hfx_res_1d(1:nbpb)   , jpi, jpj )
564         CALL tab_1d_2d( nbpb, hfx_err_rem   , npb, hfx_err_rem_1d(1:nbpb), jpi, jpj )
565         CALL tab_1d_2d( nbpb, hfx_err_dif   , npb, hfx_err_dif_1d(1:nbpb), jpi, jpj )
566         !
567         CALL tab_1d_2d( nbpb, qns_ice(:,:,jl), npb, qns_ice_1d(1:nbpb) , jpi, jpj)
568         CALL tab_1d_2d( nbpb, ftr_ice(:,:,jl), npb, ftr_ice_1d(1:nbpb) , jpi, jpj )
569         !
570         ! SIMIP diagnostics         
571         CALL tab_1d_2d( nbpb, t_si(:,:,jl)   , npb, t_si_1d    (1:nbpb)     , jpi, jpj )
572         CALL tab_1d_2d( nbpb, diag_fc_bo     , npb, diag_fc_bo_1d(1:nbpb)   , jpi, jpj )
573         CALL tab_1d_2d( nbpb, diag_fc_su     , npb, diag_fc_su_1d(1:nbpb)   , jpi, jpj )
574      END SELECT
575      !
576   END SUBROUTINE lim_thd_1d2d
577
578
579   SUBROUTINE lim_thd_init
580      !!-----------------------------------------------------------------------
581      !!                   ***  ROUTINE lim_thd_init ***
582      !!                 
583      !! ** Purpose :   Physical constants and parameters linked to the ice
584      !!              thermodynamics
585      !!
586      !! ** Method  :   Read the namicethd namelist and check the ice-thermo
587      !!              parameter values called at the first timestep (nit000)
588      !!
589      !! ** input   :   Namelist namicether
590      !!-------------------------------------------------------------------
591      INTEGER  ::   ios                 ! Local integer output status for namelist read
592      NAMELIST/namicethd/ rn_kappa_i, nn_conv_dif, rn_terr_dif, nn_ice_thcon, ln_it_qnsice, nn_monocat, rn_cdsn,  &
593         &                ln_limdH, rn_betas,                                                                     &
594         &                ln_limdA, rn_beta, rn_dmin,                                                             &
595         &                ln_limdO, rn_hnewice, ln_frazil, rn_maxfrazb, rn_vfrazb, rn_Cfrazb, rn_himin
596      !!-------------------------------------------------------------------
597      !
598      REWIND( numnam_ice_ref )              ! Namelist namicethd in reference namelist : Ice thermodynamics
599      READ  ( numnam_ice_ref, namicethd, IOSTAT = ios, ERR = 901)
600901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namicethd in reference namelist', lwp )
601
602      REWIND( numnam_ice_cfg )              ! Namelist namicethd in configuration namelist : Ice thermodynamics
603      READ  ( numnam_ice_cfg, namicethd, IOSTAT = ios, ERR = 902 )
604902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namicethd in configuration namelist', lwp )
605      IF(lwm) WRITE ( numoni, namicethd )
606      !
607      IF ( ( jpl > 1 ) .AND. ( nn_monocat == 1 ) ) THEN
608         nn_monocat = 0
609         IF(lwp) WRITE(numout,*)
610         IF(lwp) WRITE(numout,*) '   nn_monocat forced to 0 as jpl>1, i.e. multi-category case is chosen'
611      ENDIF
612      !
613      IF(lwp) THEN                          ! control print
614         WRITE(numout,*) 'lim_thd_init : Ice Thermodynamics'
615         WRITE(numout,*) '~~~~~~~~~~~~~'
616         WRITE(numout,*)'   -- limthd_dif --'
617         WRITE(numout,*)'      extinction radiation parameter in sea ice               rn_kappa_i   = ', rn_kappa_i
618         WRITE(numout,*)'      maximal n. of iter. for heat diffusion computation      nn_conv_dif  = ', nn_conv_dif
619         WRITE(numout,*)'      maximal err. on T for heat diffusion computation        rn_terr_dif  = ', rn_terr_dif
620         WRITE(numout,*)'      switch for comp. of thermal conductivity in the ice     nn_ice_thcon = ', nn_ice_thcon
621         WRITE(numout,*)'      iterate the surface non-solar flux (T) or not (F)       ln_it_qnsice = ', ln_it_qnsice
622         WRITE(numout,*)'      virtual ITD mono-category parameterizations (1) or not  nn_monocat   = ', nn_monocat
623         WRITE(numout,*)'      thermal conductivity of the snow                        rn_cdsn      = ', rn_cdsn
624         WRITE(numout,*)'   -- limthd_dh --'
625         WRITE(numout,*)'      activate ice thick change from top/bot (T) or not (F)   ln_limdH     = ', ln_limdH
626         WRITE(numout,*)'      coefficient for ice-lead partition of snowfall          rn_betas     = ', rn_betas
627         WRITE(numout,*)'   -- limthd_da --'
628         WRITE(numout,*)'      activate lateral melting (T) or not (F)                 ln_limdA     = ', ln_limdA
629         WRITE(numout,*)'      Coef. beta for lateral melting param.                   rn_beta      = ', rn_beta
630         WRITE(numout,*)'      Minimum floe diameter for lateral melting param.        rn_dmin      = ', rn_dmin
631         WRITE(numout,*)'   -- limthd_lac --'
632         WRITE(numout,*)'      activate ice growth in open-water (T) or not (F)        ln_limdO     = ', ln_limdO
633         WRITE(numout,*)'      ice thick. for lateral accretion                        rn_hnewice   = ', rn_hnewice
634         WRITE(numout,*)'      Frazil ice thickness as a function of wind or not       ln_frazil    = ', ln_frazil
635         WRITE(numout,*)'      Maximum proportion of frazil ice collecting at bottom   rn_maxfrazb  = ', rn_maxfrazb
636         WRITE(numout,*)'      Thresold relative drift speed for collection of frazil  rn_vfrazb    = ', rn_vfrazb
637         WRITE(numout,*)'      Squeezing coefficient for collection of frazil          rn_Cfrazb    = ', rn_Cfrazb
638         WRITE(numout,*)'   -- limitd_th --'
639         WRITE(numout,*)'      minimum ice thickness                                   rn_himin     = ', rn_himin 
640         WRITE(numout,*)'      check heat conservation in the ice/snow                 con_i        = ', con_i
641      ENDIF
642      !
643   END SUBROUTINE lim_thd_init
644
645#else
646   !!----------------------------------------------------------------------
647   !!   Default option         Dummy module          NO  LIM3 sea-ice model
648   !!----------------------------------------------------------------------
649#endif
650
651   !!======================================================================
652END MODULE limthd
Note: See TracBrowser for help on using the repository browser.