New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p4zprod.F90 in branches/CMIP5_IPSL/NEMO/TOP_SRC/PISCES – NEMO

source: branches/CMIP5_IPSL/NEMO/TOP_SRC/PISCES/p4zprod.F90 @ 2504

Last change on this file since 2504 was 2504, checked in by cetlod, 13 years ago

Computation of monthly mean ocean carbon flux in PISCES
  • Property svn:executable set to *
  • Property svn:keywords set to Id
File size: 20.8 KB
Line 
1MODULE p4zprod
2   !!======================================================================
3   !!                         ***  MODULE p4zprod  ***
4   !! TOP :   PISCES
5   !!======================================================================
6   !! History :   1.0  !  2004     (O. Aumont) Original code
7   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
8   !!----------------------------------------------------------------------
9#if defined key_pisces
10   !!----------------------------------------------------------------------
11   !!   'key_pisces'                                       PISCES bio-model
12   !!----------------------------------------------------------------------
13   !!   p4z_prod       : 
14   !!----------------------------------------------------------------------
15   USE trc
16   USE oce_trc         !
17   USE sms_pisces      !
18   USE prtctl_trc
19   USE p4zopt
20   USE p4zint
21   USE p4zlim
22   USE iom
23
24   USE lib_mpp
25
26   IMPLICIT NONE
27   PRIVATE
28
29   PUBLIC   p4z_prod    ! called in p4zbio.F90
30
31   !! * Shared module variables
32   REAL(wp), PUBLIC ::   &
33     pislope   = 3.0_wp          ,  &  !:
34     pislope2  = 3.0_wp          ,  &  !:
35     excret    = 10.e-5_wp       , &   !:
36     excret2   = 0.05_wp         , &   !:
37     chlcnm    = 0.033_wp        , &   !:
38     chlcdm    = 0.05_wp         , &   !:
39     fecnm     = 10.E-6_wp       , &   !:
40     fecdm     = 15.E-6_wp       , &   !:
41     grosip    = 0.151_wp
42
43   REAL(wp), PUBLIC, DIMENSION(jpi,jpj,jpk)  ::        &
44     &                   prmax
45   
46   REAL(wp) ::   &
47      texcret                    ,  &  !: 1 - excret
48      texcret2                   ,  &  !: 1 - excret2       
49      rpis180                    ,  &  !: rpi / 180
50      tpp                              !: Total primary production
51
52   !!* Substitution
53#  include "top_substitute.h90"
54   !!----------------------------------------------------------------------
55   !! NEMO/TOP 2.0 , LOCEAN-IPSL (2007)
56   !! $Id$
57   !! Software governed by the CeCILL licence (modipsl/doc/NEMO_CeCILL.txt)
58   !!----------------------------------------------------------------------
59
60CONTAINS
61
62   SUBROUTINE p4z_prod( kt , jnt )
63      !!---------------------------------------------------------------------
64      !!                     ***  ROUTINE p4z_prod  ***
65      !!
66      !! ** Purpose :   Compute the phytoplankton production depending on
67      !!              light, temperature and nutrient availability
68      !!
69      !! ** Method  : - ???
70      !!---------------------------------------------------------------------
71      INTEGER, INTENT(in) :: kt, jnt
72      INTEGER  ::   ji, jj, jk
73      REAL(wp) ::   zsilfac, zfact
74      REAL(wp) ::   zprdiachl, zprbiochl, zsilim, ztn, zadap, zadap2
75      REAL(wp) ::   zlim, zsilfac2, zsiborn, zprod, zetot2, zmax, zproreg, zproreg2
76      REAL(wp) ::   zmxltst, zmxlday, zlim1
77      REAL(wp) ::   zpislopen  , zpislope2n
78      REAL(wp) ::   zrum, zcodel, zargu, zvol
79#if defined key_trc_diaadd && defined key_trc_dia3d
80      REAL(wp) ::   zrfact2
81#if defined key_iomput && defined key_diaar5
82      REAL(wp), DIMENSION(jpi,jpj) ::   zw2d
83#endif
84#endif
85      REAL(wp), DIMENSION(jpi,jpj)     ::   zmixnano   , zmixdiat, zstrn
86      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zpislopead , zpislopead2
87      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zprdia     , zprbio, zysopt
88      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zprorca    , zprorcad, zprofed
89      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zprofen   , zprochln, zprochld
90      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zpronew    , zpronewd
91      CHARACTER (len=25) :: charout
92      !!---------------------------------------------------------------------
93
94
95      IF( ( kt * jnt ) == nittrc000  )   CALL p4z_prod_init      ! Initialization (first time-step only)
96
97
98      zprorca (:,:,:) = 0.0
99      zprorcad(:,:,:) = 0.0
100      zprofed(:,:,:) = 0.0
101      zprofen(:,:,:) = 0.0
102      zprochln(:,:,:) = 0.0
103      zprochld(:,:,:) = 0.0
104      zpronew (:,:,:) = 0.0
105      zpronewd(:,:,:) = 0.0
106      zprdia  (:,:,:) = 0.0
107      zprbio  (:,:,:) = 0.0
108      zysopt  (:,:,:) = 0.0
109
110      ! Computation of the optimal production
111
112# if defined key_off_degrad
113      prmax(:,:,:) = 0.6 / rday * tgfunc(:,:,:) * facvol(:,:,:)
114# else
115      prmax(:,:,:) = 0.6 / rday * tgfunc(:,:,:)
116# endif
117
118      ! compute the day length depending on latitude and the day
119      IF(lwp) write(numout,*)
120      IF(lwp) write(numout,*) 'p4zday : - Julian day ', nday_year
121      IF(lwp) write(numout,*) '~~~~~~'
122
123      IF( nleapy == 1 .AND. MOD( nyear, 4 ) == 0 ) THEN
124         zrum = FLOAT( nday_year - 80 ) / 366.
125      ELSE
126         zrum = FLOAT( nday_year - 80 ) / 365.
127      ENDIF
128      zcodel = ASIN(  SIN( zrum * rpi * 2. ) * SIN( rpis180 * 23.5 )  )
129
130      ! day length in hours
131      zstrn(:,:) = 0.
132      DO jj = 1, jpj
133         DO ji = 1, jpi
134            zargu = TAN( zcodel ) * TAN( gphit(ji,jj) * rpis180 )
135            zargu = MAX( -1., MIN(  1., zargu ) )
136            zstrn(ji,jj) = MAX( 0.0, 24. - 2. * ACOS( zargu ) / rpis180 / 15. )
137         END DO
138      END DO
139
140
141!CDIR NOVERRCHK
142      DO jk = 1, jpkm1
143!CDIR NOVERRCHK
144         DO jj = 1, jpj
145!CDIR NOVERRCHK
146            DO ji = 1, jpi
147
148               ! Computation of the P-I slope for nanos and diatoms
149               IF( etot(ji,jj,jk) > 1.E-3 ) THEN
150                   ztn    = MAX( 0., tn(ji,jj,jk) - 15. )
151                   zadap  = 0.+ 1.* ztn / ( 2.+ ztn )
152                   zadap2 = 0.e0
153
154                   zfact  = EXP( -0.21 * emoy(ji,jj,jk) )
155
156                   zpislopead (ji,jj,jk) = pislope  * ( 1.+ zadap  * zfact )
157                   zpislopead2(ji,jj,jk) = pislope2 * ( 1.+ zadap2 * zfact )
158
159                   zpislopen = zpislopead(ji,jj,jk) * trn(ji,jj,jk,jpnch)                 &
160                     &         / ( trn(ji,jj,jk,jpphy) * 12.                   + rtrn )   &
161                     &         / ( prmax(ji,jj,jk) * rday * xlimphy(ji,jj,jk) + rtrn )
162
163                   zpislope2n = zpislopead2(ji,jj,jk) * trn(ji,jj,jk,jpdch)                &
164                     &          / ( trn(ji,jj,jk,jpdia) * 12.                   + rtrn )   &
165                     &          / ( prmax(ji,jj,jk) * rday * xlimdia(ji,jj,jk) + rtrn )
166
167                   ! Computation of production function
168                   zprbio(ji,jj,jk) = prmax(ji,jj,jk) * &
169                     &                (  1.- EXP( -zpislopen * enano(ji,jj,jk) )  )
170                   zprdia(ji,jj,jk) = prmax(ji,jj,jk) * &
171                     &                (  1.- EXP( -zpislope2n * ediat(ji,jj,jk) )  )
172               ENDIF
173            END DO
174         END DO
175      END DO
176
177
178      DO jk = 1, jpkm1
179         DO jj = 1, jpj
180            DO ji = 1, jpi
181
182                IF( etot(ji,jj,jk) > 1.E-3 ) THEN
183                   !    Si/C of diatoms
184                   !    ------------------------
185                   !    Si/C increases with iron stress and silicate availability
186                   !    Si/C is arbitrariliy increased for very high Si concentrations
187                   !    to mimic the very high ratios observed in the Southern Ocean (silpot2)
188
189                  zlim1  = trn(ji,jj,jk,jpsil) / ( trn(ji,jj,jk,jpsil) + xksi1 )
190                  zlim   = xdiatno3(ji,jj,jk) + xdiatnh4(ji,jj,jk)
191
192                  zsilim = MIN( zprdia(ji,jj,jk)    / ( rtrn + prmax(ji,jj,jk) ),                 &
193                  &          trn(ji,jj,jk,jpfer) / ( concdfe(ji,jj,jk) + trn(ji,jj,jk,jpfer) ),   &
194                  &          trn(ji,jj,jk,jppo4) / ( concdnh4 + trn(ji,jj,jk,jppo4) ),            &
195                  &          zlim )
196                  zsilfac = 5.4 * EXP( -4.23 * zsilim ) * MAX( 0.e0, MIN( 1., 2.2 * ( zlim1 - 0.5 ) )  ) + 1.e0
197                  zsiborn = MAX( 0.e0, ( trn(ji,jj,jk,jpsil) - 15.e-6 ) )
198                  zsilfac2 = 1.+ 3.* zsiborn / ( zsiborn + xksi2 )
199                  zsilfac = MIN( 6.4,zsilfac * zsilfac2)
200                  zysopt(ji,jj,jk) = grosip * zlim1 * zsilfac
201
202              ENDIF
203            END DO
204         END DO
205      END DO
206
207      !  Computation of the limitation term due to
208      !  A mixed layer deeper than the euphotic depth
209      DO jj = 1, jpj
210         DO ji = 1, jpi
211            zmxltst = MAX( 0.e0, hmld(ji,jj) - heup(ji,jj) )
212            zmxlday = zmxltst**2 / rday
213            zmixnano(ji,jj) = 1.- zmxlday / ( 1.+ zmxlday )
214            zmixdiat(ji,jj) = 1.- zmxlday / ( 3.+ zmxlday )
215         END DO
216      END DO
217 
218      !  Mixed-layer effect on production                                                                               
219      DO jk = 1, jpkm1
220         DO jj = 1, jpj
221            DO ji = 1, jpi
222               IF( fsdepw(ji,jj,jk+1) <= hmld(ji,jj) ) THEN
223                  zprbio(ji,jj,jk) = zprbio(ji,jj,jk) * zmixnano(ji,jj)
224                  zprdia(ji,jj,jk) = zprdia(ji,jj,jk) * zmixdiat(ji,jj)
225               ENDIF
226            END DO
227         END DO
228      END DO
229
230
231      WHERE( zstrn(:,:) < 1.e0 ) zstrn(:,:) = 24.
232      zstrn(:,:) = 24. / zstrn(:,:)
233
234!CDIR NOVERRCHK
235      DO jk = 1, jpkm1
236!CDIR NOVERRCHK
237         DO jj = 1, jpj
238!CDIR NOVERRCHK
239            DO ji = 1, jpi
240
241               IF( etot(ji,jj,jk) > 1.E-3 ) THEN
242                  !     Computation of the various production terms for nanophyto.
243                  zetot2 = enano(ji,jj,jk) * zstrn(ji,jj)
244                  zmax = MAX( 0.1, xlimphy(ji,jj,jk) )
245                  zpislopen = zpislopead(ji,jj,jk)          &
246                  &         * trn(ji,jj,jk,jpnch) / ( rtrn + trn(ji,jj,jk,jpphy) * 12.)         &
247                  &         / ( prmax(ji,jj,jk) * rday * zmax + rtrn )
248
249                  zprbiochl = prmax(ji,jj,jk) * (  1.- EXP( -zpislopen * zetot2 )  )
250
251                  zprorca(ji,jj,jk) = zprbio(ji,jj,jk)  * xlimphy(ji,jj,jk) * trn(ji,jj,jk,jpphy) * rfact2
252
253                  zpronew(ji,jj,jk) = zprorca(ji,jj,jk) * xnanono3(ji,jj,jk)    &
254                  &             / ( xnanono3(ji,jj,jk) + xnanonh4(ji,jj,jk) + rtrn )
255                  zprod = rday * zprorca(ji,jj,jk) * zprbiochl * trn(ji,jj,jk,jpphy) *zmax
256
257                  zprofen(ji,jj,jk) = (fecnm)**2 * zprod / chlcnm            &
258                  &              / (  zpislopead(ji,jj,jk) * zetot2 * trn(ji,jj,jk,jpnfe) + rtrn  )
259
260                  zprochln(ji,jj,jk) = chlcnm * 144. * zprod                  &
261                  &              / (  zpislopead(ji,jj,jk) * zetot2 * trn(ji,jj,jk,jpnch) + rtrn  )
262               ENDIF
263            END DO
264         END DO
265      END DO
266
267!CDIR NOVERRCHK
268      DO jk = 1, jpkm1
269!CDIR NOVERRCHK
270         DO jj = 1, jpj
271!CDIR NOVERRCHK
272            DO ji = 1, jpi
273               IF( etot(ji,jj,jk) > 1.E-3 ) THEN
274                  !  Computation of the various production terms for diatoms
275                  zetot2 = ediat(ji,jj,jk) * zstrn(ji,jj)
276                  zmax = MAX( 0.1, xlimdia(ji,jj,jk) )
277                  zpislope2n = zpislopead2(ji,jj,jk) * trn(ji,jj,jk,jpdch)        &
278                  &           / ( rtrn + trn(ji,jj,jk,jpdia) * 12.)        &
279                  &           / ( prmax(ji,jj,jk) * rday * zmax + rtrn )
280
281                  zprdiachl = prmax(ji,jj,jk) * (  1.- EXP( -zetot2 * zpislope2n )  )
282
283                  zprorcad(ji,jj,jk) = zprdia(ji,jj,jk) * xlimdia(ji,jj,jk) * trn(ji,jj,jk,jpdia) * rfact2
284
285                  zpronewd(ji,jj,jk) = zprorcad(ji,jj,jk) * xdiatno3(ji,jj,jk)     &
286                  &              / ( xdiatno3(ji,jj,jk) + xdiatnh4(ji,jj,jk) + rtrn )
287
288                  zprod = rday * zprorcad(ji,jj,jk) * zprdiachl * trn(ji,jj,jk,jpdia) * zmax
289
290                  zprofed(ji,jj,jk) = (fecdm)**2 * zprod / chlcdm                   &
291                  &              / ( zpislopead2(ji,jj,jk) * zetot2 * trn(ji,jj,jk,jpdfe) + rtrn )
292
293                  zprochld(ji,jj,jk) = chlcdm * 144. * zprod       &
294                  &              / ( zpislopead2(ji,jj,jk) * zetot2 * trn(ji,jj,jk,jpdch) + rtrn )
295
296               ENDIF
297            END DO
298         END DO
299      END DO
300      !
301
302      !   Update the arrays TRA which contain the biological sources and sinks
303      DO jk = 1, jpkm1
304         DO jj = 1, jpj
305           DO ji =1 ,jpi
306              zproreg  = zprorca(ji,jj,jk) - zpronew(ji,jj,jk)
307              zproreg2 = zprorcad(ji,jj,jk) - zpronewd(ji,jj,jk)
308              tra(ji,jj,jk,jppo4) = tra(ji,jj,jk,jppo4) - zprorca(ji,jj,jk) - zprorcad(ji,jj,jk)
309              tra(ji,jj,jk,jpno3) = tra(ji,jj,jk,jpno3) - zpronew(ji,jj,jk) - zpronewd(ji,jj,jk)
310              tra(ji,jj,jk,jpnh4) = tra(ji,jj,jk,jpnh4) - zproreg - zproreg2
311              tra(ji,jj,jk,jpphy) = tra(ji,jj,jk,jpphy) + zprorca(ji,jj,jk) * texcret
312              tra(ji,jj,jk,jpnch) = tra(ji,jj,jk,jpnch) + zprochln(ji,jj,jk) * texcret
313              tra(ji,jj,jk,jpnfe) = tra(ji,jj,jk,jpnfe) + zprofen(ji,jj,jk) * texcret
314              tra(ji,jj,jk,jpdia) = tra(ji,jj,jk,jpdia) + zprorcad(ji,jj,jk) * texcret2
315              tra(ji,jj,jk,jpdch) = tra(ji,jj,jk,jpdch) + zprochld(ji,jj,jk) * texcret2
316              tra(ji,jj,jk,jpdfe) = tra(ji,jj,jk,jpdfe) + zprofed(ji,jj,jk) * texcret2
317              tra(ji,jj,jk,jpbsi) = tra(ji,jj,jk,jpbsi) + zprorcad(ji,jj,jk) * zysopt(ji,jj,jk) * texcret2
318              tra(ji,jj,jk,jpdoc) = tra(ji,jj,jk,jpdoc) + &
319              &                     excret2 * zprorcad(ji,jj,jk) + excret * zprorca(ji,jj,jk)
320              tra(ji,jj,jk,jpoxy) = tra(ji,jj,jk,jpoxy) + o2ut * ( zproreg + zproreg2) &
321              &                    + ( o2ut + o2nit ) * ( zpronew(ji,jj,jk) + zpronewd(ji,jj,jk) )
322              tra(ji,jj,jk,jpfer) = tra(ji,jj,jk,jpfer) &
323              &                     - texcret * zprofen(ji,jj,jk) - texcret2 * zprofed(ji,jj,jk)
324              tra(ji,jj,jk,jpsil) = tra(ji,jj,jk,jpsil) &
325              &                     - texcret2 * zprorcad(ji,jj,jk) * zysopt(ji,jj,jk)
326              tra(ji,jj,jk,jpdic) = tra(ji,jj,jk,jpdic) - zprorca(ji,jj,jk) - zprorcad(ji,jj,jk)
327              tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) &
328              &                    + rno3 * ( zpronew(ji,jj,jk) + zpronewd(ji,jj,jk) )
329          END DO
330        END DO
331     END DO
332
333     ! Total primary production per year
334     DO jk = 1, jpkm1
335        DO jj = 1, jpj
336          DO ji = 1, jpi
337             zvol = cvol(ji,jj,jk)
338#if defined key_off_degrad
339             zvol = zvol * facvol(ji,jj,jk)
340#endif
341             tpp  = tpp + ( zprorca(ji,jj,jk) + zprorcad(ji,jj,jk) ) &
342                          * zvol * tmask(ji,jj,jk) * tmask_i(ji,jj)
343          END DO
344        END DO
345      END DO
346
347     IF( kt == nitend .AND. jnt == nrdttrc ) THEN
348        IF( lk_mpp ) CALL mpp_sum( tpp )
349        WRITE(numout,*) 'Total PP (Gtc) :'
350        WRITE(numout,*) '-------------------- : ',tpp * 12. / 1.E12
351        WRITE(numout,*)
352      ENDIF
353
354#if defined key_trc_diaadd && defined key_trc_dia3d && ! defined key_iomput
355      !   Supplementary diagnostics
356      zrfact2 = 1.e3 * rfact2r
357      trc3d(:,:,:,jp_pcs0_3d + 4)  = zprorca (:,:,:) * zrfact2 * tmask(:,:,:)
358      trc3d(:,:,:,jp_pcs0_3d + 5)  = zprorcad(:,:,:) * zrfact2 * tmask(:,:,:)
359      trc3d(:,:,:,jp_pcs0_3d + 6)  = zpronew (:,:,:) * zrfact2 * tmask(:,:,:)
360      trc3d(:,:,:,jp_pcs0_3d + 7)  = zpronewd(:,:,:) * zrfact2 * tmask(:,:,:)
361      trc3d(:,:,:,jp_pcs0_3d + 8)  = zprorcad(:,:,:) * zrfact2 * tmask(:,:,:) * zysopt(:,:,:)
362      trc3d(:,:,:,jp_pcs0_3d + 9)  = zprofed (:,:,:) * zrfact2 * tmask(:,:,:)
363#  if ! defined key_kriest
364      trc3d(:,:,:,jp_pcs0_3d + 10) = zprofen (:,:,:) * zrfact2 * tmask(:,:,:)
365#  endif
366#endif
367
368#if defined key_trc_diaadd && defined key_trc_dia3d && defined key_iomput
369      zrfact2 = 1.e3 * rfact2r
370      IF ( jnt == nrdttrc ) then
371         CALL iom_put( "PPPHY" , zprorca (:,:,:) * zrfact2 * tmask(:,:,:) )  ! primary production by nanophyto
372         CALL iom_put( "PPPHY2", zprorcad(:,:,:) * zrfact2 * tmask(:,:,:) )  ! primary production by diatom
373         CALL iom_put( "PPNEWN", zpronew (:,:,:) * zrfact2 * tmask(:,:,:) )  ! new primary production by nanophyto
374         CALL iom_put( "PPNEWD", zpronewd(:,:,:) * zrfact2 * tmask(:,:,:) )  ! new primary production by diatom
375         CALL iom_put( "PBSi"  , zprorcad(:,:,:) * zrfact2 * tmask(:,:,:) * zysopt(:,:,:) ) ! biogenic silica production
376         CALL iom_put( "PFeD"  , zprofed (:,:,:) * zrfact2 * tmask(:,:,:) )  ! biogenic iron production by diatom
377         CALL iom_put( "PFeN"  , zprofen (:,:,:) * zrfact2 * tmask(:,:,:) )  ! biogenic iron production by nanophyto
378      ENDIF
379#if  defined key_diaar5
380      IF ( jnt == nrdttrc ) then
381         CALL iom_put( "TPP"  , ( zprorca(:,:,:) + zprorcad(:,:,:) ) * zrfact2 * tmask(:,:,:) )  ! total primary production
382         CALL iom_put( "TPNEW", ( zpronew(:,:,:) + zpronewd(:,:,:) ) * zrfact2 * tmask(:,:,:) )  ! total new primary production 
383         CALL iom_put( "TPBFE", ( zprofen(:,:,:) + zprofed (:,:,:) ) * zrfact2 * tmask(:,:,:) )  ! total biogenic iron production
384      ENDIF
385      ! primary production by nanophyto ( vertically integrated )
386      zw2d(:,:) = 0.
387      DO jk = 1, jpkm1
388         zw2d(:,:) = zw2d(:,:) + zprorca (:,:,jk) * fse3t(:,:,jk) * zrfact2 * tmask(:,:,jk)
389      ENDDO
390      IF ( jnt == nrdttrc ) CALL iom_put( "INTPPPHY" , zw2d ) 
391      ! primary production by diatom ( vertically integrated )
392      zw2d(:,:) = 0.
393      DO jk = 1, jpkm1
394         zw2d(:,:) = zw2d(:,:) + zprorcad(:,:,jk) * fse3t(:,:,jk) * zrfact2 * tmask(:,:,jk)
395      ENDDO
396      IF ( jnt == nrdttrc ) CALL iom_put( "INTPPPHY2" , zw2d ) 
397      ! total primary production  ( vertically integrated )
398      zw2d(:,:) = 0.
399      DO jk = 1, jpkm1
400         zw2d(:,:) = zw2d(:,:) + ( zprorca (:,:,jk) + zprorcad(:,:,jk) ) * fse3t(:,:,jk) * zrfact2 * tmask(:,:,jk)
401      ENDDO
402      IF ( jnt == nrdttrc ) CALL iom_put( "INTPP" , zw2d ) 
403      ! total new primary production  ( vertically integrated )
404      zw2d(:,:) = 0.
405      DO jk = 1, jpkm1
406         zw2d(:,:) = zw2d(:,:) + ( zpronew (:,:,jk) + zpronewd(:,:,jk) ) * fse3t(:,:,jk) * zrfact2 * tmask(:,:,jk)
407      ENDDO
408      IF ( jnt == nrdttrc ) CALL iom_put( "INTPNEW" , zw2d ) 
409      ! total biogenic iron production  ( vertically integrated )
410      zw2d(:,:) = 0.
411      DO jk = 1, jpkm1
412         zw2d(:,:) = zw2d(:,:) + ( zprofen (:,:,jk) + zprofed(:,:,jk) ) * fse3t(:,:,jk) * zrfact2 * tmask(:,:,jk)
413      ENDDO
414      IF ( jnt == nrdttrc ) CALL iom_put( "INTPBFE" , zw2d ) 
415      ! biogenic silica production  ( vertically integrated )
416      zw2d(:,:) = 0.
417      DO jk = 1, jpkm1
418         zw2d(:,:) = zw2d(:,:) + zprorcad(:,:,jk) * zysopt(:,:,jk) * fse3t(:,:,jk) * zrfact2 * tmask(:,:,jk)
419      ENDDO
420      IF ( jnt == nrdttrc ) CALL iom_put( "INTPBSI" , zw2d ) 
421#endif
422#endif
423
424       IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
425         WRITE(charout, FMT="('prod')")
426         CALL prt_ctl_trc_info(charout)
427         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
428       ENDIF
429
430   END SUBROUTINE p4z_prod
431
432   SUBROUTINE p4z_prod_init
433
434      !!----------------------------------------------------------------------
435      !!                  ***  ROUTINE p4z_prod_init  ***
436      !!
437      !! ** Purpose :   Initialization of phytoplankton production parameters
438      !!
439      !! ** Method  :   Read the nampisprod namelist and check the parameters
440      !!      called at the first timestep (nittrc000)
441      !!
442      !! ** input   :   Namelist nampisprod
443      !!
444      !!----------------------------------------------------------------------
445
446      NAMELIST/nampisprod/ pislope, pislope2, excret, excret2, chlcnm, chlcdm,   &
447         &              fecnm, fecdm, grosip
448
449      REWIND( numnat )                     ! read numnat
450      READ  ( numnat, nampisprod )
451
452      IF(lwp) THEN                         ! control print
453         WRITE(numout,*) ' '
454         WRITE(numout,*) ' Namelist parameters for phytoplankton growth, nampisprod'
455         WRITE(numout,*) ' ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
456         WRITE(numout,*) '    mean Si/C ratio                           grosip    =', grosip
457         WRITE(numout,*) '    P-I slope                                 pislope   =', pislope
458         WRITE(numout,*) '    excretion ratio of nanophytoplankton      excret    =', excret
459         WRITE(numout,*) '    excretion ratio of diatoms                excret2   =', excret2
460         WRITE(numout,*) '    P-I slope  for diatoms                    pislope2  =', pislope2
461         WRITE(numout,*) '    Minimum Chl/C in nanophytoplankton        chlcnm    =', chlcnm
462         WRITE(numout,*) '    Minimum Chl/C in diatoms                  chlcdm    =', chlcdm
463         WRITE(numout,*) '    Maximum Fe/C in nanophytoplankton         fecnm     =', fecnm
464         WRITE(numout,*) '    Minimum Fe/C in diatoms                   fecdm     =', fecdm
465      ENDIF
466
467      rpis180   = rpi / 180.
468      texcret   = 1.0 - excret
469      texcret2  = 1.0 - excret2
470      tpp       = 0.
471
472   END SUBROUTINE p4z_prod_init
473
474
475
476#else
477   !!======================================================================
478   !!  Dummy module :                                   No PISCES bio-model
479   !!======================================================================
480CONTAINS
481   SUBROUTINE p4z_prod                    ! Empty routine
482   END SUBROUTINE p4z_prod
483#endif 
484
485   !!======================================================================
486END MODULE  p4zprod
Note: See TracBrowser for help on using the repository browser.