New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
agrif_lim3_update.F90 in branches/2017/dev_r8624_AGRIF3_VVL/NEMOGCM/NEMO/NST_SRC – NEMO

source: branches/2017/dev_r8624_AGRIF3_VVL/NEMOGCM/NEMO/NST_SRC/agrif_lim3_update.F90 @ 8965

Last change on this file since 8965 was 8901, checked in by jchanut, 7 years ago

AGRIF: Remove update frequency parameter from namelist - #1965

File size: 8.7 KB
Line 
1#define TWO_WAY
2
3MODULE agrif_lim3_update
4   !!=====================================================================================
5   !!                       ***  MODULE agrif_lim3_update ***
6   !! Nesting module :  update surface ocean boundary condition over ice from a child grid
7   !! Sea-Ice model  :  LIM 3.6 Sea ice model time-stepping
8   !!=====================================================================================
9   !! History :  2.0   !  04-2008  (F. Dupont)  initial version
10   !!            3.4   !  08-2012  (R. Benshila, C. Herbaut) update and EVP
11   !!            3.6   !  05-2016  (C. Rousset)  Add LIM3 compatibility
12   !!----------------------------------------------------------------------
13#if defined key_agrif && defined key_lim3
14   !!----------------------------------------------------------------------
15   !!   'key_lim3'  :                                 LIM 3.6 sea-ice model
16   !!   'key_agrif' :                                 AGRIF library
17   !!----------------------------------------------------------------------
18   !!   agrif_update_lim3  : update sea-ice on boundaries or total
19   !!                        child domain for velocities and ice properties
20   !!   update_tra_ice     : sea-ice properties
21   !!   update_u_ice       : zonal      ice velocity
22   !!   update_v_ice       : meridional ice velocity
23   !!----------------------------------------------------------------------
24   USE dom_oce
25   USE sbc_oce
26   USE agrif_oce
27   USE ice
28   USE agrif_ice 
29
30   IMPLICIT NONE
31   PRIVATE
32
33   PUBLIC agrif_update_lim3
34
35   !!----------------------------------------------------------------------
36   !! NEMO/NST 3.6 , LOCEAN-IPSL (2016)
37   !! $Id: agrif_lim3_update.F90 6204 2016-01-04 13:47:06Z cetlod $
38   !! Software governed by the CeCILL licence (modipsl/doc/NEMO_CeCILL.txt)
39   !!----------------------------------------------------------------------
40
41CONTAINS
42
43   SUBROUTINE agrif_update_lim3( kt )
44      !!----------------------------------------------------------------------
45      !!                     *** ROUTINE agrif_update_lim3 ***
46      !! ** Method  :   Call the hydrostaticupdate pressure at the boundary or the entire domain
47      !!
48      !! ** Action : - Update (u_ice,v_ice) and ice tracers
49      !!----------------------------------------------------------------------
50      INTEGER, INTENT(in) :: kt
51      !!
52      !!----------------------------------------------------------------------
53      !
54      !! clem: I think the update should take place each time the ocean sees the surface forcings
55      !!       (but maybe I am wrong and we should update every rhot time steps)
56      IF( ( MOD( (kt-nit000)/nn_fsbc + 1, Agrif_irhot() * Agrif_Parent(nn_fsbc) / nn_fsbc ) /=0 ) .AND. (kt /= 0) ) RETURN ! do not update if nb of child time steps differ from time refinement
57                                                                                                                           ! i.e. update only at the parent time step
58      Agrif_UseSpecialValueInUpdate = .TRUE.
59      Agrif_SpecialValueFineGrid = -9999.
60# if defined TWO_WAY
61      CALL Agrif_Update_Variable( tra_ice_id , procname = update_tra_ice  )
62      CALL Agrif_Update_Variable( u_ice_id   , procname = update_u_ice    )
63      CALL Agrif_Update_Variable( v_ice_id   , procname = update_v_ice    )
64
65!      CALL Agrif_Update_Variable( tra_ice_id , locupdate=(/0,2/), procname = update_tra_ice  )
66!      CALL Agrif_Update_Variable( u_ice_id   , locupdate=(/0,1/), procname = update_u_ice    )
67!      CALL Agrif_Update_Variable( v_ice_id   , locupdate=(/0,1/), procname = update_v_ice    )
68# endif
69      Agrif_UseSpecialValueInUpdate = .FALSE.
70      !
71   END SUBROUTINE agrif_update_lim3
72
73
74   !!------------------
75   !! Local subroutines
76   !!------------------
77   SUBROUTINE update_tra_ice( ptab, i1, i2, j1, j2, k1, k2, before )
78      !!-----------------------------------------------------------------------
79      !!                        *** ROUTINE update_tra_ice ***
80      !! ** Method  : Compute the mass properties on the fine grid and recover
81      !!              the properties per mass on the coarse grid
82      !!-----------------------------------------------------------------------
83      INTEGER , INTENT(in) :: i1, i2, j1, j2, k1, k2
84      REAL(wp), DIMENSION(i1:i2,j1:j2,k1:k2), INTENT(inout) :: ptab
85      LOGICAL , INTENT(in) :: before
86      !!
87      INTEGER  :: jk, jl, jm
88      !!-----------------------------------------------------------------------
89      ! it is ok not to multiply by e1*e2 since we conserve tracers here (same as in the ocean).
90      IF( before ) THEN
91         jm = 1
92         DO jl = 1, jpl
93            ptab(:,:,jm) = a_i  (i1:i2,j1:j2,jl) ; jm = jm + 1
94            ptab(:,:,jm) = v_i  (i1:i2,j1:j2,jl) ; jm = jm + 1
95            ptab(:,:,jm) = v_s  (i1:i2,j1:j2,jl) ; jm = jm + 1
96            ptab(:,:,jm) = smv_i(i1:i2,j1:j2,jl) ; jm = jm + 1
97            ptab(:,:,jm) = oa_i (i1:i2,j1:j2,jl) ; jm = jm + 1
98            DO jk = 1, nlay_s
99               ptab(:,:,jm) = e_s(i1:i2,j1:j2,jk,jl) ; jm = jm + 1
100            ENDDO
101            DO jk = 1, nlay_i
102               ptab(:,:,jm) = e_i(i1:i2,j1:j2,jk,jl) ; jm = jm + 1
103            ENDDO
104         ENDDO
105
106         DO jk = k1, k2
107            WHERE( tmask(i1:i2,j1:j2,1) == 0. )  ptab(:,:,jk) = -9999.
108         ENDDO
109                 
110      ELSE
111         jm = 1
112         DO jl = 1, jpl
113            a_i  (i1:i2,j1:j2,jl) = ptab(:,:,jm) * tmask(i1:i2,j1:j2,1) ; jm = jm + 1
114            v_i  (i1:i2,j1:j2,jl) = ptab(:,:,jm) * tmask(i1:i2,j1:j2,1) ; jm = jm + 1
115            v_s  (i1:i2,j1:j2,jl) = ptab(:,:,jm) * tmask(i1:i2,j1:j2,1) ; jm = jm + 1
116            smv_i(i1:i2,j1:j2,jl) = ptab(:,:,jm) * tmask(i1:i2,j1:j2,1) ; jm = jm + 1
117            oa_i (i1:i2,j1:j2,jl) = ptab(:,:,jm) * tmask(i1:i2,j1:j2,1) ; jm = jm + 1
118            DO jk = 1, nlay_s
119               e_s(i1:i2,j1:j2,jk,jl) = ptab(:,:,jm) * tmask(i1:i2,j1:j2,1) ; jm = jm + 1
120            ENDDO
121            DO jk = 1, nlay_i
122               e_i(i1:i2,j1:j2,jk,jl) = ptab(:,:,jm) * tmask(i1:i2,j1:j2,1) ; jm = jm + 1
123            ENDDO
124         ENDDO
125
126         ! integrated values
127         vt_i (i1:i2,j1:j2) = SUM( v_i(i1:i2,j1:j2,:), dim=3 )
128         vt_s (i1:i2,j1:j2) = SUM( v_s(i1:i2,j1:j2,:), dim=3 )
129         at_i (i1:i2,j1:j2) = SUM( a_i(i1:i2,j1:j2,:), dim=3 )
130         et_s(i1:i2,j1:j2)  = SUM( SUM( e_s(i1:i2,j1:j2,:,:), dim=4 ), dim=3 )
131         et_i(i1:i2,j1:j2)  = SUM( SUM( e_i(i1:i2,j1:j2,:,:), dim=4 ), dim=3 )
132         
133      ENDIF
134      !
135   END SUBROUTINE update_tra_ice
136
137
138   SUBROUTINE update_u_ice( ptab, i1, i2, j1, j2, before )
139      !!-----------------------------------------------------------------------
140      !!                        *** ROUTINE update_u_ice ***
141      !! ** Method  : Update the fluxes and recover the properties (C-grid)
142      !!-----------------------------------------------------------------------
143      INTEGER , INTENT(in) :: i1, i2, j1, j2
144      REAL(wp), DIMENSION(i1:i2,j1:j2), INTENT(inout) :: ptab
145      LOGICAL , INTENT(in) :: before
146      !!
147      REAL(wp) :: zrhoy
148      !!-----------------------------------------------------------------------
149      !
150      IF( before ) THEN
151         zrhoy = Agrif_Rhoy()
152         ptab(:,:) = e2u(i1:i2,j1:j2) * u_ice(i1:i2,j1:j2) * zrhoy
153         WHERE( umask(i1:i2,j1:j2,1) == 0. )  ptab(:,:) = -9999.
154      ELSE
155         u_ice(i1:i2,j1:j2) = ptab(:,:) / e2u(i1:i2,j1:j2) * umask(i1:i2,j1:j2,1)
156      ENDIF
157      !
158   END SUBROUTINE update_u_ice
159
160
161   SUBROUTINE update_v_ice( ptab, i1, i2, j1, j2, before )
162      !!-----------------------------------------------------------------------
163      !!                    *** ROUTINE update_v_ice ***
164      !! ** Method  : Update the fluxes and recover the properties (C-grid)
165      !!-----------------------------------------------------------------------
166      INTEGER , INTENT(in) :: i1,i2,j1,j2
167      REAL(wp), DIMENSION(i1:i2,j1:j2),  INTENT(inout) :: ptab
168      LOGICAL , INTENT(in) :: before
169      !!
170      REAL(wp) :: zrhox
171      !!-----------------------------------------------------------------------
172      !
173      IF( before ) THEN
174         zrhox = Agrif_Rhox()
175         ptab(:,:) = e1v(i1:i2,j1:j2) * v_ice(i1:i2,j1:j2) * zrhox
176         WHERE( vmask(i1:i2,j1:j2,1) == 0. )  ptab(:,:) = -9999.
177      ELSE
178         v_ice(i1:i2,j1:j2) = ptab(:,:) / e1v(i1:i2,j1:j2) * vmask(i1:i2,j1:j2,1)
179      ENDIF
180      !
181   END SUBROUTINE update_v_ice
182
183#else
184CONTAINS
185   SUBROUTINE agrif_lim3_update_empty
186      !!---------------------------------------------
187      !!   *** ROUTINE agrif_lim3_update_empty ***
188      !!---------------------------------------------
189      WRITE(*,*)  'agrif_lim3_update : You should not have seen this print! error?'
190   END SUBROUTINE agrif_lim3_update_empty
191#endif
192END MODULE agrif_lim3_update
Note: See TracBrowser for help on using the repository browser.