| 1 | MODULE p5zmeso |
|---|
| 2 | !!====================================================================== |
|---|
| 3 | !! *** MODULE p5zmeso *** |
|---|
| 4 | !! TOP : PISCES Compute the sources/sinks for mesozooplankton |
|---|
| 5 | !!====================================================================== |
|---|
| 6 | !! History : 1.0 ! 2002 (O. Aumont) Original code |
|---|
| 7 | !! 2.0 ! 2007-12 (C. Ethe, G. Madec) F90 |
|---|
| 8 | !! 3.4 ! 2011-06 (O. Aumont, C. Ethe) Quota model for iron |
|---|
| 9 | !! 3.6 ! 2015-05 (O. Aumont) PISCES quota |
|---|
| 10 | !!---------------------------------------------------------------------- |
|---|
| 11 | #if defined key_pisces_quota |
|---|
| 12 | !!---------------------------------------------------------------------- |
|---|
| 13 | !! 'key_pisces_quota' PISCES bio-model |
|---|
| 14 | !!---------------------------------------------------------------------- |
|---|
| 15 | !! p5z_meso : Compute the sources/sinks for mesozooplankton |
|---|
| 16 | !! p5z_meso_init : Initialization of the parameters for mesozooplankton |
|---|
| 17 | !!---------------------------------------------------------------------- |
|---|
| 18 | USE oce_trc ! shared variables between ocean and passive tracers |
|---|
| 19 | USE trc ! passive tracers common variables |
|---|
| 20 | USE sms_pisces ! PISCES Source Minus Sink variables |
|---|
| 21 | USE prtctl_trc ! print control for debugging |
|---|
| 22 | USE p5zsink ! Sedimentation of particles |
|---|
| 23 | USE iom ! I/O manager |
|---|
| 24 | |
|---|
| 25 | IMPLICIT NONE |
|---|
| 26 | PRIVATE |
|---|
| 27 | |
|---|
| 28 | PUBLIC p5z_meso ! called in p5zbio.F90 |
|---|
| 29 | PUBLIC p5z_meso_init ! called in trcsms_pisces.F90 |
|---|
| 30 | |
|---|
| 31 | !! * Shared module variables |
|---|
| 32 | REAL(wp), PUBLIC :: part2 !: part of calcite not dissolved in mesozoo guts |
|---|
| 33 | REAL(wp), PUBLIC :: xpref2c !: mesozoo preference for POC |
|---|
| 34 | REAL(wp), PUBLIC :: xpref2p !: mesozoo preference for nanophyto |
|---|
| 35 | REAL(wp), PUBLIC :: xpref2z !: mesozoo preference for zooplankton |
|---|
| 36 | REAL(wp), PUBLIC :: xpref2d !: mesozoo preference for Diatoms |
|---|
| 37 | REAL(wp), PUBLIC :: xpref2m !: mesozoo preference for mesozoo |
|---|
| 38 | REAL(wp), PUBLIC :: xthresh2zoo !: zoo feeding threshold for mesozooplankton |
|---|
| 39 | REAL(wp), PUBLIC :: xthresh2dia !: diatoms feeding threshold for mesozooplankton |
|---|
| 40 | REAL(wp), PUBLIC :: xthresh2phy !: nanophyto feeding threshold for mesozooplankton |
|---|
| 41 | REAL(wp), PUBLIC :: xthresh2poc !: poc feeding threshold for mesozooplankton |
|---|
| 42 | REAL(wp), PUBLIC :: xthresh2mes !: mesozoo feeding threshold for mesozooplankton |
|---|
| 43 | REAL(wp), PUBLIC :: xthresh2 !: feeding threshold for mesozooplankton |
|---|
| 44 | REAL(wp), PUBLIC :: resrat2 !: exsudation rate of mesozooplankton |
|---|
| 45 | REAL(wp), PUBLIC :: mzrat2 !: microzooplankton mortality rate |
|---|
| 46 | REAL(wp), PUBLIC :: grazrat2 !: maximal mesozoo grazing rate |
|---|
| 47 | REAL(wp), PUBLIC :: xkgraz2 !: non assimilated fraction of P by mesozoo |
|---|
| 48 | REAL(wp), PUBLIC :: unass2c !: Efficicency of mesozoo growth |
|---|
| 49 | REAL(wp), PUBLIC :: unass2n !: Efficicency of mesozoo growth |
|---|
| 50 | REAL(wp), PUBLIC :: unass2p !: Efficicency of mesozoo growth |
|---|
| 51 | REAL(wp), PUBLIC :: epsher2 !: half sturation constant for grazing 2 |
|---|
| 52 | REAL(wp), PUBLIC :: ssigma2 !: Fraction excreted as semi-labile DOM |
|---|
| 53 | REAL(wp), PUBLIC :: srespir2 !: Active respiration |
|---|
| 54 | REAL(wp), PUBLIC :: grazflux !: mesozoo flux feeding rate |
|---|
| 55 | LOGICAL, PUBLIC :: bmetexc2 !: Use of excess carbon for respiration |
|---|
| 56 | |
|---|
| 57 | !!* Substitution |
|---|
| 58 | # include "top_substitute.h90" |
|---|
| 59 | !!---------------------------------------------------------------------- |
|---|
| 60 | !! NEMO/TOP 3.3 , NEMO Consortium (2010) |
|---|
| 61 | !! $Id: p4zmeso.F90 3160 2011-11-20 14:27:18Z cetlod $ |
|---|
| 62 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
|---|
| 63 | !!---------------------------------------------------------------------- |
|---|
| 64 | |
|---|
| 65 | CONTAINS |
|---|
| 66 | |
|---|
| 67 | SUBROUTINE p5z_meso( kt, knt ) |
|---|
| 68 | !!--------------------------------------------------------------------- |
|---|
| 69 | !! *** ROUTINE p5z_meso *** |
|---|
| 70 | !! |
|---|
| 71 | !! ** Purpose : Compute the sources/sinks for mesozooplankton |
|---|
| 72 | !! |
|---|
| 73 | !! ** Method : - ??? |
|---|
| 74 | !!--------------------------------------------------------------------- |
|---|
| 75 | INTEGER, INTENT(in) :: kt, knt ! ocean time step |
|---|
| 76 | INTEGER :: ji, jj, jk |
|---|
| 77 | REAL(wp) :: zcompadi, zcompaph, zcompapoc, zcompaz, zcompam, zcompames |
|---|
| 78 | REAL(wp) :: zgraze2, zdenom, zfact, zstep, zfood, zfoodlim, zproport |
|---|
| 79 | REAL(wp) :: zmortzgoc, zfracc, zfracn, zfracp, zfracfe, zratio, zratio2 |
|---|
| 80 | REAL(wp) :: zepsherf, zepshert, zepsherv, zrespirc, zrespirn, zrespirp, zbasresb, zbasresi |
|---|
| 81 | REAL(wp) :: zgraztotc, zgraztotn, zgraztotp, zgraztotf, zbasresn, zbasresp, zbasresf |
|---|
| 82 | REAL(wp) :: zgradoc, zgradon, zgradop, zgratmp, zgradoct, zgradont, zgrareft, zgradopt |
|---|
| 83 | REAL(wp) :: zgrapoc, zgrapon, zgrapop, zgrapof, zprcaca, zmortz |
|---|
| 84 | REAL(wp) :: zexcess, zgrarem, zgraren, zgrarep, zgraref |
|---|
| 85 | REAL(wp) :: zbeta, zrespz, ztortz, zgrasratp, zgrasratn, zgrasratf |
|---|
| 86 | REAL(wp) :: ztmp1, ztmp2, ztmp3, ztmp4, ztmp5, ztmptot |
|---|
| 87 | REAL(wp) :: zgrazdc, zgrazz, zgrazm, zgrazpof, zgrazcal, zfracal |
|---|
| 88 | REAL(wp) :: zgraznc, zgrazpoc, zgrazpon, zgrazpop, zgraznf, zgrazdf |
|---|
| 89 | REAL(wp) :: zgraznp, zgraznn, zgrazdn, zgrazdp |
|---|
| 90 | REAL(wp) :: zgrazfffp, zgrazfffg, zgrazffep, zgrazffeg |
|---|
| 91 | REAL(wp) :: zgrazffnp, zgrazffng, zgrazffpp, zgrazffpg |
|---|
| 92 | CHARACTER (len=25) :: charout |
|---|
| 93 | REAL(wp) :: zrfact2, zmetexcess |
|---|
| 94 | REAL(wp), POINTER, DIMENSION(:,:,:) :: zgrazing, zw3d, zfezoo2 |
|---|
| 95 | #if defined key_ligand |
|---|
| 96 | REAL(wp), POINTER, DIMENSION(:,:,:) :: zz2ligprod |
|---|
| 97 | #endif |
|---|
| 98 | |
|---|
| 99 | !!--------------------------------------------------------------------- |
|---|
| 100 | ! |
|---|
| 101 | IF( nn_timing == 1 ) CALL timing_start('p5z_meso') |
|---|
| 102 | ! |
|---|
| 103 | CALL wrk_alloc( jpi, jpj, jpk, zgrazing, zfezoo2 ) |
|---|
| 104 | #if defined key_ligand |
|---|
| 105 | CALL wrk_alloc( jpi, jpj, jpk, zz2ligprod ) |
|---|
| 106 | zz2ligprod(:,:,:) = 0._wp |
|---|
| 107 | #endif |
|---|
| 108 | zgrazing(:,:,:) = 0._wp |
|---|
| 109 | zfezoo2(:,:,:) = 0._wp |
|---|
| 110 | |
|---|
| 111 | zmetexcess = 0.0 |
|---|
| 112 | IF ( bmetexc2 ) zmetexcess = 1.0 |
|---|
| 113 | |
|---|
| 114 | DO jk = 1, jpkm1 |
|---|
| 115 | DO jj = 1, jpj |
|---|
| 116 | DO ji = 1, jpi |
|---|
| 117 | zcompam = MAX( ( trb(ji,jj,jk,jpmes) - 1.e-9 ), 0.e0 ) |
|---|
| 118 | zstep = xstep |
|---|
| 119 | zfact = zstep * tgfunc2(ji,jj,jk) * zcompam |
|---|
| 120 | |
|---|
| 121 | ! Michaelis-Menten mortality rates of mesozooplankton |
|---|
| 122 | ! --------------------------------------------------- |
|---|
| 123 | zrespz = resrat2 * zfact * ( trb(ji,jj,jk,jpmes) / ( xkmort + trb(ji,jj,jk,jpmes) ) & |
|---|
| 124 | & + 3. * nitrfac(ji,jj,jk) ) |
|---|
| 125 | |
|---|
| 126 | ! Zooplankton mortality. A square function has been selected with |
|---|
| 127 | ! no real reason except that it seems to be more stable and may mimic predation |
|---|
| 128 | ! --------------------------------------------------------------- |
|---|
| 129 | ztortz = mzrat2 * 1.e6 * zfact * trb(ji,jj,jk,jpmes) |
|---|
| 130 | |
|---|
| 131 | ! Computation of the abundance of the preys |
|---|
| 132 | ! A threshold can be specified in the namelist |
|---|
| 133 | ! -------------------------------------------- |
|---|
| 134 | zcompadi = MAX( ( trb(ji,jj,jk,jpdia) - xthresh2dia ), 0.e0 ) |
|---|
| 135 | zcompaz = MAX( ( trb(ji,jj,jk,jpzoo) - xthresh2zoo ), 0.e0 ) |
|---|
| 136 | zcompaph = MAX( ( trb(ji,jj,jk,jpphy) - xthresh2phy ), 0.e0 ) |
|---|
| 137 | zcompapoc = MAX( ( trb(ji,jj,jk,jppoc) - xthresh2poc ), 0.e0 ) |
|---|
| 138 | zcompames = MAX( ( trb(ji,jj,jk,jpmes) - xthresh2mes ), 0.e0 ) |
|---|
| 139 | |
|---|
| 140 | ! Mesozooplankton grazing |
|---|
| 141 | ! ------------------------ |
|---|
| 142 | zfood = xpref2d * zcompadi + xpref2z * zcompaz + xpref2p * zcompaph + xpref2c * zcompapoc & |
|---|
| 143 | & + xpref2m * zcompames |
|---|
| 144 | zfoodlim = MAX( 0., zfood - MIN( 0.5 * zfood, xthresh2 ) ) |
|---|
| 145 | zdenom = zfoodlim / ( xkgraz2 + zfoodlim ) |
|---|
| 146 | zgraze2 = grazrat2 * zstep * tgfunc2(ji,jj,jk) * trb(ji,jj,jk,jpmes) |
|---|
| 147 | |
|---|
| 148 | ! An active switching parameterization is used here. |
|---|
| 149 | ! We don't use the KTW parameterization proposed by |
|---|
| 150 | ! Vallina et al. because it tends to produce to steady biomass |
|---|
| 151 | ! composition and the variance of Chl is too low as it grazes |
|---|
| 152 | ! too strongly on winning organisms. Thus, instead of a square |
|---|
| 153 | ! a 1.5 power value is used which decreases the pressure on the |
|---|
| 154 | ! most abundant species |
|---|
| 155 | ! ------------------------------------------------------------ |
|---|
| 156 | ztmp1 = xpref2p * zcompaph * (0.75 * zcompaph + 0.25 * zcompadi) |
|---|
| 157 | ztmp2 = xpref2m * zcompames**2 |
|---|
| 158 | ztmp3 = xpref2c * zcompapoc**2 |
|---|
| 159 | ztmp4 = xpref2d * zcompadi * (0.75 * zcompadi + 0.25 * zcompaph) |
|---|
| 160 | ztmp5 = xpref2z * zcompaz**2 |
|---|
| 161 | ztmptot = ztmp1 + ztmp2 + ztmp3 + ztmp4 + ztmp5 + rtrn |
|---|
| 162 | ztmp1 = ztmp1 / ztmptot |
|---|
| 163 | ztmp2 = ztmp2 / ztmptot |
|---|
| 164 | ztmp3 = ztmp3 / ztmptot |
|---|
| 165 | ztmp4 = ztmp4 / ztmptot |
|---|
| 166 | ztmp5 = ztmp5 / ztmptot |
|---|
| 167 | |
|---|
| 168 | ! Mesozooplankton regular grazing on the different preys |
|---|
| 169 | ! ------------------------------------------------------ |
|---|
| 170 | zgrazdc = zgraze2 * ztmp4 * zdenom |
|---|
| 171 | zgrazdn = zgrazdc * trb(ji,jj,jk,jpndi) / ( trb(ji,jj,jk,jpdia) + rtrn) |
|---|
| 172 | zgrazdp = zgrazdc * trb(ji,jj,jk,jppdi) / ( trb(ji,jj,jk,jpdia) + rtrn) |
|---|
| 173 | zgrazdf = zgrazdc * trb(ji,jj,jk,jpdfe) / ( trb(ji,jj,jk,jpdia) + rtrn) |
|---|
| 174 | zgrazz = zgraze2 * ztmp5 * zdenom |
|---|
| 175 | zgrazm = zgraze2 * ztmp2 * zdenom |
|---|
| 176 | zgraznc = zgraze2 * ztmp1 * zdenom |
|---|
| 177 | zgraznn = zgraznc * trb(ji,jj,jk,jpnph) / ( trb(ji,jj,jk,jpphy) + rtrn) |
|---|
| 178 | zgraznp = zgraznc * trb(ji,jj,jk,jppph) / ( trb(ji,jj,jk,jpphy) + rtrn) |
|---|
| 179 | zgraznf = zgraznc * trb(ji,jj,jk,jpnfe) / ( trb(ji,jj,jk,jpphy) + rtrn) |
|---|
| 180 | zgrazpoc = zgraze2 * ztmp3 * zdenom |
|---|
| 181 | zgrazpon = zgrazpoc * trb(ji,jj,jk,jppon) / ( trb(ji,jj,jk,jppoc) + rtrn) |
|---|
| 182 | zgrazpop = zgrazpoc * trb(ji,jj,jk,jppop) / ( trb(ji,jj,jk,jppoc) + rtrn) |
|---|
| 183 | zgrazpof = zgrazpoc * trb(ji,jj,jk,jpsfe) / ( trb(ji,jj,jk,jppoc) + rtrn) |
|---|
| 184 | |
|---|
| 185 | ! Mesozooplankton flux feeding on GOC |
|---|
| 186 | ! ---------------------------------- |
|---|
| 187 | zgrazffeg = grazflux * zstep * wsbio4(ji,jj,jk) & |
|---|
| 188 | & * tgfunc2(ji,jj,jk) * trb(ji,jj,jk,jpgoc) * trb(ji,jj,jk,jpmes) |
|---|
| 189 | zgrazfffg = zgrazffeg * trb(ji,jj,jk,jpbfe) / (trb(ji,jj,jk,jpgoc) + rtrn) |
|---|
| 190 | zgrazffng = zgrazffeg * trb(ji,jj,jk,jpgon) / (trb(ji,jj,jk,jpgoc) + rtrn) |
|---|
| 191 | zgrazffpg = zgrazffeg * trb(ji,jj,jk,jpgop) / (trb(ji,jj,jk,jpgoc) + rtrn) |
|---|
| 192 | zgrazffep = grazflux * zstep * wsbio3(ji,jj,jk) & |
|---|
| 193 | & * tgfunc2(ji,jj,jk) * trb(ji,jj,jk,jppoc) * trb(ji,jj,jk,jpmes) |
|---|
| 194 | zgrazfffp = zgrazffep * trb(ji,jj,jk,jpsfe) / (trb(ji,jj,jk,jppoc) + rtrn) |
|---|
| 195 | zgrazffnp = zgrazffep * trb(ji,jj,jk,jppon) / (trb(ji,jj,jk,jppoc) + rtrn) |
|---|
| 196 | zgrazffpp = zgrazffep * trb(ji,jj,jk,jppop) / (trb(ji,jj,jk,jppoc) + rtrn) |
|---|
| 197 | ! |
|---|
| 198 | zgraztotc = zgrazdc + zgrazz + zgraznc + zgrazm + zgrazpoc + zgrazffep + zgrazffeg |
|---|
| 199 | |
|---|
| 200 | ! Compute the proportion of filter feeders |
|---|
| 201 | ! ---------------------------------------- |
|---|
| 202 | zproport = (zgrazffep + zgrazffeg)/(rtrn + zgraztotc) |
|---|
| 203 | |
|---|
| 204 | ! Compute fractionation of aggregates. It is assumed that |
|---|
| 205 | ! diatoms based aggregates are more prone to fractionation |
|---|
| 206 | ! since they are more porous (marine snow instead of fecal pellets) |
|---|
| 207 | ! ---------------------------------------------------------------- |
|---|
| 208 | zratio = trb(ji,jj,jk,jpgsi) / ( trb(ji,jj,jk,jpgoc) + rtrn ) |
|---|
| 209 | zratio2 = zratio * zratio |
|---|
| 210 | zfracc = zproport * grazflux * zstep * wsbio4(ji,jj,jk) & |
|---|
| 211 | & * trb(ji,jj,jk,jpgoc) * trb(ji,jj,jk,jpmes) & |
|---|
| 212 | & * ( 0.2 + 3.8 * zratio2 / ( 1.**2 + zratio2 ) ) |
|---|
| 213 | zfracfe = zfracc * trb(ji,jj,jk,jpbfe) / (trb(ji,jj,jk,jpgoc) + rtrn) |
|---|
| 214 | zfracn = zfracc * trb(ji,jj,jk,jpgon) / (trb(ji,jj,jk,jpgoc) + rtrn) |
|---|
| 215 | zfracp = zfracc * trb(ji,jj,jk,jpgop) / (trb(ji,jj,jk,jpgoc) + rtrn) |
|---|
| 216 | |
|---|
| 217 | zgrazffep = zproport * zgrazffep ; zgrazffeg = zproport * zgrazffeg |
|---|
| 218 | zgrazfffp = zproport * zgrazfffp ; zgrazfffg = zproport * zgrazfffg |
|---|
| 219 | zgrazffnp = zproport * zgrazffnp ; zgrazffng = zproport * zgrazffng |
|---|
| 220 | zgrazffpp = zproport * zgrazffpp ; zgrazffpg = zproport * zgrazffpg |
|---|
| 221 | |
|---|
| 222 | zgraztotc = zgrazdc + zgrazz + zgraznc + zgrazm + zgrazpoc + zgrazffep + zgrazffeg |
|---|
| 223 | zgraztotf = zgrazdf + zgraznf + ( zgrazz + zgrazm ) * ferat3 + zgrazpof & |
|---|
| 224 | & + zgrazfffp + zgrazfffg |
|---|
| 225 | zgraztotn = zgrazdn + (zgrazm + zgrazz) * no3rat3 + zgraznn + zgrazpon & |
|---|
| 226 | & + zgrazffnp + zgrazffng |
|---|
| 227 | zgraztotp = zgrazdp + (zgrazz + zgrazm) * po4rat3 + zgraznp + zgrazpop & |
|---|
| 228 | & + zgrazffpp + zgrazffpg |
|---|
| 229 | |
|---|
| 230 | ! Total grazing ( grazing by microzoo is already computed in p5zmicro ) |
|---|
| 231 | IF( ln_diatrc .AND. lk_iomput ) zgrazing(ji,jj,jk) = zgraztotc |
|---|
| 232 | |
|---|
| 233 | ! Stoichiometruc ratios of the food ingested by zooplanton |
|---|
| 234 | ! -------------------------------------------------------- |
|---|
| 235 | zgrasratf = (zgraztotf + rtrn) / ( zgraztotc + rtrn ) |
|---|
| 236 | zgrasratn = (zgraztotn + rtrn) / ( zgraztotc + rtrn ) |
|---|
| 237 | zgrasratp = (zgraztotp + rtrn) / ( zgraztotc + rtrn ) |
|---|
| 238 | |
|---|
| 239 | ! Growth efficiency is made a function of the quality |
|---|
| 240 | ! and the quantity of the preys |
|---|
| 241 | ! --------------------------------------------------- |
|---|
| 242 | zepshert = MIN( 1., zgrasratn/ no3rat3, zgrasratp/ po4rat3, zgrasratf / ferat3) |
|---|
| 243 | zbeta = 1./ (epsher2 - 0.2) |
|---|
| 244 | zepsherf = 0.2 + 1./ (zbeta + 0.04 * 12. * zfood *1E6 ) |
|---|
| 245 | zepsherv = zepsherf * zepshert |
|---|
| 246 | |
|---|
| 247 | ! Respiration of mesozooplankton |
|---|
| 248 | ! Excess carbon in the food is used preferentially |
|---|
| 249 | ! ---------------- ------------------------------ |
|---|
| 250 | zexcess = zgraztotc * zepsherf * (1.0 - zepshert) * zmetexcess |
|---|
| 251 | zbasresb = MAX(0., zrespz - zexcess) |
|---|
| 252 | zbasresi = zexcess + MIN(0., zrespz - zexcess) |
|---|
| 253 | zrespirc = srespir2 * zepsherv * zgraztotc + zbasresb |
|---|
| 254 | |
|---|
| 255 | ! When excess carbon is used, the other elements in excess |
|---|
| 256 | ! are also used proportionally to their abundance |
|---|
| 257 | ! -------------------------------------------------------- |
|---|
| 258 | zexcess = ( zgrasratn/ no3rat3 - zepshert ) / ( 1.0 - zepshert + rtrn) |
|---|
| 259 | zbasresn = zbasresi * zexcess * zgrasratn |
|---|
| 260 | zexcess = ( zgrasratp/ po4rat3 - zepshert ) / ( 1.0 - zepshert + rtrn) |
|---|
| 261 | zbasresp = zbasresi * zexcess * zgrasratp |
|---|
| 262 | zexcess = ( zgrasratf/ ferat3 - zepshert ) / ( 1.0 - zepshert + rtrn) |
|---|
| 263 | zbasresf = zbasresi * zexcess * zgrasratf |
|---|
| 264 | |
|---|
| 265 | ! Voiding of the excessive elements as organic matter |
|---|
| 266 | ! -------------------------------------------------------- |
|---|
| 267 | zgradoct = (1. - unass2c - zepsherv) * zgraztotc - zbasresi |
|---|
| 268 | zgradont = (1. - unass2n) * zgraztotn - zepsherv * no3rat3 * zgraztotc - zbasresn |
|---|
| 269 | zgradopt = (1. - unass2p) * zgraztotp - zepsherv * po4rat3 * zgraztotc - zbasresp |
|---|
| 270 | zgrareft = (1. - unass2c) * zgraztotf - zepsherv * ferat3 * zgraztotc - zbasresf |
|---|
| 271 | ztmp1 = ( 1. - epsher2 - unass2c ) /( 1. - 0.8 * epsher2 ) * ztortz |
|---|
| 272 | zgradoc = (zgradoct + ztmp1) * ssigma2 |
|---|
| 273 | zgradon = (zgradont + no3rat3 * ztmp1) * ssigma2 |
|---|
| 274 | zgradop = (zgradopt + po4rat3 * ztmp1) * ssigma2 |
|---|
| 275 | zgratmp = 0.2 * epsher2 /( 1. - 0.8 * epsher2 ) * ztortz |
|---|
| 276 | |
|---|
| 277 | ! Since only semilabile DOM is represented in PISCES |
|---|
| 278 | ! part of DOM is in fact labile and is then released |
|---|
| 279 | ! as dissolved inorganic compounds (ssigma2) |
|---|
| 280 | ! -------------------------------------------------- |
|---|
| 281 | zgrarem = zgratmp + ( zgradoct + ztmp1 ) * (1.0 - ssigma2) |
|---|
| 282 | zgraren = no3rat3 * zgratmp + ( zgradont + no3rat3 * ztmp1 ) * (1.0 - ssigma2) |
|---|
| 283 | zgrarep = po4rat3 * zgratmp + ( zgradopt + po4rat3 * ztmp1 ) * (1.0 - ssigma2) |
|---|
| 284 | zgraref = zgrareft + ferat3 * ( ztmp1 + zgratmp ) |
|---|
| 285 | |
|---|
| 286 | ! Defecation as a result of non assimilated products |
|---|
| 287 | ! -------------------------------------------------- |
|---|
| 288 | zgrapoc = zgraztotc * unass2c + unass2c / ( 1. - 0.8 * epsher2 ) * ztortz |
|---|
| 289 | zgrapon = zgraztotn * unass2n + no3rat3 * unass2n / ( 1. - 0.8 * epsher2 ) * ztortz |
|---|
| 290 | zgrapop = zgraztotp * unass2p + po4rat3 * unass2p / ( 1. - 0.8 * epsher2 ) * ztortz |
|---|
| 291 | zgrapof = zgraztotf * unass2c + ferat3 * unass2c / ( 1. - 0.8 * epsher2 ) * ztortz |
|---|
| 292 | |
|---|
| 293 | ! Addition of respiration to the release of inorganic nutrients |
|---|
| 294 | ! ------------------------------------------------------------- |
|---|
| 295 | zgrarem = zgrarem + zbasresi + zrespirc |
|---|
| 296 | zgraren = zgraren + zbasresn + zrespirc * no3rat3 |
|---|
| 297 | zgrarep = zgrarep + zbasresp + zrespirc * po4rat3 |
|---|
| 298 | zgraref = zgraref + zbasresf + zrespirc * ferat3 |
|---|
| 299 | |
|---|
| 300 | ! Update the arrays TRA which contain the biological sources and |
|---|
| 301 | ! sinks |
|---|
| 302 | ! -------------------------------------------------------------- |
|---|
| 303 | tra(ji,jj,jk,jppo4) = tra(ji,jj,jk,jppo4) + zgrarep |
|---|
| 304 | tra(ji,jj,jk,jpnh4) = tra(ji,jj,jk,jpnh4) + zgraren |
|---|
| 305 | tra(ji,jj,jk,jpdoc) = tra(ji,jj,jk,jpdoc) + zgradoc |
|---|
| 306 | #if defined key_ligand |
|---|
| 307 | tra(ji,jj,jk,jplgw) = tra(ji,jj,jk,jplgw) + zgradoc * ldocz |
|---|
| 308 | zz2ligprod(ji,jj,jk) = zgradoc * ldocz |
|---|
| 309 | #endif |
|---|
| 310 | tra(ji,jj,jk,jpdon) = tra(ji,jj,jk,jpdon) + zgradon |
|---|
| 311 | tra(ji,jj,jk,jpdop) = tra(ji,jj,jk,jpdop) + zgradop |
|---|
| 312 | tra(ji,jj,jk,jpoxy) = tra(ji,jj,jk,jpoxy) - o2ut * zgrarem |
|---|
| 313 | tra(ji,jj,jk,jpfer) = tra(ji,jj,jk,jpfer) + zgraref |
|---|
| 314 | zfezoo2(ji,jj,jk) = zgraref |
|---|
| 315 | tra(ji,jj,jk,jpdic) = tra(ji,jj,jk,jpdic) + zgrarem |
|---|
| 316 | tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) + rno3 * zgraren |
|---|
| 317 | tra(ji,jj,jk,jpmes) = tra(ji,jj,jk,jpmes) + zepsherv * zgraztotc - zrespirc & |
|---|
| 318 | & - ztortz - zgrazm |
|---|
| 319 | tra(ji,jj,jk,jpdia) = tra(ji,jj,jk,jpdia) - zgrazdc |
|---|
| 320 | tra(ji,jj,jk,jpndi) = tra(ji,jj,jk,jpndi) - zgrazdn |
|---|
| 321 | tra(ji,jj,jk,jppdi) = tra(ji,jj,jk,jppdi) - zgrazdp |
|---|
| 322 | tra(ji,jj,jk,jpdfe) = tra(ji,jj,jk,jpdfe) - zgrazdf |
|---|
| 323 | tra(ji,jj,jk,jpzoo) = tra(ji,jj,jk,jpzoo) - zgrazz |
|---|
| 324 | tra(ji,jj,jk,jpphy) = tra(ji,jj,jk,jpphy) - zgraznc |
|---|
| 325 | tra(ji,jj,jk,jpnph) = tra(ji,jj,jk,jpnph) - zgraznn |
|---|
| 326 | tra(ji,jj,jk,jppph) = tra(ji,jj,jk,jppph) - zgraznp |
|---|
| 327 | tra(ji,jj,jk,jpnfe) = tra(ji,jj,jk,jpnfe) - zgraznf |
|---|
| 328 | tra(ji,jj,jk,jpnch) = tra(ji,jj,jk,jpnch) - zgraznc * trb(ji,jj,jk,jpnch) / ( trb(ji,jj,jk,jpphy) + rtrn ) |
|---|
| 329 | tra(ji,jj,jk,jpdch) = tra(ji,jj,jk,jpdch) - zgrazdc * trb(ji,jj,jk,jpdch) / ( trb(ji,jj,jk,jpdia) + rtrn ) |
|---|
| 330 | tra(ji,jj,jk,jpdsi) = tra(ji,jj,jk,jpdsi) - zgrazdc * trb(ji,jj,jk,jpdsi) / ( trb(ji,jj,jk,jpdia) + rtrn ) |
|---|
| 331 | tra(ji,jj,jk,jpgsi) = tra(ji,jj,jk,jpgsi) + zgrazdc * trb(ji,jj,jk,jpdsi) / ( trb(ji,jj,jk,jpdia) + rtrn ) |
|---|
| 332 | |
|---|
| 333 | tra(ji,jj,jk,jppoc) = tra(ji,jj,jk,jppoc) - zgrazpoc - zgrazffep + zfracc |
|---|
| 334 | prodpoc(ji,jj,jk) = prodpoc(ji,jj,jk) + zfracc |
|---|
| 335 | conspoc(ji,jj,jk) = conspoc(ji,jj,jk) - zgrazpoc - zgrazffep |
|---|
| 336 | tra(ji,jj,jk,jppon) = tra(ji,jj,jk,jppon) - zgrazpon - zgrazffnp + zfracn |
|---|
| 337 | tra(ji,jj,jk,jppop) = tra(ji,jj,jk,jppop) - zgrazpop - zgrazffpp + zfracp |
|---|
| 338 | tra(ji,jj,jk,jpgoc) = tra(ji,jj,jk,jpgoc) - zgrazffeg + zgrapoc - zfracc |
|---|
| 339 | prodgoc(ji,jj,jk) = prodgoc(ji,jj,jk) + zgrapoc |
|---|
| 340 | consgoc(ji,jj,jk) = consgoc(ji,jj,jk) - zgrazffeg - zfracc |
|---|
| 341 | tra(ji,jj,jk,jpgon) = tra(ji,jj,jk,jpgon) - zgrazffng + zgrapon - zfracn |
|---|
| 342 | tra(ji,jj,jk,jpgop) = tra(ji,jj,jk,jpgop) - zgrazffpg + zgrapop - zfracp |
|---|
| 343 | tra(ji,jj,jk,jpsfe) = tra(ji,jj,jk,jpsfe) - zgrazpof - zgrazfffp + zfracfe |
|---|
| 344 | tra(ji,jj,jk,jpbfe) = tra(ji,jj,jk,jpbfe) - zgrazfffg + zgrapof - zfracfe |
|---|
| 345 | zfracal = trb(ji,jj,jk,jpcal) / ( trb(ji,jj,jk,jpgoc) + rtrn ) |
|---|
| 346 | zgrazcal = zgrazffeg * (1. - part2) * zfracal |
|---|
| 347 | |
|---|
| 348 | ! calcite production |
|---|
| 349 | ! ------------------ |
|---|
| 350 | zprcaca = xfracal(ji,jj,jk) * zgraznc |
|---|
| 351 | prodcal(ji,jj,jk) = prodcal(ji,jj,jk) + zprcaca ! prodcal=prodcal(nanophy)+prodcal(microzoo)+prodcal(mesozoo) |
|---|
| 352 | zprcaca = part2 * zprcaca |
|---|
| 353 | tra(ji,jj,jk,jpdic) = tra(ji,jj,jk,jpdic) + zgrazcal - zprcaca |
|---|
| 354 | tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) + 2. * ( zgrazcal - zprcaca ) |
|---|
| 355 | tra(ji,jj,jk,jpcal) = tra(ji,jj,jk,jpcal) - zgrazcal + zprcaca |
|---|
| 356 | END DO |
|---|
| 357 | END DO |
|---|
| 358 | END DO |
|---|
| 359 | ! |
|---|
| 360 | IF( lk_iomput .AND. knt == nrdttrc ) THEN |
|---|
| 361 | CALL wrk_alloc( jpi, jpj, jpk, zw3d ) |
|---|
| 362 | IF( iom_use( "GRAZ2" ) ) THEN |
|---|
| 363 | zw3d(:,:,:) = zgrazing(:,:,:) * 1.e+3 * rfact2r * tmask(:,:,:) ! Total grazing of phyto by zooplankton |
|---|
| 364 | CALL iom_put( "GRAZ2", zw3d ) |
|---|
| 365 | ENDIF |
|---|
| 366 | IF( iom_use( "PCAL" ) ) THEN |
|---|
| 367 | zw3d(:,:,:) = prodcal(:,:,:) * 1.e+3 * rfact2r * tmask(:,:,:) ! Calcite production |
|---|
| 368 | CALL iom_put( "PCAL", zw3d ) |
|---|
| 369 | ENDIF |
|---|
| 370 | IF( iom_use( "FEZOO2" ) ) THEN |
|---|
| 371 | zw3d(:,:,:) = zfezoo2(:,:,:) * 1e9 * 1.e+3 * rfact2r * tmask(:,:,:) ! |
|---|
| 372 | CALL iom_put( "FEZOO2", zw3d ) |
|---|
| 373 | ENDIF |
|---|
| 374 | #if defined key_ligand |
|---|
| 375 | IF( iom_use( "LPRODZ2" ) ) THEN |
|---|
| 376 | zw3d(:,:,:) = zz2ligprod(:,:,:) * 1e9 * 1.e+3 * rfact2r * tmask(:,:,:) |
|---|
| 377 | CALL iom_put( "LPRODZ2" , zw3d ) |
|---|
| 378 | ENDIF |
|---|
| 379 | #endif |
|---|
| 380 | CALL wrk_dealloc( jpi, jpj, jpk, zw3d ) |
|---|
| 381 | ENDIF |
|---|
| 382 | ! |
|---|
| 383 | IF(ln_ctl) THEN ! print mean trends (used for debugging) |
|---|
| 384 | WRITE(charout, FMT="('meso')") |
|---|
| 385 | CALL prt_ctl_trc_info(charout) |
|---|
| 386 | CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm) |
|---|
| 387 | ENDIF |
|---|
| 388 | ! |
|---|
| 389 | #if defined key_ligand |
|---|
| 390 | CALL wrk_dealloc( jpi, jpj, jpk, zgrazing, zfezoo2, zz2ligprod ) |
|---|
| 391 | #else |
|---|
| 392 | CALL wrk_dealloc( jpi, jpj, jpk, zgrazing, zfezoo2 ) |
|---|
| 393 | #endif |
|---|
| 394 | ! |
|---|
| 395 | IF( nn_timing == 1 ) CALL timing_stop('p5z_meso') |
|---|
| 396 | ! |
|---|
| 397 | END SUBROUTINE p5z_meso |
|---|
| 398 | |
|---|
| 399 | SUBROUTINE p5z_meso_init |
|---|
| 400 | |
|---|
| 401 | !!---------------------------------------------------------------------- |
|---|
| 402 | !! *** ROUTINE p5z_meso_init *** |
|---|
| 403 | !! |
|---|
| 404 | !! ** Purpose : Initialization of mesozooplankton parameters |
|---|
| 405 | !! |
|---|
| 406 | !! ** Method : Read the nampismes namelist and check the parameters |
|---|
| 407 | !! called at the first timestep (nittrc000) |
|---|
| 408 | !! |
|---|
| 409 | !! ** input : Namelist nampismes |
|---|
| 410 | !! |
|---|
| 411 | !!---------------------------------------------------------------------- |
|---|
| 412 | |
|---|
| 413 | NAMELIST/nampismes/ part2, bmetexc2, grazrat2, resrat2, mzrat2, xpref2c, xpref2p, xpref2z, & |
|---|
| 414 | & xpref2m, xpref2d, xthresh2dia, xthresh2phy, xthresh2zoo, xthresh2poc, & |
|---|
| 415 | & xthresh2mes, xthresh2, xkgraz2, epsher2, ssigma2, unass2c, & |
|---|
| 416 | & unass2n, unass2p, srespir2, grazflux |
|---|
| 417 | |
|---|
| 418 | INTEGER :: ios ! Local integer output status for namelist read |
|---|
| 419 | |
|---|
| 420 | REWIND( numnatp_ref ) ! Namelist nampismes in reference namelist : Pisces mesozooplankton |
|---|
| 421 | READ ( numnatp_ref, nampismes, IOSTAT = ios, ERR = 901) |
|---|
| 422 | 901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampismes in reference namelist', lwp ) |
|---|
| 423 | |
|---|
| 424 | REWIND( numnatp_cfg ) ! Namelist nampismes in configuration namelist : Pisces mesozooplankton |
|---|
| 425 | READ ( numnatp_cfg, nampismes, IOSTAT = ios, ERR = 902 ) |
|---|
| 426 | 902 IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampismes in configuration namelist', lwp ) |
|---|
| 427 | IF(lwm) WRITE ( numonp, nampismes ) |
|---|
| 428 | |
|---|
| 429 | |
|---|
| 430 | IF(lwp) THEN ! control print |
|---|
| 431 | WRITE(numout,*) ' ' |
|---|
| 432 | WRITE(numout,*) ' Namelist parameters for mesozooplankton, nampismes' |
|---|
| 433 | WRITE(numout,*) ' ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~' |
|---|
| 434 | WRITE(numout,*) ' part of calcite not dissolved in mesozoo guts part2 =', part2 |
|---|
| 435 | WRITE(numout,*) ' mesozoo preference for nano. xpref2p =', xpref2p |
|---|
| 436 | WRITE(numout,*) ' mesozoo preference for diatoms xpref2d =', xpref2d |
|---|
| 437 | WRITE(numout,*) ' mesozoo preference for zoo xpref2z =', xpref2z |
|---|
| 438 | WRITE(numout,*) ' mesozoo preference for mesozoo xpref2m =', xpref2m |
|---|
| 439 | WRITE(numout,*) ' mesozoo preference for poc xpref2c =', xpref2c |
|---|
| 440 | WRITE(numout,*) ' microzoo feeding threshold for mesozoo xthresh2zoo =', xthresh2zoo |
|---|
| 441 | WRITE(numout,*) ' diatoms feeding threshold for mesozoo xthresh2dia =', xthresh2dia |
|---|
| 442 | WRITE(numout,*) ' nanophyto feeding threshold for mesozoo xthresh2phy =', xthresh2phy |
|---|
| 443 | WRITE(numout,*) ' poc feeding threshold for mesozoo xthresh2poc =', xthresh2poc |
|---|
| 444 | WRITE(numout,*) ' mesozoo feeding threshold for mesozoo xthresh2mes =', xthresh2mes |
|---|
| 445 | WRITE(numout,*) ' feeding threshold for mesozooplankton xthresh2 =', xthresh2 |
|---|
| 446 | WRITE(numout,*) ' exsudation rate of mesozooplankton resrat2 =', resrat2 |
|---|
| 447 | WRITE(numout,*) ' mesozooplankton mortality rate mzrat2 =', mzrat2 |
|---|
| 448 | WRITE(numout,*) ' maximal mesozoo grazing rate grazrat2 =', grazrat2 |
|---|
| 449 | WRITE(numout,*) ' mesozoo flux feeding rate grazflux =', grazflux |
|---|
| 450 | WRITE(numout,*) ' C egested fraction of food by mesozoo unass2c =', unass2c |
|---|
| 451 | WRITE(numout,*) ' C egested fraction of food by mesozoo unass2n =', unass2n |
|---|
| 452 | WRITE(numout,*) ' C egested fraction of food by mesozoo unass2p =', unass2p |
|---|
| 453 | WRITE(numout,*) ' Efficicency of Mesozoo growth epsher2 =', epsher2 |
|---|
| 454 | WRITE(numout,*) ' Fraction excreted as semi-labile DOM ssigma2 =', ssigma2 |
|---|
| 455 | WRITE(numout,*) ' Active respiration srespir2 =', srespir2 |
|---|
| 456 | WRITE(numout,*) ' half sturation constant for grazing 2 xkgraz2 =', xkgraz2 |
|---|
| 457 | WRITE(numout,*) ' Use excess carbon for respiration bmetexc2 =', bmetexc2 |
|---|
| 458 | ENDIF |
|---|
| 459 | |
|---|
| 460 | |
|---|
| 461 | END SUBROUTINE p5z_meso_init |
|---|
| 462 | |
|---|
| 463 | |
|---|
| 464 | #else |
|---|
| 465 | !!====================================================================== |
|---|
| 466 | !! Dummy module : No PISCES bio-model |
|---|
| 467 | !!====================================================================== |
|---|
| 468 | CONTAINS |
|---|
| 469 | SUBROUTINE p5z_meso ! Empty routine |
|---|
| 470 | END SUBROUTINE p5z_meso |
|---|
| 471 | #endif |
|---|
| 472 | |
|---|
| 473 | !!====================================================================== |
|---|
| 474 | END MODULE p5zmeso |
|---|
