[3443] | 1 | MODULE p4zlim |
---|
| 2 | !!====================================================================== |
---|
| 3 | !! *** MODULE p4zlim *** |
---|
| 4 | !! TOP : PISCES |
---|
| 5 | !!====================================================================== |
---|
| 6 | !! History : 1.0 ! 2004 (O. Aumont) Original code |
---|
| 7 | !! 2.0 ! 2007-12 (C. Ethe, G. Madec) F90 |
---|
| 8 | !! 3.4 ! 2011-04 (O. Aumont, C. Ethe) Limitation for iron modelled in quota |
---|
| 9 | !!---------------------------------------------------------------------- |
---|
| 10 | #if defined key_pisces |
---|
| 11 | !!---------------------------------------------------------------------- |
---|
| 12 | !! 'key_pisces' PISCES bio-model |
---|
| 13 | !!---------------------------------------------------------------------- |
---|
| 14 | !! p4z_lim : Compute the nutrients limitation terms |
---|
| 15 | !! p4z_lim_init : Read the namelist |
---|
| 16 | !!---------------------------------------------------------------------- |
---|
| 17 | USE oce_trc ! Shared ocean-passive tracers variables |
---|
| 18 | USE trc ! Tracers defined |
---|
| 19 | USE sms_pisces ! PISCES variables |
---|
| 20 | USE p4zopt ! Optical |
---|
[3446] | 21 | USE iom ! I/O manager |
---|
[3443] | 22 | |
---|
| 23 | IMPLICIT NONE |
---|
| 24 | PRIVATE |
---|
| 25 | |
---|
| 26 | PUBLIC p4z_lim |
---|
| 27 | PUBLIC p4z_lim_init |
---|
[6453] | 28 | PUBLIC p4z_lim_alloc |
---|
[3443] | 29 | |
---|
| 30 | !! * Shared module variables |
---|
[4147] | 31 | REAL(wp), PUBLIC :: concnno3 !: NO3, PO4 half saturation |
---|
| 32 | REAL(wp), PUBLIC :: concdno3 !: Phosphate half saturation for diatoms |
---|
| 33 | REAL(wp), PUBLIC :: concnnh4 !: NH4 half saturation for phyto |
---|
| 34 | REAL(wp), PUBLIC :: concdnh4 !: NH4 half saturation for diatoms |
---|
| 35 | REAL(wp), PUBLIC :: concnfer !: Iron half saturation for nanophyto |
---|
| 36 | REAL(wp), PUBLIC :: concdfer !: Iron half saturation for diatoms |
---|
| 37 | REAL(wp), PUBLIC :: concbno3 !: NO3 half saturation for bacteria |
---|
| 38 | REAL(wp), PUBLIC :: concbnh4 !: NH4 half saturation for bacteria |
---|
| 39 | REAL(wp), PUBLIC :: xsizedia !: Minimum size criteria for diatoms |
---|
| 40 | REAL(wp), PUBLIC :: xsizephy !: Minimum size criteria for nanophyto |
---|
| 41 | REAL(wp), PUBLIC :: xsizern !: Size ratio for nanophytoplankton |
---|
| 42 | REAL(wp), PUBLIC :: xsizerd !: Size ratio for diatoms |
---|
| 43 | REAL(wp), PUBLIC :: xksi1 !: half saturation constant for Si uptake |
---|
| 44 | REAL(wp), PUBLIC :: xksi2 !: half saturation constant for Si/C |
---|
| 45 | REAL(wp), PUBLIC :: xkdoc !: 2nd half-sat. of DOC remineralization |
---|
| 46 | REAL(wp), PUBLIC :: concbfe !: Fe half saturation for bacteria |
---|
| 47 | REAL(wp), PUBLIC :: qnfelim !: optimal Fe quota for nanophyto |
---|
| 48 | REAL(wp), PUBLIC :: qdfelim !: optimal Fe quota for diatoms |
---|
| 49 | REAL(wp), PUBLIC :: caco3r !: mean rainratio |
---|
[3443] | 50 | |
---|
[6453] | 51 | !!* Phytoplankton limitation terms |
---|
| 52 | REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: xnanono3 !: ??? |
---|
| 53 | REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: xdiatno3 !: ??? |
---|
| 54 | REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: xnanonh4 !: ??? |
---|
| 55 | REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: xdiatnh4 !: ??? |
---|
| 56 | REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: xnanopo4 !: ??? |
---|
| 57 | REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: xdiatpo4 !: ??? |
---|
| 58 | REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: xlimphy !: ??? |
---|
| 59 | REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: xlimdia !: ??? |
---|
| 60 | REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: xlimnfe !: ??? |
---|
| 61 | REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: xlimdfe !: ??? |
---|
| 62 | REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: xlimsi !: ??? |
---|
| 63 | REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: xlimbac !: ?? |
---|
| 64 | REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: xlimbacl !: ?? |
---|
| 65 | REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: concdfe !: ??? |
---|
| 66 | REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: concnfe !: ??? |
---|
| 67 | |
---|
[3443] | 68 | ! Coefficient for iron limitation |
---|
| 69 | REAL(wp) :: xcoef1 = 0.0016 / 55.85 |
---|
| 70 | REAL(wp) :: xcoef2 = 1.21E-5 * 14. / 55.85 / 7.625 * 0.5 * 1.5 |
---|
| 71 | REAL(wp) :: xcoef3 = 1.15E-4 * 14. / 55.85 / 7.625 * 0.5 |
---|
| 72 | !!* Substitution |
---|
| 73 | # include "top_substitute.h90" |
---|
| 74 | !!---------------------------------------------------------------------- |
---|
| 75 | !! NEMO/TOP 3.3 , NEMO Consortium (2010) |
---|
| 76 | !! $Id: p4zlim.F90 3160 2011-11-20 14:27:18Z cetlod $ |
---|
| 77 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
---|
| 78 | !!---------------------------------------------------------------------- |
---|
| 79 | |
---|
| 80 | CONTAINS |
---|
| 81 | |
---|
[5385] | 82 | SUBROUTINE p4z_lim( kt, knt ) |
---|
[3443] | 83 | !!--------------------------------------------------------------------- |
---|
| 84 | !! *** ROUTINE p4z_lim *** |
---|
| 85 | !! |
---|
| 86 | !! ** Purpose : Compute the co-limitations by the various nutrients |
---|
| 87 | !! for the various phytoplankton species |
---|
| 88 | !! |
---|
| 89 | !! ** Method : - ??? |
---|
| 90 | !!--------------------------------------------------------------------- |
---|
| 91 | ! |
---|
[5385] | 92 | INTEGER, INTENT(in) :: kt, knt |
---|
[3443] | 93 | ! |
---|
| 94 | INTEGER :: ji, jj, jk |
---|
| 95 | REAL(wp) :: zlim1, zlim2, zlim3, zlim4, zno3, zferlim |
---|
| 96 | REAL(wp) :: zconcd, zconcd2, zconcn, zconcn2 |
---|
[5385] | 97 | REAL(wp) :: z1_trbdia, z1_trbphy, ztem1, ztem2, zetot1, zetot2 |
---|
[3443] | 98 | REAL(wp) :: zdenom, zratio, zironmin |
---|
| 99 | REAL(wp) :: zconc1d, zconc1dnh4, zconc0n, zconc0nnh4 |
---|
| 100 | !!--------------------------------------------------------------------- |
---|
| 101 | ! |
---|
| 102 | IF( nn_timing == 1 ) CALL timing_start('p4z_lim') |
---|
| 103 | ! |
---|
| 104 | DO jk = 1, jpkm1 |
---|
| 105 | DO jj = 1, jpj |
---|
| 106 | DO ji = 1, jpi |
---|
| 107 | |
---|
| 108 | ! Tuning of the iron concentration to a minimum level that is set to the detection limit |
---|
| 109 | !------------------------------------- |
---|
[5385] | 110 | zno3 = trb(ji,jj,jk,jpno3) / 40.e-6 |
---|
[3443] | 111 | zferlim = MAX( 3e-11 * zno3 * zno3, 5e-12 ) |
---|
[4529] | 112 | zferlim = MIN( zferlim, 7e-11 ) |
---|
[5385] | 113 | trb(ji,jj,jk,jpfer) = MAX( trb(ji,jj,jk,jpfer), zferlim ) |
---|
[3443] | 114 | |
---|
| 115 | ! Computation of a variable Ks for iron on diatoms taking into account |
---|
| 116 | ! that increasing biomass is made of generally bigger cells |
---|
| 117 | !------------------------------------------------ |
---|
[5385] | 118 | zconcd = MAX( 0.e0 , trb(ji,jj,jk,jpdia) - xsizedia ) |
---|
| 119 | zconcd2 = trb(ji,jj,jk,jpdia) - zconcd |
---|
| 120 | zconcn = MAX( 0.e0 , trb(ji,jj,jk,jpphy) - xsizephy ) |
---|
| 121 | zconcn2 = trb(ji,jj,jk,jpphy) - zconcn |
---|
| 122 | z1_trbphy = 1. / ( trb(ji,jj,jk,jpphy) + rtrn ) |
---|
| 123 | z1_trbdia = 1. / ( trb(ji,jj,jk,jpdia) + rtrn ) |
---|
[3443] | 124 | |
---|
[5385] | 125 | concdfe(ji,jj,jk) = MAX( concdfer, ( zconcd2 * concdfer + concdfer * xsizerd * zconcd ) * z1_trbdia ) |
---|
| 126 | zconc1d = MAX( concdno3, ( zconcd2 * concdno3 + concdno3 * xsizerd * zconcd ) * z1_trbdia ) |
---|
| 127 | zconc1dnh4 = MAX( concdnh4, ( zconcd2 * concdnh4 + concdnh4 * xsizerd * zconcd ) * z1_trbdia ) |
---|
[3443] | 128 | |
---|
[5385] | 129 | concnfe(ji,jj,jk) = MAX( concnfer, ( zconcn2 * concnfer + concnfer * xsizern * zconcn ) * z1_trbphy ) |
---|
| 130 | zconc0n = MAX( concnno3, ( zconcn2 * concnno3 + concnno3 * xsizern * zconcn ) * z1_trbphy ) |
---|
| 131 | zconc0nnh4 = MAX( concnnh4, ( zconcn2 * concnnh4 + concnnh4 * xsizern * zconcn ) * z1_trbphy ) |
---|
[3443] | 132 | |
---|
[3446] | 133 | ! Michaelis-Menten Limitation term for nutrients Small bacteria |
---|
| 134 | ! ------------------------------------------------------------- |
---|
[5385] | 135 | zdenom = 1. / ( concbno3 * concbnh4 + concbnh4 * trb(ji,jj,jk,jpno3) + concbno3 * trb(ji,jj,jk,jpnh4) ) |
---|
| 136 | xnanono3(ji,jj,jk) = trb(ji,jj,jk,jpno3) * concbnh4 * zdenom |
---|
| 137 | xnanonh4(ji,jj,jk) = trb(ji,jj,jk,jpnh4) * concbno3 * zdenom |
---|
[3446] | 138 | ! |
---|
| 139 | zlim1 = xnanono3(ji,jj,jk) + xnanonh4(ji,jj,jk) |
---|
[5385] | 140 | zlim2 = trb(ji,jj,jk,jppo4) / ( trb(ji,jj,jk,jppo4) + concbnh4 ) |
---|
| 141 | zlim3 = trb(ji,jj,jk,jpfer) / ( concbfe + trb(ji,jj,jk,jpfer) ) |
---|
| 142 | zlim4 = trb(ji,jj,jk,jpdoc) / ( xkdoc + trb(ji,jj,jk,jpdoc) ) |
---|
[3446] | 143 | xlimbacl(ji,jj,jk) = MIN( zlim1, zlim2, zlim3 ) |
---|
| 144 | xlimbac (ji,jj,jk) = MIN( zlim1, zlim2, zlim3 ) * zlim4 |
---|
| 145 | |
---|
[3443] | 146 | ! Michaelis-Menten Limitation term for nutrients Small flagellates |
---|
| 147 | ! ----------------------------------------------- |
---|
[5385] | 148 | zdenom = 1. / ( zconc0n * zconc0nnh4 + zconc0nnh4 * trb(ji,jj,jk,jpno3) + zconc0n * trb(ji,jj,jk,jpnh4) ) |
---|
| 149 | xnanono3(ji,jj,jk) = trb(ji,jj,jk,jpno3) * zconc0nnh4 * zdenom |
---|
| 150 | xnanonh4(ji,jj,jk) = trb(ji,jj,jk,jpnh4) * zconc0n * zdenom |
---|
[3443] | 151 | ! |
---|
| 152 | zlim1 = xnanono3(ji,jj,jk) + xnanonh4(ji,jj,jk) |
---|
[5385] | 153 | zlim2 = trb(ji,jj,jk,jppo4) / ( trb(ji,jj,jk,jppo4) + zconc0nnh4 ) |
---|
| 154 | zratio = trb(ji,jj,jk,jpnfe) * z1_trbphy |
---|
| 155 | zironmin = xcoef1 * trb(ji,jj,jk,jpnch) * z1_trbphy + xcoef2 * zlim1 + xcoef3 * xnanono3(ji,jj,jk) |
---|
[3443] | 156 | zlim3 = MAX( 0.,( zratio - zironmin ) / qnfelim ) |
---|
[4529] | 157 | xnanopo4(ji,jj,jk) = zlim2 |
---|
| 158 | xlimnfe (ji,jj,jk) = MIN( 1., zlim3 ) |
---|
| 159 | xlimphy (ji,jj,jk) = MIN( zlim1, zlim2, zlim3 ) |
---|
[3443] | 160 | ! |
---|
| 161 | ! Michaelis-Menten Limitation term for nutrients Diatoms |
---|
| 162 | ! ---------------------------------------------- |
---|
[5385] | 163 | zdenom = 1. / ( zconc1d * zconc1dnh4 + zconc1dnh4 * trb(ji,jj,jk,jpno3) + zconc1d * trb(ji,jj,jk,jpnh4) ) |
---|
| 164 | xdiatno3(ji,jj,jk) = trb(ji,jj,jk,jpno3) * zconc1dnh4 * zdenom |
---|
| 165 | xdiatnh4(ji,jj,jk) = trb(ji,jj,jk,jpnh4) * zconc1d * zdenom |
---|
[3443] | 166 | ! |
---|
| 167 | zlim1 = xdiatno3(ji,jj,jk) + xdiatnh4(ji,jj,jk) |
---|
[5385] | 168 | zlim2 = trb(ji,jj,jk,jppo4) / ( trb(ji,jj,jk,jppo4) + zconc1dnh4 ) |
---|
| 169 | zlim3 = trb(ji,jj,jk,jpsil) / ( trb(ji,jj,jk,jpsil) + xksi(ji,jj) ) |
---|
| 170 | zratio = trb(ji,jj,jk,jpdfe) * z1_trbdia |
---|
| 171 | zironmin = xcoef1 * trb(ji,jj,jk,jpdch) * z1_trbdia + xcoef2 * zlim1 + xcoef3 * xdiatno3(ji,jj,jk) |
---|
[3443] | 172 | zlim4 = MAX( 0., ( zratio - zironmin ) / qdfelim ) |
---|
[4529] | 173 | xdiatpo4(ji,jj,jk) = zlim2 |
---|
| 174 | xlimdfe (ji,jj,jk) = MIN( 1., zlim4 ) |
---|
| 175 | xlimdia (ji,jj,jk) = MIN( zlim1, zlim2, zlim3, zlim4 ) |
---|
| 176 | xlimsi (ji,jj,jk) = MIN( zlim1, zlim2, zlim4 ) |
---|
[3443] | 177 | END DO |
---|
| 178 | END DO |
---|
| 179 | END DO |
---|
| 180 | |
---|
| 181 | ! Compute the fraction of nanophytoplankton that is made of calcifiers |
---|
| 182 | ! -------------------------------------------------------------------- |
---|
| 183 | DO jk = 1, jpkm1 |
---|
| 184 | DO jj = 1, jpj |
---|
| 185 | DO ji = 1, jpi |
---|
[5385] | 186 | zlim1 = ( trb(ji,jj,jk,jpno3) * concnnh4 + trb(ji,jj,jk,jpnh4) * concnno3 ) & |
---|
| 187 | & / ( concnno3 * concnnh4 + concnnh4 * trb(ji,jj,jk,jpno3) + concnno3 * trb(ji,jj,jk,jpnh4) ) |
---|
| 188 | zlim2 = trb(ji,jj,jk,jppo4) / ( trb(ji,jj,jk,jppo4) + concnnh4 ) |
---|
[7180] | 189 | zlim3 = trb(ji,jj,jk,jpfer) / ( trb(ji,jj,jk,jpfer) + 1.E-10 ) |
---|
[3443] | 190 | ztem1 = MAX( 0., tsn(ji,jj,jk,jp_tem) ) |
---|
| 191 | ztem2 = tsn(ji,jj,jk,jp_tem) - 10. |
---|
[5385] | 192 | zetot1 = MAX( 0., etot_ndcy(ji,jj,jk) - 1.) / ( 4. + etot_ndcy(ji,jj,jk) ) |
---|
| 193 | zetot2 = 30. / ( 30. + etot_ndcy(ji,jj,jk) ) |
---|
[3443] | 194 | |
---|
| 195 | xfracal(ji,jj,jk) = caco3r * MIN( zlim1, zlim2, zlim3 ) & |
---|
| 196 | & * ztem1 / ( 0.1 + ztem1 ) & |
---|
[5385] | 197 | & * MAX( 1., trb(ji,jj,jk,jpphy) * 1.e6 / 2. ) & |
---|
[3446] | 198 | & * zetot1 * zetot2 & |
---|
[3443] | 199 | & * ( 1. + EXP(-ztem2 * ztem2 / 25. ) ) & |
---|
| 200 | & * MIN( 1., 50. / ( hmld(ji,jj) + rtrn ) ) |
---|
| 201 | xfracal(ji,jj,jk) = MIN( 0.8 , xfracal(ji,jj,jk) ) |
---|
| 202 | xfracal(ji,jj,jk) = MAX( 0.02, xfracal(ji,jj,jk) ) |
---|
| 203 | END DO |
---|
| 204 | END DO |
---|
| 205 | END DO |
---|
| 206 | ! |
---|
[4996] | 207 | ! |
---|
[5385] | 208 | IF( lk_iomput .AND. knt == nrdttrc ) THEN ! save output diagnostics |
---|
[4996] | 209 | IF( iom_use( "xfracal" ) ) CALL iom_put( "xfracal", xfracal(:,:,:) * tmask(:,:,:) ) ! euphotic layer deptht |
---|
| 210 | IF( iom_use( "LNnut" ) ) CALL iom_put( "LNnut" , xlimphy(:,:,:) * tmask(:,:,:) ) ! Nutrient limitation term |
---|
| 211 | IF( iom_use( "LDnut" ) ) CALL iom_put( "LDnut" , xlimdia(:,:,:) * tmask(:,:,:) ) ! Nutrient limitation term |
---|
| 212 | IF( iom_use( "LNFe" ) ) CALL iom_put( "LNFe" , xlimnfe(:,:,:) * tmask(:,:,:) ) ! Iron limitation term |
---|
| 213 | IF( iom_use( "LDFe" ) ) CALL iom_put( "LDFe" , xlimdfe(:,:,:) * tmask(:,:,:) ) ! Iron limitation term |
---|
[3446] | 214 | ENDIF |
---|
| 215 | ! |
---|
[3443] | 216 | IF( nn_timing == 1 ) CALL timing_stop('p4z_lim') |
---|
| 217 | ! |
---|
| 218 | END SUBROUTINE p4z_lim |
---|
| 219 | |
---|
| 220 | SUBROUTINE p4z_lim_init |
---|
| 221 | |
---|
| 222 | !!---------------------------------------------------------------------- |
---|
| 223 | !! *** ROUTINE p4z_lim_init *** |
---|
| 224 | !! |
---|
| 225 | !! ** Purpose : Initialization of nutrient limitation parameters |
---|
| 226 | !! |
---|
| 227 | !! ** Method : Read the nampislim namelist and check the parameters |
---|
| 228 | !! called at the first timestep (nittrc000) |
---|
| 229 | !! |
---|
| 230 | !! ** input : Namelist nampislim |
---|
| 231 | !! |
---|
| 232 | !!---------------------------------------------------------------------- |
---|
| 233 | |
---|
| 234 | NAMELIST/nampislim/ concnno3, concdno3, concnnh4, concdnh4, concnfer, concdfer, concbfe, & |
---|
[3446] | 235 | & concbno3, concbnh4, xsizedia, xsizephy, xsizern, xsizerd, & |
---|
| 236 | & xksi1, xksi2, xkdoc, qnfelim, qdfelim, caco3r |
---|
[4147] | 237 | INTEGER :: ios ! Local integer output status for namelist read |
---|
[3443] | 238 | |
---|
[4147] | 239 | REWIND( numnatp_ref ) ! Namelist nampislim in reference namelist : Pisces nutrient limitation parameters |
---|
| 240 | READ ( numnatp_ref, nampislim, IOSTAT = ios, ERR = 901) |
---|
| 241 | 901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampislim in reference namelist', lwp ) |
---|
[3443] | 242 | |
---|
[4147] | 243 | REWIND( numnatp_cfg ) ! Namelist nampislim in configuration namelist : Pisces nutrient limitation parameters |
---|
| 244 | READ ( numnatp_cfg, nampislim, IOSTAT = ios, ERR = 902 ) |
---|
| 245 | 902 IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampislim in configuration namelist', lwp ) |
---|
[4624] | 246 | IF(lwm) WRITE ( numonp, nampislim ) |
---|
[4147] | 247 | |
---|
[3443] | 248 | IF(lwp) THEN ! control print |
---|
| 249 | WRITE(numout,*) ' ' |
---|
| 250 | WRITE(numout,*) ' Namelist parameters for nutrient limitations, nampislim' |
---|
| 251 | WRITE(numout,*) ' ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~' |
---|
| 252 | WRITE(numout,*) ' mean rainratio caco3r = ', caco3r |
---|
[3446] | 253 | WRITE(numout,*) ' NO3 half saturation of nanophyto concnno3 = ', concnno3 |
---|
| 254 | WRITE(numout,*) ' NO3 half saturation of diatoms concdno3 = ', concdno3 |
---|
[3443] | 255 | WRITE(numout,*) ' NH4 half saturation for phyto concnnh4 = ', concnnh4 |
---|
| 256 | WRITE(numout,*) ' NH4 half saturation for diatoms concdnh4 = ', concdnh4 |
---|
| 257 | WRITE(numout,*) ' half saturation constant for Si uptake xksi1 = ', xksi1 |
---|
| 258 | WRITE(numout,*) ' half saturation constant for Si/C xksi2 = ', xksi2 |
---|
| 259 | WRITE(numout,*) ' half-sat. of DOC remineralization xkdoc = ', xkdoc |
---|
| 260 | WRITE(numout,*) ' Iron half saturation for nanophyto concnfer = ', concnfer |
---|
| 261 | WRITE(numout,*) ' Iron half saturation for diatoms concdfer = ', concdfer |
---|
| 262 | WRITE(numout,*) ' size ratio for nanophytoplankton xsizern = ', xsizern |
---|
| 263 | WRITE(numout,*) ' size ratio for diatoms xsizerd = ', xsizerd |
---|
[3446] | 264 | WRITE(numout,*) ' NO3 half saturation of bacteria concbno3 = ', concbno3 |
---|
| 265 | WRITE(numout,*) ' NH4 half saturation for bacteria concbnh4 = ', concbnh4 |
---|
[3443] | 266 | WRITE(numout,*) ' Minimum size criteria for diatoms xsizedia = ', xsizedia |
---|
| 267 | WRITE(numout,*) ' Minimum size criteria for nanophyto xsizephy = ', xsizephy |
---|
| 268 | WRITE(numout,*) ' Fe half saturation for bacteria concbfe = ', concbfe |
---|
| 269 | WRITE(numout,*) ' optimal Fe quota for nano. qnfelim = ', qnfelim |
---|
| 270 | WRITE(numout,*) ' Optimal Fe quota for diatoms qdfelim = ', qdfelim |
---|
| 271 | ENDIF |
---|
| 272 | |
---|
| 273 | END SUBROUTINE p4z_lim_init |
---|
| 274 | |
---|
[6453] | 275 | INTEGER FUNCTION p4z_lim_alloc() |
---|
| 276 | !!---------------------------------------------------------------------- |
---|
| 277 | !! *** ROUTINE p5z_lim_alloc *** |
---|
| 278 | !!---------------------------------------------------------------------- |
---|
| 279 | USE lib_mpp , ONLY: ctl_warn |
---|
| 280 | !!---------------------------------------------------------------------- |
---|
| 281 | |
---|
| 282 | !* Biological arrays for phytoplankton growth |
---|
| 283 | ALLOCATE( xnanono3(jpi,jpj,jpk), xdiatno3(jpi,jpj,jpk), & |
---|
| 284 | & xnanonh4(jpi,jpj,jpk), xdiatnh4(jpi,jpj,jpk), & |
---|
| 285 | & xnanopo4(jpi,jpj,jpk), xdiatpo4(jpi,jpj,jpk), & |
---|
| 286 | & xlimphy (jpi,jpj,jpk), xlimdia (jpi,jpj,jpk), & |
---|
| 287 | & xlimnfe (jpi,jpj,jpk), xlimdfe (jpi,jpj,jpk), & |
---|
| 288 | & xlimbac (jpi,jpj,jpk), xlimbacl(jpi,jpj,jpk), & |
---|
| 289 | & concnfe (jpi,jpj,jpk), concdfe (jpi,jpj,jpk), & |
---|
| 290 | & xlimsi (jpi,jpj,jpk), STAT=p4z_lim_alloc ) |
---|
| 291 | ! |
---|
| 292 | IF( p4z_lim_alloc /= 0 ) CALL ctl_warn('p4z_lim_alloc : failed to allocate arrays.') |
---|
| 293 | ! |
---|
| 294 | END FUNCTION p4z_lim_alloc |
---|
| 295 | |
---|
| 296 | |
---|
[3443] | 297 | #else |
---|
| 298 | !!====================================================================== |
---|
| 299 | !! Dummy module : No PISCES bio-model |
---|
| 300 | !!====================================================================== |
---|
| 301 | CONTAINS |
---|
| 302 | SUBROUTINE p4z_lim ! Empty routine |
---|
| 303 | END SUBROUTINE p4z_lim |
---|
| 304 | #endif |
---|
| 305 | |
---|
| 306 | !!====================================================================== |
---|
[6204] | 307 | END MODULE p4zlim |
---|