New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
limthd_lac.F90 in branches/2017/dev_r8183_ICEMODEL/NEMOGCM/NEMO/LIM_SRC_3 – NEMO

source: branches/2017/dev_r8183_ICEMODEL/NEMOGCM/NEMO/LIM_SRC_3/limthd_lac.F90 @ 8342

Last change on this file since 8342 was 8342, checked in by clem, 7 years ago

simplify the code
  • Property svn:keywords set to Id
File size: 24.4 KB
Line 
1MODULE limthd_lac
2   !!======================================================================
3   !!                       ***  MODULE limthd_lac   ***
4   !!                lateral thermodynamic growth of the ice
5   !!======================================================================
6   !! History :  LIM  ! 2005-12 (M. Vancoppenolle)  Original code
7   !!             -   ! 2006-01 (M. Vancoppenolle)  add ITD
8   !!            3.0  ! 2007-07 (M. Vancoppenolle)  Mass and energy conservation tested
9   !!            4.0  ! 2011-02 (G. Madec) dynamical allocation
10   !!----------------------------------------------------------------------
11#if defined key_lim3
12   !!----------------------------------------------------------------------
13   !!   'key_lim3'                                      LIM3 sea-ice model
14   !!----------------------------------------------------------------------
15   !!   lim_lat_acr   : lateral accretion of ice
16   !!----------------------------------------------------------------------
17   USE par_oce        ! ocean parameters
18   USE dom_oce        ! domain variables
19   USE phycst         ! physical constants
20   USE sbc_oce , ONLY : sss_m
21   USE sbc_ice , ONLY : utau_ice, vtau_ice
22   USE thd_ice        ! LIM thermodynamics
23   USE ice            ! LIM variables
24   USE limtab         ! LIM 2D <==> 1D
25   USE limcons        ! LIM conservation
26   USE in_out_manager ! I/O manager
27   USE lib_mpp        ! MPP library
28   USE wrk_nemo       ! work arrays
29   USE lbclnk         ! ocean lateral boundary conditions (or mpp link)
30   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) 
31   USE limthd_ent
32   USE limvar
33
34   IMPLICIT NONE
35   PRIVATE
36
37   PUBLIC lim_thd_lac     ! called by lim_thd
38
39   !!----------------------------------------------------------------------
40   !! NEMO/LIM3 4.0 , UCL - NEMO Consortium (2011)
41   !! $Id$
42   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
43   !!----------------------------------------------------------------------
44CONTAINS
45
46   SUBROUTINE lim_thd_lac
47      !!-------------------------------------------------------------------
48      !!               ***   ROUTINE lim_thd_lac  ***
49      !! 
50      !! ** Purpose : Computation of the evolution of the ice thickness and
51      !!      concentration as a function of the heat balance in the leads.
52      !!      It is only used for lateral accretion
53      !!       
54      !! ** Method  : Ice is formed in the open water when ocean lose heat
55      !!      (heat budget of open water Bl is negative) .
56      !!      Computation of the increase of 1-A (ice concentration) fol-
57      !!      lowing the law :
58      !!      (dA/dt)acc = F[ (1-A)/(1-a) ] * [ Bl / (Li*h0) ]
59      !!       where - h0 is the thickness of ice created in the lead
60      !!             - a is a minimum fraction for leads
61      !!             - F is a monotonic non-increasing function defined as:
62      !!                  F(X)=( 1 - X**exld )**(1.0/exld)
63      !!             - exld is the exponent closure rate (=2 default val.)
64      !!
65      !! ** Action : - Adjustment of snow and ice thicknesses and heat
66      !!                content in brine pockets
67      !!             - Updating ice internal temperature
68      !!             - Computation of variation of ice volume and mass
69      !!             - Computation of a_i after lateral accretion and
70      !!               update ht_s_1d, ht_i_1d and tbif_1d(:,:)     
71      !!------------------------------------------------------------------------
72      INTEGER  ::   ji,jj,jk,jl      ! dummy loop indices
73      INTEGER  ::   iter     !   -       -
74      REAL(wp) ::   ztmelts, zdv, zfrazb, zweight, zde                          ! local scalars
75      REAL(wp) ::   zgamafr, zvfrx, zvgx, ztaux, ztwogp, zf                     !   -      -
76      REAL(wp) ::   ztenagm, zvfry, zvgy, ztauy, zvrel2, zfp, zsqcd , zhicrit   !   -      -
77
78      REAL(wp) ::   zQm          ! enthalpy exchanged with the ocean (J/m2, >0 towards ocean)
79      REAL(wp) ::   zEi          ! sea ice specific enthalpy (J/kg)
80      REAL(wp) ::   zEw          ! seawater specific enthalpy (J/kg)
81      REAL(wp) ::   zfmdt        ! mass flux x time step (kg/m2, >0 towards ocean)
82     
83      REAL(wp) ::   zv_newfra
84 
85      INTEGER , POINTER, DIMENSION(:) ::   jcat        ! indexes of categories where new ice grows
86      REAL(wp), POINTER, DIMENSION(:) ::   zswinew     ! switch for new ice or not
87
88      REAL(wp), POINTER, DIMENSION(:) ::   zv_newice   ! volume of accreted ice
89      REAL(wp), POINTER, DIMENSION(:) ::   za_newice   ! fractional area of accreted ice
90      REAL(wp), POINTER, DIMENSION(:) ::   zh_newice   ! thickness of accreted ice
91      REAL(wp), POINTER, DIMENSION(:) ::   ze_newice   ! heat content of accreted ice
92      REAL(wp), POINTER, DIMENSION(:) ::   zs_newice   ! salinity of accreted ice
93      REAL(wp), POINTER, DIMENSION(:) ::   zo_newice   ! age of accreted ice
94      REAL(wp), POINTER, DIMENSION(:) ::   zdv_res     ! residual volume in case of excessive heat budget
95      REAL(wp), POINTER, DIMENSION(:) ::   zda_res     ! residual area in case of excessive heat budget
96      REAL(wp), POINTER, DIMENSION(:) ::   zat_i_1d    ! total ice fraction   
97      REAL(wp), POINTER, DIMENSION(:) ::   zv_frazb    ! accretion of frazil ice at the ice bottom
98      REAL(wp), POINTER, DIMENSION(:) ::   zvrel_1d    ! relative ice / frazil velocity (1D vector)
99
100      REAL(wp), POINTER, DIMENSION(:,:) ::   zv_b      ! old volume of ice in category jl
101      REAL(wp), POINTER, DIMENSION(:,:) ::   za_b      ! old area of ice in category jl
102      REAL(wp), POINTER, DIMENSION(:,:) ::   za_i_1d   ! 1-D version of a_i
103      REAL(wp), POINTER, DIMENSION(:,:) ::   zv_i_1d   ! 1-D version of v_i
104      REAL(wp), POINTER, DIMENSION(:,:) ::   zsmv_i_1d ! 1-D version of smv_i
105
106      REAL(wp), POINTER, DIMENSION(:,:,:) ::   ze_i_1d !: 1-D version of e_i
107
108      REAL(wp), POINTER, DIMENSION(:,:) ::   zvrel     ! relative ice / frazil velocity
109
110      REAL(wp) :: zcai = 1.4e-3_wp                     ! ice-air drag (clem: should be dependent on coupling/forcing used)
111      !!-----------------------------------------------------------------------!
112
113      CALL wrk_alloc( jpij, jcat )   ! integer
114      CALL wrk_alloc( jpij, zswinew, zv_newice, za_newice, zh_newice, ze_newice, zs_newice, zo_newice )
115      CALL wrk_alloc( jpij, zdv_res, zda_res, zat_i_1d, zv_frazb, zvrel_1d )
116      CALL wrk_alloc( jpij,jpl, zv_b, za_b, za_i_1d, zv_i_1d, zsmv_i_1d )
117      CALL wrk_alloc( jpij,nlay_i,jpl, ze_i_1d )
118      CALL wrk_alloc( jpi,jpj, zvrel )
119
120      CALL lim_var_agg(1)
121      CALL lim_var_glo2eqv
122
123      !------------------------------------------------------------------------------!
124      ! 3) Collection thickness of ice formed in leads and polynyas
125      !------------------------------------------------------------------------------!   
126      ! hicol is the thickness of new ice formed in open water
127      ! hicol can be either prescribed (frazswi = 0) or computed (frazswi = 1)
128      ! Frazil ice forms in open water, is transported by wind
129      ! accumulates at the edge of the consolidated ice edge
130      ! where it forms aggregates of a specific thickness called
131      ! collection thickness.
132
133      ! Note : the following algorithm currently breaks vectorization
134      !
135
136      zvrel(:,:) = 0._wp
137
138      ! Default new ice thickness
139      WHERE( qlead(:,:) < 0._wp ) ; hicol(:,:) = rn_hnewice
140      ELSEWHERE                   ; hicol(:,:) = 0._wp
141      END WHERE
142
143      IF( ln_frazil ) THEN
144
145         !--------------------
146         ! Physical constants
147         !--------------------
148         hicol(:,:) = 0._wp
149
150         zhicrit = 0.04 ! frazil ice thickness
151         ztwogp  = 2. * rau0 / ( grav * 0.3 * ( rau0 - rhoic ) ) ! reduced grav
152         zsqcd   = 1.0 / SQRT( 1.3 * zcai ) ! 1/SQRT(airdensity*drag)
153         zgamafr = 0.03
154
155         DO jj = 2, jpjm1
156            DO ji = 2, jpim1
157               IF ( qlead(ji,jj) < 0._wp .AND. tau_icebfr(ji,jj) == 0._wp ) THEN ! activated if cooling and no landfast
158                  !-------------
159                  ! Wind stress
160                  !-------------
161                  ! C-grid wind stress components
162                  ztaux         = ( utau_ice(ji-1,jj  ) * umask(ji-1,jj  ,1)   &
163                     &          +   utau_ice(ji  ,jj  ) * umask(ji  ,jj  ,1) ) * 0.5_wp
164                  ztauy         = ( vtau_ice(ji  ,jj-1) * vmask(ji  ,jj-1,1)   &
165                     &          +   vtau_ice(ji  ,jj  ) * vmask(ji  ,jj  ,1) ) * 0.5_wp
166                  ! Square root of wind stress
167                  ztenagm       =  SQRT( SQRT( ztaux * ztaux + ztauy * ztauy ) )
168
169                  !---------------------
170                  ! Frazil ice velocity
171                  !---------------------
172                  rswitch = MAX( 0._wp, SIGN( 1._wp , ztenagm - epsi10 ) )
173                  zvfrx   = rswitch * zgamafr * zsqcd * ztaux / MAX( ztenagm, epsi10 )
174                  zvfry   = rswitch * zgamafr * zsqcd * ztauy / MAX( ztenagm, epsi10 )
175
176                  !-------------------
177                  ! Pack ice velocity
178                  !-------------------
179                  ! C-grid ice velocity
180                  zvgx    = ( u_ice(ji-1,jj  ) * umask(ji-1,jj  ,1)  + u_ice(ji,jj) * umask(ji,jj,1) ) * 0.5_wp
181                  zvgy    = ( v_ice(ji  ,jj-1) * vmask(ji  ,jj-1,1)  + v_ice(ji,jj) * vmask(ji,jj,1) ) * 0.5_wp
182
183                  !-----------------------------------
184                  ! Relative frazil/pack ice velocity
185                  !-----------------------------------
186                  ! absolute relative velocity
187                  rswitch      = MAX( 0._wp, SIGN( 1._wp , at_i(ji,jj) - epsi10 ) )
188                  zvrel2       = MAX(  ( zvfrx - zvgx ) * ( zvfrx - zvgx )   &
189                     &               + ( zvfry - zvgy ) * ( zvfry - zvgy ) , 0.15 * 0.15 ) * rswitch
190                  zvrel(ji,jj) = SQRT( zvrel2 )
191
192                  !---------------------
193                  ! Iterative procedure
194                  !---------------------
195                  hicol(ji,jj) = zhicrit +   ( zhicrit + 0.1 )    &
196                     &                   / ( ( zhicrit + 0.1 ) * ( zhicrit + 0.1 ) -  zhicrit * zhicrit ) * ztwogp * zvrel2
197
198                  iter = 1
199                  DO WHILE ( iter < 20 ) 
200                     zf  = ( hicol(ji,jj) - zhicrit ) * ( hicol(ji,jj) * hicol(ji,jj) - zhicrit * zhicrit ) -   &
201                        &    hicol(ji,jj) * zhicrit * ztwogp * zvrel2
202                     zfp = ( hicol(ji,jj) - zhicrit ) * ( 3.0 * hicol(ji,jj) + zhicrit ) - zhicrit * ztwogp * zvrel2
203
204                     hicol(ji,jj) = hicol(ji,jj) - zf / MAX( zfp, epsi20 )
205                     iter = iter + 1
206                  END DO
207
208               ENDIF ! end of selection of pixels where ice forms
209
210            END DO
211         END DO 
212         !
213         CALL lbc_lnk( zvrel, 'T', 1. )
214         CALL lbc_lnk( hicol, 'T', 1. )
215
216      ENDIF ! End of computation of frazil ice collection thickness
217
218      !------------------------------------------------------------------------------!
219      ! 4) Identify grid points where new ice forms
220      !------------------------------------------------------------------------------!
221
222      !-------------------------------------
223      ! Select points for new ice formation
224      !-------------------------------------
225      ! This occurs if open water energy budget is negative (cooling) and there is no landfast ice
226      nidx = 0 ; idxice(:) = 0
227      DO jj = 1, jpj
228         DO ji = 1, jpi
229            IF ( qlead(ji,jj)  <  0._wp .AND. tau_icebfr(ji,jj) == 0._wp ) THEN
230               nidx = nidx + 1
231               idxice( nidx ) = (jj - 1) * jpi + ji
232            ENDIF
233         END DO
234      END DO
235
236      ! debug point to follow
237      jiindex_1d = 0
238      IF( ln_limctl ) THEN
239         DO ji = mi0(iiceprt), mi1(iiceprt)
240            DO jj = mj0(jiceprt), mj1(jiceprt)
241               IF ( qlead(ji,jj)  <  0._wp ) THEN
242                  jiindex_1d = (jj - 1) * jpi + ji
243               ENDIF
244            END DO
245         END DO
246      ENDIF
247   
248      IF( ln_limctl ) WRITE(numout,*) 'lim_thd_lac : nidx = ', nidx
249
250      !------------------------------
251      ! Move from 2-D to 1-D vectors
252      !------------------------------
253      ! If ocean gains heat do nothing. Otherwise compute new ice formation
254
255      IF ( nidx > 0 ) THEN
256
257         CALL tab_2d_1d( nidx, idxice(1:nidx), zat_i_1d  (1:nidx)     , at_i           )
258         DO jl = 1, jpl
259            CALL tab_2d_1d( nidx, idxice(1:nidx), za_i_1d  (1:nidx,jl), a_i  (:,:,jl)  )
260            CALL tab_2d_1d( nidx, idxice(1:nidx), zv_i_1d  (1:nidx,jl), v_i  (:,:,jl)  )
261            CALL tab_2d_1d( nidx, idxice(1:nidx), zsmv_i_1d(1:nidx,jl), smv_i(:,:,jl)  )
262            DO jk = 1, nlay_i
263               CALL tab_2d_1d( nidx, idxice(1:nidx), ze_i_1d(1:nidx,jk,jl), e_i(:,:,jk,jl)   )
264            END DO
265         END DO
266
267         CALL tab_2d_1d( nidx, idxice(1:nidx), qlead_1d  (1:nidx)     , qlead       )
268         CALL tab_2d_1d( nidx, idxice(1:nidx), t_bo_1d   (1:nidx)     , t_bo        )
269         CALL tab_2d_1d( nidx, idxice(1:nidx), sfx_opw_1d(1:nidx)     , sfx_opw     )
270         CALL tab_2d_1d( nidx, idxice(1:nidx), wfx_opw_1d(1:nidx)     , wfx_opw     )
271         CALL tab_2d_1d( nidx, idxice(1:nidx), hicol_1d  (1:nidx)     , hicol       )
272         CALL tab_2d_1d( nidx, idxice(1:nidx), zvrel_1d  (1:nidx)     , zvrel       )
273
274         CALL tab_2d_1d( nidx, idxice(1:nidx), hfx_thd_1d(1:nidx)     , hfx_thd     )
275         CALL tab_2d_1d( nidx, idxice(1:nidx), hfx_opw_1d(1:nidx)     , hfx_opw     )
276         CALL tab_2d_1d( nidx, idxice(1:nidx), rn_amax_1d(1:nidx)     , rn_amax_2d  )
277         CALL tab_2d_1d( nidx, idxice(1:nidx), sss_1d    (1:nidx)     , sss_m       )
278
279         !------------------------------------------------------------------------------|
280         ! 2) Convert units for ice internal energy
281         !------------------------------------------------------------------------------|
282         DO jl = 1, jpl
283            DO jk = 1, nlay_i
284               DO ji = 1, nidx
285                  IF( zv_i_1d(ji,jl) > 0._wp )   ze_i_1d(ji,jk,jl) = ze_i_1d(ji,jk,jl) / zv_i_1d(ji,jl) * REAL( nlay_i )
286               END DO
287            END DO
288         END DO
289         !------------------------------------------------------------------------------!
290         ! 5) Compute thickness, salinity, enthalpy, age, area and volume of new ice
291         !------------------------------------------------------------------------------!
292
293         !-----------------------------------------
294         ! Keep old ice areas and volume in memory
295         !-----------------------------------------
296         zv_b(1:nidx,:) = zv_i_1d(1:nidx,:) 
297         za_b(1:nidx,:) = za_i_1d(1:nidx,:)
298
299         !----------------------
300         ! Thickness of new ice
301         !----------------------
302         zh_newice(1:nidx) = hicol_1d(1:nidx)
303
304         !----------------------
305         ! Salinity of new ice
306         !----------------------
307         SELECT CASE ( nn_icesal )
308         CASE ( 1 )                    ! Sice = constant
309            zs_newice(1:nidx) = rn_icesal
310         CASE ( 2 )                    ! Sice = F(z,t) [Vancoppenolle et al (2005)]
311            DO ji = 1, nidx
312               zs_newice(ji) = MIN(  4.606 + 0.91 / zh_newice(ji) , rn_simax , 0.5 * sss_1d(ji) )
313            END DO
314         CASE ( 3 )                    ! Sice = F(z) [multiyear ice]
315            zs_newice(1:nidx) =   2.3
316         END SELECT
317
318         !-------------------------
319         ! Heat content of new ice
320         !-------------------------
321         ! We assume that new ice is formed at the seawater freezing point
322         DO ji = 1, nidx
323            ztmelts       = - tmut * zs_newice(ji) + rt0                  ! Melting point (K)
324            ze_newice(ji) =   rhoic * (  cpic * ( ztmelts - t_bo_1d(ji) )                                         &
325               &                       + lfus * ( 1.0 - ( ztmelts - rt0 ) / MIN( t_bo_1d(ji) - rt0, -epsi10 ) )   &
326               &                       - rcp  *         ( ztmelts - rt0 )  )
327         END DO
328
329         !----------------
330         ! Age of new ice
331         !----------------
332         DO ji = 1, nidx
333            zo_newice(ji) = 0._wp
334         END DO
335
336         !-------------------
337         ! Volume of new ice
338         !-------------------
339         DO ji = 1, nidx
340
341            zEi           = - ze_newice(ji) * r1_rhoic             ! specific enthalpy of forming ice [J/kg]
342
343            zEw           = rcp * ( t_bo_1d(ji) - rt0 )            ! specific enthalpy of seawater at t_bo_1d [J/kg]
344                                                                   ! clem: we suppose we are already at the freezing point (condition qlead<0 is satisfyied)
345                                                                   
346            zdE           = zEi - zEw                              ! specific enthalpy difference [J/kg]
347                                             
348            zfmdt         = - qlead_1d(ji) / zdE                   ! Fm.dt [kg/m2] (<0)
349                                                                   ! clem: we use qlead instead of zqld (limthd) because we suppose we are at the freezing point   
350            zv_newice(ji) = - zfmdt * r1_rhoic
351
352            zQm           = zfmdt * zEw                            ! heat to the ocean >0 associated with mass flux 
353
354            ! Contribution to heat flux to the ocean [W.m-2], >0 
355            hfx_thd_1d(ji) = hfx_thd_1d(ji) + zfmdt * zEw * r1_rdtice
356            ! Total heat flux used in this process [W.m-2] 
357            hfx_opw_1d(ji) = hfx_opw_1d(ji) - zfmdt * zdE * r1_rdtice
358            ! mass flux
359            wfx_opw_1d(ji) = wfx_opw_1d(ji) - zv_newice(ji) * rhoic * r1_rdtice
360            ! salt flux
361            sfx_opw_1d(ji) = sfx_opw_1d(ji) - zv_newice(ji) * rhoic * zs_newice(ji) * r1_rdtice
362         END DO
363         
364         zv_frazb(:) = 0._wp
365         IF( ln_frazil ) THEN
366            ! A fraction zfrazb of frazil ice is accreted at the ice bottom
367            DO ji = 1, nidx
368               rswitch       = 1._wp - MAX( 0._wp, SIGN( 1._wp , - zat_i_1d(ji) ) )
369               zfrazb        = rswitch * ( TANH( rn_Cfrazb * ( zvrel_1d(ji) - rn_vfrazb ) ) + 1.0 ) * 0.5 * rn_maxfrazb
370               zv_frazb(ji)  =         zfrazb   * zv_newice(ji)
371               zv_newice(ji) = ( 1.0 - zfrazb ) * zv_newice(ji)
372            END DO
373         END IF
374         
375         !-----------------
376         ! Area of new ice
377         !-----------------
378         DO ji = 1, nidx
379            za_newice(ji) = zv_newice(ji) / zh_newice(ji)
380         END DO
381
382         !------------------------------------------------------------------------------!
383         ! 6) Redistribute new ice area and volume into ice categories                  !
384         !------------------------------------------------------------------------------!
385
386         !------------------------
387         ! 6.1) lateral ice growth
388         !------------------------
389         ! If lateral ice growth gives an ice concentration gt 1, then
390         ! we keep the excessive volume in memory and attribute it later to bottom accretion
391         DO ji = 1, nidx
392            IF ( za_newice(ji) >  ( rn_amax_1d(ji) - zat_i_1d(ji) ) ) THEN
393               zda_res(ji)   = za_newice(ji) - ( rn_amax_1d(ji) - zat_i_1d(ji) )
394               zdv_res(ji)   = zda_res  (ji) * zh_newice(ji) 
395               za_newice(ji) = za_newice(ji) - zda_res  (ji)
396               zv_newice(ji) = zv_newice(ji) - zdv_res  (ji)
397            ELSE
398               zda_res(ji) = 0._wp
399               zdv_res(ji) = 0._wp
400            ENDIF
401         END DO
402
403         ! find which category to fill
404         zat_i_1d(:) = 0._wp
405         DO jl = 1, jpl
406            DO ji = 1, nidx
407               IF( zh_newice(ji) > hi_max(jl-1) .AND. zh_newice(ji) <= hi_max(jl) ) THEN
408                  za_i_1d (ji,jl) = za_i_1d (ji,jl) + za_newice(ji)
409                  zv_i_1d (ji,jl) = zv_i_1d (ji,jl) + zv_newice(ji)
410                  jcat    (ji)    = jl
411               ENDIF
412               zat_i_1d(ji) = zat_i_1d(ji) + za_i_1d  (ji,jl)
413            END DO
414         END DO
415
416         ! Heat content
417         DO ji = 1, nidx
418            jl = jcat(ji)                                                    ! categroy in which new ice is put
419            zswinew  (ji) = MAX( 0._wp , SIGN( 1._wp , - za_b(ji,jl) ) )   ! 0 if old ice
420         END DO
421
422         DO jk = 1, nlay_i
423            DO ji = 1, nidx
424               jl = jcat(ji)
425               rswitch = MAX( 0._wp, SIGN( 1._wp , zv_i_1d(ji,jl) - epsi20 ) )
426               ze_i_1d(ji,jk,jl) = zswinew(ji)   *   ze_newice(ji) +                                                    &
427                  &        ( 1.0 - zswinew(ji) ) * ( ze_newice(ji) * zv_newice(ji) + ze_i_1d(ji,jk,jl) * zv_b(ji,jl) )  &
428                  &        * rswitch / MAX( zv_i_1d(ji,jl), epsi20 )
429            END DO
430         END DO
431
432         !------------------------------------------------
433         ! 6.2) bottom ice growth + ice enthalpy remapping
434         !------------------------------------------------
435         DO jl = 1, jpl
436
437            ! for remapping
438            h_i_old (1:nidx,0:nlay_i+1) = 0._wp
439            eh_i_old(1:nidx,0:nlay_i+1) = 0._wp
440            DO jk = 1, nlay_i
441               DO ji = 1, nidx
442                  h_i_old (ji,jk) = zv_i_1d(ji,jl) * r1_nlay_i
443                  eh_i_old(ji,jk) = ze_i_1d(ji,jk,jl) * h_i_old(ji,jk)
444               END DO
445            END DO
446
447            ! new volumes including lateral/bottom accretion + residual
448            DO ji = 1, nidx
449               rswitch        = MAX( 0._wp, SIGN( 1._wp , zat_i_1d(ji) - epsi20 ) )
450               zv_newfra      = rswitch * ( zdv_res(ji) + zv_frazb(ji) ) * za_i_1d(ji,jl) / MAX( zat_i_1d(ji) , epsi20 )
451               za_i_1d(ji,jl) = rswitch * za_i_1d(ji,jl)               
452               zv_i_1d(ji,jl) = zv_i_1d(ji,jl) + zv_newfra
453               ! for remapping
454               h_i_old (ji,nlay_i+1) = zv_newfra
455               eh_i_old(ji,nlay_i+1) = ze_newice(ji) * zv_newfra
456            ENDDO
457            ! --- Ice enthalpy remapping --- !
458            CALL lim_thd_ent( ze_i_1d(1:nidx,:,jl) ) 
459         ENDDO
460
461         !-----------------
462         ! Update salinity
463         !-----------------
464         DO jl = 1, jpl
465            DO ji = 1, nidx
466               zdv   = zv_i_1d(ji,jl) - zv_b(ji,jl)
467               zsmv_i_1d(ji,jl) = zsmv_i_1d(ji,jl) + zdv * zs_newice(ji)
468            END DO
469         END DO
470
471         !------------------------------------------------------------------------------!
472         ! 8) Change units for e_i
473         !------------------------------------------------------------------------------!   
474         DO jl = 1, jpl
475            DO jk = 1, nlay_i
476               DO ji = 1, nidx
477                  ze_i_1d(ji,jk,jl) = ze_i_1d(ji,jk,jl) * zv_i_1d(ji,jl) * r1_nlay_i 
478               END DO
479            END DO
480         END DO
481         !------------------------------------------------------------------------------!
482         ! 7) Change 2D vectors to 1D vectors
483         !------------------------------------------------------------------------------!
484         DO jl = 1, jpl
485            CALL tab_1d_2d( nidx, idxice(1:nidx), za_i_1d (1:nidx,jl), a_i (:,:,jl)  )
486            CALL tab_1d_2d( nidx, idxice(1:nidx), zv_i_1d (1:nidx,jl), v_i (:,:,jl)  )
487            CALL tab_1d_2d( nidx, idxice(1:nidx), zsmv_i_1d(1:nidx,jl), smv_i (:,:,jl)   )
488            DO jk = 1, nlay_i
489               CALL tab_1d_2d( nidx, idxice(1:nidx), ze_i_1d(1:nidx,jk,jl), e_i(:,:,jk,jl)  )
490            END DO
491         END DO
492         CALL tab_1d_2d( nidx, idxice(1:nidx), sfx_opw_1d(1:nidx), sfx_opw  )
493         CALL tab_1d_2d( nidx, idxice(1:nidx), wfx_opw_1d(1:nidx), wfx_opw  )
494         CALL tab_1d_2d( nidx, idxice(1:nidx), hfx_thd_1d(1:nidx), hfx_thd  )
495         CALL tab_1d_2d( nidx, idxice(1:nidx), hfx_opw_1d(1:nidx), hfx_opw  )
496         !
497      ENDIF ! nidx > 0
498      !
499      CALL wrk_dealloc( jpij, jcat )   ! integer
500      CALL wrk_dealloc( jpij, zswinew, zv_newice, za_newice, zh_newice, ze_newice, zs_newice, zo_newice )
501      CALL wrk_dealloc( jpij, zdv_res, zda_res, zat_i_1d, zv_frazb, zvrel_1d )
502      CALL wrk_dealloc( jpij,jpl, zv_b, za_b, za_i_1d, zv_i_1d, zsmv_i_1d )
503      CALL wrk_dealloc( jpij,nlay_i,jpl, ze_i_1d )
504      CALL wrk_dealloc( jpi,jpj, zvrel )
505      !
506   END SUBROUTINE lim_thd_lac
507
508#else
509   !!----------------------------------------------------------------------
510   !!   Default option                               NO  LIM3 sea-ice model
511   !!----------------------------------------------------------------------
512CONTAINS
513   SUBROUTINE lim_thd_lac           ! Empty routine
514   END SUBROUTINE lim_thd_lac
515#endif
516
517   !!======================================================================
518END MODULE limthd_lac
Note: See TracBrowser for help on using the repository browser.