New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
restart.F90 in branches/DEV_r1837_MLF/NEMO/OPA_SRC/IOM – NEMO

source: branches/DEV_r1837_MLF/NEMO/OPA_SRC/IOM/restart.F90 @ 2068

Last change on this file since 2068 was 2068, checked in by mlelod, 14 years ago

ticket: #663 ensuring restartability and conservation
  • Property svn:eol-style set to native
  • Property svn:keywords set to Id
File size: 11.2 KB
Line 
1MODULE restart
2   !!======================================================================
3   !!                     ***  MODULE  restart  ***
4   !! Ocean restart :  write the ocean restart file
5   !!======================================================================
6   !! History :        !  99-11  (M. Imbard)  Original code
7   !!             8.5  !  02-08  (G. Madec)  F90: Free form
8   !!             9.0  !  05-11  (V. Garnier) Surface pressure gradient organization
9   !!             9.0  !  06-07  (S. Masson)  use IOM for restart
10   !!----------------------------------------------------------------------
11
12   !!----------------------------------------------------------------------
13   !!   rst_opn    : open the ocean restart file
14   !!   rst_write  : write the ocean restart file
15   !!   rst_read   : read the ocean restart file
16   !!----------------------------------------------------------------------
17   USE dom_oce         ! ocean space and time domain
18   USE oce             ! ocean dynamics and tracers
19   USE phycst          ! physical constants
20   USE in_out_manager  ! I/O manager
21   USE iom             ! I/O module
22   USE c1d             ! re-initialization of u-v mask for the 1D configuration
23   USE zpshde          ! partial step: hor. derivative (zps_hde routine)
24   USE eosbn2          ! equation of state            (eos bn2 routine)
25   USE zdfddm          ! double diffusion mixing
26   USE zdfmxl          ! mixed layer depth
27   USE trdmld_oce      ! ocean active mixed layer tracers trends variables
28   USE domvvl          ! variable volume
29
30   IMPLICIT NONE
31   PRIVATE
32
33   PUBLIC   rst_opn    ! routine called by step module
34   PUBLIC   rst_write  ! routine called by step module
35   PUBLIC   rst_read   ! routine called by opa  module
36
37   LOGICAL, PUBLIC ::   lrst_oce =  .FALSE.       !: logical to control the oce restart write
38   INTEGER, PUBLIC ::   numror, numrow            !: logical unit for cean restart (read and write)
39
40   !! * Substitutions
41#  include "domzgr_substitute.h90"
42#  include "vectopt_loop_substitute.h90"
43   !!----------------------------------------------------------------------
44   !!  OPA 9.0 , LOCEAN-IPSL (2006)
45   !! $Id$
46   !! Software governed by the CeCILL licence (modipsl/doc/NEMO_CeCILL.txt)
47   !!----------------------------------------------------------------------
48
49CONTAINS
50
51   SUBROUTINE rst_opn( kt )
52      !!---------------------------------------------------------------------
53      !!                   ***  ROUTINE rst_opn  ***
54      !!                     
55      !! ** Purpose : + initialization (should be read in the namelist) of nitrst
56      !!              + open the restart when we are one time step before nitrst
57      !!                   - restart header is defined when kt = nitrst-1
58      !!                   - restart data  are written when kt = nitrst
59      !!              + define lrst_oce to .TRUE. when we need to define or write the restart
60      !!----------------------------------------------------------------------
61      INTEGER, INTENT(in) ::   kt     ! ocean time-step
62      !!
63      CHARACTER(LEN=20)   ::   clkt     ! ocean time-step deine as a character
64      CHARACTER(LEN=50)   ::   clname   ! ice output restart file name
65      !!----------------------------------------------------------------------
66      !
67      IF( kt == nit000 ) THEN   ! default definitions
68         lrst_oce = .FALSE.   
69         nitrst = nitend
70      ENDIF
71      IF( MOD( kt - 1, nstock ) == 0 ) THEN   
72         ! we use kt - 1 and not kt - nit000 to keep the same periodicity from the beginning of the experiment
73         nitrst = kt + nstock - 1                  ! define the next value of nitrst for restart writing
74         IF( nitrst > nitend )   nitrst = nitend   ! make sure we write a restart at the end of the run
75      ENDIF
76      ! to get better performances with NetCDF format:
77      ! we open and define the ocean restart file one time step before writing the data (-> at nitrst - 1)
78      ! except if we write ocean restart files every time step or if an ocean restart file was writen at nitend - 1
79      IF( kt == nitrst - 1 .OR. nstock == 1 .OR. ( kt == nitend .AND. .NOT. lrst_oce ) ) THEN
80         ! beware of the format used to write kt (default is i8.8, that should be large enough...)
81         IF( nitrst > 999999999 ) THEN   ;   WRITE(clkt, *       ) nitrst
82         ELSE                            ;   WRITE(clkt, '(i8.8)') nitrst
83         ENDIF
84         ! create the file
85         clname = TRIM(cexper)//"_"//TRIM(ADJUSTL(clkt))//"_"//TRIM(cn_ocerst_out)
86         IF(lwp) THEN
87            WRITE(numout,*)
88            SELECT CASE ( jprstlib )
89            CASE ( jprstdimg )   ;   WRITE(numout,*) '             open ocean restart binary file: '//clname
90            CASE DEFAULT         ;   WRITE(numout,*) '             open ocean restart NetCDF file: '//clname
91            END SELECT
92            IF( kt == nitrst - 1 ) THEN   ;   WRITE(numout,*) '             kt = nitrst - 1 = ', kt
93            ELSE                          ;   WRITE(numout,*) '             kt = '             , kt
94            ENDIF
95         ENDIF
96
97         CALL iom_open( clname, numrow, ldwrt = .TRUE., kiolib = jprstlib )
98         lrst_oce = .TRUE.
99      ENDIF
100      !
101   END SUBROUTINE rst_opn
102
103
104   SUBROUTINE rst_write( kt )
105      !!---------------------------------------------------------------------
106      !!                   ***  ROUTINE rstwrite  ***
107      !!                     
108      !! ** Purpose :   Write restart fields in the format corresponding to jprstlib
109      !!
110      !! ** Method  :   Write in numrow when kt == nitrst in NetCDF
111      !!      file, save fields which are necessary for restart
112      !!----------------------------------------------------------------------
113      INTEGER, INTENT(in) ::   kt   ! ocean time-step
114      !!----------------------------------------------------------------------
115
116      CALL iom_rstput( kt, nitrst, numrow, 'rdt'    , rdt       )   ! dynamics time step
117      CALL iom_rstput( kt, nitrst, numrow, 'rdttra1', rdttra(1) )   ! surface tracer time step
118
119      CALL iom_rstput( kt, nitrst, numrow, 'ub'     , ub      )     ! before fields
120      CALL iom_rstput( kt, nitrst, numrow, 'vb'     , vb      )
121      CALL iom_rstput( kt, nitrst, numrow, 'tb'     , tb      )
122      CALL iom_rstput( kt, nitrst, numrow, 'sb'     , sb      )
123      CALL iom_rstput( kt, nitrst, numrow, 'rotb'   , rotb    )
124      CALL iom_rstput( kt, nitrst, numrow, 'hdivb'  , hdivb   )
125      CALL iom_rstput( kt, nitrst, numrow, 'sshb'   , sshb    )
126      IF( lk_vvl ) THEN
127         CALL iom_rstput( kt, nitrst, numrow, 'fse3t_b', fse3t_b(:,:,:) )
128      ENDIF
129      !
130      CALL iom_rstput( kt, nitrst, numrow, 'un'     , un      )     ! now fields
131      CALL iom_rstput( kt, nitrst, numrow, 'vn'     , vn      )
132      CALL iom_rstput( kt, nitrst, numrow, 'tn'     , tn      )
133      CALL iom_rstput( kt, nitrst, numrow, 'sn'     , sn      )
134      CALL iom_rstput( kt, nitrst, numrow, 'rotn'   , rotn    )
135      CALL iom_rstput( kt, nitrst, numrow, 'hdivn'  , hdivn   )
136      CALL iom_rstput( kt, nitrst, numrow, 'sshn'   , sshn    )
137
138      CALL iom_rstput( kt, nitrst, numrow, 'rhop'   , rhop    )
139#if defined key_zdfkpp
140      CALL iom_rstput( kt, nitrst, numrow, 'rhd'  , rhd   )
141#endif
142
143      IF( kt == nitrst ) THEN
144         CALL iom_close( numrow )     ! close the restart file (only at last time step)
145         IF( .NOT. lk_trdmld )   lrst_oce = .FALSE.
146      ENDIF
147      !
148   END SUBROUTINE rst_write
149
150
151   SUBROUTINE rst_read
152      !!----------------------------------------------------------------------
153      !!                   ***  ROUTINE rst_read  ***
154      !!
155      !! ** Purpose :   Read files for restart (format fixed by jprstlib )
156      !!
157      !! ** Method  :   Read in restart.nc file fields which are necessary for restart
158      !!----------------------------------------------------------------------
159      REAL(wp) ::   zrdt, zrdttra1
160      INTEGER  ::   jlibalt = jprstlib
161      INTEGER  ::   jk                    ! dummy loop indices
162      LOGICAL  ::   llok
163      !!----------------------------------------------------------------------
164
165      IF(lwp) THEN                                             ! Contol prints
166         WRITE(numout,*)
167         SELECT CASE ( jprstlib )
168         CASE ( jpnf90    )   ;   WRITE(numout,*) 'rst_read : read oce NetCDF restart file'
169         CASE ( jprstdimg )   ;   WRITE(numout,*) 'rst_read : read oce binary restart file'
170         END SELECT
171         WRITE(numout,*) '~~~~~~~~'
172      ENDIF
173
174      IF ( jprstlib == jprstdimg ) THEN
175        ! eventually read netcdf file (monobloc)  for restarting on different number of processors
176        ! if {cn_ocerst_in}.nc exists, then set jlibalt to jpnf90
177        INQUIRE( FILE = TRIM(cn_ocerst_in)//'.nc', EXIST = llok )
178        IF ( llok ) THEN ; jlibalt = jpnf90  ; ELSE ; jlibalt = jprstlib ; ENDIF
179      ENDIF
180      CALL iom_open( cn_ocerst_in, numror, kiolib = jlibalt )
181
182      ! Check dynamics and tracer time-step consistency and force Euler restart if changed
183      IF( iom_varid( numror, 'rdt', ldstop = .FALSE. ) > 0 )   THEN
184         CALL iom_get( numror, 'rdt', zrdt )
185         IF( zrdt /= rdt )   neuler = 0
186      ENDIF
187      IF( iom_varid( numror, 'rdttra1', ldstop = .FALSE. ) > 0 )   THEN
188         CALL iom_get( numror, 'rdttra1', zrdttra1 )
189         IF( zrdttra1 /= rdttra(1) )   neuler = 0
190      ENDIF
191      !
192      CALL iom_get( numror, jpdom_autoglo, 'ub'   , ub    )        ! before fields
193      CALL iom_get( numror, jpdom_autoglo, 'vb'   , vb    )
194      CALL iom_get( numror, jpdom_autoglo, 'tb'   , tb    )
195      CALL iom_get( numror, jpdom_autoglo, 'sb'   , sb    )
196      CALL iom_get( numror, jpdom_autoglo, 'rotb' , rotb  )
197      CALL iom_get( numror, jpdom_autoglo, 'hdivb', hdivb )
198      CALL iom_get( numror, jpdom_autoglo, 'sshb' , sshb  )
199      IF( lk_vvl ) THEN
200         CALL iom_get( numror, jpdom_autoglo, 'fse3t_b', fse3t_b(:,:,:) )
201      ENDIF
202      !
203      CALL iom_get( numror, jpdom_autoglo, 'un'   , un    )        ! now    fields
204      CALL iom_get( numror, jpdom_autoglo, 'vn'   , vn    )
205      CALL iom_get( numror, jpdom_autoglo, 'tn'   , tn    )
206      CALL iom_get( numror, jpdom_autoglo, 'sn'   , sn    )
207      CALL iom_get( numror, jpdom_autoglo, 'rotn' , rotn  )
208      CALL iom_get( numror, jpdom_autoglo, 'hdivn', hdivn )
209      CALL iom_get( numror, jpdom_autoglo, 'sshn' , sshn  )
210
211      CALL iom_get( numror, jpdom_autoglo, 'rhop' , rhop  )        ! now    potential density
212#if defined key_zdfkpp
213      IF( iom_varid( numror, 'rhd', ldstop = .FALSE. ) > 0 ) THEN
214         CALL iom_get( numror, jpdom_autoglo, 'rhd' , rhd  )       ! now    in situ density anomaly
215      ELSE
216         CALL eos( tn, sn, rhd )   ! compute rhd
217      ENDIF
218#endif
219
220      IF( neuler == 0 ) THEN                                  ! Euler restart (neuler=0)
221         tb   (:,:,:) = tn   (:,:,:)                             ! all before fields set to now values
222         sb   (:,:,:) = sn   (:,:,:)
223         ub   (:,:,:) = un   (:,:,:)
224         vb   (:,:,:) = vn   (:,:,:)
225         rotb (:,:,:) = rotn (:,:,:)
226         hdivb(:,:,:) = hdivn(:,:,:)
227         sshb (:,:)   = sshn (:,:)
228         IF( lk_vvl ) THEN
229            DO jk = 1, jpk
230               fse3t_b(:,:,jk) = fse3t_n(:,:,jk)
231            ENDDO
232         ENDIF
233      ENDIF
234      !
235   END SUBROUTINE rst_read
236
237   !!=====================================================================
238END MODULE restart
Note: See TracBrowser for help on using the repository browser.