New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
iom_nf90.F90 in branches/DEV_r2106_LOCEAN2010/NEMO/OPA_SRC/IOM – NEMO

source: branches/DEV_r2106_LOCEAN2010/NEMO/OPA_SRC/IOM/iom_nf90.F90 @ 2200

Last change on this file since 2200 was 2200, checked in by smasson, 13 years ago

merge trunk rev 2198 into DEV_r2106_LOCEAN2010

  • Property svn:eol-style set to native
  • Property svn:keywords set to Id
File size: 29.4 KB
Line 
1MODULE iom_nf90
2   !!=====================================================================
3   !!                    ***  MODULE  iom_nf90 ***
4   !! Input/Output manager :  Library to read input files with NF90 (only fliocom module)
5   !!====================================================================
6   !! History :  9.0  ! 05 12  (J. Belier) Original code
7   !!            9.0  ! 06 02  (S. Masson) Adaptation to NEMO
8   !!             "   ! 07 07  (D. Storkey) Changes to iom_nf90_gettime
9   !!--------------------------------------------------------------------
10   !!gm  caution add !DIR nec: improved performance to be checked as well as no result changes
11
12   !!--------------------------------------------------------------------
13   !!   iom_open       : open a file read only
14   !!   iom_close      : close a file or all files opened by iom
15   !!   iom_get        : read a field (interfaced to several routines)
16   !!   iom_gettime    : read the time axis kvid in the file
17   !!   iom_varid      : get the id of a variable in a file
18   !!   iom_rstput     : write a field in a restart file (interfaced to several routines)
19   !!--------------------------------------------------------------------
20   USE in_out_manager  ! I/O manager
21   USE dom_oce         ! ocean space and time domain
22   USE lbclnk          ! lateal boundary condition / mpp exchanges
23   USE iom_def         ! iom variables definitions
24   USE netcdf          ! NetCDF library
25
26   IMPLICIT NONE
27   PRIVATE
28
29   PUBLIC iom_nf90_open, iom_nf90_close, iom_nf90_varid, iom_nf90_get, iom_nf90_gettime, iom_nf90_rstput
30
31   INTERFACE iom_nf90_get
32      MODULE PROCEDURE iom_nf90_g0d, iom_nf90_g123d
33   END INTERFACE
34   INTERFACE iom_nf90_rstput
35      MODULE PROCEDURE iom_nf90_rp0123d
36   END INTERFACE
37   !!----------------------------------------------------------------------
38   !!  OPA 9.0 , LOCEAN-IPSL (2006)
39   !! $Id$
40   !! Software governed by the CeCILL licence (modipsl/doc/NEMO_CeCILL.txt)
41   !!----------------------------------------------------------------------
42
43CONTAINS
44
45   SUBROUTINE iom_nf90_open( cdname, kiomid, ldwrt, ldok, kdompar )
46      !!---------------------------------------------------------------------
47      !!                   ***  SUBROUTINE  iom_open  ***
48      !!
49      !! ** Purpose : open an input file with NF90
50      !!---------------------------------------------------------------------
51      CHARACTER(len=*)       , INTENT(inout)           ::   cdname      ! File name
52      INTEGER                , INTENT(  out)           ::   kiomid      ! nf90 identifier of the opened file
53      LOGICAL                , INTENT(in   )           ::   ldwrt       ! read or write the file?
54      LOGICAL                , INTENT(in   )           ::   ldok        ! check the existence
55      INTEGER, DIMENSION(2,5), INTENT(in   ), OPTIONAL ::   kdompar     ! domain parameters:
56
57      CHARACTER(LEN=100) ::   clinfo           ! info character
58      CHARACTER(LEN=100) ::   cltmp            ! temporary character
59      INTEGER            ::   iln              ! lengths of character
60      INTEGER            ::   istop            ! temporary storage of nstop
61      INTEGER            ::   if90id           ! nf90 identifier of the opened file
62      INTEGER            ::   idmy             ! dummy variable
63      INTEGER            ::   jl               ! loop variable
64      INTEGER            ::   ichunk           ! temporary storage of nn_chunksz
65      INTEGER            ::   imode            ! creation mode flag: NF90_CLOBBER or NF90_NOCLOBBER
66      LOGICAL            ::   llclobber        ! local definition of ln_clobber
67      !---------------------------------------------------------------------
68
69      clinfo = '                    iom_nf90_open ~~~  '
70      istop = nstop   ! store the actual value of nstop
71      IF( nn_chunksz > 0 ) THEN   ;   ichunk = nn_chunksz
72      ELSE                        ;   ichunk = NF90_SIZEHINT_DEFAULT
73      ENDIF
74      !
75      llclobber = ldwrt .AND. ln_clobber
76      IF( ldok .AND. .NOT. llclobber ) THEN      ! Open existing file...
77         !                 ! =============
78         IF( ldwrt ) THEN  ! ... in write mode
79            IF(lwp) WRITE(numout,*) TRIM(clinfo)//' open existing file: '//TRIM(cdname)//' in WRITE mode'
80            CALL iom_nf90_check(NF90_OPEN( TRIM(cdname), NF90_WRITE  , if90id, chunksize = ichunk ), clinfo)
81            CALL iom_nf90_check(NF90_SET_FILL( if90id, NF90_NOFILL, idmy                          ), clinfo)
82         ELSE              ! ... in read mode
83            IF(lwp) WRITE(numout,*) TRIM(clinfo)//' open existing file: '//TRIM(cdname)//' in READ mode'
84            CALL iom_nf90_check(NF90_OPEN( TRIM(cdname), NF90_NOWRITE, if90id, chunksize = ichunk ), clinfo)
85         ENDIF
86      ELSE                                       ! the file does not exist (or we overwrite it)
87         !                 ! =============
88         iln = INDEX( cdname, '.nc' )
89         IF( ldwrt ) THEN  ! the file should be open in write mode so we create it...
90            IF( jpnij > 1 ) THEN
91               WRITE(cltmp,'(a,a,i4.4,a)') cdname(1:iln-1), '_', narea-1, '.nc'
92               cdname = TRIM(cltmp)
93            ENDIF
94            IF(lwp) WRITE(numout,*) TRIM(clinfo)//' create new file: '//TRIM(cdname)//' in WRITE mode'
95
96            IF( llclobber ) THEN   ;   imode = IOR( NF90_64BIT_OFFSET, NF90_CLOBBER   )
97            ELSE                   ;   imode = IOR( NF90_64BIT_OFFSET, NF90_NOCLOBBER ) 
98            ENDIF
99            CALL iom_nf90_check(NF90_CREATE( TRIM(cdname), imode, if90id, chunksize = ichunk ), clinfo)
100            CALL iom_nf90_check(NF90_SET_FILL( if90id, NF90_NOFILL, idmy                     ), clinfo)
101            ! define dimensions
102            CALL iom_nf90_check(NF90_DEF_DIM( if90id, 'x', kdompar(1,1)  , idmy ), clinfo)
103            CALL iom_nf90_check(NF90_DEF_DIM( if90id, 'y', kdompar(2,1)  , idmy ), clinfo)
104            CALL iom_nf90_check(NF90_DEF_DIM( if90id, 'z', jpk           , idmy ), clinfo)
105            CALL iom_nf90_check(NF90_DEF_DIM( if90id, 't', NF90_UNLIMITED, idmy ), clinfo)
106            ! global attributes
107            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_number_total'   , jpnij              ), clinfo)
108            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_number'         , narea-1            ), clinfo)
109            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_dimensions_ids' , (/1     , 2     /) ), clinfo)
110            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_size_global'    , (/jpiglo, jpjglo/) ), clinfo)
111            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_size_local'     , kdompar(:,1)       ), clinfo)
112            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_position_first' , kdompar(:,2)       ), clinfo)
113            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_position_last'  , kdompar(:,3)       ), clinfo)
114            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_halo_size_start', kdompar(:,4)       ), clinfo)
115            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_halo_size_end'  , kdompar(:,5)       ), clinfo)
116            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_type'           , 'BOX'              ), clinfo)
117         ELSE              ! the file should be open for read mode so it must exist...
118            CALL ctl_stop( TRIM(clinfo), ' should be impossible case...' )
119         ENDIF
120      ENDIF
121      ! start to fill file informations
122      ! =============
123      IF( istop == nstop ) THEN   ! no error within this routine
124!does not work with some compilers         kiomid = MINLOC(iom_file(:)%nfid, dim = 1)
125         kiomid = 0
126         DO jl = jpmax_files, 1, -1
127            IF( iom_file(jl)%nfid == 0 )   kiomid = jl
128         ENDDO
129         iom_file(kiomid)%name   = TRIM(cdname)
130         iom_file(kiomid)%nfid   = if90id
131         iom_file(kiomid)%iolib  = jpnf90
132         iom_file(kiomid)%nvars  = 0
133         iom_file(kiomid)%irec   = -1   ! useless for NetCDF files, used to know if the file is in define mode
134         CALL iom_nf90_check(NF90_Inquire(if90id, unlimitedDimId = iom_file(kiomid)%iduld), clinfo)
135         IF ( iom_file(kiomid)%iduld .GE. 0 ) THEN
136           CALL iom_nf90_check(NF90_Inquire_Dimension(if90id, iom_file(kiomid)%iduld,   &
137        &                                               name = iom_file(kiomid)%uldname), clinfo)
138         ENDIF
139         IF(lwp) WRITE(numout,*) '                   ---> '//TRIM(cdname)//' OK'
140      ELSE
141         kiomid = 0               ! return error flag
142      ENDIF
143      !
144   END SUBROUTINE iom_nf90_open
145
146
147   SUBROUTINE iom_nf90_close( kiomid )
148      !!--------------------------------------------------------------------
149      !!                   ***  SUBROUTINE  iom_nf90_close  ***
150      !!
151      !! ** Purpose : close an input file with NF90
152      !!--------------------------------------------------------------------
153      INTEGER, INTENT(in) ::   kiomid   ! iom identifier of the file to be closed
154      CHARACTER(LEN=100)  ::   clinfo   ! info character
155      !---------------------------------------------------------------------
156      !
157      clinfo = '      iom_nf90_close    , file: '//TRIM(iom_file(kiomid)%name)
158      CALL iom_nf90_check(NF90_CLOSE(iom_file(kiomid)%nfid), clinfo)
159      !   
160   END SUBROUTINE iom_nf90_close
161
162
163   FUNCTION iom_nf90_varid ( kiomid, cdvar, kiv, kdimsz ) 
164      !!-----------------------------------------------------------------------
165      !!                  ***  FUNCTION  iom_varid  ***
166      !!
167      !! ** Purpose : get the id of a variable in a file with NF90
168      !!-----------------------------------------------------------------------
169      INTEGER              , INTENT(in   )           ::   kiomid   ! file Identifier
170      CHARACTER(len=*)     , INTENT(in   )           ::   cdvar    ! name of the variable
171      INTEGER              , INTENT(in   )           ::   kiv   !
172      INTEGER, DIMENSION(:), INTENT(  out), OPTIONAL ::   kdimsz   ! size of the dimensions
173      !
174      INTEGER                        ::   iom_nf90_varid   ! iom variable Id
175      INTEGER                        ::   if90id           ! nf90 file identifier
176      INTEGER                        ::   ji               ! dummy loop index
177      INTEGER                        ::   ivarid           ! NetCDF  variable Id
178      INTEGER                        ::   i_nvd            ! number of dimension of the variable
179      INTEGER, DIMENSION(jpmax_dims) ::   idimid           ! dimension ids of the variable
180      LOGICAL                        ::   llok             ! ok  test
181      CHARACTER(LEN=100)             ::   clinfo           ! info character
182      !!-----------------------------------------------------------------------
183      clinfo = '          iom_nf90_varid, file: '//TRIM(iom_file(kiomid)%name)//', var: '//TRIM(cdvar)
184      iom_nf90_varid = 0                    ! default definition
185      IF( PRESENT(kdimsz) ) kdimsz(:) = 0   ! default definition
186      if90id = iom_file(kiomid)%nfid        ! get back NetCDF file id
187      !
188      llok = NF90_INQ_VARID( if90id, TRIM(cdvar), ivarid ) == nf90_noerr   ! does the variable exist in the file
189      IF( llok ) THEN
190         iom_nf90_varid = kiv
191         iom_file(kiomid)%nvars       = kiv
192         iom_file(kiomid)%nvid(kiv)   = ivarid
193         iom_file(kiomid)%cn_var(kiv) = TRIM(cdvar)
194         CALL iom_nf90_check(NF90_Inquire_Variable(if90id, ivarid, ndims = i_nvd), clinfo)   ! number of dimensions
195         iom_file(kiomid)%ndims(kiv)  = i_nvd
196         CALL iom_nf90_check(NF90_Inquire_Variable(if90id, ivarid, dimids = idimid(1:i_nvd)), clinfo)   ! dimensions ids
197         iom_file(kiomid)%luld(kiv) = .FALSE.   ! default value
198         DO ji = 1, i_nvd                       ! dimensions size
199            CALL iom_nf90_check(NF90_Inquire_Dimension(if90id, idimid(ji), len = iom_file(kiomid)%dimsz(ji,kiv)), clinfo)   
200            IF( idimid(ji) == iom_file(kiomid)%iduld ) iom_file(kiomid)%luld(kiv) = .TRUE.   ! unlimited dimension?
201         END DO
202         !---------- Deal with scale_factor and add_offset
203         llok = NF90_Inquire_attribute(if90id, ivarid, 'scale_factor') == nf90_noerr
204         IF( llok) THEN
205            CALL iom_nf90_check(NF90_GET_ATT(if90id, ivarid, 'scale_factor', iom_file(kiomid)%scf(kiv)), clinfo)
206         ELSE
207            iom_file(kiomid)%scf(kiv) = 1.
208         END IF
209         llok = NF90_Inquire_attribute(if90id, ivarid, 'add_offset') == nf90_noerr
210         IF( llok ) THEN
211            CALL iom_nf90_check(NF90_GET_ATT(if90id, ivarid, 'add_offset', iom_file(kiomid)%ofs(kiv)), clinfo)
212         ELSE
213            iom_file(kiomid)%ofs(kiv) = 0.
214         END IF
215         ! return the simension size
216         IF( PRESENT(kdimsz) ) THEN
217            IF( i_nvd == SIZE(kdimsz) ) THEN
218               kdimsz(:) = iom_file(kiomid)%dimsz(1:i_nvd,kiv)
219            ELSE
220               WRITE(ctmp1,*) i_nvd, SIZE(kdimsz)
221               CALL ctl_stop( TRIM(clinfo), 'error in kdimsz size'//TRIM(ctmp1) )
222            ENDIF
223         ENDIF
224      ELSE 
225         iom_nf90_varid = -1   !   variable not found, return error code: -1
226      ENDIF
227      !
228   END FUNCTION iom_nf90_varid
229
230
231   SUBROUTINE iom_nf90_g0d( kiomid, kvid, pvar )
232      !!-----------------------------------------------------------------------
233      !!                  ***  ROUTINE  iom_nf90_g0d  ***
234      !!
235      !! ** Purpose : read a scalar with NF90
236      !!-----------------------------------------------------------------------
237      INTEGER , INTENT(in   ) ::   kiomid   ! Identifier of the file
238      INTEGER , INTENT(in   ) ::   kvid     ! variable id
239      REAL(wp), INTENT(  out) ::   pvar     ! read field
240      !
241      CHARACTER(LEN=100)      ::   clinfo   ! info character
242      !---------------------------------------------------------------------
243      clinfo = 'iom_nf90_g0d , file: '//TRIM(iom_file(kiomid)%name)//', var: '//TRIM(iom_file(kiomid)%cn_var(kvid))
244      CALL iom_nf90_check(NF90_GET_VAR(iom_file(kiomid)%nfid, iom_file(kiomid)%nvid(kvid), pvar), clinfo )
245      !
246   END SUBROUTINE iom_nf90_g0d
247
248
249   SUBROUTINE iom_nf90_g123d( kiomid, kvid, knbdim, kstart, kcount, kx1, kx2, ky1, ky2,   &
250         &                    pv_r1d, pv_r2d, pv_r3d )
251      !!-----------------------------------------------------------------------
252      !!                  ***  ROUTINE  iom_nf90_g123d  ***
253      !!
254      !! ** Purpose : read a 1D/2D/3D variable with NF90
255      !!
256      !! ** Method : read ONE record at each CALL
257      !!-----------------------------------------------------------------------
258      INTEGER                    , INTENT(in   )           ::   kiomid    ! iom identifier of the file
259      INTEGER                    , INTENT(in   )           ::   kvid      ! Name of the variable
260      INTEGER                    , INTENT(in   )           ::   knbdim    ! number of dimensions of the variable
261      INTEGER , DIMENSION(:)     , INTENT(in   )           ::   kstart    ! start position of the reading in each axis
262      INTEGER , DIMENSION(:)     , INTENT(in   )           ::   kcount    ! number of points to be read in each axis
263      INTEGER ,                    INTENT(in   )           ::   kx1, kx2, ky1, ky2   ! subdomain indexes
264      REAL(wp), DIMENSION(:)     , INTENT(  out), OPTIONAL ::   pv_r1d    ! read field (1D case)
265      REAL(wp), DIMENSION(:,:)   , INTENT(  out), OPTIONAL ::   pv_r2d    ! read field (2D case)
266      REAL(wp), DIMENSION(:,:,:) , INTENT(  out), OPTIONAL ::   pv_r3d    ! read field (3D case)
267      !
268      CHARACTER(LEN=100) ::   clinfo               ! info character
269      INTEGER            ::   if90id               ! nf90 identifier of the opened file
270      INTEGER            ::   ivid                 ! nf90 variable id
271      !---------------------------------------------------------------------
272      clinfo = 'iom_nf90_g123d , file: '//TRIM(iom_file(kiomid)%name)//', var: '//TRIM(iom_file(kiomid)%cn_var(kvid))
273      if90id = iom_file(kiomid)%nfid         ! get back NetCDF file id
274      ivid   = iom_file(kiomid)%nvid(kvid)   ! get back NetCDF var id
275      !
276      IF(     PRESENT(pv_r1d) ) THEN
277         CALL iom_nf90_check( NF90_GET_VAR(if90id, ivid, pv_r1d(:                ), start = kstart(1:knbdim),   &
278            &                                                                       count = kcount(1:knbdim)), clinfo )
279      ELSEIF( PRESENT(pv_r2d) ) THEN
280         CALL iom_nf90_check( NF90_GET_VAR(if90id, ivid, pv_r2d(kx1:kx2,ky1:ky2  ), start = kstart(1:knbdim),   &
281            &                                                                       count = kcount(1:knbdim)), clinfo )
282      ELSEIF( PRESENT(pv_r3d) ) THEN
283         CALL iom_nf90_check( NF90_GET_VAR(if90id, ivid, pv_r3d(kx1:kx2,ky1:ky2,:), start = kstart(1:knbdim),   &
284            &                                                                       count = kcount(1:knbdim)), clinfo )
285      ENDIF
286      !
287   END SUBROUTINE iom_nf90_g123d
288
289
290   SUBROUTINE iom_nf90_gettime( kiomid, kvid, ptime, cdunits, cdcalendar )
291      !!--------------------------------------------------------------------
292      !!                   ***  SUBROUTINE iom_gettime  ***
293      !!
294      !! ** Purpose : read the time axis kvid in the file with NF90
295      !!--------------------------------------------------------------------
296      INTEGER                   , INTENT(in   ) ::   kiomid     ! file Identifier
297      INTEGER                   , INTENT(in   ) ::   kvid       ! variable id
298      REAL(wp), DIMENSION(:)    , INTENT(  out) ::   ptime      ! the time axis
299      CHARACTER(len=*), OPTIONAL, INTENT(  out) ::   cdunits    ! units attribute
300      CHARACTER(len=*), OPTIONAL, INTENT(  out) ::   cdcalendar ! calendar attribute
301      !
302      CHARACTER(LEN=100) ::   clinfo     ! info character
303      !---------------------------------------------------------------------
304      clinfo = 'iom_nf90_gettime, file: '//TRIM(iom_file(kiomid)%name)//', var: '//TRIM(iom_file(kiomid)%cn_var(kvid))
305      CALL iom_nf90_check(NF90_GET_VAR(iom_file(kiomid)%nfid, iom_file(kiomid)%nvid(kvid), ptime(:),   &
306            &                           start=(/ 1 /), count=(/ iom_file(kiomid)%dimsz(1, kvid) /)), clinfo)
307      IF ( PRESENT(cdunits) ) THEN
308         CALL iom_nf90_check(NF90_GET_ATT(iom_file(kiomid)%nfid, iom_file(kiomid)%nvid(kvid), "units", &
309            &                           values=cdunits), clinfo)
310      ENDIF
311      IF ( PRESENT(cdcalendar) ) THEN
312         CALL iom_nf90_check(NF90_GET_ATT(iom_file(kiomid)%nfid, iom_file(kiomid)%nvid(kvid), "calendar", &
313            &                           values=cdcalendar), clinfo)
314      ENDIF
315      !
316   END SUBROUTINE iom_nf90_gettime
317
318
319   SUBROUTINE iom_nf90_rp0123d( kt, kwrite, kiomid, cdvar , kvid  , ktype,   &
320         &                               pv_r0d, pv_r1d, pv_r2d, pv_r3d )
321      !!--------------------------------------------------------------------
322      !!                   ***  SUBROUTINE  iom_nf90_rstput  ***
323      !!
324      !! ** Purpose : read the time axis cdvar in the file
325      !!--------------------------------------------------------------------
326      INTEGER                     , INTENT(in)           ::   kt       ! ocean time-step
327      INTEGER                     , INTENT(in)           ::   kwrite   ! writing time-step
328      INTEGER                     , INTENT(in)           ::   kiomid   ! Identifier of the file
329      CHARACTER(len=*)            , INTENT(in)           ::   cdvar    ! variable name
330      INTEGER                     , INTENT(in)           ::   kvid     ! variable id
331      INTEGER                     , INTENT(in), OPTIONAL ::   ktype    ! variable type (default R8)
332      REAL(wp)                    , INTENT(in), OPTIONAL ::   pv_r0d   ! written Od field
333      REAL(wp), DIMENSION(      :), INTENT(in), OPTIONAL ::   pv_r1d   ! written 1d field
334      REAL(wp), DIMENSION(:, :   ), INTENT(in), OPTIONAL ::   pv_r2d   ! written 2d field
335      REAL(wp), DIMENSION(:, :, :), INTENT(in), OPTIONAL ::   pv_r3d   ! written 3d field
336      !
337      INTEGER               :: idims                ! number of dimension
338      INTEGER               :: idvar                ! variable id
339      INTEGER               :: jd                   ! dimension loop counter   
340      INTEGER               :: ix1, ix2, iy1, iy2   ! subdomain indexes   
341      INTEGER, DIMENSION(4) :: idimsz               ! dimensions size 
342      INTEGER, DIMENSION(4) :: idimid               ! dimensions id
343      CHARACTER(LEN=100)    :: clinfo               ! info character
344      CHARACTER(LEN= 12), DIMENSION(4) :: cltmp     ! temporary character
345      INTEGER               :: if90id               ! nf90 file identifier
346      INTEGER               :: idmy                 ! dummy variable
347      INTEGER               :: itype                ! variable type
348      !---------------------------------------------------------------------
349      !
350      clinfo = '          iom_nf90_rp0123d, file: '//TRIM(iom_file(kiomid)%name)//', var: '//TRIM(cdvar)
351      if90id = iom_file(kiomid)%nfid
352      !
353      ! define dimension variables if it is not already done
354      ! ==========================
355      IF( iom_file(kiomid)%nvars == 0 ) THEN
356         ! are we in define mode?
357         IF( iom_file(kiomid)%irec /= -1 ) THEN   ! trick: irec used to know if the file is in define mode or not
358            CALL iom_nf90_check(NF90_REDEF( if90id ), clinfo)   ;   iom_file(kiomid)%irec = -1
359         ENDIF
360         ! define the dimension variables if it is not already done
361         cltmp = (/ 'nav_lon     ', 'nav_lat     ', 'nav_lev     ', 'time_counter' /)
362         CALL iom_nf90_check(NF90_DEF_VAR( if90id, TRIM(cltmp(1)), NF90_FLOAT , (/ 1, 2 /), iom_file(kiomid)%nvid(1) ), clinfo)
363         CALL iom_nf90_check(NF90_DEF_VAR( if90id, TRIM(cltmp(2)), NF90_FLOAT , (/ 1, 2 /), iom_file(kiomid)%nvid(2) ), clinfo)
364         CALL iom_nf90_check(NF90_DEF_VAR( if90id, TRIM(cltmp(3)), NF90_FLOAT , (/ 3    /), iom_file(kiomid)%nvid(3) ), clinfo)
365         CALL iom_nf90_check(NF90_DEF_VAR( if90id, TRIM(cltmp(4)), NF90_DOUBLE, (/ 4    /), iom_file(kiomid)%nvid(4) ), clinfo)
366         ! update informations structure related the dimension variable we just added...
367         iom_file(kiomid)%nvars       = 4
368         iom_file(kiomid)%luld(1:4)   = (/ .FALSE., .FALSE., .FALSE., .TRUE. /)
369         iom_file(kiomid)%cn_var(1:4) = cltmp
370         iom_file(kiomid)%ndims(1:4)  = (/ 2, 2, 1, 1 /) 
371         ! trick: defined to 0 to say that dimension variables are defined but not yet written
372         iom_file(kiomid)%dimsz(1, 1)  = 0   
373         IF(lwp) WRITE(numout,*) TRIM(clinfo)//' define dimension variables done'
374      ENDIF
375      ! define the data if it is not already done
376      ! ===============
377      IF( kvid <= 0 ) THEN
378         idvar = iom_file(kiomid)%nvars + 1
379         ! are we in define mode?
380         IF( iom_file(kiomid)%irec /= -1 ) THEN   ! trick: irec used to know if the file is in define mode or not
381            CALL iom_nf90_check(NF90_REDEF( if90id ), clinfo)   ;   iom_file(kiomid)%irec = -1
382         ENDIF
383         ! variable definition
384         IF(     PRESENT(pv_r0d) ) THEN   ;   idims = 0
385         ELSEIF( PRESENT(pv_r1d) ) THEN   ;   idims = 2   ;   idimid(1:idims) = (/    3,4/)
386         ELSEIF( PRESENT(pv_r2d) ) THEN   ;   idims = 3   ;   idimid(1:idims) = (/1,2  ,4/)
387         ELSEIF( PRESENT(pv_r3d) ) THEN   ;   idims = 4   ;   idimid(1:idims) = (/1,2,3,4/)
388         ENDIF
389         IF( PRESENT(ktype) ) THEN   ! variable external type
390            SELECT CASE (ktype)
391            CASE (jp_r8)  ;   itype = NF90_DOUBLE
392            CASE (jp_r4)  ;   itype = NF90_FLOAT
393            CASE (jp_i4)  ;   itype = NF90_INT
394            CASE (jp_i2)  ;   itype = NF90_SHORT
395            CASE (jp_i1)  ;   itype = NF90_BYTE
396            CASE DEFAULT   ;   CALL ctl_stop( TRIM(clinfo)//' unknown variable type' )
397            END SELECT
398         ELSE
399            itype = NF90_DOUBLE
400         ENDIF
401         IF( PRESENT(pv_r0d) ) THEN
402            CALL iom_nf90_check(NF90_DEF_VAR( if90id, TRIM(cdvar), itype,                    &
403                 &                            iom_file(kiomid)%nvid(idvar) ), clinfo)
404         ELSE
405            CALL iom_nf90_check(NF90_DEF_VAR( if90id, TRIM(cdvar), itype, idimid(1:idims),   &
406                 &                            iom_file(kiomid)%nvid(idvar) ), clinfo)
407         ENDIF
408         ! update informations structure related the new variable we want to add...
409         iom_file(kiomid)%nvars         = idvar
410         iom_file(kiomid)%cn_var(idvar) = TRIM(cdvar)
411         iom_file(kiomid)%scf(idvar)    = 1.
412         iom_file(kiomid)%ofs(idvar)    = 0.
413         iom_file(kiomid)%ndims(idvar)  = idims
414         IF( .NOT. PRESENT(pv_r0d) ) THEN   ;   iom_file(kiomid)%luld(idvar) = .TRUE.
415         ELSE                               ;   iom_file(kiomid)%luld(idvar) = .FALSE.
416         ENDIF
417         DO jd = 1, idims
418            CALL iom_nf90_check(NF90_INQUIRE_DIMENSION( if90id, idimid(jd), len = iom_file(kiomid)%dimsz(jd,idvar) ), clinfo)
419         END DO
420         IF(lwp) WRITE(numout,*) TRIM(clinfo)//' defined ok'
421      ELSE
422         idvar = kvid
423      ENDIF
424
425      ! time step kwrite : write the variable
426      IF( kt == kwrite ) THEN
427         ! are we in write mode?
428         IF( iom_file(kiomid)%irec == -1 ) THEN   ! trick: irec used to know if the file is in define mode or not
429            CALL iom_nf90_check(NF90_ENDDEF( if90id ), clinfo)   ;   iom_file(kiomid)%irec = 0
430         ENDIF
431         ! on what kind of domain must the data be written?
432         IF( PRESENT(pv_r2d) .OR. PRESENT(pv_r3d) ) THEN
433            idimsz(1:2) = iom_file(kiomid)%dimsz(1:2,idvar)
434            IF(     idimsz(1) == (nlei - nldi + 1) .AND. idimsz(2) == (nlej - nldj + 1) ) THEN
435               ix1 = nldi   ;   ix2 = nlei   ;   iy1 = nldj   ;   iy2 = nlej
436            ELSEIF( idimsz(1) == nlci              .AND. idimsz(2) == nlcj              ) THEN
437               ix1 = 1      ;   ix2 = nlci   ;   iy1 = 1      ;   iy2 = nlcj
438            ELSEIF( idimsz(1) == jpi               .AND. idimsz(2) == jpj               ) THEN
439               ix1 = 1      ;   ix2 = jpi    ;   iy1 = 1      ;   iy2 = jpj
440            ELSE
441               CALL ctl_stop( 'iom_nf90_rp0123d: should have been an impossible case...' )
442            ENDIF
443
444            ! write dimension variables if it is not already done
445            ! =============
446            ! trick: is defined to 0 => dimension variable are defined but not yet written
447            IF( iom_file(kiomid)%dimsz(1, 1) == 0 ) THEN
448               CALL iom_nf90_check(NF90_INQ_VARID( if90id, 'nav_lon'     , idmy ), clinfo)
449               CALL iom_nf90_check(NF90_PUT_VAR( if90id, idmy, glamt(ix1:ix2, iy1:iy2) ), clinfo)
450               CALL iom_nf90_check(NF90_INQ_VARID( if90id, 'nav_lat'     , idmy ), clinfo)
451               CALL iom_nf90_check(NF90_PUT_VAR( if90id, idmy, gphit(ix1:ix2, iy1:iy2) ), clinfo)
452               CALL iom_nf90_check(NF90_INQ_VARID( if90id, 'nav_lev'     , idmy ), clinfo)
453               CALL iom_nf90_check(NF90_PUT_VAR( if90id, idmy, gdept_0                 ), clinfo)
454               ! +++ WRONG VALUE: to be improved but not really useful...
455               CALL iom_nf90_check(NF90_INQ_VARID( if90id, 'time_counter', idmy ), clinfo)
456               CALL iom_nf90_check(NF90_PUT_VAR( if90id, idmy, kt                      ), clinfo)   
457               ! update the values of the variables dimensions size
458               CALL iom_nf90_check(NF90_INQUIRE_DIMENSION( if90id, 1, len = iom_file(kiomid)%dimsz(1,1) ), clinfo)
459               CALL iom_nf90_check(NF90_INQUIRE_DIMENSION( if90id, 2, len = iom_file(kiomid)%dimsz(2,1) ), clinfo)
460               iom_file(kiomid)%dimsz(1:2, 2) = iom_file(kiomid)%dimsz(1:2, 1)
461               CALL iom_nf90_check(NF90_INQUIRE_DIMENSION( if90id, 3, len = iom_file(kiomid)%dimsz(1,3) ), clinfo)
462               iom_file(kiomid)%dimsz(1  , 4) = 1   ! unlimited dimension
463               IF(lwp) WRITE(numout,*) TRIM(clinfo)//' write dimension variables done'
464            ENDIF
465         ENDIF
466
467         ! write the data
468         ! =============
469         IF(     PRESENT(pv_r0d) ) THEN
470            CALL iom_nf90_check(NF90_PUT_VAR( if90id, idvar, pv_r0d                      ), clinfo)
471         ELSEIF( PRESENT(pv_r1d) ) THEN
472            CALL iom_nf90_check(NF90_PUT_VAR( if90id, idvar, pv_r1d(                  :) ), clinfo)
473         ELSEIF( PRESENT(pv_r2d) ) THEN
474            CALL iom_nf90_check(NF90_PUT_VAR( if90id, idvar, pv_r2d(ix1:ix2, iy1:iy2   ) ), clinfo)
475         ELSEIF( PRESENT(pv_r3d) ) THEN
476            CALL iom_nf90_check(NF90_PUT_VAR( if90id, idvar, pv_r3d(ix1:ix2, iy1:iy2, :) ), clinfo)
477         ENDIF
478         ! add 1 to the size of the temporal dimension (not really useful...)
479         IF( iom_file(kiomid)%luld(idvar) )   iom_file(kiomid)%dimsz(iom_file(kiomid)%ndims(idvar), idvar)    &
480               &                            = iom_file(kiomid)%dimsz(iom_file(kiomid)%ndims(idvar), idvar) + 1
481         IF(lwp) WRITE(numout,*) TRIM(clinfo)//' written ok'
482      ENDIF
483      !     
484   END SUBROUTINE iom_nf90_rp0123d
485
486
487   SUBROUTINE iom_nf90_check( kstatus, cdinfo )
488      !!--------------------------------------------------------------------
489      !!                   ***  SUBROUTINE iom_nf90_check  ***
490      !!
491      !! ** Purpose :   check nf90 errors
492      !!--------------------------------------------------------------------
493      INTEGER,          INTENT(in) :: kstatus
494      CHARACTER(LEN=*), INTENT(in) :: cdinfo
495      !---------------------------------------------------------------------
496      IF(kstatus /= nf90_noerr)   CALL ctl_stop( 'iom_nf90_check : '//TRIM(nf90_strerror(kstatus)), TRIM(cdinfo) )
497   END SUBROUTINE iom_nf90_check
498
499
500   !!======================================================================
501END MODULE iom_nf90
Note: See TracBrowser for help on using the repository browser.