New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p5zprod.F90 in branches/CNRS/dev_r4826_PISCES_QUOTA/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z – NEMO

source: branches/CNRS/dev_r4826_PISCES_QUOTA/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z/p5zprod.F90 @ 5288

Last change on this file since 5288 was 5288, checked in by aumont, 9 years ago

various bug fixes and updates of PISCES quota
  • Property svn:executable set to *
File size: 35.5 KB
Line 
1MODULE p5zprod
2   !!======================================================================
3   !!                         ***  MODULE p5zprod  ***
4   !! TOP :  Growth Rate of the two phytoplanktons groups
5   !!======================================================================
6   !! History :   1.0  !  2004     (O. Aumont) Original code
7   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
8   !!             3.4  !  2011-05  (O. Aumont, C. Ethe) New parameterization of light limitation
9   !!             3.6  !  2015-05  (O. Aumont) PISCES quota
10   !!----------------------------------------------------------------------
11#if defined key_pisces_quota
12   !!----------------------------------------------------------------------
13   !!   'key_pisces_quota'     PISCES bio-model with variable stoichiometry
14   !!----------------------------------------------------------------------
15   !!   p5z_prod       :   Compute the growth Rate of the two phytoplanktons groups
16   !!   p5z_prod_init  :   Initialization of the parameters for growth
17   !!   p5z_prod_alloc :   Allocate variables for growth
18   !!----------------------------------------------------------------------
19   USE oce_trc         !  shared variables between ocean and passive tracers
20   USE trc             !  passive tracers common variables
21   USE sms_pisces      !  PISCES Source Minus Sink variables
22   USE p4zopt          !  optical model
23   USE p5zlim          !  Co-limitations of differents nutrients
24   USE prtctl_trc      !  print control for debugging
25   USE iom             !  I/O manager
26
27   IMPLICIT NONE
28   PRIVATE
29
30   PUBLIC   p5z_prod         ! called in p5zbio.F90
31   PUBLIC   p5z_prod_init    ! called in trcsms_pisces.F90
32   PUBLIC   p5z_prod_alloc
33
34   !! * Shared module variables
35   REAL(wp), PUBLIC ::  pislope         !:
36   REAL(wp), PUBLIC ::  pislopep        !:
37   REAL(wp), PUBLIC ::  pislope2        !:
38   REAL(wp), PUBLIC ::  xadap           !:
39   REAL(wp), PUBLIC ::  excret          !:
40   REAL(wp), PUBLIC ::  excretp         !:
41   REAL(wp), PUBLIC ::  excret2         !:
42   REAL(wp), PUBLIC ::  bresp           !:
43   REAL(wp), PUBLIC ::  thetanpm        !:
44   REAL(wp), PUBLIC ::  thetannm        !:
45   REAL(wp), PUBLIC ::  thetandm        !:
46   REAL(wp), PUBLIC ::  chlcmin         !:
47   REAL(wp), PUBLIC ::  grosip          !:
48   REAL(wp), PUBLIC ::  zlimmxln        !:
49   REAL(wp), PUBLIC ::  zlimmxlp        !:
50   REAL(wp), PUBLIC ::  zlimmxld        !:
51
52   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   prmaxn   !: optimal production = f(temperature)
53   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   prmaxp   !: optimal production = f(temperature)
54   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   prmaxd   !: optimal production = f(temperature)
55   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   zdaylen
56   
57   REAL(wp) :: r1_rday                !: 1 / rday
58   REAL(wp) :: texcret                !: 1 - excret
59   REAL(wp) :: texcretp               !: 1 - excretp
60   REAL(wp) :: texcret2               !: 1 - excret2       
61
62
63   !!* Substitution
64#  include "top_substitute.h90"
65   !!----------------------------------------------------------------------
66   !! NEMO/TOP 3.3 , NEMO Consortium (2010)
67   !! $Id: p4zprod.F90 3160 2011-11-20 14:27:18Z cetlod $
68   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
69   !!----------------------------------------------------------------------
70CONTAINS
71
72   SUBROUTINE p5z_prod( kt , jnt )
73      !!---------------------------------------------------------------------
74      !!                     ***  ROUTINE p5z_prod  ***
75      !!
76      !! ** Purpose :   Compute the phytoplankton production depending on
77      !!              light, temperature and nutrient availability
78      !!
79      !! ** Method  : - ???
80      !!---------------------------------------------------------------------
81      !
82      INTEGER, INTENT(in) :: kt, jnt
83      !
84      INTEGER  ::   ji, jj, jk
85      REAL(wp) ::   zsilfac, znanotot, zpicotot, zdiattot, zconctemp, zconctemp2
86      REAL(wp) ::   zration, zratiop, zratiof, zmax, zmax2, zsilim, ztn, zadap
87      REAL(wp) ::   zpronmax, zpropmax, zprofmax, zrat
88      REAL(wp) ::   zlim, zsilfac2, zsiborn, zprod, zprontot, zproptot, zprodtot
89      REAL(wp) ::   zmxltst, zmxlday, zprnutmax
90      REAL(wp) ::   zpislopen, zpislopep, zpislope2n
91      REAL(wp) ::   zrum, zcodel, zargu, zval
92      REAL(wp) ::   zrfact2
93      CHARACTER (len=25) :: charout
94      REAL(wp), POINTER, DIMENSION(:,:  ) :: zmixnano, zmixpico, zmixdiat, zstrn
95      REAL(wp), POINTER, DIMENSION(:,:,:) :: zpislopead, zpislopeadp, zpislopead2
96      REAL(wp), POINTER, DIMENSION(:,:,:) :: zprbio, zprpic, zprdia, zysopt
97      REAL(wp), POINTER, DIMENSION(:,:,:) :: zprchln, zprchlp, zprchld
98      REAL(wp), POINTER, DIMENSION(:,:,:) :: zprorcan, zprorcap, zprorcad 
99      REAL(wp), POINTER, DIMENSION(:,:,:) :: zprofed, zprofep, zprofen
100      REAL(wp), POINTER, DIMENSION(:,:,:) :: zprochln, zprochlp, zprochld
101      REAL(wp), POINTER, DIMENSION(:,:,:) :: zpronew, zpronewp, zpronewd
102      REAL(wp), POINTER, DIMENSION(:,:,:) :: zproreg, zproregp, zproregd
103      REAL(wp), POINTER, DIMENSION(:,:,:) :: zpropo4, zpropo4p, zpropo4d
104      REAL(wp), POINTER, DIMENSION(:,:,:) :: zprodopn, zprodopp, zprodopd
105      REAL(wp), POINTER, DIMENSION(:,:,:) :: zrespn, zrespp, zrespd, zprnut
106      REAL(wp), POINTER, DIMENSION(:,:,:) :: zcroissn, zcroissp, zcroissd
107      !!---------------------------------------------------------------------
108      !
109      IF( nn_timing == 1 )  CALL timing_start('p5z_prod')
110      !
111      !  Allocate temporary workspace
112      CALL wrk_alloc( jpi, jpj,      zmixnano, zmixpico, zmixdiat, zstrn )
113      CALL wrk_alloc( jpi, jpj, jpk, zpislopead, zpislopeadp, zpislopead2, zysopt ) 
114      CALL wrk_alloc( jpi, jpj, jpk, zprdia, zprpic, zprbio, zprorcan, zprorcap, zprorcad )
115      CALL wrk_alloc( jpi, jpj, jpk, zprofed, zprofep, zprofen, zprochln, zprochlp, zprochld )
116      CALL wrk_alloc( jpi, jpj, jpk, zpronew, zpronewp, zpronewd, zproreg, zproregp, zproregd )
117      CALL wrk_alloc( jpi, jpj, jpk, zpropo4, zpropo4p, zpropo4d, zrespn, zrespp, zrespd, zprnut )
118      CALL wrk_alloc( jpi, jpj, jpk, zprchln, zprchlp, zprchld, zprodopn, zprodopp, zprodopd )
119      CALL wrk_alloc( jpi, jpj, jpk, zcroissp, zcroissn, zcroissd )
120      !
121      zprorcan(:,:,:) = 0._wp
122      zprorcap(:,:,:) = 0._wp
123      zprorcad(:,:,:) = 0._wp
124      zprofed (:,:,:) = 0._wp
125      zprofep (:,:,:) = 0._wp
126      zprofen (:,:,:) = 0._wp
127      zprochln(:,:,:) = 0._wp
128      zprochlp(:,:,:) = 0._wp
129      zprochld(:,:,:) = 0._wp
130      zpronew (:,:,:) = 0._wp
131      zpronewp(:,:,:) = 0._wp
132      zpronewd(:,:,:) = 0._wp
133      zproreg (:,:,:) = 0._wp
134      zproregp(:,:,:) = 0._wp
135      zproregd(:,:,:) = 0._wp
136      zpropo4 (:,:,:) = 0._wp
137      zpropo4p(:,:,:) = 0._wp
138      zpropo4d(:,:,:) = 0._wp
139      zprdia  (:,:,:) = 0._wp
140      zprpic  (:,:,:) = 0._wp
141      zprbio  (:,:,:) = 0._wp
142      zysopt  (:,:,:) = 0._wp
143      zrespn   (:,:,:) = 0._wp
144      zrespp   (:,:,:) = 0._wp
145      zrespd   (:,:,:) = 0._wp
146
147      ! Computation of the optimal production
148      prmaxn(:,:,:) = ( 0.8_wp * (1. + zpsino3 * qnpmax ) ) * r1_rday * tgfunc(:,:,:)
149      prmaxp(:,:,:) = 0.6 / 0.8 * prmaxn(:,:,:) 
150      prmaxd(:,:,:) = prmaxn(:,:,:) 
151      zprnut(:,:,:) = 0.8_wp * r1_rday * tgfunc(:,:,:)
152
153      IF( lk_degrad )  THEN
154         prmaxn(:,:,:) = prmaxn(:,:,:) * facvol(:,:,:) 
155         prmaxp(:,:,:) = prmaxp(:,:,:) * facvol(:,:,:)
156         prmaxd(:,:,:) = prmaxd(:,:,:) * facvol(:,:,:)
157      ENDIF
158
159      ! compute the day length depending on latitude and the day
160      zrum = REAL( nday_year - 80, wp ) / REAL( nyear_len(1), wp )
161      zcodel = ASIN(  SIN( zrum * rpi * 2._wp ) * SIN( rad * 23.5_wp )  )
162
163      ! day length in hours
164      zstrn(:,:) = 0.
165      DO jj = 1, jpj
166         DO ji = 1, jpi
167            zargu = TAN( zcodel ) * TAN( gphit(ji,jj) * rad )
168            zargu = MAX( -1., MIN(  1., zargu ) )
169            zstrn(ji,jj) = MAX( 0.0, 24. - 2. * ACOS( zargu ) / rad / 15. )
170         END DO
171      END DO
172
173         ! Impact of the day duration on phytoplankton growth
174      DO jk = 1, jpkm1
175         DO jj = 1 ,jpj
176            DO ji = 1, jpi
177               IF( etot(ji,jj,jk) > 1.E-3 ) THEN
178                  zval = MAX( 1., zstrn(ji,jj) )
179                  zval = 1.5 * zval / (12. + zval)
180                  zprbio(ji,jj,jk) = prmaxn(ji,jj,jk) * zval
181                  zprpic(ji,jj,jk) = prmaxp(ji,jj,jk) * zval
182                  zprdia(ji,jj,jk) = prmaxd(ji,jj,jk) * zval
183               ENDIF
184            END DO
185         END DO
186      END DO
187
188      ! Maximum light intensity
189      zdaylen(:,:) = MAX(1., zstrn(:,:)) / 24.
190      WHERE( zstrn(:,:) < 1.e0 ) zstrn(:,:) = 24.
191      zstrn(:,:) = 24. / zstrn(:,:)
192
193      DO jk = 1, jpkm1
194!CDIR NOVERRCHK
195         DO jj = 1, jpj
196!CDIR NOVERRCHK
197            DO ji = 1, jpi
198                  ! Computation of the P-I slope for nanos and diatoms
199               IF( etot(ji,jj,jk) > 1.E-3 ) THEN
200                  ztn         = MAX( 0., tsn(ji,jj,jk,jp_tem) - 15. )
201                  zadap       = xadap * ztn / ( 2.+ ztn )
202                  znanotot    = enano(ji,jj,jk) * zstrn(ji,jj)
203                  zpicotot    = epico(ji,jj,jk) * zstrn(ji,jj)
204                  zdiattot    = ediat(ji,jj,jk) * zstrn(ji,jj)
205                  !
206                  zpislopead (ji,jj,jk) = pislope * trn(ji,jj,jk,jpnch)    &
207                  &                       /( trn(ji,jj,jk,jpphy) * 12. + rtrn)
208                  zpislopeadp(ji,jj,jk) = pislopep * ( 1. + zadap * EXP( -0.5 * zpicotot ) )   &
209                  &                       * trn(ji,jj,jk,jppch) /( trn(ji,jj,jk,jppic) * 12. + rtrn)
210                  zpislopead2(ji,jj,jk) = pislope2 * trn(ji,jj,jk,jpdch)    &
211                     &                    /( trn(ji,jj,jk,jpdia) * 12. + rtrn)
212                  zpislopen   = zpislopead (ji,jj,jk) / ( prmaxn(ji,jj,jk) * rday * xlimphy(ji,jj,jk) + rtrn )
213                  zpislopep   = zpislopeadp(ji,jj,jk) / ( prmaxp(ji,jj,jk) * rday * xlimpic(ji,jj,jk) + rtrn )
214                  zpislope2n  = zpislopead2(ji,jj,jk) / ( prmaxd(ji,jj,jk) * rday * xlimdia(ji,jj,jk) + rtrn )
215
216                  ! Computation of production function for Carbon
217                  !  ---------------------------------------------
218                  zprbio(ji,jj,jk) = zprbio(ji,jj,jk) * ( 1.- EXP( -zpislopen  * znanotot )  )
219                  zprpic(ji,jj,jk) = zprpic(ji,jj,jk) * ( 1.- EXP( -zpislopep  * zpicotot )  )
220                  zprdia(ji,jj,jk) = zprdia(ji,jj,jk) * ( 1.- EXP( -zpislope2n * zdiattot )  )
221
222                  ! Computation of production function for Chlorophyll
223                  !  -------------------------------------------------
224                  zprchln(ji,jj,jk) = prmaxn(ji,jj,jk) * ( 1.- EXP( -zpislopen  * enano(ji,jj,jk) )  )
225                  zprchlp(ji,jj,jk) = prmaxp(ji,jj,jk) * ( 1.- EXP( -zpislopep  * epico(ji,jj,jk) )  )
226                  zprchld(ji,jj,jk) = prmaxd(ji,jj,jk) * ( 1.- EXP( -zpislope2n * ediat(ji,jj,jk) )  )
227               ENDIF
228            END DO
229         END DO
230      END DO
231
232      DO jk = 1, jpkm1
233         DO jj = 1, jpj
234            DO ji = 1, jpi
235              IF( etot(ji,jj,jk) > 1.E-3 ) THEN
236                  !    Si/C of diatoms
237                  !    ------------------------
238                  !    Si/C increases with iron stress and silicate availability
239                  !    Si/C is arbitrariliy increased for very high Si concentrations
240                  !    to mimic the very high ratios observed in the Southern Ocean (silpot2)
241                  zlim  = trn(ji,jj,jk,jpsil) / ( trn(ji,jj,jk,jpsil) + xksi1 )
242                  zsilim = MIN( zprdia(ji,jj,jk) / ( prmaxd(ji,jj,jk) + rtrn ), xlimsi(ji,jj,jk) )
243                  zsilfac = 4.4 * EXP( -4.23 * zsilim ) * MAX( 0.e0, MIN( 1., 2.2 * ( zlim - 0.5 ) )  ) + 1.e0
244                  zsiborn = trn(ji,jj,jk,jpsil) * trn(ji,jj,jk,jpsil) * trn(ji,jj,jk,jpsil)
245                  IF (gphit(ji,jj) < -30 ) THEN
246                    zsilfac2 = 1. + 2. * zsiborn / ( zsiborn + xksi2**3 )
247                  ELSE
248                    zsilfac2 = 1. +      zsiborn / ( zsiborn + xksi2**3 )
249                  ENDIF
250                  zysopt(ji,jj,jk) = grosip * zlim * zsilfac * zsilfac2
251              ENDIF
252            END DO
253         END DO
254      END DO
255
256      !  Computation of the limitation term due to a mixed layer deeper than the euphotic depth
257      DO jj = 1, jpj
258         DO ji = 1, jpi
259            zmxltst = MAX( 0.e0, hmld(ji,jj) - heup_01(ji,jj) )
260            zmxlday = zmxltst * zmxltst * r1_rday
261            zmixnano(ji,jj) = 1. - zmxlday / ( zlimmxln + zmxlday )
262            zmixpico(ji,jj) = 1. - zmxlday / ( zlimmxlp + zmxlday )
263            zmixdiat(ji,jj) = 1. - zmxlday / ( zlimmxld + zmxlday )
264         END DO
265      END DO
266 
267      !  Mixed-layer effect on production                                                                               
268      DO jk = 1, jpkm1
269         DO jj = 1, jpj
270            DO ji = 1, jpi
271               IF( fsdepw(ji,jj,jk+1) <= hmld(ji,jj) ) THEN
272                  zprbio(ji,jj,jk)  = zprbio(ji,jj,jk) * zmixnano(ji,jj)
273                  zprpic(ji,jj,jk)  = zprpic(ji,jj,jk) * zmixpico(ji,jj)
274                  zprdia(ji,jj,jk)  = zprdia(ji,jj,jk) * zmixdiat(ji,jj)
275                  zprchln(ji,jj,jk) = zprchln(ji,jj,jk) * zmixnano(ji,jj)
276                  zprchlp(ji,jj,jk) = zprchlp(ji,jj,jk) * zmixpico(ji,jj)
277                  zprchld(ji,jj,jk) = zprchld(ji,jj,jk) * zmixdiat(ji,jj)
278               ENDIF
279            END DO
280         END DO
281      END DO
282
283      ! Computation of the various production terms of nanophytoplankton
284      DO jk = 1, jpkm1
285         DO jj = 1, jpj
286            DO ji = 1, jpi
287               IF( etot(ji,jj,jk) > 1.E-3 ) THEN
288                  !  production terms for nanophyto.
289                  zprorcan(ji,jj,jk) = zprbio(ji,jj,jk)  * xlimphy(ji,jj,jk) * trn(ji,jj,jk,jpphy) * rfact2
290                  !
291                  zration = trn(ji,jj,jk,jpnph) / ( trn(ji,jj,jk,jpphy) + rtrn )
292                  zratiop = trn(ji,jj,jk,jppph) / ( trn(ji,jj,jk,jpphy) + rtrn )
293                  zratiof = trn(ji,jj,jk,jpnfe) / ( trn(ji,jj,jk,jpphy) + rtrn )
294                  zprnutmax = zprnut(ji,jj,jk) * fvnuptk(ji,jj,jk) / rno3 * trn(ji,jj,jk,jpphy) * rfact2
295                  ! Uptake of nitrogen
296                  zrat = MIN( 1., zration / (xqnnmax(ji,jj,jk) + rtrn) ) 
297                  zmax = MAX(0., MIN(1., (1. - zrat)/ (1.05 - zrat) * 1.05))
298                  zpronmax = zprnutmax * zmax * MAX(0., MIN(1., ( zratiop - xqpnmin(ji,jj,jk) )   &
299                  &          / ( xqpnmax(ji,jj,jk) - xqpnmin(ji,jj,jk) ), xlimnfe(ji,jj,jk) ) )
300                  zpronew(ji,jj,jk) = zpronmax * zdaylen(ji,jj) * xnanono3(ji,jj,jk)
301                  zproreg(ji,jj,jk) = zpronmax * xnanonh4(ji,jj,jk)
302                  ! Uptake of phosphorus
303                  zrat = MIN( 1., zratiop / (xqpnmax(ji,jj,jk) + rtrn) )
304                  zmax = MAX(0., MIN(1., (1. - zrat)/ (1.05 - zrat) * 1.05))
305                  zpropmax = zprnutmax * zmax * xlimnfe(ji,jj,jk)
306                  zpropo4(ji,jj,jk) = zpropmax * xnanopo4(ji,jj,jk)
307                  zprodopn(ji,jj,jk) = zpropmax * xnanodop(ji,jj,jk)
308                  ! Uptake of iron
309                  zrat = MIN( 1., zratiof / qfnmax )
310                  zmax = MAX(0., MIN(1., (1. - zrat)/ (1.05 - zrat) * 1.05))
311                  zprofmax = zprnutmax * qfnmax * zmax
312                  zprofen(ji,jj,jk) = zprofmax * xnanofer(ji,jj,jk) * ( 4. - 3.6 * xlimnfe(ji,jj,jk)    &
313                  &          / ( xlimnfe(ji,jj,jk) + 0.2 ) ) * (1. + 0.8 * xnanono3(ji,jj,jk) / ( rtrn  &
314                  &          + xnanono3(ji,jj,jk) + xnanonh4(ji,jj,jk) ) * (1. - xnanofer(ji,jj,jk) ) )
315               ENDIF
316            END DO
317         END DO
318      END DO
319
320      ! Computation of the various production terms of picophytoplankton
321      DO jk = 1, jpkm1
322         DO jj = 1, jpj
323            DO ji = 1, jpi
324               IF( etot(ji,jj,jk) > 1.E-3 ) THEN
325                  !  production terms for picophyto.
326                  zprorcap(ji,jj,jk) = zprpic(ji,jj,jk)  * xlimpic(ji,jj,jk) * trn(ji,jj,jk,jppic) * rfact2
327                  !
328                  zration = trn(ji,jj,jk,jpnpi) / ( trn(ji,jj,jk,jppic) + rtrn )
329                  zratiop = trn(ji,jj,jk,jpppi) / ( trn(ji,jj,jk,jppic) + rtrn )
330                  zratiof = trn(ji,jj,jk,jppfe) / ( trn(ji,jj,jk,jppic) + rtrn )
331                  zprnutmax = zprnut(ji,jj,jk) * fvpuptk(ji,jj,jk) / rno3 * trn(ji,jj,jk,jppic) * rfact2
332                  ! Uptake of nitrogen
333                  zrat = MIN( 1., zration / (xqnpmax(ji,jj,jk) + rtrn) )
334                  zmax = MAX(0., MIN(1., (1. - zrat)/ (1.05 - zrat) * 1.05))
335                  zpronmax = zprnutmax * zmax * MAX(0., MIN(1., ( zratiop - xqppmin(ji,jj,jk) )   &
336                  &          / ( xqppmax(ji,jj,jk) - xqppmin(ji,jj,jk) ), xlimpfe(ji,jj,jk) ) )
337                  zpronewp(ji,jj,jk) = zpronmax * zdaylen(ji,jj) * xpicono3(ji,jj,jk) 
338                  zproregp(ji,jj,jk) = zpronmax * xpiconh4(ji,jj,jk)
339                  ! Uptake of phosphorus
340                  zrat = MIN( 1., zratiop / (xqppmax(ji,jj,jk) + rtrn) )
341                  zmax = MAX(0., MIN(1., (1. - zrat)/ (1.05 - zrat) * 1.05))
342                  zpropmax = zprnutmax * zmax * xlimpfe(ji,jj,jk)
343                  zpropo4p(ji,jj,jk) = zpropmax * xpicopo4(ji,jj,jk)
344                  zprodopp(ji,jj,jk) = zpropmax * xpicodop(ji,jj,jk)
345                  ! Uptake of iron
346                  zrat = MIN( 1., zratiof / qfpmax )
347                  zmax = MAX(0., MIN(1., (1. - zrat)/ (1.05 - zrat) * 1.05))
348                  zprofmax = zprnutmax * qfpmax * zmax
349                  zprofep(ji,jj,jk) = zprofmax * xpicofer(ji,jj,jk) * ( 4. - 3.6 * xlimpfe(ji,jj,jk)   &
350                  &          / ( xlimpfe(ji,jj,jk) + 0.2 ) ) * (1. + 0.8 * xpicono3(ji,jj,jk) / ( rtrn   &
351                  &          + xpicono3(ji,jj,jk) + xpiconh4(ji,jj,jk) ) * (1. - xpicofer(ji,jj,jk) ) )
352               ENDIF
353            END DO
354         END DO
355      END DO
356
357      ! Computation of the various production terms of diatoms
358      DO jk = 1, jpkm1
359         DO jj = 1, jpj
360            DO ji = 1, jpi
361               IF( etot(ji,jj,jk) > 1.E-3 ) THEN
362                  !  production terms for diatomees
363                  zprorcad(ji,jj,jk) = zprdia(ji,jj,jk) * xlimdia(ji,jj,jk) * trn(ji,jj,jk,jpdia) * rfact2
364                  ! Computation of the respiration term according to pahlow
365                  ! & oschlies (2013)
366                  !
367                  zration = trn(ji,jj,jk,jpndi) / ( trn(ji,jj,jk,jpdia) + rtrn )
368                  zratiop = trn(ji,jj,jk,jppdi) / ( trn(ji,jj,jk,jpdia) + rtrn )
369                  zratiof = trn(ji,jj,jk,jpdfe) / ( trn(ji,jj,jk,jpdia) + rtrn )
370                  zprnutmax = zprnut(ji,jj,jk) * fvduptk(ji,jj,jk) / rno3 * trn(ji,jj,jk,jpdia) * rfact2
371                  ! Uptake of nitrogen
372                  zrat = MIN( 1., zration / (xqndmax(ji,jj,jk) + rtrn) )
373                  zmax = MAX(0., MIN(1., (1. - zrat)/ (1.05 - zrat) * 1.05)) 
374                  zpronmax = zprnutmax * zmax * MAX(0., MIN(1., ( zratiop - xqpdmin(ji,jj,jk) )   &
375                  &          / ( xqpdmax(ji,jj,jk) - xqpdmin(ji,jj,jk) ), xlimdfe(ji,jj,jk) ) )
376                  zpronewd(ji,jj,jk) = zpronmax * zdaylen(ji,jj) * xdiatno3(ji,jj,jk)
377                  zproregd(ji,jj,jk) = zpronmax * xdiatnh4(ji,jj,jk)
378                  ! Uptake of phosphorus
379                  zrat = MIN( 1., zratiop / (xqpdmax(ji,jj,jk) + rtrn) )
380                  zmax = MAX(0., MIN(1., (1. - zrat)/ (1.05 - zrat) * 1.05)) 
381                  zpropmax = zprnutmax * zmax * xlimdfe(ji,jj,jk)
382                  zpropo4d(ji,jj,jk) = zpropmax * xdiatpo4(ji,jj,jk)
383                  zprodopd(ji,jj,jk) = zpropmax * xdiatdop(ji,jj,jk)
384                  ! Uptake of iron
385                  zrat = MIN( 1., zratiof / qfdmax )
386                  zmax = MAX(0., MIN(1., (1. - zrat)/ (1.05 - zrat) * 1.05))
387                  zprofmax = zprnutmax * qfdmax * zmax
388                  zprofed(ji,jj,jk) = zprofmax * xdiatfer(ji,jj,jk) * ( 4. - 3.6 * xlimdfe(ji,jj,jk)     &
389                  &          / ( xlimdfe(ji,jj,jk) + 0.2 ) ) * (1. + 0.8 * xdiatno3(ji,jj,jk) / ( rtrn   &
390                  &          + xdiatno3(ji,jj,jk) + xdiatnh4(ji,jj,jk) ) * (1. - xdiatfer(ji,jj,jk) ) )
391               ENDIF
392            END DO
393         END DO
394      END DO
395
396      DO jk = 1, jpkm1
397         DO jj = 1, jpj
398            DO ji = 1, jpi
399               IF( etot(ji,jj,jk) > 1.E-3 ) THEN
400                     !  production terms for nanophyto. ( chlorophyll )
401                  zprod = rday * (zpronew(ji,jj,jk) + zproreg(ji,jj,jk)) * zprchln(ji,jj,jk) * xlimphy(ji,jj,jk)
402                  zprochln(ji,jj,jk) = thetannm * zprod / ( zpislopead(ji,jj,jk) * enano(ji,jj,jk) +rtrn )
403                  zprochln(ji,jj,jk) = MAX(zprochln(ji,jj,jk), chlcmin * 12. * zprorcan (ji,jj,jk) )
404                     !  production terms for picophyto. ( chlorophyll )
405                  zprod = rday * (zpronewp(ji,jj,jk) + zproregp(ji,jj,jk)) * zprchlp(ji,jj,jk) * xlimpic(ji,jj,jk)
406                  zprochlp(ji,jj,jk) = thetanpm * zprod / ( zpislopeadp(ji,jj,jk) * epico(ji,jj,jk) +rtrn )
407                  zprochlp(ji,jj,jk) = MAX(zprochlp(ji,jj,jk), chlcmin * 12. * zprorcap(ji,jj,jk) )
408                  !  production terms for diatomees ( chlorophyll )
409                  zprod = rday * (zpronewd(ji,jj,jk) + zproregd(ji,jj,jk)) * zprchld(ji,jj,jk) * xlimdia(ji,jj,jk)
410                  zprochld(ji,jj,jk) = thetandm * zprod / ( zpislopead2(ji,jj,jk) * ediat(ji,jj,jk) +rtrn )
411                  zprochld(ji,jj,jk) = MAX(zprochld(ji,jj,jk), chlcmin * 12. * zprorcad(ji,jj,jk) )
412               ENDIF
413            END DO
414         END DO
415      END DO
416
417      !   Update the arrays TRA which contain the biological sources and sinks
418      DO jk = 1, jpkm1
419         DO jj = 1, jpj
420           DO ji =1 ,jpi
421              zprontot = zpronew(ji,jj,jk) + zproreg(ji,jj,jk)
422              zproptot = zpronewp(ji,jj,jk) + zproregp(ji,jj,jk)
423              zprodtot = zpronewd(ji,jj,jk) + zproregd(ji,jj,jk)
424              tra(ji,jj,jk,jppo4) = tra(ji,jj,jk,jppo4) - zpropo4(ji,jj,jk) - zpropo4d(ji,jj,jk)  &
425              &                     - zpropo4p(ji,jj,jk)
426              tra(ji,jj,jk,jpno3) = tra(ji,jj,jk,jpno3) - zpronew(ji,jj,jk) - zpronewd(ji,jj,jk)  &
427              &                     - zpronewp(ji,jj,jk)
428              tra(ji,jj,jk,jpnh4) = tra(ji,jj,jk,jpnh4) - zproreg(ji,jj,jk) - zproregd(ji,jj,jk)  &
429              &                     - zproregp(ji,jj,jk)
430              tra(ji,jj,jk,jpphy) = tra(ji,jj,jk,jpphy) + zprorcan(ji,jj,jk) * texcret     &
431                 &                  - zpsino3 * zpronew(ji,jj,jk) - zpsinh4 * zproreg(ji,jj,jk)   &
432                 &                  - zrespn(ji,jj,jk) 
433              zcroissn(ji,jj,jk) = tra(ji,jj,jk,jpphy) / rfact2/ (trn(ji,jj,jk,jpphy) + rtrn)
434              tra(ji,jj,jk,jpnph) = tra(ji,jj,jk,jpnph) + zprontot * texcret
435              tra(ji,jj,jk,jppph) = tra(ji,jj,jk,jppph) + zpropo4(ji,jj,jk) * texcret   &
436              &                     + zprodopn(ji,jj,jk) * texcret
437              tra(ji,jj,jk,jpnch) = tra(ji,jj,jk,jpnch) + zprochln(ji,jj,jk) * texcret
438              tra(ji,jj,jk,jpnfe) = tra(ji,jj,jk,jpnfe) + zprofen(ji,jj,jk) * texcret
439              tra(ji,jj,jk,jppic) = tra(ji,jj,jk,jppic) + zprorcap(ji,jj,jk) * texcretp     &
440                 &                  - zpsino3 * zpronewp(ji,jj,jk) - zpsinh4 * zproregp(ji,jj,jk)   &
441                 &                  - zrespp(ji,jj,jk) 
442              zcroissp(ji,jj,jk) = tra(ji,jj,jk,jppic) / rfact2/ (trn(ji,jj,jk,jppic) + rtrn)
443              tra(ji,jj,jk,jpnpi) = tra(ji,jj,jk,jpnpi) + zproptot * texcretp
444              tra(ji,jj,jk,jpppi) = tra(ji,jj,jk,jpppi) + zpropo4p(ji,jj,jk) * texcretp   &
445              &                     + zprodopp(ji,jj,jk) * texcretp
446              tra(ji,jj,jk,jppch) = tra(ji,jj,jk,jppch) + zprochlp(ji,jj,jk) * texcretp
447              tra(ji,jj,jk,jppfe) = tra(ji,jj,jk,jppfe) + zprofep(ji,jj,jk) * texcretp
448              tra(ji,jj,jk,jpdia) = tra(ji,jj,jk,jpdia) + zprorcad(ji,jj,jk) * texcret2   &
449                 &                  - zpsino3 * zpronewd(ji,jj,jk) - zpsinh4 * zproregd(ji,jj,jk)   &
450                 &                  - zrespd(ji,jj,jk) 
451              zcroissd(ji,jj,jk) = tra(ji,jj,jk,jpdia) / rfact2 / (trn(ji,jj,jk,jpdia) + rtrn)
452              tra(ji,jj,jk,jpndi) = tra(ji,jj,jk,jpndi) + zprodtot * texcret2
453              tra(ji,jj,jk,jppdi) = tra(ji,jj,jk,jppdi) + zpropo4d(ji,jj,jk) * texcret2   &
454              &                     + zprodopd(ji,jj,jk) * texcret2
455              tra(ji,jj,jk,jpdch) = tra(ji,jj,jk,jpdch) + zprochld(ji,jj,jk) * texcret2
456              tra(ji,jj,jk,jpdfe) = tra(ji,jj,jk,jpdfe) + zprofed(ji,jj,jk) * texcret2
457              tra(ji,jj,jk,jpdsi) = tra(ji,jj,jk,jpdsi) + zprorcad(ji,jj,jk) * zysopt(ji,jj,jk) * texcret2
458              tra(ji,jj,jk,jpdoc) = tra(ji,jj,jk,jpdoc) + excret2 * zprorcad(ji,jj,jk) + excret * zprorcan(ji,jj,jk)  &
459              &                     + excretp * zprorcap(ji,jj,jk)
460              tra(ji,jj,jk,jpdon) = tra(ji,jj,jk,jpdon) + excret2 * zprodtot + excret * zprontot   &
461              &                     + excretp * zproptot
462              tra(ji,jj,jk,jpdop) = tra(ji,jj,jk,jpdop) + excret2 * zpropo4d(ji,jj,jk) + excret * zpropo4(ji,jj,jk)   &
463              &    - texcret * zprodopn(ji,jj,jk) - texcret2 * zprodopd(ji,jj,jk) + excretp * zpropo4p(ji,jj,jk)     &
464              &    - texcretp * zprodopp(ji,jj,jk)
465              tra(ji,jj,jk,jpoxy) = tra(ji,jj,jk,jpoxy) + o2ut * ( zproreg(ji,jj,jk) + zproregd(ji,jj,jk)   &
466                 &                + zproregp(ji,jj,jk) ) + ( o2ut + o2nit ) * ( zpronew(ji,jj,jk)           &
467                 &                + zpronewd(ji,jj,jk) + zpronewp(ji,jj,jk) )   &
468                 &                - o2ut * ( zrespn(ji,jj,jk) + zrespp(ji,jj,jk) + zrespd(ji,jj,jk) )
469              tra(ji,jj,jk,jpfer) = tra(ji,jj,jk,jpfer) - texcret * zprofen(ji,jj,jk) - texcret2 * zprofed(ji,jj,jk)  &
470              &                     - texcretp * zprofep(ji,jj,jk)
471              tra(ji,jj,jk,jpsil) = tra(ji,jj,jk,jpsil) - texcret2 * zprorcad(ji,jj,jk) * zysopt(ji,jj,jk)
472              tra(ji,jj,jk,jpdic) = tra(ji,jj,jk,jpdic) - zprorcan(ji,jj,jk) - zprorcad(ji,jj,jk) - zprorcap(ji,jj,jk)  &
473              &                     + zpsino3 * zpronew(ji,jj,jk) + zpsinh4 * zproreg(ji,jj,jk)   &
474              &                     + zpsino3 * zpronewp(ji,jj,jk) + zpsinh4 * zproregp(ji,jj,jk)   &
475              &                     + zpsino3 * zpronewd(ji,jj,jk) + zpsinh4 * zproregd(ji,jj,jk)  &
476              &                     + zrespn(ji,jj,jk) + zrespd(ji,jj,jk) + zrespp(ji,jj,jk) 
477              tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) + rno3 * ( zpronew(ji,jj,jk) + zpronewd(ji,jj,jk)  &
478              &                     + zpronewp(ji,jj,jk) ) - rno3 * ( zproreg(ji,jj,jk) + zproregd(ji,jj,jk)     &
479              &                     + zproregp(ji,jj,jk) ) 
480          END DO
481        END DO
482     END DO
483
484     ! Total primary production per year
485     tpp = tpp + glob_sum( ( zprorcan(:,:,:) + zprorcad(:,:,:) + zprorcap(:,:,:) ) * cvol(:,:,:) )
486
487     IF( ln_diatrc ) THEN
488         !
489         zrfact2 = 1.e3 * rfact2r  ! conversion from mol/L/timestep into mol/m3/s
490         IF( lk_iomput ) THEN
491           IF( jnt == nrdttrc ) THEN
492              CALL iom_put( "PPPHY"  , zprorcan(:,:,:) * zrfact2 * tmask(:,:,:) )  ! primary production by nanophyto
493              CALL iom_put( "PPPHYP" , zprorcap(:,:,:) * zrfact2 * tmask(:,:,:) )  ! primary production by nanophyto
494              CALL iom_put( "PPPHY2" , zprorcad(:,:,:) * zrfact2 * tmask(:,:,:) )  ! primary production by diatom
495              CALL iom_put( "PPNEWN" , zpronew (:,:,:) * zrfact2 * tmask(:,:,:) )  ! new primary production by nanophyto
496              CALL iom_put( "PPNEWP" , zpronewp(:,:,:) * zrfact2 * tmask(:,:,:) )  ! new primary production by nanophyto
497              CALL iom_put( "PPNEWD" , zpronewd(:,:,:) * zrfact2 * tmask(:,:,:) )  ! new primary production by diatom
498              CALL iom_put( "PBSi"   , zprorcad(:,:,:) * zrfact2 * tmask(:,:,:) * zysopt(:,:,:) ) ! biogenic silica production
499              CALL iom_put( "PFeD"   , zprofed (:,:,:) * zrfact2 * tmask(:,:,:) )  ! biogenic iron production by diatom
500              CALL iom_put( "PFeP"   , zprofep (:,:,:) * zrfact2 * tmask(:,:,:) )  ! biogenic iron production by diatom
501              CALL iom_put( "PFeN"   , zprofen (:,:,:) * zrfact2 * tmask(:,:,:) )  ! biogenic iron production by nanophyto
502              CALL iom_put( "Mumax"  , prmaxn(:,:,:) * tmask(:,:,:) )  ! Maximum growth rate
503              CALL iom_put( "MuN"    , zprbio(:,:,:) * xlimphy(:,:,:) * tmask(:,:,:) )  ! Realized growth rate for nanophyto
504              CALL iom_put( "MuP"    , zprpic(:,:,:) * xlimpic(:,:,:) * tmask(:,:,:) )  ! Realized growth rate for nanophyto
505              CALL iom_put( "MuD"    , zprdia(:,:,:) * xlimdia(:,:,:) * tmask(:,:,:) )  ! Realized growth rate for diatoms
506              CALL iom_put( "MunetN"    , zcroissn(:,:,:) * tmask(:,:,:) )  ! Realized growth rate for nanophyto
507              CALL iom_put( "MunetP"    , zcroissp(:,:,:) * tmask(:,:,:) )  ! Realized growth rate for nanophyto
508              CALL iom_put( "MunetD"    , zcroissd(:,:,:) * tmask(:,:,:) )  ! Realized growth rate for diatoms
509              CALL iom_put( "LNlight", zprbio (:,:,:) / (prmaxn(:,:,:) + rtrn) * tmask(:,:,:) )  ! light limitation term
510              CALL iom_put( "LPlight", zprpic (:,:,:) / (prmaxp(:,:,:) + rtrn) * tmask(:,:,:) )  ! light limitation term
511              CALL iom_put( "LDlight", zprdia (:,:,:) / (prmaxd(:,:,:) + rtrn) * tmask(:,:,:) )  ! light limitation term
512           ENDIF
513         ELSE
514              trc3d(:,:,:,jp_pcs0_3d + 4)  = zprorcan(:,:,:) * zrfact2 * tmask(:,:,:)
515              trc3d(:,:,:,jp_pcs0_3d + 5)  = zprorcad(:,:,:) * zrfact2 * tmask(:,:,:)
516              trc3d(:,:,:,jp_pcs0_3d + 6)  = zpronew (:,:,:) * zrfact2 * tmask(:,:,:)
517              trc3d(:,:,:,jp_pcs0_3d + 7)  = zpronewd(:,:,:) * zrfact2 * tmask(:,:,:)
518              trc3d(:,:,:,jp_pcs0_3d + 8)  = zprorcad(:,:,:) * zrfact2 * tmask(:,:,:) * zysopt(:,:,:)
519              trc3d(:,:,:,jp_pcs0_3d + 9)  = zprofed (:,:,:) * zrfact2 * tmask(:,:,:)
520#  if ! defined key_kriest
521              trc3d(:,:,:,jp_pcs0_3d + 10) = zprofen (:,:,:) * zrfact2 * tmask(:,:,:)
522#  endif
523         ENDIF
524         !
525      ENDIF
526
527      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
528         WRITE(charout, FMT="('prod')")
529         CALL prt_ctl_trc_info(charout)
530         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
531      ENDIF
532      !
533      CALL wrk_dealloc( jpi, jpj,      zmixnano, zmixpico, zmixdiat, zstrn )
534      CALL wrk_dealloc( jpi, jpj, jpk, zpislopead, zpislopeadp, zpislopead2, zysopt )                           
535      CALL wrk_dealloc( jpi, jpj, jpk, zprdia, zprpic, zprbio, zprorcan, zprorcap, zprorcad )
536      CALL wrk_dealloc( jpi, jpj, jpk, zprofed, zprofep, zprofen, zprochln, zprochlp, zprochld ) 
537      CALL wrk_dealloc( jpi, jpj, jpk, zpronew, zpronewp, zpronewd, zproreg, zproregp, zproregd )
538      CALL wrk_dealloc( jpi, jpj, jpk, zpropo4, zpropo4p, zpropo4d, zrespn, zrespp, zrespd, zprnut )
539      CALL wrk_dealloc( jpi, jpj, jpk, zprchln, zprchlp, zprchld, zprodopn, zprodopp, zprodopd )
540      CALL wrk_dealloc( jpi, jpj, jpk, zcroissp, zcroissn, zcroissd )
541      !
542      IF( nn_timing == 1 )  CALL timing_stop('p5z_prod')
543      !
544   END SUBROUTINE p5z_prod
545
546
547   SUBROUTINE p5z_prod_init
548      !!----------------------------------------------------------------------
549      !!                  ***  ROUTINE p5z_prod_init  ***
550      !!
551      !! ** Purpose :   Initialization of phytoplankton production parameters
552      !!
553      !! ** Method  :   Read the nampisprod namelist and check the parameters
554      !!      called at the first timestep (nittrc000)
555      !!
556      !! ** input   :   Namelist nampisprod
557      !!----------------------------------------------------------------------
558      !
559      NAMELIST/nampisprod/ pislope, pislopep, pislope2, xadap, bresp, excret, excretp, excret2,  &
560         &                 thetannm, thetanpm, thetandm, chlcmin, grosip, zlimmxln,           &
561         &                 zlimmxlp, zlimmxld
562
563      INTEGER :: ios                 ! Local integer output status for namelist read
564      !!----------------------------------------------------------------------
565
566      REWIND( numnatp_ref )              ! Namelist nampisprod in reference namelist : Pisces phytoplankton production
567      READ  ( numnatp_ref, nampisprod, IOSTAT = ios, ERR = 901)
568901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampisprod in reference namelist', lwp )
569
570      REWIND( numnatp_cfg )              ! Namelist nampisprod in configuration namelist : Pisces phytoplankton production
571      READ  ( numnatp_cfg, nampisprod, IOSTAT = ios, ERR = 902 )
572902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampisprod in configuration namelist', lwp )
573      IF(lwm) WRITE ( numonp, nampisprod )
574
575      IF(lwp) THEN                         ! control print
576         WRITE(numout,*) ' '
577         WRITE(numout,*) ' Namelist parameters for phytoplankton growth, nampisprod'
578         WRITE(numout,*) ' ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
579         WRITE(numout,*) '    mean Si/C ratio                           grosip       =', grosip
580         WRITE(numout,*) '    P-I slope                                 pislope      =', pislope
581         WRITE(numout,*) '    Acclimation factor to low light           xadap       =', xadap
582         WRITE(numout,*) '    excretion ratio of nanophytoplankton      excret       =', excret
583         WRITE(numout,*) '    excretion ratio of picophytoplankton      excretp      =', excretp
584         WRITE(numout,*) '    excretion ratio of diatoms                excret2      =', excret2
585         WRITE(numout,*) '    basal respiration in phytoplankton        bresp        =', bresp
586         WRITE(numout,*) '    Maximum Chl/C in phytoplankton            chlcmin      =', chlcmin
587         WRITE(numout,*) '    P-I slope  for diatoms                    pislope2     =', pislope2
588         WRITE(numout,*) '    P-I slope  for picophytoplankton          pislopep     =', pislopep
589         WRITE(numout,*) '    Minimum Chl/N in nanophytoplankton        thetannm     =', thetannm
590         WRITE(numout,*) '    Minimum Chl/N in picophytoplankton        thetanpm     =', thetanpm
591         WRITE(numout,*) '    Minimum Chl/N in diatoms                  thetandm     =', thetandm
592         WRITE(numout,*) '    Critical time scale for mixing (nano)     zlimmxln     =', zlimmxln
593         WRITE(numout,*) '    Critical time scale for mixing (pico)     zlimmxlp     =', zlimmxlp
594         WRITE(numout,*) '    Critical time scale for mixing (diatoms)  zlimmxld     =', zlimmxld
595      ENDIF
596      !
597      r1_rday   = 1._wp / rday 
598      texcret   = 1._wp - excret
599      texcretp  = 1._wp - excretp
600      texcret2  = 1._wp - excret2
601      tpp       = 0._wp
602      !
603   END SUBROUTINE p5z_prod_init
604
605
606   INTEGER FUNCTION p5z_prod_alloc()
607      !!----------------------------------------------------------------------
608      !!                     ***  ROUTINE p5z_prod_alloc  ***
609      !!----------------------------------------------------------------------
610      ALLOCATE( prmaxn(jpi,jpj,jpk), prmaxp(jpi,jpj,jpk), prmaxd(jpi,jpj,jpk),  &
611      &          zdaylen(jpi,jpj), STAT = p5z_prod_alloc )
612      !
613      IF( p5z_prod_alloc /= 0 ) CALL ctl_warn('p5z_prod_alloc : failed to allocate arrays.')
614      !
615   END FUNCTION p5z_prod_alloc
616
617#else
618   !!======================================================================
619   !!  Dummy module :                                   No PISCES bio-model
620   !!======================================================================
621CONTAINS
622   SUBROUTINE p5z_prod                    ! Empty routine
623   END SUBROUTINE p5z_prod
624#endif 
625
626   !!======================================================================
627END MODULE  p5zprod
Note: See TracBrowser for help on using the repository browser.