| 1 | MODULE p4zflx |
|---|
| 2 | !!====================================================================== |
|---|
| 3 | !! *** MODULE p4zflx *** |
|---|
| 4 | !! TOP : PISCES CALCULATES GAS EXCHANGE AND CHEMISTRY AT SEA SURFACE |
|---|
| 5 | !!====================================================================== |
|---|
| 6 | !! History : - ! 1988-07 (E. MAIER-REIMER) Original code |
|---|
| 7 | !! - ! 1998 (O. Aumont) additions |
|---|
| 8 | !! - ! 1999 (C. Le Quere) modifications |
|---|
| 9 | !! 1.0 ! 2004 (O. Aumont) modifications |
|---|
| 10 | !! 2.0 ! 2007-12 (C. Ethe, G. Madec) F90 |
|---|
| 11 | !! ! 2011-02 (J. Simeon, J. Orr) Include total atm P correction |
|---|
| 12 | !! 3.6 ! 2015-05 (O. Aumont) PISCES quota |
|---|
| 13 | !!---------------------------------------------------------------------- |
|---|
| 14 | #if defined key_pisces || defined key_pisces_quota |
|---|
| 15 | !!---------------------------------------------------------------------- |
|---|
| 16 | !! 'key_pisces*' PISCES bio-model |
|---|
| 17 | !!---------------------------------------------------------------------- |
|---|
| 18 | !! p4z_flx : CALCULATES GAS EXCHANGE AND CHEMISTRY AT SEA SURFACE |
|---|
| 19 | !! p4z_flx_init : Read the namelist |
|---|
| 20 | !! p4z_patm : Read sfc atm pressure [atm] for each grid cell |
|---|
| 21 | !!---------------------------------------------------------------------- |
|---|
| 22 | USE oce_trc ! shared variables between ocean and passive tracers |
|---|
| 23 | USE trc ! passive tracers common variables |
|---|
| 24 | USE sms_pisces ! PISCES Source Minus Sink variables |
|---|
| 25 | USE p4zche ! Chemical model |
|---|
| 26 | USE prtctl_trc ! print control for debugging |
|---|
| 27 | USE iom ! I/O manager |
|---|
| 28 | USE fldread ! read input fields |
|---|
| 29 | #if defined key_cpl_carbon_cycle |
|---|
| 30 | USE sbc_oce, ONLY : atm_co2 ! atmospheric pCO2 |
|---|
| 31 | #endif |
|---|
| 32 | |
|---|
| 33 | IMPLICIT NONE |
|---|
| 34 | PRIVATE |
|---|
| 35 | |
|---|
| 36 | PUBLIC p4z_flx |
|---|
| 37 | PUBLIC p4z_flx_init |
|---|
| 38 | PUBLIC p4z_flx_alloc |
|---|
| 39 | |
|---|
| 40 | ! !!** Namelist nampisext ** |
|---|
| 41 | REAL(wp) :: atcco2 !: pre-industrial atmospheric [co2] (ppm) |
|---|
| 42 | LOGICAL :: ln_co2int !: flag to read in a file and interpolate atmospheric pco2 or not |
|---|
| 43 | CHARACTER(len=34) :: clname !: filename of pco2 values |
|---|
| 44 | INTEGER :: nn_offset !: Offset model-data start year (default = 0) |
|---|
| 45 | |
|---|
| 46 | !! Variables related to reading atmospheric CO2 time history |
|---|
| 47 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:) :: atcco2h, years |
|---|
| 48 | INTEGER :: nmaxrec, numco2 |
|---|
| 49 | |
|---|
| 50 | ! !!* nampisatm namelist (Atmospheric PRessure) * |
|---|
| 51 | LOGICAL, PUBLIC :: ln_presatm !: ref. pressure: global mean Patm (F) or a constant (F) |
|---|
| 52 | |
|---|
| 53 | REAL(wp) , ALLOCATABLE, SAVE, DIMENSION(:,:) :: patm ! atmospheric pressure at kt [N/m2] |
|---|
| 54 | TYPE(FLD), ALLOCATABLE, DIMENSION(:) :: sf_patm ! structure of input fields (file informations, fields read) |
|---|
| 55 | LOGICAL, PUBLIC :: ln_presatmco2 !: accounting for spatial atm CO2 in the compuation of carbon flux (T) or not (F) |
|---|
| 56 | TYPE(FLD), ALLOCATABLE, DIMENSION(:) :: sf_atmco2 ! structure of input fields (file informations, fields read) |
|---|
| 57 | |
|---|
| 58 | REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:) :: oce_co2 !: ocean carbon flux |
|---|
| 59 | REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:) :: satmco2 !: atmospheric pco2 |
|---|
| 60 | |
|---|
| 61 | REAL(wp) :: xconv = 0.01_wp / 3600._wp !: coefficients for conversion |
|---|
| 62 | |
|---|
| 63 | !!* Substitution |
|---|
| 64 | # include "top_substitute.h90" |
|---|
| 65 | !!---------------------------------------------------------------------- |
|---|
| 66 | !! NEMO/TOP 3.3 , NEMO Consortium (2010) |
|---|
| 67 | !! $Id$ |
|---|
| 68 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
|---|
| 69 | !!---------------------------------------------------------------------- |
|---|
| 70 | CONTAINS |
|---|
| 71 | |
|---|
| 72 | SUBROUTINE p4z_flx ( kt, knt ) |
|---|
| 73 | !!--------------------------------------------------------------------- |
|---|
| 74 | !! *** ROUTINE p4z_flx *** |
|---|
| 75 | !! |
|---|
| 76 | !! ** Purpose : CALCULATES GAS EXCHANGE AND CHEMISTRY AT SEA SURFACE |
|---|
| 77 | !! |
|---|
| 78 | !! ** Method : |
|---|
| 79 | !! - Include total atm P correction via Esbensen & Kushnir (1981) |
|---|
| 80 | !! - Pressure correction NOT done for key_cpl_carbon_cycle |
|---|
| 81 | !! - Remove Wanninkhof chemical enhancement; |
|---|
| 82 | !! - Add option for time-interpolation of atcco2.txt |
|---|
| 83 | !!--------------------------------------------------------------------- |
|---|
| 84 | ! |
|---|
| 85 | INTEGER, INTENT(in) :: kt, knt ! |
|---|
| 86 | ! |
|---|
| 87 | INTEGER :: ji, jj, jm, iind, iindm1 |
|---|
| 88 | REAL(wp) :: ztc, ztc2, ztc3, ztc4, zws, zkgwan |
|---|
| 89 | REAL(wp) :: zfld, zflu, zfld16, zflu16, zfact |
|---|
| 90 | REAL(wp) :: zvapsw, zsal, zfco2, zxc2, xCO2approx, ztkel, zfugcoeff |
|---|
| 91 | REAL(wp) :: zph, zdic, zsch_o2, zsch_co2 |
|---|
| 92 | REAL(wp) :: zyr_dec, zdco2dt |
|---|
| 93 | CHARACTER (len=25) :: charout |
|---|
| 94 | REAL(wp), POINTER, DIMENSION(:,:) :: zkgco2, zkgo2, zh2co3, zoflx, zw2d |
|---|
| 95 | !!--------------------------------------------------------------------- |
|---|
| 96 | ! |
|---|
| 97 | IF( nn_timing == 1 ) CALL timing_start('p4z_flx') |
|---|
| 98 | ! |
|---|
| 99 | CALL wrk_alloc( jpi, jpj, zkgco2, zkgo2, zh2co3, zoflx ) |
|---|
| 100 | ! |
|---|
| 101 | |
|---|
| 102 | ! SURFACE CHEMISTRY (PCO2 AND [H+] IN |
|---|
| 103 | ! SURFACE LAYER); THE RESULT OF THIS CALCULATION |
|---|
| 104 | ! IS USED TO COMPUTE AIR-SEA FLUX OF CO2 |
|---|
| 105 | |
|---|
| 106 | IF( kt /= nit000 .AND. knt == 1 ) CALL p4z_patm( kt ) ! Get sea-level pressure (E&K [1981] climatology) for use in flux calcs |
|---|
| 107 | |
|---|
| 108 | IF( ln_co2int .AND. .NOT.ln_presatmco2 ) THEN |
|---|
| 109 | ! Linear temporal interpolation of atmospheric pco2. atcco2.txt has annual values. |
|---|
| 110 | ! Caveats: First column of .txt must be in years, decimal years preferably. |
|---|
| 111 | ! For nn_offset, if your model year is iyy, nn_offset=(years(1)-iyy) |
|---|
| 112 | ! then the first atmospheric CO2 record read is at years(1) |
|---|
| 113 | zyr_dec = REAL( nyear + nn_offset, wp ) + REAL( nday_year, wp ) / REAL( nyear_len(1), wp ) |
|---|
| 114 | jm = 1 |
|---|
| 115 | DO WHILE( jm <= nmaxrec .AND. years(jm) < zyr_dec ) ; jm = jm + 1 ; END DO |
|---|
| 116 | iind = jm ; iindm1 = jm - 1 |
|---|
| 117 | zdco2dt = ( atcco2h(iind) - atcco2h(iindm1) ) / ( years(iind) - years(iindm1) + rtrn ) |
|---|
| 118 | atcco2 = zdco2dt * ( zyr_dec - years(iindm1) ) + atcco2h(iindm1) |
|---|
| 119 | satmco2(:,:) = atcco2 |
|---|
| 120 | ENDIF |
|---|
| 121 | |
|---|
| 122 | #if defined key_cpl_carbon_cycle |
|---|
| 123 | satmco2(:,:) = atm_co2(:,:) |
|---|
| 124 | #endif |
|---|
| 125 | |
|---|
| 126 | DO jj = 1, jpj |
|---|
| 127 | DO ji = 1, jpi |
|---|
| 128 | ! DUMMY VARIABLES FOR DIC, H+, AND BORATE |
|---|
| 129 | zfact = rhop(ji,jj,1) / 1000. + rtrn |
|---|
| 130 | zdic = trb(ji,jj,1,jpdic) / zfact |
|---|
| 131 | zph = MAX( hi(ji,jj,1), 1.e-10 ) / zfact |
|---|
| 132 | ! CALCULATE [H2CO3] |
|---|
| 133 | zh2co3(ji,jj) = zdic/(1. + ak13(ji,jj,1)/zph + ak13(ji,jj,1)*ak23(ji,jj,1)/zph**2)*zfact |
|---|
| 134 | END DO |
|---|
| 135 | END DO |
|---|
| 136 | |
|---|
| 137 | ! -------------- |
|---|
| 138 | ! COMPUTE FLUXES |
|---|
| 139 | ! -------------- |
|---|
| 140 | |
|---|
| 141 | ! FIRST COMPUTE GAS EXCHANGE COEFFICIENTS |
|---|
| 142 | ! ------------------------------------------- |
|---|
| 143 | |
|---|
| 144 | !CDIR NOVERRCHK |
|---|
| 145 | DO jj = 1, jpj |
|---|
| 146 | !CDIR NOVERRCHK |
|---|
| 147 | DO ji = 1, jpi |
|---|
| 148 | ztc = MIN( 35., tsn(ji,jj,1,jp_tem) ) |
|---|
| 149 | ztc2 = ztc * ztc |
|---|
| 150 | ztc3 = ztc * ztc2 |
|---|
| 151 | ztc4 = ztc2 * ztc2 |
|---|
| 152 | ! Compute the schmidt Number both O2 and CO2 |
|---|
| 153 | zsch_co2 = 2116.8 - 136.25 * ztc + 4.7353 * ztc2 - 0.092307 * ztc3 + 0.0007555 * ztc4 |
|---|
| 154 | zsch_o2 = 1920.4 - 135.6 * ztc + 5.2122 * ztc2 - 0.109390 * ztc3 + 0.0009377 * ztc4 |
|---|
| 155 | ! wind speed |
|---|
| 156 | zws = wndm(ji,jj) * wndm(ji,jj) |
|---|
| 157 | ! Compute the piston velocity for O2 and CO2 |
|---|
| 158 | zkgwan = 0.251 * zws |
|---|
| 159 | zkgwan = zkgwan * xconv * ( 1.- fr_i(ji,jj) ) * tmask(ji,jj,1) |
|---|
| 160 | # if defined key_degrad |
|---|
| 161 | zkgwan = zkgwan * facvol(ji,jj,1) |
|---|
| 162 | #endif |
|---|
| 163 | ! compute gas exchange for CO2 and O2 |
|---|
| 164 | zkgco2(ji,jj) = zkgwan * SQRT( 660./ zsch_co2 ) |
|---|
| 165 | zkgo2 (ji,jj) = zkgwan * SQRT( 660./ zsch_o2 ) |
|---|
| 166 | END DO |
|---|
| 167 | END DO |
|---|
| 168 | |
|---|
| 169 | DO jj = 1, jpj |
|---|
| 170 | DO ji = 1, jpi |
|---|
| 171 | ztkel = tsn(ji,jj,1,jp_tem) + 273.15 |
|---|
| 172 | zsal = tsn(ji,jj,1,jp_sal) + ( 1.- tmask(ji,jj,1) ) * 35. |
|---|
| 173 | zvapsw = exp(24.4543 - 67.4509*(100.0/ztkel) - 4.8489*log(ztkel/100) - 0.000544*zsal) |
|---|
| 174 | xCO2approx = satmco2(ji,jj) * ( patm(ji,jj) - zvapsw ) * 1.E-6 |
|---|
| 175 | zxc2 = (1.0 - xCO2approx)**2 |
|---|
| 176 | zfugcoeff = exp(patm(ji,jj) * (chemc(ji,jj,2) + 2.0 * zxc2 * chemc(ji,jj,3) ) & |
|---|
| 177 | & / (82.05736 * ztkel)) |
|---|
| 178 | zfco2 = satmco2(ji,jj) * ( patm(ji,jj) - zvapsw ) * zfugcoeff |
|---|
| 179 | ! Compute CO2 flux for the sea and air |
|---|
| 180 | zfld = satmco2(ji,jj) * patm(ji,jj) * tmask(ji,jj,1) * chemc(ji,jj,1) * zkgco2(ji,jj) ! (mol/L) * (m/s) |
|---|
| 181 | zflu = zh2co3(ji,jj) * tmask(ji,jj,1) * zkgco2(ji,jj) ! (mol/L) (m/s) ? |
|---|
| 182 | oce_co2(ji,jj) = ( zfld - zflu ) * rfact2 * e1e2t(ji,jj) * tmask(ji,jj,1) * 1000. |
|---|
| 183 | ! compute the trend |
|---|
| 184 | tra(ji,jj,1,jpdic) = tra(ji,jj,1,jpdic) + ( zfld - zflu ) * rfact2 / fse3t(ji,jj,1) |
|---|
| 185 | ! Compute O2 flux |
|---|
| 186 | zfld16 = patm(ji,jj) * chemo2(ji,jj,1) * tmask(ji,jj,1) * zkgo2(ji,jj) ! (mol/L) * (m/s) |
|---|
| 187 | zflu16 = trb(ji,jj,1,jpoxy) * tmask(ji,jj,1) * zkgo2(ji,jj) |
|---|
| 188 | zoflx(ji,jj) = zfld16 - zflu16 |
|---|
| 189 | tra(ji,jj,1,jpoxy) = tra(ji,jj,1,jpoxy) + zoflx(ji,jj) * rfact2 / fse3t(ji,jj,1) |
|---|
| 190 | END DO |
|---|
| 191 | END DO |
|---|
| 192 | |
|---|
| 193 | t_oce_co2_flx = glob_sum( oce_co2(:,:) ) ! Total Flux of Carbon |
|---|
| 194 | t_oce_co2_flx_cum = t_oce_co2_flx_cum + t_oce_co2_flx ! Cumulative Total Flux of Carbon |
|---|
| 195 | t_atm_co2_flx = glob_sum( satmco2(:,:) * e1e2t(:,:) ) ! Total atmospheric pCO2 |
|---|
| 196 | |
|---|
| 197 | IF(ln_ctl) THEN ! print mean trends (used for debugging) |
|---|
| 198 | WRITE(charout, FMT="('flx ')") |
|---|
| 199 | CALL prt_ctl_trc_info(charout) |
|---|
| 200 | CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm) |
|---|
| 201 | ENDIF |
|---|
| 202 | |
|---|
| 203 | IF( lk_iomput .AND. knt == nrdttrc ) THEN |
|---|
| 204 | CALL wrk_alloc( jpi, jpj, zw2d ) |
|---|
| 205 | IF( iom_use( "Cflx" ) ) THEN |
|---|
| 206 | zw2d(:,:) = oce_co2(:,:) / e1e2t(:,:) * rfact2r |
|---|
| 207 | CALL iom_put( "Cflx" , zw2d ) |
|---|
| 208 | ENDIF |
|---|
| 209 | IF( iom_use( "Oflx" ) ) THEN |
|---|
| 210 | zw2d(:,:) = zoflx(:,:) * 1000 * tmask(:,:,1) |
|---|
| 211 | CALL iom_put( "Oflx" , zw2d ) |
|---|
| 212 | ENDIF |
|---|
| 213 | IF( iom_use( "Kg" ) ) THEN |
|---|
| 214 | zw2d(:,:) = zkgco2(:,:) * tmask(:,:,1) |
|---|
| 215 | CALL iom_put( "Kg" , zw2d ) |
|---|
| 216 | ENDIF |
|---|
| 217 | IF( iom_use( "Dpco2" ) ) THEN |
|---|
| 218 | zw2d(:,:) = ( satmco2(:,:) * patm(:,:) - zh2co3(:,:) / ( chemc(:,:,1) + rtrn ) ) * tmask(:,:,1) |
|---|
| 219 | CALL iom_put( "Dpco2" , zw2d ) |
|---|
| 220 | ENDIF |
|---|
| 221 | IF( iom_use( "Dpo2" ) ) THEN |
|---|
| 222 | zw2d(:,:) = ( patm(:,:) - trb(:,:,1,jpoxy) / ( chemo2(:,:,1) + rtrn ) ) * atcox * tmask(:,:,1) |
|---|
| 223 | CALL iom_put( "Dpo2" , zw2d ) |
|---|
| 224 | ENDIF |
|---|
| 225 | IF( iom_use( "tcflx" ) ) CALL iom_put( "tcflx" , t_oce_co2_flx * rfact2r ) ! molC/s |
|---|
| 226 | CALL iom_put( "tcflxcum" , t_oce_co2_flx_cum ) ! molC |
|---|
| 227 | ! |
|---|
| 228 | CALL wrk_dealloc( jpi, jpj, zw2d ) |
|---|
| 229 | ELSE |
|---|
| 230 | IF( ln_diatrc ) THEN |
|---|
| 231 | trc2d(:,:,jp_pcs0_2d ) = oce_co2(:,:) / e1e2t(:,:) * rfact2r |
|---|
| 232 | trc2d(:,:,jp_pcs0_2d + 1) = zoflx(:,:) * 1000 * tmask(:,:,1) |
|---|
| 233 | trc2d(:,:,jp_pcs0_2d + 2) = zkgco2(:,:) * tmask(:,:,1) |
|---|
| 234 | trc2d(:,:,jp_pcs0_2d + 3) = ( satmco2(:,:) * patm(:,:) - zh2co3(:,:) / ( chemc(:,:,1) + rtrn ) ) * tmask(:,:,1) |
|---|
| 235 | ENDIF |
|---|
| 236 | ENDIF |
|---|
| 237 | ! |
|---|
| 238 | CALL wrk_dealloc( jpi, jpj, zkgco2, zkgo2, zh2co3, zoflx ) |
|---|
| 239 | ! |
|---|
| 240 | IF( nn_timing == 1 ) CALL timing_stop('p4z_flx') |
|---|
| 241 | ! |
|---|
| 242 | END SUBROUTINE p4z_flx |
|---|
| 243 | |
|---|
| 244 | |
|---|
| 245 | SUBROUTINE p4z_flx_init |
|---|
| 246 | !!---------------------------------------------------------------------- |
|---|
| 247 | !! *** ROUTINE p4z_flx_init *** |
|---|
| 248 | !! |
|---|
| 249 | !! ** Purpose : Initialization of atmospheric conditions |
|---|
| 250 | !! |
|---|
| 251 | !! ** Method : Read the nampisext namelist and check the parameters |
|---|
| 252 | !! called at the first timestep (nittrc000) |
|---|
| 253 | !! ** input : Namelist nampisext |
|---|
| 254 | !!---------------------------------------------------------------------- |
|---|
| 255 | NAMELIST/nampisext/ln_co2int, atcco2, clname, nn_offset |
|---|
| 256 | INTEGER :: jm |
|---|
| 257 | INTEGER :: ios ! Local integer output status for namelist read |
|---|
| 258 | !!---------------------------------------------------------------------- |
|---|
| 259 | ! |
|---|
| 260 | |
|---|
| 261 | REWIND( numnatp_ref ) ! Namelist nampisext in reference namelist : Pisces atm. conditions |
|---|
| 262 | READ ( numnatp_ref, nampisext, IOSTAT = ios, ERR = 901) |
|---|
| 263 | 901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampisext in reference namelist', lwp ) |
|---|
| 264 | |
|---|
| 265 | REWIND( numnatp_cfg ) ! Namelist nampisext in configuration namelist : Pisces atm. conditions |
|---|
| 266 | READ ( numnatp_cfg, nampisext, IOSTAT = ios, ERR = 902 ) |
|---|
| 267 | 902 IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampisext in configuration namelist', lwp ) |
|---|
| 268 | IF(lwm) WRITE ( numonp, nampisext ) |
|---|
| 269 | ! |
|---|
| 270 | IF(lwp) THEN ! control print |
|---|
| 271 | WRITE(numout,*) ' ' |
|---|
| 272 | WRITE(numout,*) ' Namelist parameters for air-sea exchange, nampisext' |
|---|
| 273 | WRITE(numout,*) ' ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~' |
|---|
| 274 | WRITE(numout,*) ' Choice for reading in the atm pCO2 file or constant value, ln_co2int =', ln_co2int |
|---|
| 275 | WRITE(numout,*) ' ' |
|---|
| 276 | ENDIF |
|---|
| 277 | IF( .NOT.ln_co2int .AND. .NOT.ln_presatmco2 ) THEN |
|---|
| 278 | IF(lwp) THEN ! control print |
|---|
| 279 | WRITE(numout,*) ' Constant Atmospheric pCO2 value atcco2 =', atcco2 |
|---|
| 280 | WRITE(numout,*) ' ' |
|---|
| 281 | ENDIF |
|---|
| 282 | satmco2(:,:) = atcco2 ! Initialisation of atmospheric pco2 |
|---|
| 283 | ELSEIF(ln_co2int .AND. .NOT.ln_presatmco2) THEN |
|---|
| 284 | IF(lwp) THEN |
|---|
| 285 | WRITE(numout,*) ' Atmospheric pCO2 value from file clname =', TRIM( clname ) |
|---|
| 286 | WRITE(numout,*) ' Offset model-data start year nn_offset =', nn_offset |
|---|
| 287 | WRITE(numout,*) ' ' |
|---|
| 288 | ENDIF |
|---|
| 289 | CALL ctl_opn( numco2, TRIM( clname) , 'OLD', 'FORMATTED', 'SEQUENTIAL', -1 , numout, lwp ) |
|---|
| 290 | jm = 0 ! Count the number of record in co2 file |
|---|
| 291 | DO |
|---|
| 292 | READ(numco2,*,END=100) |
|---|
| 293 | jm = jm + 1 |
|---|
| 294 | END DO |
|---|
| 295 | 100 nmaxrec = jm - 1 |
|---|
| 296 | ALLOCATE( years (nmaxrec) ) ; years (:) = 0._wp |
|---|
| 297 | ALLOCATE( atcco2h(nmaxrec) ) ; atcco2h(:) = 0._wp |
|---|
| 298 | |
|---|
| 299 | REWIND(numco2) |
|---|
| 300 | DO jm = 1, nmaxrec ! get xCO2 data |
|---|
| 301 | READ(numco2, *) years(jm), atcco2h(jm) |
|---|
| 302 | IF(lwp) WRITE(numout, '(f6.0,f7.2)') years(jm), atcco2h(jm) |
|---|
| 303 | END DO |
|---|
| 304 | CLOSE(numco2) |
|---|
| 305 | ELSEIF(.NOT.ln_co2int .AND. ln_presatmco2) THEN |
|---|
| 306 | IF(lwp) THEN |
|---|
| 307 | WRITE(numout,*) ' Spatialized Atmospheric pCO2 from an external file' |
|---|
| 308 | WRITE(numout,*) ' ' |
|---|
| 309 | ENDIF |
|---|
| 310 | ELSE |
|---|
| 311 | IF(lwp) THEN |
|---|
| 312 | WRITE(numout,*) ' Spatialized Atmospheric pCO2 from an external file' |
|---|
| 313 | WRITE(numout,*) ' ' |
|---|
| 314 | ENDIF |
|---|
| 315 | ENDIF |
|---|
| 316 | ! |
|---|
| 317 | oce_co2(:,:) = 0._wp ! Initialization of Flux of Carbon |
|---|
| 318 | t_atm_co2_flx = 0._wp |
|---|
| 319 | t_oce_co2_flx = 0._wp |
|---|
| 320 | ! |
|---|
| 321 | CALL p4z_patm( nit000 ) |
|---|
| 322 | ! |
|---|
| 323 | END SUBROUTINE p4z_flx_init |
|---|
| 324 | |
|---|
| 325 | SUBROUTINE p4z_patm( kt ) |
|---|
| 326 | |
|---|
| 327 | !!---------------------------------------------------------------------- |
|---|
| 328 | !! *** ROUTINE p4z_atm *** |
|---|
| 329 | !! |
|---|
| 330 | !! ** Purpose : Read and interpolate the external atmospheric sea-levl pressure |
|---|
| 331 | !! ** Method : Read the files and interpolate the appropriate variables |
|---|
| 332 | !! |
|---|
| 333 | !!---------------------------------------------------------------------- |
|---|
| 334 | !! * arguments |
|---|
| 335 | INTEGER, INTENT( in ) :: kt ! ocean time step |
|---|
| 336 | ! |
|---|
| 337 | INTEGER :: ierr |
|---|
| 338 | INTEGER :: ios ! Local integer output status for namelist read |
|---|
| 339 | CHARACTER(len=100) :: cn_dir ! Root directory for location of ssr files |
|---|
| 340 | TYPE(FLD_N) :: sn_patm ! informations about the fields to be read |
|---|
| 341 | TYPE(FLD_N) :: sn_atmco2 ! informations about the fields to be read |
|---|
| 342 | !! |
|---|
| 343 | NAMELIST/nampisatm/ ln_presatm, ln_presatmco2, sn_patm, sn_atmco2, cn_dir |
|---|
| 344 | ! ! ----------------------- ! |
|---|
| 345 | IF( kt == nit000 ) THEN ! First call kt=nittrc000 ! |
|---|
| 346 | |
|---|
| 347 | REWIND( numnatp_ref ) ! Namelist nampisatm in reference namelist : Pisces atm. sea level pressure file |
|---|
| 348 | READ ( numnatp_ref, nampisatm, IOSTAT = ios, ERR = 901) |
|---|
| 349 | 901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampisatm in reference namelist', lwp ) |
|---|
| 350 | |
|---|
| 351 | REWIND( numnatp_cfg ) ! Namelist nampisatm in configuration namelist : Pisces atm. sea level pressure file |
|---|
| 352 | READ ( numnatp_cfg, nampisatm, IOSTAT = ios, ERR = 902 ) |
|---|
| 353 | 902 IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampisatm in configuration namelist', lwp ) |
|---|
| 354 | IF(lwm) WRITE ( numonp, nampisatm ) |
|---|
| 355 | ! |
|---|
| 356 | ! |
|---|
| 357 | IF(lwp) THEN !* control print |
|---|
| 358 | WRITE(numout,*) |
|---|
| 359 | WRITE(numout,*) ' Namelist nampisatm : Atmospheric Pressure as external forcing' |
|---|
| 360 | WRITE(numout,*) ' constant atmopsheric pressure (F) or from a file (T) ln_presatm = ', ln_presatm |
|---|
| 361 | WRITE(numout,*) ' spatial atmopsheric CO2 for flux calcs ln_presatmco2 = ', ln_presatmco2 |
|---|
| 362 | WRITE(numout,*) |
|---|
| 363 | ENDIF |
|---|
| 364 | ! |
|---|
| 365 | IF( ln_presatm ) THEN |
|---|
| 366 | ALLOCATE( sf_patm(1), STAT=ierr ) !* allocate and fill sf_patm (forcing structure) with sn_patm |
|---|
| 367 | IF( ierr > 0 ) CALL ctl_stop( 'STOP', 'p4z_flx: unable to allocate sf_patm structure' ) |
|---|
| 368 | ! |
|---|
| 369 | CALL fld_fill( sf_patm, (/ sn_patm /), cn_dir, 'p4z_flx', 'Atmospheric pressure ', 'nampisatm' ) |
|---|
| 370 | ALLOCATE( sf_patm(1)%fnow(jpi,jpj,1) ) |
|---|
| 371 | IF( sn_patm%ln_tint ) ALLOCATE( sf_patm(1)%fdta(jpi,jpj,1,2) ) |
|---|
| 372 | ENDIF |
|---|
| 373 | ! |
|---|
| 374 | IF( ln_presatmco2 ) THEN |
|---|
| 375 | ALLOCATE( sf_atmco2(1), STAT=ierr ) !* allocate and fill sf_atmco2 (forcing structure) with sn_atmco2 |
|---|
| 376 | IF( ierr > 0 ) CALL ctl_stop( 'STOP', 'p4z_flx: unable to allocate sf_atmco2 structure' ) |
|---|
| 377 | ! |
|---|
| 378 | CALL fld_fill( sf_atmco2, (/ sn_atmco2 /), cn_dir, 'p4z_flx', 'Atmospheric co2 partial pressure ', 'nampisatm' ) |
|---|
| 379 | ALLOCATE( sf_atmco2(1)%fnow(jpi,jpj,1) ) |
|---|
| 380 | IF( sn_atmco2%ln_tint ) ALLOCATE( sf_atmco2(1)%fdta(jpi,jpj,1,2) ) |
|---|
| 381 | ENDIF |
|---|
| 382 | ! |
|---|
| 383 | ENDIF |
|---|
| 384 | ! |
|---|
| 385 | IF( ln_presatm ) THEN |
|---|
| 386 | CALL fld_read( kt, 1, sf_patm ) !* input Patm provided at kt + 1/2 |
|---|
| 387 | patm(:,:) = sf_patm(1)%fnow(:,:,1) ! atmospheric pressure |
|---|
| 388 | ELSE |
|---|
| 389 | patm(:,:) = 1.e0 ! Initialize patm if no reading from a file |
|---|
| 390 | ENDIF |
|---|
| 391 | ! |
|---|
| 392 | IF( ln_presatmco2 ) THEN |
|---|
| 393 | CALL fld_read( kt, 1, sf_atmco2 ) !* input atmco2 provided at kt + 1/2 |
|---|
| 394 | satmco2(:,:) = sf_atmco2(1)%fnow(:,:,1) ! atmospheric pressure |
|---|
| 395 | ELSE |
|---|
| 396 | satmco2(:,:) = atcco2 ! Initialize atmco2 if no reading from a file |
|---|
| 397 | ENDIF |
|---|
| 398 | ! |
|---|
| 399 | IF(lwp) THEN !* control print |
|---|
| 400 | WRITE(numout,*) ' Min-Max atmospheric CO2 = ', MINVAL(satmco2(:,:)),MAXVAL(satmco2(:,:)) |
|---|
| 401 | ENDIF |
|---|
| 402 | ! |
|---|
| 403 | END SUBROUTINE p4z_patm |
|---|
| 404 | |
|---|
| 405 | INTEGER FUNCTION p4z_flx_alloc() |
|---|
| 406 | !!---------------------------------------------------------------------- |
|---|
| 407 | !! *** ROUTINE p4z_flx_alloc *** |
|---|
| 408 | !!---------------------------------------------------------------------- |
|---|
| 409 | ALLOCATE( oce_co2(jpi,jpj), satmco2(jpi,jpj), patm(jpi,jpj), STAT=p4z_flx_alloc ) |
|---|
| 410 | ! |
|---|
| 411 | IF( p4z_flx_alloc /= 0 ) CALL ctl_warn('p4z_flx_alloc : failed to allocate arrays') |
|---|
| 412 | ! |
|---|
| 413 | END FUNCTION p4z_flx_alloc |
|---|
| 414 | |
|---|
| 415 | #else |
|---|
| 416 | !!====================================================================== |
|---|
| 417 | !! Dummy module : No PISCES bio-model |
|---|
| 418 | !!====================================================================== |
|---|
| 419 | CONTAINS |
|---|
| 420 | SUBROUTINE p4z_flx( kt ) ! Empty routine |
|---|
| 421 | INTEGER, INTENT( in ) :: kt |
|---|
| 422 | WRITE(*,*) 'p4z_flx: You should not have seen this print! error?', kt |
|---|
| 423 | END SUBROUTINE p4z_flx |
|---|
| 424 | #endif |
|---|
| 425 | |
|---|
| 426 | !!====================================================================== |
|---|
| 427 | END MODULE p4zflx |
|---|
