New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p4zopt.F90 in branches/DEV_r2006_merge_TRA_TRC/NEMO/TOP_SRC/PISCES – NEMO

source: branches/DEV_r2006_merge_TRA_TRC/NEMO/TOP_SRC/PISCES/p4zopt.F90 @ 2038

Last change on this file since 2038 was 2038, checked in by cetlod, 14 years ago

Apply the merge to passive tracers, see ticket:693
  • Property svn:executable set to *
  • Property svn:keywords set to Id
File size: 10.1 KB
Line 
1MODULE p4zopt
2   !!======================================================================
3   !!                         ***  MODULE p4zopt  ***
4   !! TOP - PISCES : Compute the light availability in the water column
5   !!======================================================================
6   !! History :   1.0  !  2004     (O. Aumont) Original code
7   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
8   !!             3.2  !  2009-04  (C. Ethe, G. Madec)  optimisaion
9   !!----------------------------------------------------------------------
10#if defined  key_pisces
11   !!----------------------------------------------------------------------
12   !!   'key_pisces'                                       PISCES bio-model
13   !!----------------------------------------------------------------------
14   !!   p4z_opt       : light availability in the water column
15   !!----------------------------------------------------------------------
16   USE trc            ! tracer variables
17   USE oce_trc        ! tracer-ocean share variables
18   USE sms_pisces     ! Source Minus Sink of PISCES
19   USE iom
20
21   IMPLICIT NONE
22   PRIVATE
23
24   PUBLIC   p4z_opt   ! called in p4zbio.F90 module
25
26   REAL(wp), PUBLIC, DIMENSION(jpi,jpj,jpk) ::   etot, enano, ediat   !: PAR for phyto, nano and diat
27   REAL(wp), PUBLIC, DIMENSION(jpi,jpj,jpk) ::   emoy                 !: averaged PAR in the mixed layer
28
29   INTEGER  ::   nksrp   ! levels below which the light cannot penetrate ( depth larger than 391 m)
30   REAL(wp) ::   &
31      parlux = 0.43 / 3.e0
32
33   REAL(wp), DIMENSION(3,61), PUBLIC ::   xkrgb  !: tabulated attenuation coefficients for RGB absorption
34   
35   !!* Substitution
36#  include "top_substitute.h90"
37   !!----------------------------------------------------------------------
38   !! NEMO/TOP 2.0 , LOCEAN-IPSL (2007)
39   !! $Id$
40   !! Software governed by the CeCILL licence (modipsl/doc/NEMO_CeCILL.txt)
41   !!----------------------------------------------------------------------
42
43CONTAINS
44
45   SUBROUTINE p4z_opt(kt, jnt)
46      !!---------------------------------------------------------------------
47      !!                     ***  ROUTINE p4z_opt  ***
48      !!
49      !! ** Purpose :   Compute the light availability in the water column
50      !!              depending on the depth and the chlorophyll concentration
51      !!
52      !! ** Method  : - ???
53      !!---------------------------------------------------------------------
54      INTEGER, INTENT(in) ::   kt, jnt ! ocean time step
55      INTEGER  ::   ji, jj, jk, jc
56      INTEGER  ::   irgb
57      REAL(wp) ::   zchl, zxsi0r
58      REAL(wp) ::   zc0 , zc1 , zc2, zc3
59      REAL(wp), DIMENSION(jpi,jpj)     ::   zdepmoy, zetmp
60      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zekg, zekr, zekb
61      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   ze1 , ze2 , ze3, ze0
62      !!---------------------------------------------------------------------
63
64
65      !                                        !* tabulated attenuation coef.
66      IF( kt * jnt == nittrc000 ) THEN
67         !                                ! level of light extinction
68         nksrp = trc_oce_ext_lev( rn_si2, 0.33e2 )
69         IF(lwp) THEN
70           WRITE(numout,*)
71           WRITE(numout,*) ' level max of computation of qsr = ', nksrp, ' ref depth = ', gdepw_0(nksrp+1), ' m'
72         ENDIF
73!!         CALL trc_oce_rgb( xkrgb )     ! tabulated attenuation coefficients
74         CALL trc_oce_rgb_read( xkrgb )     ! tabulated attenuation coefficients
75         etot (:,:,:) = 0.e0
76         enano(:,:,:) = 0.e0
77         ediat(:,:,:) = 0.e0
78         IF( ln_qsr_bio ) etot3(:,:,:) = 0.e0
79      ENDIF
80
81
82!     Initialisation of variables used to compute PAR
83!     -----------------------------------------------
84      ze1 (:,:,jpk) = 0.e0
85      ze2 (:,:,jpk) = 0.e0
86      ze3 (:,:,jpk) = 0.e0
87
88      !                                        !* attenuation coef. function of Chlorophyll and wavelength (Red-Green-Blue)
89      DO jk = 1, jpkm1                         !  --------------------------------------------------------
90!CDIR NOVERRCHK
91         DO jj = 1, jpj
92!CDIR NOVERRCHK
93            DO ji = 1, jpi
94               zchl = ( trn(ji,jj,jk,jpnch) + trn(ji,jj,jk,jpdch) + rtrn ) * 1.e6
95               zchl = MIN(  10. , MAX( 0.03, zchl )  )
96               irgb = NINT( 41 + 20.* LOG10( zchl ) + rtrn )
97               !                                                         
98               zekb(ji,jj,jk) = xkrgb(1,irgb) * fse3t(ji,jj,jk)
99               zekg(ji,jj,jk) = xkrgb(2,irgb) * fse3t(ji,jj,jk)
100               zekr(ji,jj,jk) = xkrgb(3,irgb) * fse3t(ji,jj,jk)
101            END DO
102         END DO
103      END DO
104
105!!gm  Potential BUG  must discuss with Olivier about this implementation....
106!!gm           the questions are : - PAR at T-point or mean PAR over T-level....
107!!gm                               - shallow water: no penetration of light through the bottom....
108
109
110      !                                        !* Photosynthetically Available Radiation (PAR)
111      !                                        !  --------------------------------------
112!CDIR NOVERRCHK
113      DO jj = 1, jpj
114!CDIR NOVERRCHK
115         DO ji = 1, jpi
116            zc1 = parlux * qsr(ji,jj) * EXP( -0.5 * zekb(ji,jj,1) )
117            zc2 = parlux * qsr(ji,jj) * EXP( -0.5 * zekg(ji,jj,1) )
118            zc3 = parlux * qsr(ji,jj) * EXP( -0.5 * zekr(ji,jj,1) )
119            ze1  (ji,jj,1) = zc1
120            ze2  (ji,jj,1) = zc2
121            ze3  (ji,jj,1) = zc3
122            etot (ji,jj,1) = (       zc1 +        zc2 +       zc3 )
123            enano(ji,jj,1) = ( 2.1 * zc1 + 0.42 * zc2 + 0.4 * zc3 )
124            ediat(ji,jj,1) = ( 1.6 * zc1 + 0.69 * zc2 + 0.7 * zc3 )
125         END DO
126      END DO
127
128   
129      DO jk = 2, nksrp     
130!CDIR NOVERRCHK
131         DO jj = 1, jpj
132!CDIR NOVERRCHK
133            DO ji = 1, jpi
134               zc1 = ze1(ji,jj,jk-1) * EXP( -0.5 * ( zekb(ji,jj,jk-1) + zekb(ji,jj,jk) ) )
135               zc2 = ze2(ji,jj,jk-1) * EXP( -0.5 * ( zekg(ji,jj,jk-1) + zekg(ji,jj,jk) ) )
136               zc3 = ze3(ji,jj,jk-1) * EXP( -0.5 * ( zekr(ji,jj,jk-1) + zekr(ji,jj,jk) ) )
137               ze1  (ji,jj,jk) = zc1
138               ze2  (ji,jj,jk) = zc2
139               ze3  (ji,jj,jk) = zc3
140               etot (ji,jj,jk) = (       zc1 +        zc2 +       zc3 )
141               enano(ji,jj,jk) = ( 2.1 * zc1 + 0.42 * zc2 + 0.4 * zc3 )
142               ediat(ji,jj,jk) = ( 1.6 * zc1 + 0.69 * zc2 + 0.7 * zc3 )
143            END DO
144         END DO
145      END DO
146
147      IF( ln_qsr_bio ) THEN                    !* heat flux accros w-level (used in the dynamics)
148         !                                     !  ------------------------
149         zxsi0r = 1.e0 / rn_si0
150         !
151         ze0  (:,:,1) = rn_abs * qsr(:,:)
152         ze1  (:,:,1) = parlux * qsr(:,:)             ! surface value : separation in R-G-B + near surface
153         ze2  (:,:,1) = parlux * qsr(:,:)
154         ze3  (:,:,1) = parlux * qsr(:,:)
155         etot3(:,:,1) =          qsr(:,:) * tmask(:,:,1)
156         !
157         DO jk = 2, nksrp+1
158!CDIR NOVERRCHK
159            DO jj = 1, jpj
160!CDIR NOVERRCHK
161               DO ji = 1, jpi
162                  zc0 = ze0(ji,jj,jk-1) * EXP( -fse3t(ji,jj,jk-1) * zxsi0r )
163                  zc1 = ze1(ji,jj,jk-1) * EXP( -zekb(ji,jj,jk-1 ) )
164                  zc2 = ze2(ji,jj,jk-1) * EXP( -zekg(ji,jj,jk-1 ) )
165                  zc3 = ze3(ji,jj,jk-1) * EXP( -zekr(ji,jj,jk-1 ) )
166                  ze0(ji,jj,jk) = zc0
167                  ze1(ji,jj,jk) = zc1
168                  ze2(ji,jj,jk) = zc2
169                  ze3(ji,jj,jk) = zc3
170                  etot3(ji,jj,jk) = ( zc0 + zc1 + zc2 + zc3 ) * tmask(ji,jj,jk)
171              END DO
172              !
173            END DO
174            !
175        END DO
176        !
177      ENDIF
178
179      !                                        !* Euphotic depth and level
180      neln(:,:) = 1                            !  ------------------------
181      heup(:,:) = 300.
182
183      DO jk = 2, nksrp
184         DO jj = 1, jpj
185           DO ji = 1, jpi
186              IF( etot(ji,jj,jk) >= 0.0043 * qsr(ji,jj) )  THEN
187                 neln(ji,jj) = jk+1                    ! Euphotic level : 1rst T-level strictly below Euphotic layer
188                 !                                     ! nb: ensure the compatibility with nmld_trc definition in trd_mld_trc_zint
189                 heup(ji,jj) = fsdepw(ji,jj,jk+1)      ! Euphotic layer depth
190              ENDIF
191           END DO
192        END DO
193      END DO
194 
195      heup(:,:) = MIN( 300., heup(:,:) )
196
197      !                                        !* mean light over the mixed layer
198      zdepmoy(:,:)   = 0.e0                    !  -------------------------------
199      zetmp  (:,:)   = 0.e0
200      emoy   (:,:,:) = 0.e0
201
202      DO jk = 1, nksrp
203!CDIR NOVERRCHK
204         DO jj = 1, jpj
205!CDIR NOVERRCHK
206            DO ji = 1, jpi
207               IF( fsdepw(ji,jj,jk+1) <= hmld(ji,jj) ) THEN
208                  zetmp  (ji,jj) = zetmp  (ji,jj) + etot(ji,jj,jk) * fse3t(ji,jj,jk)
209                  zdepmoy(ji,jj) = zdepmoy(ji,jj) + fse3t(ji,jj,jk)
210               ENDIF
211            END DO
212         END DO
213      END DO
214      !
215      emoy(:,:,:) = etot(:,:,:)
216      !
217      DO jk = 1, nksrp
218!CDIR NOVERRCHK
219         DO jj = 1, jpj
220!CDIR NOVERRCHK
221            DO ji = 1, jpi
222               IF( fsdepw(ji,jj,jk+1) <= hmld(ji,jj) ) &
223       &           emoy(ji,jj,jk) = zetmp(ji,jj) / ( zdepmoy(ji,jj) + rtrn )
224            END DO
225         END DO
226      END DO
227
228#if defined key_diatrc
229# if ! defined key_iomput
230      ! save for outputs
231      trc2d(:,:,  jp_pcs0_2d + 10) = heup(:,:  ) * tmask(:,:,1) 
232      trc3d(:,:,:,jp_pcs0_3d + 3)  = etot(:,:,:) * tmask(:,:,:)
233# else
234      ! write diagnostics
235      IF( jnt == nrdttrc ) then
236         CALL iom_put( "Heup", heup(:,:  ) * tmask(:,:,1) )  ! euphotic layer deptht
237         CALL iom_put( "PAR" , etot(:,:,:) * tmask(:,:,:) )  ! Photosynthetically Available Radiation
238      ENDIF
239# endif
240#endif
241      !
242   END SUBROUTINE p4z_opt
243
244#else
245   !!----------------------------------------------------------------------
246   !!  Dummy module :                                   No PISCES bio-model
247   !!----------------------------------------------------------------------
248CONTAINS
249   SUBROUTINE p4z_opt                   ! Empty routine
250   END SUBROUTINE p4z_opt
251#endif 
252
253   !!======================================================================
254END MODULE  p4zopt
Note: See TracBrowser for help on using the repository browser.