1 | MODULE trcadv_tvd |
---|
2 | !!====================================================================== |
---|
3 | !! *** MODULE trcadv_tvd *** |
---|
4 | !! Ocean passive tracers: horizontal & vertical advective trend |
---|
5 | !!====================================================================== |
---|
6 | !! History : ! 95-12 (L. Mortier) Original code |
---|
7 | !! ! 00-01 (H. Loukos) adapted to ORCA |
---|
8 | !! ! 00-10 (MA Foujols E.Kestenare) include file not routine |
---|
9 | !! ! 00-12 (E. Kestenare M. Levy) fix bug in trtrd indexes |
---|
10 | !! ! 01-07 (E. Durand G. Madec) adaptation to ORCA config |
---|
11 | !! 9.0 ! 02-06 (C. Ethe, G. Madec) F90: Free form and module |
---|
12 | !! ! 07-02 (C. Deltel) Diagnose ML trends for passive tracers |
---|
13 | !!---------------------------------------------------------------------- |
---|
14 | #if defined key_top |
---|
15 | !!---------------------------------------------------------------------- |
---|
16 | !! trc_adv_tvd : update the passive tracer trend with the horizontal |
---|
17 | !! and vertical advection trends using a TVD scheme |
---|
18 | !! nonosc : compute monotonic tracer fluxes by a nonoscillatory |
---|
19 | !! algorithm |
---|
20 | !!---------------------------------------------------------------------- |
---|
21 | USE oce_trc ! ocean dynamics and active tracers variables |
---|
22 | USE trc ! ocean passive tracers variables |
---|
23 | USE trp_trc |
---|
24 | USE lbclnk ! ocean lateral boundary conditions (or mpp link) |
---|
25 | USE trcbbl ! advective passive tracers in the BBL |
---|
26 | USE prtctl_trc ! Print control for debbuging |
---|
27 | USE trdmld_trc |
---|
28 | USE trdmld_trc_oce |
---|
29 | |
---|
30 | IMPLICIT NONE |
---|
31 | PRIVATE |
---|
32 | |
---|
33 | PUBLIC trc_adv_tvd ! routine called by trcstp.F90 |
---|
34 | |
---|
35 | !! * Substitutions |
---|
36 | # include "top_substitute.h90" |
---|
37 | !!---------------------------------------------------------------------- |
---|
38 | !! TOP 1.0 , LOCEAN-IPSL (2005) |
---|
39 | !! $Header: /home/opalod/NEMOCVSROOT/NEMO/TOP_SRC/TRP/trcadv_tvd.F90,v 1.12 2006/04/10 15:38:54 opalod Exp $ |
---|
40 | !! Software governed by the CeCILL licence (modipsl/doc/NEMO_CeCILL.txt) |
---|
41 | !!---------------------------------------------------------------------- |
---|
42 | |
---|
43 | CONTAINS |
---|
44 | |
---|
45 | SUBROUTINE trc_adv_tvd( kt ) |
---|
46 | !!---------------------------------------------------------------------- |
---|
47 | !! *** ROUTINE trc_adv_tvd *** |
---|
48 | !! |
---|
49 | !! ** Purpose : Compute the now trend due to total advection of |
---|
50 | !! tracers and add it to the general trend of tracer equations |
---|
51 | !! |
---|
52 | !! ** Method : TVD scheme, i.e. 2nd order centered scheme with |
---|
53 | !! corrected flux (monotonic correction) |
---|
54 | !! note: - this advection scheme needs a leap-frog time scheme |
---|
55 | !! |
---|
56 | !! ** Action : - update tra with the now advective tracer trends |
---|
57 | !! - save the trends ('key_trdmld_trc) |
---|
58 | !!---------------------------------------------------------------------- |
---|
59 | #if defined key_trcbbl_adv |
---|
60 | USE oce_trc , zun => ua, & ! use ua as workspace |
---|
61 | & zvn => va ! use va as workspace |
---|
62 | REAL(wp), DIMENSION(jpi,jpj,jpk) :: zwn |
---|
63 | #else |
---|
64 | USE oce_trc , zun => un, & ! When no bbl, zun == un |
---|
65 | & zvn => vn, & ! zvn == vn |
---|
66 | & zwn => wn ! zwn == wn |
---|
67 | #endif |
---|
68 | INTEGER, INTENT( in ) :: kt ! ocean time-step |
---|
69 | INTEGER :: ji, jj, jk, jn ! dummy loop indices |
---|
70 | !! |
---|
71 | REAL(wp), DIMENSION(jpi,jpj,jpk) :: ztu, ztv |
---|
72 | REAL(wp), DIMENSION(jpi,jpj,jpk) :: zti, ztw |
---|
73 | REAL(wp), DIMENSION(:,:,:), ALLOCATABLE :: ztrtrd ! trends |
---|
74 | !! |
---|
75 | REAL(wp) :: z_hdivn_x, z_hdivn_y ! temporary scalars |
---|
76 | REAL(wp) :: z2dtt, zbtr, zeu, zev, zew, z2 |
---|
77 | REAL(wp) :: zfp_ui, zfp_vj, zfp_wk |
---|
78 | REAL(wp) :: zfm_ui, zfm_vj, zfm_wk |
---|
79 | #if defined key_trc_diatrd |
---|
80 | REAL(wp) :: zgm, zgz |
---|
81 | #endif |
---|
82 | CHARACTER (len=22) :: charout |
---|
83 | !!---------------------------------------------------------------------- |
---|
84 | |
---|
85 | zti(:,:,:) = 0.e0 |
---|
86 | |
---|
87 | IF( kt == nittrc000 .AND. lwp ) THEN |
---|
88 | WRITE(numout,*) |
---|
89 | WRITE(numout,*) 'trc_adv_tvd : TVD advection scheme' |
---|
90 | WRITE(numout,*) '~~~~~~~~~~~' |
---|
91 | ENDIF |
---|
92 | |
---|
93 | IF( l_trdtrc ) ALLOCATE( ztrtrd(jpi,jpj,jpk) ) |
---|
94 | |
---|
95 | IF( neuler == 0 .AND. kt == nittrc000 ) THEN |
---|
96 | z2=1. |
---|
97 | ELSE |
---|
98 | z2=2. |
---|
99 | ENDIF |
---|
100 | |
---|
101 | #if defined key_trcbbl_adv |
---|
102 | ! Advective Bottom boundary layer: add the velocity |
---|
103 | ! ------------------------------------------------- |
---|
104 | zun(:,:,:) = un (:,:,:) - u_trc_bbl(:,:,:) |
---|
105 | zvn(:,:,:) = vn (:,:,:) - v_trc_bbl(:,:,:) |
---|
106 | zwn(:,:,:) = wn (:,:,:) + w_trc_bbl(:,:,:) |
---|
107 | #endif |
---|
108 | |
---|
109 | ! ! =========== |
---|
110 | DO jn = 1, jptra ! tracer loop |
---|
111 | ! ! =========== |
---|
112 | |
---|
113 | ! ============================================================ |
---|
114 | ! I. Intermediate advective trends |
---|
115 | ! ============================================================ |
---|
116 | |
---|
117 | ! 1. Bottom value : flux set to zero |
---|
118 | ! ---------------------------------- |
---|
119 | ztu(:,:,jpk) = 0.e0 ; ztv(:,:,jpk) = 0.e0 |
---|
120 | ztw(:,:,jpk) = 0.e0 ; zti(:,:,jpk) = 0.e0 |
---|
121 | |
---|
122 | |
---|
123 | ! 2. Upstream advection with initial mass fluxes & intermediate update |
---|
124 | ! -------------------------------------------------------------------- |
---|
125 | |
---|
126 | ! ... Upstream tracer flux in the i and j direction |
---|
127 | DO jk = 1, jpkm1 |
---|
128 | DO jj = 1, jpjm1 |
---|
129 | DO ji = 1, fs_jpim1 ! vector opt. |
---|
130 | !??? CD DO ji = fs_2, fs_jpim1 ! Vector opt. |
---|
131 | zeu = 0.5 * e2u(ji,jj) * fse3u(ji,jj,jk) * zun(ji,jj,jk) |
---|
132 | zev = 0.5 * e1v(ji,jj) * fse3v(ji,jj,jk) * zvn(ji,jj,jk) |
---|
133 | zfp_ui = zeu + ABS( zeu ) ! upstream scheme |
---|
134 | zfm_ui = zeu - ABS( zeu ) |
---|
135 | zfp_vj = zev + ABS( zev ) |
---|
136 | zfm_vj = zev - ABS( zev ) |
---|
137 | ztu(ji,jj,jk) = zfp_ui * trb(ji,jj,jk,jn) + zfm_ui * trb(ji+1,jj ,jk,jn) |
---|
138 | ztv(ji,jj,jk) = zfp_vj * trb(ji,jj,jk,jn) + zfm_vj * trb(ji ,jj+1,jk,jn) |
---|
139 | END DO |
---|
140 | END DO |
---|
141 | END DO |
---|
142 | |
---|
143 | ! ... Upstream tracer flux in the k direction |
---|
144 | ! Surface value |
---|
145 | IF( lk_vvl ) THEN |
---|
146 | ! variable volume: flux set to zero |
---|
147 | ztw(:,:,1) = 0.e0 |
---|
148 | ELSE |
---|
149 | ! free surface-constant volume |
---|
150 | DO jj = 1, jpj |
---|
151 | DO ji = 1, jpi |
---|
152 | zew = e1t(ji,jj) * e2t(ji,jj) * zwn(ji,jj,1) |
---|
153 | ztw(ji,jj,1) = zew * trb(ji,jj,1,jn) |
---|
154 | END DO |
---|
155 | END DO |
---|
156 | ENDIF |
---|
157 | |
---|
158 | ! Interior value |
---|
159 | DO jk = 2, jpkm1 |
---|
160 | DO jj = 1, jpj |
---|
161 | DO ji = 1, jpi ! CD ??? Vector opt. |
---|
162 | zew = 0.5 * e1t(ji,jj) * e2t(ji,jj) * zwn(ji,jj,jk) |
---|
163 | zfp_wk = zew + ABS( zew ) |
---|
164 | zfm_wk = zew - ABS( zew ) |
---|
165 | ztw(ji,jj,jk) = zfp_wk * trb(ji,jj,jk,jn) + zfm_wk * trb(ji,jj,jk-1,jn) |
---|
166 | END DO |
---|
167 | END DO |
---|
168 | END DO |
---|
169 | |
---|
170 | ! ... Total intermediate advective trend (flux divergence) |
---|
171 | DO jk = 1, jpkm1 |
---|
172 | DO jj = 2, jpjm1 |
---|
173 | DO ji = fs_2, fs_jpim1 ! vector opt. |
---|
174 | zbtr = 1./ ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) ) |
---|
175 | zti(ji,jj,jk) = - ( ztu(ji,jj,jk) - ztu(ji-1,jj ,jk ) & |
---|
176 | & + ztv(ji,jj,jk) - ztv(ji ,jj-1,jk ) & |
---|
177 | & + ztw(ji,jj,jk) - ztw(ji ,jj ,jk+1) ) * zbtr |
---|
178 | #if defined key_trc_diatrd |
---|
179 | IF ( luttrd(jn) ) & |
---|
180 | trtrd(ji,jj,jk,ikeep(jn),1) = trtrd(ji,jj,jk,ikeep(jn),1) - & |
---|
181 | & zbtr * ( ztu(ji,jj,jk) - ztu(ji-1,jj,jk) ) |
---|
182 | IF ( luttrd(jn) ) & |
---|
183 | trtrd(ji,jj,jk,ikeep(jn),2) = trtrd(ji,jj,jk,ikeep(jn),2) - & |
---|
184 | & zbtr * ( ztv(ji,jj,jk) - ztv(ji,jj-1,jk) ) |
---|
185 | IF ( luttrd(jn) ) & |
---|
186 | trtrd(ji,jj,jk,ikeep(jn),3) = trtrd(ji,jj,jk,ikeep(jn),3) - & |
---|
187 | & zbtr * ( ztw(ji,jj,jk) - ztw(ji,jj,jk+1) ) |
---|
188 | #endif |
---|
189 | END DO |
---|
190 | END DO |
---|
191 | END DO |
---|
192 | |
---|
193 | ! 3. Save the intermediate i / j / k advective trends for diagnostics |
---|
194 | ! ------------------------------------------------------------------- |
---|
195 | |
---|
196 | IF( l_trdtrc ) THEN |
---|
197 | |
---|
198 | ! 3.1) Passive tracer ZONAL advection trends |
---|
199 | ztrtrd(:,:,:) = 0.e0 |
---|
200 | |
---|
201 | DO jk = 1, jpkm1 |
---|
202 | DO jj = 2, jpjm1 |
---|
203 | DO ji = fs_2, fs_jpim1 ! vector opt. |
---|
204 | |
---|
205 | !-- Compute zonal divergence by splitting hdivn (see divcur.F90) |
---|
206 | ! N.B. This computation is not valid along OBCs (if any) |
---|
207 | zbtr = 1./ ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) ) |
---|
208 | z_hdivn_x = ( e2u(ji ,jj) * fse3u(ji ,jj,jk) * un(ji ,jj,jk) & |
---|
209 | & - e2u(ji-1,jj) * fse3u(ji-1,jj,jk) * un(ji-1,jj,jk) ) * zbtr |
---|
210 | |
---|
211 | !-- Compute zonal advection trends |
---|
212 | ztrtrd(ji,jj,jk) = - ( ztu(ji,jj,jk) - ztu(ji-1,jj,jk) ) * zbtr & |
---|
213 | & + trb(ji,jj,jk,jn) * z_hdivn_x |
---|
214 | END DO |
---|
215 | END DO |
---|
216 | END DO |
---|
217 | |
---|
218 | IF (luttrd(jn)) CALL trd_mod_trc(ztrtrd, jn, jptrc_trd_xad, kt) ! save the trends |
---|
219 | |
---|
220 | ! 3.2) Passive tracer MERIDIONAL advection trends |
---|
221 | ztrtrd(:,:,:) = 0.e0 |
---|
222 | |
---|
223 | DO jk = 1, jpkm1 |
---|
224 | DO jj = 2, jpjm1 |
---|
225 | DO ji = fs_2, fs_jpim1 ! vector opt. |
---|
226 | |
---|
227 | !-- Compute merid. divergence by splitting hdivn (see divcur.F90) |
---|
228 | ! N.B. This computation is not valid along OBCs (if any) |
---|
229 | zbtr = 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) ) |
---|
230 | z_hdivn_y = ( e1v(ji, jj) * fse3v(ji,jj ,jk) * vn(ji,jj ,jk) & |
---|
231 | & - e1v(ji,jj-1) * fse3v(ji,jj-1,jk) * vn(ji,jj-1,jk) ) * zbtr |
---|
232 | |
---|
233 | !-- Compute merid. advection trends |
---|
234 | ztrtrd(ji,jj,jk) = - ( ztv(ji,jj,jk) - ztv(ji,jj-1,jk) ) * zbtr & |
---|
235 | & + trb(ji,jj,jk,jn) * z_hdivn_y |
---|
236 | END DO |
---|
237 | END DO |
---|
238 | END DO |
---|
239 | |
---|
240 | IF (luttrd(jn)) CALL trd_mod_trc(ztrtrd, jn, jptrc_trd_yad, kt) ! save the trends |
---|
241 | |
---|
242 | ! 3.3) Passive tracer VERTICAL advection trends |
---|
243 | ztrtrd(:,:,:) = 0.e0 |
---|
244 | DO jk = 1, jpkm1 |
---|
245 | DO jj = 2, jpjm1 |
---|
246 | DO ji = fs_2, fs_jpim1 ! Vector opt. |
---|
247 | zbtr = 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) ) |
---|
248 | ztrtrd(ji,jj,jk) = - ( ztw(ji,jj,jk) - ztw(ji ,jj ,jk+1) ) * zbtr & |
---|
249 | & - trb(ji,jj,jk,jn) * hdivn(ji,jj,jk) |
---|
250 | END DO |
---|
251 | END DO |
---|
252 | END DO |
---|
253 | |
---|
254 | IF (luttrd(jn)) CALL trd_mod_trc(ztrtrd, jn, jptrc_trd_zad, kt) ! save the trends |
---|
255 | |
---|
256 | ENDIF |
---|
257 | |
---|
258 | ! 4. Update and guess with monotonic sheme |
---|
259 | ! ---------------------------------------- |
---|
260 | DO jk = 1, jpkm1 |
---|
261 | z2dtt = z2 * rdttra(jk) * FLOAT(ndttrc) |
---|
262 | DO jj = 2, jpjm1 |
---|
263 | DO ji = fs_2, fs_jpim1 ! vector opt. |
---|
264 | tra(ji,jj,jk,jn) = tra(ji,jj,jk,jn) + zti(ji,jj,jk) |
---|
265 | zti (ji,jj,jk) = ( trb(ji,jj,jk,jn) + z2dtt * zti(ji,jj,jk) ) * tmask(ji,jj,jk) |
---|
266 | END DO |
---|
267 | END DO |
---|
268 | END DO |
---|
269 | |
---|
270 | ! 5. Lateral boundary conditions on zti, zsi (unchanged sign) |
---|
271 | ! ----------------------------------------------------------- |
---|
272 | CALL lbc_lnk( zti, 'T', 1. ) |
---|
273 | |
---|
274 | |
---|
275 | ! ============================================================ |
---|
276 | ! II. Corrected advective trends |
---|
277 | ! ============================================================ |
---|
278 | |
---|
279 | ! 1. Antidiffusive flux : high order minus low order |
---|
280 | ! -------------------------------------------------- |
---|
281 | ! Antidiffusive flux on i and j |
---|
282 | DO jk = 1, jpkm1 |
---|
283 | DO jj = 1, jpjm1 |
---|
284 | DO ji = 1, fs_jpim1 ! vector opt. |
---|
285 | zeu = 0.5 * e2u(ji,jj) * fse3u(ji,jj,jk) * zun(ji,jj,jk) |
---|
286 | zev = 0.5 * e1v(ji,jj) * fse3v(ji,jj,jk) * zvn(ji,jj,jk) |
---|
287 | ztu(ji,jj,jk) = zeu * ( trn(ji,jj,jk,jn) + trn(ji+1,jj,jk,jn) ) - ztu(ji,jj,jk) |
---|
288 | ztv(ji,jj,jk) = zev * ( trn(ji,jj,jk,jn) + trn(ji,jj+1,jk,jn) ) - ztv(ji,jj,jk) |
---|
289 | END DO |
---|
290 | END DO |
---|
291 | END DO |
---|
292 | |
---|
293 | ! Antidiffusive flux on k |
---|
294 | ztw(:,:,1) = 0.e0 ! surface value |
---|
295 | DO jk = 2, jpkm1 ! interior value |
---|
296 | DO jj = 1, jpj |
---|
297 | DO ji = 1, jpi |
---|
298 | zew = 0.5 * e1t(ji,jj) * e2t(ji,jj) * zwn(ji,jj,jk) |
---|
299 | ztw(ji,jj,jk) = zew * ( trn(ji,jj,jk,jn) + trn(ji,jj,jk-1,jn) ) - ztw(ji,jj,jk) |
---|
300 | END DO |
---|
301 | END DO |
---|
302 | END DO |
---|
303 | |
---|
304 | ! Lateral bondary conditions |
---|
305 | CALL lbc_lnk( ztu, 'U', -1. ) |
---|
306 | CALL lbc_lnk( ztv, 'V', -1. ) |
---|
307 | CALL lbc_lnk( ztw, 'W', 1. ) |
---|
308 | |
---|
309 | ! 2. Monotonicity algorithm |
---|
310 | ! ------------------------- |
---|
311 | CALL nonosc( trb(:,:,:,jn), ztu, ztv, ztw, zti, z2 ) |
---|
312 | |
---|
313 | |
---|
314 | ! 3. Final trend with corrected fluxes |
---|
315 | ! ------------------------------------ |
---|
316 | DO jk = 1, jpkm1 |
---|
317 | DO jj = 2, jpjm1 |
---|
318 | DO ji = fs_2, fs_jpim1 ! vector opt. |
---|
319 | zbtr = 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) ) |
---|
320 | tra(ji,jj,jk,jn) = tra(ji,jj,jk,jn) & |
---|
321 | & - ( ztu(ji,jj,jk) - ztu(ji-1,jj ,jk ) & |
---|
322 | & + ztv(ji,jj,jk) - ztv(ji ,jj-1,jk ) & |
---|
323 | & + ztw(ji,jj,jk) - ztw(ji ,jj ,jk+1) ) * zbtr |
---|
324 | #if defined key_trc_diatrd |
---|
325 | IF ( luttrd(jn) ) & |
---|
326 | trtrd(ji,jj,jk,ikeep(jn),1) = trtrd(ji,jj,jk,ikeep(jn),1) - & |
---|
327 | & zbtr * ( ztu(ji,jj,jk) - ztu(ji-1,jj,jk) ) |
---|
328 | IF ( luttrd(jn) ) & |
---|
329 | trtrd(ji,jj,jk,ikeep(jn),2) = trtrd(ji,jj,jk,ikeep(jn),2) - & |
---|
330 | & zbtr * ( ztv(ji,jj,jk) - ztv(ji,jj-1,jk) ) |
---|
331 | IF ( luttrd(jn) ) & |
---|
332 | trtrd(ji,jj,jk,ikeep(jn),3) = trtrd(ji,jj,jk,ikeep(jn),3) - & |
---|
333 | & zbtr * ( ztw(ji,jj,jk) - ztw(ji,jj,jk+1) ) |
---|
334 | #endif |
---|
335 | |
---|
336 | END DO |
---|
337 | END DO |
---|
338 | END DO |
---|
339 | |
---|
340 | #if defined key_trc_diatrd |
---|
341 | DO jk = 1,jpk |
---|
342 | DO jj = 2,jpjm1 |
---|
343 | DO ji = 2,jpim1 |
---|
344 | zbtr = 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) ) |
---|
345 | zgm = zbtr * trn(ji,jj,jk,jn) * & |
---|
346 | & ( zun(ji ,jj,jk) * e2u(ji ,jj) * fse3u(ji ,jj,jk) & |
---|
347 | & - zun(ji-1,jj,jk) * e2u(ji-1,jj) * fse3u(ji-1,jj,jk) ) |
---|
348 | |
---|
349 | zgz = zbtr * trn(ji,jj,jk,jn) * & |
---|
350 | & ( zvn(ji,jj ,jk) * e1v(ji,jj ) * fse3v(ji,jj ,jk) & |
---|
351 | & - zvn(ji,jj-1,jk) * e1v(ji,jj-1) * fse3v(ji,jj-1,jk) ) |
---|
352 | |
---|
353 | IF (luttrd(jn)) trtrd(ji,jj,jk,ikeep(jn),1) = trtrd(ji,jj,jk,ikeep(jn),1) + zgm |
---|
354 | IF (luttrd(jn)) trtrd(ji,jj,jk,ikeep(jn),2) = trtrd(ji,jj,jk,ikeep(jn),2) + zgz |
---|
355 | IF (luttrd(jn)) trtrd(ji,jj,jk,ikeep(jn),3) = trtrd(ji,jj,jk,ikeep(jn),3) & |
---|
356 | & - trn(ji,jj,jk,jn) * hdivn(ji,jj,jk) |
---|
357 | END DO |
---|
358 | END DO |
---|
359 | END DO |
---|
360 | |
---|
361 | ! Lateral boundary conditions on trtrd: |
---|
362 | |
---|
363 | IF (luttrd(jn)) CALL lbc_lnk( trtrd(:,:,:,ikeep(jn),1), 'T', 1. ) |
---|
364 | IF (luttrd(jn)) CALL lbc_lnk( trtrd(:,:,:,ikeep(jn),2), 'T', 1. ) |
---|
365 | IF (luttrd(jn)) CALL lbc_lnk( trtrd(:,:,:,ikeep(jn),3), 'T', 1. ) |
---|
366 | #endif |
---|
367 | |
---|
368 | ! 4. Save the advective trends for diagnostics |
---|
369 | ! -------------------------------------------- |
---|
370 | ! Warning : mass fluxes should probably be converted into advection |
---|
371 | ! terms in the computations below ??? |
---|
372 | |
---|
373 | IF( l_trdtrc ) THEN |
---|
374 | |
---|
375 | ! 4.1) Passive tracer ZONAL advection trends |
---|
376 | ztrtrd(:,:,:) = 0.e0 |
---|
377 | DO jk = 1, jpkm1 |
---|
378 | DO jj = 2, jpjm1 |
---|
379 | DO ji = fs_2, fs_jpim1 ! vector opt. |
---|
380 | zbtr = 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) ) |
---|
381 | ztrtrd(ji,jj,jk) = - ( ztu(ji,jj,jk) - ztu(ji-1,jj,jk) ) * zbtr |
---|
382 | END DO |
---|
383 | END DO |
---|
384 | END DO |
---|
385 | |
---|
386 | IF (luttrd(jn)) CALL trd_mod_trc(ztrtrd, jn, jptrc_trd_xad, kt) ! <<< ADD TO PREVIOUSLY COMPUTED |
---|
387 | |
---|
388 | ! 4.2) Passive tracer MERIDIONAL advection trends |
---|
389 | ztrtrd(:,:,:) = 0.e0 |
---|
390 | DO jk = 1, jpkm1 |
---|
391 | DO jj = 2, jpjm1 |
---|
392 | DO ji = fs_2, fs_jpim1 ! vector opt. |
---|
393 | zbtr = 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) ) |
---|
394 | ztrtrd(ji,jj,jk) = - ( ztv(ji,jj,jk) - ztv(ji,jj-1,jk) ) * zbtr |
---|
395 | END DO |
---|
396 | END DO |
---|
397 | END DO |
---|
398 | |
---|
399 | IF (luttrd(jn)) CALL trd_mod_trc(ztrtrd, jn, jptrc_trd_yad, kt) ! <<< ADD TO PREVIOUSLY COMPUTED |
---|
400 | |
---|
401 | ! 4.3) Passive tracer VERTICAL advection trends |
---|
402 | ztrtrd(:,:,:) = 0.e0 |
---|
403 | DO jk = 1, jpkm1 |
---|
404 | DO jj = 2, jpjm1 |
---|
405 | DO ji = fs_2, fs_jpim1 ! vector opt. |
---|
406 | zbtr = 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) ) |
---|
407 | ztrtrd(ji,jj,jk) = - ( ztw(ji,jj,jk) - ztw(ji,jj,jk+1) ) * zbtr |
---|
408 | END DO |
---|
409 | END DO |
---|
410 | END DO |
---|
411 | |
---|
412 | IF (luttrd(jn)) CALL trd_mod_trc(ztrtrd, jn, jptrc_trd_zad, kt) ! <<< ADD TO PREVIOUSLY COMPUTED |
---|
413 | |
---|
414 | ENDIF |
---|
415 | |
---|
416 | |
---|
417 | END DO |
---|
418 | |
---|
419 | IF( l_trdtrc ) DEALLOCATE( ztrtrd ) |
---|
420 | |
---|
421 | IF(ln_ctl) THEN ! print mean trends (used for debugging) |
---|
422 | WRITE(charout, FMT="('tvd - adv')") |
---|
423 | CALL prt_ctl_trc_info(charout) |
---|
424 | CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm,clinfo2='trd') |
---|
425 | ENDIF |
---|
426 | |
---|
427 | END SUBROUTINE trc_adv_tvd |
---|
428 | |
---|
429 | |
---|
430 | SUBROUTINE nonosc( pbef, paa, pbb, pcc, paft, prdt ) |
---|
431 | !!--------------------------------------------------------------------- |
---|
432 | !! *** ROUTINE nonosc *** |
---|
433 | !! |
---|
434 | !! ** Purpose : compute monotonic tracer fluxes from the upstream |
---|
435 | !! scheme and the before field by a nonoscillatory algorithm |
---|
436 | !! |
---|
437 | !! ** Method : ... ??? |
---|
438 | !! warning : pbef and paft must be masked, but the boundaries |
---|
439 | !! conditions on the fluxes are not necessary zalezak (1979) |
---|
440 | !! drange (1995) multi-dimensional forward-in-time and upstream- |
---|
441 | !! in-space based differencing for fluid |
---|
442 | !! |
---|
443 | !! History : |
---|
444 | !! ! 97-04 (L. Mortier) Original code |
---|
445 | !! ! 00-02 (H. Loukos) rewritting for opa8 |
---|
446 | !! ! 00-10 (M.A Foujols, E. Kestenare) lateral b.c. |
---|
447 | !! ! 01-03 (E. Kestenare) add key_passivetrc |
---|
448 | !! ! 01-07 (E. Durand G. Madec) adapted for T & S |
---|
449 | !! 8.5 ! 02-06 (G. Madec) F90: Free form and module |
---|
450 | !!---------------------------------------------------------------------- |
---|
451 | !! * Arguments |
---|
452 | REAL(wp), INTENT( in ) :: & |
---|
453 | prdt ! ??? |
---|
454 | REAL(wp), DIMENSION (jpi,jpj,jpk), INTENT( inout ) :: & |
---|
455 | pbef, & ! before field |
---|
456 | paft, & ! after field |
---|
457 | paa, & ! monotonic flux in the i direction |
---|
458 | pbb, & ! monotonic flux in the j direction |
---|
459 | pcc ! monotonic flux in the k direction |
---|
460 | |
---|
461 | !! * Local declarations |
---|
462 | INTEGER :: ji, jj, jk ! dummy loop indices |
---|
463 | INTEGER :: ikm1 |
---|
464 | REAL(wp), DIMENSION (jpi,jpj,jpk) :: zbetup, zbetdo |
---|
465 | REAL(wp) :: zpos, zneg, zbt, za, zb, zc, zbig, zrtrn, z2dtt |
---|
466 | !!---------------------------------------------------------------------- |
---|
467 | |
---|
468 | zbig = 1.e+40 |
---|
469 | zrtrn = 1.e-15 |
---|
470 | zbetup(:,:,:) = 0.e0 ; zbetdo(:,:,:) = 0.e0 |
---|
471 | |
---|
472 | ! Search local extrema |
---|
473 | ! -------------------- |
---|
474 | ! large negative value (-zbig) inside land |
---|
475 | ! large negative value (-zbig) inside land |
---|
476 | pbef(:,:,:) = pbef(:,:,:) * tmask(:,:,:) - zbig * ( 1.e0 - tmask(:,:,:) ) |
---|
477 | paft(:,:,:) = paft(:,:,:) * tmask(:,:,:) - zbig * ( 1.e0 - tmask(:,:,:) ) |
---|
478 | ! search maximum in neighbourhood |
---|
479 | DO jk = 1, jpkm1 |
---|
480 | ikm1 = MAX(jk-1,1) |
---|
481 | DO jj = 2, jpjm1 |
---|
482 | DO ji = fs_2, fs_jpim1 ! vector opt. |
---|
483 | zbetup(ji,jj,jk) = MAX( pbef(ji ,jj ,jk ), paft(ji ,jj ,jk ), & |
---|
484 | & pbef(ji-1,jj ,jk ), pbef(ji+1,jj ,jk ), & |
---|
485 | & paft(ji-1,jj ,jk ), paft(ji+1,jj ,jk ), & |
---|
486 | & pbef(ji ,jj-1,jk ), pbef(ji ,jj+1,jk ), & |
---|
487 | & paft(ji ,jj-1,jk ), paft(ji ,jj+1,jk ), & |
---|
488 | & pbef(ji ,jj ,ikm1), pbef(ji ,jj ,jk+1), & |
---|
489 | & paft(ji ,jj ,ikm1), paft(ji ,jj ,jk+1) ) |
---|
490 | END DO |
---|
491 | END DO |
---|
492 | END DO |
---|
493 | ! large positive value (+zbig) inside land |
---|
494 | pbef(:,:,:) = pbef(:,:,:) * tmask(:,:,:) + zbig * ( 1.e0 - tmask(:,:,:) ) |
---|
495 | paft(:,:,:) = paft(:,:,:) * tmask(:,:,:) + zbig * ( 1.e0 - tmask(:,:,:) ) |
---|
496 | ! search minimum in neighbourhood |
---|
497 | DO jk = 1, jpkm1 |
---|
498 | ikm1 = MAX(jk-1,1) |
---|
499 | DO jj = 2, jpjm1 |
---|
500 | DO ji = fs_2, fs_jpim1 ! vector opt. |
---|
501 | zbetdo(ji,jj,jk) = MIN( pbef(ji ,jj ,jk ), paft(ji ,jj ,jk ), & |
---|
502 | & pbef(ji-1,jj ,jk ), pbef(ji+1,jj ,jk ), & |
---|
503 | & paft(ji-1,jj ,jk ), paft(ji+1,jj ,jk ), & |
---|
504 | & pbef(ji ,jj-1,jk ), pbef(ji ,jj+1,jk ), & |
---|
505 | & paft(ji ,jj-1,jk ), paft(ji ,jj+1,jk ), & |
---|
506 | & pbef(ji ,jj ,ikm1), pbef(ji ,jj ,jk+1), & |
---|
507 | & paft(ji ,jj ,ikm1), paft(ji ,jj ,jk+1) ) |
---|
508 | END DO |
---|
509 | END DO |
---|
510 | END DO |
---|
511 | |
---|
512 | ! restore masked values to zero |
---|
513 | pbef(:,:,:) = pbef(:,:,:) * tmask(:,:,:) |
---|
514 | paft(:,:,:) = paft(:,:,:) * tmask(:,:,:) |
---|
515 | |
---|
516 | |
---|
517 | ! 2. Positive and negative part of fluxes and beta terms |
---|
518 | ! ------------------------------------------------------ |
---|
519 | |
---|
520 | DO jk = 1, jpkm1 |
---|
521 | z2dtt = prdt * rdttra(jk) * FLOAT(ndttrc) |
---|
522 | DO jj = 2, jpjm1 |
---|
523 | DO ji = fs_2, fs_jpim1 ! vector opt. |
---|
524 | ! positive & negative part of the flux |
---|
525 | zpos = MAX( 0., paa(ji-1,jj ,jk ) ) - MIN( 0., paa(ji ,jj ,jk ) ) & |
---|
526 | & + MAX( 0., pbb(ji ,jj-1,jk ) ) - MIN( 0., pbb(ji ,jj ,jk ) ) & |
---|
527 | & + MAX( 0., pcc(ji ,jj ,jk+1) ) - MIN( 0., pcc(ji ,jj ,jk ) ) |
---|
528 | zneg = MAX( 0., paa(ji ,jj ,jk ) ) - MIN( 0., paa(ji-1,jj ,jk ) ) & |
---|
529 | & + MAX( 0., pbb(ji ,jj ,jk ) ) - MIN( 0., pbb(ji ,jj-1,jk ) ) & |
---|
530 | & + MAX( 0., pcc(ji ,jj ,jk ) ) - MIN( 0., pcc(ji ,jj ,jk+1) ) |
---|
531 | ! up & down beta terms |
---|
532 | zbt = e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) / z2dtt |
---|
533 | zbetup(ji,jj,jk) = ( zbetup(ji,jj,jk) - paft(ji,jj,jk) ) / (zpos+zrtrn) * zbt |
---|
534 | zbetdo(ji,jj,jk) = ( paft(ji,jj,jk) - zbetdo(ji,jj,jk) ) / (zneg+zrtrn) * zbt |
---|
535 | END DO |
---|
536 | END DO |
---|
537 | END DO |
---|
538 | |
---|
539 | ! lateral boundary condition on zbetup & zbetdo (unchanged sign) |
---|
540 | CALL lbc_lnk( zbetup, 'T', 1. ) |
---|
541 | CALL lbc_lnk( zbetdo, 'T', 1. ) |
---|
542 | |
---|
543 | |
---|
544 | ! 3. monotonic flux in the i direction, i.e. paa |
---|
545 | ! ---------------------------------------------- |
---|
546 | DO jk = 1, jpkm1 |
---|
547 | DO jj = 2, jpjm1 |
---|
548 | DO ji = fs_2, fs_jpim1 ! vector opt. |
---|
549 | zc = paa(ji,jj,jk) |
---|
550 | IF( zc >= 0. ) THEN |
---|
551 | za = MIN( 1., zbetdo(ji,jj,jk), zbetup(ji+1,jj,jk) ) |
---|
552 | paa(ji,jj,jk) = za * zc |
---|
553 | ELSE |
---|
554 | zb = MIN( 1., zbetup(ji,jj,jk), zbetdo(ji+1,jj,jk) ) |
---|
555 | paa(ji,jj,jk) = zb * zc |
---|
556 | ENDIF |
---|
557 | END DO |
---|
558 | END DO |
---|
559 | END DO |
---|
560 | |
---|
561 | ! lateral boundary condition on paa (changed sign) |
---|
562 | CALL lbc_lnk( paa, 'U', -1. ) |
---|
563 | |
---|
564 | |
---|
565 | ! 4. monotonic flux in the j direction, i.e. pbb |
---|
566 | ! ---------------------------------------------- |
---|
567 | DO jk = 1, jpkm1 |
---|
568 | DO jj = 2, jpjm1 |
---|
569 | DO ji = fs_2, fs_jpim1 ! vector opt. |
---|
570 | zc = pbb(ji,jj,jk) |
---|
571 | IF( zc >= 0. ) THEN |
---|
572 | za = MIN( 1., zbetdo(ji,jj,jk), zbetup(ji,jj+1,jk) ) |
---|
573 | pbb(ji,jj,jk) = za * zc |
---|
574 | ELSE |
---|
575 | zb = MIN( 1., zbetup(ji,jj,jk), zbetdo(ji,jj+1,jk) ) |
---|
576 | pbb(ji,jj,jk) = zb * zc |
---|
577 | ENDIF |
---|
578 | END DO |
---|
579 | END DO |
---|
580 | END DO |
---|
581 | |
---|
582 | ! lateral boundary condition on pbb (changed sign) |
---|
583 | CALL lbc_lnk( pbb, 'V', -1. ) |
---|
584 | |
---|
585 | |
---|
586 | ! monotonic flux in the k direction, i.e. pcc |
---|
587 | ! ------------------------------------------- |
---|
588 | DO jk = 2, jpkm1 |
---|
589 | DO jj = 2, jpjm1 |
---|
590 | DO ji = fs_2, fs_jpim1 ! vector opt. |
---|
591 | zc = pcc(ji,jj,jk) |
---|
592 | IF( zc >= 0. ) THEN |
---|
593 | za = MIN( 1., zbetdo(ji,jj,jk), zbetup(ji,jj,jk-1) ) |
---|
594 | pcc(ji,jj,jk) = za * zc |
---|
595 | ELSE |
---|
596 | zb = MIN( 1., zbetup(ji,jj,jk), zbetdo(ji,jj,jk-1) ) |
---|
597 | pcc(ji,jj,jk) = zb * zc |
---|
598 | ENDIF |
---|
599 | END DO |
---|
600 | END DO |
---|
601 | END DO |
---|
602 | |
---|
603 | ! lateral boundary condition on pcc (unchanged sign) |
---|
604 | CALL lbc_lnk( pcc, 'W', 1. ) |
---|
605 | |
---|
606 | END SUBROUTINE nonosc |
---|
607 | |
---|
608 | #else |
---|
609 | !!---------------------------------------------------------------------- |
---|
610 | !! Default option Empty module |
---|
611 | !!---------------------------------------------------------------------- |
---|
612 | CONTAINS |
---|
613 | SUBROUTINE trc_adv_tvd( kt ) |
---|
614 | INTEGER, INTENT(in) :: kt |
---|
615 | WRITE(*,*) 'trc_adv_tvd: You should not have seen this print! error?', kt |
---|
616 | END SUBROUTINE trc_adv_tvd |
---|
617 | #endif |
---|
618 | |
---|
619 | !!====================================================================== |
---|
620 | END MODULE trcadv_tvd |
---|