New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
sbcmod.F90 in branches/DEV_r1837_MLF/NEMO/OPA_SRC/SBC – NEMO

source: branches/DEV_r1837_MLF/NEMO/OPA_SRC/SBC/sbcmod.F90 @ 1975

Last change on this file since 1975 was 1975, checked in by mlelod, 14 years ago

ticket: #663 MLF: first part
  • Property svn:keywords set to Id
File size: 19.9 KB
Line 
1MODULE sbcmod
2   !!======================================================================
3   !!                       ***  MODULE  sbcmod  ***
4   !! Surface module :  provide to the ocean its surface boundary condition
5   !!======================================================================
6   !! History :  3.0  !  2006-07  (G. Madec)  Original code
7   !!            3.1  !  2008-08  (S. Masson, E. Maisonnave, G. Madec) coupled interface
8   !!            3.3  !  2010-04  (M. Leclair, G. Madec)  Forcing averaged over 2 time steps
9   !!----------------------------------------------------------------------
10
11   !!----------------------------------------------------------------------
12   !!   sbc_init       : read namsbc namelist
13   !!   sbc            : surface ocean momentum, heat and freshwater boundary conditions
14   !!----------------------------------------------------------------------
15   USE oce             ! ocean dynamics and tracers
16   USE dom_oce         ! ocean space and time domain
17   USE phycst          ! physical constants
18
19   USE sbc_oce         ! Surface boundary condition: ocean fields
20   USE sbc_ice         ! Surface boundary condition: ice fields
21   USE sbcssm          ! surface boundary condition: sea-surface mean variables
22   USE sbcana          ! surface boundary condition: analytical formulation
23   USE sbcflx          ! surface boundary condition: flux formulation
24   USE sbcblk_clio     ! surface boundary condition: bulk formulation : CLIO
25   USE sbcblk_core     ! surface boundary condition: bulk formulation : CORE
26   USE sbcice_if       ! surface boundary condition: ice-if sea-ice model
27   USE sbcice_lim      ! surface boundary condition: LIM 3.0 sea-ice model
28   USE sbcice_lim_2    ! surface boundary condition: LIM 2.0 sea-ice model
29   USE sbccpl          ! surface boundary condition: coupled florulation
30   USE cpl_oasis3, ONLY:lk_cpl      ! are we in coupled mode?
31   USE sbcssr          ! surface boundary condition: sea surface restoring
32   USE sbcrnf          ! surface boundary condition: runoffs
33   USE sbcfwb          ! surface boundary condition: freshwater budget
34   USE closea          ! closed sea
35
36   USE prtctl          ! Print control                    (prt_ctl routine)
37   USE restart         ! ocean restart
38   USE iom
39   USE in_out_manager  ! I/O manager
40
41   IMPLICIT NONE
42   PRIVATE
43
44   PUBLIC   sbc        ! routine called by step.F90
45   PUBLIC   sbc_init   ! routine called by opa.F90
46   
47   INTEGER ::   nsbc   ! type of surface boundary condition (deduced from namsbc informations)
48     
49   !! * Substitutions
50#  include "domzgr_substitute.h90"
51   !!----------------------------------------------------------------------
52   !! NEMO/OPA 3.3 , LOCEAN-IPSL (2010)
53   !! $Id$
54   !! Software governed by the CeCILL licence (modipsl/doc/NEMO_CeCILL.txt)
55   !!----------------------------------------------------------------------
56
57CONTAINS
58
59   SUBROUTINE sbc_init
60      !!---------------------------------------------------------------------
61      !!                    ***  ROUTINE sbc_init ***
62      !!
63      !! ** Purpose :   Initialisation of the ocean surface boundary computation
64      !!
65      !! ** Method  :   Read the namsbc namelist and set derived parameters
66      !!
67      !! ** Action  : - read namsbc parameters
68      !!              - nsbc: type of sbc
69      !!----------------------------------------------------------------------
70      INTEGER ::   icpt      ! temporary integer
71      !!
72      NAMELIST/namsbc/ nn_fsbc, ln_ana, ln_flx, ln_blk_clio, ln_blk_core, ln_cpl,   &
73         &             nn_ice , ln_dm2dc, ln_rnf, ln_ssr, nn_fwb, nn_ico_cpl
74      !!----------------------------------------------------------------------
75
76      IF(lwp) THEN
77         WRITE(numout,*)
78         WRITE(numout,*) 'sbc_init : surface boundary condition setting'
79         WRITE(numout,*) '~~~~~~~~ '
80      ENDIF
81
82      REWIND( numnam )                   ! Read Namelist namsbc
83      READ  ( numnam, namsbc )
84
85      ! overwrite namelist parameter using CPP key information
86!!gm here no overwrite, test all option via namelist change: require more incore memory
87!!gm  IF( lk_sbc_cpl       ) THEN   ;   ln_cpl      = .TRUE.   ;   ELSE   ;   ln_cpl      = .FALSE.   ;   ENDIF
88
89      IF( Agrif_Root() ) THEN
90        IF( lk_lim2 )            nn_ice      = 2
91        IF( lk_lim3 )            nn_ice      = 3
92      ENDIF
93      !
94      IF( cp_cfg == 'gyre' ) THEN
95          ln_ana      = .TRUE.   
96          nn_ice      =   0
97      ENDIF
98     
99      ! Control print
100      IF(lwp) THEN
101         WRITE(numout,*) '        Namelist namsbc (partly overwritten with CPP key setting)'
102         WRITE(numout,*) '           frequency update of sbc (and ice)             nn_fsbc     = ', nn_fsbc
103         WRITE(numout,*) '           Type of sbc : '
104         WRITE(numout,*) '              analytical formulation                     ln_ana      = ', ln_ana
105         WRITE(numout,*) '              flux       formulation                     ln_flx      = ', ln_flx
106         WRITE(numout,*) '              CLIO bulk  formulation                     ln_blk_clio = ', ln_blk_clio
107         WRITE(numout,*) '              CLIO bulk  formulation                     ln_blk_core = ', ln_blk_core
108         WRITE(numout,*) '              coupled    formulation (T if key_sbc_cpl)  ln_cpl      = ', ln_cpl
109         WRITE(numout,*) '           Misc. options of sbc : '
110         WRITE(numout,*) '              ice management in the sbc (=0/1/2/3)       nn_ice      = ', nn_ice 
111         WRITE(numout,*) '              ice-ocean stress computation (=0/1/2)      nn_ico_cpl  = ', nn_ico_cpl
112         WRITE(numout,*) '              daily mean to diurnal cycle qsr            ln_dm2dc    = ', ln_dm2dc 
113         WRITE(numout,*) '              runoff / runoff mouths                     ln_rnf      = ', ln_rnf
114         WRITE(numout,*) '              Sea Surface Restoring on SST and/or SSS    ln_ssr      = ', ln_ssr
115         WRITE(numout,*) '              FreshWater Budget control  (=0/1/2)        nn_fwb      = ', nn_fwb
116         WRITE(numout,*) '              closed sea (=0/1) (set in namdom)          nn_closea   = ', nn_closea
117      ENDIF
118
119      IF( .NOT. ln_rnf ) THEN                      ! no specific treatment in vicinity of river mouths
120         ln_rnf_mouth  = .false.                     
121         nkrnf         = 0
122         rnfmsk  (:,:) = 0.e0
123         rnfmsk_z(:)   = 0.e0
124      ENDIF
125      IF( nn_ice == 0  )   fr_i(:,:) = 0.e0        ! no ice in the domain, ice fraction is always zero
126
127      !                                            ! restartability   
128      IF( MOD( nitend - nit000 + 1, nn_fsbc) /= 0 .OR.   &
129          MOD( nstock             , nn_fsbc) /= 0 ) THEN
130         WRITE(ctmp1,*) 'experiment length (', nitend - nit000 + 1, ') or nstock (', nstock,   &
131            &           ' is NOT a multiple of nn_fsbc (', nn_fsbc, ')'
132         CALL ctl_stop( ctmp1, 'Impossible to properly do model restart' )
133      ENDIF
134      !
135      IF( MOD( rday, REAL(nn_fsbc, wp) * rdt ) /= 0 )   &
136         &  CALL ctl_warn( 'nn_fsbc is NOT a multiple of the number of time steps in a day' )
137      !
138      IF( nn_ice == 2 .AND. .NOT.( ln_blk_clio .OR. ln_blk_core .OR. lk_cpl ) )   &
139         &   CALL ctl_stop( 'sea-ice model requires a bulk formulation or coupled configuration' )
140     
141      ! Choice of the Surface Boudary Condition (set nsbc)
142      icpt = 0
143      IF( ln_ana          ) THEN   ;   nsbc =  1   ; icpt = icpt + 1   ;   ENDIF       ! analytical      formulation
144      IF( ln_flx          ) THEN   ;   nsbc =  2   ; icpt = icpt + 1   ;   ENDIF       ! flux            formulation
145      IF( ln_blk_clio     ) THEN   ;   nsbc =  3   ; icpt = icpt + 1   ;   ENDIF       ! CLIO bulk       formulation
146      IF( ln_blk_core     ) THEN   ;   nsbc =  4   ; icpt = icpt + 1   ;   ENDIF       ! CORE bulk       formulation
147      IF( ln_cpl          ) THEN   ;   nsbc =  5   ; icpt = icpt + 1   ;   ENDIF       ! Coupled         formulation
148      IF( cp_cfg == 'gyre') THEN   ;   nsbc =  0                       ;   ENDIF       ! GYRE analytical formulation
149      IF( lk_esopa        )            nsbc = -1                                       ! esopa test, ALL formulations
150
151      IF( icpt /= 1 .AND. .NOT.lk_esopa ) THEN
152         WRITE(numout,*)
153         WRITE(numout,*) '           E R R O R in setting the sbc, one and only one namelist/CPP key option '
154         WRITE(numout,*) '                     must be choosen. You choose ', icpt, ' option(s)'
155         WRITE(numout,*) '                     We stop'
156         nstop = nstop + 1
157      ENDIF
158      IF(lwp) THEN
159         WRITE(numout,*)
160         IF( nsbc == -1 )   WRITE(numout,*) '              ESOPA test All surface boundary conditions'
161         IF( nsbc ==  0 )   WRITE(numout,*) '              GYRE analytical formulation'
162         IF( nsbc ==  1 )   WRITE(numout,*) '              analytical formulation'
163         IF( nsbc ==  2 )   WRITE(numout,*) '              flux formulation'
164         IF( nsbc ==  3 )   WRITE(numout,*) '              CLIO bulk formulation'
165         IF( nsbc ==  4 )   WRITE(numout,*) '              CORE bulk formulation'
166         IF( nsbc ==  5 )   WRITE(numout,*) '              coupled formulation'
167      ENDIF
168      !
169   END SUBROUTINE sbc_init
170
171
172   SUBROUTINE sbc( kt )
173      !!---------------------------------------------------------------------
174      !!                    ***  ROUTINE sbc  ***
175      !!             
176      !! ** Purpose :   provide at each time-step the ocean surface boundary
177      !!                condition (momentum, heat and freshwater fluxes)
178      !!
179      !! ** Method  :   blah blah  to be written ?????????
180      !!                CAUTION : never mask the surface stress field (tke sbc)
181      !!
182      !! ** Action  : - set the ocean surface boundary condition at before and now
183      !!                time step, i.e. 
184      !!                utau_b, vtau_b, qns_b, qsr_b, emp_n, emps_b, qrp_b, erp_b
185      !!                utau  , vtau  , qns  , qsr  , emp  , emps  , qrp  , erp
186      !!              - updte the ice fraction : fr_i
187      !!----------------------------------------------------------------------
188      INTEGER, INTENT(in) ::   kt       ! ocean time step
189      !!---------------------------------------------------------------------
190
191      !                                            ! ---------------------------------------- !
192      IF( kt /= nit000 ) THEN                      !          Swap of forcing fields          !
193         !                                         ! ---------------------------------------- !
194         utau_b(:,:) = utau(:,:)                         ! Swap the ocean forcing fields
195         vtau_b(:,:) = vtau(:,:)                         ! (except at nit000 where before fields
196         qns_b (:,:) = qns (:,:)                         !  are set the end of the routine)
197         qsr_b (:,:) = qsr (:,:)
198         emp_b (:,:) = emp (:,:)
199         emps_b(:,:) = emps(:,:)
200         ! - ML -
201         sbc_trd_hc_b(:,:) = sbc_trd_hc_n(:,:)
202         qsr_trd_hc_b(:,:,:) = qsr_trd_hc_n(:,:,:)
203         IF ( .NOT. lk_vvl )  sbc_trd_sc_b(:,:) = sbc_trd_sc_n(:,:)
204         
205      ENDIF
206
207      !                                            ! ---------------------------------------- !
208      !                                            !        forcing field computation         !
209      !                                            ! ---------------------------------------- !
210
211      CALL iom_setkt( kt + nn_fsbc - 1 )                 ! in sbc, iom_put is called every nn_fsbc time step
212      !
213      CALL sbc_ssm( kt )                                 ! ocean sea surface variables (sst_m, sss_m, ssu_m, ssv_m)
214      !                                                  ! averaged over nf_sbc time-step
215
216                                                   !==  sbc formulation  ==!
217                                                           
218      SELECT CASE( nsbc )                                ! Compute ocean surface boundary condition
219      !                                                  ! (i.e. utau,vtau, qns, qsr, emp, emps)
220      CASE(  0 )   ;   CALL sbc_gyre    ( kt )                    ! analytical formulation : GYRE configuration
221      CASE(  1 )   ;   CALL sbc_ana     ( kt )                    ! analytical formulation : uniform sbc
222      CASE(  2 )   ;   CALL sbc_flx     ( kt )                    ! flux formulation
223      CASE(  3 )   ;   CALL sbc_blk_clio( kt )                    ! bulk formulation : CLIO for the ocean
224      CASE(  4 )   ;   CALL sbc_blk_core( kt )                    ! bulk formulation : CORE for the ocean
225      CASE(  5 )   ;   CALL sbc_cpl_rcv ( kt, nn_fsbc, nn_ice )   ! coupled formulation
226      CASE( -1 )                               
227                       CALL sbc_ana     ( kt )                    ! ESOPA, test ALL the formulations
228                       CALL sbc_gyre    ( kt )                    !
229                       CALL sbc_flx     ( kt )                    !
230                       CALL sbc_blk_clio( kt )                    !
231                       CALL sbc_blk_core( kt )                    !
232                       CALL sbc_cpl_rcv ( kt, nn_fsbc, nn_ice )   !
233      END SELECT
234
235      !                                            !==  Misc. Options  ==!
236
237!!gm  IF( ln_dm2dc       )   CALL sbc_dcy( kt )                 ! Daily mean qsr distributed over the Diurnal Cycle
238     
239      SELECT CASE( nn_ice )                                     ! Update heat and freshwater fluxes over sea-ice areas
240      CASE(  1 )   ;       CALL sbc_ice_if   ( kt )                   ! Ice-cover climatology ("Ice-if" model)
241         !                                                     
242      CASE(  2 )   ;       CALL sbc_ice_lim_2( kt, nsbc )             ! LIM 2.0 ice model
243         !                                                     
244      CASE(  3 )   ;       CALL sbc_ice_lim  ( kt, nsbc, nn_ico_cpl)  ! LIM 3.0 ice model
245      END SELECT                                             
246
247      IF( ln_rnf       )   CALL sbc_rnf( kt )                   ! add runoffs to fresh water fluxes
248 
249      IF( ln_ssr       )   CALL sbc_ssr( kt )                   ! add SST/SSS damping term
250
251      IF( nn_fwb  /= 0 )   CALL sbc_fwb( kt, nn_fwb, nn_fsbc )  ! control the freshwater budget
252
253      IF( nclosea == 1 )   CALL sbc_clo( kt )                   ! treatment of closed sea in the model domain
254      !                                                         ! (update freshwater fluxes)
255      !
256      !                                                ! ---------------------------------------- !
257      IF( kt == nit000 ) THEN                          !   set the forcing field at nit000 - 1    !
258         !                                             ! ---------------------------------------- !
259         IF( ln_rstart .AND.    &                               !* Restart: read in restart file
260            & iom_varid( numror, 'utau_b', ldstop = .FALSE. ) > 0 ) THEN
261            IF(lwp) WRITE(numout,*) '          nit000-1 surface forcing fields red in the restart file'
262            CALL iom_get( numror, jpdom_autoglo, 'utau_b', utau_b )   ! before i-stress  (U-point)
263            CALL iom_get( numror, jpdom_autoglo, 'vtau_b', vtau_b )   ! before j-stress  (V-point)
264            CALL iom_get( numror, jpdom_autoglo, 'qns_b' , qns_b  )   ! before non solar heat flux (T-point)
265            CALL iom_get( numror, jpdom_autoglo, 'qsr_b' , qsr_b  )   ! before     solar heat flux (T-point)
266            CALL iom_get( numror, jpdom_autoglo, 'emp_b' , emp_b  )   ! before     freshwater flux (T-point)
267            CALL iom_get( numror, jpdom_autoglo, 'emps_b', emp_b  )   ! before C/D freshwater flux (T-point)
268            ! - ML -
269            CALL iom_get( numror, jpdom_autoglo, 'sbc_trd_hc_b', sbc_trd_hc_b )   ! before heat content sbc trend
270            CALL iom_get( numror, jpdom_autoglo, 'qsr_trd_hc_b', qsr_trd_hc_b )   ! before heat content trend due to Qsr flux
271            IF ( .NOT. lk_vvl ) THEN
272               CALL iom_get( numror, jpdom_autoglo, 'sbc_trd_sc_b', sbc_trd_sc_b )   ! before salt content sbc trend
273            ENDIF
274            !
275         ELSE                                                   !* no restart: set from nit000 values
276            IF(lwp) WRITE(numout,*) '          nit000-1 surface forcing fields set to nit000'
277            utau_b(:,:) = utau(:,:) 
278            vtau_b(:,:) = vtau(:,:)
279            qns_b (:,:) = qns (:,:)
280            qsr_b (:,:) = qsr (:,:)
281            emp_b (:,:) = emp (:,:)
282            emps_b(:,:) = emps(:,:)
283         ENDIF
284      ENDIF
285
286      !                                                ! ---------------------------------------- !
287      IF( lrst_oce ) THEN                              !      Write in the ocean restart file     !
288         !                                             ! ---------------------------------------- !
289         IF(lwp) WRITE(numout,*)
290         IF(lwp) WRITE(numout,*) 'sbc : ocean surface forcing fields written in ocean restart file ',   &
291            &                    'at it= ', kt,' date= ', ndastp
292         IF(lwp) WRITE(numout,*) '~~~~'
293         CALL iom_rstput( kt, nitrst, numrow, 'utau_b' , utau_b )    !
294         CALL iom_rstput( kt, nitrst, numrow, 'vtau_b' , vtau_b )
295         CALL iom_rstput( kt, nitrst, numrow, 'qns_b'  , qns_b  )
296         CALL iom_rstput( kt, nitrst, numrow, 'qsr_b'  , qsr_b  )
297         CALL iom_rstput( kt, nitrst, numrow, 'emp_b'  , emp_b  )
298         CALL iom_rstput( kt, nitrst, numrow, 'emps_b' , emps_b )
299         ! - ML -
300         CALL iom_rstput( kt, nitrst, numrow, 'sbc_trd_hc_b', sbc_trd_hc_b )
301         CALL iom_rstput( kt, nitrst, numrow, 'qsr_trd_hc_b', qsr_trd_hc_b )
302         IF ( .NOT. lk_vvl ) THEN
303            CALL iom_rstput( kt, nitrst, numrow, 'sbc_trd_sc_b', sbc_trd_sc_b )
304         ENDIF
305         !
306      ENDIF
307
308      !                                                ! ---------------------------------------- !
309      !                                                !        Outputs and control print         !
310      !                                                ! ---------------------------------------- !
311      IF( MOD( kt-1, nn_fsbc ) == 0 ) THEN
312         CALL iom_put( "emp"    , emp       )                   ! upward water flux
313         CALL iom_put( "emps"   , emps      )                   ! c/d water flux
314         CALL iom_put( "qns+qsr", qns + qsr )                   ! total heat flux   (caution if ln_dm2dc=true, to be
315         CALL iom_put( "qns"    , qns       )                   ! solar heat flux    moved after the call to iom_setkt)
316         CALL iom_put( "qsr"    ,       qsr )                   ! solar heat flux    moved after the call to iom_setkt)
317         IF( nn_ice > 0 )   CALL iom_put( "ice_cover", fr_i )   ! ice fraction
318      ENDIF
319      !
320      CALL iom_setkt( kt )           ! iom_put outside of sbc is called at every time step
321      !
322      CALL iom_put( "utau", utau )   ! i-wind stress   (stress can be updated at
323      CALL iom_put( "vtau", vtau )   ! j-wind stress    each time step in sea-ice)
324      CALL iom_put( "taum", taum )   ! wind stress module
325      CALL iom_put( "wspd", wndm )   ! wind speed  module
326      !
327      IF(ln_ctl) THEN         ! print mean trends (used for debugging)
328         CALL prt_ctl(tab2d_1=fr_i   , clinfo1=' fr_i - : ', mask1=tmask, ovlap=1 )
329         CALL prt_ctl(tab2d_1=emp    , clinfo1=' emp  - : ', mask1=tmask, ovlap=1 )
330         CALL prt_ctl(tab2d_1=emps   , clinfo1=' emps - : ', mask1=tmask, ovlap=1 )
331         CALL prt_ctl(tab2d_1=qns    , clinfo1=' qns  - : ', mask1=tmask, ovlap=1 )
332         CALL prt_ctl(tab2d_1=qsr    , clinfo1=' qsr  - : ', mask1=tmask, ovlap=1 )
333         CALL prt_ctl(tab3d_1=tmask  , clinfo1=' tmask  : ', mask1=tmask, ovlap=1, kdim=jpk )
334         CALL prt_ctl(tab3d_1=tn     , clinfo1=' sst  - : ', mask1=tmask, ovlap=1, kdim=1   )
335         CALL prt_ctl(tab3d_1=sn     , clinfo1=' sss  - : ', mask1=tmask, ovlap=1, kdim=1   )
336         CALL prt_ctl(tab2d_1=utau   , clinfo1=' utau - : ', mask1=umask,                      &
337            &         tab2d_2=vtau   , clinfo2=' vtau - : ', mask2=vmask, ovlap=1 )
338      ENDIF
339      !
340   END SUBROUTINE sbc
341
342   !!======================================================================
343END MODULE sbcmod
Note: See TracBrowser for help on using the repository browser.