New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p5zprod.F90 in branches/CNRS/dev_r6270_PISCES_QUOTA/NEMOGCM/NEMO/TOP_SRC/PISCES/P5Z – NEMO

source: branches/CNRS/dev_r6270_PISCES_QUOTA/NEMOGCM/NEMO/TOP_SRC/PISCES/P5Z/p5zprod.F90 @ 6847

Last change on this file since 6847 was 6841, checked in by aumont, 8 years ago

Various bug fixes + explicit gamma function for lability
  • Property svn:executable set to *
File size: 35.8 KB
Line 
1MODULE p5zprod
2   !!======================================================================
3   !!                         ***  MODULE p5zprod  ***
4   !! TOP :  Growth Rate of the two phytoplanktons groups
5   !!======================================================================
6   !! History :   1.0  !  2004     (O. Aumont) Original code
7   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
8   !!             3.4  !  2011-05  (O. Aumont, C. Ethe) New parameterization of light limitation
9   !!             3.6  !  2015-05  (O. Aumont) PISCES quota
10   !!----------------------------------------------------------------------
11#if defined key_pisces_quota
12   !!----------------------------------------------------------------------
13   !!   'key_pisces_quota'     PISCES bio-model with variable stoichiometry
14   !!----------------------------------------------------------------------
15   !!   p5z_prod       :   Compute the growth Rate of the two phytoplanktons groups
16   !!   p5z_prod_init  :   Initialization of the parameters for growth
17   !!   p5z_prod_alloc :   Allocate variables for growth
18   !!----------------------------------------------------------------------
19   USE oce_trc         !  shared variables between ocean and passive tracers
20   USE trc             !  passive tracers common variables
21   USE sms_pisces      !  PISCES Source Minus Sink variables
22   USE p4zopt          !  optical model
23   USE p5zlim          !  Co-limitations of differents nutrients
24   USE prtctl_trc      !  print control for debugging
25   USE iom             !  I/O manager
26
27   IMPLICIT NONE
28   PRIVATE
29
30   PUBLIC   p5z_prod         ! called in p5zbio.F90
31   PUBLIC   p5z_prod_init    ! called in trcsms_pisces.F90
32   PUBLIC   p5z_prod_alloc
33
34   !! * Shared module variables
35   REAL(wp), PUBLIC ::  pislope         !:
36   REAL(wp), PUBLIC ::  pislopep        !:
37   REAL(wp), PUBLIC ::  pislope2        !:
38   REAL(wp), PUBLIC ::  xadap           !:
39   REAL(wp), PUBLIC ::  excret          !:
40   REAL(wp), PUBLIC ::  excretp         !:
41   REAL(wp), PUBLIC ::  excret2         !:
42   REAL(wp), PUBLIC ::  bresp           !:
43   REAL(wp), PUBLIC ::  thetanpm        !:
44   REAL(wp), PUBLIC ::  thetannm        !:
45   REAL(wp), PUBLIC ::  thetandm        !:
46   REAL(wp), PUBLIC ::  chlcmin         !:
47   REAL(wp), PUBLIC ::  grosip          !:
48   REAL(wp), PUBLIC ::  zlimmxln        !:
49   REAL(wp), PUBLIC ::  zlimmxlp        !:
50   REAL(wp), PUBLIC ::  zlimmxld        !:
51
52   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   prmaxn   !: optimal production = f(temperature)
53   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   prmaxp   !: optimal production = f(temperature)
54   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   prmaxd   !: optimal production = f(temperature)
55   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   zdaylen
56   
57   REAL(wp) :: r1_rday                !: 1 / rday
58   REAL(wp) :: texcret                !: 1 - excret
59   REAL(wp) :: texcretp               !: 1 - excretp
60   REAL(wp) :: texcret2               !: 1 - excret2       
61
62
63   !!* Substitution
64#  include "top_substitute.h90"
65   !!----------------------------------------------------------------------
66   !! NEMO/TOP 3.3 , NEMO Consortium (2010)
67   !! $Id: p4zprod.F90 3160 2011-11-20 14:27:18Z cetlod $
68   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
69   !!----------------------------------------------------------------------
70CONTAINS
71
72   SUBROUTINE p5z_prod( kt , knt )
73      !!---------------------------------------------------------------------
74      !!                     ***  ROUTINE p5z_prod  ***
75      !!
76      !! ** Purpose :   Compute the phytoplankton production depending on
77      !!              light, temperature and nutrient availability
78      !!
79      !! ** Method  : - ???
80      !!---------------------------------------------------------------------
81      !
82      INTEGER, INTENT(in) :: kt, knt
83      !
84      INTEGER  ::   ji, jj, jk
85      REAL(wp) ::   zsilfac, znanotot, zpicotot, zdiattot, zconctemp, zconctemp2
86      REAL(wp) ::   zration, zratiop, zratiof, zmax, zmax2, zsilim, ztn, zadap
87      REAL(wp) ::   zpronmax, zpropmax, zprofmax, zrat
88      REAL(wp) ::   zlim, zsilfac2, zsiborn, zprod, zprontot, zproptot, zprodtot
89      REAL(wp) ::   zmxltst, zmxlday, zprnutmax, zdocprod
90      REAL(wp) ::   zpislopen, zpislopep, zpislope2n
91      REAL(wp) ::   zrum, zcodel, zargu, zval, zfeup
92      REAL(wp) ::   zrfact2
93      CHARACTER (len=25) :: charout
94      REAL(wp), POINTER, DIMENSION(:,:  ) :: zmixnano, zmixpico, zmixdiat, zstrn
95      REAL(wp), POINTER, DIMENSION(:,:,:) :: zpislopead, zpislopeadp, zpislopead2
96      REAL(wp), POINTER, DIMENSION(:,:,:) :: zprbio, zprpic, zprdia, zysopt
97      REAL(wp), POINTER, DIMENSION(:,:,:) :: zprchln, zprchlp, zprchld
98      REAL(wp), POINTER, DIMENSION(:,:,:) :: zprorcan, zprorcap, zprorcad 
99      REAL(wp), POINTER, DIMENSION(:,:,:) :: zprofed, zprofep, zprofen
100      REAL(wp), POINTER, DIMENSION(:,:,:) :: zprochln, zprochlp, zprochld
101      REAL(wp), POINTER, DIMENSION(:,:,:) :: zpronewn, zpronewp, zpronewd
102      REAL(wp), POINTER, DIMENSION(:,:,:) :: zproregn, zproregp, zproregd
103      REAL(wp), POINTER, DIMENSION(:,:,:) :: zpropo4n, zpropo4p, zpropo4d
104      REAL(wp), POINTER, DIMENSION(:,:,:) :: zprodopn, zprodopp, zprodopd
105      REAL(wp), POINTER, DIMENSION(:,:,:) :: zrespn, zrespp, zrespd, zprnut
106      REAL(wp), POINTER, DIMENSION(:,:,:) :: zcroissn, zcroissp, zcroissd
107      !!---------------------------------------------------------------------
108      !
109      IF( nn_timing == 1 )  CALL timing_start('p5z_prod')
110      !
111      !  Allocate temporary workspace
112      CALL wrk_alloc( jpi, jpj,      zmixnano, zmixpico, zmixdiat, zstrn )
113      CALL wrk_alloc( jpi, jpj, jpk, zpislopead, zpislopeadp, zpislopead2, zysopt ) 
114      CALL wrk_alloc( jpi, jpj, jpk, zprdia, zprpic, zprbio, zprorcan, zprorcap, zprorcad )
115      CALL wrk_alloc( jpi, jpj, jpk, zprofed, zprofep, zprofen, zprochln, zprochlp, zprochld )
116      CALL wrk_alloc( jpi, jpj, jpk, zpronewn, zpronewp, zpronewd, zproregn, zproregp, zproregd )
117      CALL wrk_alloc( jpi, jpj, jpk, zpropo4n, zpropo4p, zpropo4d, zrespn, zrespp, zrespd, zprnut )
118      CALL wrk_alloc( jpi, jpj, jpk, zprchln, zprchlp, zprchld, zprodopn, zprodopp, zprodopd )
119      CALL wrk_alloc( jpi, jpj, jpk, zcroissp, zcroissn, zcroissd )
120      !
121      zprorcan(:,:,:) = 0._wp ; zprorcap(:,:,:) = 0._wp ; zprorcad(:,:,:) = 0._wp
122      zprofed (:,:,:) = 0._wp ; zprofep (:,:,:) = 0._wp ; zprofen (:,:,:) = 0._wp
123      zprochln(:,:,:) = 0._wp ; zprochlp(:,:,:) = 0._wp ; zprochld(:,:,:) = 0._wp
124      zpronewn(:,:,:) = 0._wp ; zpronewp(:,:,:) = 0._wp ; zpronewd(:,:,:) = 0._wp
125      zproregn(:,:,:) = 0._wp ; zproregp(:,:,:) = 0._wp ; zproregd(:,:,:) = 0._wp 
126      zpropo4n(:,:,:) = 0._wp ; zpropo4p(:,:,:) = 0._wp ; zpropo4d(:,:,:) = 0._wp
127      zprdia  (:,:,:) = 0._wp ; zprpic  (:,:,:) = 0._wp ; zprbio  (:,:,:) = 0._wp
128      zysopt  (:,:,:) = 0._wp
129      zrespn  (:,:,:) = 0._wp ; zrespp  (:,:,:) = 0._wp ; zrespd  (:,:,:) = 0._wp 
130
131      ! Computation of the optimal production
132      prmaxn(:,:,:) = ( 0.65_wp * (1. + zpsino3 * qnpmax ) ) * r1_rday * tgfunc(:,:,:)
133      prmaxp(:,:,:) = 0.5 / 0.65 * prmaxn(:,:,:) 
134      prmaxd(:,:,:) = prmaxn(:,:,:) 
135      zprnut(:,:,:) = 0.65_wp * r1_rday * tgfunc(:,:,:)
136
137      IF( lk_degrad )  THEN
138         prmaxn(:,:,:) = prmaxn(:,:,:) * facvol(:,:,:) 
139         prmaxp(:,:,:) = prmaxp(:,:,:) * facvol(:,:,:)
140         prmaxd(:,:,:) = prmaxd(:,:,:) * facvol(:,:,:)
141      ENDIF
142
143      ! compute the day length depending on latitude and the day
144      zrum = REAL( nday_year - 80, wp ) / REAL( nyear_len(1), wp )
145      zcodel = ASIN(  SIN( zrum * rpi * 2._wp ) * SIN( rad * 23.5_wp )  )
146
147      ! day length in hours
148      zstrn(:,:) = 0.
149      DO jj = 1, jpj
150         DO ji = 1, jpi
151            zargu = TAN( zcodel ) * TAN( gphit(ji,jj) * rad )
152            zargu = MAX( -1., MIN(  1., zargu ) )
153            zstrn(ji,jj) = MAX( 0.0, 24. - 2. * ACOS( zargu ) / rad / 15. )
154         END DO
155      END DO
156
157         ! Impact of the day duration on phytoplankton growth
158      DO jk = 1, jpkm1
159         DO jj = 1 ,jpj
160            DO ji = 1, jpi
161               IF( etot(ji,jj,jk) > 1.E-3 ) THEN
162                  zval = MAX( 1., zstrn(ji,jj) )
163                  zval = 1.5 * zval / (12. + zval) * (1. - fr_i(ji,jj))
164                  zprbio(ji,jj,jk) = prmaxn(ji,jj,jk) * zval
165                  zprpic(ji,jj,jk) = prmaxp(ji,jj,jk) * zval
166                  zprdia(ji,jj,jk) = prmaxd(ji,jj,jk) * zval
167               ENDIF
168            END DO
169         END DO
170      END DO
171
172      ! Maximum light intensity
173      zdaylen(:,:) = MAX(1., zstrn(:,:)) / 24.
174      WHERE( zstrn(:,:) < 1.e0 ) zstrn(:,:) = 24.
175      zstrn(:,:) = 24. / zstrn(:,:)
176
177      DO jk = 1, jpkm1
178!CDIR NOVERRCHK
179         DO jj = 1, jpj
180!CDIR NOVERRCHK
181            DO ji = 1, jpi
182                  ! Computation of the P-I slope for nanos and diatoms
183               IF( etot(ji,jj,jk) > 1.E-3 ) THEN
184                  ztn         = MAX( 0., tsn(ji,jj,jk,jp_tem) - 15. )
185                  zadap       = xadap * ztn / ( 2.+ ztn )
186                  znanotot    = enano(ji,jj,jk) * zstrn(ji,jj)
187                  zpicotot    = epico(ji,jj,jk) * zstrn(ji,jj)
188                  zdiattot    = ediat(ji,jj,jk) * zstrn(ji,jj)
189                  !
190                  zpislopead (ji,jj,jk) = pislope * trb(ji,jj,jk,jpnch)    &
191                  &                       /( trb(ji,jj,jk,jpphy) * 12. + rtrn)
192                  zpislopeadp(ji,jj,jk) = pislopep * ( 1. + zadap * EXP( -0.5 * zpicotot ) )   &
193                  &                       * trb(ji,jj,jk,jppch) /( trb(ji,jj,jk,jppic) * 12. + rtrn)
194                  zpislopead2(ji,jj,jk) = pislope2 * trb(ji,jj,jk,jpdch)    &
195                     &                    /( trb(ji,jj,jk,jpdia) * 12. + rtrn)
196                  zpislopen   = zpislopead (ji,jj,jk) / ( prmaxn(ji,jj,jk) * rday * xlimphy(ji,jj,jk) + rtrn )
197                  zpislopep   = zpislopeadp(ji,jj,jk) / ( prmaxp(ji,jj,jk) * rday * xlimpic(ji,jj,jk) + rtrn )
198                  zpislope2n  = zpislopead2(ji,jj,jk) / ( prmaxd(ji,jj,jk) * rday * xlimdia(ji,jj,jk) + rtrn )
199
200                  ! Computation of production function for Carbon
201                  !  ---------------------------------------------
202                  zprbio(ji,jj,jk) = zprbio(ji,jj,jk) * ( 1.- EXP( -zpislopen  * znanotot )  )
203                  zprpic(ji,jj,jk) = zprpic(ji,jj,jk) * ( 1.- EXP( -zpislopep  * zpicotot )  )
204                  zprdia(ji,jj,jk) = zprdia(ji,jj,jk) * ( 1.- EXP( -zpislope2n * zdiattot )  )
205
206                  ! Computation of production function for Chlorophyll
207                  !  -------------------------------------------------
208                  zprchln(ji,jj,jk) = prmaxn(ji,jj,jk) * ( 1.- EXP( -zpislopen  * enano(ji,jj,jk) )  )
209                  zprchlp(ji,jj,jk) = prmaxp(ji,jj,jk) * ( 1.- EXP( -zpislopep  * epico(ji,jj,jk) )  )
210                  zprchld(ji,jj,jk) = prmaxd(ji,jj,jk) * ( 1.- EXP( -zpislope2n * ediat(ji,jj,jk) )  )
211               ENDIF
212            END DO
213         END DO
214      END DO
215
216      DO jk = 1, jpkm1
217         DO jj = 1, jpj
218            DO ji = 1, jpi
219              IF( etot(ji,jj,jk) > 1.E-3 ) THEN
220                  !    Si/C of diatoms
221                  !    ------------------------
222                  !    Si/C increases with iron stress and silicate availability
223                  !    Si/C is arbitrariliy increased for very high Si concentrations
224                  !    to mimic the very high ratios observed in the Southern Ocean (silpot2)
225                  zlim  = trb(ji,jj,jk,jpsil) / ( trb(ji,jj,jk,jpsil) + xksi1 )
226                  zsilim = MIN( zprdia(ji,jj,jk) / ( prmaxd(ji,jj,jk) + rtrn ), xlimsi(ji,jj,jk) )
227                  zsilfac = 3.4 * EXP( -4.23 * zsilim ) * MAX( 0.e0, MIN( 1., 2.2 * ( zlim - 0.5 ) )  ) + 1.e0
228                  zsiborn = trb(ji,jj,jk,jpsil) * trb(ji,jj,jk,jpsil) * trb(ji,jj,jk,jpsil)
229                  IF (gphit(ji,jj) < -30 ) THEN
230                    zsilfac2 = 1. + 2. * zsiborn / ( zsiborn + xksi2**3 )
231                  ELSE
232                    zsilfac2 = 1. +      zsiborn / ( zsiborn + xksi2**3 )
233                  ENDIF
234                  zysopt(ji,jj,jk) = grosip * zlim * zsilfac * zsilfac2
235              ENDIF
236            END DO
237         END DO
238      END DO
239
240      !  Computation of the limitation term due to a mixed layer deeper than the euphotic depth
241      DO jj = 1, jpj
242         DO ji = 1, jpi
243            zmxltst = MAX( 0.e0, hmld(ji,jj) - heup_01(ji,jj) )
244            zmxlday = zmxltst * zmxltst * r1_rday
245            zmixnano(ji,jj) = 1. - zmxlday / ( zlimmxln + zmxlday )
246            zmixpico(ji,jj) = 1. - zmxlday / ( zlimmxlp + zmxlday )
247            zmixdiat(ji,jj) = 1. - zmxlday / ( zlimmxld + zmxlday )
248         END DO
249      END DO
250 
251      !  Mixed-layer effect on production                                                                               
252      DO jk = 1, jpkm1
253         DO jj = 1, jpj
254            DO ji = 1, jpi
255               IF( fsdepw(ji,jj,jk+1) <= hmld(ji,jj) ) THEN
256                  zprbio(ji,jj,jk)  = zprbio(ji,jj,jk) * zmixnano(ji,jj)
257                  zprpic(ji,jj,jk)  = zprpic(ji,jj,jk) * zmixpico(ji,jj)
258                  zprdia(ji,jj,jk)  = zprdia(ji,jj,jk) * zmixdiat(ji,jj)
259                  zprchln(ji,jj,jk) = zprchln(ji,jj,jk) * zmixnano(ji,jj)
260                  zprchlp(ji,jj,jk) = zprchlp(ji,jj,jk) * zmixpico(ji,jj)
261                  zprchld(ji,jj,jk) = zprchld(ji,jj,jk) * zmixdiat(ji,jj)
262               ENDIF
263            END DO
264         END DO
265      END DO
266
267      ! Computation of the various production terms of nanophytoplankton
268      DO jk = 1, jpkm1
269         DO jj = 1, jpj
270            DO ji = 1, jpi
271               IF( etot(ji,jj,jk) > 1.E-3 ) THEN
272                  !  production terms for nanophyto.
273                  zprorcan(ji,jj,jk) = zprbio(ji,jj,jk)  * xlimphy(ji,jj,jk) * trb(ji,jj,jk,jpphy) * rfact2
274                  !
275                  zration = trb(ji,jj,jk,jpnph) / ( trb(ji,jj,jk,jpphy) + rtrn )
276                  zratiop = trb(ji,jj,jk,jppph) / ( trb(ji,jj,jk,jpphy) + rtrn )
277                  zratiof = trb(ji,jj,jk,jpnfe) / ( trb(ji,jj,jk,jpphy) + rtrn )
278                  zprnutmax = zprnut(ji,jj,jk) * fvnuptk(ji,jj,jk) / rno3 * trb(ji,jj,jk,jpphy) * rfact2
279                  ! Uptake of nitrogen
280                  zrat = MIN( 1., zration / (xqnnmax(ji,jj,jk) + rtrn) ) 
281                  zmax = MAX(0., MIN(1., (1. - zrat)/ (1.05 - zrat) * 1.05))
282                  zpronmax = zprnutmax * zmax * MAX(0., MIN(1., ( zratiop - xqpnmin(ji,jj,jk) )   &
283                  &          / ( xqpnmax(ji,jj,jk) - xqpnmin(ji,jj,jk) ), xlimnfe(ji,jj,jk) ) )
284                  zpronewn(ji,jj,jk) = zpronmax * zdaylen(ji,jj) * xnanono3(ji,jj,jk)
285                  zproregn(ji,jj,jk) = zpronmax * xnanonh4(ji,jj,jk)
286                  ! Uptake of phosphorus
287                  zrat = MIN( 1., zratiop / (xqpnmax(ji,jj,jk) + rtrn) )
288                  zmax = MAX(0., MIN(1., (1. - zrat)/ (1.05 - zrat) * 1.05))
289                  zpropmax = zprnutmax * zmax * xlimnfe(ji,jj,jk)
290                  zpropo4n(ji,jj,jk) = zpropmax * xnanopo4(ji,jj,jk)
291                  zprodopn(ji,jj,jk) = zpropmax * xnanodop(ji,jj,jk)
292                  ! Uptake of iron
293                  zrat = MIN( 1., zratiof / qfnmax )
294                  zmax = MAX(0., MIN(1., (1. - zrat)/ (1.05 - zrat) * 1.05))
295                  zprofmax = zprnutmax * qfnmax * zmax
296                  zprofen(ji,jj,jk) = zprofmax * xnanofer(ji,jj,jk) * ( 3. - 2.4 * xlimnfe(ji,jj,jk)    &
297                  &          / ( xlimnfe(ji,jj,jk) + 0.2 ) ) * (1. + 0.8 * xnanono3(ji,jj,jk) / ( rtrn  &
298                  &          + xnanono3(ji,jj,jk) + xnanonh4(ji,jj,jk) ) * (1. - xnanofer(ji,jj,jk) ) )
299               ENDIF
300            END DO
301         END DO
302      END DO
303
304      ! Computation of the various production terms of picophytoplankton
305      DO jk = 1, jpkm1
306         DO jj = 1, jpj
307            DO ji = 1, jpi
308               IF( etot(ji,jj,jk) > 1.E-3 ) THEN
309                  !  production terms for picophyto.
310                  zprorcap(ji,jj,jk) = zprpic(ji,jj,jk)  * xlimpic(ji,jj,jk) * trb(ji,jj,jk,jppic) * rfact2
311                  !
312                  zration = trb(ji,jj,jk,jpnpi) / ( trb(ji,jj,jk,jppic) + rtrn )
313                  zratiop = trb(ji,jj,jk,jpppi) / ( trb(ji,jj,jk,jppic) + rtrn )
314                  zratiof = trb(ji,jj,jk,jppfe) / ( trb(ji,jj,jk,jppic) + rtrn )
315                  zprnutmax = zprnut(ji,jj,jk) * fvpuptk(ji,jj,jk) / rno3 * trb(ji,jj,jk,jppic) * rfact2
316                  ! Uptake of nitrogen
317                  zrat = MIN( 1., zration / (xqnpmax(ji,jj,jk) + rtrn) )
318                  zmax = MAX(0., MIN(1., (1. - zrat)/ (1.05 - zrat) * 1.05))
319                  zpronmax = zprnutmax * zmax * MAX(0., MIN(1., ( zratiop - xqppmin(ji,jj,jk) )   &
320                  &          / ( xqppmax(ji,jj,jk) - xqppmin(ji,jj,jk) ), xlimpfe(ji,jj,jk) ) )
321                  zpronewp(ji,jj,jk) = zpronmax * zdaylen(ji,jj) * xpicono3(ji,jj,jk) 
322                  zproregp(ji,jj,jk) = zpronmax * xpiconh4(ji,jj,jk)
323                  ! Uptake of phosphorus
324                  zrat = MIN( 1., zratiop / (xqppmax(ji,jj,jk) + rtrn) )
325                  zmax = MAX(0., MIN(1., (1. - zrat)/ (1.05 - zrat) * 1.05))
326                  zpropmax = zprnutmax * zmax * xlimpfe(ji,jj,jk)
327                  zpropo4p(ji,jj,jk) = zpropmax * xpicopo4(ji,jj,jk)
328                  zprodopp(ji,jj,jk) = zpropmax * xpicodop(ji,jj,jk)
329                  ! Uptake of iron
330                  zrat = MIN( 1., zratiof / qfpmax )
331                  zmax = MAX(0., MIN(1., (1. - zrat)/ (1.05 - zrat) * 1.05))
332                  zprofmax = zprnutmax * qfpmax * zmax
333                  zprofep(ji,jj,jk) = zprofmax * xpicofer(ji,jj,jk) * ( 3. - 2.4 * xlimpfe(ji,jj,jk)   &
334                  &          / ( xlimpfe(ji,jj,jk) + 0.2 ) ) * (1. + 0.8 * xpicono3(ji,jj,jk) / ( rtrn   &
335                  &          + xpicono3(ji,jj,jk) + xpiconh4(ji,jj,jk) ) * (1. - xpicofer(ji,jj,jk) ) )
336               ENDIF
337            END DO
338         END DO
339      END DO
340
341      ! Computation of the various production terms of diatoms
342      DO jk = 1, jpkm1
343         DO jj = 1, jpj
344            DO ji = 1, jpi
345               IF( etot(ji,jj,jk) > 1.E-3 ) THEN
346                  !  production terms for diatomees
347                  zprorcad(ji,jj,jk) = zprdia(ji,jj,jk) * xlimdia(ji,jj,jk) * trb(ji,jj,jk,jpdia) * rfact2
348                  ! Computation of the respiration term according to pahlow
349                  ! & oschlies (2013)
350                  !
351                  zration = trb(ji,jj,jk,jpndi) / ( trb(ji,jj,jk,jpdia) + rtrn )
352                  zratiop = trb(ji,jj,jk,jppdi) / ( trb(ji,jj,jk,jpdia) + rtrn )
353                  zratiof = trb(ji,jj,jk,jpdfe) / ( trb(ji,jj,jk,jpdia) + rtrn )
354                  zprnutmax = zprnut(ji,jj,jk) * fvduptk(ji,jj,jk) / rno3 * trb(ji,jj,jk,jpdia) * rfact2
355                  ! Uptake of nitrogen
356                  zrat = MIN( 1., zration / (xqndmax(ji,jj,jk) + rtrn) )
357                  zmax = MAX(0., MIN(1., (1. - zrat)/ (1.05 - zrat) * 1.05)) 
358                  zpronmax = zprnutmax * zmax * MAX(0., MIN(1., ( zratiop - xqpdmin(ji,jj,jk) )   &
359                  &          / ( xqpdmax(ji,jj,jk) - xqpdmin(ji,jj,jk) ), xlimdfe(ji,jj,jk) ) )
360                  zpronewd(ji,jj,jk) = zpronmax * zdaylen(ji,jj) * xdiatno3(ji,jj,jk)
361                  zproregd(ji,jj,jk) = zpronmax * xdiatnh4(ji,jj,jk)
362                  ! Uptake of phosphorus
363                  zrat = MIN( 1., zratiop / (xqpdmax(ji,jj,jk) + rtrn) )
364                  zmax = MAX(0., MIN(1., (1. - zrat)/ (1.05 - zrat) * 1.05)) 
365                  zpropmax = zprnutmax * zmax * xlimdfe(ji,jj,jk)
366                  zpropo4d(ji,jj,jk) = zpropmax * xdiatpo4(ji,jj,jk)
367                  zprodopd(ji,jj,jk) = zpropmax * xdiatdop(ji,jj,jk)
368                  ! Uptake of iron
369                  zrat = MIN( 1., zratiof / qfdmax )
370                  zmax = MAX(0., MIN(1., (1. - zrat)/ (1.05 - zrat) * 1.05))
371                  zprofmax = zprnutmax * qfdmax * zmax
372                  zprofed(ji,jj,jk) = zprofmax * xdiatfer(ji,jj,jk) * ( 3. - 2.4 * xlimdfe(ji,jj,jk)     &
373                  &          / ( xlimdfe(ji,jj,jk) + 0.2 ) ) * (1. + 0.8 * xdiatno3(ji,jj,jk) / ( rtrn   &
374                  &          + xdiatno3(ji,jj,jk) + xdiatnh4(ji,jj,jk) ) * (1. - xdiatfer(ji,jj,jk) ) )
375               ENDIF
376            END DO
377         END DO
378      END DO
379
380      DO jk = 1, jpkm1
381         DO jj = 1, jpj
382            DO ji = 1, jpi
383               IF( etot(ji,jj,jk) > 1.E-3 ) THEN
384                     !  production terms for nanophyto. ( chlorophyll )
385                  zprod = rday * (zpronewn(ji,jj,jk) + zproregn(ji,jj,jk)) * zprchln(ji,jj,jk) * xlimphy(ji,jj,jk)
386                  zprochln(ji,jj,jk) = thetannm * zprod / ( zpislopead(ji,jj,jk) * enano(ji,jj,jk) +rtrn )
387                  zprochln(ji,jj,jk) = MAX(zprochln(ji,jj,jk), chlcmin * 12. * zprorcan (ji,jj,jk) )
388                     !  production terms for picophyto. ( chlorophyll )
389                  zprod = rday * (zpronewp(ji,jj,jk) + zproregp(ji,jj,jk)) * zprchlp(ji,jj,jk) * xlimpic(ji,jj,jk)
390                  zprochlp(ji,jj,jk) = thetanpm * zprod / ( zpislopeadp(ji,jj,jk) * epico(ji,jj,jk) +rtrn )
391                  zprochlp(ji,jj,jk) = MAX(zprochlp(ji,jj,jk), chlcmin * 12. * zprorcap(ji,jj,jk) )
392                  !  production terms for diatomees ( chlorophyll )
393                  zprod = rday * (zpronewd(ji,jj,jk) + zproregd(ji,jj,jk)) * zprchld(ji,jj,jk) * xlimdia(ji,jj,jk)
394                  zprochld(ji,jj,jk) = thetandm * zprod / ( zpislopead2(ji,jj,jk) * ediat(ji,jj,jk) +rtrn )
395                  zprochld(ji,jj,jk) = MAX(zprochld(ji,jj,jk), chlcmin * 12. * zprorcad(ji,jj,jk) )
396               ENDIF
397            END DO
398         END DO
399      END DO
400
401      !   Update the arrays TRA which contain the biological sources and sinks
402      DO jk = 1, jpkm1
403         DO jj = 1, jpj
404           DO ji =1 ,jpi
405              zprontot = zpronewn(ji,jj,jk) + zproregn(ji,jj,jk)
406              zproptot = zpronewp(ji,jj,jk) + zproregp(ji,jj,jk)
407              zprodtot = zpronewd(ji,jj,jk) + zproregd(ji,jj,jk)
408              zdocprod = excret2 * zprorcad(ji,jj,jk) + excret * zprorcan(ji,jj,jk)  &
409              &          + excretp * zprorcap(ji,jj,jk)
410              tra(ji,jj,jk,jppo4) = tra(ji,jj,jk,jppo4) - zpropo4n(ji,jj,jk) - zpropo4d(ji,jj,jk)  &
411              &                     - zpropo4p(ji,jj,jk)
412              tra(ji,jj,jk,jpno3) = tra(ji,jj,jk,jpno3) - zpronewn(ji,jj,jk) - zpronewd(ji,jj,jk)  &
413              &                     - zpronewp(ji,jj,jk)
414              tra(ji,jj,jk,jpnh4) = tra(ji,jj,jk,jpnh4) - zproregn(ji,jj,jk) - zproregd(ji,jj,jk)  &
415              &                     - zproregp(ji,jj,jk)
416              tra(ji,jj,jk,jpphy) = tra(ji,jj,jk,jpphy) + zprorcan(ji,jj,jk) * texcret     &
417                 &                  - zpsino3 * zpronewn(ji,jj,jk) - zpsinh4 * zproregn(ji,jj,jk)   &
418                 &                  - zrespn(ji,jj,jk) 
419              zcroissn(ji,jj,jk) = tra(ji,jj,jk,jpphy) / rfact2/ (trb(ji,jj,jk,jpphy) + rtrn)
420              tra(ji,jj,jk,jpnph) = tra(ji,jj,jk,jpnph) + zprontot * texcret
421              tra(ji,jj,jk,jppph) = tra(ji,jj,jk,jppph) + zpropo4n(ji,jj,jk) * texcret   &
422              &                     + zprodopn(ji,jj,jk) * texcret
423              tra(ji,jj,jk,jpnch) = tra(ji,jj,jk,jpnch) + zprochln(ji,jj,jk) * texcret
424              tra(ji,jj,jk,jpnfe) = tra(ji,jj,jk,jpnfe) + zprofen(ji,jj,jk) * texcret
425              tra(ji,jj,jk,jppic) = tra(ji,jj,jk,jppic) + zprorcap(ji,jj,jk) * texcretp     &
426                 &                  - zpsino3 * zpronewp(ji,jj,jk) - zpsinh4 * zproregp(ji,jj,jk)   &
427                 &                  - zrespp(ji,jj,jk) 
428              zcroissp(ji,jj,jk) = tra(ji,jj,jk,jppic) / rfact2/ (trb(ji,jj,jk,jppic) + rtrn)
429              tra(ji,jj,jk,jpnpi) = tra(ji,jj,jk,jpnpi) + zproptot * texcretp
430              tra(ji,jj,jk,jpppi) = tra(ji,jj,jk,jpppi) + zpropo4p(ji,jj,jk) * texcretp   &
431              &                     + zprodopp(ji,jj,jk) * texcretp
432              tra(ji,jj,jk,jppch) = tra(ji,jj,jk,jppch) + zprochlp(ji,jj,jk) * texcretp
433              tra(ji,jj,jk,jppfe) = tra(ji,jj,jk,jppfe) + zprofep(ji,jj,jk) * texcretp
434              tra(ji,jj,jk,jpdia) = tra(ji,jj,jk,jpdia) + zprorcad(ji,jj,jk) * texcret2   &
435                 &                  - zpsino3 * zpronewd(ji,jj,jk) - zpsinh4 * zproregd(ji,jj,jk)   &
436                 &                  - zrespd(ji,jj,jk) 
437              zcroissd(ji,jj,jk) = tra(ji,jj,jk,jpdia) / rfact2 / (trb(ji,jj,jk,jpdia) + rtrn)
438              tra(ji,jj,jk,jpndi) = tra(ji,jj,jk,jpndi) + zprodtot * texcret2
439              tra(ji,jj,jk,jppdi) = tra(ji,jj,jk,jppdi) + zpropo4d(ji,jj,jk) * texcret2   &
440              &                     + zprodopd(ji,jj,jk) * texcret2
441              tra(ji,jj,jk,jpdch) = tra(ji,jj,jk,jpdch) + zprochld(ji,jj,jk) * texcret2
442              tra(ji,jj,jk,jpdfe) = tra(ji,jj,jk,jpdfe) + zprofed(ji,jj,jk) * texcret2
443              tra(ji,jj,jk,jpdsi) = tra(ji,jj,jk,jpdsi) + zprorcad(ji,jj,jk) * zysopt(ji,jj,jk) * texcret2
444              tra(ji,jj,jk,jpdoc) = tra(ji,jj,jk,jpdoc) + excret2 * zprorcad(ji,jj,jk) + excret * zprorcan(ji,jj,jk)  &
445              &                     + excretp * zprorcap(ji,jj,jk)
446              tra(ji,jj,jk,jpdon) = tra(ji,jj,jk,jpdon) + excret2 * zprodtot + excret * zprontot   &
447              &                     + excretp * zproptot
448              tra(ji,jj,jk,jpdop) = tra(ji,jj,jk,jpdop) + excret2 * zpropo4d(ji,jj,jk) + excret * zpropo4n(ji,jj,jk)   &
449              &    - texcret * zprodopn(ji,jj,jk) - texcret2 * zprodopd(ji,jj,jk) + excretp * zpropo4p(ji,jj,jk)     &
450              &    - texcretp * zprodopp(ji,jj,jk)
451              tra(ji,jj,jk,jpoxy) = tra(ji,jj,jk,jpoxy) + o2ut * ( zproregn(ji,jj,jk) + zproregd(ji,jj,jk)   &
452                 &                + zproregp(ji,jj,jk) ) + ( o2ut + o2nit ) * ( zpronewn(ji,jj,jk)           &
453                 &                + zpronewd(ji,jj,jk) + zpronewp(ji,jj,jk) )   &
454                 &                - o2ut * ( zrespn(ji,jj,jk) + zrespp(ji,jj,jk) + zrespd(ji,jj,jk) )
455              zfeup    = texcret * zprofen(ji,jj,jk) + texcret2 * zprofed(ji,jj,jk)  &
456              &          + texcretp * zprofep(ji,jj,jk)
457              tra(ji,jj,jk,jpfer) = tra(ji,jj,jk,jpfer) - zfeup
458              tra(ji,jj,jk,jpsil) = tra(ji,jj,jk,jpsil) - texcret2 * zprorcad(ji,jj,jk) * zysopt(ji,jj,jk)
459              tra(ji,jj,jk,jpdic) = tra(ji,jj,jk,jpdic) - zprorcan(ji,jj,jk) - zprorcad(ji,jj,jk) - zprorcap(ji,jj,jk)  &
460              &                     + zpsino3 * zpronewn(ji,jj,jk) + zpsinh4 * zproregn(ji,jj,jk)   &
461              &                     + zpsino3 * zpronewp(ji,jj,jk) + zpsinh4 * zproregp(ji,jj,jk)   &
462              &                     + zpsino3 * zpronewd(ji,jj,jk) + zpsinh4 * zproregd(ji,jj,jk)  &
463              &                     + zrespn(ji,jj,jk) + zrespd(ji,jj,jk) + zrespp(ji,jj,jk) 
464              tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) + rno3 * ( zpronewn(ji,jj,jk) + zpronewd(ji,jj,jk)  &
465              &                     + zpronewp(ji,jj,jk) ) - rno3 * ( zproregn(ji,jj,jk) + zproregd(ji,jj,jk)     &
466              &                     + zproregp(ji,jj,jk) ) 
467#if defined key_ligand
468              tra(ji,jj,jk,jplgw) = tra(ji,jj,jk,jplgw) + zdocprod * ldocp - zfeup * plig(ji,jj,jk) * lthet
469#endif
470          END DO
471        END DO
472     END DO
473
474     ! Total primary production per year
475     tpp = tpp + glob_sum( ( zprorcan(:,:,:) + zprorcad(:,:,:) + zprorcap(:,:,:) ) * cvol(:,:,:) )
476
477     IF( ln_diatrc ) THEN
478         !
479         zrfact2 = 1.e3 * rfact2r  ! conversion from mol/L/timestep into mol/m3/s
480         IF( lk_iomput ) THEN
481           IF( knt == nrdttrc ) THEN
482              CALL iom_put( "PPPHY"  , zprorcan(:,:,:) * zrfact2 * tmask(:,:,:) )  ! primary production by nanophyto
483              CALL iom_put( "PPPHYP" , zprorcap(:,:,:) * zrfact2 * tmask(:,:,:) )  ! primary production by nanophyto
484              CALL iom_put( "PPPHY2" , zprorcad(:,:,:) * zrfact2 * tmask(:,:,:) )  ! primary production by diatom
485              CALL iom_put( "PPNEWN" , zpronewn(:,:,:) * zrfact2 * tmask(:,:,:) )  ! new primary production by nanophyto
486              CALL iom_put( "PPNEWP" , zpronewp(:,:,:) * zrfact2 * tmask(:,:,:) )  ! new primary production by nanophyto
487              CALL iom_put( "PPNEWD" , zpronewd(:,:,:) * zrfact2 * tmask(:,:,:) )  ! new primary production by diatom
488              CALL iom_put( "PBSi"   , zprorcad(:,:,:) * zrfact2 * tmask(:,:,:) * zysopt(:,:,:) ) ! biogenic silica production
489              CALL iom_put( "PFeD"   , zprofed (:,:,:) * zrfact2 * tmask(:,:,:) )  ! biogenic iron production by diatom
490              CALL iom_put( "PFeP"   , zprofep (:,:,:) * zrfact2 * tmask(:,:,:) )  ! biogenic iron production by diatom
491              CALL iom_put( "PFeN"   , zprofen (:,:,:) * zrfact2 * tmask(:,:,:) )  ! biogenic iron production by nanophyto
492              CALL iom_put( "Mumax"  , prmaxn(:,:,:) * tmask(:,:,:) )  ! Maximum growth rate
493              CALL iom_put( "MuN"    , zprbio(:,:,:) * xlimphy(:,:,:) * tmask(:,:,:) )  ! Realized growth rate for nanophyto
494              CALL iom_put( "MuP"    , zprpic(:,:,:) * xlimpic(:,:,:) * tmask(:,:,:) )  ! Realized growth rate for nanophyto
495              CALL iom_put( "MuD"    , zprdia(:,:,:) * xlimdia(:,:,:) * tmask(:,:,:) )  ! Realized growth rate for diatoms
496              CALL iom_put( "MunetN"    , zcroissn(:,:,:) * tmask(:,:,:) )  ! Realized growth rate for nanophyto
497              CALL iom_put( "MunetP"    , zcroissp(:,:,:) * tmask(:,:,:) )  ! Realized growth rate for nanophyto
498              CALL iom_put( "MunetD"    , zcroissd(:,:,:) * tmask(:,:,:) )  ! Realized growth rate for diatoms
499              CALL iom_put( "LNlight", zprbio (:,:,:) / (prmaxn(:,:,:) + rtrn) * tmask(:,:,:) )  ! light limitation term
500              CALL iom_put( "LPlight", zprpic (:,:,:) / (prmaxp(:,:,:) + rtrn) * tmask(:,:,:) )  ! light limitation term
501              CALL iom_put( "LDlight", zprdia (:,:,:) / (prmaxd(:,:,:) + rtrn) * tmask(:,:,:) )  ! light limitation term
502           ENDIF
503         ELSE
504              trc3d(:,:,:,jp_pcs0_3d + 4)  = zprorcan(:,:,:) * zrfact2 * tmask(:,:,:)
505              trc3d(:,:,:,jp_pcs0_3d + 5)  = zprorcad(:,:,:) * zrfact2 * tmask(:,:,:)
506              trc3d(:,:,:,jp_pcs0_3d + 6)  = zpronewn(:,:,:) * zrfact2 * tmask(:,:,:)
507              trc3d(:,:,:,jp_pcs0_3d + 7)  = zpronewd(:,:,:) * zrfact2 * tmask(:,:,:)
508              trc3d(:,:,:,jp_pcs0_3d + 8)  = zprorcad(:,:,:) * zrfact2 * tmask(:,:,:) * zysopt(:,:,:)
509              trc3d(:,:,:,jp_pcs0_3d + 9)  = zprofed (:,:,:) * zrfact2 * tmask(:,:,:)
510#  if ! defined key_kriest
511              trc3d(:,:,:,jp_pcs0_3d + 10) = zprofen (:,:,:) * zrfact2 * tmask(:,:,:)
512#  endif
513         ENDIF
514         !
515      ENDIF
516
517      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
518         WRITE(charout, FMT="('prod')")
519         CALL prt_ctl_trc_info(charout)
520         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
521      ENDIF
522      !
523      CALL wrk_dealloc( jpi, jpj,      zmixnano, zmixpico, zmixdiat, zstrn )
524      CALL wrk_dealloc( jpi, jpj, jpk, zpislopead, zpislopeadp, zpislopead2, zysopt )                           
525      CALL wrk_dealloc( jpi, jpj, jpk, zprdia, zprpic, zprbio, zprorcan, zprorcap, zprorcad )
526      CALL wrk_dealloc( jpi, jpj, jpk, zprofed, zprofep, zprofen, zprochln, zprochlp, zprochld ) 
527      CALL wrk_dealloc( jpi, jpj, jpk, zpronewn, zpronewp, zpronewd, zproregn, zproregp, zproregd )
528      CALL wrk_dealloc( jpi, jpj, jpk, zpropo4n, zpropo4p, zpropo4d, zrespn, zrespp, zrespd, zprnut )
529      CALL wrk_dealloc( jpi, jpj, jpk, zprchln, zprchlp, zprchld, zprodopn, zprodopp, zprodopd )
530      CALL wrk_dealloc( jpi, jpj, jpk, zcroissp, zcroissn, zcroissd )
531      !
532      IF( nn_timing == 1 )  CALL timing_stop('p5z_prod')
533      !
534   END SUBROUTINE p5z_prod
535
536
537   SUBROUTINE p5z_prod_init
538      !!----------------------------------------------------------------------
539      !!                  ***  ROUTINE p5z_prod_init  ***
540      !!
541      !! ** Purpose :   Initialization of phytoplankton production parameters
542      !!
543      !! ** Method  :   Read the nampisprod namelist and check the parameters
544      !!      called at the first timestep (nittrc000)
545      !!
546      !! ** input   :   Namelist nampisprod
547      !!----------------------------------------------------------------------
548      !
549      NAMELIST/nampisprod/ pislope, pislopep, pislope2, xadap, bresp, excret, excretp, excret2,  &
550         &                 thetannm, thetanpm, thetandm, chlcmin, grosip, zlimmxln,           &
551         &                 zlimmxlp, zlimmxld
552
553      INTEGER :: ios                 ! Local integer output status for namelist read
554      !!----------------------------------------------------------------------
555
556      REWIND( numnatp_ref )              ! Namelist nampisprod in reference namelist : Pisces phytoplankton production
557      READ  ( numnatp_ref, nampisprod, IOSTAT = ios, ERR = 901)
558901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampisprod in reference namelist', lwp )
559
560      REWIND( numnatp_cfg )              ! Namelist nampisprod in configuration namelist : Pisces phytoplankton production
561      READ  ( numnatp_cfg, nampisprod, IOSTAT = ios, ERR = 902 )
562902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampisprod in configuration namelist', lwp )
563      IF(lwm) WRITE ( numonp, nampisprod )
564
565      IF(lwp) THEN                         ! control print
566         WRITE(numout,*) ' '
567         WRITE(numout,*) ' Namelist parameters for phytoplankton growth, nampisprod'
568         WRITE(numout,*) ' ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
569         WRITE(numout,*) '    mean Si/C ratio                           grosip       =', grosip
570         WRITE(numout,*) '    P-I slope                                 pislope      =', pislope
571         WRITE(numout,*) '    Acclimation factor to low light           xadap       =', xadap
572         WRITE(numout,*) '    excretion ratio of nanophytoplankton      excret       =', excret
573         WRITE(numout,*) '    excretion ratio of picophytoplankton      excretp      =', excretp
574         WRITE(numout,*) '    excretion ratio of diatoms                excret2      =', excret2
575         WRITE(numout,*) '    basal respiration in phytoplankton        bresp        =', bresp
576         WRITE(numout,*) '    Maximum Chl/C in phytoplankton            chlcmin      =', chlcmin
577         WRITE(numout,*) '    P-I slope  for diatoms                    pislope2     =', pislope2
578         WRITE(numout,*) '    P-I slope  for picophytoplankton          pislopep     =', pislopep
579         WRITE(numout,*) '    Minimum Chl/N in nanophytoplankton        thetannm     =', thetannm
580         WRITE(numout,*) '    Minimum Chl/N in picophytoplankton        thetanpm     =', thetanpm
581         WRITE(numout,*) '    Minimum Chl/N in diatoms                  thetandm     =', thetandm
582         WRITE(numout,*) '    Critical time scale for mixing (nano)     zlimmxln     =', zlimmxln
583         WRITE(numout,*) '    Critical time scale for mixing (pico)     zlimmxlp     =', zlimmxlp
584         WRITE(numout,*) '    Critical time scale for mixing (diatoms)  zlimmxld     =', zlimmxld
585      ENDIF
586      !
587      r1_rday   = 1._wp / rday 
588      texcret   = 1._wp - excret
589      texcretp  = 1._wp - excretp
590      texcret2  = 1._wp - excret2
591      tpp       = 0._wp
592      !
593   END SUBROUTINE p5z_prod_init
594
595
596   INTEGER FUNCTION p5z_prod_alloc()
597      !!----------------------------------------------------------------------
598      !!                     ***  ROUTINE p5z_prod_alloc  ***
599      !!----------------------------------------------------------------------
600      ALLOCATE( prmaxn(jpi,jpj,jpk), prmaxp(jpi,jpj,jpk), prmaxd(jpi,jpj,jpk),  &
601      &          zdaylen(jpi,jpj), STAT = p5z_prod_alloc )
602      !
603      IF( p5z_prod_alloc /= 0 ) CALL ctl_warn('p5z_prod_alloc : failed to allocate arrays.')
604      !
605   END FUNCTION p5z_prod_alloc
606
607#else
608   !!======================================================================
609   !!  Dummy module :                                   No PISCES bio-model
610   !!======================================================================
611CONTAINS
612   SUBROUTINE p5z_prod                    ! Empty routine
613   END SUBROUTINE p5z_prod
614#endif 
615
616   !!======================================================================
617END MODULE  p5zprod
Note: See TracBrowser for help on using the repository browser.