[825] | 1 | MODULE limthd_dh |
---|
[1572] | 2 | !!====================================================================== |
---|
| 3 | !! *** MODULE limthd_dh *** |
---|
| 4 | !! LIM-3 : thermodynamic growth and decay of the ice |
---|
| 5 | !!====================================================================== |
---|
| 6 | !! History : LIM ! 2003-05 (M. Vancoppenolle) Original code in 1D |
---|
| 7 | !! ! 2005-06 (M. Vancoppenolle) 3D version |
---|
[4688] | 8 | !! 3.2 ! 2009-07 (M. Vancoppenolle, Y. Aksenov, G. Madec) bug correction in wfx_snw & wfx_ice |
---|
[3625] | 9 | !! 3.4 ! 2011-02 (G. Madec) dynamical allocation |
---|
| 10 | !! 3.5 ! 2012-10 (G. Madec & co) salt flux + bug fixes |
---|
[1572] | 11 | !!---------------------------------------------------------------------- |
---|
[825] | 12 | #if defined key_lim3 |
---|
[834] | 13 | !!---------------------------------------------------------------------- |
---|
| 14 | !! 'key_lim3' LIM3 sea-ice model |
---|
| 15 | !!---------------------------------------------------------------------- |
---|
[3625] | 16 | !! lim_thd_dh : vertical accr./abl. and lateral ablation of sea ice |
---|
[825] | 17 | !!---------------------------------------------------------------------- |
---|
[3625] | 18 | USE par_oce ! ocean parameters |
---|
| 19 | USE phycst ! physical constants (OCE directory) |
---|
| 20 | USE ice ! LIM variables |
---|
| 21 | USE thd_ice ! LIM thermodynamics |
---|
| 22 | USE in_out_manager ! I/O manager |
---|
| 23 | USE lib_mpp ! MPP library |
---|
| 24 | USE wrk_nemo ! work arrays |
---|
| 25 | USE lib_fortran ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) |
---|
[4688] | 26 | |
---|
[825] | 27 | IMPLICIT NONE |
---|
| 28 | PRIVATE |
---|
| 29 | |
---|
[5407] | 30 | PUBLIC lim_thd_dh ! called by lim_thd |
---|
[5487] | 31 | PUBLIC lim_thd_snwblow ! called in sbcblk/sbcclio/sbccpl and here |
---|
[825] | 32 | |
---|
[5407] | 33 | INTERFACE lim_thd_snwblow |
---|
| 34 | MODULE PROCEDURE lim_thd_snwblow_1d, lim_thd_snwblow_2d |
---|
| 35 | END INTERFACE |
---|
| 36 | |
---|
[825] | 37 | !!---------------------------------------------------------------------- |
---|
[4161] | 38 | !! NEMO/LIM3 4.0 , UCL - NEMO Consortium (2010) |
---|
[1156] | 39 | !! $Id$ |
---|
[2715] | 40 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
---|
[825] | 41 | !!---------------------------------------------------------------------- |
---|
| 42 | CONTAINS |
---|
| 43 | |
---|
[4688] | 44 | SUBROUTINE lim_thd_dh( kideb, kiut ) |
---|
[921] | 45 | !!------------------------------------------------------------------ |
---|
| 46 | !! *** ROUTINE lim_thd_dh *** |
---|
| 47 | !! |
---|
[1572] | 48 | !! ** Purpose : determines variations of ice and snow thicknesses. |
---|
[921] | 49 | !! |
---|
[1572] | 50 | !! ** Method : Ice/Snow surface melting arises from imbalance in surface fluxes |
---|
| 51 | !! Bottom accretion/ablation arises from flux budget |
---|
| 52 | !! Snow thickness can increase by precipitation and decrease by sublimation |
---|
| 53 | !! If snow load excesses Archmiede limit, snow-ice is formed by |
---|
| 54 | !! the flooding of sea-water in the snow |
---|
[921] | 55 | !! |
---|
[1572] | 56 | !! 1) Compute available flux of heat for surface ablation |
---|
| 57 | !! 2) Compute snow and sea ice enthalpies |
---|
| 58 | !! 3) Surface ablation and sublimation |
---|
| 59 | !! 4) Bottom accretion/ablation |
---|
| 60 | !! 5) Case of Total ablation |
---|
| 61 | !! 6) Snow ice formation |
---|
[921] | 62 | !! |
---|
[1572] | 63 | !! References : Bitz and Lipscomb, 1999, J. Geophys. Res. |
---|
| 64 | !! Fichefet T. and M. Maqueda 1997, J. Geophys. Res., 102(C6), 12609-12646 |
---|
| 65 | !! Vancoppenolle, Fichefet and Bitz, 2005, Geophys. Res. Let. |
---|
| 66 | !! Vancoppenolle et al.,2009, Ocean Modelling |
---|
[921] | 67 | !!------------------------------------------------------------------ |
---|
[1572] | 68 | INTEGER , INTENT(in) :: kideb, kiut ! Start/End point on which the the computation is applied |
---|
| 69 | !! |
---|
| 70 | INTEGER :: ji , jk ! dummy loop indices |
---|
| 71 | INTEGER :: iter |
---|
[825] | 72 | |
---|
[4688] | 73 | REAL(wp) :: ztmelts ! local scalar |
---|
[6416] | 74 | REAL(wp) :: zdum |
---|
[1572] | 75 | REAL(wp) :: zfracs ! fractionation coefficient for bottom salt entrapment |
---|
| 76 | REAL(wp) :: zswi1 ! switch for computation of bottom salinity |
---|
| 77 | REAL(wp) :: zswi12 ! switch for computation of bottom salinity |
---|
| 78 | REAL(wp) :: zswi2 ! switch for computation of bottom salinity |
---|
| 79 | REAL(wp) :: zgrr ! bottom growth rate |
---|
[4688] | 80 | REAL(wp) :: zt_i_new ! bottom formation temperature |
---|
| 81 | |
---|
| 82 | REAL(wp) :: zQm ! enthalpy exchanged with the ocean (J/m2), >0 towards the ocean |
---|
| 83 | REAL(wp) :: zEi ! specific enthalpy of sea ice (J/kg) |
---|
| 84 | REAL(wp) :: zEw ! specific enthalpy of exchanged water (J/kg) |
---|
| 85 | REAL(wp) :: zdE ! specific enthalpy difference (J/kg) |
---|
| 86 | REAL(wp) :: zfmdt ! exchange mass flux x time step (J/m2), >0 towards the ocean |
---|
| 87 | |
---|
| 88 | REAL(wp), POINTER, DIMENSION(:) :: zqprec ! energy of fallen snow (J.m-3) |
---|
| 89 | REAL(wp), POINTER, DIMENSION(:) :: zq_su ! heat for surface ablation (J.m-2) |
---|
| 90 | REAL(wp), POINTER, DIMENSION(:) :: zq_bo ! heat for bottom ablation (J.m-2) |
---|
| 91 | REAL(wp), POINTER, DIMENSION(:) :: zq_rema ! remaining heat at the end of the routine (J.m-2) |
---|
[5123] | 92 | REAL(wp), POINTER, DIMENSION(:) :: zf_tt ! Heat budget to determine melting or freezing(W.m-2) |
---|
[6416] | 93 | REAL(wp), POINTER, DIMENSION(:) :: zevap_rema ! remaining mass flux from sublimation (kg.m-2) |
---|
[3294] | 94 | |
---|
[3625] | 95 | REAL(wp), POINTER, DIMENSION(:) :: zdh_s_mel ! snow melt |
---|
| 96 | REAL(wp), POINTER, DIMENSION(:) :: zdh_s_pre ! snow precipitation |
---|
| 97 | REAL(wp), POINTER, DIMENSION(:) :: zdh_s_sub ! snow sublimation |
---|
[3294] | 98 | |
---|
| 99 | REAL(wp), POINTER, DIMENSION(:,:) :: zdeltah |
---|
[4688] | 100 | REAL(wp), POINTER, DIMENSION(:,:) :: zh_i ! ice layer thickness |
---|
[5202] | 101 | INTEGER , POINTER, DIMENSION(:,:) :: icount ! number of layers vanished by melting |
---|
[3294] | 102 | |
---|
[8325] | 103 | REAL(wp), POINTER, DIMENSION(:) :: zeh_i ! total ice heat content (J.m-2) |
---|
[5407] | 104 | REAL(wp), POINTER, DIMENSION(:) :: zsnw ! distribution of snow after wind blowing |
---|
[3294] | 105 | |
---|
[5123] | 106 | REAL(wp) :: zswitch_sal |
---|
[4161] | 107 | |
---|
[3294] | 108 | ! Heat conservation |
---|
[4688] | 109 | INTEGER :: num_iter_max |
---|
| 110 | |
---|
[1572] | 111 | !!------------------------------------------------------------------ |
---|
[825] | 112 | |
---|
[5123] | 113 | ! Discriminate between varying salinity (nn_icesal=2) and prescribed cases (other values) |
---|
[7646] | 114 | SELECT CASE( nn_icesal ) ! varying salinity or not |
---|
[6470] | 115 | CASE( 1, 3 ) ; zswitch_sal = 0 ! prescribed salinity profile |
---|
| 116 | CASE( 2 ) ; zswitch_sal = 1 ! varying salinity profile |
---|
[4688] | 117 | END SELECT |
---|
[825] | 118 | |
---|
[6416] | 119 | CALL wrk_alloc( jpij, zqprec, zq_su, zq_bo, zf_tt, zq_rema, zsnw, zevap_rema ) |
---|
[8325] | 120 | CALL wrk_alloc( jpij, zdh_s_mel, zdh_s_pre, zdh_s_sub, zeh_i ) |
---|
[5202] | 121 | CALL wrk_alloc( jpij, nlay_i, zdeltah, zh_i ) |
---|
| 122 | CALL wrk_alloc( jpij, nlay_i, icount ) |
---|
[5487] | 123 | |
---|
| 124 | zqprec (:) = 0._wp ; zq_su (:) = 0._wp ; zq_bo (:) = 0._wp ; zf_tt(:) = 0._wp |
---|
[6416] | 125 | zq_rema (:) = 0._wp ; zsnw (:) = 0._wp ; zevap_rema(:) = 0._wp ; |
---|
[8325] | 126 | zdh_s_mel(:) = 0._wp ; zdh_s_pre(:) = 0._wp ; zdh_s_sub(:) = 0._wp ; zeh_i(:) = 0._wp |
---|
[4161] | 127 | |
---|
[5487] | 128 | zdeltah(:,:) = 0._wp ; zh_i(:,:) = 0._wp |
---|
| 129 | icount (:,:) = 0 |
---|
[4688] | 130 | |
---|
[5167] | 131 | ! Initialize enthalpy at nlay_i+1 |
---|
| 132 | DO ji = kideb, kiut |
---|
[8325] | 133 | e_i_1d(ji,nlay_i+1) = 0._wp |
---|
[5167] | 134 | END DO |
---|
| 135 | |
---|
[4688] | 136 | ! initialize layer thicknesses and enthalpies |
---|
| 137 | h_i_old (:,0:nlay_i+1) = 0._wp |
---|
[8325] | 138 | eh_i_old(:,0:nlay_i+1) = 0._wp |
---|
[4688] | 139 | DO jk = 1, nlay_i |
---|
| 140 | DO ji = kideb, kiut |
---|
[5123] | 141 | h_i_old (ji,jk) = ht_i_1d(ji) * r1_nlay_i |
---|
[8325] | 142 | eh_i_old(ji,jk) = e_i_1d(ji,jk) * h_i_old(ji,jk) |
---|
[4688] | 143 | ENDDO |
---|
| 144 | ENDDO |
---|
[921] | 145 | ! |
---|
| 146 | !------------------------------------------------------------------------------! |
---|
[4688] | 147 | ! 1) Calculate available heat for surface and bottom ablation ! |
---|
[921] | 148 | !------------------------------------------------------------------------------! |
---|
| 149 | ! |
---|
[2715] | 150 | DO ji = kideb, kiut |
---|
[6416] | 151 | zdum = qns_ice_1d(ji) + ( 1._wp - i0(ji) ) * qsr_ice_1d(ji) - fc_su(ji) |
---|
[4990] | 152 | zf_tt(ji) = fc_bo_i(ji) + fhtur_1d(ji) + fhld_1d(ji) |
---|
[4688] | 153 | |
---|
[6416] | 154 | zq_su (ji) = MAX( 0._wp, zdum * rdt_ice ) * MAX( 0._wp , SIGN( 1._wp, t_su_1d(ji) - rt0 ) ) |
---|
[4688] | 155 | zq_bo (ji) = MAX( 0._wp, zf_tt(ji) * rdt_ice ) |
---|
| 156 | END DO |
---|
| 157 | |
---|
[921] | 158 | ! |
---|
| 159 | !------------------------------------------------------------------------------! |
---|
[4688] | 160 | ! If snow temperature is above freezing point, then snow melts |
---|
| 161 | ! (should not happen but sometimes it does) |
---|
[921] | 162 | !------------------------------------------------------------------------------! |
---|
[4688] | 163 | DO ji = kideb, kiut |
---|
[5123] | 164 | IF( t_s_1d(ji,1) > rt0 ) THEN !!! Internal melting |
---|
[4688] | 165 | ! Contribution to heat flux to the ocean [W.m-2], < 0 |
---|
[8325] | 166 | hfx_res_1d(ji) = hfx_res_1d(ji) + e_s_1d(ji,1) * ht_s_1d(ji) * a_i_1d(ji) * r1_rdtice |
---|
[4688] | 167 | ! Contribution to mass flux |
---|
[8233] | 168 | wfx_snw_sum_1d(ji) = wfx_snw_sum_1d(ji) + rhosn * ht_s_1d(ji) * a_i_1d(ji) * r1_rdtice |
---|
[4688] | 169 | ! updates |
---|
[4872] | 170 | ht_s_1d(ji) = 0._wp |
---|
[8325] | 171 | e_s_1d (ji,1) = 0._wp |
---|
[5123] | 172 | t_s_1d (ji,1) = rt0 |
---|
[4688] | 173 | END IF |
---|
| 174 | END DO |
---|
| 175 | |
---|
| 176 | !------------------------------------------------------------! |
---|
| 177 | ! 2) Computing layer thicknesses and enthalpies. ! |
---|
| 178 | !------------------------------------------------------------! |
---|
[921] | 179 | ! |
---|
[825] | 180 | DO jk = 1, nlay_i |
---|
[2715] | 181 | DO ji = kideb, kiut |
---|
[5123] | 182 | zh_i(ji,jk) = ht_i_1d(ji) * r1_nlay_i |
---|
[8325] | 183 | zeh_i(ji) = zeh_i(ji) + e_i_1d(ji,jk) * zh_i(ji,jk) |
---|
[825] | 184 | END DO |
---|
| 185 | END DO |
---|
[921] | 186 | ! |
---|
| 187 | !------------------------------------------------------------------------------| |
---|
| 188 | ! 3) Surface ablation and sublimation | |
---|
| 189 | !------------------------------------------------------------------------------| |
---|
| 190 | ! |
---|
[834] | 191 | !------------------------- |
---|
| 192 | ! 3.1 Snow precips / melt |
---|
| 193 | !------------------------- |
---|
[825] | 194 | ! Snow accumulation in one thermodynamic time step |
---|
| 195 | ! snowfall is partitionned between leads and ice |
---|
| 196 | ! if snow fall was uniform, a fraction (1-at_i) would fall into leads |
---|
| 197 | ! but because of the winds, more snow falls on leads than on sea ice |
---|
| 198 | ! and a greater fraction (1-at_i)^beta of the total mass of snow |
---|
[834] | 199 | ! (beta < 1) falls in leads. |
---|
[825] | 200 | ! In reality, beta depends on wind speed, |
---|
| 201 | ! and should decrease with increasing wind speed but here, it is |
---|
[834] | 202 | ! considered as a constant. an average value is 0.66 |
---|
[825] | 203 | ! Martin Vancoppenolle, December 2006 |
---|
| 204 | |
---|
[5487] | 205 | CALL lim_thd_snwblow( 1. - at_i_1d(kideb:kiut), zsnw(kideb:kiut) ) ! snow distribution over ice after wind blowing |
---|
| 206 | |
---|
[5167] | 207 | zdeltah(:,:) = 0._wp |
---|
[825] | 208 | DO ji = kideb, kiut |
---|
[4688] | 209 | !----------- |
---|
| 210 | ! Snow fall |
---|
| 211 | !----------- |
---|
| 212 | ! thickness change |
---|
[5407] | 213 | zdh_s_pre(ji) = zsnw(ji) * sprecip_1d(ji) * rdt_ice * r1_rhosn / at_i_1d(ji) |
---|
| 214 | ! enthalpy of the precip (>0, J.m-3) |
---|
| 215 | zqprec (ji) = - qprec_ice_1d(ji) |
---|
[4688] | 216 | IF( sprecip_1d(ji) == 0._wp ) zqprec(ji) = 0._wp |
---|
| 217 | ! heat flux from snow precip (>0, W.m-2) |
---|
[4872] | 218 | hfx_spr_1d(ji) = hfx_spr_1d(ji) + zdh_s_pre(ji) * a_i_1d(ji) * zqprec(ji) * r1_rdtice |
---|
[4688] | 219 | ! mass flux, <0 |
---|
[4872] | 220 | wfx_spr_1d(ji) = wfx_spr_1d(ji) - rhosn * a_i_1d(ji) * zdh_s_pre(ji) * r1_rdtice |
---|
[825] | 221 | |
---|
[4688] | 222 | !--------------------- |
---|
| 223 | ! Melt of falling snow |
---|
| 224 | !--------------------- |
---|
| 225 | ! thickness change |
---|
[5134] | 226 | rswitch = MAX( 0._wp , SIGN( 1._wp , zqprec(ji) - epsi20 ) ) |
---|
[5167] | 227 | zdeltah (ji,1) = - rswitch * zq_su(ji) / MAX( zqprec(ji) , epsi20 ) |
---|
| 228 | zdeltah (ji,1) = MAX( - zdh_s_pre(ji), zdeltah(ji,1) ) ! bound melting |
---|
[4688] | 229 | ! heat used to melt snow (W.m-2, >0) |
---|
[5167] | 230 | hfx_snw_1d(ji) = hfx_snw_1d(ji) - zdeltah(ji,1) * a_i_1d(ji) * zqprec(ji) * r1_rdtice |
---|
[4688] | 231 | ! snow melting only = water into the ocean (then without snow precip), >0 |
---|
[8233] | 232 | wfx_snw_sum_1d(ji) = wfx_snw_sum_1d(ji) - rhosn * a_i_1d(ji) * zdeltah(ji,1) * r1_rdtice |
---|
[5167] | 233 | ! updates available heat + precipitations after melting |
---|
| 234 | zq_su (ji) = MAX( 0._wp , zq_su (ji) + zdeltah(ji,1) * zqprec(ji) ) |
---|
| 235 | zdh_s_pre (ji) = zdh_s_pre(ji) + zdeltah(ji,1) |
---|
[4688] | 236 | |
---|
[5167] | 237 | ! update thickness |
---|
| 238 | ht_s_1d(ji) = MAX( 0._wp , ht_s_1d(ji) + zdh_s_pre(ji) ) |
---|
[825] | 239 | END DO |
---|
| 240 | |
---|
[5167] | 241 | ! If heat still available (zq_su > 0), then melt more snow |
---|
| 242 | zdeltah(:,:) = 0._wp |
---|
[825] | 243 | DO jk = 1, nlay_s |
---|
| 244 | DO ji = kideb, kiut |
---|
[4688] | 245 | ! thickness change |
---|
[4990] | 246 | rswitch = 1._wp - MAX( 0._wp, SIGN( 1._wp, - ht_s_1d(ji) ) ) |
---|
[8325] | 247 | rswitch = rswitch * ( MAX( 0._wp, SIGN( 1._wp, e_s_1d(ji,jk) - epsi20 ) ) ) |
---|
| 248 | zdeltah (ji,jk) = - rswitch * zq_su(ji) / MAX( e_s_1d(ji,jk), epsi20 ) |
---|
[5167] | 249 | zdeltah (ji,jk) = MAX( zdeltah(ji,jk) , - ht_s_1d(ji) ) ! bound melting |
---|
[4688] | 250 | zdh_s_mel(ji) = zdh_s_mel(ji) + zdeltah(ji,jk) |
---|
| 251 | ! heat used to melt snow(W.m-2, >0) |
---|
[8325] | 252 | hfx_snw_1d(ji) = hfx_snw_1d(ji) - zdeltah(ji,jk) * a_i_1d(ji) * e_s_1d(ji,jk) * r1_rdtice |
---|
[4688] | 253 | ! snow melting only = water into the ocean (then without snow precip) |
---|
[8233] | 254 | wfx_snw_sum_1d(ji) = wfx_snw_sum_1d(ji) - rhosn * a_i_1d(ji) * zdeltah(ji,jk) * r1_rdtice |
---|
[4688] | 255 | ! updates available heat + thickness |
---|
[8325] | 256 | zq_su (ji) = MAX( 0._wp , zq_su (ji) + zdeltah(ji,jk) * e_s_1d(ji,jk) ) |
---|
[4872] | 257 | ht_s_1d(ji) = MAX( 0._wp , ht_s_1d(ji) + zdeltah(ji,jk) ) |
---|
[1572] | 258 | END DO |
---|
| 259 | END DO |
---|
[825] | 260 | |
---|
[6416] | 261 | !------------------------------ |
---|
| 262 | ! 3.2 Sublimation (part1: snow) |
---|
| 263 | !------------------------------ |
---|
[4688] | 264 | ! qla_ice is always >=0 (upwards), heat goes to the atmosphere, therefore snow sublimates |
---|
[5167] | 265 | ! clem comment: not counted in mass/heat exchange in limsbc since this is an exchange with atm. (not ocean) |
---|
| 266 | zdeltah(:,:) = 0._wp |
---|
[5407] | 267 | DO ji = kideb, kiut |
---|
[6416] | 268 | zdh_s_sub(ji) = MAX( - ht_s_1d(ji) , - evap_ice_1d(ji) * r1_rhosn * rdt_ice ) |
---|
| 269 | ! remaining evap in kg.m-2 (used for ice melting later on) |
---|
| 270 | zevap_rema(ji) = evap_ice_1d(ji) * rdt_ice + zdh_s_sub(ji) * rhosn |
---|
| 271 | ! Heat flux by sublimation [W.m-2], < 0 (sublimate first snow that had fallen, then pre-existing snow) |
---|
[5407] | 272 | zdeltah(ji,1) = MAX( zdh_s_sub(ji), - zdh_s_pre(ji) ) |
---|
[8325] | 273 | hfx_sub_1d(ji) = hfx_sub_1d(ji) + ( zdeltah(ji,1) * zqprec(ji) + ( zdh_s_sub(ji) - zdeltah(ji,1) ) * e_s_1d(ji,1) & |
---|
[5407] | 274 | & ) * a_i_1d(ji) * r1_rdtice |
---|
| 275 | ! Mass flux by sublimation |
---|
[8239] | 276 | wfx_snw_sub_1d(ji) = wfx_snw_sub_1d(ji) - rhosn * a_i_1d(ji) * zdh_s_sub(ji) * r1_rdtice |
---|
| 277 | |
---|
[5407] | 278 | ! new snow thickness |
---|
| 279 | ht_s_1d(ji) = MAX( 0._wp , ht_s_1d(ji) + zdh_s_sub(ji) ) |
---|
| 280 | ! update precipitations after sublimation and correct sublimation |
---|
| 281 | zdh_s_pre(ji) = zdh_s_pre(ji) + zdeltah(ji,1) |
---|
| 282 | zdh_s_sub(ji) = zdh_s_sub(ji) - zdeltah(ji,1) |
---|
| 283 | END DO |
---|
| 284 | |
---|
[4688] | 285 | ! --- Update snow diags --- ! |
---|
[825] | 286 | DO ji = kideb, kiut |
---|
[5167] | 287 | dh_s_tot(ji) = zdh_s_mel(ji) + zdh_s_pre(ji) + zdh_s_sub(ji) |
---|
| 288 | END DO |
---|
[825] | 289 | |
---|
[4688] | 290 | !------------------------------------------- |
---|
| 291 | ! 3.3 Update temperature, energy |
---|
| 292 | !------------------------------------------- |
---|
| 293 | ! new temp and enthalpy of the snow (remaining snow precip + remaining pre-existing snow) |
---|
[825] | 294 | DO jk = 1, nlay_s |
---|
| 295 | DO ji = kideb,kiut |
---|
[6416] | 296 | rswitch = MAX( 0._wp , SIGN( 1._wp, ht_s_1d(ji) - epsi20 ) ) |
---|
[8325] | 297 | e_s_1d(ji,jk) = rswitch / MAX( ht_s_1d(ji), epsi20 ) * & |
---|
[6416] | 298 | & ( ( zdh_s_pre(ji) ) * zqprec(ji) + & |
---|
| 299 | & ( ht_s_1d(ji) - zdh_s_pre(ji) ) * rhosn * ( cpic * ( rt0 - t_s_1d(ji,jk) ) + lfus ) ) |
---|
[825] | 300 | END DO |
---|
| 301 | END DO |
---|
| 302 | |
---|
[4688] | 303 | !-------------------------- |
---|
| 304 | ! 3.4 Surface ice ablation |
---|
| 305 | !-------------------------- |
---|
| 306 | zdeltah(:,:) = 0._wp ! important |
---|
| 307 | DO jk = 1, nlay_i |
---|
[5167] | 308 | DO ji = kideb, kiut |
---|
[5202] | 309 | ztmelts = - tmut * s_i_1d(ji,jk) + rt0 ! Melting point of layer k [K] |
---|
| 310 | |
---|
| 311 | IF( t_i_1d(ji,jk) >= ztmelts ) THEN !!! Internal melting |
---|
[4688] | 312 | |
---|
[8325] | 313 | zEi = - e_i_1d(ji,jk) * r1_rhoic ! Specific enthalpy of layer k [J/kg, <0] |
---|
[5202] | 314 | zdE = 0._wp ! Specific enthalpy difference (J/kg, <0) |
---|
| 315 | ! set up at 0 since no energy is needed to melt water...(it is already melted) |
---|
| 316 | zdeltah(ji,jk) = MIN( 0._wp , - zh_i(ji,jk) ) ! internal melting occurs when the internal temperature is above freezing |
---|
| 317 | ! this should normally not happen, but sometimes, heat diffusion leads to this |
---|
| 318 | zfmdt = - zdeltah(ji,jk) * rhoic ! Mass flux x time step > 0 |
---|
| 319 | |
---|
| 320 | dh_i_surf(ji) = dh_i_surf(ji) + zdeltah(ji,jk) ! Cumulate surface melt |
---|
| 321 | |
---|
| 322 | zfmdt = - rhoic * zdeltah(ji,jk) ! Recompute mass flux [kg/m2, >0] |
---|
[4688] | 323 | |
---|
[5202] | 324 | ! Contribution to heat flux to the ocean [W.m-2], <0 (ice enthalpy zEi is "sent" to the ocean) |
---|
| 325 | hfx_res_1d(ji) = hfx_res_1d(ji) + zfmdt * a_i_1d(ji) * zEi * r1_rdtice |
---|
| 326 | |
---|
| 327 | ! Contribution to salt flux (clem: using sm_i_1d and not s_i_1d(jk) is ok) |
---|
| 328 | sfx_res_1d(ji) = sfx_res_1d(ji) - rhoic * a_i_1d(ji) * zdeltah(ji,jk) * sm_i_1d(ji) * r1_rdtice |
---|
| 329 | |
---|
| 330 | ! Contribution to mass flux |
---|
| 331 | wfx_res_1d(ji) = wfx_res_1d(ji) - rhoic * a_i_1d(ji) * zdeltah(ji,jk) * r1_rdtice |
---|
[4688] | 332 | |
---|
[5202] | 333 | ELSE !!! Surface melting |
---|
| 334 | |
---|
[8325] | 335 | zEi = - e_i_1d(ji,jk) * r1_rhoic ! Specific enthalpy of layer k [J/kg, <0] |
---|
[5202] | 336 | zEw = rcp * ( ztmelts - rt0 ) ! Specific enthalpy of resulting meltwater [J/kg, <0] |
---|
| 337 | zdE = zEi - zEw ! Specific enthalpy difference < 0 |
---|
| 338 | |
---|
| 339 | zfmdt = - zq_su(ji) / zdE ! Mass flux to the ocean [kg/m2, >0] |
---|
| 340 | |
---|
| 341 | zdeltah(ji,jk) = - zfmdt * r1_rhoic ! Melt of layer jk [m, <0] |
---|
| 342 | |
---|
| 343 | zdeltah(ji,jk) = MIN( 0._wp , MAX( zdeltah(ji,jk) , - zh_i(ji,jk) ) ) ! Melt of layer jk cannot exceed the layer thickness [m, <0] |
---|
| 344 | |
---|
| 345 | zq_su(ji) = MAX( 0._wp , zq_su(ji) - zdeltah(ji,jk) * rhoic * zdE ) ! update available heat |
---|
| 346 | |
---|
| 347 | dh_i_surf(ji) = dh_i_surf(ji) + zdeltah(ji,jk) ! Cumulate surface melt |
---|
| 348 | |
---|
| 349 | zfmdt = - rhoic * zdeltah(ji,jk) ! Recompute mass flux [kg/m2, >0] |
---|
| 350 | |
---|
| 351 | zQm = zfmdt * zEw ! Energy of the melt water sent to the ocean [J/m2, <0] |
---|
| 352 | |
---|
[6416] | 353 | ! Contribution to salt flux >0 (clem: using sm_i_1d and not s_i_1d(jk) is ok) |
---|
[5202] | 354 | sfx_sum_1d(ji) = sfx_sum_1d(ji) - rhoic * a_i_1d(ji) * zdeltah(ji,jk) * sm_i_1d(ji) * r1_rdtice |
---|
| 355 | |
---|
| 356 | ! Contribution to heat flux [W.m-2], < 0 |
---|
| 357 | hfx_thd_1d(ji) = hfx_thd_1d(ji) + zfmdt * a_i_1d(ji) * zEw * r1_rdtice |
---|
| 358 | |
---|
| 359 | ! Total heat flux used in this process [W.m-2], > 0 |
---|
| 360 | hfx_sum_1d(ji) = hfx_sum_1d(ji) - zfmdt * a_i_1d(ji) * zdE * r1_rdtice |
---|
| 361 | |
---|
| 362 | ! Contribution to mass flux |
---|
| 363 | wfx_sum_1d(ji) = wfx_sum_1d(ji) - rhoic * a_i_1d(ji) * zdeltah(ji,jk) * r1_rdtice |
---|
| 364 | |
---|
[5167] | 365 | END IF |
---|
[6416] | 366 | ! ---------------------- |
---|
| 367 | ! Sublimation part2: ice |
---|
| 368 | ! ---------------------- |
---|
| 369 | zdum = MAX( - ( zh_i(ji,jk) + zdeltah(ji,jk) ) , - zevap_rema(ji) * r1_rhoic ) |
---|
| 370 | zdeltah(ji,jk) = zdeltah(ji,jk) + zdum |
---|
| 371 | dh_i_sub(ji) = dh_i_sub(ji) + zdum |
---|
| 372 | ! Salt flux > 0 (clem2016: flux is sent to the ocean for simplicity but salt should remain in the ice except if all ice is melted. |
---|
| 373 | ! It must be corrected at some point) |
---|
| 374 | sfx_sub_1d(ji) = sfx_sub_1d(ji) - rhoic * a_i_1d(ji) * zdum * sm_i_1d(ji) * r1_rdtice |
---|
| 375 | ! Heat flux [W.m-2], < 0 |
---|
[8325] | 376 | hfx_sub_1d(ji) = hfx_sub_1d(ji) + zdum * e_i_1d(ji,jk) * a_i_1d(ji) * r1_rdtice |
---|
[6416] | 377 | ! Mass flux > 0 |
---|
[8239] | 378 | wfx_ice_sub_1d(ji) = wfx_ice_sub_1d(ji) - rhoic * a_i_1d(ji) * zdum * r1_rdtice |
---|
| 379 | |
---|
[6416] | 380 | ! update remaining mass flux |
---|
| 381 | zevap_rema(ji) = zevap_rema(ji) + zdum * rhoic |
---|
| 382 | |
---|
[4688] | 383 | ! record which layers have disappeared (for bottom melting) |
---|
| 384 | ! => icount=0 : no layer has vanished |
---|
| 385 | ! => icount=5 : 5 layers have vanished |
---|
[5202] | 386 | rswitch = MAX( 0._wp , SIGN( 1._wp , - ( zh_i(ji,jk) + zdeltah(ji,jk) ) ) ) |
---|
| 387 | icount(ji,jk) = NINT( rswitch ) |
---|
| 388 | zh_i(ji,jk) = MAX( 0._wp , zh_i(ji,jk) + zdeltah(ji,jk) ) |
---|
[6416] | 389 | |
---|
[4688] | 390 | ! update heat content (J.m-2) and layer thickness |
---|
[8325] | 391 | eh_i_old(ji,jk) = eh_i_old(ji,jk) + zdeltah(ji,jk) * e_i_1d(ji,jk) |
---|
[4688] | 392 | h_i_old (ji,jk) = h_i_old (ji,jk) + zdeltah(ji,jk) |
---|
[825] | 393 | END DO |
---|
[921] | 394 | END DO |
---|
[4688] | 395 | ! update ice thickness |
---|
| 396 | DO ji = kideb, kiut |
---|
[6416] | 397 | ht_i_1d(ji) = MAX( 0._wp , ht_i_1d(ji) + dh_i_surf(ji) + dh_i_sub(ji) ) |
---|
[4688] | 398 | END DO |
---|
[825] | 399 | |
---|
[6416] | 400 | ! remaining "potential" evap is sent to ocean |
---|
| 401 | DO ji = kideb, kiut |
---|
[8326] | 402 | wfx_err_sub_1d(ji) = wfx_err_sub_1d(ji) - zevap_rema(ji) * a_i_1d(ji) * r1_rdtice ! <=0 (net evap for the ocean in kg.m-2.s-1) |
---|
[6416] | 403 | END DO |
---|
| 404 | |
---|
[921] | 405 | ! |
---|
| 406 | !------------------------------------------------------------------------------! |
---|
| 407 | ! 4) Basal growth / melt ! |
---|
| 408 | !------------------------------------------------------------------------------! |
---|
| 409 | ! |
---|
[4688] | 410 | !------------------ |
---|
| 411 | ! 4.1 Basal growth |
---|
| 412 | !------------------ |
---|
| 413 | ! Basal growth is driven by heat imbalance at the ice-ocean interface, |
---|
| 414 | ! between the inner conductive flux (fc_bo_i), from the open water heat flux |
---|
| 415 | ! (fhld) and the turbulent ocean flux (fhtur). |
---|
| 416 | ! fc_bo_i is positive downwards. fhtur and fhld are positive to the ice |
---|
[825] | 417 | |
---|
[4688] | 418 | ! If salinity varies in time, an iterative procedure is required, because |
---|
| 419 | ! the involved quantities are inter-dependent. |
---|
| 420 | ! Basal growth (dh_i_bott) depends upon new ice specific enthalpy (zEi), |
---|
| 421 | ! which depends on forming ice salinity (s_i_new), which depends on dh/dt (dh_i_bott) |
---|
| 422 | ! -> need for an iterative procedure, which converges quickly |
---|
| 423 | |
---|
[5167] | 424 | num_iter_max = 1 |
---|
| 425 | IF( nn_icesal == 2 ) num_iter_max = 5 |
---|
[825] | 426 | |
---|
[4688] | 427 | ! Iterative procedure |
---|
| 428 | DO iter = 1, num_iter_max |
---|
| 429 | DO ji = kideb, kiut |
---|
| 430 | IF( zf_tt(ji) < 0._wp ) THEN |
---|
[825] | 431 | |
---|
[4688] | 432 | ! New bottom ice salinity (Cox & Weeks, JGR88 ) |
---|
| 433 | !--- zswi1 if dh/dt < 2.0e-8 |
---|
| 434 | !--- zswi12 if 2.0e-8 < dh/dt < 3.6e-7 |
---|
| 435 | !--- zswi2 if dh/dt > 3.6e-7 |
---|
| 436 | zgrr = MIN( 1.0e-3, MAX ( dh_i_bott(ji) * r1_rdtice , epsi10 ) ) |
---|
| 437 | zswi2 = MAX( 0._wp , SIGN( 1._wp , zgrr - 3.6e-7 ) ) |
---|
| 438 | zswi12 = MAX( 0._wp , SIGN( 1._wp , zgrr - 2.0e-8 ) ) * ( 1.0 - zswi2 ) |
---|
| 439 | zswi1 = 1. - zswi2 * zswi12 |
---|
| 440 | zfracs = MIN ( zswi1 * 0.12 + zswi12 * ( 0.8925 + 0.0568 * LOG( 100.0 * zgrr ) ) & |
---|
| 441 | & + zswi2 * 0.26 / ( 0.26 + 0.74 * EXP ( - 724300.0 * zgrr ) ) , 0.5 ) |
---|
[825] | 442 | |
---|
[8326] | 443 | s_i_new(ji) = zswitch_sal * zfracs * sss_1d(ji) & ! New ice salinity |
---|
[4872] | 444 | + ( 1. - zswitch_sal ) * sm_i_1d(ji) |
---|
[4688] | 445 | ! New ice growth |
---|
[5123] | 446 | ztmelts = - tmut * s_i_new(ji) + rt0 ! New ice melting point (K) |
---|
[825] | 447 | |
---|
[4872] | 448 | zt_i_new = zswitch_sal * t_bo_1d(ji) + ( 1. - zswitch_sal) * t_i_1d(ji, nlay_i) |
---|
[4688] | 449 | |
---|
| 450 | zEi = cpic * ( zt_i_new - ztmelts ) & ! Specific enthalpy of forming ice (J/kg, <0) |
---|
[5123] | 451 | & - lfus * ( 1.0 - ( ztmelts - rt0 ) / ( zt_i_new - rt0 ) ) & |
---|
| 452 | & + rcp * ( ztmelts-rt0 ) |
---|
[4688] | 453 | |
---|
[4872] | 454 | zEw = rcp * ( t_bo_1d(ji) - rt0 ) ! Specific enthalpy of seawater (J/kg, < 0) |
---|
[4688] | 455 | |
---|
| 456 | zdE = zEi - zEw ! Specific enthalpy difference (J/kg, <0) |
---|
| 457 | |
---|
| 458 | dh_i_bott(ji) = rdt_ice * MAX( 0._wp , zf_tt(ji) / ( zdE * rhoic ) ) |
---|
| 459 | |
---|
[8325] | 460 | e_i_1d(ji,nlay_i+1) = -zEi * rhoic ! New ice energy of melting (J/m3, >0) |
---|
[4688] | 461 | |
---|
[5134] | 462 | ENDIF |
---|
| 463 | END DO |
---|
| 464 | END DO |
---|
[4688] | 465 | |
---|
| 466 | ! Contribution to Energy and Salt Fluxes |
---|
[825] | 467 | DO ji = kideb, kiut |
---|
[4688] | 468 | IF( zf_tt(ji) < 0._wp ) THEN |
---|
| 469 | ! New ice growth |
---|
| 470 | |
---|
| 471 | zfmdt = - rhoic * dh_i_bott(ji) ! Mass flux x time step (kg/m2, < 0) |
---|
| 472 | |
---|
[5123] | 473 | ztmelts = - tmut * s_i_new(ji) + rt0 ! New ice melting point (K) |
---|
[4688] | 474 | |
---|
[4872] | 475 | zt_i_new = zswitch_sal * t_bo_1d(ji) + ( 1. - zswitch_sal) * t_i_1d(ji, nlay_i) |
---|
[4688] | 476 | |
---|
| 477 | zEi = cpic * ( zt_i_new - ztmelts ) & ! Specific enthalpy of forming ice (J/kg, <0) |
---|
[5123] | 478 | & - lfus * ( 1.0 - ( ztmelts - rt0 ) / ( zt_i_new - rt0 ) ) & |
---|
| 479 | & + rcp * ( ztmelts-rt0 ) |
---|
[4688] | 480 | |
---|
[4872] | 481 | zEw = rcp * ( t_bo_1d(ji) - rt0 ) ! Specific enthalpy of seawater (J/kg, < 0) |
---|
[4688] | 482 | |
---|
| 483 | zdE = zEi - zEw ! Specific enthalpy difference (J/kg, <0) |
---|
| 484 | |
---|
| 485 | ! Contribution to heat flux to the ocean [W.m-2], >0 |
---|
[4872] | 486 | hfx_thd_1d(ji) = hfx_thd_1d(ji) + zfmdt * a_i_1d(ji) * zEw * r1_rdtice |
---|
[4688] | 487 | |
---|
| 488 | ! Total heat flux used in this process [W.m-2], <0 |
---|
[4872] | 489 | hfx_bog_1d(ji) = hfx_bog_1d(ji) - zfmdt * a_i_1d(ji) * zdE * r1_rdtice |
---|
[4688] | 490 | |
---|
| 491 | ! Contribution to salt flux, <0 |
---|
[5167] | 492 | sfx_bog_1d(ji) = sfx_bog_1d(ji) - rhoic * a_i_1d(ji) * dh_i_bott(ji) * s_i_new(ji) * r1_rdtice |
---|
[4688] | 493 | |
---|
| 494 | ! Contribution to mass flux, <0 |
---|
[4872] | 495 | wfx_bog_1d(ji) = wfx_bog_1d(ji) - rhoic * a_i_1d(ji) * dh_i_bott(ji) * r1_rdtice |
---|
[4688] | 496 | |
---|
| 497 | ! update heat content (J.m-2) and layer thickness |
---|
[8325] | 498 | eh_i_old(ji,nlay_i+1) = eh_i_old(ji,nlay_i+1) + dh_i_bott(ji) * e_i_1d(ji,nlay_i+1) |
---|
[4688] | 499 | h_i_old (ji,nlay_i+1) = h_i_old (ji,nlay_i+1) + dh_i_bott(ji) |
---|
[825] | 500 | ENDIF |
---|
| 501 | END DO |
---|
| 502 | |
---|
[4688] | 503 | !---------------- |
---|
| 504 | ! 4.2 Basal melt |
---|
| 505 | !---------------- |
---|
| 506 | zdeltah(:,:) = 0._wp ! important |
---|
[825] | 507 | DO jk = nlay_i, 1, -1 |
---|
| 508 | DO ji = kideb, kiut |
---|
[5202] | 509 | IF( zf_tt(ji) > 0._wp .AND. jk > icount(ji,jk) ) THEN ! do not calculate where layer has already disappeared by surface melting |
---|
[825] | 510 | |
---|
[5123] | 511 | ztmelts = - tmut * s_i_1d(ji,jk) + rt0 ! Melting point of layer jk (K) |
---|
[825] | 512 | |
---|
[4872] | 513 | IF( t_i_1d(ji,jk) >= ztmelts ) THEN !!! Internal melting |
---|
[825] | 514 | |
---|
[8325] | 515 | zEi = - e_i_1d(ji,jk) * r1_rhoic ! Specific enthalpy of melting ice (J/kg, <0) |
---|
[4688] | 516 | zdE = 0._wp ! Specific enthalpy difference (J/kg, <0) |
---|
| 517 | ! set up at 0 since no energy is needed to melt water...(it is already melted) |
---|
[5202] | 518 | zdeltah (ji,jk) = MIN( 0._wp , - zh_i(ji,jk) ) ! internal melting occurs when the internal temperature is above freezing |
---|
| 519 | ! this should normally not happen, but sometimes, heat diffusion leads to this |
---|
[4161] | 520 | |
---|
[4688] | 521 | dh_i_bott (ji) = dh_i_bott(ji) + zdeltah(ji,jk) |
---|
[825] | 522 | |
---|
[5202] | 523 | zfmdt = - zdeltah(ji,jk) * rhoic ! Mass flux x time step > 0 |
---|
[825] | 524 | |
---|
[4688] | 525 | ! Contribution to heat flux to the ocean [W.m-2], <0 (ice enthalpy zEi is "sent" to the ocean) |
---|
[4872] | 526 | hfx_res_1d(ji) = hfx_res_1d(ji) + zfmdt * a_i_1d(ji) * zEi * r1_rdtice |
---|
[825] | 527 | |
---|
[4872] | 528 | ! Contribution to salt flux (clem: using sm_i_1d and not s_i_1d(jk) is ok) |
---|
[5167] | 529 | sfx_res_1d(ji) = sfx_res_1d(ji) - rhoic * a_i_1d(ji) * zdeltah(ji,jk) * sm_i_1d(ji) * r1_rdtice |
---|
[4688] | 530 | |
---|
| 531 | ! Contribution to mass flux |
---|
[4872] | 532 | wfx_res_1d(ji) = wfx_res_1d(ji) - rhoic * a_i_1d(ji) * zdeltah(ji,jk) * r1_rdtice |
---|
[825] | 533 | |
---|
[4688] | 534 | ! update heat content (J.m-2) and layer thickness |
---|
[8325] | 535 | eh_i_old(ji,jk) = eh_i_old(ji,jk) + zdeltah(ji,jk) * e_i_1d(ji,jk) |
---|
[4688] | 536 | h_i_old (ji,jk) = h_i_old (ji,jk) + zdeltah(ji,jk) |
---|
[825] | 537 | |
---|
[4688] | 538 | ELSE !!! Basal melting |
---|
[825] | 539 | |
---|
[8325] | 540 | zEi = - e_i_1d(ji,jk) * r1_rhoic ! Specific enthalpy of melting ice (J/kg, <0) |
---|
[5202] | 541 | zEw = rcp * ( ztmelts - rt0 ) ! Specific enthalpy of meltwater (J/kg, <0) |
---|
| 542 | zdE = zEi - zEw ! Specific enthalpy difference (J/kg, <0) |
---|
[825] | 543 | |
---|
[5202] | 544 | zfmdt = - zq_bo(ji) / zdE ! Mass flux x time step (kg/m2, >0) |
---|
[825] | 545 | |
---|
[5202] | 546 | zdeltah(ji,jk) = - zfmdt * r1_rhoic ! Gross thickness change |
---|
[4688] | 547 | |
---|
[5202] | 548 | zdeltah(ji,jk) = MIN( 0._wp , MAX( zdeltah(ji,jk), - zh_i(ji,jk) ) ) ! bound thickness change |
---|
[4688] | 549 | |
---|
[5202] | 550 | zq_bo(ji) = MAX( 0._wp , zq_bo(ji) - zdeltah(ji,jk) * rhoic * zdE ) ! update available heat. MAX is necessary for roundup errors |
---|
[4688] | 551 | |
---|
[5202] | 552 | dh_i_bott(ji) = dh_i_bott(ji) + zdeltah(ji,jk) ! Update basal melt |
---|
[4688] | 553 | |
---|
[5202] | 554 | zfmdt = - zdeltah(ji,jk) * rhoic ! Mass flux x time step > 0 |
---|
[4688] | 555 | |
---|
[5202] | 556 | zQm = zfmdt * zEw ! Heat exchanged with ocean |
---|
[4688] | 557 | |
---|
| 558 | ! Contribution to heat flux to the ocean [W.m-2], <0 |
---|
[5202] | 559 | hfx_thd_1d(ji) = hfx_thd_1d(ji) + zfmdt * a_i_1d(ji) * zEw * r1_rdtice |
---|
[4688] | 560 | |
---|
[4872] | 561 | ! Contribution to salt flux (clem: using sm_i_1d and not s_i_1d(jk) is ok) |
---|
[5202] | 562 | sfx_bom_1d(ji) = sfx_bom_1d(ji) - rhoic * a_i_1d(ji) * zdeltah(ji,jk) * sm_i_1d(ji) * r1_rdtice |
---|
[4688] | 563 | |
---|
| 564 | ! Total heat flux used in this process [W.m-2], >0 |
---|
[5202] | 565 | hfx_bom_1d(ji) = hfx_bom_1d(ji) - zfmdt * a_i_1d(ji) * zdE * r1_rdtice |
---|
[4688] | 566 | |
---|
| 567 | ! Contribution to mass flux |
---|
[5202] | 568 | wfx_bom_1d(ji) = wfx_bom_1d(ji) - rhoic * a_i_1d(ji) * zdeltah(ji,jk) * r1_rdtice |
---|
[4688] | 569 | |
---|
| 570 | ! update heat content (J.m-2) and layer thickness |
---|
[8325] | 571 | eh_i_old(ji,jk) = eh_i_old(ji,jk) + zdeltah(ji,jk) * e_i_1d(ji,jk) |
---|
[4688] | 572 | h_i_old (ji,jk) = h_i_old (ji,jk) + zdeltah(ji,jk) |
---|
| 573 | ENDIF |
---|
| 574 | |
---|
| 575 | ENDIF |
---|
[5123] | 576 | END DO |
---|
| 577 | END DO |
---|
[4688] | 578 | |
---|
[825] | 579 | !------------------------------------------- |
---|
[4688] | 580 | ! Update temperature, energy |
---|
[825] | 581 | !------------------------------------------- |
---|
| 582 | DO ji = kideb, kiut |
---|
[4872] | 583 | ht_i_1d(ji) = MAX( 0._wp , ht_i_1d(ji) + dh_i_bott(ji) ) |
---|
[4688] | 584 | END DO |
---|
[825] | 585 | |
---|
[4688] | 586 | !------------------------------------------- |
---|
| 587 | ! 5. What to do with remaining energy |
---|
| 588 | !------------------------------------------- |
---|
| 589 | ! If heat still available for melting and snow remains, then melt more snow |
---|
| 590 | !------------------------------------------- |
---|
| 591 | zdeltah(:,:) = 0._wp ! important |
---|
| 592 | DO ji = kideb, kiut |
---|
| 593 | zq_rema(ji) = zq_su(ji) + zq_bo(ji) |
---|
[5128] | 594 | rswitch = 1._wp - MAX( 0._wp, SIGN( 1._wp, - ht_s_1d(ji) ) ) ! =1 if snow |
---|
[8325] | 595 | rswitch = rswitch * MAX( 0._wp, SIGN( 1._wp, e_s_1d(ji,1) - epsi20 ) ) |
---|
| 596 | zdeltah (ji,1) = - rswitch * zq_rema(ji) / MAX( e_s_1d(ji,1), epsi20 ) |
---|
[5128] | 597 | zdeltah (ji,1) = MIN( 0._wp , MAX( zdeltah(ji,1) , - ht_s_1d(ji) ) ) ! bound melting |
---|
| 598 | dh_s_tot (ji) = dh_s_tot(ji) + zdeltah(ji,1) |
---|
| 599 | ht_s_1d (ji) = ht_s_1d(ji) + zdeltah(ji,1) |
---|
| 600 | |
---|
[8325] | 601 | zq_rema(ji) = zq_rema(ji) + zdeltah(ji,1) * e_s_1d(ji,1) ! update available heat (J.m-2) |
---|
[5128] | 602 | ! heat used to melt snow |
---|
[8325] | 603 | hfx_snw_1d(ji) = hfx_snw_1d(ji) - zdeltah(ji,1) * a_i_1d(ji) * e_s_1d(ji,1) * r1_rdtice ! W.m-2 (>0) |
---|
[5128] | 604 | ! Contribution to mass flux |
---|
[8233] | 605 | wfx_snw_sum_1d(ji) = wfx_snw_sum_1d(ji) - rhosn * a_i_1d(ji) * zdeltah(ji,1) * r1_rdtice |
---|
[5128] | 606 | ! |
---|
[4688] | 607 | ! Remaining heat flux (W.m-2) is sent to the ocean heat budget |
---|
[8326] | 608 | hfx_out_1d(ji) = hfx_out_1d(ji) + ( zq_rema(ji) * a_i_1d(ji) ) * r1_rdtice |
---|
[825] | 609 | |
---|
[7646] | 610 | IF( ln_limctl .AND. zq_rema(ji) < 0. .AND. lwp ) WRITE(numout,*) 'ALERTE zq_rema <0 = ', zq_rema(ji) |
---|
[4688] | 611 | END DO |
---|
[8239] | 612 | |
---|
| 613 | ! Water fluxes |
---|
| 614 | DO ji = kideb, kiut |
---|
| 615 | wfx_sub_1d(ji) = wfx_snw_sub_1d(ji) + wfx_ice_sub_1d(ji) ! sum ice and snow sublimation contributions |
---|
| 616 | END DO |
---|
| 617 | |
---|
[921] | 618 | ! |
---|
| 619 | !------------------------------------------------------------------------------| |
---|
| 620 | ! 6) Snow-Ice formation | |
---|
| 621 | !------------------------------------------------------------------------------| |
---|
[1572] | 622 | ! When snow load excesses Archimede's limit, snow-ice interface goes down under sea-level, |
---|
| 623 | ! flooding of seawater transforms snow into ice dh_snowice is positive for the ice |
---|
[825] | 624 | DO ji = kideb, kiut |
---|
[1572] | 625 | ! |
---|
[4872] | 626 | dh_snowice(ji) = MAX( 0._wp , ( rhosn * ht_s_1d(ji) + (rhoic-rau0) * ht_i_1d(ji) ) / ( rhosn+rau0-rhoic ) ) |
---|
[825] | 627 | |
---|
[5167] | 628 | ht_i_1d(ji) = ht_i_1d(ji) + dh_snowice(ji) |
---|
| 629 | ht_s_1d(ji) = ht_s_1d(ji) - dh_snowice(ji) |
---|
[825] | 630 | |
---|
[4688] | 631 | ! Contribution to energy flux to the ocean [J/m2], >0 (if sst<0) |
---|
[7646] | 632 | zfmdt = ( rhosn - rhoic ) * dh_snowice(ji) ! <0 |
---|
[8326] | 633 | zEw = rcp * sst_1d(ji) |
---|
[4688] | 634 | zQm = zfmdt * zEw |
---|
| 635 | |
---|
| 636 | ! Contribution to heat flux |
---|
[4872] | 637 | hfx_thd_1d(ji) = hfx_thd_1d(ji) + zfmdt * a_i_1d(ji) * zEw * r1_rdtice |
---|
[825] | 638 | |
---|
[4688] | 639 | ! Contribution to salt flux |
---|
[8326] | 640 | sfx_sni_1d(ji) = sfx_sni_1d(ji) + sss_1d(ji) * a_i_1d(ji) * zfmdt * r1_rdtice |
---|
[7646] | 641 | |
---|
[6470] | 642 | ! virtual salt flux to keep salinity constant |
---|
| 643 | IF( nn_icesal == 1 .OR. nn_icesal == 3 ) THEN |
---|
[8326] | 644 | sfx_bri_1d(ji) = sfx_bri_1d(ji) - sss_1d (ji) * a_i_1d(ji) * zfmdt * r1_rdtice & ! put back sss_m into the ocean |
---|
[7646] | 645 | & - sm_i_1d(ji) * a_i_1d(ji) * dh_snowice(ji) * rhoic * r1_rdtice ! and get rn_icesal from the ocean |
---|
[6470] | 646 | ENDIF |
---|
| 647 | |
---|
[4688] | 648 | ! Contribution to mass flux |
---|
| 649 | ! All snow is thrown in the ocean, and seawater is taken to replace the volume |
---|
[4872] | 650 | wfx_sni_1d(ji) = wfx_sni_1d(ji) - a_i_1d(ji) * dh_snowice(ji) * rhoic * r1_rdtice |
---|
| 651 | wfx_snw_1d(ji) = wfx_snw_1d(ji) + a_i_1d(ji) * dh_snowice(ji) * rhosn * r1_rdtice |
---|
[4688] | 652 | |
---|
| 653 | ! update heat content (J.m-2) and layer thickness |
---|
[8325] | 654 | eh_i_old(ji,0) = eh_i_old(ji,0) + dh_snowice(ji) * e_s_1d(ji,1) + zfmdt * zEw |
---|
[4688] | 655 | h_i_old (ji,0) = h_i_old (ji,0) + dh_snowice(ji) |
---|
| 656 | |
---|
[5134] | 657 | END DO |
---|
[825] | 658 | |
---|
[2715] | 659 | ! |
---|
[4688] | 660 | !------------------------------------------- |
---|
| 661 | ! Update temperature, energy |
---|
| 662 | !------------------------------------------- |
---|
| 663 | DO ji = kideb, kiut |
---|
[4990] | 664 | rswitch = 1.0 - MAX( 0._wp , SIGN( 1._wp , - ht_i_1d(ji) ) ) |
---|
[5123] | 665 | t_su_1d(ji) = rswitch * t_su_1d(ji) + ( 1.0 - rswitch ) * rt0 |
---|
[5134] | 666 | END DO |
---|
[4688] | 667 | |
---|
| 668 | DO jk = 1, nlay_s |
---|
| 669 | DO ji = kideb,kiut |
---|
| 670 | ! mask enthalpy |
---|
[5134] | 671 | rswitch = 1._wp - MAX( 0._wp , SIGN( 1._wp, - ht_s_1d(ji) ) ) |
---|
[8325] | 672 | e_s_1d(ji,jk) = rswitch * e_s_1d(ji,jk) |
---|
| 673 | ! recalculate t_s_1d from e_s_1d |
---|
| 674 | t_s_1d(ji,jk) = rt0 + rswitch * ( - e_s_1d(ji,jk) / ( rhosn * cpic ) + lfus / cpic ) |
---|
[4688] | 675 | END DO |
---|
| 676 | END DO |
---|
[5134] | 677 | |
---|
| 678 | ! --- ensure that a_i = 0 where ht_i = 0 --- |
---|
| 679 | WHERE( ht_i_1d == 0._wp ) a_i_1d = 0._wp |
---|
[5123] | 680 | |
---|
[6416] | 681 | CALL wrk_dealloc( jpij, zqprec, zq_su, zq_bo, zf_tt, zq_rema, zsnw, zevap_rema ) |
---|
[8325] | 682 | CALL wrk_dealloc( jpij, zdh_s_mel, zdh_s_pre, zdh_s_sub, zeh_i ) |
---|
[5202] | 683 | CALL wrk_dealloc( jpij, nlay_i, zdeltah, zh_i ) |
---|
| 684 | CALL wrk_dealloc( jpij, nlay_i, icount ) |
---|
[2715] | 685 | ! |
---|
[4161] | 686 | ! |
---|
[921] | 687 | END SUBROUTINE lim_thd_dh |
---|
[5407] | 688 | |
---|
| 689 | |
---|
| 690 | !!-------------------------------------------------------------------------- |
---|
| 691 | !! INTERFACE lim_thd_snwblow |
---|
| 692 | !! ** Purpose : Compute distribution of precip over the ice |
---|
| 693 | !!-------------------------------------------------------------------------- |
---|
| 694 | SUBROUTINE lim_thd_snwblow_2d( pin, pout ) |
---|
[8313] | 695 | REAL(wp), DIMENSION(:,:), INTENT(in ) :: pin ! previous fraction lead ( 1. - a_i_b ) |
---|
[5487] | 696 | REAL(wp), DIMENSION(:,:), INTENT(inout) :: pout |
---|
[5407] | 697 | pout = ( 1._wp - ( pin )**rn_betas ) |
---|
| 698 | END SUBROUTINE lim_thd_snwblow_2d |
---|
| 699 | |
---|
| 700 | SUBROUTINE lim_thd_snwblow_1d( pin, pout ) |
---|
[5487] | 701 | REAL(wp), DIMENSION(:), INTENT(in ) :: pin |
---|
| 702 | REAL(wp), DIMENSION(:), INTENT(inout) :: pout |
---|
[5407] | 703 | pout = ( 1._wp - ( pin )**rn_betas ) |
---|
| 704 | END SUBROUTINE lim_thd_snwblow_1d |
---|
| 705 | |
---|
[1572] | 706 | |
---|
[825] | 707 | #else |
---|
[1572] | 708 | !!---------------------------------------------------------------------- |
---|
| 709 | !! Default option NO LIM3 sea-ice model |
---|
| 710 | !!---------------------------------------------------------------------- |
---|
[825] | 711 | CONTAINS |
---|
| 712 | SUBROUTINE lim_thd_dh ! Empty routine |
---|
| 713 | END SUBROUTINE lim_thd_dh |
---|
| 714 | #endif |
---|
[1572] | 715 | |
---|
| 716 | !!====================================================================== |
---|
[921] | 717 | END MODULE limthd_dh |
---|