New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
dtasal.F90 in branches/DEV_r1784_3DF/NEMO/OPA_SRC/DTA – NEMO

source: branches/DEV_r1784_3DF/NEMO/OPA_SRC/DTA/dtasal.F90 @ 1856

Last change on this file since 1856 was 1856, checked in by smasson, 14 years ago

fldread_3D: small bugfix and style
  • Property svn:eol-style set to native
  • Property svn:keywords set to Id
File size: 11.1 KB
Line 
1MODULE dtasal
2   !!======================================================================
3   !!                     ***  MODULE  dtasal  ***
4   !! Ocean data  :  read ocean salinity data from monthly atlas data
5   !!=====================================================================
6#if defined key_dtasal   ||   defined key_esopa
7   !!----------------------------------------------------------------------
8   !!   'key_dtasal'                                          salinity data
9   !!----------------------------------------------------------------------
10   !!   dta_sal      : read ocean salinity data
11   !!----------------------------------------------------------------------
12   !! * Modules used
13   USE oce             ! ocean dynamics and tracers
14   USE dom_oce         ! ocean space and time domain
15   USE fldread         ! read input fields
16   USE in_out_manager  ! I/O manager
17   USE phycst          ! physical constants
18#if defined key_orca_lev10
19   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
20#endif
21
22   IMPLICIT NONE
23   PRIVATE
24
25   !! * Routine accessibility
26   PUBLIC dta_sal   ! called by step.F90 and inidta.F90
27   
28   !! * Shared module variables
29   LOGICAL , PUBLIC, PARAMETER ::   lk_dtasal = .TRUE.    !: salinity data flag
30   REAL(wp), PUBLIC, DIMENSION(jpi,jpj,jpk) ::   s_dta    !: salinity data at given time-step
31
32   !! * Module variables
33   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_sal       ! structure of input SST (file informations, fields read)
34
35   !! * Substitutions
36#  include "domzgr_substitute.h90"
37   !!----------------------------------------------------------------------
38   !!   OPA 9.0 , LOCEAN-IPSL (2005)
39   !! $Id$
40   !! This software is governed by the CeCILL licence see modipsl/doc/NEMO_CeCILL.txt
41   !!----------------------------------------------------------------------
42
43CONTAINS
44
45   !!----------------------------------------------------------------------
46   !!   Default option:                                         NetCDF file
47   !!----------------------------------------------------------------------
48
49   SUBROUTINE dta_sal( kt )
50      !!----------------------------------------------------------------------
51      !!                   ***  ROUTINE dta_sal  ***
52      !!       
53      !! ** Purpose :   Reads monthly salinity data
54      !!             
55      !! ** Method  : - Read on unit numsdt the monthly salinity data interpo-
56      !!     lated onto the model grid.
57      !!              - At each time step, a linear interpolation is applied
58      !!     between two monthly values.
59      !!
60      !! History :
61      !!        !  91-03  ()  Original code
62      !!        !  92-07  (M. Imbard)
63      !!   9.0  !  02-06  (G. Madec)  F90: Free form and module
64      !!----------------------------------------------------------------------
65     
66      !! * Arguments
67      INTEGER, INTENT(in) ::   kt             ! ocean time step
68     
69      !! * Local declarations
70      INTEGER ::   ji, jj, jk, jl, jkk            ! dummy loop indicies
71      INTEGER ::   imois, iman, i15 , ik          ! temporary integers
72      INTEGER ::   ierror
73#if defined key_tradmp
74      INTEGER ::   il0, il1, ii0, ii1, ij0, ij1   ! temporary integers
75#endif
76      REAL(wp)::   zxy, zl
77#if defined key_orca_lev10
78      INTEGER ::   ikr, ikw, ikt, jjk 
79      REAL(wp)::   zfac
80#endif
81      REAL(wp), DIMENSION(jpk) ::   zsaldta            ! auxiliary array for interpolation
82      CHARACTER(len=100)       :: cn_dir          ! Root directory for location of ssr files
83      TYPE(FLD_N)              :: sn_sal
84      LOGICAL , SAVE           :: linit_sal = .FALSE.
85      !!----------------------------------------------------------------------
86      NAMELIST/namdta_sal/cn_dir,sn_sal
87     
88      ! 1. Initialization
89      ! -----------------------
90     
91      IF( kt == nit000 .AND. ( .NOT. linit_sal ) ) THEN
92       
93         !                         ! set file information
94         cn_dir = './'             ! directory in which the model is executed
95         ! ... default values (NB: frequency positive => hours, negative => months)
96         !            !   file    ! frequency !  variable  ! time intep !  clim   ! 'yearly' or ! weights  ! rotation   !
97         !            !   name    !  (hours)  !   name     !   (T/F)    !  (T/F)  !  'monthly'  ! filename ! pairs      !
98         sn_sal = FLD_N( 'salinity',  -1.  ,  'vosaline',  .false.   , .true.  ,  'monthly'  , ''       , ''         )
99
100         REWIND ( numnam )         ! ... read in namlist namdta_sal
101         READ( numnam, namdta_sal ) 
102
103         IF(lwp) THEN              ! control print
104            WRITE(numout,*)
105            WRITE(numout,*) 'dta_sal : Salinity Climatology '
106            WRITE(numout,*) '~~~~~~~ '
107         ENDIF
108         ALLOCATE( sf_sal(1), STAT=ierror )
109         IF( ierror > 0 ) THEN
110             CALL ctl_stop( 'dta_sal: unable to allocate sf_sal structure' )   ;   RETURN
111         ENDIF
112#if defined key_orca_lev10
113         ALLOCATE( sf_sal(1)%fnow(jpi,jpj,jpkdta  ) )
114         ALLOCATE( sf_sal(1)%fdta(jpi,jpj,jpkdta,2) )
115#else
116         ALLOCATE( sf_sal(1)%fnow(jpi,jpj,jpk  ) )
117         ALLOCATE( sf_sal(1)%fdta(jpi,jpj,jpk,2) )
118#endif
119
120         ! fill sf_sal with sn_sal and control print
121         CALL fld_fill( sf_sal, (/ sn_sal /), cn_dir, 'dta_sal', 'Salinity data', 'namdta_sal' )
122         linit_sal = .TRUE.       
123      ENDIF
124     
125     
126      ! 2. Read monthly file
127      ! -------------------
128     
129      CALL fld_read( kt, 1, sf_sal )
130
131      IF( lwp .AND. kt==nn_it000 ) THEN
132         WRITE(numout,*)
133         WRITE(numout,*) ' read Levitus salinity ok'
134         WRITE(numout,*)
135      ENDIF
136
137#if defined key_tradmp
138      IF( cp_cfg == "orca"  .AND. jp_cfg == 2 ) THEN
139   
140         !                                        ! =======================
141         !                                        !  ORCA_R2 configuration
142         !                                        ! =======================
143         ij0 = 101   ;   ij1 = 109
144         ii0 = 141   ;   ii1 = 155   
145         DO jj = mj0(ij0), mj1(ij1)                  ! Reduced salinity in the Alboran Sea
146            DO ji = mi0(ii0), mi1(ii1)
147               sf_sal(1)%fnow(ji,jj,13:13) = sf_sal(1)%fnow(ji,jj,13:13) - 0.15
148               sf_sal(1)%fnow(ji,jj,14:15) = sf_sal(1)%fnow(ji,jj,14:15) - 0.25
149               sf_sal(1)%fnow(ji,jj,16:17) = sf_sal(1)%fnow(ji,jj,16:17) - 0.30
150               sf_sal(1)%fnow(ji,jj,18:25) = sf_sal(1)%fnow(ji,jj,18:25) - 0.35
151            END DO
152         END DO
153
154         IF( n_cla == 1 ) THEN 
155            !                                         ! New salinity profile at Gibraltar
156            il0 = 138   ;   il1 = 138   
157            ij0 = 101   ;   ij1 = 102
158            ii0 = 139   ;   ii1 = 139   
159            DO jl = mi0(il0), mi1(il1)
160               DO jj = mj0(ij0), mj1(ij1)
161                  DO ji = mi0(ii0), mi1(ii1)
162                        sf_sal(1)%fnow(ji,jj,:) = sf_sal(1)%fnow(jl,jj,:)
163                  END DO
164               END DO
165            END DO
166            !                                         ! New salinity profile at Bab el Mandeb
167            il0 = 164   ;   il1 = 164   
168            ij0 =  87   ;   ij1 =  88
169            ii0 = 161   ;   ii1 = 163   
170            DO jl = mi0(il0), mi1(il1)
171               DO jj = mj0(ij0), mj1(ij1)
172                  DO ji = mi0(ii0), mi1(ii1)
173                     sf_sal(1)%fnow(ji,jj,:) = sf_sal(1)%fnow(jl,jj,:)
174                  END DO
175               END DO
176            END DO
177            !
178         ENDIF
179            !
180      ENDIF
181#endif   
182       
183#if defined key_orca_lev10
184      DO jjk = 1, 5
185         s_dta(:,:,jjk) = sf_sal(1)%fnow(:,:,1)
186      ENDDO
187      DO jk = 1, jpk-20,10
188         ikr =  INT(jk/10) + 1
189         ikw =  (ikr-1) *10 + 1
190         ikt =  ikw + 5
191         DO jjk=ikt,ikt+9
192            zfac = ( gdept_0(jjk   ) - gdepw_0(ikt) ) / ( gdepw_0(ikt+10) - gdepw_0(ikt) )
193            s_dta(:,:,jjk) = sf_sal(1)%fnow(:,:,ikr) + ( sf_sal(1)%fnow(:,:,ikr+1) - sf_sal(1)%fnow(:,:,ikr) ) * zfac
194         END DO
195      END DO
196      DO jjk = jpk-5, jpk
197         s_dta(:,:,jjk) = sf_sal(1)%fnow(:,:,jpkdta-1)
198      END DO
199      ! fill the overlap areas
200      CALL lbc_lnk (s_dta(:,:,:),'Z',-999.,'no0')       
201#else
202      s_dta(:,:,:)=sf_sal(1)%fnow(:,:,:)
203#endif
204       
205      IF( ln_sco ) THEN
206         DO jj = 1, jpj                  ! interpolation of salinites
207            DO ji = 1, jpi
208               DO jk = 1, jpk
209                  zl=fsdept_0(ji,jj,jk)
210                  IF(zl < gdept_0(1)  ) zsaldta(jk) =  s_dta(ji,jj,1    ) 
211                  IF(zl > gdept_0(jpk)) zsaldta(jk) =  s_dta(ji,jj,jpkm1) 
212                  DO jkk = 1, jpkm1
213                     IF((zl-gdept_0(jkk))*(zl-gdept_0(jkk+1)).le.0.0) THEN
214                          zsaldta(jk) = s_dta(ji,jj,jkk)                                 &
215                                     &           + (zl-gdept_0(jkk))/(gdept_0(jkk+1)-gdept_0(jkk))      &
216                                     &                              *(s_dta(ji,jj,jkk+1) - s_dta(ji,jj,jkk))
217                     ENDIF
218                  END DO
219               END DO
220               DO jk = 1, jpkm1
221                  s_dta(ji,jj,jk) = zsaldta(jk) 
222               END DO
223               s_dta(ji,jj,jpk) = 0.0 
224            END DO
225         END DO
226           
227         IF( lwp .AND. kt==nn_it000 ) THEN
228            WRITE(numout,*)
229            WRITE(numout,*) ' Levitus salinity data interpolated to s-coordinate'
230            WRITE(numout,*)
231         ENDIF
232
233      ELSE
234         !                                  ! Mask
235         s_dta(:,:,:) = s_dta(:,:,:) * tmask(:,:,:)
236         s_dta(:,:,jpk) = 0. 
237         IF( ln_zps ) THEN               ! z-coord. partial steps
238            DO jj = 1, jpj               ! interpolation of salinity at the last ocean level (i.e. the partial step)
239               DO ji = 1, jpi
240                  ik = mbathy(ji,jj) - 1
241                  IF( ik > 2 ) THEN
242                     zl = ( gdept_0(ik) - fsdept_0(ji,jj,ik) ) / ( gdept_0(ik) - gdept_0(ik-1) )
243                     s_dta(ji,jj,ik) = (1.-zl) * s_dta(ji,jj,ik) + zl * s_dta(ji,jj,ik-1)
244                  ENDIF
245               END DO
246            END DO
247         ENDIF
248      ENDIF
249       
250      IF( lwp .AND. kt==nn_it000 ) THEN
251         WRITE(numout,*)' salinity Levitus '
252         WRITE(numout,*)
253         WRITE(numout,*)'  level = 1'
254         CALL prihre(s_dta(:,:,1),    jpi,jpj,1,jpi,20,1,jpj,20,1.,numout)
255         WRITE(numout,*)'  level = ',jpk/2
256         CALL prihre(s_dta(:,:,jpk/2),jpi,jpj,1,jpi,20,1,jpj,20,1.,numout)           
257         WRITE(numout,*) '  level = ',jpkm1
258         CALL prihre(s_dta(:,:,jpkm1),jpi,jpj,1,jpi,20,1,jpj,20,1.,numout)
259      ENDIF
260
261   END SUBROUTINE dta_sal
262
263#else
264   !!----------------------------------------------------------------------
265   !!   Default option:                                    NO salinity data
266   !!----------------------------------------------------------------------
267   LOGICAL , PUBLIC, PARAMETER ::   lk_dtasal = .FALSE.   !: salinity data flag
268CONTAINS
269   SUBROUTINE dta_sal( kt )        ! Empty routine
270      WRITE(*,*) 'dta_sal: You should not have seen this print! error?', kt
271   END SUBROUTINE dta_sal
272#endif
273   !!======================================================================
274END MODULE dtasal
Note: See TracBrowser for help on using the repository browser.