[152] | 1 | MODULE albedo |
---|
| 2 | !!====================================================================== |
---|
| 3 | !! *** MODULE albedo *** |
---|
| 4 | !! Ocean forcing: bulk thermohaline forcing of the ocean (or ice) |
---|
| 5 | !!===================================================================== |
---|
[1601] | 6 | !! History : 8.0 ! 2001-04 (LIM 1.0) |
---|
| 7 | !! NEMO 1.0 ! 2003-07 (C. Ethe, G. Madec) Optimization (old name:shine) |
---|
| 8 | !! - ! 2004-11 (C. Talandier) add albedo_init |
---|
[8233] | 9 | !! - ! 2006-06 (M. Vancoppenolle) LIM 3.0 |
---|
[1601] | 10 | !! - ! 2006-08 (G. Madec) cleaning for surface module |
---|
[6416] | 11 | !! 3.6 ! 2016-01 (C. Rousset) new parameterization for sea ice albedo |
---|
[8233] | 12 | !! 4.0 ! 2017-05 (M. Vancoppenolle, O. Lecomte) Melt ponds |
---|
[152] | 13 | !!---------------------------------------------------------------------- |
---|
[1601] | 14 | |
---|
| 15 | !!---------------------------------------------------------------------- |
---|
[3625] | 16 | !! albedo_ice : albedo for ice (clear and overcast skies) |
---|
| 17 | !! albedo_oce : albedo for ocean (clear and overcast skies) |
---|
| 18 | !! albedo_init : initialisation of albedo computation |
---|
[152] | 19 | !!---------------------------------------------------------------------- |
---|
[3625] | 20 | USE phycst ! physical constants |
---|
| 21 | USE in_out_manager ! I/O manager |
---|
| 22 | USE lib_mpp ! MPP library |
---|
| 23 | USE wrk_nemo ! work arrays |
---|
| 24 | USE lib_fortran ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) |
---|
[152] | 25 | |
---|
| 26 | IMPLICIT NONE |
---|
| 27 | PRIVATE |
---|
| 28 | |
---|
[1601] | 29 | PUBLIC albedo_ice ! routine called sbcice_lim.F90 |
---|
| 30 | PUBLIC albedo_oce ! routine called by ??? |
---|
[165] | 31 | |
---|
[888] | 32 | INTEGER :: albd_init = 0 !: control flag for initialization |
---|
[6416] | 33 | |
---|
| 34 | REAL(wp) :: rmue = 0.40 ! cosine of local solar altitude |
---|
| 35 | REAL(wp) :: ralb_oce = 0.066 ! ocean or lead albedo (Pegau and Paulson, Ann. Glac. 2001) |
---|
| 36 | REAL(wp) :: c1 = 0.05 ! snow thickness (only for nn_ice_alb=0) |
---|
| 37 | REAL(wp) :: c2 = 0.10 ! " " |
---|
| 38 | REAL(wp) :: rcloud = 0.06 ! cloud effect on albedo (only-for nn_ice_alb=0) |
---|
| 39 | |
---|
[4147] | 40 | ! !!* namelist namsbc_alb |
---|
[6416] | 41 | INTEGER :: nn_ice_alb |
---|
[8233] | 42 | REAL(wp) :: rn_alb_sdry, rn_alb_smlt, rn_alb_idry, rn_alb_imlt, rn_alb_dpnd |
---|
[152] | 43 | |
---|
| 44 | !!---------------------------------------------------------------------- |
---|
[2528] | 45 | !! NEMO/OPA 3.3 , NEMO Consortium (2010) |
---|
[888] | 46 | !! $Id$ |
---|
[2715] | 47 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
---|
[152] | 48 | !!---------------------------------------------------------------------- |
---|
| 49 | CONTAINS |
---|
| 50 | |
---|
[8233] | 51 | SUBROUTINE albedo_ice( pt_ice, ph_ice, ph_snw, pafrac_pnd, ph_pnd, ld_pnd, pa_ice_cs, pa_ice_os ) |
---|
[152] | 52 | !!---------------------------------------------------------------------- |
---|
[888] | 53 | !! *** ROUTINE albedo_ice *** |
---|
[152] | 54 | !! |
---|
| 55 | !! ** Purpose : Computation of the albedo of the snow/ice system |
---|
| 56 | !! |
---|
[6416] | 57 | !! ** Method : Two schemes are available (from namelist parameter nn_ice_alb) |
---|
| 58 | !! 0: the scheme is that of Shine & Henderson-Sellers (JGR 1985) for clear-skies |
---|
| 59 | !! 1: the scheme is "home made" (for cloudy skies) and based on Brandt et al. (J. Climate 2005) |
---|
| 60 | !! and Grenfell & Perovich (JGR 2004) |
---|
[8233] | 61 | !! 2: fractional surface-based formulation of scheme 1 (NEW) |
---|
[6416] | 62 | !! Description of scheme 1: |
---|
| 63 | !! 1) Albedo dependency on ice thickness follows the findings from Brandt et al (2005) |
---|
| 64 | !! which are an update of Allison et al. (JGR 1993) ; Brandt et al. 1999 |
---|
| 65 | !! 0-5cm : linear function of ice thickness |
---|
| 66 | !! 5-150cm: log function of ice thickness |
---|
| 67 | !! > 150cm: constant |
---|
| 68 | !! 2) Albedo dependency on snow thickness follows the findings from Grenfell & Perovich (2004) |
---|
| 69 | !! i.e. it increases as -EXP(-snw_thick/0.02) during freezing and -EXP(-snw_thick/0.03) during melting |
---|
| 70 | !! 3) Albedo dependency on clouds is speculated from measurements of Grenfell and Perovich (2004) |
---|
| 71 | !! i.e. cloudy-clear albedo depend on cloudy albedo following a 2d order polynomial law |
---|
| 72 | !! 4) The needed 4 parameters are: dry and melting snow, freezing ice and bare puddled ice |
---|
[152] | 73 | !! |
---|
[6416] | 74 | !! ** Note : The parameterization from Shine & Henderson-Sellers presents several misconstructions: |
---|
| 75 | !! 1) ice albedo when ice thick. tends to 0 is different than ocean albedo |
---|
| 76 | !! 2) for small ice thick. covered with some snow (<3cm?), albedo is larger |
---|
| 77 | !! under melting conditions than under freezing conditions |
---|
| 78 | !! 3) the evolution of ice albedo as a function of ice thickness shows |
---|
| 79 | !! 3 sharp inflexion points (at 5cm, 100cm and 150cm) that look highly unrealistic |
---|
| 80 | !! |
---|
| 81 | !! References : Shine & Henderson-Sellers 1985, JGR, 90(D1), 2243-2250. |
---|
| 82 | !! Brandt et al. 2005, J. Climate, vol 18 |
---|
| 83 | !! Grenfell & Perovich 2004, JGR, vol 109 |
---|
[8233] | 84 | !! |
---|
[888] | 85 | !!---------------------------------------------------------------------- |
---|
[719] | 86 | !! |
---|
[8233] | 87 | REAL(wp), INTENT(in ), DIMENSION(:,:,:) :: pt_ice ! ice surface temperature (Kelvin) |
---|
| 88 | REAL(wp), INTENT(in ), DIMENSION(:,:,:) :: ph_ice ! sea-ice thickness |
---|
| 89 | REAL(wp), INTENT(in ), DIMENSION(:,:,:) :: ph_snw ! snow depth |
---|
| 90 | REAL(wp), INTENT(in ), DIMENSION(:,:,:) :: pafrac_pnd ! melt pond relative fraction (per unit ice area) |
---|
| 91 | REAL(wp), INTENT(in ), DIMENSION(:,:,:) :: ph_pnd ! melt pond depth |
---|
| 92 | LOGICAL , INTENT(in ) :: ld_pnd ! melt ponds radiatively active or not |
---|
| 93 | REAL(wp), INTENT( out), DIMENSION(:,:,:) :: pa_ice_cs ! albedo of ice under clear sky |
---|
| 94 | REAL(wp), INTENT( out), DIMENSION(:,:,:) :: pa_ice_os ! albedo of ice under overcast sky |
---|
| 95 | !! |
---|
| 96 | INTEGER :: ji, jj, jl ! dummy loop indices |
---|
| 97 | INTEGER :: ijpl ! number of ice categories (3rd dim of ice input arrays) |
---|
| 98 | REAL(wp) :: zswitch, z1_c1, z1_c2 |
---|
| 99 | REAL(wp) :: zhref_pnd |
---|
[6416] | 100 | REAL(wp) :: zalb_sm, zalb_sf, zalb_st ! albedo of snow melting, freezing, total |
---|
| 101 | REAL(wp), POINTER, DIMENSION(:,:,:) :: zalb, zalb_it ! intermediate variable & albedo of ice (snow free) |
---|
[8233] | 102 | !! MV MP |
---|
| 103 | REAL(wp), POINTER, DIMENSION(:,:,:) :: zalb_pnd ! ponded sea ice albedo |
---|
| 104 | REAL(wp), POINTER, DIMENSION(:,:,:) :: zalb_ice ! bare sea ice albedo |
---|
| 105 | REAL(wp), POINTER, DIMENSION(:,:,:) :: zalb_snw ! snow-covered sea ice albedo |
---|
| 106 | REAL(wp), POINTER, DIMENSION(:,:,:) :: zafrac_snw ! relative snow fraction |
---|
| 107 | REAL(wp), POINTER, DIMENSION(:,:,:) :: zafrac_ice ! relative ice fraction |
---|
| 108 | REAL(wp), POINTER, DIMENSION(:,:,:) :: zafrac_pnd ! relative ice fraction (effective) |
---|
| 109 | !! |
---|
[152] | 110 | !!--------------------------------------------------------------------- |
---|
[6416] | 111 | |
---|
| 112 | ijpl = SIZE( pt_ice, 3 ) ! number of ice categories |
---|
[152] | 113 | |
---|
[6416] | 114 | CALL wrk_alloc( jpi,jpj,ijpl, zalb, zalb_it ) |
---|
[8233] | 115 | CALL wrk_alloc( jpi,jpj,ijpl, zalb_pnd, zalb_ice, zalb_snw ) |
---|
| 116 | CALL wrk_alloc( jpi,jpj,ijpl, zalb_pnd, zafrac_snw, zafrac_ice, zafrac_pnd ) |
---|
[165] | 117 | |
---|
[888] | 118 | IF( albd_init == 0 ) CALL albedo_init ! initialization |
---|
[8233] | 119 | |
---|
| 120 | !----------------------------------------------------- |
---|
| 121 | ! Snow-free albedo (no ice thickness dependence yet) |
---|
| 122 | !----------------------------------------------------- |
---|
| 123 | ! |
---|
| 124 | ! Part common to nn_ice_alb = 0, 1, 2 |
---|
| 125 | ! |
---|
| 126 | IF ( .NOT. ld_pnd ) THEN !--- No melt ponds OR radiatively inactive melt ponds |
---|
| 127 | ! Bare ice albedo is prescribed, with implicit assumption on pond fraction and depth |
---|
| 128 | WHERE ( ph_snw == 0._wp .AND. pt_ice >= rt0_ice ) ; zalb(:,:,:) = rn_alb_imlt |
---|
| 129 | ! !!! MV I think we could replace rt0_ice by rt0 and get rid of rt0 |
---|
| 130 | ELSE WHERE ; zalb(:,:,:) = rn_alb_idry |
---|
| 131 | END WHERE |
---|
| 132 | ENDIF |
---|
| 133 | |
---|
[6416] | 134 | SELECT CASE ( nn_ice_alb ) |
---|
[2715] | 135 | |
---|
[6416] | 136 | !------------------------------------------ |
---|
| 137 | ! Shine and Henderson-Sellers (1985) |
---|
| 138 | !------------------------------------------ |
---|
[8233] | 139 | ! NB: This parameterization is based on clear sky values |
---|
| 140 | |
---|
[6416] | 141 | CASE( 0 ) |
---|
| 142 | |
---|
[8233] | 143 | ! Thickness-dependent bare ice albedo |
---|
[6416] | 144 | WHERE ( 1.5 < ph_ice ) ; zalb_it = zalb |
---|
| 145 | ELSE WHERE( 1.0 < ph_ice .AND. ph_ice <= 1.5 ) ; zalb_it = 0.472 + 2.0 * ( zalb - 0.472 ) * ( ph_ice - 1.0 ) |
---|
| 146 | ELSE WHERE( 0.05 < ph_ice .AND. ph_ice <= 1.0 ) ; zalb_it = 0.2467 + 0.7049 * ph_ice & |
---|
| 147 | & - 0.8608 * ph_ice * ph_ice & |
---|
| 148 | & + 0.3812 * ph_ice * ph_ice * ph_ice |
---|
| 149 | ELSE WHERE ; zalb_it = 0.1 + 3.6 * ph_ice |
---|
| 150 | END WHERE |
---|
[8233] | 151 | |
---|
| 152 | IF ( ld_pnd ) THEN |
---|
| 153 | ! Depth-dependent ponded ice albedo |
---|
| 154 | zhref_pnd = 0.05 ! Characteristic length scale for thickness dependence of ponded ice albedo, Lecomte et al (2015) |
---|
| 155 | zalb_pnd = rn_alb_dpnd - ( rn_alb_dpnd - zalb_it ) * EXP( - ph_pnd / zhref_pnd ) |
---|
| 156 | |
---|
| 157 | ! Snow-free ice albedo is a function of pond fraction |
---|
| 158 | WHERE ( ph_snw == 0._wp .AND. pt_ice >= rt0_ice ) ; zalb_it = zalb_it * ( 1. - pafrac_pnd ) + zalb_pnd * pafrac_pnd ; END WHERE |
---|
| 159 | ENDIF |
---|
| 160 | |
---|
[6416] | 161 | DO jl = 1, ijpl |
---|
| 162 | DO jj = 1, jpj |
---|
| 163 | DO ji = 1, jpi |
---|
[8233] | 164 | ! Freezing snow |
---|
[6416] | 165 | ! no effect of underlying ice layer IF snow thickness > c1. Albedo does not depend on snow thick if > c2 |
---|
| 166 | zswitch = 1._wp - MAX( 0._wp , SIGN( 1._wp , - ( ph_snw(ji,jj,jl) - c1 ) ) ) |
---|
| 167 | zalb_sf = ( 1._wp - zswitch ) * ( zalb_it(ji,jj,jl) & |
---|
[7813] | 168 | & + ph_snw(ji,jj,jl) * ( rn_alb_sdry - zalb_it(ji,jj,jl) ) / c1 ) & |
---|
| 169 | & + zswitch * rn_alb_sdry |
---|
[888] | 170 | |
---|
[8233] | 171 | ! Melting snow |
---|
[6416] | 172 | ! no effect of underlying ice layer. Albedo does not depend on snow thick IF > c2 |
---|
| 173 | zswitch = MAX( 0._wp , SIGN( 1._wp , ph_snw(ji,jj,jl) - c2 ) ) |
---|
[7813] | 174 | zalb_sm = ( 1._wp - zswitch ) * ( rn_alb_imlt + ph_snw(ji,jj,jl) * ( rn_alb_smlt - rn_alb_imlt ) / c2 ) & |
---|
| 175 | & + zswitch * rn_alb_smlt |
---|
[6416] | 176 | ! |
---|
[8233] | 177 | ! Snow albedo |
---|
[6416] | 178 | zswitch = MAX( 0._wp , SIGN( 1._wp , pt_ice(ji,jj,jl) - rt0_snow ) ) |
---|
| 179 | zalb_st = zswitch * zalb_sm + ( 1._wp - zswitch ) * zalb_sf |
---|
| 180 | |
---|
[8233] | 181 | ! Surface albedo |
---|
| 182 | zswitch = 1._wp - MAX( 0._wp , SIGN( 1._wp , - ph_snw(ji,jj,jl) ) ) |
---|
| 183 | pa_ice_cs(ji,jj,jl) = zswitch * zalb_st + ( 1._wp - zswitch ) * zalb_it(ji,jj,jl) |
---|
[6416] | 184 | ! |
---|
| 185 | END DO |
---|
[833] | 186 | END DO |
---|
| 187 | END DO |
---|
[6416] | 188 | |
---|
[7753] | 189 | pa_ice_os(:,:,:) = pa_ice_cs(:,:,:) + rcloud ! Oberhuber correction for overcast sky |
---|
[6416] | 190 | |
---|
| 191 | !------------------------------------------ |
---|
| 192 | ! New parameterization (2016) |
---|
| 193 | !------------------------------------------ |
---|
[8233] | 194 | ! NB: This parameterization is based on overcast skies values |
---|
| 195 | |
---|
[6416] | 196 | CASE( 1 ) |
---|
| 197 | |
---|
[8233] | 198 | ! compilation of values from literature (reference overcast sky values) |
---|
[7813] | 199 | ! rn_alb_sdry = 0.85 ! dry snow |
---|
| 200 | ! rn_alb_smlt = 0.75 ! melting snow |
---|
| 201 | ! rn_alb_idry = 0.60 ! bare frozen ice |
---|
[8233] | 202 | ! rn_alb_dpnd = 0.36 ! ponded-ice overcast albedo (Lecomte et al, 2015) |
---|
| 203 | ! ! early melt pnds 0.27, late melt ponds 0.14 Grenfell & Perovich |
---|
[6416] | 204 | ! Perovich et al 2002 (Sheba) => the only dataset for which all types of ice/snow were retrieved |
---|
[7813] | 205 | ! rn_alb_sdry = 0.85 ! dry snow |
---|
| 206 | ! rn_alb_smlt = 0.72 ! melting snow |
---|
| 207 | ! rn_alb_idry = 0.65 ! bare frozen ice |
---|
[6416] | 208 | ! Brandt et al 2005 (East Antarctica) |
---|
[7813] | 209 | ! rn_alb_sdry = 0.87 ! dry snow |
---|
| 210 | ! rn_alb_smlt = 0.82 ! melting snow |
---|
| 211 | ! rn_alb_idry = 0.54 ! bare frozen ice |
---|
[6416] | 212 | ! |
---|
[8233] | 213 | ! Computation of snow-free ice albedo |
---|
[6416] | 214 | z1_c1 = 1. / ( LOG(1.5) - LOG(0.05) ) |
---|
| 215 | z1_c2 = 1. / 0.05 |
---|
[8233] | 216 | |
---|
| 217 | ! Accounting for the ice-thickness dependency |
---|
| 218 | WHERE ( 1.5 < ph_ice ) ; zalb_it = zalb |
---|
| 219 | ELSE WHERE( 0.05 < ph_ice .AND. ph_ice <= 1.5 ) ; zalb_it = zalb + ( 0.18 - zalb ) * z1_c1 * & |
---|
[6416] | 220 | & ( LOG(1.5) - LOG(ph_ice) ) |
---|
[8233] | 221 | ELSE WHERE ; zalb_it = ralb_oce + ( 0.18 - ralb_oce ) * z1_c2 * ph_ice |
---|
[6416] | 222 | END WHERE |
---|
| 223 | |
---|
[8233] | 224 | IF ( ld_pnd ) THEN |
---|
| 225 | ! Depth-dependent ponded ice albedo |
---|
| 226 | zhref_pnd = 0.05 ! Characteristic length scale for thickness dependence of ponded ice albedo, Lecomte et al (2015) |
---|
| 227 | zalb_pnd = rn_alb_dpnd - ( rn_alb_dpnd - zalb_it ) * EXP( - ph_pnd / zhref_pnd ) |
---|
| 228 | |
---|
| 229 | ! Snow-free ice albedo is weighted mean of ponded ice and bare ice contributions |
---|
| 230 | WHERE ( ph_snw == 0._wp .AND. pt_ice >= rt0_ice ) ; zalb_it = zalb_it * ( 1. - pafrac_pnd ) + zalb_pnd * pafrac_pnd ; END WHERE |
---|
| 231 | ENDIF |
---|
| 232 | |
---|
[6416] | 233 | z1_c1 = 1. / 0.02 |
---|
| 234 | z1_c2 = 1. / 0.03 |
---|
[8233] | 235 | |
---|
| 236 | ! Overcast sky surface albedo (accounting for snow, ice melt ponds) |
---|
[6416] | 237 | DO jl = 1, ijpl |
---|
| 238 | DO jj = 1, jpj |
---|
| 239 | DO ji = 1, jpi |
---|
[8233] | 240 | ! Snow depth dependence of snow albedo |
---|
[7813] | 241 | zalb_sf = rn_alb_sdry - ( rn_alb_sdry - zalb_it(ji,jj,jl)) * EXP( - ph_snw(ji,jj,jl) * z1_c1 ); |
---|
| 242 | zalb_sm = rn_alb_smlt - ( rn_alb_smlt - zalb_it(ji,jj,jl)) * EXP( - ph_snw(ji,jj,jl) * z1_c2 ); |
---|
[6416] | 243 | |
---|
[8233] | 244 | ! Snow albedo (MV I guess we could use rt0 instead of rt0_snow) |
---|
[6416] | 245 | zswitch = MAX( 0._wp , SIGN( 1._wp , pt_ice(ji,jj,jl) - rt0_snow ) ) |
---|
| 246 | zalb_st = zswitch * zalb_sm + ( 1._wp - zswitch ) * zalb_sf |
---|
| 247 | |
---|
[8233] | 248 | ! Surface albedo |
---|
[6416] | 249 | zswitch = MAX( 0._wp , SIGN( 1._wp , - ph_snw(ji,jj,jl) ) ) |
---|
| 250 | pa_ice_os(ji,jj,jl) = ( 1._wp - zswitch ) * zalb_st + zswitch * zalb_it(ji,jj,jl) |
---|
| 251 | |
---|
| 252 | END DO |
---|
| 253 | END DO |
---|
| 254 | END DO |
---|
[8233] | 255 | |
---|
| 256 | ! Clear sky surface albedo |
---|
[6416] | 257 | pa_ice_cs = pa_ice_os - ( - 0.1010 * pa_ice_os * pa_ice_os + 0.1933 * pa_ice_os - 0.0148 ); |
---|
| 258 | |
---|
[8233] | 259 | !--------------------------------------------------- |
---|
| 260 | ! Fractional surface-based parameterization (2017) |
---|
| 261 | !--------------------------------------------------- |
---|
| 262 | CASE( 2 ) |
---|
| 263 | |
---|
| 264 | ! MV: I propose this formulation that is more elegant, and more easy to expand towards |
---|
| 265 | ! varying pond and snow fraction. |
---|
| 266 | ! Formulation 1 has issues to handle ponds and snow together that |
---|
| 267 | ! can't easily be fixed. This one handles it better, I believe. |
---|
| 268 | |
---|
| 269 | !----------------------------------------- |
---|
| 270 | ! Snow, bare ice and ponded ice fractions |
---|
| 271 | !----------------------------------------- |
---|
| 272 | ! Specific fractions (zafrac) refer to relative area covered by snow within each ice category |
---|
| 273 | |
---|
| 274 | !--- Effective pond fraction (for now, we prevent melt ponds and snow at the same time) |
---|
| 275 | zafrac_pnd = 0._wp |
---|
| 276 | IF ( ld_pnd ) THEN |
---|
| 277 | WHERE( ph_snw == 0._wp ) ; zafrac_pnd = pafrac_pnd ; END WHERE ! Snow fully "shades" melt ponds |
---|
| 278 | ENDIF |
---|
| 279 | |
---|
| 280 | !--- Specific snow fraction (for now, prescribed) |
---|
| 281 | WHERE ( ph_snw > 0._wp ) ; zafrac_snw = 1. |
---|
| 282 | ELSE WHERE ; zafrac_snw = 0. |
---|
| 283 | END WHERE |
---|
| 284 | |
---|
| 285 | !--- Specific ice fraction |
---|
| 286 | zafrac_ice = 1. - zafrac_snw - zafrac_pnd |
---|
| 287 | |
---|
| 288 | !-------------------------------------------------- |
---|
| 289 | ! Snow-covered, pond-covered, and bare ice albedos |
---|
| 290 | !-------------------------------------------------- |
---|
| 291 | ! Bare ice albedo |
---|
| 292 | z1_c1 = 1. / ( LOG(1.5) - LOG(0.05) ) |
---|
| 293 | z1_c2 = 1. / 0.05 |
---|
| 294 | WHERE ( 1.5 < ph_ice ) ; zalb_ice = zalb |
---|
| 295 | ELSE WHERE( 0.05 < ph_ice .AND. ph_ice <= 1.5 ) ; zalb_ice = zalb + ( 0.18 - zalb ) * z1_c1 * & |
---|
| 296 | & ( LOG(1.5) - LOG(ph_ice) ) |
---|
| 297 | ELSE WHERE ; zalb_ice = ralb_oce + ( 0.18 - ralb_oce ) * z1_c2 * ph_ice |
---|
| 298 | END WHERE |
---|
| 299 | |
---|
| 300 | ! Snow-covered ice albedo (freezing, melting cases) |
---|
| 301 | z1_c1 = 1. / 0.02 |
---|
| 302 | z1_c2 = 1. / 0.03 |
---|
| 303 | |
---|
| 304 | WHERE( pt_ice < rt0_snow ) ; zalb_snw = rn_alb_sdry - ( rn_alb_sdry - zalb_ice ) * EXP( - ph_snw * z1_c1 ); |
---|
| 305 | ELSE WHERE ; zalb_snw = rn_alb_smlt - ( rn_alb_smlt - zalb_ice ) * EXP( - ph_snw * z1_c2 ); |
---|
| 306 | END WHERE |
---|
| 307 | |
---|
| 308 | ! Depth-dependent ponded ice albedo |
---|
| 309 | IF ( ld_pnd ) THEN |
---|
| 310 | zhref_pnd = 0.05 ! Characteristic length scale for thickness dependence of ponded ice albedo, Lecomte et al (2015) |
---|
| 311 | zalb_pnd = rn_alb_dpnd - ( rn_alb_dpnd - zalb_ice ) * EXP( - ph_pnd / zhref_pnd ) |
---|
| 312 | ELSE |
---|
| 313 | zalb_pnd = rn_alb_dpnd |
---|
| 314 | ENDIF |
---|
| 315 | |
---|
| 316 | ! Surface albedo is weighted mean of snow, ponds and bare ice contributions |
---|
| 317 | pa_ice_os = zafrac_snw * zalb_snw + zafrac_pnd * zalb_pnd + zafrac_ice * zalb_ice |
---|
| 318 | |
---|
| 319 | pa_ice_cs = pa_ice_os - ( - 0.1010 * pa_ice_os * pa_ice_os + 0.1933 * pa_ice_os - 0.0148 ) |
---|
| 320 | |
---|
[6416] | 321 | END SELECT |
---|
[833] | 322 | |
---|
[6416] | 323 | CALL wrk_dealloc( jpi,jpj,ijpl, zalb, zalb_it ) |
---|
[8233] | 324 | CALL wrk_dealloc( jpi,jpj,ijpl, zalb_pnd, zalb_ice, zalb_snw ) |
---|
| 325 | CALL wrk_dealloc( jpi,jpj,ijpl, zalb_pnd, zafrac_snw, zafrac_ice, zafrac_pnd ) |
---|
[888] | 326 | ! |
---|
| 327 | END SUBROUTINE albedo_ice |
---|
[833] | 328 | |
---|
| 329 | |
---|
[888] | 330 | SUBROUTINE albedo_oce( pa_oce_os , pa_oce_cs ) |
---|
[152] | 331 | !!---------------------------------------------------------------------- |
---|
[888] | 332 | !! *** ROUTINE albedo_oce *** |
---|
[152] | 333 | !! |
---|
[888] | 334 | !! ** Purpose : Computation of the albedo of the ocean |
---|
| 335 | !!---------------------------------------------------------------------- |
---|
[2715] | 336 | REAL(wp), DIMENSION(:,:), INTENT(out) :: pa_oce_os ! albedo of ocean under overcast sky |
---|
| 337 | REAL(wp), DIMENSION(:,:), INTENT(out) :: pa_oce_cs ! albedo of ocean under clear sky |
---|
[152] | 338 | !! |
---|
[6416] | 339 | REAL(wp) :: zcoef |
---|
[152] | 340 | !!---------------------------------------------------------------------- |
---|
[888] | 341 | ! |
---|
[6416] | 342 | zcoef = 0.05 / ( 1.1 * rmue**1.4 + 0.15 ) ! Parameterization of Briegled and Ramanathan, 1982 |
---|
[7753] | 343 | pa_oce_cs(:,:) = zcoef |
---|
| 344 | pa_oce_os(:,:) = 0.06 ! Parameterization of Kondratyev, 1969 and Payne, 1972 |
---|
[888] | 345 | ! |
---|
| 346 | END SUBROUTINE albedo_oce |
---|
[152] | 347 | |
---|
| 348 | |
---|
[165] | 349 | SUBROUTINE albedo_init |
---|
| 350 | !!---------------------------------------------------------------------- |
---|
| 351 | !! *** ROUTINE albedo_init *** |
---|
| 352 | !! |
---|
| 353 | !! ** Purpose : initializations for the albedo parameters |
---|
| 354 | !! |
---|
[1601] | 355 | !! ** Method : Read the namelist namsbc_alb |
---|
[165] | 356 | !!---------------------------------------------------------------------- |
---|
[4147] | 357 | INTEGER :: ios ! Local integer output status for namelist read |
---|
[7813] | 358 | NAMELIST/namsbc_alb/ nn_ice_alb, rn_alb_sdry, rn_alb_smlt, rn_alb_idry , rn_alb_imlt |
---|
[719] | 359 | !!---------------------------------------------------------------------- |
---|
[1601] | 360 | ! |
---|
| 361 | albd_init = 1 ! indicate that the initialization has been done |
---|
| 362 | ! |
---|
[4147] | 363 | REWIND( numnam_ref ) ! Namelist namsbc_alb in reference namelist : Albedo parameters |
---|
| 364 | READ ( numnam_ref, namsbc_alb, IOSTAT = ios, ERR = 901) |
---|
| 365 | 901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc_alb in reference namelist', lwp ) |
---|
| 366 | |
---|
| 367 | REWIND( numnam_cfg ) ! Namelist namsbc_alb in configuration namelist : Albedo parameters |
---|
| 368 | READ ( numnam_cfg, namsbc_alb, IOSTAT = ios, ERR = 902 ) |
---|
| 369 | 902 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc_alb in configuration namelist', lwp ) |
---|
[4624] | 370 | IF(lwm) WRITE ( numond, namsbc_alb ) |
---|
[1601] | 371 | ! |
---|
| 372 | IF(lwp) THEN ! Control print |
---|
[165] | 373 | WRITE(numout,*) |
---|
[1601] | 374 | WRITE(numout,*) 'albedo : set albedo parameters' |
---|
| 375 | WRITE(numout,*) '~~~~~~~' |
---|
| 376 | WRITE(numout,*) ' Namelist namsbc_alb : albedo ' |
---|
[7813] | 377 | WRITE(numout,*) ' choose the albedo parameterization nn_ice_alb = ', nn_ice_alb |
---|
| 378 | WRITE(numout,*) ' albedo of dry snow rn_alb_sdry = ', rn_alb_sdry |
---|
| 379 | WRITE(numout,*) ' albedo of melting snow rn_alb_smlt = ', rn_alb_smlt |
---|
| 380 | WRITE(numout,*) ' albedo of dry ice rn_alb_idry = ', rn_alb_idry |
---|
| 381 | WRITE(numout,*) ' albedo of bare puddled ice rn_alb_imlt = ', rn_alb_imlt |
---|
[165] | 382 | ENDIF |
---|
[888] | 383 | ! |
---|
| 384 | END SUBROUTINE albedo_init |
---|
[719] | 385 | |
---|
[152] | 386 | !!====================================================================== |
---|
| 387 | END MODULE albedo |
---|