New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traadv_muscl2.F90 in branches/DEV_r2006_merge_TRA_TRC/NEMO/OPA_SRC/TRA – NEMO

source: branches/DEV_r2006_merge_TRA_TRC/NEMO/OPA_SRC/TRA/traadv_muscl2.F90 @ 2083

Last change on this file since 2083 was 2083, checked in by cetlod, 14 years ago

correction of minor bugs
  • Property svn:eol-style set to native
  • Property svn:keywords set to Id
File size: 15.3 KB
Line 
1MODULE traadv_muscl2
2   !!==============================================================================
3   !!                       ***  MODULE  traadv_muscl2  ***
4   !! Ocean  tracers:  horizontal & vertical advective trend
5   !!==============================================================================
6   !! History :  1.0  !  2002-06  (G. Madec) from traadv_muscl
7   !!            3.2  !  2010-05  (C. Ethe, G. Madec)  merge TRC-TRA + switch from velocity to transport
8   !!----------------------------------------------------------------------
9
10   !!----------------------------------------------------------------------
11   !!   tra_adv_muscl2 : update the tracer trend with the horizontal
12   !!                    and vertical advection trends using MUSCL2 scheme
13   !!----------------------------------------------------------------------
14   USE oce             ! ocean dynamics and active tracers
15   USE dom_oce         ! ocean space and time domain
16   USE trdmod_oce      ! tracers trends
17   USE trdtra          ! tracers trends
18   USE in_out_manager  ! I/O manager
19   USE dynspg_oce      ! choice/control of key cpp for surface pressure gradient
20   USE trabbl          ! tracers: bottom boundary layer
21   USE lib_mpp         ! distribued memory computing
22   USE lbclnk          ! ocean lateral boundary condition (or mpp link)
23   USE diaptr          ! poleward transport diagnostics
24   USE trc_oce         ! share passive tracers/Ocean variables
25
26
27   IMPLICIT NONE
28   PRIVATE
29
30   !! * Accessibility
31   PUBLIC tra_adv_muscl2        ! routine called by step.F90
32
33   LOGICAL  :: l_trd       ! flag to compute trends
34
35   !! * Substitutions
36#  include "domzgr_substitute.h90"
37#  include "vectopt_loop_substitute.h90"
38   !!----------------------------------------------------------------------
39   !! NEMO/OPA 3.3 , LOCEAN-IPSL (2010)
40   !! $Id$
41   !! Software governed by the CeCILL licence (modipsl/doc/NEMO_CeCILL.txt)
42   !!----------------------------------------------------------------------
43
44CONTAINS
45
46   SUBROUTINE tra_adv_muscl2( kt, cdtype, p2dt, pun, pvn, pwn, &
47      &                                         ptb, ptn, pta, kjpt   )
48      !!----------------------------------------------------------------------
49      !!                   ***  ROUTINE tra_adv_muscl2  ***
50      !!
51      !! ** Purpose :   Compute the now trend due to total advection of T and
52      !!      S using a MUSCL scheme (Monotone Upstream-centered Scheme for
53      !!      Conservation Laws) and add it to the general tracer trend.
54      !!
55      !! ** Method  : MUSCL scheme plus centered scheme at ocean boundaries
56      !!
57      !! ** Action  : - update (pta) with the now advective tracer trends
58      !!              - save trends
59      !!
60      !! References : Estubier, A., and M. Levy, Notes Techn. Pole de Modelisation
61      !!              IPSL, Sept. 2000 (http://www.lodyc.jussieu.fr/opa)
62      !!----------------------------------------------------------------------
63      !!* Module used
64      USE oce         , zwx => ua   ! use ua as workspace
65      USE oce         , zwy => va   ! use va as workspace
66      !!* Arguments
67      INTEGER         , INTENT(in   )                               ::   kt              ! ocean time-step index
68      CHARACTER(len=3), INTENT(in   )                               ::   cdtype          ! =TRA or TRC (tracer indicator)
69      INTEGER         , INTENT(in   )                               ::   kjpt            ! number of tracers
70      REAL(wp)        , INTENT(in   ), DIMENSION(jpk)               ::   p2dt            ! vertical profile of tracer time-step
71      REAL(wp)        , INTENT(in   ), DIMENSION(jpi,jpj,jpk)       ::   pun, pvn, pwn   ! 3 ocean velocity components
72      REAL(wp)        , INTENT(in   ), DIMENSION(jpi,jpj,jpk,kjpt)  ::   ptb, ptn        ! before and now tracer fields
73      REAL(wp)        , INTENT(inout), DIMENSION(jpi,jpj,jpk,kjpt)  ::   pta           ! tracer trend
74      !!* Local declarations
75      INTEGER  ::   ji, jj, jk, jn   ! dummy loop indices
76      REAL(wp) ::   zu, z0u, zzwx
77      REAL(wp) ::   zv, z0v, zzwy
78      REAL(wp) ::   zw, z0w
79      REAL(wp) ::   ztra, zbtr, zdt, zalpha
80      REAL(wp), DIMENSION (jpi,jpj,jpk) ::  zslpx, zslpy   ! 3D workspace
81      !!----------------------------------------------------------------------
82
83      IF( ( cdtype == 'TRA' .AND. kt == nit000 ) .OR. ( cdtype == 'TRC' .AND. kt == nittrc000 ) )  THEN
84         WRITE(numout,*)
85         WRITE(numout,*) 'tra_adv_muscl2 : MUSCL2 advection scheme on ', cdtype
86         WRITE(numout,*) '~~~~~~~~~~~~~~~'
87         !
88         l_trd = .FALSE.
89         IF( ( cdtype == 'TRA' .AND. l_trdtra ) .OR. ( cdtype == 'TRC' .AND. l_trdtrc ) ) l_trd = .TRUE.
90      ENDIF
91
92      !
93      DO jn = 1, kjpt                                            ! tracer loop
94         !                                                       ! ===========
95         ! I. Horizontal advective fluxes
96         ! ------------------------------
97         ! first guess of the slopes
98         zwx(:,:,jpk) = 0.e0   ;   zwy(:,:,jpk) = 0.e0        ! bottom values
99         ! interior values
100         DO jk = 1, jpkm1
101            DO jj = 1, jpjm1     
102               DO ji = 1, fs_jpim1   ! vector opt.
103                  zwx(ji,jj,jk) = umask(ji,jj,jk) * ( ptb(ji+1,jj,jk,jn) - ptb(ji,jj,jk,jn) )
104                  zwy(ji,jj,jk) = vmask(ji,jj,jk) * ( ptb(ji,jj+1,jk,jn) - ptb(ji,jj,jk,jn) )
105               END DO
106           END DO
107         END DO
108         !
109         CALL lbc_lnk( zwx, 'U', -1. )                        ! lateral boundary conditions on zwx, zwy   (changed sign)
110         CALL lbc_lnk( zwy, 'V', -1. )
111         !                                             !-- Slopes of tracer
112         zslpx(:,:,jpk) = 0.e0   ;   zslpy(:,:,jpk) = 0.e0    ! bottom values
113         DO jk = 1, jpkm1                                     ! interior values
114            DO jj = 2, jpj
115               DO ji = fs_2, jpi   ! vector opt.
116                  zslpx(ji,jj,jk) =                    ( zwx(ji,jj,jk) + zwx(ji-1,jj  ,jk) )   &
117                     &            * ( 0.25 + SIGN( 0.25, zwx(ji,jj,jk) * zwx(ji-1,jj  ,jk) ) )
118                  zslpy(ji,jj,jk) =                    ( zwy(ji,jj,jk) + zwy(ji  ,jj-1,jk) )   &
119                     &            * ( 0.25 + SIGN( 0.25, zwy(ji,jj,jk) * zwy(ji  ,jj-1,jk) ) )
120               END DO
121            END DO
122         END DO
123         !
124         DO jk = 1, jpkm1                                     ! Slopes limitation
125            DO jj = 2, jpj
126               DO ji = fs_2, jpi   ! vector opt.
127                  zslpx(ji,jj,jk) = SIGN( 1., zslpx(ji,jj,jk) ) * MIN(    ABS( zslpx(ji  ,jj,jk) ),   &
128                     &                                                 2.*ABS( zwx  (ji-1,jj,jk) ),   &
129                     &                                                 2.*ABS( zwx  (ji  ,jj,jk) ) )
130                  zslpy(ji,jj,jk) = SIGN( 1., zslpy(ji,jj,jk) ) * MIN(    ABS( zslpy(ji,jj  ,jk) ),   &
131                     &                                                 2.*ABS( zwy  (ji,jj-1,jk) ),   &
132                     &                                                 2.*ABS( zwy  (ji,jj  ,jk) ) )
133               END DO
134           END DO
135         END DO             ! interior values
136
137        !                                             !-- MUSCL horizontal advective fluxes
138         DO jk = 1, jpkm1                                     ! interior values
139            zdt  = p2dt(jk)
140            DO jj = 2, jpjm1
141               DO ji = fs_2, fs_jpim1   ! vector opt.
142                  ! MUSCL fluxes
143                  z0u = SIGN( 0.5, pun(ji,jj,jk) )
144                  zalpha = 0.5 - z0u
145                  zu  = z0u - 0.5 * pun(ji,jj,jk) * zdt / ( e1u(ji,jj) * e2u(ji,jj) * fse3u(ji,jj,jk) )
146                  zzwx = ptb(ji+1,jj,jk,jn) + zu * zslpx(ji+1,jj,jk)
147                  zzwy = ptb(ji  ,jj,jk,jn) + zu * zslpx(ji  ,jj,jk)
148                  zwx(ji,jj,jk) = pun(ji,jj,jk) * ( zalpha * zzwx + (1.-zalpha) * zzwy )
149                  !
150                  z0v = SIGN( 0.5, pvn(ji,jj,jk) )
151                  zalpha = 0.5 - z0v
152                  zv  = z0v - 0.5 * pvn(ji,jj,jk) * zdt / ( e1v(ji,jj) * e2v(ji,jj) * fse3v(ji,jj,jk) )
153                  zzwx = ptb(ji,jj+1,jk,jn) + zv * zslpy(ji,jj+1,jk)
154                  zzwy = ptb(ji,jj  ,jk,jn) + zv * zslpy(ji,jj  ,jk)
155                  zwy(ji,jj,jk) = pvn(ji,jj,jk) * ( zalpha * zzwx + (1.-zalpha) * zzwy )
156               END DO
157            END DO
158         END DO
159
160         !!  centered scheme at lateral b.C. if off-shore velocity
161         DO jk = 1, jpkm1
162            DO jj = 2, jpjm1
163               DO ji = fs_2, fs_jpim1   ! vector opt.
164                  IF( umask(ji,jj,jk) == 0. ) THEN
165                     IF( pun(ji+1,jj,jk) > 0. .AND. ji /= jpi ) THEN
166                        zwx(ji+1,jj,jk) = 0.5 * pun(ji+1,jj,jk) * ( ptn(ji+1,jj,jk,jn) + ptn(ji+2,jj,jk,jn) )
167                     ENDIF
168                     IF( pun(ji-1,jj,jk) < 0. ) THEN
169                        zwx(ji-1,jj,jk) = 0.5 * pun(ji-1,jj,jk) * ( ptn(ji-1,jj,jk,jn) + ptn(ji,jj,jk,jn) ) 
170                     ENDIF
171                  ENDIF
172                  IF( vmask(ji,jj,jk) == 0. ) THEN
173                     IF( pvn(ji,jj+1,jk) > 0. .AND. jj /= jpj ) THEN
174                        zwy(ji,jj+1,jk) = 0.5 * pvn(ji,jj+1,jk) * ( ptn(ji,jj+1,jk,jn) + ptn(ji,jj+2,jk,jn) )
175                     ENDIF
176                     IF( pvn(ji,jj-1,jk) < 0. ) THEN
177                        zwy(ji,jj-1,jk) = 0.5 * pvn(ji,jj-1,jk) * ( ptn(ji,jj-1,jk,jn) + ptn(ji,jj,jk,jn) ) 
178                     ENDIF
179                  ENDIF
180               END DO
181            END DO
182         END DO
183
184         !                                                    ! lateral boundary conditions on zwx, zwy   (changed sign)
185         CALL lbc_lnk( zwx, 'U', -1. )   ;   CALL lbc_lnk( zwy, 'V', -1. )
186         ! Tracer flux divergence at t-point added to the general trend
187         DO jk = 1, jpkm1
188            DO jj = 2, jpjm1
189               DO ji = fs_2, fs_jpim1   ! vector opt.
190                  zbtr = 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
191                  ! horizontal advective trends
192                  ztra = - zbtr * ( zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
193                  &               + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  ) )
194                  ! added to the general tracer trends
195                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) + ztra
196               END DO
197           END DO
198         END DO
199         !                                 ! trend diagnostics (contribution of upstream fluxes)
200         IF( l_trd ) THEN
201            CALL trd_tra( kt, cdtype, jn, jptra_trd_xad, zwx, pun, ptb(:,:,:,jn) )
202            CALL trd_tra( kt, cdtype, jn, jptra_trd_yad, zwy, pvn, ptb(:,:,:,jn) )
203         END IF
204
205         !                                 ! "Poleward" heat and salt transports (contribution of upstream fluxes)
206         IF( cdtype == 'TRA' .AND. ln_diaptr .AND. ( MOD( kt, nf_ptr ) == 0 ) ) THEN
207            IF( lk_zco ) THEN
208               DO jk = 1, jpkm1
209                  DO jj = 2, jpjm1
210                     DO ji = fs_2, fs_jpim1   ! vector opt.
211                       zwy(ji,jj,jk) = zwy(ji,jj,jk) * fse3v(ji,jj,jk)
212                     END DO
213                  END DO
214               END DO
215            ENDIF
216            IF( jn == jp_tem )  pht_adv(:) = ptr_vj( zwy(:,:,:) )
217            IF( jn == jp_sal )  pst_adv(:) = ptr_vj( zwy(:,:,:) )
218         ENDIF
219
220         ! II. Vertical advective fluxes
221         ! -----------------------------
222         !                                             !-- first guess of the slopes
223         zwx (:,:, 1 ) = 0.e0    ;    zwx (:,:,jpk) = 0.e0    ! surface & bottom boundary conditions
224         DO jk = 2, jpkm1                                     ! interior values
225            zwx(:,:,jk) = tmask(:,:,jk) * ( ptb(:,:,jk-1,jn) - ptb(:,:,jk,jn) )
226         END DO
227
228         !                                             !-- Slopes of tracer
229         zslpx(:,:,1) = 0.e0                                  ! surface values
230         DO jk = 2, jpkm1                                     ! interior value
231            DO jj = 1, jpj
232               DO ji = 1, jpi
233                  zslpx(ji,jj,jk) =                    ( zwx(ji,jj,jk) + zwx(ji,jj,jk+1) )   &
234                     &            * ( 0.25 + SIGN( 0.25, zwx(ji,jj,jk) * zwx(ji,jj,jk+1) ) )
235               END DO
236            END DO
237         END DO
238         !                                             !-- Slopes limitation
239         DO jk = 2, jpkm1                                     ! interior values
240            DO jj = 1, jpj
241               DO ji = 1, jpi
242                  zslpx(ji,jj,jk) = SIGN( 1., zslpx(ji,jj,jk) ) * MIN(    ABS( zslpx(ji,jj,jk  ) ),   &
243                     &                                                 2.*ABS( zwx  (ji,jj,jk+1) ),   &
244                     &                                                 2.*ABS( zwx  (ji,jj,jk  ) )  )
245               END DO
246            END DO
247         END DO
248         !                                             !-- vertical advective flux
249         !                                                    ! surface values  (bottom already set to zero)
250         IF( lk_vvl ) THEN    ;   zwx(:,:, 1 ) = 0.e0                      !  variable volume
251         ELSE                 ;   zwx(:,:, 1 ) = pwn(:,:,1) * ptb(:,:,1,jn)   ! linear free surface
252         ENDIF
253         !
254         DO jk = 1, jpkm1                                     ! interior values
255            zdt  = p2dt(jk)
256            DO jj = 2, jpjm1
257               DO ji = fs_2, fs_jpim1   ! vector opt.
258                  zbtr = 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3w(ji,jj,jk+1) )
259                  z0w = SIGN( 0.5, pwn(ji,jj,jk+1) )
260                  zalpha = 0.5 + z0w
261                  zw  = z0w - 0.5 * pwn(ji,jj,jk+1) * zdt * zbtr
262                  zzwx = ptb(ji,jj,jk+1,jn) + zw * zslpx(ji,jj,jk+1)
263                  zzwy = ptb(ji,jj,jk  ,jn) + zw * zslpx(ji,jj,jk  )
264                  zwx(ji,jj,jk+1) = pwn(ji,jj,jk+1) * ( zalpha * zzwx + (1.-zalpha) * zzwy )
265               END DO
266            END DO
267         END DO
268         !
269         DO jk = 2, jpkm1        ! centered near the bottom
270            DO jj = 2, jpjm1
271               DO ji = fs_2, fs_jpim1   ! vector opt.
272                  IF( tmask(ji,jj,jk+1) == 0. ) THEN
273                     IF( pwn(ji,jj,jk) > 0. ) THEN
274                        zwx(ji,jj,jk) = 0.5 * pwn(ji,jj,jk) * ( ptn(ji,jj,jk-1,jn) + ptn(ji,jj,jk,jn) ) 
275                     ENDIF
276                  ENDIF
277               END DO
278            END DO
279         END DO
280
281         ! Compute & add the vertical advective trend
282         DO jk = 1, jpkm1
283            DO jj = 2, jpjm1     
284               DO ji = fs_2, fs_jpim1   ! vector opt.
285                  zbtr = 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
286                  ! vertical advective trends
287                  ztra = - zbtr * ( zwx(ji,jj,jk) - zwx(ji,jj,jk+1) )
288                  ! added to the general tracer trends
289                  pta(ji,jj,jk,jn) =  pta(ji,jj,jk,jn) + ztra
290               END DO
291            END DO
292         END DO
293
294         ! Save the vertical advective trends for diagnostic
295         ! -------------------------------------------------
296         !                                 ! trend diagnostics (contribution of upstream fluxes)
297         IF( l_trd )  CALL trd_tra( kt, cdtype, jn, jptra_trd_zad, zwx, pwn, ptb(:,:,:,jn) )
298         !
299      ENDDO
300      !
301   END SUBROUTINE tra_adv_muscl2
302
303   !!======================================================================
304END MODULE traadv_muscl2
Note: See TracBrowser for help on using the repository browser.