New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
limthd.F90 in branches/2017/dev_r8183_ICEMODEL/NEMOGCM/NEMO/LIM_SRC_3 – NEMO

source: branches/2017/dev_r8183_ICEMODEL/NEMOGCM/NEMO/LIM_SRC_3/limthd.F90 @ 8321

Last change on this file since 8321 was 8321, checked in by clem, 7 years ago

STEP3 (1): clean separation between sea-ice and ocean
  • Property svn:keywords set to Id
File size: 36.9 KB
Line 
1MODULE limthd
2   !!======================================================================
3   !!                  ***  MODULE limthd   ***
4   !!  LIM-3 :   ice thermodynamic
5   !!======================================================================
6   !! History :  LIM  ! 2000-01 (M.A. Morales Maqueda, H. Goosse, T. Fichefet) LIM-1
7   !!            2.0  ! 2002-07 (C. Ethe, G. Madec)  LIM-2 (F90 rewriting)
8   !!            3.0  ! 2005-11 (M. Vancoppenolle)  LIM-3 : Multi-layer thermodynamics + salinity variations
9   !!             -   ! 2007-04 (M. Vancoppenolle) add lim_thd_glohec, lim_thd_con_dh and lim_thd_con_dif
10   !!            3.2  ! 2009-07 (M. Vancoppenolle, Y. Aksenov, G. Madec) bug correction in wfx_snw
11   !!            3.3  ! 2010-11 (G. Madec) corrected snow melting heat (due to factor betas)
12   !!            4.0  ! 2011-02 (G. Madec) dynamical allocation
13   !!             -   ! 2012-05 (C. Rousset) add penetration solar flux
14   !!----------------------------------------------------------------------
15#if defined key_lim3
16   !!----------------------------------------------------------------------
17   !!   'key_lim3'                                      LIM3 sea-ice model
18   !!----------------------------------------------------------------------
19   !!   lim_thd       : thermodynamic of sea ice
20   !!   lim_thd_init  : initialisation of sea-ice thermodynamic
21   !!----------------------------------------------------------------------
22   USE phycst         ! physical constants
23   USE dom_oce        ! ocean space and time domain variables
24   USE ice            ! sea-ice variables
25   USE sbc_oce , ONLY : sst_m, e3t_m, utau, vtau, ssu_m, ssv_m, frq_m, qns_tot, qsr_tot, sprecip, ln_cpl
26   USE sbc_ice , ONLY : qsr_oce, qns_oce, qemp_oce, qsr_ice, qns_ice, dqns_ice, evap_ice, qprec_ice, qevap_ice, &
27      &                 fr1_i0, fr2_i0, nn_limflx
28   USE thd_ice        ! thermodynamic sea-ice variables
29   USE limthd_dif     ! vertical diffusion
30   USE limthd_dh      ! ice-snow growth and melt
31   USE limthd_da      ! lateral melting
32   USE limthd_sal     ! ice salinity
33   USE limthd_ent     ! ice enthalpy redistribution
34   USE limthd_lac     ! lateral accretion
35   USE limitd_th      ! remapping thickness distribution
36   USE limtab         ! 1D <==> 2D transformation
37   USE limvar         !
38   USE limcons        ! conservation tests
39   USE limctl         ! control print
40   !
41   USE in_out_manager ! I/O manager
42   USE lbclnk         ! lateral boundary condition - MPP links
43   USE lib_mpp        ! MPP library
44   USE wrk_nemo       ! work arrays
45   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) 
46   USE timing         ! Timing
47
48   IMPLICIT NONE
49   PRIVATE
50
51   PUBLIC   lim_thd         ! called by limstp module
52   PUBLIC   lim_thd_init    ! called by ice_init
53
54   !! * Substitutions
55#  include "vectopt_loop_substitute.h90"
56   !!----------------------------------------------------------------------
57   !! NEMO/LIM3 3.3 , UCL - NEMO Consortium (2010)
58   !! $Id$
59   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
60   !!----------------------------------------------------------------------
61CONTAINS
62
63   SUBROUTINE lim_thd( kt )
64      !!-------------------------------------------------------------------
65      !!                ***  ROUTINE lim_thd  ***       
66      !! 
67      !! ** Purpose : This routine manages ice thermodynamics
68      !!         
69      !! ** Action : - Initialisation of some variables
70      !!             - Some preliminary computation (oceanic heat flux
71      !!               at the ice base, snow acc.,heat budget of the leads)
72      !!             - selection of the icy points and put them in an array
73      !!             - call lim_thd_dif  for vertical heat diffusion
74      !!             - call lim_thd_dh   for vertical ice growth and melt
75      !!             - call lim_thd_ent  for enthalpy remapping
76      !!             - call lim_thd_sal  for ice desalination
77      !!             - call lim_thd_temp to  retrieve temperature from ice enthalpy
78      !!             - back to the geographic grid
79      !!     
80      !! ** References :
81      !!---------------------------------------------------------------------
82      INTEGER, INTENT(in) :: kt    ! number of iteration
83      !
84      INTEGER  :: ji, jj, jk, jl   ! dummy loop indices
85      INTEGER  :: nbpb             ! nb of icy pts for vertical thermo calculations
86      REAL(wp) :: zfric_u, zqld, zqfr, zqfr_neg
87      REAL(wp) :: zvi_b, zsmv_b, zei_b, zfs_b, zfw_b, zft_b 
88      REAL(wp), PARAMETER :: zfric_umin = 0._wp           ! lower bound for the friction velocity (cice value=5.e-04)
89      REAL(wp), PARAMETER :: zch        = 0.0057_wp       ! heat transfer coefficient
90      REAL(wp), POINTER, DIMENSION(:,:) ::   zu_io, zv_io, zfric   ! ice-ocean velocity (m/s) and frictional velocity (m2/s2)
91      !
92      !!-------------------------------------------------------------------
93
94      IF( nn_timing == 1 )   CALL timing_start('limthd')
95
96      CALL wrk_alloc( jpi,jpj, zu_io, zv_io, zfric )
97
98      IF( kt == nit000 .AND. lwp ) THEN
99         WRITE(numout,*)'' 
100         WRITE(numout,*)' lim_thd '
101         WRITE(numout,*)' ~~~~~~~~'
102      ENDIF
103     
104      ! conservation test
105      IF( ln_limdiachk ) CALL lim_cons_hsm(0, 'limthd', zvi_b, zsmv_b, zei_b, zfw_b, zfs_b, zft_b)
106
107      CALL lim_var_glo2eqv
108
109      !---------------------------------------------!
110      ! computation of friction velocity at T points
111      !---------------------------------------------!
112      IF( ln_limdyn ) THEN
113         zu_io(:,:) = u_ice(:,:) - ssu_m(:,:)
114         zv_io(:,:) = v_ice(:,:) - ssv_m(:,:)
115         DO jj = 2, jpjm1 
116            DO ji = fs_2, fs_jpim1
117               zfric(ji,jj) = rn_cio * ( 0.5_wp *  &
118                  &                    (  zu_io(ji,jj) * zu_io(ji,jj) + zu_io(ji-1,jj) * zu_io(ji-1,jj)   &
119                  &                     + zv_io(ji,jj) * zv_io(ji,jj) + zv_io(ji,jj-1) * zv_io(ji,jj-1) ) ) * tmask(ji,jj,1)
120            END DO
121         END DO
122      ELSE      !  if no ice dynamics => transmit directly the atmospheric stress to the ocean
123         DO jj = 2, jpjm1
124            DO ji = fs_2, fs_jpim1
125               zfric(ji,jj) = r1_rau0 * SQRT( 0.5_wp *  &
126                  &                         (  utau(ji,jj) * utau(ji,jj) + utau(ji-1,jj) * utau(ji-1,jj)   &
127                  &                          + vtau(ji,jj) * vtau(ji,jj) + vtau(ji,jj-1) * vtau(ji,jj-1) ) ) * tmask(ji,jj,1)
128            END DO
129         END DO
130      ENDIF
131      CALL lbc_lnk( zfric, 'T',  1. )
132      !
133      !----------------------------------!
134      ! Initialization and units change
135      !----------------------------------!
136      ftr_ice(:,:,:) = 0._wp  ! part of solar radiation transmitted through the ice
137
138      ! Change the units of heat content; from J/m2 to J/m3
139      DO jl = 1, jpl
140         DO jk = 1, nlay_i
141            DO jj = 1, jpj
142               DO ji = 1, jpi
143                  rswitch = MAX(  0._wp , SIGN( 1._wp , v_i(ji,jj,jl) - epsi20 )  )
144                  !Energy of melting q(S,T) [J.m-3]
145                  e_i(ji,jj,jk,jl) = rswitch * e_i(ji,jj,jk,jl) / MAX( v_i(ji,jj,jl) , epsi20 ) * REAL( nlay_i )
146               END DO
147            END DO
148         END DO
149         DO jk = 1, nlay_s
150            DO jj = 1, jpj
151               DO ji = 1, jpi
152                  rswitch = MAX(  0._wp , SIGN( 1._wp , v_s(ji,jj,jl) - epsi20 )  )
153                  !Energy of melting q(S,T) [J.m-3]
154                  e_s(ji,jj,jk,jl) = rswitch * e_s(ji,jj,jk,jl) / MAX( v_s(ji,jj,jl) , epsi20 ) * REAL( nlay_s )
155               END DO
156            END DO
157         END DO
158      END DO
159
160      !--------------------------------------------------------------------!
161      ! Partial computation of forcing for the thermodynamic sea ice model
162      !--------------------------------------------------------------------!
163      DO jj = 1, jpj
164         DO ji = 1, jpi
165            rswitch  = tmask(ji,jj,1) * MAX( 0._wp , SIGN( 1._wp , at_i(ji,jj) - epsi10 ) ) ! 0 if no ice
166            !
167            !           !  solar irradiance transmission at the mixed layer bottom and used in the lead heat budget
168            !           !  practically no "direct lateral ablation"
169            !           
170            !           !  net downward heat flux from the ice to the ocean, expressed as a function of ocean
171            !           !  temperature and turbulent mixing (McPhee, 1992)
172            !
173            ! --- Energy received in the lead, zqld is defined everywhere (J.m-2) --- !
174            zqld =  tmask(ji,jj,1) * rdt_ice *  &
175               &    ( ( 1._wp - at_i_b(ji,jj) ) * qsr_oce(ji,jj) * frq_m(ji,jj) +  &
176               &      ( 1._wp - at_i_b(ji,jj) ) * qns_oce(ji,jj) + qemp_oce(ji,jj) )
177
178            ! --- Energy needed to bring ocean surface layer until its freezing (<0, J.m-2) --- !
179            ! includes supercooling potential energy (>0) or "above-freezing" energy (<0)
180            zqfr = tmask(ji,jj,1) * rau0 * rcp * e3t_m(ji,jj) * ( t_bo(ji,jj) - ( sst_m(ji,jj) + rt0 ) )
181
182            ! --- Above-freezing sensible heat content (J/m2 grid)
183            zqfr_neg = tmask(ji,jj,1) * rau0 * rcp * e3t_m(ji,jj) * MIN( ( t_bo(ji,jj) - ( sst_m(ji,jj) + rt0 ) ), 0._wp )
184
185            ! --- Sensible ocean-to-ice heat flux (W/m2)
186            zfric_u      = MAX( SQRT( zfric(ji,jj) ), zfric_umin ) 
187            fhtur(ji,jj) = rswitch * rau0 * rcp * zch  * zfric_u * ( ( sst_m(ji,jj) + rt0 ) - t_bo(ji,jj) ) ! W.m-2
188
189            fhtur(ji,jj) = rswitch * MIN( fhtur(ji,jj), - zqfr_neg * r1_rdtice / MAX( at_i(ji,jj), epsi10 ) )
190            ! upper bound for fhtur: the heat retrieved from the ocean must be smaller than the heat necessary to reach
191            !                        the freezing point, so that we do not have SST < T_freeze
192            !                        This implies: - ( fhtur(ji,jj) * at_i(ji,jj) * rtdice ) - zqfr >= 0
193
194            !-- Energy Budget of the leads (J.m-2), source of lateral accretion. Must be < 0 to form ice
195            qlead(ji,jj) = MIN( 0._wp , zqld - ( fhtur(ji,jj) * at_i(ji,jj) * rdt_ice ) - zqfr )
196
197            ! If there is ice and leads are warming, then transfer energy from the lead budget and use it for bottom melting
198            IF( zqld > 0._wp ) THEN
199               fhld (ji,jj) = rswitch * zqld * r1_rdtice / MAX( at_i(ji,jj), epsi10 ) ! divided by at_i since this is (re)multiplied by a_i in limthd_dh.F90
200               qlead(ji,jj) = 0._wp
201            ELSE
202               fhld (ji,jj) = 0._wp
203            ENDIF
204            !
205            ! Net heat flux on top of the ice-ocean [W.m-2]
206            ! ---------------------------------------------
207            hfx_in(ji,jj) = qns_tot(ji,jj) + qsr_tot(ji,jj) 
208         END DO
209      END DO
210     
211      ! In case we bypass open-water ice formation
212      IF( .NOT. ln_limdO )  qlead(:,:) = 0._wp
213      ! In case we bypass growing/melting from top and bottom: we suppose ice is impermeable => ocean is isolated from atmosphere
214      IF( .NOT. ln_limdH )  hfx_in(:,:) = ( 1._wp - at_i_b(:,:) ) * ( qns_oce(:,:) + qsr_oce(:,:) ) + qemp_oce(:,:)
215      IF( .NOT. ln_limdH )  fhtur (:,:) = 0._wp  ;  fhld  (:,:) = 0._wp
216
217      ! ---------------------------------------------------------------------
218      ! Net heat flux on top of the ocean after ice thermo (1st step) [W.m-2]
219      ! ---------------------------------------------------------------------
220      !     First  step here              :  non solar + precip - qlead - qturb
221      !     Second step in limthd_dh      :  heat remaining if total melt (zq_rema)
222      !     Third  step in limsbc         :  heat from ice-ocean mass exchange (zf_mass) + solar
223      DO jj = 1, jpj
224         DO ji = 1, jpi
225            hfx_out(ji,jj) = ( 1._wp - at_i_b(ji,jj) ) * qns_oce(ji,jj) + qemp_oce(ji,jj)  &  ! Non solar heat flux received by the ocean               
226               &             - qlead(ji,jj) * r1_rdtice                                    &  ! heat flux taken from the ocean where there is open water ice formation
227               &             - at_i(ji,jj) * fhtur(ji,jj)                                  &  ! heat flux taken by turbulence
228               &             - at_i(ji,jj) *  fhld(ji,jj)                                     ! heat flux taken during bottom growth/melt
229                                                                                              !    (fhld should be 0 while bott growth)
230         END DO
231      END DO
232
233      !------------------------------------------------------------------------------!
234      ! Thermodynamic computation (only on grid points covered by ice)
235      !------------------------------------------------------------------------------!
236
237      DO jl = 1, jpl      !loop over ice categories
238
239         ! select ice covered grid points
240         nbpb = 0
241         DO jj = 1, jpj
242            DO ji = 1, jpi
243               IF ( a_i(ji,jj,jl) > epsi10 ) THEN     
244                  nbpb      = nbpb  + 1
245                  npb(nbpb) = (jj - 1) * jpi + ji
246               ENDIF
247            END DO
248         END DO
249
250         ! debug point to follow
251         jiindex_1d = 0
252         IF( ln_limctl ) THEN
253            DO ji = mi0(iiceprt), mi1(iiceprt)
254               DO jj = mj0(jiceprt), mj1(jiceprt)
255                  jiindex_1d = (jj - 1) * jpi + ji
256                  WRITE(numout,*) ' lim_thd : Category no : ', jl 
257               END DO
258            END DO
259         ENDIF
260
261         IF( lk_mpp )         CALL mpp_ini_ice( nbpb , numout )
262
263         IF( nbpb > 0 ) THEN  ! If there is no ice, do nothing.
264            !                                                               
265            s_i_new   (:) = 0._wp ; dh_s_tot (:) = 0._wp                     ! --- some init --- !
266            dh_i_surf (:) = 0._wp ; dh_i_bott(:) = 0._wp
267            dh_snowice(:) = 0._wp ; dh_i_sub (:) = 0._wp
268
269                              CALL lim_thd_1d2d( nbpb, jl, 1 )               ! --- Move to 1D arrays --- !
270            !
271            IF( ln_limdH )    CALL lim_thd_dif( 1, nbpb )                    ! --- Ice/Snow Temperature profile --- !
272            !
273            IF( ln_limdH )    CALL lim_thd_dh( 1, nbpb )                     ! --- Ice/Snow thickness --- !   
274            !
275            IF( ln_limdH )    CALL lim_thd_ent( 1, nbpb, q_i_1d(1:nbpb,:) )  ! --- Ice enthalpy remapping --- !
276            !
277                              CALL lim_thd_sal( 1, nbpb )                    ! --- Ice salinity --- !   
278            !
279                              CALL lim_thd_temp( 1, nbpb )                   ! --- temperature update --- !
280            !
281            IF( ln_limdH ) THEN
282               IF ( ( nn_monocat == 1 .OR. nn_monocat == 4 ) .AND. jpl == 1 ) THEN
283                              CALL lim_thd_lam( 1, nbpb )                    ! --- extra lateral melting if monocat --- !
284               END IF
285            END IF
286            !
287                              CALL lim_thd_1d2d( nbpb, jl, 2 )               ! --- Move to 2D arrays --- !
288            !
289            IF( lk_mpp )      CALL mpp_comm_free( ncomm_ice ) !RB necessary ??
290         ENDIF
291         !
292      END DO !jl
293
294      IF( ln_limdA)           CALL lim_thd_da                                ! --- lateral melting --- !
295
296      ! Enthalpies are global variables we have to readjust the units (heat content in J/m2)
297      DO jl = 1, jpl
298         DO jk = 1, nlay_i
299            e_i(:,:,jk,jl) = e_i(:,:,jk,jl) * a_i(:,:,jl) * ht_i(:,:,jl) * r1_nlay_i
300         END DO
301         DO jk = 1, nlay_s
302            e_s(:,:,jk,jl) = e_s(:,:,jk,jl) * a_i(:,:,jl) * ht_s(:,:,jl) * r1_nlay_s
303         END DO
304      END DO
305 
306      ! Change thickness to volume
307      v_i(:,:,:)   = ht_i(:,:,:) * a_i(:,:,:)
308      v_s(:,:,:)   = ht_s(:,:,:) * a_i(:,:,:)
309      smv_i(:,:,:) = sm_i(:,:,:) * v_i(:,:,:)
310
311      ! update ice age (in case a_i changed, i.e. becomes 0 or lateral melting in monocat)
312      DO jl  = 1, jpl
313         DO jj = 1, jpj
314            DO ji = 1, jpi
315               rswitch = MAX( 0._wp , SIGN( 1._wp, a_i_b(ji,jj,jl) - epsi10 ) )
316               oa_i(ji,jj,jl) = rswitch * oa_i(ji,jj,jl) * a_i(ji,jj,jl) / MAX( a_i_b(ji,jj,jl), epsi10 )
317            END DO
318         END DO
319      END DO
320
321      CALL lim_var_zapsmall
322
323      ! control checks
324      IF( ln_limctl )    CALL lim_prt( kt, iiceprt, jiceprt, 1, ' - ice thermodyn. - ' )   ! control print
325      !
326      IF( ln_limdiachk ) CALL lim_cons_hsm(1, 'limthd', zvi_b, zsmv_b, zei_b, zfw_b, zfs_b, zft_b)
327
328      !------------------------------------------------!
329      !  Transport ice between thickness categories
330      !------------------------------------------------!
331      ! Given thermodynamic growth rates, transport ice between thickness categories.
332      IF( ln_limdiachk ) CALL lim_cons_hsm(0, 'limitd_th_rem', zvi_b, zsmv_b, zei_b, zfw_b, zfs_b, zft_b)
333
334      IF( jpl > 1 )      CALL lim_itd_th_rem( 1, jpl, kt )
335
336      IF( ln_limdiachk ) CALL lim_cons_hsm(1, 'limitd_th_rem', zvi_b, zsmv_b, zei_b, zfw_b, zfs_b, zft_b)
337
338      !------------------------------------------------!
339      !  Add frazil ice growing in leads
340      !------------------------------------------------!
341      IF( ln_limdiachk ) CALL lim_cons_hsm(0, 'limthd_lac', zvi_b, zsmv_b, zei_b, zfw_b, zfs_b, zft_b)
342
343      IF( ln_limdO )     CALL lim_thd_lac
344     
345      ! conservation test
346      IF( ln_limdiachk ) CALL lim_cons_hsm(1, 'limthd_lac', zvi_b, zsmv_b, zei_b, zfw_b, zfs_b, zft_b)
347
348      ! Control print
349      IF( ln_ctl )       CALL lim_prt3D( 'limthd' )
350      !
351      CALL wrk_dealloc( jpi,jpj, zu_io, zv_io, zfric )
352      !
353      IF( nn_timing == 1 )  CALL timing_stop('limthd')
354
355   END SUBROUTINE lim_thd 
356
357 
358   SUBROUTINE lim_thd_temp( kideb, kiut )
359      !!-----------------------------------------------------------------------
360      !!                   ***  ROUTINE lim_thd_temp ***
361      !!                 
362      !! ** Purpose :   Computes sea ice temperature (Kelvin) from enthalpy
363      !!
364      !! ** Method  :   Formula (Bitz and Lipscomb, 1999)
365      !!-------------------------------------------------------------------
366      INTEGER, INTENT(in) ::   kideb, kiut   ! bounds for the spatial loop
367      !
368      INTEGER  ::   ji, jk   ! dummy loop indices
369      REAL(wp) ::   ztmelts, zaaa, zbbb, zccc, zdiscrim  ! local scalar
370      !!-------------------------------------------------------------------
371      ! Recover ice temperature
372      DO jk = 1, nlay_i
373         DO ji = kideb, kiut
374            ztmelts       =  -tmut * s_i_1d(ji,jk) + rt0
375            ! Conversion q(S,T) -> T (second order equation)
376            zaaa          =  cpic
377            zbbb          =  ( rcp - cpic ) * ( ztmelts - rt0 ) + q_i_1d(ji,jk) * r1_rhoic - lfus
378            zccc          =  lfus * ( ztmelts - rt0 )
379            zdiscrim      =  SQRT( MAX( zbbb * zbbb - 4._wp * zaaa * zccc, 0._wp ) )
380            t_i_1d(ji,jk) =  rt0 - ( zbbb + zdiscrim ) / ( 2._wp * zaaa )
381           
382            ! mask temperature
383            rswitch       =  1._wp - MAX( 0._wp , SIGN( 1._wp , - ht_i_1d(ji) ) ) 
384            t_i_1d(ji,jk) =  rswitch * t_i_1d(ji,jk) + ( 1._wp - rswitch ) * rt0
385         END DO
386      END DO 
387      !
388   END SUBROUTINE lim_thd_temp
389
390
391   SUBROUTINE lim_thd_lam( kideb, kiut )
392      !!-----------------------------------------------------------------------
393      !!                   ***  ROUTINE lim_thd_lam ***
394      !!                 
395      !! ** Purpose :   Lateral melting in case monocategory
396      !!                          ( dA = A/2h dh )
397      !!-----------------------------------------------------------------------
398      INTEGER, INTENT(in) ::   kideb, kiut        ! bounds for the spatial loop
399      !
400      INTEGER  ::   ji                 ! dummy loop indices
401      REAL(wp) ::   zhi_bef            ! ice thickness before thermo
402      REAL(wp) ::   zdh_mel, zda_mel   ! net melting
403      REAL(wp) ::   zvi, zvs           ! ice/snow volumes
404      !!-----------------------------------------------------------------------
405      !
406      DO ji = kideb, kiut
407         zdh_mel = MIN( 0._wp, dh_i_surf(ji) + dh_i_bott(ji) + dh_snowice(ji) + dh_i_sub(ji) )
408         IF( zdh_mel < 0._wp .AND. a_i_1d(ji) > 0._wp )  THEN
409            zvi          = a_i_1d(ji) * ht_i_1d(ji)
410            zvs          = a_i_1d(ji) * ht_s_1d(ji)
411            ! lateral melting = concentration change
412            zhi_bef     = ht_i_1d(ji) - zdh_mel
413            rswitch     = MAX( 0._wp , SIGN( 1._wp , zhi_bef - epsi20 ) )
414            zda_mel     = rswitch * a_i_1d(ji) * zdh_mel / ( 2._wp * MAX( zhi_bef, epsi20 ) )
415            a_i_1d(ji)  = MAX( epsi20, a_i_1d(ji) + zda_mel ) 
416            ! adjust thickness
417            ht_i_1d(ji) = zvi / a_i_1d(ji)           
418            ht_s_1d(ji) = zvs / a_i_1d(ji)           
419            ! retrieve total concentration
420            at_i_1d(ji) = a_i_1d(ji)
421         END IF
422      END DO
423      !
424   END SUBROUTINE lim_thd_lam
425
426
427   SUBROUTINE lim_thd_1d2d( nbpb, jl, kn )
428      !!-----------------------------------------------------------------------
429      !!                   ***  ROUTINE lim_thd_1d2d ***
430      !!                 
431      !! ** Purpose :   move arrays from 1d to 2d and the reverse
432      !!-----------------------------------------------------------------------
433      INTEGER, INTENT(in) ::   kn       ! 1= from 2D to 1D   ;   2= from 1D to 2D
434      INTEGER, INTENT(in) ::   nbpb     ! size of 1D arrays
435      INTEGER, INTENT(in) ::   jl       ! ice cat
436      !
437      INTEGER             ::   jk       ! dummy loop indices
438      !!-----------------------------------------------------------------------
439      !
440      SELECT CASE( kn )
441      !
442      CASE( 1 )            ! from 2D to 1D
443         !
444         CALL tab_2d_1d( nbpb, at_i_1d     (1:nbpb), at_i            , jpi, jpj, npb(1:nbpb) )
445         CALL tab_2d_1d( nbpb, a_i_1d      (1:nbpb), a_i(:,:,jl)     , jpi, jpj, npb(1:nbpb) )
446         CALL tab_2d_1d( nbpb, ht_i_1d     (1:nbpb), ht_i(:,:,jl)    , jpi, jpj, npb(1:nbpb) )
447         CALL tab_2d_1d( nbpb, ht_s_1d     (1:nbpb), ht_s(:,:,jl)    , jpi, jpj, npb(1:nbpb) )
448         !
449         CALL tab_2d_1d( nbpb, t_su_1d     (1:nbpb), t_su(:,:,jl)    , jpi, jpj, npb(1:nbpb) )
450         CALL tab_2d_1d( nbpb, sm_i_1d     (1:nbpb), sm_i(:,:,jl)    , jpi, jpj, npb(1:nbpb) )
451         DO jk = 1, nlay_s
452            CALL tab_2d_1d( nbpb, t_s_1d(1:nbpb,jk), t_s(:,:,jk,jl)  , jpi, jpj, npb(1:nbpb) )
453            CALL tab_2d_1d( nbpb, q_s_1d(1:nbpb,jk), e_s(:,:,jk,jl)  , jpi, jpj, npb(1:nbpb) )
454         END DO
455         DO jk = 1, nlay_i
456            CALL tab_2d_1d( nbpb, t_i_1d(1:nbpb,jk), t_i(:,:,jk,jl)  , jpi, jpj, npb(1:nbpb) )
457            CALL tab_2d_1d( nbpb, q_i_1d(1:nbpb,jk), e_i(:,:,jk,jl)  , jpi, jpj, npb(1:nbpb) )
458            CALL tab_2d_1d( nbpb, s_i_1d(1:nbpb,jk), s_i(:,:,jk,jl)  , jpi, jpj, npb(1:nbpb) )
459         END DO
460         !
461         CALL tab_2d_1d( nbpb, qprec_ice_1d(1:nbpb), qprec_ice(:,:) , jpi, jpj, npb(1:nbpb) )
462         CALL tab_2d_1d( nbpb, qevap_ice_1d(1:nbpb), qevap_ice(:,:,jl) , jpi, jpj, npb(1:nbpb) )
463         CALL tab_2d_1d( nbpb, qsr_ice_1d (1:nbpb), qsr_ice(:,:,jl) , jpi, jpj, npb(1:nbpb) )
464         CALL tab_2d_1d( nbpb, fr1_i0_1d  (1:nbpb), fr1_i0          , jpi, jpj, npb(1:nbpb) )
465         CALL tab_2d_1d( nbpb, fr2_i0_1d  (1:nbpb), fr2_i0          , jpi, jpj, npb(1:nbpb) )
466         CALL tab_2d_1d( nbpb, qns_ice_1d (1:nbpb), qns_ice(:,:,jl) , jpi, jpj, npb(1:nbpb) )
467         CALL tab_2d_1d( nbpb, ftr_ice_1d (1:nbpb), ftr_ice(:,:,jl) , jpi, jpj, npb(1:nbpb) )
468         CALL tab_2d_1d( nbpb, evap_ice_1d (1:nbpb), evap_ice(:,:,jl), jpi, jpj, npb(1:nbpb) )
469         CALL tab_2d_1d( nbpb, dqns_ice_1d(1:nbpb), dqns_ice(:,:,jl), jpi, jpj, npb(1:nbpb) )
470         CALL tab_2d_1d( nbpb, t_bo_1d     (1:nbpb), t_bo            , jpi, jpj, npb(1:nbpb) )
471         CALL tab_2d_1d( nbpb, sprecip_1d (1:nbpb), sprecip         , jpi, jpj, npb(1:nbpb) ) 
472         CALL tab_2d_1d( nbpb, fhtur_1d   (1:nbpb), fhtur           , jpi, jpj, npb(1:nbpb) )
473         CALL tab_2d_1d( nbpb, qlead_1d   (1:nbpb), qlead           , jpi, jpj, npb(1:nbpb) )
474         CALL tab_2d_1d( nbpb, fhld_1d    (1:nbpb), fhld            , jpi, jpj, npb(1:nbpb) )
475         !
476         CALL tab_2d_1d( nbpb, wfx_snw_1d (1:nbpb), wfx_snw         , jpi, jpj, npb(1:nbpb) )
477         CALL tab_2d_1d( nbpb, wfx_snw_sum_1d(1:nbpb), wfx_snw_sum  , jpi, jpj, npb(1:nbpb) )
478         CALL tab_2d_1d( nbpb, wfx_sub_1d (1:nbpb), wfx_sub         , jpi, jpj, npb(1:nbpb) )
479         CALL tab_2d_1d( nbpb, wfx_snw_sub_1d(1:nbpb), wfx_snw_sub  , jpi, jpj, npb(1:nbpb) )
480         CALL tab_2d_1d( nbpb, wfx_ice_sub_1d(1:nbpb), wfx_ice_sub  , jpi, jpj, npb(1:nbpb) )
481         !
482         CALL tab_2d_1d( nbpb, wfx_bog_1d (1:nbpb), wfx_bog         , jpi, jpj, npb(1:nbpb) )
483         CALL tab_2d_1d( nbpb, wfx_bom_1d (1:nbpb), wfx_bom         , jpi, jpj, npb(1:nbpb) )
484         CALL tab_2d_1d( nbpb, wfx_sum_1d (1:nbpb), wfx_sum         , jpi, jpj, npb(1:nbpb) )
485         CALL tab_2d_1d( nbpb, wfx_sni_1d (1:nbpb), wfx_sni         , jpi, jpj, npb(1:nbpb) )
486         CALL tab_2d_1d( nbpb, wfx_res_1d (1:nbpb), wfx_res         , jpi, jpj, npb(1:nbpb) )
487         CALL tab_2d_1d( nbpb, wfx_spr_1d (1:nbpb), wfx_spr         , jpi, jpj, npb(1:nbpb) )
488         !
489         CALL tab_2d_1d( nbpb, sfx_bog_1d (1:nbpb), sfx_bog         , jpi, jpj, npb(1:nbpb) )
490         CALL tab_2d_1d( nbpb, sfx_bom_1d (1:nbpb), sfx_bom         , jpi, jpj, npb(1:nbpb) )
491         CALL tab_2d_1d( nbpb, sfx_sum_1d (1:nbpb), sfx_sum         , jpi, jpj, npb(1:nbpb) )
492         CALL tab_2d_1d( nbpb, sfx_sni_1d (1:nbpb), sfx_sni         , jpi, jpj, npb(1:nbpb) )
493         CALL tab_2d_1d( nbpb, sfx_bri_1d (1:nbpb), sfx_bri         , jpi, jpj, npb(1:nbpb) )
494         CALL tab_2d_1d( nbpb, sfx_res_1d (1:nbpb), sfx_res         , jpi, jpj, npb(1:nbpb) )
495         CALL tab_2d_1d( nbpb, sfx_sub_1d (1:nbpb), sfx_sub         , jpi, jpj,npb(1:nbpb) )
496         !
497         CALL tab_2d_1d( nbpb, hfx_thd_1d (1:nbpb), hfx_thd         , jpi, jpj, npb(1:nbpb) )
498         CALL tab_2d_1d( nbpb, hfx_spr_1d (1:nbpb), hfx_spr         , jpi, jpj, npb(1:nbpb) )
499         CALL tab_2d_1d( nbpb, hfx_sum_1d (1:nbpb), hfx_sum         , jpi, jpj, npb(1:nbpb) )
500         CALL tab_2d_1d( nbpb, hfx_bom_1d (1:nbpb), hfx_bom         , jpi, jpj, npb(1:nbpb) )
501         CALL tab_2d_1d( nbpb, hfx_bog_1d (1:nbpb), hfx_bog         , jpi, jpj, npb(1:nbpb) )
502         CALL tab_2d_1d( nbpb, hfx_dif_1d (1:nbpb), hfx_dif         , jpi, jpj, npb(1:nbpb) )
503         CALL tab_2d_1d( nbpb, hfx_opw_1d (1:nbpb), hfx_opw         , jpi, jpj, npb(1:nbpb) )
504         CALL tab_2d_1d( nbpb, hfx_snw_1d (1:nbpb), hfx_snw         , jpi, jpj, npb(1:nbpb) )
505         CALL tab_2d_1d( nbpb, hfx_sub_1d (1:nbpb), hfx_sub         , jpi, jpj, npb(1:nbpb) )
506         CALL tab_2d_1d( nbpb, hfx_err_1d (1:nbpb), hfx_err         , jpi, jpj, npb(1:nbpb) )
507         CALL tab_2d_1d( nbpb, hfx_res_1d (1:nbpb), hfx_res         , jpi, jpj, npb(1:nbpb) )
508         CALL tab_2d_1d( nbpb, hfx_err_dif_1d (1:nbpb), hfx_err_dif , jpi, jpj, npb(1:nbpb) )
509         CALL tab_2d_1d( nbpb, hfx_err_rem_1d (1:nbpb), hfx_err_rem , jpi, jpj, npb(1:nbpb) )
510         !
511         ! SIMIP diagnostics
512         CALL tab_2d_1d( nbpb, diag_fc_bo_1d   (1:nbpb), diag_fc_bo  , jpi, jpj, npb(1:nbpb) )
513         CALL tab_2d_1d( nbpb, diag_fc_su_1d   (1:nbpb), diag_fc_su  , jpi, jpj, npb(1:nbpb) )
514         !
515      CASE( 2 )            ! from 1D to 2D
516         !
517         CALL tab_1d_2d( nbpb, at_i          , npb, at_i_1d    (1:nbpb)   , jpi, jpj )
518         CALL tab_1d_2d( nbpb, ht_i(:,:,jl)  , npb, ht_i_1d    (1:nbpb)   , jpi, jpj )
519         CALL tab_1d_2d( nbpb, ht_s(:,:,jl)  , npb, ht_s_1d    (1:nbpb)   , jpi, jpj )
520         CALL tab_1d_2d( nbpb, a_i (:,:,jl)  , npb, a_i_1d     (1:nbpb)   , jpi, jpj )
521         CALL tab_1d_2d( nbpb, t_su(:,:,jl)  , npb, t_su_1d    (1:nbpb)   , jpi, jpj )
522         CALL tab_1d_2d( nbpb, sm_i(:,:,jl)  , npb, sm_i_1d    (1:nbpb)   , jpi, jpj )
523         DO jk = 1, nlay_s
524            CALL tab_1d_2d( nbpb, t_s(:,:,jk,jl), npb, t_s_1d     (1:nbpb,jk), jpi, jpj)
525            CALL tab_1d_2d( nbpb, e_s(:,:,jk,jl), npb, q_s_1d     (1:nbpb,jk), jpi, jpj)
526         END DO
527         DO jk = 1, nlay_i
528            CALL tab_1d_2d( nbpb, t_i(:,:,jk,jl), npb, t_i_1d     (1:nbpb,jk), jpi, jpj)
529            CALL tab_1d_2d( nbpb, e_i(:,:,jk,jl), npb, q_i_1d     (1:nbpb,jk), jpi, jpj)
530            CALL tab_1d_2d( nbpb, s_i(:,:,jk,jl), npb, s_i_1d     (1:nbpb,jk), jpi, jpj)
531         END DO
532         CALL tab_1d_2d( nbpb, qlead         , npb, qlead_1d  (1:nbpb)   , jpi, jpj )
533         !
534         CALL tab_1d_2d( nbpb, wfx_snw       , npb, wfx_snw_1d(1:nbpb)   , jpi, jpj )
535         CALL tab_1d_2d( nbpb, wfx_snw_sum   , npb, wfx_snw_sum_1d(1:nbpb),jpi, jpj )
536         CALL tab_1d_2d( nbpb, wfx_sub       , npb, wfx_sub_1d(1:nbpb)   , jpi, jpj )
537         CALL tab_1d_2d( nbpb, wfx_snw_sub   , npb, wfx_snw_sub_1d(1:nbpb), jpi, jpj )
538         CALL tab_1d_2d( nbpb, wfx_ice_sub   , npb, wfx_ice_sub_1d(1:nbpb), jpi, jpj )
539         !
540         CALL tab_1d_2d( nbpb, wfx_bog       , npb, wfx_bog_1d(1:nbpb)   , jpi, jpj )
541         CALL tab_1d_2d( nbpb, wfx_bom       , npb, wfx_bom_1d(1:nbpb)   , jpi, jpj )
542         CALL tab_1d_2d( nbpb, wfx_sum       , npb, wfx_sum_1d(1:nbpb)   , jpi, jpj )
543         CALL tab_1d_2d( nbpb, wfx_sni       , npb, wfx_sni_1d(1:nbpb)   , jpi, jpj )
544         CALL tab_1d_2d( nbpb, wfx_res       , npb, wfx_res_1d(1:nbpb)   , jpi, jpj )
545         CALL tab_1d_2d( nbpb, wfx_spr       , npb, wfx_spr_1d(1:nbpb)   , jpi, jpj )
546         !
547         CALL tab_1d_2d( nbpb, sfx_bog       , npb, sfx_bog_1d(1:nbpb)   , jpi, jpj )
548         CALL tab_1d_2d( nbpb, sfx_bom       , npb, sfx_bom_1d(1:nbpb)   , jpi, jpj )
549         CALL tab_1d_2d( nbpb, sfx_sum       , npb, sfx_sum_1d(1:nbpb)   , jpi, jpj )
550         CALL tab_1d_2d( nbpb, sfx_sni       , npb, sfx_sni_1d(1:nbpb)   , jpi, jpj )
551         CALL tab_1d_2d( nbpb, sfx_res       , npb, sfx_res_1d(1:nbpb)   , jpi, jpj )
552         CALL tab_1d_2d( nbpb, sfx_bri       , npb, sfx_bri_1d(1:nbpb)   , jpi, jpj )
553         CALL tab_1d_2d( nbpb, sfx_sub       , npb, sfx_sub_1d(1:nbpb)   , jpi, jpj )       
554         !
555         CALL tab_1d_2d( nbpb, hfx_thd       , npb, hfx_thd_1d(1:nbpb)   , jpi, jpj )
556         CALL tab_1d_2d( nbpb, hfx_spr       , npb, hfx_spr_1d(1:nbpb)   , jpi, jpj )
557         CALL tab_1d_2d( nbpb, hfx_sum       , npb, hfx_sum_1d(1:nbpb)   , jpi, jpj )
558         CALL tab_1d_2d( nbpb, hfx_bom       , npb, hfx_bom_1d(1:nbpb)   , jpi, jpj )
559         CALL tab_1d_2d( nbpb, hfx_bog       , npb, hfx_bog_1d(1:nbpb)   , jpi, jpj )
560         CALL tab_1d_2d( nbpb, hfx_dif       , npb, hfx_dif_1d(1:nbpb)   , jpi, jpj )
561         CALL tab_1d_2d( nbpb, hfx_opw       , npb, hfx_opw_1d(1:nbpb)   , jpi, jpj )
562         CALL tab_1d_2d( nbpb, hfx_snw       , npb, hfx_snw_1d(1:nbpb)   , jpi, jpj )
563         CALL tab_1d_2d( nbpb, hfx_sub       , npb, hfx_sub_1d(1:nbpb)   , jpi, jpj )
564         CALL tab_1d_2d( nbpb, hfx_err       , npb, hfx_err_1d(1:nbpb)   , jpi, jpj )
565         CALL tab_1d_2d( nbpb, hfx_res       , npb, hfx_res_1d(1:nbpb)   , jpi, jpj )
566         CALL tab_1d_2d( nbpb, hfx_err_rem   , npb, hfx_err_rem_1d(1:nbpb), jpi, jpj )
567         CALL tab_1d_2d( nbpb, hfx_err_dif   , npb, hfx_err_dif_1d(1:nbpb), jpi, jpj )
568         !
569         CALL tab_1d_2d( nbpb, qns_ice(:,:,jl), npb, qns_ice_1d(1:nbpb) , jpi, jpj)
570         CALL tab_1d_2d( nbpb, ftr_ice(:,:,jl), npb, ftr_ice_1d(1:nbpb) , jpi, jpj )
571         !
572         ! SIMIP diagnostics         
573         CALL tab_1d_2d( nbpb, t_si(:,:,jl)   , npb, t_si_1d    (1:nbpb)     , jpi, jpj )
574         CALL tab_1d_2d( nbpb, diag_fc_bo     , npb, diag_fc_bo_1d(1:nbpb)   , jpi, jpj )
575         CALL tab_1d_2d( nbpb, diag_fc_su     , npb, diag_fc_su_1d(1:nbpb)   , jpi, jpj )
576      END SELECT
577      !
578   END SUBROUTINE lim_thd_1d2d
579
580
581   SUBROUTINE lim_thd_init
582      !!-----------------------------------------------------------------------
583      !!                   ***  ROUTINE lim_thd_init ***
584      !!                 
585      !! ** Purpose :   Physical constants and parameters linked to the ice
586      !!              thermodynamics
587      !!
588      !! ** Method  :   Read the namicethd namelist and check the ice-thermo
589      !!              parameter values called at the first timestep (nit000)
590      !!
591      !! ** input   :   Namelist namicether
592      !!-------------------------------------------------------------------
593      INTEGER  ::   ios                 ! Local integer output status for namelist read
594      NAMELIST/namicethd/ rn_kappa_i, nn_ice_thcon, ln_dqnsice, rn_cdsn,                                  &
595         &                ln_limdH, rn_betas,                                                             &
596         &                ln_limdA, rn_beta, rn_dmin,                                                     &
597         &                ln_limdO, rn_hnewice, ln_frazil, rn_maxfrazb, rn_vfrazb, rn_Cfrazb, rn_himin,   &
598         &                nn_limflx
599      !!-------------------------------------------------------------------
600      !
601      REWIND( numnam_ice_ref )              ! Namelist namicethd in reference namelist : Ice thermodynamics
602      READ  ( numnam_ice_ref, namicethd, IOSTAT = ios, ERR = 901)
603901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namicethd in reference namelist', lwp )
604
605      REWIND( numnam_ice_cfg )              ! Namelist namicethd in configuration namelist : Ice thermodynamics
606      READ  ( numnam_ice_cfg, namicethd, IOSTAT = ios, ERR = 902 )
607902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namicethd in configuration namelist', lwp )
608      IF(lwm) WRITE ( numoni, namicethd )
609      !
610      !
611      IF(lwp) THEN                          ! control print
612         WRITE(numout,*) 'lim_thd_init : Ice Thermodynamics'
613         WRITE(numout,*) '~~~~~~~~~~~~~'
614         WRITE(numout,*)'   -- limthd_dif --'
615         WRITE(numout,*)'      extinction radiation parameter in sea ice               rn_kappa_i   = ', rn_kappa_i
616         WRITE(numout,*)'      switch for comp. of thermal conductivity in the ice     nn_ice_thcon = ', nn_ice_thcon
617         WRITE(numout,*)'      change the surface non-solar flux with Tsu or not       ln_dqnsice   = ', ln_dqnsice
618         WRITE(numout,*)'      thermal conductivity of the snow                        rn_cdsn      = ', rn_cdsn
619         WRITE(numout,*)'   -- limthd_dh --'
620         WRITE(numout,*)'      activate ice thick change from top/bot (T) or not (F)   ln_limdH     = ', ln_limdH
621         WRITE(numout,*)'      coefficient for ice-lead partition of snowfall          rn_betas     = ', rn_betas
622         WRITE(numout,*)'   -- limthd_da --'
623         WRITE(numout,*)'      activate lateral melting (T) or not (F)                 ln_limdA     = ', ln_limdA
624         WRITE(numout,*)'      Coef. beta for lateral melting param.                   rn_beta      = ', rn_beta
625         WRITE(numout,*)'      Minimum floe diameter for lateral melting param.        rn_dmin      = ', rn_dmin
626         WRITE(numout,*)'   -- limthd_lac --'
627         WRITE(numout,*)'      activate ice growth in open-water (T) or not (F)        ln_limdO     = ', ln_limdO
628         WRITE(numout,*)'      ice thick. for lateral accretion                        rn_hnewice   = ', rn_hnewice
629         WRITE(numout,*)'      Frazil ice thickness as a function of wind or not       ln_frazil    = ', ln_frazil
630         WRITE(numout,*)'      Maximum proportion of frazil ice collecting at bottom   rn_maxfrazb  = ', rn_maxfrazb
631         WRITE(numout,*)'      Thresold relative drift speed for collection of frazil  rn_vfrazb    = ', rn_vfrazb
632         WRITE(numout,*)'      Squeezing coefficient for collection of frazil          rn_Cfrazb    = ', rn_Cfrazb
633         WRITE(numout,*)'   -- limitd_th --'
634         WRITE(numout,*)'      minimum ice thickness                                   rn_himin     = ', rn_himin 
635         WRITE(numout,*)'      check heat conservation in the ice/snow                 con_i        = ', con_i
636         WRITE(numout,*)'   -- icestp --'
637         WRITE(numout,*)'      Multicategory heat flux formulation                     nn_limflx    = ', nn_limflx
638      ENDIF
639      !
640      IF ( rn_hnewice < rn_himin )   CALL ctl_stop( 'STOP', 'lim_thd_init : rn_hnewice should be >= rn_himin' )
641      !
642      IF(lwp) WRITE(numout,*)
643      SELECT CASE( nn_limflx )         ! LIM3 Multi-category heat flux formulation
644      CASE ( -1 )
645         IF(lwp) WRITE(numout,*) '   LIM3: use per-category fluxes (nn_limflx = -1) '
646         IF( ln_cpl )   CALL ctl_stop( 'sbc_init : the chosen nn_limflx for LIM3 in coupled mode must be 0 or 2' )
647      CASE ( 0  )
648         IF(lwp) WRITE(numout,*) '   LIM3: use average per-category fluxes (nn_limflx = 0) '
649      CASE ( 1  )
650         IF(lwp) WRITE(numout,*) '   LIM3: use average then redistribute per-category fluxes (nn_limflx = 1) '
651         IF( ln_cpl )   CALL ctl_stop( 'sbc_init : the chosen nn_limflx for LIM3 in coupled mode must be 0 or 2' )
652      CASE ( 2  )
653         IF(lwp) WRITE(numout,*) '   LIM3: Redistribute a single flux over categories (nn_limflx = 2) '
654         IF( .NOT. ln_cpl )   CALL ctl_stop( 'sbc_init : the chosen nn_limflx for LIM3 in forced mode cannot be 2' )
655      CASE DEFAULT
656         CALL ctl_stop( 'sbcmod: LIM3 option, nn_limflx, should be between -1 and 2' )
657      END SELECT
658      !
659   END SUBROUTINE lim_thd_init
660
661#else
662   !!----------------------------------------------------------------------
663   !!   Default option         Dummy module          NO  LIM3 sea-ice model
664   !!----------------------------------------------------------------------
665#endif
666
667   !!======================================================================
668END MODULE limthd
Note: See TracBrowser for help on using the repository browser.