New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traadv_tvd.F90 in branches/DEV_r2006_merge_TRA_TRC/NEMO/OPA_SRC/TRA – NEMO

source: branches/DEV_r2006_merge_TRA_TRC/NEMO/OPA_SRC/TRA/traadv_tvd.F90 @ 2034

Last change on this file since 2034 was 2034, checked in by cetlod, 14 years ago

cosmetic changes
  • Property svn:eol-style set to native
  • Property svn:keywords set to Id
File size: 17.5 KB
Line 
1MODULE traadv_tvd
2   !!==============================================================================
3   !!                       ***  MODULE  traadv_tvd  ***
4   !! Ocean  tracers:  horizontal & vertical advective trend
5   !!==============================================================================
6   !! History :       !  95-12  (L. Mortier)  Original code
7   !!                 !  00-01  (H. Loukos)  adapted to ORCA
8   !!                 !  00-10  (MA Foujols E.Kestenare)  include file not routine
9   !!                 !  00-12  (E. Kestenare M. Levy)  fix bug in trtrd indexes
10   !!                 !  01-07  (E. Durand G. Madec)  adaptation to ORCA config
11   !!            8.5  !  02-06  (G. Madec)  F90: Free form and module
12   !!            9.0  !  04-01  (A. de Miranda, G. Madec, J.M. Molines ): advective bbl
13   !!            9.0  !  08-04  (S. Cravatte) add the i-, j- & k- trends computation
14   !!            " "  !  09-11  (V. Garnier) Surface pressure gradient organization
15   !!            3.3  !  10-05  (C. Ethe, G. Madec)  merge TRC-TRA + switch from velocity to transport
16   !!----------------------------------------------------------------------
17
18
19   !!----------------------------------------------------------------------
20   !!   tra_adv_tvd  : update the tracer trend with the horizontal
21   !!                  and vertical advection trends using a TVD scheme
22   !!   nonosc       : compute monotonic tracer fluxes by a nonoscillatory
23   !!                  algorithm
24   !!----------------------------------------------------------------------
25   USE oce             ! ocean dynamics and active tracers
26   USE dom_oce         ! ocean space and time domain
27   USE trdmod_oce      ! tracers trends
28   USE trdtra      ! tracers trends
29   USE in_out_manager  ! I/O manager
30   USE dynspg_oce      ! choice/control of key cpp for surface pressure gradient
31   USE lib_mpp
32   USE lbclnk          ! ocean lateral boundary condition (or mpp link)
33   USE diaptr          ! poleward transport diagnostics
34
35
36   IMPLICIT NONE
37   PRIVATE
38
39   PUBLIC   tra_adv_tvd    ! routine called by step.F90
40
41   LOGICAL  :: l_trd       ! flag to compute trends
42
43   !! * Substitutions
44#  include "domzgr_substitute.h90"
45#  include "vectopt_loop_substitute.h90"
46   !!----------------------------------------------------------------------
47   !! NEMO/OPA 3.3 , LOCEAN-IPSL (2010)
48   !! $Id$
49   !! Software governed by the CeCILL licence (modipsl/doc/NEMO_CeCILL.txt)
50   !!----------------------------------------------------------------------
51
52CONTAINS
53
54   SUBROUTINE tra_adv_tvd ( kt, cdtype, pun, pvn, pwn, &
55      &                                 ptb, ptn, pta, kjpt   )
56      !!----------------------------------------------------------------------
57      !!                  ***  ROUTINE tra_adv_tvd  ***
58      !!
59      !! **  Purpose :   Compute the now trend due to total advection of
60      !!       tracers and add it to the general trend of tracer equations
61      !!
62      !! **  Method  :   TVD scheme, i.e. 2nd order centered scheme with
63      !!       corrected flux (monotonic correction)
64      !!       note: - this advection scheme needs a leap-frog time scheme
65      !!
66      !! ** Action : - update (pta) with the now advective tracer trends
67      !!             - save the trends
68      !!----------------------------------------------------------------------
69      USE oce         , zwx => ua   ! use ua as workspace
70      USE oce         , zwy => va   ! use va as workspace
71      !!
72      INTEGER         , INTENT(in   )                               ::   kt              ! ocean time-step index
73      CHARACTER(len=3), INTENT(in   )                               ::   cdtype          ! =TRA or TRC (tracer indicator)
74      INTEGER         , INTENT(in   )                               ::   kjpt            ! number of tracers
75      REAL(wp)        , INTENT(in   ), DIMENSION(jpi,jpj,jpk)       ::   pun, pvn, pwn   ! 3 ocean velocity components
76      REAL(wp)        , INTENT(in   ), DIMENSION(jpi,jpj,jpk,kjpt)  ::   ptb, ptn        ! before and now tracer fields
77      REAL(wp)        , INTENT(inout), DIMENSION(jpi,jpj,jpk,kjpt)  ::   pta           ! tracer trend
78      !!
79      INTEGER  ::   ji, jj, jk, jn          ! dummy loop indices 
80      REAL(wp) ::   &
81         z2, z2dtt, zbtr, ztra,              &  ! temporary scalar
82         zfp_ui, zfp_vj, zfp_wk,             &  !    "         "
83         zfm_ui, zfm_vj, zfm_wk                 !    "         "
84      REAL(wp), DIMENSION (jpi,jpj,jpk) ::   zwi, zwz   ! temporary workspace
85      REAL(wp), DIMENSION (:,:,:), ALLOCATABLE :: ztrdx, ztrdy, ztrdz
86      !!----------------------------------------------------------------------
87
88      zwi(:,:,:) = 0.e0
89
90      IF( kt == nit000 .AND. lwp ) THEN
91         WRITE(numout,*)
92         WRITE(numout,*) 'tra_adv_tvd : TVD advection scheme'
93         WRITE(numout,*) '~~~~~~~~~~~'
94         !
95         l_trd = .FALSE.
96         IF( ( cdtype == 'TRA' .AND. l_trdtra ) .OR. ( cdtype == 'TRC' .AND. l_trdtrc ) ) l_trd = .TRUE.
97      ENDIF
98      !
99      IF( l_trd )  THEN
100        ALLOCATE( ztrdx(jpi,jpj,jpk) )      ;      ztrdx(:,:,:) = 0.
101        ALLOCATE( ztrdy(jpi,jpj,jpk) )      ;      ztrdy(:,:,:) = 0.
102        ALLOCATE( ztrdz(jpi,jpj,jpk) )      ;      ztrdz(:,:,:) = 0.
103      END IF
104      !
105      IF( neuler == 0 .AND. kt == nit000 ) THEN   ;    z2 = 1.
106      ELSE                                        ;    z2 = 2.
107      ENDIF
108      !
109      !                                                          ! ===========
110      DO jn = 1, kjpt                                            ! tracer loop
111         !                                                       ! ===========
112         ! 1. Bottom value : flux set to zero
113         ! ----------------------------------
114         zwx(:,:,jpk) = 0.e0    ;    zwz(:,:,jpk) = 0.e0
115         zwy(:,:,jpk) = 0.e0    ;    zwi(:,:,jpk) = 0.e0
116
117         ! 2. upstream advection with initial mass fluxes & intermediate update
118         ! --------------------------------------------------------------------
119         ! upstream tracer flux in the i and j direction
120         DO jk = 1, jpkm1
121            DO jj = 1, jpjm1
122               DO ji = 1, fs_jpim1   ! vector opt.
123                  ! upstream scheme
124                  zfp_ui = pun(ji,jj,jk) + ABS( pun(ji,jj,jk) )
125                  zfm_ui = pun(ji,jj,jk) - ABS( pun(ji,jj,jk) )
126                  zfp_vj = pvn(ji,jj,jk) + ABS( pvn(ji,jj,jk) )
127                  zfm_vj = pvn(ji,jj,jk) - ABS( pvn(ji,jj,jk) )
128                  zwx(ji,jj,jk) = 0.5 * ( zfp_ui * ptb(ji,jj,jk,jn) + zfm_ui * ptb(ji+1,jj  ,jk,jn) )
129                  zwy(ji,jj,jk) = 0.5 * ( zfp_vj * ptb(ji,jj,jk,jn) + zfm_vj * ptb(ji  ,jj+1,jk,jn) )
130               END DO
131            END DO
132         END DO
133
134         ! upstream tracer flux in the k direction
135         ! Surface value
136         IF( lk_vvl ) THEN   ;   zwz(:,:, 1 ) = 0.e0                         ! volume variable
137         ELSE                ;   zwz(:,:, 1 ) = pwn(:,:,1) * ptb(:,:,1,jn)   ! linear free surface
138         ENDIF
139         ! Interior value
140         DO jk = 2, jpkm1
141            DO jj = 1, jpj
142               DO ji = 1, jpi
143                  zfp_wk = pwn(ji,jj,jk) + ABS( pwn(ji,jj,jk) )
144                  zfm_wk = pwn(ji,jj,jk) - ABS( pwn(ji,jj,jk) )
145                  zwz(ji,jj,jk) = 0.5 * ( zfp_wk * ptb(ji,jj,jk,jn) + zfm_wk * ptb(ji,jj,jk-1,jn) )
146               END DO
147            END DO
148         END DO
149
150         ! total advective trend
151         DO jk = 1, jpkm1
152            z2dtt = z2 * rdttra(jk)
153            DO jj = 2, jpjm1
154               DO ji = fs_2, fs_jpim1   ! vector opt.
155                  zbtr = 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
156                  ! total intermediate advective trends
157                  ztra = - zbtr * (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
158                     &             + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )   &
159                     &             + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1) )
160                  ! update and guess with monotonic sheme
161                  pta(ji,jj,jk,jn) =   pta(ji,jj,jk,jn)         + ztra
162                  zwi(ji,jj,jk)    = ( ptb(ji,jj,jk,jn) + z2dtt * ztra ) * tmask(ji,jj,jk)
163               END DO
164            END DO
165         END DO
166         !                             ! Lateral boundary conditions on zwi  (unchanged sign)
167         CALL lbc_lnk( zwi, 'T', 1. ) 
168
169         !                                 ! trend diagnostics (contribution of upstream fluxes)
170         IF( l_trd )  THEN 
171            ! store intermediate advective trends
172            ztrdx(:,:,:) = zwx(:,:,:)   ;    ztrdy(:,:,:) = zwy(:,:,:)  ;   ztrdz(:,:,:) = zwz(:,:,:)
173         END IF
174         !                                 ! "Poleward" heat and salt transports (contribution of upstream fluxes)
175         IF( cdtype == 'TRA' .AND. ln_diaptr .AND. ( MOD( kt, nf_ptr ) == 0 ) ) THEN 
176           IF( jn == jp_tem )  pht_adv(:) = ptr_vj( zwy(:,:,:) )
177           IF( jn == jp_sal )  pst_adv(:) = ptr_vj( zwy(:,:,:) )
178         ENDIF
179
180         ! 3. antidiffusive flux : high order minus low order
181         ! --------------------------------------------------
182         ! antidiffusive flux on i and j
183         DO jk = 1, jpkm1
184            DO jj = 1, jpjm1
185               DO ji = 1, fs_jpim1   ! vector opt.
186                  zwx(ji,jj,jk) = 0.5 * pun(ji,jj,jk) * ( ptn(ji,jj,jk,jn) + ptn(ji+1,jj,jk,jn) ) - zwx(ji,jj,jk)
187                  zwy(ji,jj,jk) = 0.5 * pvn(ji,jj,jk) * ( ptn(ji,jj,jk,jn) + ptn(ji,jj+1,jk,jn) ) - zwy(ji,jj,jk)
188               END DO
189            END DO
190         END DO
191     
192         ! antidiffusive flux on k
193         ! Surface value
194         zwz(:,:,1) = 0.e0
195         ! Interior value
196         DO jk = 2, jpkm1
197            DO jj = 1, jpj
198               DO ji = 1, jpi
199                  zwz(ji,jj,jk) = 0.5 * pwn(ji,jj,jk) * ( ptn(ji,jj,jk,jn) + ptn(ji,jj,jk-1,jn) ) - zwz(ji,jj,jk)
200               END DO
201            END DO
202         END DO
203
204         ! Lateral bondary conditions
205         CALL lbc_lnk( zwx, 'U', -1. )
206         CALL lbc_lnk( zwy, 'V', -1. )
207         CALL lbc_lnk( zwz, 'W',  1. )
208
209         ! 4. monotonicity algorithm
210         ! -------------------------
211         CALL nonosc( ptb(:,:,:,jn), zwx, zwy, zwz, zwi, z2 )
212
213
214         ! 5. final trend with corrected fluxes
215         ! ------------------------------------
216         DO jk = 1, jpkm1
217            DO jj = 2, jpjm1
218               DO ji = fs_2, fs_jpim1   ! vector opt. 
219                  zbtr = 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
220                  ! total advective trends
221                  ztra = - zbtr * (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
222                     &             + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )   &
223                     &             + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1) )
224                  ! add them to the general tracer trends
225                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) + ztra
226               END DO
227            END DO
228         END DO
229
230         !                                 ! trend diagnostics (contribution of upstream fluxes)
231         IF( l_trd )  THEN
232            ztrdx(:,:,:) = ztrdx(:,:,:) + zwx(:,:,:)  ! <<< Add to previously computed
233            ztrdy(:,:,:) = ztrdy(:,:,:) + zwy(:,:,:)  ! <<< Add to previously computed
234            ztrdz(:,:,:) = ztrdz(:,:,:) + zwz(:,:,:)  ! <<< Add to previously computed
235           
236            CALL trd_tra( kt, cdtype, jn, jpt_trd_xad, ztrdx, pun, ptn(:,:,:,jn) )   
237            CALL trd_tra( kt, cdtype, jn, jpt_trd_yad, ztrdy, pvn, ptn(:,:,:,jn) ) 
238            CALL trd_tra( kt, cdtype, jn, jpt_trd_zad, ztrdz, pwn, ptn(:,:,:,jn) ) 
239         END IF
240         !                                 ! "Poleward" heat and salt transports (contribution of upstream fluxes)
241         IF( cdtype == 'TRA' .AND. ln_diaptr .AND. ( MOD( kt, nf_ptr ) == 0 ) ) THEN 
242           IF( jn == jp_tem )  pht_adv(:) = ptr_vj( zwy(:,:,:) ) + pht_adv(:)
243           IF( jn == jp_sal )  pst_adv(:) = ptr_vj( zwy(:,:,:) ) + pst_adv(:)
244         ENDIF
245         !
246      ENDDO
247      !
248      IF( l_trd )  THEN
249        DEALLOCATE( ztrdx )     ;     DEALLOCATE( ztrdy )     ;      DEALLOCATE( ztrdz ) 
250      END IF
251      !
252   END SUBROUTINE tra_adv_tvd
253
254
255   SUBROUTINE nonosc( pbef, paa, pbb, pcc, paft, prdt )
256      !!---------------------------------------------------------------------
257      !!                    ***  ROUTINE nonosc  ***
258      !!     
259      !! **  Purpose :   compute monotonic tracer fluxes from the upstream
260      !!       scheme and the before field by a nonoscillatory algorithm
261      !!
262      !! **  Method  :   ... ???
263      !!       warning : pbef and paft must be masked, but the boundaries
264      !!       conditions on the fluxes are not necessary zalezak (1979)
265      !!       drange (1995) multi-dimensional forward-in-time and upstream-
266      !!       in-space based differencing for fluid
267      !!----------------------------------------------------------------------
268      REAL(wp), INTENT( in ) ::   prdt   ! ???
269      REAL(wp), DIMENSION (jpi,jpj,jpk), INTENT( in    ) ::   &
270         pbef,                            & ! before field
271         paft                               ! after field
272      REAL(wp), DIMENSION (jpi,jpj,jpk), INTENT( inout ) ::   &
273         paa,                             & ! monotonic flux in the i direction
274         pbb,                             & ! monotonic flux in the j direction
275         pcc                                ! monotonic flux in the k direction
276      !!
277      INTEGER ::   ji, jj, jk               ! dummy loop indices
278      INTEGER ::   ikm1
279      REAL(wp), DIMENSION (jpi,jpj,jpk) ::   zbetup, zbetdo
280      REAL(wp), DIMENSION (jpi,jpj,jpk) ::   zbup, zbdo
281      REAL(wp) ::   zpos, zneg, zbt, za, zb, zc, zbig, zrtrn, z2dtt
282      REAL(wp) ::   zau, zbu, zcu, zav, zbv, zcv
283      REAL(wp) ::   zup, zdo
284      !!----------------------------------------------------------------------
285
286      zbig = 1.e+40
287      zrtrn = 1.e-15
288      zbetup(:,:,jpk) = 0.e0   ;   zbetdo(:,:,jpk) = 0.e0
289
290
291      ! Search local extrema
292      ! --------------------
293      ! max/min of pbef & paft with large negative/positive value (-/+zbig) inside land
294      zbup = MAX( pbef * tmask - zbig * ( 1.e0 - tmask ),   &
295         &        paft * tmask - zbig * ( 1.e0 - tmask )  )
296      zbdo = MIN( pbef * tmask + zbig * ( 1.e0 - tmask ),   &
297         &        paft * tmask + zbig * ( 1.e0 - tmask )  )
298
299      DO jk = 1, jpkm1
300         ikm1 = MAX(jk-1,1)
301         z2dtt = prdt * rdttra(jk)
302         DO jj = 2, jpjm1
303            DO ji = fs_2, fs_jpim1   ! vector opt.
304
305               ! search maximum in neighbourhood
306               zup = MAX(  zbup(ji  ,jj  ,jk  ),   &
307                  &        zbup(ji-1,jj  ,jk  ), zbup(ji+1,jj  ,jk  ),   &
308                  &        zbup(ji  ,jj-1,jk  ), zbup(ji  ,jj+1,jk  ),   &
309                  &        zbup(ji  ,jj  ,ikm1), zbup(ji  ,jj  ,jk+1)  )
310
311               ! search minimum in neighbourhood
312               zdo = MIN(  zbdo(ji  ,jj  ,jk  ),   &
313                  &        zbdo(ji-1,jj  ,jk  ), zbdo(ji+1,jj  ,jk  ),   &
314                  &        zbdo(ji  ,jj-1,jk  ), zbdo(ji  ,jj+1,jk  ),   &
315                  &        zbdo(ji  ,jj  ,ikm1), zbdo(ji  ,jj  ,jk+1)  )
316
317               ! positive part of the flux
318               zpos = MAX( 0., paa(ji-1,jj  ,jk  ) ) - MIN( 0., paa(ji  ,jj  ,jk  ) )   &
319                  & + MAX( 0., pbb(ji  ,jj-1,jk  ) ) - MIN( 0., pbb(ji  ,jj  ,jk  ) )   &
320                  & + MAX( 0., pcc(ji  ,jj  ,jk+1) ) - MIN( 0., pcc(ji  ,jj  ,jk  ) )
321
322               ! negative part of the flux
323               zneg = MAX( 0., paa(ji  ,jj  ,jk  ) ) - MIN( 0., paa(ji-1,jj  ,jk  ) )   &
324                  & + MAX( 0., pbb(ji  ,jj  ,jk  ) ) - MIN( 0., pbb(ji  ,jj-1,jk  ) )   &
325                  & + MAX( 0., pcc(ji  ,jj  ,jk  ) ) - MIN( 0., pcc(ji  ,jj  ,jk+1) )
326
327               ! up & down beta terms
328               zbt = e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) / z2dtt
329               zbetup(ji,jj,jk) = ( zup            - paft(ji,jj,jk) ) / ( zpos + zrtrn ) * zbt
330               zbetdo(ji,jj,jk) = ( paft(ji,jj,jk) - zdo            ) / ( zneg + zrtrn ) * zbt
331            END DO
332         END DO
333      END DO
334
335      ! lateral boundary condition on zbetup & zbetdo   (unchanged sign)
336      CALL lbc_lnk( zbetup, 'T', 1. )
337      CALL lbc_lnk( zbetdo, 'T', 1. )
338
339
340      ! 3. monotonic flux in the i & j direction (paa & pbb)
341      ! ----------------------------------------
342      DO jk = 1, jpkm1
343         DO jj = 2, jpjm1
344            DO ji = fs_2, fs_jpim1   ! vector opt.
345               zau = MIN( 1.e0, zbetdo(ji,jj,jk), zbetup(ji+1,jj,jk) )
346               zbu = MIN( 1.e0, zbetup(ji,jj,jk), zbetdo(ji+1,jj,jk) )
347               zcu =       ( 0.5  + SIGN( 0.5 , paa(ji,jj,jk) ) )
348               paa(ji,jj,jk) = paa(ji,jj,jk) * ( zcu * zau + ( 1.e0 - zcu) * zbu )
349
350               zav = MIN( 1.e0, zbetdo(ji,jj,jk), zbetup(ji,jj+1,jk) )
351               zbv = MIN( 1.e0, zbetup(ji,jj,jk), zbetdo(ji,jj+1,jk) )
352               zcv =       ( 0.5  + SIGN( 0.5 , pbb(ji,jj,jk) ) )
353               pbb(ji,jj,jk) = pbb(ji,jj,jk) * ( zcv * zav + ( 1.e0 - zcv) * zbv )
354
355      ! monotonic flux in the k direction, i.e. pcc
356      ! -------------------------------------------
357               za = MIN( 1., zbetdo(ji,jj,jk+1), zbetup(ji,jj,jk) )
358               zb = MIN( 1., zbetup(ji,jj,jk+1), zbetdo(ji,jj,jk) )
359               zc =       ( 0.5  + SIGN( 0.5 , pcc(ji,jj,jk+1) ) )
360               pcc(ji,jj,jk+1) = pcc(ji,jj,jk+1) * ( zc * za + ( 1.e0 - zc) * zb )
361            END DO
362         END DO
363      END DO
364
365      ! lateral boundary condition on paa, pbb, pcc
366      CALL lbc_lnk( paa, 'U', -1. )      ! changed sign
367      CALL lbc_lnk( pbb, 'V', -1. )      ! changed sign
368      !
369   END SUBROUTINE nonosc
370
371   !!======================================================================
372END MODULE traadv_tvd
Note: See TracBrowser for help on using the repository browser.