New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p4zprod.F90 in branches/CNRS/dev_r6270_PISCES_QUOTA/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z – NEMO

source: branches/CNRS/dev_r6270_PISCES_QUOTA/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z/p4zprod.F90 @ 7180

Last change on this file since 7180 was 7180, checked in by aumont, 7 years ago

various bug fixes on iron chemistry
File size: 29.5 KB
Line 
1MODULE p4zprod
2   !!======================================================================
3   !!                         ***  MODULE p4zprod  ***
4   !! TOP :  Growth Rate of the two phytoplanktons groups
5   !!======================================================================
6   !! History :   1.0  !  2004     (O. Aumont) Original code
7   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
8   !!             3.4  !  2011-05  (O. Aumont, C. Ethe) New parameterization of light limitation
9   !!----------------------------------------------------------------------
10#if defined key_pisces
11   !!----------------------------------------------------------------------
12   !!   'key_pisces'                                       PISCES bio-model
13   !!----------------------------------------------------------------------
14   !!   p4z_prod       :   Compute the growth Rate of the two phytoplanktons groups
15   !!   p4z_prod_init  :   Initialization of the parameters for growth
16   !!   p4z_prod_alloc :   Allocate variables for growth
17   !!----------------------------------------------------------------------
18   USE oce_trc         !  shared variables between ocean and passive tracers
19   USE trc             !  passive tracers common variables
20   USE sms_pisces      !  PISCES Source Minus Sink variables
21   USE p4zopt          !  optical model
22   USE p4zlim          !  Co-limitations of differents nutrients
23   USE prtctl_trc      !  print control for debugging
24   USE iom             !  I/O manager
25
26   IMPLICIT NONE
27   PRIVATE
28
29   PUBLIC   p4z_prod         ! called in p4zbio.F90
30   PUBLIC   p4z_prod_init    ! called in trcsms_pisces.F90
31   PUBLIC   p4z_prod_alloc
32
33   !! * Shared module variables
34   LOGICAL , PUBLIC ::  ln_newprod      !:
35   REAL(wp), PUBLIC ::  pislopen         !:
36   REAL(wp), PUBLIC ::  pisloped        !:
37   REAL(wp), PUBLIC ::  xadap           !:
38   REAL(wp), PUBLIC ::  excretn          !:
39   REAL(wp), PUBLIC ::  excretd         !:
40   REAL(wp), PUBLIC ::  bresp           !:
41   REAL(wp), PUBLIC ::  chlcnm          !:
42   REAL(wp), PUBLIC ::  chlcdm          !:
43   REAL(wp), PUBLIC ::  chlcmin         !:
44   REAL(wp), PUBLIC ::  fecnm           !:
45   REAL(wp), PUBLIC ::  fecdm           !:
46   REAL(wp), PUBLIC ::  grosip          !:
47
48   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   prmax    !: optimal production = f(temperature)
49   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   quotan   !: proxy of N quota in Nanophyto
50   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   quotad   !: proxy of N quota in diatomee
51   
52   REAL(wp) :: r1_rday                !: 1 / rday
53   REAL(wp) :: texcretn               !: 1 - excretn
54   REAL(wp) :: texcretd               !: 1 - excretd       
55
56
57   !!* Substitution
58#  include "top_substitute.h90"
59   !!----------------------------------------------------------------------
60   !! NEMO/TOP 3.3 , NEMO Consortium (2010)
61   !! $Id: p4zprod.F90 3160 2011-11-20 14:27:18Z cetlod $
62   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
63   !!----------------------------------------------------------------------
64CONTAINS
65
66   SUBROUTINE p4z_prod( kt , knt )
67      !!---------------------------------------------------------------------
68      !!                     ***  ROUTINE p4z_prod  ***
69      !!
70      !! ** Purpose :   Compute the phytoplankton production depending on
71      !!              light, temperature and nutrient availability
72      !!
73      !! ** Method  : - ???
74      !!---------------------------------------------------------------------
75      !
76      INTEGER, INTENT(in) :: kt, knt
77      !
78      INTEGER  ::   ji, jj, jk
79      REAL(wp) ::   zsilfac, znanotot, zdiattot, zconctemp, zconctemp2
80      REAL(wp) ::   zratio, zmax, zsilim, ztn, zadap, zlim, zsilfac2, zsiborn
81      REAL(wp) ::   zprod, zproreg, zproreg2, zprochln, zprochld
82      REAL(wp) ::   zmaxday, zdocprod, zpislopen, zpisloped
83      REAL(wp) ::   zmxltst, zmxlday
84      REAL(wp) ::   zrum, zcodel, zargu, zval, zfeup, chlcnm_n, chlcdm_n
85      REAL(wp) ::   zfact
86      CHARACTER (len=25) :: charout
87      REAL(wp), POINTER, DIMENSION(:,:  ) :: zstrn, zw2d, zmixnano, zmixdiat
88      REAL(wp), POINTER, DIMENSION(:,:,:) :: zpislopeadn, zpislopeadd, zprdia, zprbio, zprdch, zprnch, zysopt, zw3d   
89      REAL(wp), POINTER, DIMENSION(:,:,:) :: zprorcan, zprorcad, zprofed, zprofen, zpronewn, zpronewd
90      REAL(wp), POINTER, DIMENSION(:,:,:) :: zmxl_fac, zmxl_chl
91      !!---------------------------------------------------------------------
92      !
93      IF( nn_timing == 1 )  CALL timing_start('p4z_prod')
94      !
95      !  Allocate temporary workspace
96      CALL wrk_alloc( jpi, jpj,      zmixnano, zmixdiat, zstrn )
97      CALL wrk_alloc( jpi, jpj, jpk, zpislopeadn, zpislopeadd, zprdia, zprbio, zprdch, zprnch, zysopt ) 
98      CALL wrk_alloc( jpi, jpj, jpk, zmxl_fac, zmxl_chl )
99      CALL wrk_alloc( jpi, jpj, jpk, zprorcan, zprorcad, zprofed, zprofen, zpronewn, zpronewd )
100      !
101      zprorcan(:,:,:) = 0._wp ; zprorcad(:,:,:) = 0._wp ; zprofed (:,:,:) = 0._wp
102      zprofen (:,:,:) = 0._wp ; zysopt  (:,:,:) = 0._wp
103      zpronewn(:,:,:) = 0._wp ; zpronewd(:,:,:) = 0._wp ; zprdia  (:,:,:) = 0._wp
104      zprbio  (:,:,:) = 0._wp ; zprdch  (:,:,:) = 0._wp ; zprnch  (:,:,:) = 0._wp 
105
106      ! Computation of the optimal production
107      prmax(:,:,:) = 0.8_wp * r1_rday * tgfunc(:,:,:) 
108      IF( lk_degrad )  prmax(:,:,:) = prmax(:,:,:) * facvol(:,:,:) 
109
110      ! compute the day length depending on latitude and the day
111      zrum = REAL( nday_year - 80, wp ) / REAL( nyear_len(1), wp )
112      zcodel = ASIN(  SIN( zrum * rpi * 2._wp ) * SIN( rad * 23.5_wp )  )
113
114      ! day length in hours
115      zstrn(:,:) = 0.
116      DO jj = 1, jpj
117         DO ji = 1, jpi
118            zargu = TAN( zcodel ) * TAN( gphit(ji,jj) * rad )
119            zargu = MAX( -1., MIN(  1., zargu ) )
120            zstrn(ji,jj) = MAX( 0.0, 24. - 2. * ACOS( zargu ) / rad / 15. )
121         END DO
122      END DO
123
124      ! Impact of the day duration and light intermittency on phytoplankton growth
125      DO jk = 1, jpkm1
126         DO jj = 1 ,jpj
127            DO ji = 1, jpi
128               IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
129                  zval = MAX( 1., zstrn(ji,jj) )
130                  IF( fsdept(ji,jj,jk) <= hmld(ji,jj) ) THEN
131                     zval = zval * MIN(1., heup_01(ji,jj) / ( hmld(ji,jj) + rtrn ))
132                  ENDIF
133                  zmxl_chl(ji,jj,jk) = zval / 24.
134                  zmxl_fac(ji,jj,jk) = 1.5 * zval / ( 12. + zval )
135               ENDIF
136            END DO
137         END DO
138      END DO
139
140      zprbio(:,:,:) = prmax(:,:,:) * zmxl_fac(:,:,:)
141      zprdia(:,:,:) = zprbio(:,:,:)
142
143      ! Maximum light intensity
144      WHERE( zstrn(:,:) < 1.e0 ) zstrn(:,:) = 24.
145
146      ! Computation of the P-I slope for nanos and diatoms
147      DO jk = 1, jpkm1
148!CDIR NOVERRCHK
149         DO jj = 1, jpj
150!CDIR NOVERRCHK
151            DO ji = 1, jpi
152               IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
153                  ztn         = MAX( 0., tsn(ji,jj,jk,jp_tem) - 15. )
154                  zadap       = xadap * ztn / ( 2.+ ztn )
155                  zconctemp   = MAX( 0.e0 , trb(ji,jj,jk,jpdia) - xsizedia )
156                  zconctemp2  = trb(ji,jj,jk,jpdia) - zconctemp
157                  !
158                  zpislopeadn(ji,jj,jk) = pislopen * ( 1.+ zadap  * EXP( -0.25 * enano(ji,jj,jk) ) )  &
159                  &                   * trb(ji,jj,jk,jpnch) /( trb(ji,jj,jk,jpphy) * 12. + rtrn)
160                  !
161                  zpislopeadd(ji,jj,jk) = (pislopen * zconctemp2 + pisloped * zconctemp) / ( trb(ji,jj,jk,jpdia) + rtrn )   &
162                  &                   * trb(ji,jj,jk,jpdch) /( trb(ji,jj,jk,jpdia) * 12. + rtrn)
163               ENDIF
164            END DO
165         END DO
166      END DO
167
168      IF( ln_newprod ) THEN
169         DO jk = 1, jpkm1
170            DO jj = 1, jpj
171               DO ji = 1, jpi
172                  IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
173                      ! Computation of production function for Carbon
174                      !  ---------------------------------------------
175                      zpislopen = zpislopeadn(ji,jj,jk) / ( ( r1_rday + bresp * r1_rday ) &
176                      &            * zmxl_fac(ji,jj,jk) * rday + rtrn)
177                      zpisloped = zpislopeadd(ji,jj,jk) / ( ( r1_rday + bresp * r1_rday ) &
178                      &            * zmxl_fac(ji,jj,jk) * rday + rtrn)
179                      zprbio(ji,jj,jk) = zprbio(ji,jj,jk) * ( 1.- EXP( -zpislopen * enano(ji,jj,jk) )  )
180                      zprdia(ji,jj,jk) = zprdia(ji,jj,jk) * ( 1.- EXP( -zpisloped * ediat(ji,jj,jk) )  )
181                      !  Computation of production function for Chlorophyll
182                      !--------------------------------------------------
183                      zpislopen = zpislopeadn(ji,jj,jk) / ( prmax(ji,jj,jk) * zmxl_chl(ji,jj,jk) * rday + rtrn )
184                      zpisloped = zpislopeadd(ji,jj,jk) / ( prmax(ji,jj,jk) * zmxl_chl(ji,jj,jk) * rday + rtrn )
185                      zprnch(ji,jj,jk) = prmax(ji,jj,jk) * ( 1.- EXP( -zpislopen * enano(ji,jj,jk) ) )
186                      zprdch(ji,jj,jk) = prmax(ji,jj,jk) * ( 1.- EXP( -zpisloped * ediat(ji,jj,jk) ) )
187                  ENDIF
188               END DO
189            END DO
190         END DO
191      ELSE
192         DO jk = 1, jpkm1
193            DO jj = 1, jpj
194               DO ji = 1, jpi
195                  IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
196                      ! Computation of production function for Carbon
197                      !  ---------------------------------------------
198                      zpislopen = zpislopeadn(ji,jj,jk)  / ( zprbio(ji,jj,jk) * rday * xlimphy(ji,jj,jk) + rtrn )
199                      zpisloped = zpislopeadd(ji,jj,jk) / ( zprdia(ji,jj,jk) * rday * xlimdia(ji,jj,jk) + rtrn )
200                      zprbio(ji,jj,jk) = zprbio(ji,jj,jk) * ( 1.- EXP( -zpislopen * enano(ji,jj,jk) ) )
201                      zprdia(ji,jj,jk) = zprdia(ji,jj,jk) * ( 1.- EXP( -zpisloped * ediat(ji,jj,jk) ) )
202                      !  Computation of production function for Chlorophyll
203                      !--------------------------------------------------
204                      zpislopen = zpislopen * zmxl_fac(ji,jj,jk) / ( zmxl_chl(ji,jj,jk) + rtrn )
205                      zpisloped = zpisloped * zmxl_fac(ji,jj,jk) / ( zmxl_chl(ji,jj,jk) + rtrn )
206                      zprnch(ji,jj,jk) = prmax(ji,jj,jk) * ( 1.- EXP( -zpislopen * enano(ji,jj,jk) ) )
207                      zprdch(ji,jj,jk) = prmax(ji,jj,jk) * ( 1.- EXP( -zpisloped * ediat(ji,jj,jk) ) )
208                  ENDIF
209               END DO
210            END DO
211         END DO
212      ENDIF
213
214      !  Computation of a proxy of the N/C ratio
215      !  ---------------------------------------
216      DO jk = 1, jpkm1
217         DO jj = 1, jpj
218            DO ji = 1, jpi
219                zval = MIN( xnanopo4(ji,jj,jk), ( xnanonh4(ji,jj,jk) + xnanono3(ji,jj,jk) ) )   &
220                &      * prmax(ji,jj,jk) / ( zprbio(ji,jj,jk) + rtrn )
221                quotan(ji,jj,jk) = MIN( 1., 0.2 + 0.8 * zval )
222                zval = MIN( xdiatpo4(ji,jj,jk), ( xdiatnh4(ji,jj,jk) + xdiatno3(ji,jj,jk) ) )   &
223                &      * prmax(ji,jj,jk) / ( zprdia(ji,jj,jk) + rtrn )
224                quotad(ji,jj,jk) = MIN( 1., 0.2 + 0.8 * zval )
225            END DO
226         END DO
227      END DO
228
229
230      DO jk = 1, jpkm1
231         DO jj = 1, jpj
232            DO ji = 1, jpi
233
234                IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
235                   !    Si/C of diatoms
236                   !    ------------------------
237                   !    Si/C increases with iron stress and silicate availability
238                   !    Si/C is arbitrariliy increased for very high Si concentrations
239                   !    to mimic the very high ratios observed in the Southern Ocean (silpot2)
240                  zlim  = trb(ji,jj,jk,jpsil) / ( trb(ji,jj,jk,jpsil) + xksi1 )
241                  zsilim = MIN( zprdia(ji,jj,jk) / ( prmax(ji,jj,jk) + rtrn ), xlimsi(ji,jj,jk) )
242                  zsilfac = 4.4 * EXP( -4.23 * zsilim ) * MAX( 0.e0, MIN( 1., 2.2 * ( zlim - 0.5 ) )  ) + 1.e0
243                  zsiborn = trb(ji,jj,jk,jpsil) * trb(ji,jj,jk,jpsil) * trb(ji,jj,jk,jpsil)
244                  IF (gphit(ji,jj) < -30 ) THEN
245                    zsilfac2 = 1. + 2. * zsiborn / ( zsiborn + xksi2**3 )
246                  ELSE
247                    zsilfac2 = 1. +      zsiborn / ( zsiborn + xksi2**3 )
248                  ENDIF
249                  zysopt(ji,jj,jk) = grosip * zlim * zsilfac * zsilfac2
250              ENDIF
251            END DO
252         END DO
253      END DO
254
255      !  Mixed-layer effect on production
256      !  Sea-ice effect on production
257
258      DO jk = 1, jpkm1
259         DO jj = 1, jpj
260            DO ji = 1, jpi
261               zprbio(ji,jj,jk) = zprbio(ji,jj,jk) * ( 1. - fr_i(ji,jj) )
262               zprdia(ji,jj,jk) = zprdia(ji,jj,jk) * ( 1. - fr_i(ji,jj) )
263            END DO
264         END DO
265      END DO
266
267      ! Computation of the various production terms
268!CDIR NOVERRCHK
269      DO jk = 1, jpkm1
270!CDIR NOVERRCHK
271         DO jj = 1, jpj
272!CDIR NOVERRCHK
273            DO ji = 1, jpi
274               IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
275                  !  production terms for nanophyto. (C)
276                  zprorcan(ji,jj,jk) = zprbio(ji,jj,jk)  * xlimphy(ji,jj,jk) * trb(ji,jj,jk,jpphy) * rfact2
277                  zpronewn(ji,jj,jk)  = zprorcan(ji,jj,jk)* xnanono3(ji,jj,jk) / ( xnanono3(ji,jj,jk) + xnanonh4(ji,jj,jk) + rtrn )
278                  !
279                  zratio = trb(ji,jj,jk,jpnfe) / ( trb(ji,jj,jk,jpphy) * fecnm + rtrn )
280                  zmax   = MAX( 0., ( 1. - zratio ) / ABS( 1.05 - zratio ) ) 
281                  zprofen(ji,jj,jk) = fecnm * prmax(ji,jj,jk) * ( 1.0 - fr_i(ji,jj) )  &
282                  &             * ( 4. - 4.5 * xlimnfe(ji,jj,jk) / ( xlimnfe(ji,jj,jk) + 0.5 ) )    &
283                  &             * biron(ji,jj,jk) / ( biron(ji,jj,jk) + concnfe(ji,jj,jk) )  &
284                  &             * zmax * trb(ji,jj,jk,jpphy) * rfact2
285                  !  production terms for diatoms (C)
286                  zprorcad(ji,jj,jk) = zprdia(ji,jj,jk) * xlimdia(ji,jj,jk) * trb(ji,jj,jk,jpdia) * rfact2
287                  zpronewd(ji,jj,jk) = zprorcad(ji,jj,jk) * xdiatno3(ji,jj,jk) / ( xdiatno3(ji,jj,jk) + xdiatnh4(ji,jj,jk) + rtrn )
288                  !
289                  zratio = trb(ji,jj,jk,jpdfe) / ( trb(ji,jj,jk,jpdia) * fecdm + rtrn )
290                  zmax   = MAX( 0., ( 1. - zratio ) / ABS( 1.05 - zratio ) ) 
291                  zprofed(ji,jj,jk) = fecdm * prmax(ji,jj,jk) * ( 1.0 - fr_i(ji,jj) )  &
292                  &             * ( 4. - 4.5 * xlimdfe(ji,jj,jk) / ( xlimdfe(ji,jj,jk) + 0.5 ) )    &
293                  &             * biron(ji,jj,jk) / ( biron(ji,jj,jk) + concdfe(ji,jj,jk) )  &
294                  &             * zmax * trb(ji,jj,jk,jpdia) * rfact2
295               ENDIF
296            END DO
297         END DO
298      END DO
299
300      ! Computation of the chlorophyll production terms
301      DO jk = 1, jpkm1
302         DO jj = 1, jpj
303            DO ji = 1, jpi
304               IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
305                  !  production terms for nanophyto. ( chlorophyll )
306                  znanotot = enano(ji,jj,jk) / ( zmxl_chl(ji,jj,jk) + rtrn )
307                  zprod    = rday * zprorcan(ji,jj,jk) * zprnch(ji,jj,jk) * xlimphy(ji,jj,jk)
308                  zprochln = chlcmin * 12. * zprorcan (ji,jj,jk)
309                  chlcnm_n   = MIN ( chlcnm, ( chlcnm / (1. - 1.14 / 43.4 *tsn(ji,jj,jk,jp_tem))) * (1. - 1.14 / 43.4 * 20.))
310                  zprochln = zprochln + (chlcnm_n-chlcmin) * 12. * zprod / &
311                                        & (  zpislopeadn(ji,jj,jk) * znanotot +rtrn)
312                  !  production terms for diatoms ( chlorophyll )
313                  zdiattot = ediat(ji,jj,jk) / ( zmxl_chl(ji,jj,jk) + rtrn )
314                  zprod    = rday * zprorcad(ji,jj,jk) * zprdch(ji,jj,jk) * xlimdia(ji,jj,jk)
315                  zprochld = chlcmin * 12. * zprorcad(ji,jj,jk)
316                  chlcdm_n   = MIN ( chlcdm, ( chlcdm / (1. - 1.14 / 43.4 * tsn(ji,jj,jk,jp_tem))) * (1. - 1.14 / 43.4 * 20.))
317                  zprochld = zprochld + (chlcdm_n-chlcmin) * 12. * zprod / &
318                                        & ( zpislopeadd(ji,jj,jk) * zdiattot +rtrn )
319                  !   Update the arrays TRA which contain the Chla sources and sinks
320                  tra(ji,jj,jk,jpnch) = tra(ji,jj,jk,jpnch) + zprochln * texcretn
321                  tra(ji,jj,jk,jpdch) = tra(ji,jj,jk,jpdch) + zprochld * texcretd
322               ENDIF
323            END DO
324         END DO
325      END DO
326
327      !   Update the arrays TRA which contain the biological sources and sinks
328      DO jk = 1, jpkm1
329         DO jj = 1, jpj
330           DO ji =1 ,jpi
331              IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
332                 zproreg  = zprorcan(ji,jj,jk) - zpronewn(ji,jj,jk)
333                 zproreg2 = zprorcad(ji,jj,jk) - zpronewd(ji,jj,jk)
334                 zdocprod = excretd * zprorcad(ji,jj,jk) + excretn * zprorcan(ji,jj,jk)
335                 tra(ji,jj,jk,jppo4) = tra(ji,jj,jk,jppo4) - zprorcan(ji,jj,jk) - zprorcad(ji,jj,jk)
336                 tra(ji,jj,jk,jpno3) = tra(ji,jj,jk,jpno3) - zpronewn(ji,jj,jk) - zpronewd(ji,jj,jk)
337                 tra(ji,jj,jk,jpnh4) = tra(ji,jj,jk,jpnh4) - zproreg - zproreg2
338                 tra(ji,jj,jk,jpphy) = tra(ji,jj,jk,jpphy) + zprorcan(ji,jj,jk) * texcretn
339                 tra(ji,jj,jk,jpnfe) = tra(ji,jj,jk,jpnfe) + zprofen(ji,jj,jk) * texcretn
340                 tra(ji,jj,jk,jpdia) = tra(ji,jj,jk,jpdia) + zprorcad(ji,jj,jk) * texcretd
341                 tra(ji,jj,jk,jpdfe) = tra(ji,jj,jk,jpdfe) + zprofed(ji,jj,jk) * texcretd
342                 tra(ji,jj,jk,jpdsi) = tra(ji,jj,jk,jpdsi) + zprorcad(ji,jj,jk) * zysopt(ji,jj,jk) * texcretd
343                 tra(ji,jj,jk,jpdoc) = tra(ji,jj,jk,jpdoc) + zdocprod
344                 zfeup = texcretn * zprofen(ji,jj,jk) + texcretd * zprofed(ji,jj,jk)
345#if defined key_ligand
346                 tra(ji,jj,jk,jplgw) = tra(ji,jj,jk,jplgw) + zdocprod * ldocp  - zfeup * plig(ji,jj,jk) * lthet
347#endif
348                 tra(ji,jj,jk,jpoxy) = tra(ji,jj,jk,jpoxy) + o2ut * ( zproreg + zproreg2) &
349                 &                   + ( o2ut + o2nit ) * ( zpronewn(ji,jj,jk) + zpronewd(ji,jj,jk) )
350                 tra(ji,jj,jk,jpfer) = tra(ji,jj,jk,jpfer) - zfeup
351                 tra(ji,jj,jk,jpsil) = tra(ji,jj,jk,jpsil) - texcretd * zprorcad(ji,jj,jk) * zysopt(ji,jj,jk)
352                 tra(ji,jj,jk,jpdic) = tra(ji,jj,jk,jpdic) - zprorcan(ji,jj,jk) - zprorcad(ji,jj,jk)
353                 tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) + rno3 * ( zpronewn(ji,jj,jk) + zpronewd(ji,jj,jk) ) &
354                 &                                         - rno3 * ( zproreg + zproreg2 )
355              ENDIF
356           END DO
357        END DO
358     END DO
359
360
361    ! Total primary production per year
362    IF( iom_use( "tintpp" ) .OR. ( ln_check_mass .AND. kt == nitend .AND. knt == nrdttrc )  )  &
363         & tpp = glob_sum( ( zprorcan(:,:,:) + zprorcad(:,:,:) ) * cvol(:,:,:) )
364
365    IF( lk_iomput ) THEN
366       IF( knt == nrdttrc ) THEN
367          CALL wrk_alloc( jpi, jpj,      zw2d )
368          CALL wrk_alloc( jpi, jpj, jpk, zw3d )
369          zfact = 1.e+3 * rfact2r  !  conversion from mol/l/kt to  mol/m3/s
370          !
371          IF( iom_use( "PPPHY" ) .OR. iom_use( "PPPHY2" ) )  THEN
372              zw3d(:,:,:) = zprorcan(:,:,:) * zfact * tmask(:,:,:)  ! primary production by nanophyto
373              CALL iom_put( "PPPHY"  , zw3d )
374              !
375              zw3d(:,:,:) = zprorcad(:,:,:) * zfact * tmask(:,:,:)  ! primary production by diatomes
376              CALL iom_put( "PPPHY2"  , zw3d )
377          ENDIF
378          IF( iom_use( "PPNEWN" ) .OR. iom_use( "PPNEWD" ) )  THEN
379              zw3d(:,:,:) = zpronewn(:,:,:) * zfact * tmask(:,:,:)  ! new primary production by nanophyto
380              CALL iom_put( "PPNEWN"  , zw3d )
381              !
382              zw3d(:,:,:) = zpronewd(:,:,:) * zfact * tmask(:,:,:)  ! new primary production by diatomes
383              CALL iom_put( "PPNEWD"  , zw3d )
384          ENDIF
385          IF( iom_use( "PBSi" ) )  THEN
386              zw3d(:,:,:) = zprorcad(:,:,:) * zfact * tmask(:,:,:) * zysopt(:,:,:) ! biogenic silica production
387              CALL iom_put( "PBSi"  , zw3d )
388          ENDIF
389          IF( iom_use( "PFeN" ) .OR. iom_use( "PFeD" ) )  THEN
390              zw3d(:,:,:) = zprofen(:,:,:) * zfact * tmask(:,:,:)  ! biogenic iron production by nanophyto
391              CALL iom_put( "PFeN"  , zw3d )
392              !
393              zw3d(:,:,:) = zprofed(:,:,:) * zfact * tmask(:,:,:)  ! biogenic iron production by  diatomes
394              CALL iom_put( "PFeD"  , zw3d )
395          ENDIF
396          IF( iom_use( "Mumax" ) )  THEN
397              zw3d(:,:,:) = prmax(:,:,:) * tmask(:,:,:)   ! Maximum growth rate
398              CALL iom_put( "Mumax"  , zw3d )
399          ENDIF
400          IF( iom_use( "MuN" ) .OR. iom_use( "MuD" ) )  THEN
401              zw3d(:,:,:) = zprbio(:,:,:) * xlimphy(:,:,:) * tmask(:,:,:)  ! Realized growth rate for nanophyto
402              CALL iom_put( "MuN"  , zw3d )
403              !
404              zw3d(:,:,:) =  zprdia(:,:,:) * xlimdia(:,:,:) * tmask(:,:,:)  ! Realized growth rate for diatoms
405              CALL iom_put( "MuD"  , zw3d )
406          ENDIF
407          IF( iom_use( "LNlight" ) .OR. iom_use( "LDlight" ) )  THEN
408              zw3d(:,:,:) = zprbio (:,:,:) / (prmax(:,:,:) + rtrn) * tmask(:,:,:) ! light limitation term
409              CALL iom_put( "LNlight"  , zw3d )
410              !
411              zw3d(:,:,:) =  zprdia (:,:,:) / (prmax(:,:,:) + rtrn) * tmask(:,:,:)  ! light limitation term
412              CALL iom_put( "LDlight"  , zw3d )
413          ENDIF
414          IF( iom_use( "TPP" ) )  THEN
415              zw3d(:,:,:) = ( zprorcan(:,:,:) + zprorcad(:,:,:) ) * zfact * tmask(:,:,:)  ! total primary production
416              CALL iom_put( "TPP"  , zw3d )
417          ENDIF
418          IF( iom_use( "TPNEW" ) )  THEN
419              zw3d(:,:,:) = ( zpronewn(:,:,:) + zpronewd(:,:,:) ) * zfact * tmask(:,:,:)  ! total new production
420              CALL iom_put( "TPNEW"  , zw3d )
421          ENDIF
422          IF( iom_use( "TPBFE" ) )  THEN
423              zw3d(:,:,:) = ( zprofen(:,:,:) + zprofed(:,:,:) ) * zfact * tmask(:,:,:)  ! total biogenic iron production
424              CALL iom_put( "TPBFE"  , zw3d )
425          ENDIF
426          IF( iom_use( "INTPPPHY" ) .OR. iom_use( "INTPPPHY2" ) ) THEN 
427             zw2d(:,:) = 0.
428             DO jk = 1, jpkm1
429               zw2d(:,:) = zw2d(:,:) + zprorcan(:,:,jk) * fse3t(:,:,jk) * zfact * tmask(:,:,jk)  ! vert. integrated  primary produc. by nano
430             ENDDO
431             CALL iom_put( "INTPPPHY" , zw2d )
432             !
433             zw2d(:,:) = 0.
434             DO jk = 1, jpkm1
435                zw2d(:,:) = zw2d(:,:) + zprorcad(:,:,jk) * fse3t(:,:,jk) * zfact * tmask(:,:,jk) ! vert. integrated  primary produc. by diatom
436             ENDDO
437             CALL iom_put( "INTPPPHY2" , zw2d )
438          ENDIF
439          IF( iom_use( "INTPP" ) ) THEN   
440             zw2d(:,:) = 0.
441             DO jk = 1, jpkm1
442                zw2d(:,:) = zw2d(:,:) + ( zprorcan(:,:,jk) + zprorcad(:,:,jk) ) * fse3t(:,:,jk) * zfact * tmask(:,:,jk) ! vert. integrated pp
443             ENDDO
444             CALL iom_put( "INTPP" , zw2d )
445          ENDIF
446          IF( iom_use( "INTPNEW" ) ) THEN   
447             zw2d(:,:) = 0.
448             DO jk = 1, jpkm1
449                zw2d(:,:) = zw2d(:,:) + ( zpronewn(:,:,jk) + zpronewd(:,:,jk) ) * fse3t(:,:,jk) * zfact * tmask(:,:,jk)  ! vert. integrated new prod
450             ENDDO
451             CALL iom_put( "INTPNEW" , zw2d )
452          ENDIF
453          IF( iom_use( "INTPBFE" ) ) THEN           !   total biogenic iron production  ( vertically integrated )
454             zw2d(:,:) = 0.
455             DO jk = 1, jpkm1
456                zw2d(:,:) = zw2d(:,:) + ( zprofen(:,:,jk) + zprofed(:,:,jk) ) * fse3t(:,:,jk) * zfact * tmask(:,:,jk) ! vert integr. bfe prod
457             ENDDO
458            CALL iom_put( "INTPBFE" , zw2d )
459          ENDIF
460          IF( iom_use( "INTPBSI" ) ) THEN           !   total biogenic silica production  ( vertically integrated )
461             zw2d(:,:) = 0.
462             DO jk = 1, jpkm1
463                zw2d(:,:) = zw2d(:,:) + zprorcad(:,:,jk) * zysopt(:,:,jk) * fse3t(:,:,jk) * zfact * tmask(:,:,jk)  ! vert integr. bsi prod
464             ENDDO
465             CALL iom_put( "INTPBSI" , zw2d )
466          ENDIF
467          IF( iom_use( "tintpp" ) )  CALL iom_put( "tintpp" , tpp * zfact )  !  global total integrated primary production molC/s
468          !
469          CALL wrk_dealloc( jpi, jpj,      zw2d )
470          CALL wrk_dealloc( jpi, jpj, jpk, zw3d )
471       ENDIF
472     ELSE
473        IF( ln_diatrc ) THEN
474           zfact = 1.e+3 * rfact2r
475           trc3d(:,:,:,jp_pcs0_3d + 4)  = zprorcan(:,:,:) * zfact * tmask(:,:,:)
476           trc3d(:,:,:,jp_pcs0_3d + 5)  = zprorcad(:,:,:) * zfact * tmask(:,:,:)
477           trc3d(:,:,:,jp_pcs0_3d + 6)  = zpronewn(:,:,:) * zfact * tmask(:,:,:)
478           trc3d(:,:,:,jp_pcs0_3d + 7)  = zpronewd(:,:,:) * zfact * tmask(:,:,:)
479           trc3d(:,:,:,jp_pcs0_3d + 8)  = zprorcad(:,:,:) * zfact * tmask(:,:,:) * zysopt(:,:,:)
480           trc3d(:,:,:,jp_pcs0_3d + 9)  = zprofed (:,:,:) * zfact * tmask(:,:,:)
481#  if ! defined key_kriest
482           trc3d(:,:,:,jp_pcs0_3d + 10) = zprofen (:,:,:) * zfact * tmask(:,:,:)
483#  endif
484        ENDIF
485     ENDIF
486
487     IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
488         WRITE(charout, FMT="('prod')")
489         CALL prt_ctl_trc_info(charout)
490         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
491     ENDIF
492     !
493     CALL wrk_dealloc( jpi, jpj,  zmixnano, zmixdiat,    zstrn )
494     CALL wrk_dealloc( jpi, jpj, jpk, zpislopeadn, zpislopeadd, zprdia, zprbio, zprdch, zprnch, zysopt ) 
495     CALL wrk_dealloc( jpi, jpj, jpk, zmxl_fac, zmxl_chl )
496     CALL wrk_dealloc( jpi, jpj, jpk, zprorcan, zprorcad, zprofed, zprofen, zpronewn, zpronewd )
497     !
498     IF( nn_timing == 1 )  CALL timing_stop('p4z_prod')
499     !
500   END SUBROUTINE p4z_prod
501
502
503   SUBROUTINE p4z_prod_init
504      !!----------------------------------------------------------------------
505      !!                  ***  ROUTINE p4z_prod_init  ***
506      !!
507      !! ** Purpose :   Initialization of phytoplankton production parameters
508      !!
509      !! ** Method  :   Read the nampisprod namelist and check the parameters
510      !!      called at the first timestep (nittrc000)
511      !!
512      !! ** input   :   Namelist nampisprod
513      !!----------------------------------------------------------------------
514      !
515      NAMELIST/nampisprod/ pislopen, pisloped, xadap, ln_newprod, bresp, excretn, excretd,  &
516         &                 chlcnm, chlcdm, chlcmin, fecnm, fecdm, grosip
517      INTEGER :: ios                 ! Local integer output status for namelist read
518      !!----------------------------------------------------------------------
519
520      REWIND( numnatp_ref )              ! Namelist nampisprod in reference namelist : Pisces phytoplankton production
521      READ  ( numnatp_ref, nampisprod, IOSTAT = ios, ERR = 901)
522901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampisprod in reference namelist', lwp )
523
524      REWIND( numnatp_cfg )              ! Namelist nampisprod in configuration namelist : Pisces phytoplankton production
525      READ  ( numnatp_cfg, nampisprod, IOSTAT = ios, ERR = 902 )
526902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampisprod in configuration namelist', lwp )
527      IF(lwm) WRITE ( numonp, nampisprod )
528
529      IF(lwp) THEN                         ! control print
530         WRITE(numout,*) ' '
531         WRITE(numout,*) ' Namelist parameters for phytoplankton growth, nampisprod'
532         WRITE(numout,*) ' ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
533         WRITE(numout,*) '    Enable new parame. of production (T/F)   ln_newprod    =', ln_newprod
534         WRITE(numout,*) '    mean Si/C ratio                           grosip       =', grosip
535         WRITE(numout,*) '    P-I slope                                 pislopen     =', pislopen
536         WRITE(numout,*) '    Acclimation factor to low light           xadap        =', xadap
537         WRITE(numout,*) '    excretion ratio of nanophytoplankton      excretn      =', excretn
538         WRITE(numout,*) '    excretion ratio of diatoms                excretd      =', excretd
539         IF( ln_newprod )  THEN
540            WRITE(numout,*) '    basal respiration in phytoplankton        bresp        =', bresp
541            WRITE(numout,*) '    Maximum Chl/C in phytoplankton            chlcmin      =', chlcmin
542         ENDIF
543         WRITE(numout,*) '    P-I slope  for diatoms                    pisloped     =', pisloped
544         WRITE(numout,*) '    Minimum Chl/C in nanophytoplankton        chlcnm       =', chlcnm
545         WRITE(numout,*) '    Minimum Chl/C in diatoms                  chlcdm       =', chlcdm
546         WRITE(numout,*) '    Maximum Fe/C in nanophytoplankton         fecnm        =', fecnm
547         WRITE(numout,*) '    Minimum Fe/C in diatoms                   fecdm        =', fecdm
548      ENDIF
549      !
550      r1_rday   = 1._wp / rday 
551      texcretn  = 1._wp - excretn
552      texcretd  = 1._wp - excretd
553      tpp       = 0._wp
554      !
555   END SUBROUTINE p4z_prod_init
556
557
558   INTEGER FUNCTION p4z_prod_alloc()
559      !!----------------------------------------------------------------------
560      !!                     ***  ROUTINE p4z_prod_alloc  ***
561      !!----------------------------------------------------------------------
562      ALLOCATE( prmax(jpi,jpj,jpk), quotan(jpi,jpj,jpk), quotad(jpi,jpj,jpk), STAT = p4z_prod_alloc )
563      !
564      IF( p4z_prod_alloc /= 0 ) CALL ctl_warn('p4z_prod_alloc : failed to allocate arrays.')
565      !
566   END FUNCTION p4z_prod_alloc
567
568#else
569   !!======================================================================
570   !!  Dummy module :                                   No PISCES bio-model
571   !!======================================================================
572CONTAINS
573   SUBROUTINE p4z_prod                    ! Empty routine
574   END SUBROUTINE p4z_prod
575#endif 
576
577   !!======================================================================
578END MODULE p4zprod
Note: See TracBrowser for help on using the repository browser.