New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traadv_muscl2.F90 in branches/DEV_r2006_merge_TRA_TRC/NEMO/OPA_SRC/TRA – NEMO

source: branches/DEV_r2006_merge_TRA_TRC/NEMO/OPA_SRC/TRA/traadv_muscl2.F90 @ 2034

Last change on this file since 2034 was 2034, checked in by cetlod, 14 years ago

cosmetic changes
  • Property svn:eol-style set to native
  • Property svn:keywords set to Id
File size: 15.2 KB
Line 
1MODULE traadv_muscl2
2   !!==============================================================================
3   !!                       ***  MODULE  traadv_muscl2  ***
4   !! Ocean  tracers:  horizontal & vertical advective trend
5   !!==============================================================================
6   !! History :  1.0  !  2002-06  (G. Madec) from traadv_muscl
7   !!            3.2  !  2010-05  (C. Ethe, G. Madec)  merge TRC-TRA + switch from velocity to transport
8   !!----------------------------------------------------------------------
9
10   !!----------------------------------------------------------------------
11   !!   tra_adv_muscl2 : update the tracer trend with the horizontal
12   !!                    and vertical advection trends using MUSCL2 scheme
13   !!----------------------------------------------------------------------
14   USE oce             ! ocean dynamics and active tracers
15   USE dom_oce         ! ocean space and time domain
16   USE trdmod_oce      ! tracers trends
17   USE trdtra          ! tracers trends
18   USE in_out_manager  ! I/O manager
19   USE dynspg_oce      ! choice/control of key cpp for surface pressure gradient
20   USE trabbl          ! tracers: bottom boundary layer
21   USE lib_mpp         ! distribued memory computing
22   USE lbclnk          ! ocean lateral boundary condition (or mpp link)
23   USE diaptr          ! poleward transport diagnostics
24
25
26   IMPLICIT NONE
27   PRIVATE
28
29   !! * Accessibility
30   PUBLIC tra_adv_muscl2        ! routine called by step.F90
31
32   LOGICAL  :: l_trd       ! flag to compute trends
33
34   !! * Substitutions
35#  include "domzgr_substitute.h90"
36#  include "vectopt_loop_substitute.h90"
37   !!----------------------------------------------------------------------
38   !! NEMO/OPA 3.3 , LOCEAN-IPSL (2010)
39   !! $Id$
40   !! Software governed by the CeCILL licence (modipsl/doc/NEMO_CeCILL.txt)
41   !!----------------------------------------------------------------------
42
43CONTAINS
44
45   SUBROUTINE tra_adv_muscl2( kt, cdtype, pun, pvn, pwn, &
46      &                                   ptb, ptn, pta, kjpt   )
47      !!----------------------------------------------------------------------
48      !!                   ***  ROUTINE tra_adv_muscl2  ***
49      !!
50      !! ** Purpose :   Compute the now trend due to total advection of T and
51      !!      S using a MUSCL scheme (Monotone Upstream-centered Scheme for
52      !!      Conservation Laws) and add it to the general tracer trend.
53      !!
54      !! ** Method  : MUSCL scheme plus centered scheme at ocean boundaries
55      !!
56      !! ** Action  : - update (pta) with the now advective tracer trends
57      !!              - save trends
58      !!
59      !! References : Estubier, A., and M. Levy, Notes Techn. Pole de Modelisation
60      !!              IPSL, Sept. 2000 (http://www.lodyc.jussieu.fr/opa)
61      !!----------------------------------------------------------------------
62      !!* Module used
63      USE oce         , zwx => ua   ! use ua as workspace
64      USE oce         , zwy => va   ! use va as workspace
65      !!* Arguments
66      INTEGER         , INTENT(in   )                               ::   kt              ! ocean time-step index
67      CHARACTER(len=3), INTENT(in   )                               ::   cdtype          ! =TRA or TRC (tracer indicator)
68      INTEGER         , INTENT(in   )                               ::   kjpt            ! number of tracers
69      REAL(wp)        , INTENT(in   ), DIMENSION(jpi,jpj,jpk)       ::   pun, pvn, pwn   ! 3 ocean velocity components
70      REAL(wp)        , INTENT(in   ), DIMENSION(jpi,jpj,jpk,kjpt)  ::   ptb, ptn        ! before and now tracer fields
71      REAL(wp)        , INTENT(inout), DIMENSION(jpi,jpj,jpk,kjpt)  ::   pta           ! tracer trend
72      !!* Local declarations
73      INTEGER  ::   ji, jj, jk, jn   ! dummy loop indices
74      REAL(wp) ::   zu, z0u, zzwx
75      REAL(wp) ::   zv, z0v, zzwy
76      REAL(wp) ::   zw, z0w
77      REAL(wp) ::   ztra, zbtr, z2, zdt, zalpha
78      REAL(wp), DIMENSION (jpi,jpj,jpk) ::  zslpx, zslpy   ! 3D workspace
79      !!----------------------------------------------------------------------
80
81      IF( kt == nit000 .AND. lwp ) THEN
82         WRITE(numout,*)
83         WRITE(numout,*) 'tra_adv_muscl2 : MUSCL2 advection scheme'
84         WRITE(numout,*) '~~~~~~~~~~~~~~~'
85         !
86         l_trd = .FALSE.
87         IF( ( cdtype == 'TRA' .AND. l_trdtra ) .OR. ( cdtype == 'TRC' .AND. l_trdtrc ) ) l_trd = .TRUE.
88      ENDIF
89
90      IF( neuler == 0 .AND. kt == nit000 ) THEN   ;   z2 = 1.
91      ELSE                                        ;   z2 = 2.
92      ENDIF
93      !
94      !
95      DO jn = 1, kjpt                                            ! tracer loop
96         !                                                       ! ===========
97         ! I. Horizontal advective fluxes
98         ! ------------------------------
99         ! first guess of the slopes
100         zwx(:,:,jpk) = 0.e0   ;   zwy(:,:,jpk) = 0.e0        ! bottom values
101         ! interior values
102         DO jk = 1, jpkm1
103            DO jj = 1, jpjm1     
104               DO ji = 1, fs_jpim1   ! vector opt.
105                  zwx(ji,jj,jk) = umask(ji,jj,jk) * ( ptb(ji+1,jj,jk,jn) - ptb(ji,jj,jk,jn) )
106                  zwy(ji,jj,jk) = vmask(ji,jj,jk) * ( ptb(ji,jj+1,jk,jn) - ptb(ji,jj,jk,jn) )
107               END DO
108           END DO
109         END DO
110         !
111         CALL lbc_lnk( zwx, 'U', -1. )                        ! lateral boundary conditions on zwx, zwy   (changed sign)
112         CALL lbc_lnk( zwy, 'V', -1. )
113         !                                             !-- Slopes of tracer
114         zslpx(:,:,jpk) = 0.e0   ;   zslpy(:,:,jpk) = 0.e0    ! bottom values
115         DO jk = 1, jpkm1                                     ! interior values
116            DO jj = 2, jpj
117               DO ji = fs_2, jpi   ! vector opt.
118                  zslpx(ji,jj,jk) =                    ( zwx(ji,jj,jk) + zwx(ji-1,jj  ,jk) )   &
119                     &            * ( 0.25 + SIGN( 0.25, zwx(ji,jj,jk) * zwx(ji-1,jj  ,jk) ) )
120                  zslpy(ji,jj,jk) =                    ( zwy(ji,jj,jk) + zwy(ji  ,jj-1,jk) )   &
121                     &            * ( 0.25 + SIGN( 0.25, zwy(ji,jj,jk) * zwy(ji  ,jj-1,jk) ) )
122               END DO
123            END DO
124         END DO
125         !
126         DO jk = 1, jpkm1                                     ! Slopes limitation
127            DO jj = 2, jpj
128               DO ji = fs_2, jpi   ! vector opt.
129                  zslpx(ji,jj,jk) = SIGN( 1., zslpx(ji,jj,jk) ) * MIN(    ABS( zslpx(ji  ,jj,jk) ),   &
130                     &                                                 2.*ABS( zwx  (ji-1,jj,jk) ),   &
131                     &                                                 2.*ABS( zwx  (ji  ,jj,jk) ) )
132                  zslpy(ji,jj,jk) = SIGN( 1., zslpy(ji,jj,jk) ) * MIN(    ABS( zslpy(ji,jj  ,jk) ),   &
133                     &                                                 2.*ABS( zwy  (ji,jj-1,jk) ),   &
134                     &                                                 2.*ABS( zwy  (ji,jj  ,jk) ) )
135               END DO
136           END DO
137         END DO             ! interior values
138
139        !                                             !-- MUSCL horizontal advective fluxes
140         DO jk = 1, jpkm1                                     ! interior values
141            zdt  = z2 * rdttra(jk)
142            DO jj = 2, jpjm1
143               DO ji = fs_2, fs_jpim1   ! vector opt.
144                  ! MUSCL fluxes
145                  z0u = SIGN( 0.5, pun(ji,jj,jk) )
146                  zalpha = 0.5 - z0u
147                  zu  = z0u - 0.5 * pun(ji,jj,jk) * zdt / ( e1u(ji,jj) * e2u(ji,jj) * fse3u(ji,jj,jk) )
148                  zzwx = ptb(ji+1,jj,jk,jn) + zu * zslpx(ji+1,jj,jk)
149                  zzwy = ptb(ji  ,jj,jk,jn) + zu * zslpx(ji  ,jj,jk)
150                  zwx(ji,jj,jk) = pun(ji,jj,jk) * ( zalpha * zzwx + (1.-zalpha) * zzwy )
151                  !
152                  z0v = SIGN( 0.5, pvn(ji,jj,jk) )
153                  zalpha = 0.5 - z0v
154                  zv  = z0v - 0.5 * pvn(ji,jj,jk) * zdt / ( e1v(ji,jj) * e2v(ji,jj) * fse3v(ji,jj,jk) )
155                  zzwx = ptb(ji,jj+1,jk,jn) + zv * zslpy(ji,jj+1,jk)
156                  zzwy = ptb(ji,jj  ,jk,jn) + zv * zslpy(ji,jj  ,jk)
157                  zwy(ji,jj,jk) = pvn(ji,jj,jk) * ( zalpha * zzwx + (1.-zalpha) * zzwy )
158               END DO
159            END DO
160         END DO
161
162         !!  centered scheme at lateral b.C. if off-shore velocity
163         DO jk = 1, jpkm1
164            DO jj = 2, jpjm1
165               DO ji = fs_2, fs_jpim1   ! vector opt.
166                  IF( umask(ji,jj,jk) == 0. ) THEN
167                     IF( pun(ji+1,jj,jk) > 0. .AND. ji /= jpi ) THEN
168                        zwx(ji+1,jj,jk) = 0.5 * pun(ji+1,jj,jk) * ( ptn(ji+1,jj,jk,jn) + ptn(ji+2,jj,jk,jn) )
169                     ENDIF
170                     IF( pun(ji-1,jj,jk) < 0. ) THEN
171                        zwx(ji-1,jj,jk) = 0.5 * pun(ji-1,jj,jk) * ( ptn(ji-1,jj,jk,jn) + ptn(ji,jj,jk,jn) ) 
172                     ENDIF
173                  ENDIF
174                  IF( vmask(ji,jj,jk) == 0. ) THEN
175                     IF( pvn(ji,jj+1,jk) > 0. .AND. jj /= jpj ) THEN
176                        zwy(ji,jj+1,jk) = 0.5 * pvn(ji,jj+1,jk) * ( ptn(ji,jj+1,jk,jn) + ptn(ji,jj+2,jk,jn) )
177                     ENDIF
178                     IF( pvn(ji,jj-1,jk) < 0. ) THEN
179                        zwy(ji,jj-1,jk) = 0.5 * pvn(ji,jj-1,jk) * ( ptn(ji,jj-1,jk,jn) + ptn(ji,jj,jk,jn) ) 
180                     ENDIF
181                  ENDIF
182               END DO
183            END DO
184         END DO
185
186         !                                                    ! lateral boundary conditions on zwx, zwy   (changed sign)
187         CALL lbc_lnk( zwx, 'U', -1. )   ;   CALL lbc_lnk( zwy, 'V', -1. )
188         ! Tracer flux divergence at t-point added to the general trend
189         DO jk = 1, jpkm1
190            DO jj = 2, jpjm1
191               DO ji = fs_2, fs_jpim1   ! vector opt.
192                  zbtr = 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
193                  ! horizontal advective trends
194                  ztra = - zbtr * ( zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
195                  &               + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  ) )
196                  ! added to the general tracer trends
197                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) + ztra
198               END DO
199           END DO
200         END DO
201         !                                 ! trend diagnostics (contribution of upstream fluxes)
202         IF( l_trd ) THEN
203            CALL trd_tra( kt, cdtype, jn, jpt_trd_xad, zwx, pun, ptb(:,:,:,jn) )
204            CALL trd_tra( kt, cdtype, jn, jpt_trd_yad, zwy, pvn, ptb(:,:,:,jn) )
205         END IF
206
207         !                                 ! "Poleward" heat and salt transports (contribution of upstream fluxes)
208         IF( cdtype == 'TRA' .AND. ln_diaptr .AND. ( MOD( kt, nf_ptr ) == 0 ) ) THEN
209            IF( lk_zco ) THEN
210               DO jk = 1, jpkm1
211                  DO jj = 2, jpjm1
212                     DO ji = fs_2, fs_jpim1   ! vector opt.
213                       zwy(ji,jj,jk) = zwy(ji,jj,jk) * fse3v(ji,jj,jk)
214                     END DO
215                  END DO
216               END DO
217            ENDIF
218            IF( jn == jp_tem )  pht_adv(:) = ptr_vj( zwy(:,:,:) )
219            IF( jn == jp_sal )  pst_adv(:) = ptr_vj( zwy(:,:,:) )
220         ENDIF
221
222         ! II. Vertical advective fluxes
223         ! -----------------------------
224         !                                             !-- first guess of the slopes
225         zwx (:,:, 1 ) = 0.e0    ;    zwx (:,:,jpk) = 0.e0    ! surface & bottom boundary conditions
226         DO jk = 2, jpkm1                                     ! interior values
227            zwx(:,:,jk) = tmask(:,:,jk) * ( ptb(:,:,jk-1,jn) - ptb(:,:,jk,jn) )
228         END DO
229
230         !                                             !-- Slopes of tracer
231         zslpx(:,:,1) = 0.e0                                  ! surface values
232         DO jk = 2, jpkm1                                     ! interior value
233            DO jj = 1, jpj
234               DO ji = 1, jpi
235                  zslpx(ji,jj,jk) =                    ( zwx(ji,jj,jk) + zwx(ji,jj,jk+1) )   &
236                     &            * ( 0.25 + SIGN( 0.25, zwx(ji,jj,jk) * zwx(ji,jj,jk+1) ) )
237               END DO
238            END DO
239         END DO
240         !                                             !-- Slopes limitation
241         DO jk = 2, jpkm1                                     ! interior values
242            DO jj = 1, jpj
243               DO ji = 1, jpi
244                  zslpx(ji,jj,jk) = SIGN( 1., zslpx(ji,jj,jk) ) * MIN(    ABS( zslpx(ji,jj,jk  ) ),   &
245                     &                                                 2.*ABS( zwx  (ji,jj,jk+1) ),   &
246                     &                                                 2.*ABS( zwx  (ji,jj,jk  ) )  )
247               END DO
248            END DO
249         END DO
250         !                                             !-- vertical advective flux
251         !                                                    ! surface values  (bottom already set to zero)
252         IF( lk_vvl ) THEN    ;   zwx(:,:, 1 ) = 0.e0                      !  variable volume
253         ELSE                 ;   zwx(:,:, 1 ) = pwn(:,:,1) * ptb(:,:,1,jn)   ! linear free surface
254         ENDIF
255         !
256         DO jk = 1, jpkm1                                     ! interior values
257            zdt  = z2 * rdttra(jk)
258            DO jj = 2, jpjm1
259               DO ji = fs_2, fs_jpim1   ! vector opt.
260                  zbtr = 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3w(ji,jj,jk+1) )
261                  z0w = SIGN( 0.5, pwn(ji,jj,jk+1) )
262                  zalpha = 0.5 + z0w
263                  zw  = z0w - 0.5 * pwn(ji,jj,jk+1) * zdt * zbtr
264                  zzwx = ptb(ji,jj,jk+1,jn) + zw * zslpx(ji,jj,jk+1)
265                  zzwy = ptb(ji,jj,jk  ,jn) + zw * zslpx(ji,jj,jk  )
266                  zwx(ji,jj,jk+1) = pwn(ji,jj,jk+1) * ( zalpha * zzwx + (1.-zalpha) * zzwy )
267               END DO
268            END DO
269         END DO
270         !
271         DO jk = 2, jpkm1        ! centered near the bottom
272            DO jj = 2, jpjm1
273               DO ji = fs_2, fs_jpim1   ! vector opt.
274                  IF( tmask(ji,jj,jk+1) == 0. ) THEN
275                     IF( pwn(ji,jj,jk) > 0. ) THEN
276                        zwx(ji,jj,jk) = 0.5 * pwn(ji,jj,jk) * ( ptn(ji,jj,jk-1,jn) + ptn(ji,jj,jk,jn) ) 
277                     ENDIF
278                  ENDIF
279               END DO
280            END DO
281         END DO
282
283         ! Compute & add the vertical advective trend
284         DO jk = 1, jpkm1
285            DO jj = 2, jpjm1     
286               DO ji = fs_2, fs_jpim1   ! vector opt.
287                  zbtr = 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
288                  ! vertical advective trends
289                  ztra = - zbtr * ( zwx(ji,jj,jk) - zwx(ji,jj,jk+1) )
290                  ! added to the general tracer trends
291                  pta(ji,jj,jk,jn) =  pta(ji,jj,jk,jn) + ztra
292               END DO
293            END DO
294         END DO
295
296         ! Save the vertical advective trends for diagnostic
297         ! -------------------------------------------------
298         !                                 ! trend diagnostics (contribution of upstream fluxes)
299         IF( l_trd )  CALL trd_tra( kt, cdtype, jn, jpt_trd_zad, zwx, pwn, ptb(:,:,:,jn) )
300         !
301      ENDDO
302      !
303   END SUBROUTINE tra_adv_muscl2
304
305   !!======================================================================
306END MODULE traadv_muscl2
Note: See TracBrowser for help on using the repository browser.