New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
daymod.F90 in branches/2017/dev_r8600_xios_read/NEMOGCM/NEMO/OPA_SRC/DOM – NEMO

source: branches/2017/dev_r8600_xios_read/NEMOGCM/NEMO/OPA_SRC/DOM/daymod.F90 @ 8612

Last change on this file since 8612 was 8612, checked in by andmirek, 6 years ago

#1953 read single file restart with XIOS

  • Property svn:keywords set to Id
File size: 20.1 KB
Line 
1MODULE daymod
2   !!======================================================================
3   !!                       ***  MODULE  daymod  ***
4   !! Ocean :   management of the model calendar
5   !!=====================================================================
6   !! History :  OPA  ! 1994-09  (M. Pontaud M. Imbard)  Original code
7   !!                 ! 1997-03  (O. Marti)
8   !!                 ! 1997-05  (G. Madec)
9   !!                 ! 1997-08  (M. Imbard)
10   !!   NEMO     1.0  ! 2003-09  (G. Madec)  F90 + nyear, nmonth, nday
11   !!                 ! 2004-01  (A.M. Treguier) new calculation based on adatrj
12   !!                 ! 2006-08  (G. Madec)  surface module major update
13   !!                 ! 2015-11  (D. Lea) Allow non-zero initial time of day
14   !!----------------------------------------------------------------------
15
16   !!----------------------------------------------------------------------
17   !!   day        : calendar
18   !!----------------------------------------------------------------------
19   !!                    ----------- WARNING -----------
20   !!                    -------------------------------
21   !!   sbcmod assume that the time step is dividing the number of second of
22   !!   in a day, i.e. ===> MOD( rday, rdt ) == 0
23   !!   except when user defined forcing is used (see sbcmod.F90)
24   !!----------------------------------------------------------------------
25   USE dom_oce        ! ocean space and time domain
26   USE phycst         ! physical constants
27   USE ioipsl  , ONLY :   ymds2ju      ! for calendar
28   USE trc_oce , ONLY :   l_offline   ! offline flag
29   !
30   USE in_out_manager ! I/O manager
31   USE prtctl         ! Print control
32   USE iom            !
33   USE timing         ! Timing
34   USE restart        ! restart
35   USE iom_def, ONLY : lxios_read
36
37   IMPLICIT NONE
38   PRIVATE
39
40   PUBLIC   day        ! called by step.F90
41   PUBLIC   day_init   ! called by istate.F90
42   PUBLIC   day_mth    ! Needed by TAM
43
44   INTEGER, PUBLIC ::   nsecd, nsecd05, ndt, ndt05   !: (PUBLIC for TAM)
45
46   !!----------------------------------------------------------------------
47   !! NEMO/OPA 4.0 , NEMO Consortium (2016)
48   !! $Id$
49   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
50   !!----------------------------------------------------------------------
51CONTAINS
52
53   SUBROUTINE day_init
54      !!----------------------------------------------------------------------
55      !!                   ***  ROUTINE day_init  ***
56      !!
57      !! ** Purpose :   Initialization of the calendar values to their values 1 time step before nit000
58      !!                because day will be called at the beginning of step
59      !!
60      !! ** Action  : - nyear        : current year
61      !!              - nmonth       : current month of the year nyear
62      !!              - nday         : current day of the month nmonth
63      !!              - nday_year    : current day of the year nyear
64      !!              - nsec_year    : current time step counted in second since 00h jan 1st of the current year
65      !!              - nsec_month   : current time step counted in second since 00h 1st day of the current month
66      !!              - nsec_day     : current time step counted in second since 00h of the current day
67      !!              - nsec1jan000  : second since Jan. 1st 00h of nit000 year and Jan. 1st 00h of the current year
68      !!              - nmonth_len, nyear_len, nmonth_half, nmonth_end through day_mth
69      !!----------------------------------------------------------------------
70      INTEGER  ::   inbday, idweek   ! local integers
71      REAL(wp) ::   zjul             ! local scalar
72      !!----------------------------------------------------------------------
73      !
74      ! max number of seconds between each restart
75      IF( REAL( nitend - nit000 + 1 ) * rdt > REAL( HUGE( nsec1jan000 ) ) ) THEN
76         CALL ctl_stop( 'The number of seconds between each restart exceeds the integer 4 max value: 2^31-1. ',   &
77            &           'You must do a restart at higher frequency (or remove this stop and recompile the code in I8)' )
78      ENDIF
79      nsecd   = NINT( rday       )
80      nsecd05 = NINT( 0.5 * rday )
81      ndt     = NINT(       rdt  )
82      ndt05   = NINT( 0.5 * rdt  )
83
84      IF( .NOT. l_offline )   CALL day_rst( nit000, 'READ' )
85
86      ! set the calandar from ndastp (read in restart file and namelist)
87      nyear   =   ndastp / 10000
88      nmonth  = ( ndastp - (nyear * 10000) ) / 100
89      nday    =   ndastp - (nyear * 10000) - ( nmonth * 100 )
90
91      nhour   =   nn_time0 / 100
92      nminute = ( nn_time0 - nhour * 100 )
93
94      CALL ymds2ju( nyear, nmonth, nday, nhour*3600._wp+nminute*60._wp, fjulday ) 
95      IF( ABS(fjulday - REAL(NINT(fjulday),wp)) < 0.1 / rday )   fjulday = REAL(NINT(fjulday),wp)   ! avoid truncation error
96      IF( nn_time0*3600 - ndt05 .lt. 0 ) fjulday = fjulday + 1.                    ! move back to the day at nit000 (and not at nit000 - 1)
97
98      nsec1jan000 = 0
99      CALL day_mth
100
101      IF ( nday == 0 ) THEN     !   for ex if ndastp = ndate0 - 1
102         nmonth = nmonth - 1
103         nday = nmonth_len(nmonth)
104      ENDIF
105      IF ( nmonth == 0 ) THEN   ! go at the end of previous year
106         nmonth = 12
107         nyear = nyear - 1
108         nsec1jan000 = nsec1jan000 - nsecd * nyear_len(0)
109         IF( nleapy == 1 )   CALL day_mth
110      ENDIF
111
112      ! day since january 1st
113      nday_year = nday + SUM( nmonth_len(1:nmonth - 1) )
114
115      !compute number of days between last monday and today
116      CALL ymds2ju( 1900, 01, 01, 0.0, zjul )  ! compute julian day value of 01.01.1900 (our reference that was a Monday)
117      inbday = FLOOR(fjulday - zjul)            ! compute nb day between  01.01.1900 and start of current day
118      idweek = MOD(inbday, 7)                  ! compute nb day between last monday and current day
119      IF (idweek .lt. 0) idweek=idweek+7       ! Avoid negative values for dates before 01.01.1900
120
121      ! number of seconds since the beginning of current year/month/week/day at the middle of the time-step
122      IF (nhour*3600+nminute*60-ndt05 .gt. 0) THEN
123         ! 1 timestep before current middle of first time step is still the same day
124         nsec_year  = (nday_year-1) * nsecd + nhour*3600+nminute*60 - ndt05 
125         nsec_month = (nday-1)      * nsecd + nhour*3600+nminute*60 - ndt05   
126      ELSE
127         ! 1 time step before the middle of the first time step is the previous day
128         nsec_year  = nday_year * nsecd + nhour*3600+nminute*60 - ndt05 
129         nsec_month = nday      * nsecd + nhour*3600+nminute*60 - ndt05   
130      ENDIF
131      nsec_week  = idweek    * nsecd + nhour*3600+nminute*60 - ndt05
132      nsec_day   =             nhour*3600+nminute*60 - ndt05 
133      IF( nsec_day .lt. 0 ) nsec_day = nsec_day + nsecd
134      IF( nsec_week .lt. 0 ) nsec_week = nsec_week + nsecd*7
135
136      ! control print
137      IF(lwp) WRITE(numout,'(a,i6,a,i2,a,i2,a,i8,a,i8,a,i8,a,i8)')   &
138           &                   ' =======>> 1/2 time step before the start of the run DATE Y/M/D = ',   &
139           &                   nyear, '/', nmonth, '/', nday, '  nsec_day:', nsec_day, '  nsec_week:', nsec_week, '  &
140           &                   nsec_month:', nsec_month , '  nsec_year:' , nsec_year
141
142      ! Up to now, calendar parameters are related to the end of previous run (nit000-1)
143      ! call day to set the calendar parameters at the begining of the current simulaton. needed by iom_init
144      CALL day( nit000 )
145      !
146   END SUBROUTINE day_init
147
148
149   SUBROUTINE day_mth
150      !!----------------------------------------------------------------------
151      !!                   ***  ROUTINE day_init  ***
152      !!
153      !! ** Purpose :   calendar values related to the months
154      !!
155      !! ** Action  : - nmonth_len    : length in days of the months of the current year
156      !!              - nyear_len     : length in days of the previous/current year
157      !!              - nmonth_half   : second since the beginning of the year and the halft of the months
158      !!              - nmonth_end    : second since the beginning of the year and the end of the months
159      !!----------------------------------------------------------------------
160      INTEGER  ::   jm               ! dummy loop indice
161      !!----------------------------------------------------------------------
162
163      ! length of the month of the current year (from nleapy, read in namelist)
164      IF ( nleapy < 2 ) THEN
165         nmonth_len(:) = (/ 31, 31, 28, 31, 30, 31, 30, 31, 31, 30, 31, 30, 31, 31 /)
166         nyear_len(:) = 365
167         IF ( nleapy == 1 ) THEN   ! we are using calandar with leap years
168            IF ( MOD(nyear-1, 4) == 0 .AND. ( MOD(nyear-1, 400) == 0 .OR. MOD(nyear-1, 100) /= 0 ) ) THEN
169               nyear_len(0)  = 366
170            ENDIF
171            IF ( MOD(nyear  , 4) == 0 .AND. ( MOD(nyear  , 400) == 0 .OR. MOD(nyear  , 100) /= 0 ) ) THEN
172               nmonth_len(2) = 29
173               nyear_len(1)  = 366
174            ENDIF
175            IF ( MOD(nyear+1, 4) == 0 .AND. ( MOD(nyear+1, 400) == 0 .OR. MOD(nyear+1, 100) /= 0 ) ) THEN
176               nyear_len(2)  = 366
177            ENDIF
178         ENDIF
179      ELSE
180         nmonth_len(:) = nleapy   ! all months with nleapy days per year
181         nyear_len(:) = 12 * nleapy
182      ENDIF
183
184      ! half month in second since the begining of the year:
185      ! time since Jan 1st   0     1     2    ...    11    12    13
186      !          ---------*--|--*--|--*--| ... |--*--|--*--|--*--|--------------------------------------
187      !                 <---> <---> <--->  ...  <---> <---> <--->
188      ! month number      0     1     2    ...    11    12    13
189      !
190      ! nmonth_half(jm) = rday * REAL( 0.5 * nmonth_len(jm) + SUM(nmonth_len(1:jm-1)) )
191      nmonth_half(0) = - nsecd05 * nmonth_len(0)
192      DO jm = 1, 13
193         nmonth_half(jm) = nmonth_half(jm-1) + nsecd05 * ( nmonth_len(jm-1) + nmonth_len(jm) )
194      END DO
195
196      nmonth_end(0) = 0
197      DO jm = 1, 13
198         nmonth_end(jm) = nmonth_end(jm-1) + nsecd * nmonth_len(jm)
199      END DO
200      !
201   END SUBROUTINE
202
203
204   SUBROUTINE day( kt )
205      !!----------------------------------------------------------------------
206      !!                      ***  ROUTINE day  ***
207      !!
208      !! ** Purpose :   Compute the date with a day iteration IF necessary.
209      !!
210      !! ** Method  : - ???
211      !!
212      !! ** Action  : - nyear     : current year
213      !!              - nmonth    : current month of the year nyear
214      !!              - nday      : current day of the month nmonth
215      !!              - nday_year : current day of the year nyear
216      !!              - ndastp    : = nyear*10000 + nmonth*100 + nday
217      !!              - adatrj    : date in days since the beginning of the run
218      !!              - nsec_year : current time of the year (in second since 00h, jan 1st)
219      !!----------------------------------------------------------------------
220      INTEGER, INTENT(in) ::   kt        ! ocean time-step indices
221      !
222      CHARACTER (len=25) ::   charout
223      REAL(wp)           ::   zprec      ! fraction of day corresponding to 0.1 second
224      !!----------------------------------------------------------------------
225      !
226      IF( nn_timing == 1 )  CALL timing_start('day')
227      !
228      zprec = 0.1 / rday
229      !                                                 ! New time-step
230      nsec_year  = nsec_year  + ndt
231      nsec_month = nsec_month + ndt
232      nsec_week  = nsec_week  + ndt
233      nsec_day   = nsec_day   + ndt
234      adatrj  = adatrj  + rdt / rday
235      fjulday = fjulday + rdt / rday
236      IF( ABS(fjulday - REAL(NINT(fjulday),wp)) < zprec )   fjulday = REAL(NINT(fjulday),wp)   ! avoid truncation error
237      IF( ABS(adatrj  - REAL(NINT(adatrj ),wp)) < zprec )   adatrj  = REAL(NINT(adatrj ),wp)   ! avoid truncation error
238
239      IF( nsec_day > nsecd ) THEN                       ! New day
240         !
241         nday      = nday + 1
242         nday_year = nday_year + 1
243         nsec_day  = ndt05
244         !
245         IF( nday == nmonth_len(nmonth) + 1 ) THEN      ! New month
246            nday   = 1
247            nmonth = nmonth + 1
248            nsec_month = ndt05
249            IF( nmonth == 13 ) THEN                     ! New year
250               nyear     = nyear + 1
251               nmonth    = 1
252               nday_year = 1
253               nsec_year = ndt05
254               nsec1jan000 = nsec1jan000 + nsecd * nyear_len(1)
255               IF( nleapy == 1 )   CALL day_mth
256            ENDIF
257         ENDIF
258         !
259         ndastp = nyear * 10000 + nmonth * 100 + nday   ! New date
260         !
261         !compute first day of the year in julian days
262         CALL ymds2ju( nyear, 01, 01, 0.0, fjulstartyear )
263         !
264         IF(lwp) WRITE(numout,'(a,i8,a,i4.4,a,i2.2,a,i2.2,a,i3.3)') '======>> time-step =', kt,   &
265              &   '      New day, DATE Y/M/D = ', nyear, '/', nmonth, '/', nday, '      nday_year = ', nday_year
266         IF(lwp) WRITE(numout,'(a,i8,a,i7,a,i5)') '         nsec_year = ', nsec_year,   &
267              &   '   nsec_month = ', nsec_month, '   nsec_day = ', nsec_day, '   nsec_week = ', nsec_week
268      ENDIF
269
270      IF( nsec_week > 7*nsecd )   nsec_week = ndt05     ! New week
271
272      IF(ln_ctl) THEN
273         WRITE(charout,FMT="('kt =', I4,'  d/m/y =',I2,I2,I4)") kt, nday, nmonth, nyear
274         CALL prt_ctl_info(charout)
275      ENDIF
276
277      IF( .NOT. l_offline ) CALL rst_opn( kt )               ! Open the restart file if needed and control lrst_oce
278      IF( lrst_oce         ) CALL day_rst( kt, 'WRITE' )      ! write day restart information
279      !
280      IF( nn_timing == 1 )  CALL timing_stop('day')
281      !
282   END SUBROUTINE day
283
284
285   SUBROUTINE day_rst( kt, cdrw )
286      !!---------------------------------------------------------------------
287      !!                   ***  ROUTINE ts_rst  ***
288      !!
289      !!  ** Purpose : Read or write calendar in restart file:
290      !!
291      !!  WRITE(READ) mode:
292      !!       kt        : number of time step since the begining of the experiment at the
293      !!                   end of the current(previous) run
294      !!       adatrj(0) : number of elapsed days since the begining of the experiment at the
295      !!                   end of the current(previous) run (REAL -> keep fractions of day)
296      !!       ndastp    : date at the end of the current(previous) run (coded as yyyymmdd integer)
297      !!
298      !!   According to namelist parameter nrstdt,
299      !!       nrstdt = 0  no control on the date (nit000 is  arbitrary).
300      !!       nrstdt = 1  we verify that nit000 is equal to the last
301      !!                   time step of previous run + 1.
302      !!       In both those options, the  exact duration of the experiment
303      !!       since the beginning (cumulated duration of all previous restart runs)
304      !!       is not stored in the restart and is assumed to be (nit000-1)*rdt.
305      !!       This is valid is the time step has remained constant.
306      !!
307      !!       nrstdt = 2  the duration of the experiment in days (adatrj)
308      !!                    has been stored in the restart file.
309      !!----------------------------------------------------------------------
310      INTEGER         , INTENT(in) ::   kt         ! ocean time-step
311      CHARACTER(len=*), INTENT(in) ::   cdrw       ! "READ"/"WRITE" flag
312      !
313      REAL(wp) ::   zkt, zndastp, zdayfrac, ksecs, ktime
314      INTEGER  ::   ihour, iminute
315      !!----------------------------------------------------------------------
316
317      IF( TRIM(cdrw) == 'READ' ) THEN
318
319         IF( iom_varid( numror, 'kt', ldstop = .FALSE. ) > 0 ) THEN
320            ! Get Calendar informations
321            CALL iom_get( numror, 'kt', zkt, lrxios = lxios_read )   ! last time-step of previous run
322            IF(lwp) THEN
323               WRITE(numout,*) ' *** Info read in restart : '
324               WRITE(numout,*) '   previous time-step                               : ', NINT( zkt )
325               WRITE(numout,*) ' *** restart option'
326               SELECT CASE ( nrstdt )
327               CASE ( 0 )   ;   WRITE(numout,*) ' nrstdt = 0 : no control of nit000'
328               CASE ( 1 )   ;   WRITE(numout,*) ' nrstdt = 1 : no control the date at nit000 (use ndate0 read in the namelist)'
329               CASE ( 2 )   ;   WRITE(numout,*) ' nrstdt = 2 : calendar parameters read in restart'
330               END SELECT
331               WRITE(numout,*)
332            ENDIF
333            ! Control of date
334            IF( nit000 - NINT( zkt ) /= 1 .AND. nrstdt /= 0 )                                         &
335                 &   CALL ctl_stop( ' ===>>>> : problem with nit000 for the restart',                 &
336                 &                  ' verify the restart file or rerun with nrstdt = 0 (namelist)' )
337            ! define ndastp and adatrj
338            IF ( nrstdt == 2 ) THEN
339               ! read the parameters corresponding to nit000 - 1 (last time step of previous run)
340               CALL iom_get( numror, 'ndastp', zndastp, lrxios = lxios_read )
341               ndastp = NINT( zndastp )
342               CALL iom_get( numror, 'adatrj', adatrj, lrxios = lxios_read )
343          CALL iom_get( numror, 'ntime', ktime, lrxios = lxios_read )
344          nn_time0=INT(ktime)
345               ! calculate start time in hours and minutes
346          zdayfrac=adatrj-INT(adatrj)
347          ksecs = NINT(zdayfrac*86400)        ! Nearest second to catch rounding errors in adatrj         
348          ihour = INT(ksecs/3600)
349          iminute = ksecs/60-ihour*60
350           
351               ! Add to nn_time0
352               nhour   =   nn_time0 / 100
353               nminute = ( nn_time0 - nhour * 100 )
354          nminute=nminute+iminute
355         
356          IF( nminute >= 60 ) THEN
357             nminute=nminute-60
358        nhour=nhour+1
359          ENDIF
360          nhour=nhour+ihour
361          IF( nhour >= 24 ) THEN
362        nhour=nhour-24
363             adatrj=adatrj+1
364          ENDIF         
365          nn_time0 = nhour * 100 + nminute
366          adatrj = INT(adatrj)                    ! adatrj set to integer as nn_time0 updated         
367            ELSE
368               ! parameters corresponding to nit000 - 1 (as we start the step loop with a call to day)
369               ndastp = ndate0        ! ndate0 read in the namelist in dom_nam
370               nhour   =   nn_time0 / 100
371               nminute = ( nn_time0 - nhour * 100 )
372               IF( nhour*3600+nminute*60-ndt05 .lt. 0 )  ndastp=ndastp-1      ! Start hour is specified in the namelist (default 0)
373               adatrj = ( REAL( nit000-1, wp ) * rdt ) / rday
374               ! note this is wrong if time step has changed during run
375            ENDIF
376         ELSE
377            ! parameters corresponding to nit000 - 1 (as we start the step loop with a call to day)
378            ndastp = ndate0           ! ndate0 read in the namelist in dom_nam
379            nhour   =   nn_time0 / 100
380       nminute = ( nn_time0 - nhour * 100 )
381            IF( nhour*3600+nminute*60-ndt05 .lt. 0 )  ndastp=ndastp-1      ! Start hour is specified in the namelist (default 0)
382            adatrj = ( REAL( nit000-1, wp ) * rdt ) / rday
383         ENDIF
384         IF( ABS(adatrj  - REAL(NINT(adatrj),wp)) < 0.1 / rday )   adatrj = REAL(NINT(adatrj),wp)   ! avoid truncation error
385         !
386         IF(lwp) THEN
387            WRITE(numout,*) ' *** Info used values : '
388            WRITE(numout,*) '   date ndastp                                      : ', ndastp
389            WRITE(numout,*) '   number of elapsed days since the begining of run : ', adatrj
390       WRITE(numout,*) '   nn_time0                                         : ',nn_time0
391            WRITE(numout,*)
392         ENDIF
393         !
394      ELSEIF( TRIM(cdrw) == 'WRITE' ) THEN
395         !
396         IF( kt == nitrst ) THEN
397            IF(lwp) WRITE(numout,*)
398            IF(lwp) WRITE(numout,*) 'rst_write : write oce restart file  kt =', kt
399            IF(lwp) WRITE(numout,*) '~~~~~~~'
400         ENDIF
401         ! calendar control
402         CALL iom_rstput( kt, nitrst, numrow, 'kt'     , REAL( kt    , wp) )   ! time-step
403         CALL iom_rstput( kt, nitrst, numrow, 'ndastp' , REAL( ndastp, wp) )   ! date
404         CALL iom_rstput( kt, nitrst, numrow, 'adatrj' , adatrj            )   ! number of elapsed days since
405         !                                                                     ! the begining of the run [s]
406    CALL iom_rstput( kt, nitrst, numrow, 'ntime'  , REAL( nn_time0, wp) ) ! time
407      ENDIF
408      !
409   END SUBROUTINE day_rst
410
411   !!======================================================================
412END MODULE daymod
Note: See TracBrowser for help on using the repository browser.