New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
zdfgls.F90 in branches/2017/dev_r8624_AGRIF3_VVL/NEMOGCM/NEMO/OPA_SRC/ZDF – NEMO

source: branches/2017/dev_r8624_AGRIF3_VVL/NEMOGCM/NEMO/OPA_SRC/ZDF/zdfgls.F90 @ 8762

Last change on this file since 8762 was 8762, checked in by jchanut, 6 years ago

AGRIF + vvl: Final changes, update SETTE tests (these are ok except SAS) - #1965
  • Property svn:keywords set to Id
File size: 58.2 KB
Line 
1MODULE zdfgls
2   !!======================================================================
3   !!                       ***  MODULE  zdfgls  ***
4   !! Ocean physics:  vertical mixing coefficient computed from the gls
5   !!                 turbulent closure parameterization
6   !!======================================================================
7   !! History :   3.0  !  2009-09  (G. Reffray)  Original code
8   !!             3.3  !  2010-10  (C. Bricaud)  Add in the reference
9   !!----------------------------------------------------------------------
10#if defined key_zdfgls
11   !!----------------------------------------------------------------------
12   !!   'key_zdfgls'                 Generic Length Scale vertical physics
13   !!----------------------------------------------------------------------
14   !!   zdf_gls       : update momentum and tracer Kz from a gls scheme
15   !!   zdf_gls_init  : initialization, namelist read, and parameters control
16   !!   gls_rst       : read/write gls restart in ocean restart file
17   !!----------------------------------------------------------------------
18   USE oce            ! ocean dynamics and active tracers
19   USE dom_oce        ! ocean space and time domain
20   USE domvvl         ! ocean space and time domain : variable volume layer
21   USE zdf_oce        ! ocean vertical physics
22   USE zdfbfr         ! bottom friction (only for rn_bfrz0)
23   USE sbc_oce        ! surface boundary condition: ocean
24   USE phycst         ! physical constants
25   USE zdfmxl         ! mixed layer
26   USE sbcwave ,  ONLY: hsw   ! significant wave height
27   !
28   USE lbclnk         ! ocean lateral boundary conditions (or mpp link)
29   USE lib_mpp        ! MPP manager
30   USE wrk_nemo       ! work arrays
31   USE prtctl         ! Print control
32   USE in_out_manager ! I/O manager
33   USE iom            ! I/O manager library
34   USE timing         ! Timing
35   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined)
36#if defined key_agrif
37   USE agrif_opa_interp ! Set bc on avm
38#endif
39
40   IMPLICIT NONE
41   PRIVATE
42
43   PUBLIC   zdf_gls        ! routine called in step module
44   PUBLIC   zdf_gls_init   ! routine called in opa module
45   PUBLIC   gls_rst        ! routine called in step module
46
47   LOGICAL , PUBLIC, PARAMETER ::   lk_zdfgls = .TRUE.   !: TKE vertical mixing flag
48   !
49   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   mxln    !: now mixing length
50   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   zwall   !: wall function
51   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   ustars2 !: Squared surface velocity scale at T-points
52   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   ustarb2 !: Squared bottom  velocity scale at T-points
53
54   !                              !! ** Namelist  namzdf_gls  **
55   LOGICAL  ::   ln_length_lim     ! use limit on the dissipation rate under stable stratification (Galperin et al. 1988)
56   LOGICAL  ::   ln_sigpsi         ! Activate Burchard (2003) modification for k-eps closure & wave breaking mixing
57   INTEGER  ::   nn_bc_surf        ! surface boundary condition (=0/1)
58   INTEGER  ::   nn_bc_bot         ! bottom boundary condition (=0/1)
59   INTEGER  ::   nn_z0_met         ! Method for surface roughness computation
60   INTEGER  ::   nn_stab_func      ! stability functions G88, KC or Canuto (=0/1/2)
61   INTEGER  ::   nn_clos           ! closure 0/1/2/3 MY82/k-eps/k-w/gen
62   REAL(wp) ::   rn_clim_galp      ! Holt 2008 value for k-eps: 0.267
63   REAL(wp) ::   rn_epsmin         ! minimum value of dissipation (m2/s3)
64   REAL(wp) ::   rn_emin           ! minimum value of TKE (m2/s2)
65   REAL(wp) ::   rn_charn          ! Charnock constant for surface breaking waves mixing : 1400. (standard) or 2.e5 (Stacey value)
66   REAL(wp) ::   rn_crban          ! Craig and Banner constant for surface breaking waves mixing
67   REAL(wp) ::   rn_hsro           ! Minimum surface roughness
68   REAL(wp) ::   rn_frac_hs        ! Fraction of wave height as surface roughness (if nn_z0_met > 1)
69
70   REAL(wp) ::   rcm_sf        =  0.73_wp     ! Shear free turbulence parameters
71   REAL(wp) ::   ra_sf         = -2.0_wp      ! Must be negative -2 < ra_sf < -1
72   REAL(wp) ::   rl_sf         =  0.2_wp      ! 0 <rl_sf<vkarmn   
73   REAL(wp) ::   rghmin        = -0.28_wp
74   REAL(wp) ::   rgh0          =  0.0329_wp
75   REAL(wp) ::   rghcri        =  0.03_wp
76   REAL(wp) ::   ra1           =  0.92_wp
77   REAL(wp) ::   ra2           =  0.74_wp
78   REAL(wp) ::   rb1           = 16.60_wp
79   REAL(wp) ::   rb2           = 10.10_wp         
80   REAL(wp) ::   re2           =  1.33_wp         
81   REAL(wp) ::   rl1           =  0.107_wp
82   REAL(wp) ::   rl2           =  0.0032_wp
83   REAL(wp) ::   rl3           =  0.0864_wp
84   REAL(wp) ::   rl4           =  0.12_wp
85   REAL(wp) ::   rl5           = 11.9_wp
86   REAL(wp) ::   rl6           =  0.4_wp
87   REAL(wp) ::   rl7           =  0.0_wp
88   REAL(wp) ::   rl8           =  0.48_wp
89   REAL(wp) ::   rm1           =  0.127_wp
90   REAL(wp) ::   rm2           =  0.00336_wp
91   REAL(wp) ::   rm3           =  0.0906_wp
92   REAL(wp) ::   rm4           =  0.101_wp
93   REAL(wp) ::   rm5           = 11.2_wp
94   REAL(wp) ::   rm6           =  0.4_wp
95   REAL(wp) ::   rm7           =  0.0_wp
96   REAL(wp) ::   rm8           =  0.318_wp
97   REAL(wp) ::   rtrans        =  0.1_wp
98   REAL(wp) ::   rc02, rc02r, rc03, rc04                          ! coefficients deduced from above parameters
99   REAL(wp) ::   rsbc_tke1, rsbc_tke2, rfact_tke                  !     -           -           -        -
100   REAL(wp) ::   rsbc_psi1, rsbc_psi2, rfact_psi                  !     -           -           -        -
101   REAL(wp) ::   rsbc_zs1, rsbc_zs2                               !     -           -           -        -
102   REAL(wp) ::   rc0, rc2, rc3, rf6, rcff, rc_diff                !     -           -           -        -
103   REAL(wp) ::   rs0, rs1, rs2, rs4, rs5, rs6                     !     -           -           -        -
104   REAL(wp) ::   rd0, rd1, rd2, rd3, rd4, rd5                     !     -           -           -        -
105   REAL(wp) ::   rsc_tke, rsc_psi, rpsi1, rpsi2, rpsi3, rsc_psi0  !     -           -           -        -
106   REAL(wp) ::   rpsi3m, rpsi3p, rpp, rmm, rnn                    !     -           -           -        -
107
108   !! * Substitutions
109#  include "vectopt_loop_substitute.h90"
110   !!----------------------------------------------------------------------
111   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
112   !! $Id$
113   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
114   !!----------------------------------------------------------------------
115CONTAINS
116
117   INTEGER FUNCTION zdf_gls_alloc()
118      !!----------------------------------------------------------------------
119      !!                ***  FUNCTION zdf_gls_alloc  ***
120      !!----------------------------------------------------------------------
121      ALLOCATE( mxln(jpi,jpj,jpk), zwall(jpi,jpj,jpk) ,     &
122         &      ustars2(jpi,jpj) , ustarb2(jpi,jpj)   , STAT= zdf_gls_alloc )
123         !
124      IF( lk_mpp             )   CALL mpp_sum ( zdf_gls_alloc )
125      IF( zdf_gls_alloc /= 0 )   CALL ctl_warn('zdf_gls_alloc: failed to allocate arrays')
126   END FUNCTION zdf_gls_alloc
127
128
129   SUBROUTINE zdf_gls( kt )
130      !!----------------------------------------------------------------------
131      !!                   ***  ROUTINE zdf_gls  ***
132      !!
133      !! ** Purpose :   Compute the vertical eddy viscosity and diffusivity
134      !!              coefficients using the GLS turbulent closure scheme.
135      !!----------------------------------------------------------------------
136      INTEGER, INTENT(in) ::   kt ! ocean time step
137      INTEGER  ::   ji, jj, jk, ibot, ibotm1, dir  ! dummy loop arguments
138      REAL(wp) ::   zesh2, zsigpsi, zcoef, zex1, zex2   ! local scalars
139      REAL(wp) ::   ztx2, zty2, zup, zdown, zcof        !   -      -
140      REAL(wp) ::   zratio, zrn2, zflxb, sh             !   -      -
141      REAL(wp) ::   prod, buoy, diss, zdiss, sm         !   -      -
142      REAL(wp) ::   gh, gm, shr, dif, zsqen, zav        !   -      -
143      REAL(wp), POINTER, DIMENSION(:,:  ) ::   zdep
144      REAL(wp), POINTER, DIMENSION(:,:  ) ::   zkar
145      REAL(wp), POINTER, DIMENSION(:,:  ) ::   zflxs       ! Turbulence fluxed induced by internal waves
146      REAL(wp), POINTER, DIMENSION(:,:  ) ::   zhsro       ! Surface roughness (surface waves)
147      REAL(wp), POINTER, DIMENSION(:,:,:) ::   eb          ! tke at time before
148      REAL(wp), POINTER, DIMENSION(:,:,:) ::   mxlb        ! mixing length at time before
149      REAL(wp), POINTER, DIMENSION(:,:,:) ::   shear       ! vertical shear
150      REAL(wp), POINTER, DIMENSION(:,:,:) ::   eps         ! dissipation rate
151      REAL(wp), POINTER, DIMENSION(:,:,:) ::   zwall_psi   ! Wall function use in the wb case (ln_sigpsi)
152      REAL(wp), POINTER, DIMENSION(:,:,:) ::   psi         ! psi at time now
153      REAL(wp), POINTER, DIMENSION(:,:,:) ::   z_elem_a    ! element of the first  matrix diagonal
154      REAL(wp), POINTER, DIMENSION(:,:,:) ::   z_elem_b    ! element of the second matrix diagonal
155      REAL(wp), POINTER, DIMENSION(:,:,:) ::   z_elem_c    ! element of the third  matrix diagonal
156      !!--------------------------------------------------------------------
157      !
158      IF( nn_timing == 1 )  CALL timing_start('zdf_gls')
159      !
160      CALL wrk_alloc( jpi,jpj,       zdep, zkar, zflxs, zhsro )
161      CALL wrk_alloc( jpi,jpj,jpk,   eb, mxlb, shear, eps, zwall_psi, z_elem_a, z_elem_b, z_elem_c, psi  )
162     
163      ! Preliminary computing
164
165      ustars2 = 0._wp   ;   ustarb2 = 0._wp   ;   psi  = 0._wp   ;   zwall_psi = 0._wp
166
167      IF( kt /= nit000 ) THEN   ! restore before value to compute tke
168         avt (:,:,:) = avt_k (:,:,:)
169         avm (:,:,:) = avm_k (:,:,:)
170         avmu(:,:,:) = avmu_k(:,:,:)
171         avmv(:,:,:) = avmv_k(:,:,:) 
172      ENDIF
173
174      ! Compute surface and bottom friction at T-points
175      DO jj = 2, jpjm1         
176         DO ji = fs_2, fs_jpim1   ! vector opt.         
177            !
178            ! surface friction
179            ustars2(ji,jj) = r1_rau0 * taum(ji,jj) * tmask(ji,jj,1)
180            !   
181            ! bottom friction (explicit before friction)       
182            ! Note that we chose here not to bound the friction as in dynbfr)   
183            ztx2 = (  bfrua(ji,jj)  * ub(ji,jj,mbku(ji,jj)) + bfrua(ji-1,jj) * ub(ji-1,jj,mbku(ji-1,jj))  )   &         
184               & * ( 1._wp - 0.5_wp * umask(ji,jj,1) * umask(ji-1,jj,1)  )     
185            zty2 = (  bfrva(ji,jj)  * vb(ji,jj,mbkv(ji,jj)) + bfrva(ji,jj-1) * vb(ji,jj-1,mbkv(ji,jj-1))  )   &         
186               & * ( 1._wp - 0.5_wp * vmask(ji,jj,1) * vmask(ji,jj-1,1)  )     
187            ustarb2(ji,jj) = SQRT( ztx2 * ztx2 + zty2 * zty2 ) * tmask(ji,jj,1)         
188         END DO         
189      END DO   
190
191      ! Set surface roughness length
192      SELECT CASE ( nn_z0_met )
193      !
194      CASE ( 0 )             ! Constant roughness         
195         zhsro(:,:) = rn_hsro
196      CASE ( 1 )             ! Standard Charnock formula
197         zhsro(:,:) = MAX(rsbc_zs1 * ustars2(:,:), rn_hsro)
198      CASE ( 2 )             ! Roughness formulae according to Rascle et al., Ocean Modelling (2008)
199         zdep(:,:)  = 30.*TANH(2.*0.3/(28.*SQRT(MAX(ustars2(:,:),rsmall))))             ! Wave age (eq. 10)
200         zhsro(:,:) = MAX(rsbc_zs2 * ustars2(:,:) * zdep(:,:)**1.5, rn_hsro) ! zhsro = rn_frac_hs * Hsw (eq. 11)
201      CASE ( 3 )             ! Roughness given by the wave model (coupled or read in file)
202         zhsro(:,:) = hsw(:,:)
203      END SELECT
204
205      ! Compute shear and dissipation rate
206      DO jk = 2, jpkm1
207         DO jj = 2, jpjm1
208            DO ji = fs_2, fs_jpim1   ! vector opt.
209!               avmu(ji,jj,jk) =   avmu(ji,jj,jk) &
210               avmu(ji,jj,jk) = 0.5_wp * ( avm(ji,jj,jk) + avm(ji+1,jj,jk) ) * umask(ji,jj,jk)  &
211                  &                    * ( un(ji,jj,jk-1) - un(ji,jj,jk)   )   &
212                  &                    * ( ub(ji,jj,jk-1) - ub(ji,jj,jk)   )   &
213                  &                    / (  e3uw_n(ji,jj,jk) * e3uw_b(ji,jj,jk) )
214!               avmv(ji,jj,jk) =   avmv(ji,jj,jk) &
215               avmv(ji,jj,jk) = 0.5_wp * ( avm(ji,jj,jk) + avm(ji,jj+1,jk) ) * vmask(ji,jj,jk)  & 
216                  &                    * ( vn(ji,jj,jk-1) - vn(ji,jj,jk)   )   &
217                  &                    * ( vb(ji,jj,jk-1) - vb(ji,jj,jk) )     &
218                  &                    / (  e3vw_n(ji,jj,jk) * e3vw_b(ji,jj,jk) )
219               eps(ji,jj,jk)  = rc03 * en(ji,jj,jk) * SQRT(en(ji,jj,jk)) / mxln(ji,jj,jk)
220            END DO
221         END DO
222      END DO
223      !
224      ! Lateral boundary conditions (avmu,avmv) (sign unchanged)
225      CALL lbc_lnk( avmu, 'U', 1. )   ;   CALL lbc_lnk( avmv, 'V', 1. )
226
227      ! Save tke at before time step
228      eb  (:,:,:) = en  (:,:,:)
229      mxlb(:,:,:) = mxln(:,:,:)
230
231      IF( nn_clos == 0 ) THEN    ! Mellor-Yamada
232         DO jk = 2, jpkm1
233            DO jj = 2, jpjm1 
234               DO ji = fs_2, fs_jpim1   ! vector opt.
235                  zup   = mxln(ji,jj,jk) * gdepw_n(ji,jj,mbkt(ji,jj)+1)
236                  zdown = vkarmn * gdepw_n(ji,jj,jk) * ( -gdepw_n(ji,jj,jk) + gdepw_n(ji,jj,mbkt(ji,jj)+1) )
237                  zcoef = ( zup / MAX( zdown, rsmall ) )
238                  zwall (ji,jj,jk) = ( 1._wp + re2 * zcoef*zcoef ) * tmask(ji,jj,jk)
239               END DO
240            END DO
241         END DO
242      ENDIF
243
244      !!---------------------------------!!
245      !!   Equation to prognostic k      !!
246      !!---------------------------------!!
247      !
248      ! Now Turbulent kinetic energy (output in en)
249      ! -------------------------------
250      ! Resolution of a tridiagonal linear system by a "methode de chasse"
251      ! computation from level 2 to jpkm1  (e(1) computed after and e(jpk)=0 ).
252      ! The surface boundary condition are set after
253      ! The bottom boundary condition are also set after. In standard e(bottom)=0.
254      ! z_elem_b : diagonal z_elem_c : upper diagonal z_elem_a : lower diagonal
255      ! Warning : after this step, en : right hand side of the matrix
256
257      DO jk = 2, jpkm1
258         DO jj = 2, jpjm1
259            DO ji = fs_2, fs_jpim1   ! vector opt.
260               !
261               ! shear prod. at w-point weightened by mask
262               shear(ji,jj,jk) =  ( avmu(ji-1,jj,jk) + avmu(ji,jj,jk) ) / MAX( 1.e0 , umask(ji-1,jj,jk) + umask(ji,jj,jk) )   &
263                  &             + ( avmv(ji,jj-1,jk) + avmv(ji,jj,jk) ) / MAX( 1.e0 , vmask(ji,jj-1,jk) + vmask(ji,jj,jk) )
264               !
265               ! stratif. destruction
266               buoy = - avt(ji,jj,jk) * rn2(ji,jj,jk)
267               !
268               ! shear prod. - stratif. destruction
269               diss = eps(ji,jj,jk)
270               !
271               dir = 0.5_wp + SIGN( 0.5_wp, shear(ji,jj,jk) + buoy )   ! dir =1(=0) if shear(ji,jj,jk)+buoy >0(<0)
272               !
273               zesh2 = dir*(shear(ji,jj,jk)+buoy)+(1._wp-dir)*shear(ji,jj,jk)          ! production term
274               zdiss = dir*(diss/en(ji,jj,jk))   +(1._wp-dir)*(diss-buoy)/en(ji,jj,jk) ! dissipation term
275               !
276               ! Compute a wall function from 1. to rsc_psi*zwall/rsc_psi0
277               ! Note that as long that Dirichlet boundary conditions are NOT set at the first and last levels (GOTM style)
278               ! there is no need to set a boundary condition for zwall_psi at the top and bottom boundaries.
279               ! Otherwise, this should be rsc_psi/rsc_psi0
280               IF( ln_sigpsi ) THEN
281                  zsigpsi = MIN( 1._wp, zesh2 / eps(ji,jj,jk) )     ! 0. <= zsigpsi <= 1.
282                  zwall_psi(ji,jj,jk) = rsc_psi /   & 
283                     &     (  zsigpsi * rsc_psi + (1._wp-zsigpsi) * rsc_psi0 / MAX( zwall(ji,jj,jk), 1._wp )  )
284               ELSE
285                  zwall_psi(ji,jj,jk) = 1._wp
286               ENDIF
287               !
288               ! building the matrix
289               zcof = rfact_tke * tmask(ji,jj,jk)
290               !
291               ! lower diagonal
292               z_elem_a(ji,jj,jk) = zcof * ( avm  (ji,jj,jk  ) + avm  (ji,jj,jk-1) )   &
293                  &                      / ( e3t_n(ji,jj,jk-1) * e3w_n(ji,jj,jk  ) )
294               !
295               ! upper diagonal
296               z_elem_c(ji,jj,jk) = zcof * ( avm  (ji,jj,jk+1) + avm  (ji,jj,jk  ) )   &
297                  &                      / ( e3t_n(ji,jj,jk  ) * e3w_n(ji,jj,jk) )
298               !
299               ! diagonal
300               z_elem_b(ji,jj,jk) = 1._wp - z_elem_a(ji,jj,jk) - z_elem_c(ji,jj,jk)  &
301                  &                       + rdt * zdiss * tmask(ji,jj,jk) 
302               !
303               ! right hand side in en
304               en(ji,jj,jk) = en(ji,jj,jk) + rdt * zesh2 * tmask(ji,jj,jk)
305            END DO
306         END DO
307      END DO
308      !
309      z_elem_b(:,:,jpk) = 1._wp
310      !
311      ! Set surface condition on zwall_psi (1 at the bottom)
312      zwall_psi(:,:,1) = zwall_psi(:,:,2)
313      zwall_psi(:,:,jpk) = 1.
314      !
315      ! Surface boundary condition on tke
316      ! ---------------------------------
317      !
318      SELECT CASE ( nn_bc_surf )
319      !
320      CASE ( 0 )             ! Dirichlet case
321      ! First level
322      en(:,:,1) = rc02r * ustars2(:,:) * (1._wp + rsbc_tke1)**(2._wp/3._wp)
323      en(:,:,1) = MAX(en(:,:,1), rn_emin) 
324      z_elem_a(:,:,1) = en(:,:,1)
325      z_elem_c(:,:,1) = 0._wp
326      z_elem_b(:,:,1) = 1._wp
327      !
328      ! One level below
329      en(:,:,2) = rc02r * ustars2(:,:) * (1._wp + rsbc_tke1 * ((zhsro(:,:)+gdepw_n(:,:,2)) &
330         &               / zhsro(:,:) )**(1.5_wp*ra_sf))**(2._wp/3._wp)
331      en(:,:,2) = MAX(en(:,:,2), rn_emin )
332      z_elem_a(:,:,2) = 0._wp 
333      z_elem_c(:,:,2) = 0._wp
334      z_elem_b(:,:,2) = 1._wp
335      !
336      !
337      CASE ( 1 )             ! Neumann boundary condition on d(e)/dz
338      !
339      ! Dirichlet conditions at k=1
340      en(:,:,1)       = rc02r * ustars2(:,:) * (1._wp + rsbc_tke1)**(2._wp/3._wp)
341      en(:,:,1)       = MAX(en(:,:,1), rn_emin)     
342      z_elem_a(:,:,1) = en(:,:,1)
343      z_elem_c(:,:,1) = 0._wp
344      z_elem_b(:,:,1) = 1._wp
345      !
346      ! at k=2, set de/dz=Fw
347      !cbr
348      z_elem_b(:,:,2) = z_elem_b(:,:,2) +  z_elem_a(:,:,2) ! Remove z_elem_a from z_elem_b
349      z_elem_a(:,:,2) = 0._wp
350      zkar(:,:)       = (rl_sf + (vkarmn-rl_sf)*(1.-exp(-rtrans*gdept_n(:,:,1)/zhsro(:,:)) ))
351      zflxs(:,:)      = rsbc_tke2 * ustars2(:,:)**1.5_wp * zkar(:,:) &
352          &                       * ((zhsro(:,:)+gdept_n(:,:,1)) / zhsro(:,:) )**(1.5_wp*ra_sf)
353
354      en(:,:,2) = en(:,:,2) + zflxs(:,:)/e3w_n(:,:,2)
355      !
356      !
357      END SELECT
358
359      ! Bottom boundary condition on tke
360      ! --------------------------------
361      !
362      SELECT CASE ( nn_bc_bot )
363      !
364      CASE ( 0 )             ! Dirichlet
365         !                      ! en(ibot) = u*^2 / Co2 and mxln(ibot) = rn_lmin
366         !                      ! Balance between the production and the dissipation terms
367         DO jj = 2, jpjm1
368            DO ji = fs_2, fs_jpim1   ! vector opt.
369               ibot   = mbkt(ji,jj) + 1      ! k   bottom level of w-point
370               ibotm1 = mbkt(ji,jj)          ! k-1 bottom level of w-point but >=1
371               !
372               ! Bottom level Dirichlet condition:
373               z_elem_a(ji,jj,ibot  ) = 0._wp
374               z_elem_c(ji,jj,ibot  ) = 0._wp
375               z_elem_b(ji,jj,ibot  ) = 1._wp
376               en(ji,jj,ibot  ) = MAX( rc02r * ustarb2(ji,jj), rn_emin )
377               !
378               ! Just above last level, Dirichlet condition again
379               z_elem_a(ji,jj,ibotm1) = 0._wp
380               z_elem_c(ji,jj,ibotm1) = 0._wp
381               z_elem_b(ji,jj,ibotm1) = 1._wp
382               en(ji,jj,ibotm1) = MAX( rc02r * ustarb2(ji,jj), rn_emin ) 
383            END DO
384         END DO
385         !
386      CASE ( 1 )             ! Neumman boundary condition
387         !                     
388         DO jj = 2, jpjm1
389            DO ji = fs_2, fs_jpim1   ! vector opt.
390               ibot   = mbkt(ji,jj) + 1      ! k   bottom level of w-point
391               ibotm1 = mbkt(ji,jj)          ! k-1 bottom level of w-point but >=1
392               !
393               ! Bottom level Dirichlet condition:
394               z_elem_a(ji,jj,ibot) = 0._wp
395               z_elem_c(ji,jj,ibot) = 0._wp
396               z_elem_b(ji,jj,ibot) = 1._wp
397               en(ji,jj,ibot) = MAX( rc02r * ustarb2(ji,jj), rn_emin )
398               !
399               ! Just above last level: Neumann condition
400               z_elem_b(ji,jj,ibotm1) = z_elem_b(ji,jj,ibotm1) + z_elem_c(ji,jj,ibotm1)   ! Remove z_elem_c from z_elem_b
401               z_elem_c(ji,jj,ibotm1) = 0._wp
402            END DO
403         END DO
404         !
405      END SELECT
406
407      ! Matrix inversion (en prescribed at surface and the bottom)
408      ! ----------------------------------------------------------
409      !
410      DO jk = 2, jpkm1                             ! First recurrence : Dk = Dk - Lk * Uk-1 / Dk-1
411         DO jj = 2, jpjm1
412            DO ji = fs_2, fs_jpim1    ! vector opt.
413               z_elem_b(ji,jj,jk) = z_elem_b(ji,jj,jk) - z_elem_a(ji,jj,jk) * z_elem_c(ji,jj,jk-1) / z_elem_b(ji,jj,jk-1)
414            END DO
415         END DO
416      END DO
417      DO jk = 2, jpk                               ! Second recurrence : Lk = RHSk - Lk / Dk-1 * Lk-1
418         DO jj = 2, jpjm1
419            DO ji = fs_2, fs_jpim1    ! vector opt.
420               z_elem_a(ji,jj,jk) = en(ji,jj,jk) - z_elem_a(ji,jj,jk) / z_elem_b(ji,jj,jk-1) * z_elem_a(ji,jj,jk-1)
421            END DO
422         END DO
423      END DO
424      DO jk = jpk-1, 2, -1                         ! thrid recurrence : Ek = ( Lk - Uk * Ek+1 ) / Dk
425         DO jj = 2, jpjm1
426            DO ji = fs_2, fs_jpim1    ! vector opt.
427               en(ji,jj,jk) = ( z_elem_a(ji,jj,jk) - z_elem_c(ji,jj,jk) * en(ji,jj,jk+1) ) / z_elem_b(ji,jj,jk)
428            END DO
429         END DO
430      END DO
431      !                                            ! set the minimum value of tke
432      en(:,:,:) = MAX( en(:,:,:), rn_emin )
433
434      !!----------------------------------------!!
435      !!   Solve prognostic equation for psi    !!
436      !!----------------------------------------!!
437
438      ! Set psi to previous time step value
439      !
440      SELECT CASE ( nn_clos )
441      !
442      CASE( 0 )               ! k-kl  (Mellor-Yamada)
443         DO jk = 2, jpkm1
444            DO jj = 2, jpjm1
445               DO ji = fs_2, fs_jpim1   ! vector opt.
446                  psi(ji,jj,jk)  = eb(ji,jj,jk) * mxlb(ji,jj,jk)
447               END DO
448            END DO
449         END DO
450         !
451      CASE( 1 )               ! k-eps
452         DO jk = 2, jpkm1
453            DO jj = 2, jpjm1
454               DO ji = fs_2, fs_jpim1   ! vector opt.
455                  psi(ji,jj,jk)  = eps(ji,jj,jk)
456               END DO
457            END DO
458         END DO
459         !
460      CASE( 2 )               ! k-w
461         DO jk = 2, jpkm1
462            DO jj = 2, jpjm1
463               DO ji = fs_2, fs_jpim1   ! vector opt.
464                  psi(ji,jj,jk)  = SQRT( eb(ji,jj,jk) ) / ( rc0 * mxlb(ji,jj,jk) )
465               END DO
466            END DO
467         END DO
468         !
469      CASE( 3 )               ! generic
470         DO jk = 2, jpkm1
471            DO jj = 2, jpjm1
472               DO ji = fs_2, fs_jpim1   ! vector opt.
473                  psi(ji,jj,jk)  = rc02 * eb(ji,jj,jk) * mxlb(ji,jj,jk)**rnn 
474               END DO
475            END DO
476         END DO
477         !
478      END SELECT
479      !
480      ! Now gls (output in psi)
481      ! -------------------------------
482      ! Resolution of a tridiagonal linear system by a "methode de chasse"
483      ! computation from level 2 to jpkm1  (e(1) already computed and e(jpk)=0 ).
484      ! z_elem_b : diagonal z_elem_c : upper diagonal z_elem_a : lower diagonal
485      ! Warning : after this step, en : right hand side of the matrix
486
487      DO jk = 2, jpkm1
488         DO jj = 2, jpjm1
489            DO ji = fs_2, fs_jpim1   ! vector opt.
490               !
491               ! psi / k
492               zratio = psi(ji,jj,jk) / eb(ji,jj,jk) 
493               !
494               ! psi3+ : stable : B=-KhN²<0 => N²>0 if rn2>0 dir = 1 (stable) otherwise dir = 0 (unstable)
495               dir = 0.5_wp + SIGN( 0.5_wp, rn2(ji,jj,jk) )
496               !
497               rpsi3 = dir * rpsi3m + ( 1._wp - dir ) * rpsi3p
498               !
499               ! shear prod. - stratif. destruction
500               prod = rpsi1 * zratio * shear(ji,jj,jk)
501               !
502               ! stratif. destruction
503               buoy = rpsi3 * zratio * (- avt(ji,jj,jk) * rn2(ji,jj,jk) )
504               !
505               ! shear prod. - stratif. destruction
506               diss = rpsi2 * zratio * zwall(ji,jj,jk) * eps(ji,jj,jk)
507               !
508               dir = 0.5_wp + SIGN( 0.5_wp, prod + buoy )   ! dir =1(=0) if shear(ji,jj,jk)+buoy >0(<0)
509               !
510               zesh2 = dir * ( prod + buoy )          + (1._wp - dir ) * prod                        ! production term
511               zdiss = dir * ( diss / psi(ji,jj,jk) ) + (1._wp - dir ) * (diss-buoy) / psi(ji,jj,jk) ! dissipation term
512               !                                                       
513               ! building the matrix
514               zcof = rfact_psi * zwall_psi(ji,jj,jk) * tmask(ji,jj,jk)
515               ! lower diagonal
516               z_elem_a(ji,jj,jk) = zcof * ( avm  (ji,jj,jk  ) + avm  (ji,jj,jk-1) )   &
517                  &                      / ( e3t_n(ji,jj,jk-1) * e3w_n(ji,jj,jk  ) )
518               ! upper diagonal
519               z_elem_c(ji,jj,jk) = zcof * ( avm  (ji,jj,jk+1) + avm  (ji,jj,jk  ) )   &
520                  &                      / ( e3t_n(ji,jj,jk  ) * e3w_n(ji,jj,jk) )
521               ! diagonal
522               z_elem_b(ji,jj,jk) = 1._wp - z_elem_a(ji,jj,jk) - z_elem_c(ji,jj,jk)  &
523                  &                       + rdt * zdiss * tmask(ji,jj,jk)
524               !
525               ! right hand side in psi
526               psi(ji,jj,jk) = psi(ji,jj,jk) + rdt * zesh2 * tmask(ji,jj,jk)
527            END DO
528         END DO
529      END DO
530      !
531      z_elem_b(:,:,jpk) = 1._wp
532
533      ! Surface boundary condition on psi
534      ! ---------------------------------
535      !
536      SELECT CASE ( nn_bc_surf )
537      !
538      CASE ( 0 )             ! Dirichlet boundary conditions
539      !
540      ! Surface value
541      zdep(:,:)       = zhsro(:,:) * rl_sf ! Cosmetic
542      psi (:,:,1)     = rc0**rpp * en(:,:,1)**rmm * zdep(:,:)**rnn * tmask(:,:,1)
543      z_elem_a(:,:,1) = psi(:,:,1)
544      z_elem_c(:,:,1) = 0._wp
545      z_elem_b(:,:,1) = 1._wp
546      !
547      ! One level below
548      zkar(:,:)       = (rl_sf + (vkarmn-rl_sf)*(1._wp-exp(-rtrans*gdepw_n(:,:,2)/zhsro(:,:) )))
549      zdep(:,:)       = (zhsro(:,:) + gdepw_n(:,:,2)) * zkar(:,:)
550      psi (:,:,2)     = rc0**rpp * en(:,:,2)**rmm * zdep(:,:)**rnn * tmask(:,:,1)
551      z_elem_a(:,:,2) = 0._wp
552      z_elem_c(:,:,2) = 0._wp
553      z_elem_b(:,:,2) = 1._wp
554      !
555      !
556      CASE ( 1 )             ! Neumann boundary condition on d(psi)/dz
557      !
558      ! Surface value: Dirichlet
559      zdep(:,:)       = zhsro(:,:) * rl_sf
560      psi (:,:,1)     = rc0**rpp * en(:,:,1)**rmm * zdep(:,:)**rnn * tmask(:,:,1)
561      z_elem_a(:,:,1) = psi(:,:,1)
562      z_elem_c(:,:,1) = 0._wp
563      z_elem_b(:,:,1) = 1._wp
564      !
565      ! Neumann condition at k=2
566      z_elem_b(:,:,2) = z_elem_b(:,:,2) +  z_elem_a(:,:,2) ! Remove z_elem_a from z_elem_b
567      z_elem_a(:,:,2) = 0._wp
568      !
569      ! Set psi vertical flux at the surface:
570      zkar(:,:) = rl_sf + (vkarmn-rl_sf)*(1._wp-exp(-rtrans*gdept_n(:,:,1)/zhsro(:,:) )) ! Lengh scale slope
571      zdep(:,:) = ((zhsro(:,:) + gdept_n(:,:,1)) / zhsro(:,:))**(rmm*ra_sf)
572      zflxs(:,:) = (rnn + rsbc_tke1 * (rnn + rmm*ra_sf) * zdep(:,:))*(1._wp + rsbc_tke1*zdep(:,:))**(2._wp*rmm/3._wp-1_wp)
573      zdep(:,:) =  rsbc_psi1 * (zwall_psi(:,:,1)*avm(:,:,1)+zwall_psi(:,:,2)*avm(:,:,2)) * &
574             & ustars2(:,:)**rmm * zkar(:,:)**rnn * (zhsro(:,:) + gdept_n(:,:,1))**(rnn-1.)
575      zflxs(:,:) = zdep(:,:) * zflxs(:,:)
576      psi(:,:,2) = psi(:,:,2) + zflxs(:,:) / e3w_n(:,:,2)
577
578      !   
579      !
580      END SELECT
581
582      ! Bottom boundary condition on psi
583      ! --------------------------------
584      !
585      SELECT CASE ( nn_bc_bot )
586      !
587      !
588      CASE ( 0 )             ! Dirichlet
589         !                      ! en(ibot) = u*^2 / Co2 and mxln(ibot) = vkarmn * rn_bfrz0
590         !                      ! Balance between the production and the dissipation terms
591         DO jj = 2, jpjm1
592            DO ji = fs_2, fs_jpim1   ! vector opt.
593               ibot   = mbkt(ji,jj) + 1      ! k   bottom level of w-point
594               ibotm1 = mbkt(ji,jj)          ! k-1 bottom level of w-point but >=1
595               zdep(ji,jj) = vkarmn * rn_bfrz0
596               psi (ji,jj,ibot) = rc0**rpp * en(ji,jj,ibot)**rmm * zdep(ji,jj)**rnn
597               z_elem_a(ji,jj,ibot) = 0._wp
598               z_elem_c(ji,jj,ibot) = 0._wp
599               z_elem_b(ji,jj,ibot) = 1._wp
600               !
601               ! Just above last level, Dirichlet condition again (GOTM like)
602               zdep(ji,jj) = vkarmn * ( rn_bfrz0 + e3t_n(ji,jj,ibotm1) )
603               psi (ji,jj,ibotm1) = rc0**rpp * en(ji,jj,ibot  )**rmm * zdep(ji,jj)**rnn
604               z_elem_a(ji,jj,ibotm1) = 0._wp
605               z_elem_c(ji,jj,ibotm1) = 0._wp
606               z_elem_b(ji,jj,ibotm1) = 1._wp
607            END DO
608         END DO
609         !
610      CASE ( 1 )             ! Neumman boundary condition
611         !                     
612         DO jj = 2, jpjm1
613            DO ji = fs_2, fs_jpim1   ! vector opt.
614               ibot   = mbkt(ji,jj) + 1      ! k   bottom level of w-point
615               ibotm1 = mbkt(ji,jj)          ! k-1 bottom level of w-point but >=1
616               !
617               ! Bottom level Dirichlet condition:
618               zdep(ji,jj) = vkarmn * rn_bfrz0
619               psi (ji,jj,ibot) = rc0**rpp * en(ji,jj,ibot)**rmm * zdep(ji,jj)**rnn
620               !
621               z_elem_a(ji,jj,ibot) = 0._wp
622               z_elem_c(ji,jj,ibot) = 0._wp
623               z_elem_b(ji,jj,ibot) = 1._wp
624               !
625               ! Just above last level: Neumann condition with flux injection
626               z_elem_b(ji,jj,ibotm1) = z_elem_b(ji,jj,ibotm1) + z_elem_c(ji,jj,ibotm1) ! Remove z_elem_c from z_elem_b
627               z_elem_c(ji,jj,ibotm1) = 0.
628               !
629               ! Set psi vertical flux at the bottom:
630               zdep(ji,jj) = rn_bfrz0 + 0.5_wp*e3t_n(ji,jj,ibotm1)
631               zflxb = rsbc_psi2 * ( avm(ji,jj,ibot) + avm(ji,jj,ibotm1) )   &
632                  &  * (0.5_wp*(en(ji,jj,ibot)+en(ji,jj,ibotm1)))**rmm * zdep(ji,jj)**(rnn-1._wp)
633               psi(ji,jj,ibotm1) = psi(ji,jj,ibotm1) + zflxb / e3w_n(ji,jj,ibotm1)
634            END DO
635         END DO
636         !
637      END SELECT
638
639      ! Matrix inversion
640      ! ----------------
641      !
642      DO jk = 2, jpkm1                             ! First recurrence : Dk = Dk - Lk * Uk-1 / Dk-1
643         DO jj = 2, jpjm1
644            DO ji = fs_2, fs_jpim1    ! vector opt.
645               z_elem_b(ji,jj,jk) = z_elem_b(ji,jj,jk) - z_elem_a(ji,jj,jk) * z_elem_c(ji,jj,jk-1) / z_elem_b(ji,jj,jk-1)
646            END DO
647         END DO
648      END DO
649      DO jk = 2, jpk                               ! Second recurrence : Lk = RHSk - Lk / Dk-1 * Lk-1
650         DO jj = 2, jpjm1
651            DO ji = fs_2, fs_jpim1    ! vector opt.
652               z_elem_a(ji,jj,jk) = psi(ji,jj,jk) - z_elem_a(ji,jj,jk) / z_elem_b(ji,jj,jk-1) * z_elem_a(ji,jj,jk-1)
653            END DO
654         END DO
655      END DO
656      DO jk = jpk-1, 2, -1                         ! Third recurrence : Ek = ( Lk - Uk * Ek+1 ) / Dk
657         DO jj = 2, jpjm1
658            DO ji = fs_2, fs_jpim1    ! vector opt.
659               psi(ji,jj,jk) = ( z_elem_a(ji,jj,jk) - z_elem_c(ji,jj,jk) * psi(ji,jj,jk+1) ) / z_elem_b(ji,jj,jk)
660            END DO
661         END DO
662      END DO
663
664      ! Set dissipation
665      !----------------
666
667      SELECT CASE ( nn_clos )
668      !
669      CASE( 0 )               ! k-kl  (Mellor-Yamada)
670         DO jk = 1, jpkm1
671            DO jj = 2, jpjm1
672               DO ji = fs_2, fs_jpim1   ! vector opt.
673                  eps(ji,jj,jk) = rc03 * en(ji,jj,jk) * en(ji,jj,jk) * SQRT( en(ji,jj,jk) ) / MAX( psi(ji,jj,jk), rn_epsmin)
674               END DO
675            END DO
676         END DO
677         !
678      CASE( 1 )               ! k-eps
679         DO jk = 1, jpkm1
680            DO jj = 2, jpjm1
681               DO ji = fs_2, fs_jpim1   ! vector opt.
682                  eps(ji,jj,jk) = psi(ji,jj,jk)
683               END DO
684            END DO
685         END DO
686         !
687      CASE( 2 )               ! k-w
688         DO jk = 1, jpkm1
689            DO jj = 2, jpjm1
690               DO ji = fs_2, fs_jpim1   ! vector opt.
691                  eps(ji,jj,jk) = rc04 * en(ji,jj,jk) * psi(ji,jj,jk) 
692               END DO
693            END DO
694         END DO
695         !
696      CASE( 3 )               ! generic
697         zcoef = rc0**( 3._wp  + rpp/rnn )
698         zex1  =      ( 1.5_wp + rmm/rnn )
699         zex2  = -1._wp / rnn
700         DO jk = 1, jpkm1
701            DO jj = 2, jpjm1
702               DO ji = fs_2, fs_jpim1   ! vector opt.
703                  eps(ji,jj,jk) = zcoef * en(ji,jj,jk)**zex1 * psi(ji,jj,jk)**zex2
704               END DO
705            END DO
706         END DO
707         !
708      END SELECT
709
710      ! Limit dissipation rate under stable stratification
711      ! --------------------------------------------------
712      DO jk = 1, jpkm1 ! Note that this set boundary conditions on mxln at the same time
713         DO jj = 2, jpjm1
714            DO ji = fs_2, fs_jpim1    ! vector opt.
715               ! limitation
716               eps(ji,jj,jk)  = MAX( eps(ji,jj,jk), rn_epsmin )
717               mxln(ji,jj,jk)  = rc03 * en(ji,jj,jk) * SQRT( en(ji,jj,jk) ) / eps(ji,jj,jk)
718               ! Galperin criterium (NOTE : Not required if the proper value of C3 in stable cases is calculated)
719               zrn2 = MAX( rn2(ji,jj,jk), rsmall )
720               IF (ln_length_lim) mxln(ji,jj,jk) = MIN(  rn_clim_galp * SQRT( 2._wp * en(ji,jj,jk) / zrn2 ), mxln(ji,jj,jk) )
721            END DO
722         END DO
723      END DO 
724
725      !
726      ! Stability function and vertical viscosity and diffusivity
727      ! ---------------------------------------------------------
728      !
729      SELECT CASE ( nn_stab_func )
730      !
731      CASE ( 0 , 1 )             ! Galperin or Kantha-Clayson stability functions
732         DO jk = 2, jpkm1
733            DO jj = 2, jpjm1
734               DO ji = fs_2, fs_jpim1   ! vector opt.
735                  ! zcof =  l²/q²
736                  zcof = mxlb(ji,jj,jk) * mxlb(ji,jj,jk) / ( 2._wp*eb(ji,jj,jk) )
737                  ! Gh = -N²l²/q²
738                  gh = - rn2(ji,jj,jk) * zcof
739                  gh = MIN( gh, rgh0   )
740                  gh = MAX( gh, rghmin )
741                  ! Stability functions from Kantha and Clayson (if C2=C3=0 => Galperin)
742                  sh = ra2*( 1._wp-6._wp*ra1/rb1 ) / ( 1.-3.*ra2*gh*(6.*ra1+rb2*( 1._wp-rc3 ) ) )
743                  sm = ( rb1**(-1._wp/3._wp) + ( 18._wp*ra1*ra1 + 9._wp*ra1*ra2*(1._wp-rc2) )*sh*gh ) / (1._wp-9._wp*ra1*ra2*gh)
744                  !
745                  ! Store stability function in avmu and avmv
746                  avmu(ji,jj,jk) = rc_diff * sh * tmask(ji,jj,jk)
747                  avmv(ji,jj,jk) = rc_diff * sm * tmask(ji,jj,jk)
748               END DO
749            END DO
750         END DO
751         !
752      CASE ( 2, 3 )               ! Canuto stability functions
753         DO jk = 2, jpkm1
754            DO jj = 2, jpjm1
755               DO ji = fs_2, fs_jpim1   ! vector opt.
756                  ! zcof =  l²/q²
757                  zcof = mxlb(ji,jj,jk)*mxlb(ji,jj,jk) / ( 2._wp * eb(ji,jj,jk) )
758                  ! Gh = -N²l²/q²
759                  gh = - rn2(ji,jj,jk) * zcof
760                  gh = MIN( gh, rgh0   )
761                  gh = MAX( gh, rghmin )
762                  gh = gh * rf6
763                  ! Gm =  M²l²/q² Shear number
764                  shr = shear(ji,jj,jk) / MAX( avm(ji,jj,jk), rsmall )
765                  gm = MAX( shr * zcof , 1.e-10 )
766                  gm = gm * rf6
767                  gm = MIN ( (rd0 - rd1*gh + rd3*gh*gh) / (rd2-rd4*gh) , gm )
768                  ! Stability functions from Canuto
769                  rcff = rd0 - rd1*gh +rd2*gm + rd3*gh*gh - rd4*gh*gm + rd5*gm*gm
770                  sm = (rs0 - rs1*gh + rs2*gm) / rcff
771                  sh = (rs4 - rs5*gh + rs6*gm) / rcff
772                  !
773                  ! Store stability function in avmu and avmv
774                  avmu(ji,jj,jk) = rc_diff * sh * tmask(ji,jj,jk)
775                  avmv(ji,jj,jk) = rc_diff * sm * tmask(ji,jj,jk)
776               END DO
777            END DO
778         END DO
779         !
780      END SELECT
781
782      ! Boundary conditions on stability functions for momentum (Neumann):
783      ! Lines below are useless if GOTM style Dirichlet conditions are used
784
785      avmv(:,:,1) = avmv(:,:,2)
786
787      DO jj = 2, jpjm1
788         DO ji = fs_2, fs_jpim1   ! vector opt.
789            avmv(ji,jj,mbkt(ji,jj)+1) = avmv(ji,jj,mbkt(ji,jj))
790         END DO
791      END DO
792
793      ! Compute diffusivities/viscosities
794      ! The computation below could be restrained to jk=2 to jpkm1 if GOTM style Dirichlet conditions are used
795      DO jk = 1, jpk
796         DO jj = 2, jpjm1
797            DO ji = fs_2, fs_jpim1   ! vector opt.
798               zsqen         = SQRT( 2._wp * en(ji,jj,jk) ) * mxln(ji,jj,jk)
799               zav           = zsqen * avmu(ji,jj,jk)
800               avt(ji,jj,jk) = MAX( zav, avtb(jk) )*tmask(ji,jj,jk) ! apply mask for zdfmxl routine
801               zav           = zsqen * avmv(ji,jj,jk)
802               avm(ji,jj,jk) = MAX( zav, avmb(jk) ) ! Note that avm is not masked at the surface and the bottom
803            END DO
804         END DO
805      END DO
806      !
807      ! Lateral boundary conditions (sign unchanged)
808      avt(:,:,1)  = 0._wp
809      !
810#if defined key_agrif 
811      CALL Agrif_avm 
812#endif
813      !
814      CALL lbc_lnk( avm, 'W', 1. )   ;   CALL lbc_lnk( avt, 'W', 1. )
815
816      DO jk = 2, jpkm1            !* vertical eddy viscosity at u- and v-points
817         DO jj = 2, jpjm1
818            DO ji = fs_2, fs_jpim1   ! vector opt.
819               avmu(ji,jj,jk) = 0.5 * ( avm(ji,jj,jk) + avm(ji+1,jj  ,jk) ) * umask(ji,jj,jk)
820               avmv(ji,jj,jk) = 0.5 * ( avm(ji,jj,jk) + avm(ji  ,jj+1,jk) ) * vmask(ji,jj,jk)
821            END DO
822         END DO
823      END DO
824      avmu(:,:,1) = 0._wp             ;   avmv(:,:,1) = 0._wp                 ! set surface to zero
825      CALL lbc_lnk( avmu, 'U', 1. )   ;   CALL lbc_lnk( avmv, 'V', 1. )       ! Lateral boundary conditions
826
827      IF(ln_ctl) THEN
828         CALL prt_ctl( tab3d_1=en  , clinfo1=' gls  - e: ', tab3d_2=avt, clinfo2=' t: ', ovlap=1, kdim=jpk)
829         CALL prt_ctl( tab3d_1=avmu, clinfo1=' gls  - u: ', mask1=umask,                   &
830            &          tab3d_2=avmv, clinfo2=       ' v: ', mask2=vmask, ovlap=1, kdim=jpk )
831      ENDIF
832      !
833      avt_k (:,:,:) = avt (:,:,:)
834      avm_k (:,:,:) = avm (:,:,:)
835      avmu_k(:,:,:) = avmu(:,:,:)
836      avmv_k(:,:,:) = avmv(:,:,:)
837      !
838      CALL wrk_dealloc( jpi,jpj,       zdep, zkar, zflxs, zhsro )
839      CALL wrk_dealloc( jpi,jpj,jpk,   eb, mxlb, shear, eps, zwall_psi, z_elem_a, z_elem_b, z_elem_c, psi )
840      !
841      IF( nn_timing == 1 )  CALL timing_stop('zdf_gls')
842      !
843      !
844   END SUBROUTINE zdf_gls
845
846
847   SUBROUTINE zdf_gls_init
848      !!----------------------------------------------------------------------
849      !!                  ***  ROUTINE zdf_gls_init  ***
850      !!                     
851      !! ** Purpose :   Initialization of the vertical eddy diffivity and
852      !!      viscosity when using a gls turbulent closure scheme
853      !!
854      !! ** Method  :   Read the namzdf_gls namelist and check the parameters
855      !!      called at the first timestep (nit000)
856      !!
857      !! ** input   :   Namlist namzdf_gls
858      !!
859      !! ** Action  :   Increase by 1 the nstop flag is setting problem encounter
860      !!
861      !!----------------------------------------------------------------------
862      USE dynzdf_exp
863      USE trazdf_exp
864      !
865      INTEGER ::   jk    ! dummy loop indices
866      INTEGER ::   ios   ! Local integer output status for namelist read
867      REAL(wp)::   zcr   ! local scalar
868      !!
869      NAMELIST/namzdf_gls/rn_emin, rn_epsmin, ln_length_lim, &
870         &            rn_clim_galp, ln_sigpsi, rn_hsro,      &
871         &            rn_crban, rn_charn, rn_frac_hs,        &
872         &            nn_bc_surf, nn_bc_bot, nn_z0_met,      &
873         &            nn_stab_func, nn_clos
874      !!----------------------------------------------------------
875      !
876      IF( nn_timing == 1 )  CALL timing_start('zdf_gls_init')
877      !
878      REWIND( numnam_ref )              ! Namelist namzdf_gls in reference namelist : Vertical eddy diffivity and viscosity using gls turbulent closure scheme
879      READ  ( numnam_ref, namzdf_gls, IOSTAT = ios, ERR = 901)
880901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namzdf_gls in reference namelist', lwp )
881
882      REWIND( numnam_cfg )              ! Namelist namzdf_gls in configuration namelist : Vertical eddy diffivity and viscosity using gls turbulent closure scheme
883      READ  ( numnam_cfg, namzdf_gls, IOSTAT = ios, ERR = 902 )
884902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namzdf_gls in configuration namelist', lwp )
885      IF(lwm) WRITE ( numond, namzdf_gls )
886
887      IF(lwp) THEN                     !* Control print
888         WRITE(numout,*)
889         WRITE(numout,*) 'zdf_gls_init : gls turbulent closure scheme'
890         WRITE(numout,*) '~~~~~~~~~~~~'
891         WRITE(numout,*) '   Namelist namzdf_gls : set gls mixing parameters'
892         WRITE(numout,*) '      minimum value of en                           rn_emin        = ', rn_emin
893         WRITE(numout,*) '      minimum value of eps                          rn_epsmin      = ', rn_epsmin
894         WRITE(numout,*) '      Limit dissipation rate under stable stratif.  ln_length_lim  = ', ln_length_lim
895         WRITE(numout,*) '      Galperin limit (Standard: 0.53, Holt: 0.26)   rn_clim_galp   = ', rn_clim_galp
896         WRITE(numout,*) '      TKE Surface boundary condition                nn_bc_surf     = ', nn_bc_surf
897         WRITE(numout,*) '      TKE Bottom boundary condition                 nn_bc_bot      = ', nn_bc_bot
898         WRITE(numout,*) '      Modify psi Schmidt number (wb case)           ln_sigpsi      = ', ln_sigpsi
899         WRITE(numout,*) '      Craig and Banner coefficient                  rn_crban       = ', rn_crban
900         WRITE(numout,*) '      Charnock coefficient                          rn_charn       = ', rn_charn
901         WRITE(numout,*) '      Surface roughness formula                     nn_z0_met      = ', nn_z0_met
902         WRITE(numout,*) '      Wave height frac. (used if nn_z0_met=2)       rn_frac_hs     = ', rn_frac_hs
903         WRITE(numout,*) '      Stability functions                           nn_stab_func   = ', nn_stab_func
904         WRITE(numout,*) '      Type of closure                               nn_clos        = ', nn_clos
905         WRITE(numout,*) '      Surface roughness (m)                         rn_hsro        = ', rn_hsro
906         WRITE(numout,*) '      Bottom roughness (m) (nambfr namelist)        rn_bfrz0       = ', rn_bfrz0
907      ENDIF
908
909      !                                !* allocate gls arrays
910      IF( zdf_gls_alloc() /= 0 )   CALL ctl_stop( 'STOP', 'zdf_gls_init : unable to allocate arrays' )
911
912      !                                !* Check of some namelist values
913      IF( nn_bc_surf < 0 .OR. nn_bc_surf > 1 ) CALL ctl_stop( 'zdf_gls_init: bad flag: nn_bc_surf is 0 or 1' )
914      IF( nn_bc_surf < 0 .OR. nn_bc_surf > 1 ) CALL ctl_stop( 'zdf_gls_init: bad flag: nn_bc_surf is 0 or 1' )
915      IF( nn_z0_met < 0 .OR. nn_z0_met > 3 ) CALL ctl_stop( 'zdf_gls_init: bad flag: nn_z0_met is 0, 1, 2 or 3' )
916      IF( nn_z0_met == 3 .AND. .NOT.ln_wave ) CALL ctl_stop( 'zdf_gls_init: nn_z0_met=3 requires ln_wave=T' )
917      IF( nn_stab_func  < 0 .OR. nn_stab_func  > 3 ) CALL ctl_stop( 'zdf_gls_init: bad flag: nn_stab_func is 0, 1, 2 and 3' )
918      IF( nn_clos       < 0 .OR. nn_clos       > 3 ) CALL ctl_stop( 'zdf_gls_init: bad flag: nn_clos is 0, 1, 2 or 3' )
919
920      SELECT CASE ( nn_clos )          !* set the parameters for the chosen closure
921      !
922      CASE( 0 )                              ! k-kl  (Mellor-Yamada)
923         !
924         IF(lwp) WRITE(numout,*) 'The choosen closure is k-kl closed to the classical Mellor-Yamada'
925         rpp     = 0._wp
926         rmm     = 1._wp
927         rnn     = 1._wp
928         rsc_tke = 1.96_wp
929         rsc_psi = 1.96_wp
930         rpsi1   = 0.9_wp
931         rpsi3p  = 1._wp
932         rpsi2   = 0.5_wp
933         !
934         SELECT CASE ( nn_stab_func )
935         CASE( 0, 1 )   ;   rpsi3m = 2.53_wp       ! G88 or KC stability functions
936         CASE( 2 )      ;   rpsi3m = 2.62_wp       ! Canuto A stability functions
937         CASE( 3 )      ;   rpsi3m = 2.38          ! Canuto B stability functions (caution : constant not identified)
938         END SELECT
939         !
940      CASE( 1 )                              ! k-eps
941         !
942         IF(lwp) WRITE(numout,*) 'The choosen closure is k-eps'
943         rpp     =  3._wp
944         rmm     =  1.5_wp
945         rnn     = -1._wp
946         rsc_tke =  1._wp
947         rsc_psi =  1.2_wp  ! Schmidt number for psi
948         rpsi1   =  1.44_wp
949         rpsi3p  =  1._wp
950         rpsi2   =  1.92_wp
951         !
952         SELECT CASE ( nn_stab_func )
953         CASE( 0, 1 )   ;   rpsi3m = -0.52_wp      ! G88 or KC stability functions
954         CASE( 2 )      ;   rpsi3m = -0.629_wp     ! Canuto A stability functions
955         CASE( 3 )      ;   rpsi3m = -0.566        ! Canuto B stability functions
956         END SELECT
957         !
958      CASE( 2 )                              ! k-omega
959         !
960         IF(lwp) WRITE(numout,*) 'The choosen closure is k-omega'
961         rpp     = -1._wp
962         rmm     =  0.5_wp
963         rnn     = -1._wp
964         rsc_tke =  2._wp
965         rsc_psi =  2._wp
966         rpsi1   =  0.555_wp
967         rpsi3p  =  1._wp
968         rpsi2   =  0.833_wp
969         !
970         SELECT CASE ( nn_stab_func )
971         CASE( 0, 1 )   ;   rpsi3m = -0.58_wp       ! G88 or KC stability functions
972         CASE( 2 )      ;   rpsi3m = -0.64_wp       ! Canuto A stability functions
973         CASE( 3 )      ;   rpsi3m = -0.64_wp       ! Canuto B stability functions caution : constant not identified)
974         END SELECT
975         !
976      CASE( 3 )                              ! generic
977         !
978         IF(lwp) WRITE(numout,*) 'The choosen closure is generic'
979         rpp     = 2._wp
980         rmm     = 1._wp
981         rnn     = -0.67_wp
982         rsc_tke = 0.8_wp
983         rsc_psi = 1.07_wp
984         rpsi1   = 1._wp
985         rpsi3p  = 1._wp
986         rpsi2   = 1.22_wp
987         !
988         SELECT CASE ( nn_stab_func )
989         CASE( 0, 1 )   ;   rpsi3m = 0.1_wp         ! G88 or KC stability functions
990         CASE( 2 )      ;   rpsi3m = 0.05_wp        ! Canuto A stability functions
991         CASE( 3 )      ;   rpsi3m = 0.05_wp        ! Canuto B stability functions caution : constant not identified)
992         END SELECT
993         !
994      END SELECT
995
996      !
997      SELECT CASE ( nn_stab_func )     !* set the parameters of the stability functions
998      !
999      CASE ( 0 )                             ! Galperin stability functions
1000         !
1001         IF(lwp) WRITE(numout,*) 'Stability functions from Galperin'
1002         rc2     =  0._wp
1003         rc3     =  0._wp
1004         rc_diff =  1._wp
1005         rc0     =  0.5544_wp
1006         rcm_sf  =  0.9884_wp
1007         rghmin  = -0.28_wp
1008         rgh0    =  0.0233_wp
1009         rghcri  =  0.02_wp
1010         !
1011      CASE ( 1 )                             ! Kantha-Clayson stability functions
1012         !
1013         IF(lwp) WRITE(numout,*) 'Stability functions from Kantha-Clayson'
1014         rc2     =  0.7_wp
1015         rc3     =  0.2_wp
1016         rc_diff =  1._wp
1017         rc0     =  0.5544_wp
1018         rcm_sf  =  0.9884_wp
1019         rghmin  = -0.28_wp
1020         rgh0    =  0.0233_wp
1021         rghcri  =  0.02_wp
1022         !
1023      CASE ( 2 )                             ! Canuto A stability functions
1024         !
1025         IF(lwp) WRITE(numout,*) 'Stability functions from Canuto A'
1026         rs0 = 1.5_wp * rl1 * rl5*rl5
1027         rs1 = -rl4*(rl6+rl7) + 2._wp*rl4*rl5*(rl1-(1._wp/3._wp)*rl2-rl3) + 1.5_wp*rl1*rl5*rl8
1028         rs2 = -(3._wp/8._wp) * rl1*(rl6*rl6-rl7*rl7)
1029         rs4 = 2._wp * rl5
1030         rs5 = 2._wp * rl4
1031         rs6 = (2._wp/3._wp) * rl5 * ( 3._wp*rl3*rl3 - rl2*rl2 ) - 0.5_wp * rl5*rl1 * (3._wp*rl3-rl2)   &
1032            &                                                    + 0.75_wp * rl1 * ( rl6 - rl7 )
1033         rd0 = 3._wp * rl5*rl5
1034         rd1 = rl5 * ( 7._wp*rl4 + 3._wp*rl8 )
1035         rd2 = rl5*rl5 * ( 3._wp*rl3*rl3 - rl2*rl2 ) - 0.75_wp*(rl6*rl6 - rl7*rl7 )
1036         rd3 = rl4 * ( 4._wp*rl4 + 3._wp*rl8)
1037         rd4 = rl4 * ( rl2 * rl6 - 3._wp*rl3*rl7 - rl5*(rl2*rl2 - rl3*rl3 ) ) + rl5*rl8 * ( 3._wp*rl3*rl3 - rl2*rl2 )
1038         rd5 = 0.25_wp * ( rl2*rl2 - 3._wp *rl3*rl3 ) * ( rl6*rl6 - rl7*rl7 )
1039         rc0 = 0.5268_wp
1040         rf6 = 8._wp / (rc0**6._wp)
1041         rc_diff = SQRT(2._wp) / (rc0**3._wp)
1042         rcm_sf  =  0.7310_wp
1043         rghmin  = -0.28_wp
1044         rgh0    =  0.0329_wp
1045         rghcri  =  0.03_wp
1046         !
1047      CASE ( 3 )                             ! Canuto B stability functions
1048         !
1049         IF(lwp) WRITE(numout,*) 'Stability functions from Canuto B'
1050         rs0 = 1.5_wp * rm1 * rm5*rm5
1051         rs1 = -rm4 * (rm6+rm7) + 2._wp * rm4*rm5*(rm1-(1._wp/3._wp)*rm2-rm3) + 1.5_wp * rm1*rm5*rm8
1052         rs2 = -(3._wp/8._wp) * rm1 * (rm6*rm6-rm7*rm7 )
1053         rs4 = 2._wp * rm5
1054         rs5 = 2._wp * rm4
1055         rs6 = (2._wp/3._wp) * rm5 * (3._wp*rm3*rm3-rm2*rm2) - 0.5_wp * rm5*rm1*(3._wp*rm3-rm2) + 0.75_wp * rm1*(rm6-rm7)
1056         rd0 = 3._wp * rm5*rm5
1057         rd1 = rm5 * (7._wp*rm4 + 3._wp*rm8)
1058         rd2 = rm5*rm5 * (3._wp*rm3*rm3 - rm2*rm2) - 0.75_wp * (rm6*rm6 - rm7*rm7)
1059         rd3 = rm4 * ( 4._wp*rm4 + 3._wp*rm8 )
1060         rd4 = rm4 * ( rm2*rm6 -3._wp*rm3*rm7 - rm5*(rm2*rm2 - rm3*rm3) ) + rm5 * rm8 * ( 3._wp*rm3*rm3 - rm2*rm2 )
1061         rd5 = 0.25_wp * ( rm2*rm2 - 3._wp*rm3*rm3 ) * ( rm6*rm6 - rm7*rm7 )
1062         rc0 = 0.5268_wp            !!       rc0 = 0.5540_wp (Warner ...) to verify !
1063         rf6 = 8._wp / ( rc0**6._wp )
1064         rc_diff = SQRT(2._wp)/(rc0**3.)
1065         rcm_sf  =  0.7470_wp
1066         rghmin  = -0.28_wp
1067         rgh0    =  0.0444_wp
1068         rghcri  =  0.0414_wp
1069         !
1070      END SELECT
1071   
1072      !                                !* Set Schmidt number for psi diffusion in the wave breaking case
1073      !                                     ! See Eq. (13) of Carniel et al, OM, 30, 225-239, 2009
1074      !                                     !  or Eq. (17) of Burchard, JPO, 31, 3133-3145, 2001
1075      IF( ln_sigpsi ) THEN
1076         ra_sf = -1.5 ! Set kinetic energy slope, then deduce rsc_psi and rl_sf
1077         ! Verification: retrieve Burchard (2001) results by uncomenting the line below:
1078         ! Note that the results depend on the value of rn_cm_sf which is constant (=rc0) in his work
1079         ! ra_sf = -SQRT(2./3.*rc0**3./rn_cm_sf*rn_sc_tke)/vkarmn
1080         rsc_psi0 = rsc_tke/(24.*rpsi2)*(-1.+(4.*rnn + ra_sf*(1.+4.*rmm))**2./(ra_sf**2.))
1081      ELSE
1082         rsc_psi0 = rsc_psi
1083      ENDIF
1084 
1085      !                                !* Shear free turbulence parameters
1086      !
1087      ra_sf  = -4._wp*rnn*SQRT(rsc_tke) / ( (1._wp+4._wp*rmm)*SQRT(rsc_tke) &
1088               &                              - SQRT(rsc_tke + 24._wp*rsc_psi0*rpsi2 ) )
1089
1090      IF ( rn_crban==0._wp ) THEN
1091         rl_sf = vkarmn
1092      ELSE
1093         rl_sf = rc0 * SQRT(rc0/rcm_sf) * SQRT( ( (1._wp + 4._wp*rmm + 8._wp*rmm**2_wp)*rsc_tke          &
1094                 &                                       + 12._wp * rsc_psi0*rpsi2 - (1._wp + 4._wp*rmm) &
1095                 &                                                *SQRT(rsc_tke*(rsc_tke                 &
1096                 &                                                   + 24._wp*rsc_psi0*rpsi2)) )         &
1097                 &                                         /(12._wp*rnn**2.)                             &
1098                 &                                       )
1099      ENDIF
1100
1101      !
1102      IF(lwp) THEN                     !* Control print
1103         WRITE(numout,*)
1104         WRITE(numout,*) 'Limit values'
1105         WRITE(numout,*) '~~~~~~~~~~~~'
1106         WRITE(numout,*) 'Parameter  m = ',rmm
1107         WRITE(numout,*) 'Parameter  n = ',rnn
1108         WRITE(numout,*) 'Parameter  p = ',rpp
1109         WRITE(numout,*) 'rpsi1   = ',rpsi1
1110         WRITE(numout,*) 'rpsi2   = ',rpsi2
1111         WRITE(numout,*) 'rpsi3m  = ',rpsi3m
1112         WRITE(numout,*) 'rpsi3p  = ',rpsi3p
1113         WRITE(numout,*) 'rsc_tke = ',rsc_tke
1114         WRITE(numout,*) 'rsc_psi = ',rsc_psi
1115         WRITE(numout,*) 'rsc_psi0 = ',rsc_psi0
1116         WRITE(numout,*) 'rc0     = ',rc0
1117         WRITE(numout,*)
1118         WRITE(numout,*) 'Shear free turbulence parameters:'
1119         WRITE(numout,*) 'rcm_sf  = ',rcm_sf
1120         WRITE(numout,*) 'ra_sf   = ',ra_sf
1121         WRITE(numout,*) 'rl_sf   = ',rl_sf
1122         WRITE(numout,*)
1123      ENDIF
1124
1125      !                                !* Constants initialization
1126      rc02  = rc0  * rc0   ;   rc02r = 1. / rc02
1127      rc03  = rc02 * rc0
1128      rc04  = rc03 * rc0
1129      rsbc_tke1 = -3._wp/2._wp*rn_crban*ra_sf*rl_sf                      ! Dirichlet + Wave breaking
1130      rsbc_tke2 = rdt * rn_crban / rl_sf                                 ! Neumann + Wave breaking
1131      zcr = MAX(rsmall, rsbc_tke1**(1./(-ra_sf*3._wp/2._wp))-1._wp )
1132      rtrans = 0.2_wp / zcr                                              ! Ad. inverse transition length between log and wave layer
1133      rsbc_zs1  = rn_charn/grav                                          ! Charnock formula for surface roughness
1134      rsbc_zs2  = rn_frac_hs / 0.85_wp / grav * 665._wp                  ! Rascle formula for surface roughness
1135      rsbc_psi1 = -0.5_wp * rdt * rc0**(rpp-2._wp*rmm) / rsc_psi
1136      rsbc_psi2 = -0.5_wp * rdt * rc0**rpp * rnn * vkarmn**rnn / rsc_psi ! Neumann + NO Wave breaking
1137
1138      rfact_tke = -0.5_wp / rsc_tke * rdt                                ! Cst used for the Diffusion term of tke
1139      rfact_psi = -0.5_wp / rsc_psi * rdt                                ! Cst used for the Diffusion term of tke
1140
1141      !                                !* Wall proximity function
1142      zwall (:,:,:) = 1._wp * tmask(:,:,:)
1143
1144      !                                !* set vertical eddy coef. to the background value
1145      DO jk = 1, jpk
1146         avt (:,:,jk) = avtb(jk) * tmask(:,:,jk)
1147         avm (:,:,jk) = avmb(jk) * tmask(:,:,jk)
1148         avmu(:,:,jk) = avmb(jk) * umask(:,:,jk)
1149         avmv(:,:,jk) = avmb(jk) * vmask(:,:,jk)
1150      END DO
1151      !                             
1152      CALL gls_rst( nit000, 'READ' )   !* read or initialize all required files
1153      !
1154      IF( nn_timing == 1 )  CALL timing_stop('zdf_gls_init')
1155      !
1156   END SUBROUTINE zdf_gls_init
1157
1158
1159   SUBROUTINE gls_rst( kt, cdrw )
1160      !!---------------------------------------------------------------------
1161      !!                   ***  ROUTINE ts_rst  ***
1162      !!                     
1163      !! ** Purpose :   Read or write TKE file (en) in restart file
1164      !!
1165      !! ** Method  :   use of IOM library
1166      !!                if the restart does not contain TKE, en is either
1167      !!                set to rn_emin or recomputed (nn_igls/=0)
1168      !!----------------------------------------------------------------------
1169      INTEGER         , INTENT(in) ::   kt         ! ocean time-step
1170      CHARACTER(len=*), INTENT(in) ::   cdrw       ! "READ"/"WRITE" flag
1171      !
1172      INTEGER ::   jit, jk   ! dummy loop indices
1173      INTEGER ::   id1, id2, id3, id4, id5, id6
1174      INTEGER ::   ji, jj, ikbu, ikbv
1175      REAL(wp)::   cbx, cby
1176      !!----------------------------------------------------------------------
1177      !
1178      IF( TRIM(cdrw) == 'READ' ) THEN        ! Read/initialise
1179         !                                   ! ---------------
1180         IF( ln_rstart ) THEN                   !* Read the restart file
1181            id1 = iom_varid( numror, 'en'   , ldstop = .FALSE. )
1182            id2 = iom_varid( numror, 'avt'  , ldstop = .FALSE. )
1183            id3 = iom_varid( numror, 'avm'  , ldstop = .FALSE. )
1184            id4 = iom_varid( numror, 'avmu' , ldstop = .FALSE. )
1185            id5 = iom_varid( numror, 'avmv' , ldstop = .FALSE. )
1186            id6 = iom_varid( numror, 'mxln' , ldstop = .FALSE. )
1187            !
1188            IF( MIN( id1, id2, id3, id4, id5, id6 ) > 0 ) THEN        ! all required arrays exist
1189               CALL iom_get( numror, jpdom_autoglo, 'en'    , en     )
1190               CALL iom_get( numror, jpdom_autoglo, 'avt'   , avt    )
1191               CALL iom_get( numror, jpdom_autoglo, 'avm'   , avm    )
1192               CALL iom_get( numror, jpdom_autoglo, 'avmu'  , avmu   )
1193               CALL iom_get( numror, jpdom_autoglo, 'avmv'  , avmv   )
1194               CALL iom_get( numror, jpdom_autoglo, 'mxln'  , mxln   )
1195            ELSE                       
1196               IF(lwp) WRITE(numout,*) ' ===>>>> : previous run without gls scheme, en and mxln computed by iterative loop'
1197               en  (:,:,:) = rn_emin
1198               mxln(:,:,:) = 0.05       
1199               avt_k (:,:,:) = avt (:,:,:)
1200               avm_k (:,:,:) = avm (:,:,:)
1201               avmu_k(:,:,:) = avmu(:,:,:)
1202               avmv_k(:,:,:) = avmv(:,:,:)
1203               DO jit = nit000 + 1, nit000 + 10   ;   CALL zdf_gls( jit )   ;   END DO
1204            ENDIF
1205         ELSE                                   !* Start from rest
1206            IF(lwp) WRITE(numout,*) ' ===>>>> : Initialisation of en and mxln by background values'
1207            en  (:,:,:) = rn_emin
1208            mxln(:,:,:) = 0.05       
1209         ENDIF
1210         !
1211      ELSEIF( TRIM(cdrw) == 'WRITE' ) THEN   ! Create restart file
1212         !                                   ! -------------------
1213         IF(lwp) WRITE(numout,*) '---- gls-rst ----'
1214         CALL iom_rstput( kt, nitrst, numrow, 'en'   , en     ) 
1215         CALL iom_rstput( kt, nitrst, numrow, 'avt'  , avt_k  )
1216         CALL iom_rstput( kt, nitrst, numrow, 'avm'  , avm_k  )
1217         CALL iom_rstput( kt, nitrst, numrow, 'avmu' , avmu_k ) 
1218         CALL iom_rstput( kt, nitrst, numrow, 'avmv' , avmv_k )
1219         CALL iom_rstput( kt, nitrst, numrow, 'mxln' , mxln   )
1220         !
1221      ENDIF
1222      !
1223   END SUBROUTINE gls_rst
1224
1225#else
1226   !!----------------------------------------------------------------------
1227   !!   Dummy module :                                        NO TKE scheme
1228   !!----------------------------------------------------------------------
1229   LOGICAL, PUBLIC, PARAMETER ::   lk_zdfgls = .FALSE.   !: TKE flag
1230CONTAINS
1231   SUBROUTINE zdf_gls_init           ! Empty routine
1232      WRITE(*,*) 'zdf_gls_init: You should not have seen this print! error?'
1233   END SUBROUTINE zdf_gls_init
1234   SUBROUTINE zdf_gls( kt )          ! Empty routine
1235      WRITE(*,*) 'zdf_gls: You should not have seen this print! error?', kt
1236   END SUBROUTINE zdf_gls
1237   SUBROUTINE gls_rst( kt, cdrw )          ! Empty routine
1238      INTEGER         , INTENT(in) ::   kt         ! ocean time-step
1239      CHARACTER(len=*), INTENT(in) ::   cdrw       ! "READ"/"WRITE" flag
1240      WRITE(*,*) 'gls_rst: You should not have seen this print! error?', kt, cdrw
1241   END SUBROUTINE gls_rst
1242#endif
1243
1244   !!======================================================================
1245END MODULE zdfgls
1246
Note: See TracBrowser for help on using the repository browser.