New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
sbcblk_core.F90 in branches/DEV_r2106_LOCEAN2010/NEMO/OPA_SRC/SBC – NEMO

source: branches/DEV_r2106_LOCEAN2010/NEMO/OPA_SRC/SBC/sbcblk_core.F90 @ 2198

Last change on this file since 2198 was 2198, checked in by smasson, 14 years ago

merge dev_r2174_DCY into DEV_r2106_LOCEAN2010
  • Property svn:keywords set to Id
File size: 47.6 KB
Line 
1MODULE sbcblk_core
2   !!======================================================================
3   !!                       ***  MODULE  sbcblk_core  ***
4   !! Ocean forcing:  momentum, heat and freshwater flux formulation
5   !!=====================================================================
6   !! History :  1.0  !  2004-08  (U. Schweckendiek)  Original code
7   !!            2.0  !  2005-04  (L. Brodeau, A.M. Treguier) additions:
8   !!                           -  new bulk routine for efficiency
9   !!                           -  WINDS ARE NOW ASSUMED TO BE AT T POINTS in input files !!!!
10   !!                           -  file names and file characteristics in namelist
11   !!                           -  Implement reading of 6-hourly fields   
12   !!            3.0  !  2006-06  (G. Madec) sbc rewritting   
13   !!            3.2  !  2009-04  (B. Lemaire)  Introduce iom_put
14   !!            3.3  !  2010-10  (S. Masson)  add diurnal cycle
15   !!----------------------------------------------------------------------
16
17   !!----------------------------------------------------------------------
18   !!   sbc_blk_core  : bulk formulation as ocean surface boundary condition
19   !!                   (forced mode, CORE bulk formulea)
20   !!   blk_oce_core  : ocean: computes momentum, heat and freshwater fluxes
21   !!   blk_ice_core  : ice  : computes momentum, heat and freshwater fluxes
22   !!   turb_core     : computes the CORE turbulent transfer coefficients
23   !!----------------------------------------------------------------------
24   USE oce             ! ocean dynamics and tracers
25   USE dom_oce         ! ocean space and time domain
26   USE phycst          ! physical constants
27   USE fldread         ! read input fields
28   USE sbc_oce         ! Surface boundary condition: ocean fields
29   USE sbcdcy          ! surface boundary condition: diurnal cycle
30   USE iom             ! I/O manager library
31   USE in_out_manager  ! I/O manager
32   USE lib_mpp         ! distribued memory computing library
33   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
34   USE prtctl          ! Print control
35#if defined key_lim3
36   USE sbc_ice         ! Surface boundary condition: ice fields
37#endif
38
39   IMPLICIT NONE
40   PRIVATE
41
42   PUBLIC   sbc_blk_core       ! routine called in sbcmod module
43   PUBLIC   blk_ice_core       ! routine called in sbc_ice_lim module
44     
45   INTEGER , PARAMETER ::   jpfld   = 9           ! maximum number of files to read
46   INTEGER , PARAMETER ::   jp_wndi = 1           ! index of 10m wind velocity (i-component) (m/s)    at T-point
47   INTEGER , PARAMETER ::   jp_wndj = 2           ! index of 10m wind velocity (j-component) (m/s)    at T-point
48   INTEGER , PARAMETER ::   jp_humi = 3           ! index of specific humidity               ( - )
49   INTEGER , PARAMETER ::   jp_qsr  = 4           ! index of solar heat                      (W/m2)
50   INTEGER , PARAMETER ::   jp_qlw  = 5           ! index of Long wave                       (W/m2)
51   INTEGER , PARAMETER ::   jp_tair = 6           ! index of 10m air temperature             (Kelvin)
52   INTEGER , PARAMETER ::   jp_prec = 7           ! index of total precipitation (rain+snow) (Kg/m2/s)
53   INTEGER , PARAMETER ::   jp_snow = 8           ! index of snow (solid prcipitation)       (kg/m2/s)
54   INTEGER , PARAMETER ::   jp_tdif = 9           ! index of tau diff associated to HF tau   (N/m2)   at T-point
55   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf   ! structure of input fields (file informations, fields read)
56         
57   !                                             !!! CORE bulk parameters
58   REAL(wp), PARAMETER ::   rhoa =    1.22        ! air density
59   REAL(wp), PARAMETER ::   cpa  = 1000.5         ! specific heat of air
60   REAL(wp), PARAMETER ::   Lv   =    2.5e6       ! latent heat of vaporization
61   REAL(wp), PARAMETER ::   Ls   =    2.839e6     ! latent heat of sublimation
62   REAL(wp), PARAMETER ::   Stef =    5.67e-8     ! Stefan Boltzmann constant
63   REAL(wp), PARAMETER ::   Cice =    1.63e-3     ! transfer coefficient over ice
64
65   !                                  !!* Namelist namsbc_core : CORE bulk parameters
66   LOGICAL  ::   ln_2m     = .FALSE.   ! logical flag for height of air temp. and hum
67   LOGICAL  ::   ln_taudif = .FALSE.   ! logical flag to use the "mean of stress module - module of mean stress" data
68   REAL(wp) ::   rn_pfac   = 1.        ! multiplication factor for precipitation
69
70   !! * Substitutions
71#  include "domzgr_substitute.h90"
72#  include "vectopt_loop_substitute.h90"
73   !!----------------------------------------------------------------------
74   !! NEMO/OPA 3.3 , NEMO-consortium (2010)
75   !! $Id$
76   !! Software governed by the CeCILL licence (modipsl/doc/NEMO_CeCILL.txt)
77   !!----------------------------------------------------------------------
78CONTAINS
79
80   SUBROUTINE sbc_blk_core( kt )
81      !!---------------------------------------------------------------------
82      !!                    ***  ROUTINE sbc_blk_core  ***
83      !!                   
84      !! ** Purpose :   provide at each time step the surface ocean fluxes
85      !!      (momentum, heat, freshwater and runoff)
86      !!
87      !! ** Method  : (1) READ each fluxes in NetCDF files:
88      !!      the 10m wind velocity (i-component) (m/s)    at T-point
89      !!      the 10m wind velocity (j-component) (m/s)    at T-point
90      !!      the specific humidity               ( - )
91      !!      the solar heat                      (W/m2)
92      !!      the Long wave                       (W/m2)
93      !!      the 10m air temperature             (Kelvin)
94      !!      the total precipitation (rain+snow) (Kg/m2/s)
95      !!      the snow (solid prcipitation)       (kg/m2/s)
96      !!   OPTIONAL parameter (see ln_taudif namelist flag):
97      !!      the tau diff associated to HF tau   (N/m2)   at T-point
98      !!              (2) CALL blk_oce_core
99      !!
100      !!      C A U T I O N : never mask the surface stress fields
101      !!                      the stress is assumed to be in the mesh referential
102      !!                      i.e. the (i,j) referential
103      !!
104      !! ** Action  :   defined at each time-step at the air-sea interface
105      !!              - utau, vtau  i- and j-component of the wind stress
106      !!              - taum        wind stress module at T-point
107      !!              - wndm        10m wind module at T-point
108      !!              - qns, qsr    non-slor and solar heat flux
109      !!              - emp, emps   evaporation minus precipitation
110      !!----------------------------------------------------------------------
111      INTEGER, INTENT( in  ) ::   kt   ! ocean time step
112      !!
113      INTEGER  ::   ierror   ! return error code
114      INTEGER  ::   ifpr     ! dummy loop indice
115      INTEGER  ::   jfld     ! dummy loop arguments
116      !!
117      CHARACTER(len=100) ::  cn_dir   !   Root directory for location of core files
118      TYPE(FLD_N), DIMENSION(jpfld) ::   slf_i     ! array of namelist informations on the fields to read
119      TYPE(FLD_N) ::   sn_wndi, sn_wndj, sn_humi, sn_qsr       ! informations about the fields to be read
120      TYPE(FLD_N) ::   sn_qlw , sn_tair, sn_prec, sn_snow      !   "                                 "
121      TYPE(FLD_N) ::   sn_tdif                                 !   "                                 "
122      NAMELIST/namsbc_core/ cn_dir , ln_2m  , ln_taudif, rn_pfac,           &
123         &                  sn_wndi, sn_wndj, sn_humi  , sn_qsr ,           &
124         &                  sn_qlw , sn_tair, sn_prec  , sn_snow, sn_tdif
125      !!---------------------------------------------------------------------
126
127      !                                         ! ====================== !
128      IF( kt == nit000 ) THEN                   !  First call kt=nit000  !
129         !                                      ! ====================== !
130         ! set file information (default values)
131         cn_dir = './'       ! directory in which the model is executed
132         !
133         ! (NB: frequency positive => hours, negative => months)
134         !            !    file     ! frequency !  variable  ! time intep !  clim   ! 'yearly' or ! weights  ! rotation   !
135         !            !    name     !  (hours)  !   name     !   (T/F)    !  (T/F)  !  'monthly'  ! filename ! pairs      !
136         sn_wndi = FLD_N( 'uwnd10m' ,    24     ,  'u_10'    ,  .false.   , .false. ,   'yearly'  , ''       , ''         )
137         sn_wndj = FLD_N( 'vwnd10m' ,    24     ,  'v_10'    ,  .false.   , .false. ,   'yearly'  , ''       , ''         )
138         sn_qsr  = FLD_N( 'qsw'     ,    24     ,  'qsw'     ,  .false.   , .false. ,   'yearly'  , ''       , ''         )
139         sn_qlw  = FLD_N( 'qlw'     ,    24     ,  'qlw'     ,  .false.   , .false. ,   'yearly'  , ''       , ''         )
140         sn_tair = FLD_N( 'tair10m' ,    24     ,  't_10'    ,  .false.   , .false. ,   'yearly'  , ''       , ''         )
141         sn_humi = FLD_N( 'humi10m' ,    24     ,  'q_10'    ,  .false.   , .false. ,   'yearly'  , ''       , ''         )
142         sn_prec = FLD_N( 'precip'  ,    -1     ,  'precip'  ,  .true.    , .false. ,   'yearly'  , ''       , ''         )
143         sn_snow = FLD_N( 'snow'    ,    -1     ,  'snow'    ,  .true.    , .false. ,   'yearly'  , ''       , ''         )
144         sn_tdif = FLD_N( 'taudif'  ,    24     ,  'taudif'  ,  .true.    , .false. ,   'yearly'  , ''       , ''         )
145         !
146         REWIND( numnam )                          ! read in namlist namsbc_core
147         READ  ( numnam, namsbc_core )
148         !                                         ! check: do we plan to use ln_dm2dc with non-daily forcing?
149         IF( ln_dm2dc .AND. sn_qsr%nfreqh /= 24 )   & 
150            &   CALL ctl_stop( 'sbc_blk_core: ln_dm2dc can be activated only with daily short-wave forcing' ) 
151         IF( ln_dm2dc .AND. sn_qsr%ln_tint ) THEN
152            CALL ctl_warn( 'sbc_blk_core: ln_dm2dc is taking care of the temporal interpolation of daily qsr',   &
153                 &         '              ==> We force time interpolation = .false. for qsr' )
154            sn_qsr%ln_tint = .false.
155         ENDIF
156         !                                         ! store namelist information in an array
157         slf_i(jp_wndi) = sn_wndi   ;   slf_i(jp_wndj) = sn_wndj
158         slf_i(jp_qsr ) = sn_qsr    ;   slf_i(jp_qlw ) = sn_qlw
159         slf_i(jp_tair) = sn_tair   ;   slf_i(jp_humi) = sn_humi
160         slf_i(jp_prec) = sn_prec   ;   slf_i(jp_snow) = sn_snow
161         slf_i(jp_tdif) = sn_tdif
162         !                 
163         lhftau = ln_taudif                        ! do we use HF tau information?
164         jfld = jpfld - COUNT( (/.NOT. lhftau/) )
165         !
166         ALLOCATE( sf(jfld), STAT=ierror )         ! set sf structure
167         IF( ierror > 0 ) THEN
168            CALL ctl_stop( 'sbc_blk_core: unable to allocate sf structure' )   ;   RETURN
169         ENDIF
170         DO ifpr= 1, jfld
171            ALLOCATE( sf(ifpr)%fnow(jpi,jpj,1  ) )
172            ALLOCATE( sf(ifpr)%fdta(jpi,jpj,1,2) )
173         END DO
174         !                                         ! fill sf with slf_i and control print
175         CALL fld_fill( sf, slf_i, cn_dir, 'sbc_blk_core', 'flux formulation for ocean surface boundary condition', 'namsbc_core' )
176         !
177      ENDIF
178
179                       CALL fld_read( kt, nn_fsbc, sf )        ! input fields provided at the current time-step
180
181      IF( ln_dm2dc )   CALL sbc_dcy ( kt , sf(jp_qsr)%fnow )   ! modify now Qsr to include the diurnal cycle
182
183#if defined key_lim3
184      tatm_ice(:,:) = sf(jp_tair)%fnow(:,:,1)                  ! LIM3: make Tair available in sea-ice
185#endif
186      !                                                        ! surface ocean fluxes computed with CLIO bulk formulea
187      IF( MOD( kt - 1, nn_fsbc ) == 0 )   CALL blk_oce_core( sf, sst_m, ssu_m, ssv_m )
188      !
189   END SUBROUTINE sbc_blk_core
190   
191   
192   SUBROUTINE blk_oce_core( sf, pst, pu, pv )
193      !!---------------------------------------------------------------------
194      !!                     ***  ROUTINE blk_core  ***
195      !!
196      !! ** Purpose :   provide the momentum, heat and freshwater fluxes at
197      !!      the ocean surface at each time step
198      !!
199      !! ** Method  :   CORE bulk formulea for the ocean using atmospheric
200      !!      fields read in sbc_read
201      !!
202      !! ** Outputs : - utau    : i-component of the stress at U-point  (N/m2)
203      !!              - vtau    : j-component of the stress at V-point  (N/m2)
204      !!              - taum    : Wind stress module at T-point         (N/m2)
205      !!              - wndm    : Wind speed module at T-point          (m/s)
206      !!              - qsr     : Solar heat flux over the ocean        (W/m2)
207      !!              - qns     : Non Solar heat flux over the ocean    (W/m2)
208      !!              - evap    : Evaporation over the ocean            (kg/m2/s)
209      !!              - emp(s)  : evaporation minus precipitation       (kg/m2/s)
210      !!
211      !!  ** Nota  :   sf has to be a dummy argument for AGRIF on NEC
212      !!---------------------------------------------------------------------
213      TYPE(fld), INTENT(in), DIMENSION(:)       ::   sf    ! input data
214      REAL(wp),  INTENT(in), DIMENSION(jpi,jpj) ::   pst   ! surface temperature                      [Celcius]
215      REAL(wp),  INTENT(in), DIMENSION(jpi,jpj) ::   pu    ! surface current at U-point (i-component) [m/s]
216      REAL(wp),  INTENT(in), DIMENSION(jpi,jpj) ::   pv    ! surface current at V-point (j-component) [m/s]
217
218      INTEGER  ::   ji, jj     ! dummy loop indices
219      REAL(wp) ::   zcoef_qsatw
220      REAL(wp) ::   zztmp                                 ! temporary variable
221      REAL(wp), DIMENSION(jpi,jpj) ::   zwnd_i, zwnd_j    ! wind speed components at T-point
222      REAL(wp), DIMENSION(jpi,jpj) ::   zqsatw            ! specific humidity at pst
223      REAL(wp), DIMENSION(jpi,jpj) ::   zqlw, zqsb        ! long wave and sensible heat fluxes
224      REAL(wp), DIMENSION(jpi,jpj) ::   zqla, zevap       ! latent heat fluxes and evaporation
225      REAL(wp), DIMENSION(jpi,jpj) ::   Cd                ! transfer coefficient for momentum      (tau)
226      REAL(wp), DIMENSION(jpi,jpj) ::   Ch                ! transfer coefficient for sensible heat (Q_sens)
227      REAL(wp), DIMENSION(jpi,jpj) ::   Ce                ! tansfert coefficient for evaporation   (Q_lat)
228      REAL(wp), DIMENSION(jpi,jpj) ::   zst               ! surface temperature in Kelvin
229      REAL(wp), DIMENSION(jpi,jpj) ::   zt_zu             ! air temperature at wind speed height
230      REAL(wp), DIMENSION(jpi,jpj) ::   zq_zu             ! air spec. hum.  at wind speed height
231      !!---------------------------------------------------------------------
232
233      ! local scalars ( place there for vector optimisation purposes)
234      zcoef_qsatw = 0.98 * 640380. / rhoa
235     
236      zst(:,:) = pst(:,:) + rt0      ! converte Celcius to Kelvin (and set minimum value far above 0 K)
237
238      ! ----------------------------------------------------------------------------- !
239      !      0   Wind components and module at T-point relative to the moving ocean   !
240      ! ----------------------------------------------------------------------------- !
241
242      ! ... components ( U10m - U_oce ) at T-point (unmasked)
243      zwnd_i(:,:) = 0.e0 
244      zwnd_j(:,:) = 0.e0
245#if defined key_vectopt_loop
246!CDIR COLLAPSE
247#endif
248      DO jj = 2, jpjm1
249         DO ji = fs_2, fs_jpim1   ! vect. opt.
250            zwnd_i(ji,jj) = (  sf(jp_wndi)%fnow(ji,jj,1) - 0.5 * ( pu(ji-1,jj  ) + pu(ji,jj) )  )
251            zwnd_j(ji,jj) = (  sf(jp_wndj)%fnow(ji,jj,1) - 0.5 * ( pv(ji  ,jj-1) + pv(ji,jj) )  )
252         END DO
253      END DO
254      CALL lbc_lnk( zwnd_i(:,:) , 'T', -1. )
255      CALL lbc_lnk( zwnd_j(:,:) , 'T', -1. )
256      ! ... scalar wind ( = | U10m - U_oce | ) at T-point (masked)
257!CDIR NOVERRCHK
258!CDIR COLLAPSE
259      wndm(:,:) = SQRT(  zwnd_i(:,:) * zwnd_i(:,:)   &
260         &             + zwnd_j(:,:) * zwnd_j(:,:)  ) * tmask(:,:,1)
261
262      ! ----------------------------------------------------------------------------- !
263      !      I   Radiative FLUXES                                                     !
264      ! ----------------------------------------------------------------------------- !
265   
266      ! ocean albedo assumed to be 0.066
267!CDIR COLLAPSE
268      qsr (:,:) = ( 1. - 0.066 ) * sf(jp_qsr)%fnow(:,:,1) * tmask(:,:,1)                                     ! Short Wave
269!CDIR COLLAPSE
270      zqlw(:,:) = (  sf(jp_qlw)%fnow(:,:,1) - Stef * zst(:,:)*zst(:,:)*zst(:,:)*zst(:,:)  ) * tmask(:,:,1)   ! Long  Wave
271                     
272      ! ----------------------------------------------------------------------------- !
273      !     II    Turbulent FLUXES                                                    !
274      ! ----------------------------------------------------------------------------- !
275
276      ! ... specific humidity at SST and IST
277!CDIR NOVERRCHK
278!CDIR COLLAPSE
279      zqsatw(:,:) = zcoef_qsatw * EXP( -5107.4 / zst(:,:) ) 
280
281      ! ... NCAR Bulk formulae, computation of Cd, Ch, Ce at T-point :
282      IF( ln_2m ) THEN
283         !! If air temp. and spec. hum. are given at different height (2m) than wind (10m) :
284         CALL TURB_CORE_2Z(2.,10., zst   , sf(jp_tair)%fnow,         &
285            &                      zqsatw, sf(jp_humi)%fnow, wndm,   &
286            &                      Cd    , Ch              , Ce  ,   &
287            &                      zt_zu , zq_zu                   )
288      ELSE
289         !! If air temp. and spec. hum. are given at same height than wind (10m) :
290!gm bug?  at the compiling phase, add a copy in temporary arrays...  ==> check perf
291!         CALL TURB_CORE_1Z( 10., zst   (:,:), sf(jp_tair)%fnow(:,:),              &
292!            &                    zqsatw(:,:), sf(jp_humi)%fnow(:,:), wndm(:,:),   &
293!            &                    Cd    (:,:),             Ch  (:,:), Ce  (:,:)  )
294!gm bug
295         CALL TURB_CORE_1Z( 10., zst   , sf(jp_tair)%fnow,         &
296            &                    zqsatw, sf(jp_humi)%fnow, wndm,   &
297            &                    Cd    , Ch              , Ce    )
298      ENDIF
299
300      ! ... tau module, i and j component
301      DO jj = 1, jpj
302         DO ji = 1, jpi
303            zztmp = rhoa * wndm(ji,jj) * Cd(ji,jj)
304            taum  (ji,jj) = zztmp * wndm  (ji,jj)
305            zwnd_i(ji,jj) = zztmp * zwnd_i(ji,jj)
306            zwnd_j(ji,jj) = zztmp * zwnd_j(ji,jj)
307         END DO
308      END DO
309
310      ! ... add the HF tau contribution to the wind stress module?
311      IF( lhftau ) THEN 
312!CDIR COLLAPSE
313         taum(:,:) = taum(:,:) + sf(jp_tdif)%fnow(:,:,1)
314      ENDIF
315      CALL iom_put( "taum_oce", taum )   ! output wind stress module
316
317      ! ... utau, vtau at U- and V_points, resp.
318      !     Note the use of 0.5*(2-umask) in order to unmask the stress along coastlines
319      DO jj = 1, jpjm1
320         DO ji = 1, fs_jpim1
321            utau(ji,jj) = 0.5 * ( 2. - umask(ji,jj,1) ) * ( zwnd_i(ji,jj) + zwnd_i(ji+1,jj  ) )
322            vtau(ji,jj) = 0.5 * ( 2. - vmask(ji,jj,1) ) * ( zwnd_j(ji,jj) + zwnd_j(ji  ,jj+1) )
323         END DO
324      END DO
325      CALL lbc_lnk( utau(:,:), 'U', -1. )
326      CALL lbc_lnk( vtau(:,:), 'V', -1. )
327
328      !  Turbulent fluxes over ocean
329      ! -----------------------------
330      IF( ln_2m ) THEN
331         ! Values of temp. and hum. adjusted to 10m must be used instead of 2m values
332         zevap(:,:) = MAX( 0.e0, rhoa    *Ce(:,:)*( zqsatw(:,:) - zq_zu(:,:) ) * wndm(:,:) )   ! Evaporation
333         zqsb (:,:) =            rhoa*cpa*Ch(:,:)*( zst   (:,:) - zt_zu(:,:) ) * wndm(:,:)     ! Sensible Heat
334      ELSE
335!CDIR COLLAPSE
336         zevap(:,:) = MAX( 0.e0, rhoa    *Ce(:,:)*( zqsatw(:,:) - sf(jp_humi)%fnow(:,:,1) ) * wndm(:,:) )   ! Evaporation
337!CDIR COLLAPSE
338         zqsb (:,:) =            rhoa*cpa*Ch(:,:)*( zst   (:,:) - sf(jp_tair)%fnow(:,:,1) ) * wndm(:,:)     ! Sensible Heat
339      ENDIF
340!CDIR COLLAPSE
341      zqla (:,:) = Lv * zevap(:,:)                                                              ! Latent Heat
342
343      IF(ln_ctl) THEN
344         CALL prt_ctl( tab2d_1=zqla  , clinfo1=' blk_oce_core: zqla   : ', tab2d_2=Ce , clinfo2=' Ce  : ' )
345         CALL prt_ctl( tab2d_1=zqsb  , clinfo1=' blk_oce_core: zqsb   : ', tab2d_2=Ch , clinfo2=' Ch  : ' )
346         CALL prt_ctl( tab2d_1=zqlw  , clinfo1=' blk_oce_core: zqlw   : ', tab2d_2=qsr, clinfo2=' qsr : ' )
347         CALL prt_ctl( tab2d_1=zqsatw, clinfo1=' blk_oce_core: zqsatw : ', tab2d_2=zst, clinfo2=' zst : ' )
348         CALL prt_ctl( tab2d_1=utau  , clinfo1=' blk_oce_core: utau   : ', mask1=umask,   &
349            &          tab2d_2=vtau  , clinfo2=              ' vtau : '  , mask2=vmask )
350         CALL prt_ctl( tab2d_1=wndm  , clinfo1=' blk_oce_core: wndm   : ')
351         CALL prt_ctl( tab2d_1=zst   , clinfo1=' blk_oce_core: zst    : ')
352      ENDIF
353       
354      ! ----------------------------------------------------------------------------- !
355      !     III    Total FLUXES                                                       !
356      ! ----------------------------------------------------------------------------- !
357     
358!CDIR COLLAPSE
359      qns(:,:) = zqlw(:,:) - zqsb(:,:) - zqla(:,:)      ! Downward Non Solar flux
360!CDIR COLLAPSE
361      emp (:,:) = zevap(:,:) - sf(jp_prec)%fnow(:,:,1) * rn_pfac * tmask(:,:,1)
362!CDIR COLLAPSE
363      emps(:,:) = emp(:,:)
364      !
365      CALL iom_put( "qlw_oce",   zqlw )                 ! output downward longwave heat over the ocean
366      CALL iom_put( "qsb_oce", - zqsb )                 ! output downward sensible heat over the ocean
367      CALL iom_put( "qla_oce", - zqla )                 ! output downward latent   heat over the ocean
368      CALL iom_put( "qns_oce",   qns  )                 ! output downward non solar heat over the ocean
369      !
370      IF(ln_ctl) THEN
371         CALL prt_ctl(tab2d_1=zqsb , clinfo1=' blk_oce_core: zqsb   : ', tab2d_2=zqlw , clinfo2=' zqlw  : ')
372         CALL prt_ctl(tab2d_1=zqla , clinfo1=' blk_oce_core: zqla   : ', tab2d_2=qsr  , clinfo2=' qsr   : ')
373         CALL prt_ctl(tab2d_1=pst  , clinfo1=' blk_oce_core: pst    : ', tab2d_2=emp  , clinfo2=' emp   : ')
374         CALL prt_ctl(tab2d_1=utau , clinfo1=' blk_oce_core: utau   : ', mask1=umask,   &
375            &         tab2d_2=vtau , clinfo2=              ' vtau  : ' , mask2=vmask )
376      ENDIF
377      !
378   END SUBROUTINE blk_oce_core
379   
380   
381   SUBROUTINE blk_ice_core(  pst   , pui   , pvi   , palb ,   &
382      &                      p_taui, p_tauj, p_qns , p_qsr,   &
383      &                      p_qla , p_dqns, p_dqla,          &
384      &                      p_tpr , p_spr ,                  &
385      &                      p_fr1 , p_fr2 , cd_grid, pdim  ) 
386      !!---------------------------------------------------------------------
387      !!                     ***  ROUTINE blk_ice_core  ***
388      !!
389      !! ** Purpose :   provide the surface boundary condition over sea-ice
390      !!
391      !! ** Method  :   compute momentum, heat and freshwater exchanged
392      !!                between atmosphere and sea-ice using CORE bulk
393      !!                formulea, ice variables and read atmmospheric fields.
394      !!                NB: ice drag coefficient is assumed to be a constant
395      !!
396      !! caution : the net upward water flux has with mm/day unit
397      !!---------------------------------------------------------------------
398      REAL(wp), INTENT(in   ), DIMENSION(:,:,:)      ::   pst      ! ice surface temperature (>0, =rt0 over land) [Kelvin]
399      REAL(wp), INTENT(in   ), DIMENSION(jpi,jpj)    ::   pui      ! ice surface velocity (i- and i- components      [m/s]
400      REAL(wp), INTENT(in   ), DIMENSION(jpi,jpj)    ::   pvi      !    at I-point (B-grid) or U & V-point (C-grid)
401      REAL(wp), INTENT(in   ), DIMENSION(:,:,:)      ::   palb     ! ice albedo (clear sky) (alb_ice_cs)               [%]
402      REAL(wp), INTENT(  out), DIMENSION(jpi,jpj)    ::   p_taui   ! i- & j-components of surface ice stress        [N/m2]
403      REAL(wp), INTENT(  out), DIMENSION(jpi,jpj)    ::   p_tauj   !   at I-point (B-grid) or U & V-point (C-grid)
404      REAL(wp), INTENT(  out), DIMENSION(:,:,:)      ::   p_qns    ! non solar heat flux over ice (T-point)         [W/m2]
405      REAL(wp), INTENT(  out), DIMENSION(:,:,:)      ::   p_qsr    !     solar heat flux over ice (T-point)         [W/m2]
406      REAL(wp), INTENT(  out), DIMENSION(:,:,:)      ::   p_qla    ! latent    heat flux over ice (T-point)         [W/m2]
407      REAL(wp), INTENT(  out), DIMENSION(:,:,:)      ::   p_dqns   ! non solar heat sensistivity  (T-point)         [W/m2]
408      REAL(wp), INTENT(  out), DIMENSION(:,:,:)      ::   p_dqla   ! latent    heat sensistivity  (T-point)         [W/m2]
409      REAL(wp), INTENT(  out), DIMENSION(jpi,jpj)    ::   p_tpr    ! total precipitation          (T-point)      [Kg/m2/s]
410      REAL(wp), INTENT(  out), DIMENSION(jpi,jpj)    ::   p_spr    ! solid precipitation          (T-point)      [Kg/m2/s]
411      REAL(wp), INTENT(  out), DIMENSION(jpi,jpj)    ::   p_fr1    ! 1sr fraction of qsr penetration in ice (T-point)  [%]
412      REAL(wp), INTENT(  out), DIMENSION(jpi,jpj)    ::   p_fr2    ! 2nd fraction of qsr penetration in ice (T-point)  [%]
413      CHARACTER(len=1), INTENT(in   )                ::   cd_grid  ! ice grid ( C or B-grid)
414      INTEGER, INTENT(in   )                         ::   pdim     ! number of ice categories
415      !!
416      INTEGER  ::   ji, jj, jl    ! dummy loop indices
417      INTEGER  ::   ijpl          ! number of ice categories (size of 3rd dim of input arrays)
418      REAL(wp) ::   zst2, zst3
419      REAL(wp) ::   zcoef_wnorm, zcoef_wnorm2, zcoef_dqlw, zcoef_dqla, zcoef_dqsb
420      REAL(wp) ::   zcoef_frca                                   ! fractional cloud amount
421      REAL(wp) ::   zwnorm_f, zwndi_f , zwndj_f                  ! relative wind module and components at F-point
422      REAL(wp) ::             zwndi_t , zwndj_t                  ! relative wind components at T-point
423      REAL(wp), DIMENSION(jpi,jpj) ::   z_wnds_t                 ! wind speed ( = | U10m - U_ice | ) at T-point
424      REAL(wp), DIMENSION(jpi,jpj,pdim) ::   z_qlw               ! long wave heat flux over ice
425      REAL(wp), DIMENSION(jpi,jpj,pdim) ::   z_qsb               ! sensible  heat flux over ice
426      REAL(wp), DIMENSION(jpi,jpj,pdim) ::   z_dqlw              ! long wave heat sensitivity over ice
427      REAL(wp), DIMENSION(jpi,jpj,pdim) ::   z_dqsb              ! sensible  heat sensitivity over ice
428      !!---------------------------------------------------------------------
429
430      ijpl  = pdim                            ! number of ice categories
431
432      ! local scalars ( place there for vector optimisation purposes)
433      zcoef_wnorm = rhoa * Cice
434      zcoef_wnorm2 = rhoa * Cice * 0.5
435      zcoef_dqlw = 4.0 * 0.95 * Stef
436      zcoef_dqla = -Ls * Cice * 11637800. * (-5897.8)
437      zcoef_dqsb = rhoa * cpa * Cice
438      zcoef_frca = 1.0  - 0.3
439
440!!gm brutal....
441      z_wnds_t(:,:) = 0.e0
442      p_taui  (:,:) = 0.e0
443      p_tauj  (:,:) = 0.e0
444!!gm end
445
446      ! ----------------------------------------------------------------------------- !
447      !    Wind components and module relative to the moving ocean ( U10m - U_ice )   !
448      ! ----------------------------------------------------------------------------- !
449      SELECT CASE( cd_grid )
450      CASE( 'B' )                  ! B-grid ice dynamics :   I-point (i.e. F-point with sea-ice indexation)
451         !                           and scalar wind at T-point ( = | U10m - U_ice | ) (masked)
452#if defined key_vectopt_loop
453!CDIR COLLAPSE
454#endif
455!CDIR NOVERRCHK
456         DO jj = 2, jpjm1
457            DO ji = 2, jpim1   ! B grid : no vector opt
458               ! ... scalar wind at I-point (fld being at T-point)
459               zwndi_f = 0.25 * (  sf(jp_wndi)%fnow(ji-1,jj  ,1) + sf(jp_wndi)%fnow(ji  ,jj  ,1)   &
460                  &              + sf(jp_wndi)%fnow(ji-1,jj-1,1) + sf(jp_wndi)%fnow(ji  ,jj-1,1)  ) - pui(ji,jj)
461               zwndj_f = 0.25 * (  sf(jp_wndj)%fnow(ji-1,jj  ,1) + sf(jp_wndj)%fnow(ji  ,jj  ,1)   &
462                  &              + sf(jp_wndj)%fnow(ji-1,jj-1,1) + sf(jp_wndj)%fnow(ji  ,jj-1,1)  ) - pvi(ji,jj)
463               zwnorm_f = zcoef_wnorm * SQRT( zwndi_f * zwndi_f + zwndj_f * zwndj_f )
464               ! ... ice stress at I-point
465               p_taui(ji,jj) = zwnorm_f * zwndi_f
466               p_tauj(ji,jj) = zwnorm_f * zwndj_f
467               ! ... scalar wind at T-point (fld being at T-point)
468               zwndi_t = sf(jp_wndi)%fnow(ji,jj,1) - 0.25 * (  pui(ji,jj+1) + pui(ji+1,jj+1)   &
469                  &                                          + pui(ji,jj  ) + pui(ji+1,jj  )  )
470               zwndj_t = sf(jp_wndj)%fnow(ji,jj,1) - 0.25 * (  pvi(ji,jj+1) + pvi(ji+1,jj+1)   &
471                  &                                          + pvi(ji,jj  ) + pvi(ji+1,jj  )  )
472               z_wnds_t(ji,jj)  = SQRT( zwndi_t * zwndi_t + zwndj_t * zwndj_t ) * tmask(ji,jj,1)
473            END DO
474         END DO
475         CALL lbc_lnk( p_taui  , 'I', -1. )
476         CALL lbc_lnk( p_tauj  , 'I', -1. )
477         CALL lbc_lnk( z_wnds_t, 'T',  1. )
478         !
479      CASE( 'C' )                  ! C-grid ice dynamics :   U & V-points (same as ocean)
480#if defined key_vectopt_loop
481!CDIR COLLAPSE
482#endif
483         DO jj = 2, jpj
484            DO ji = fs_2, jpi   ! vect. opt.
485               zwndi_t = (  sf(jp_wndi)%fnow(ji,jj,1) - 0.5 * ( pui(ji-1,jj  ) + pui(ji,jj) )  )
486               zwndj_t = (  sf(jp_wndj)%fnow(ji,jj,1) - 0.5 * ( pvi(ji  ,jj-1) + pvi(ji,jj) )  )
487               z_wnds_t(ji,jj)  = SQRT( zwndi_t * zwndi_t + zwndj_t * zwndj_t ) * tmask(ji,jj,1)
488            END DO
489         END DO
490#if defined key_vectopt_loop
491!CDIR COLLAPSE
492#endif
493         DO jj = 2, jpjm1
494            DO ji = fs_2, fs_jpim1   ! vect. opt.
495               p_taui(ji,jj) = zcoef_wnorm2 * ( z_wnds_t(ji+1,jj  ) + z_wnds_t(ji,jj) )                          &
496                  &          * ( 0.5 * (sf(jp_wndi)%fnow(ji+1,jj,1) + sf(jp_wndi)%fnow(ji,jj,1) ) - pui(ji,jj) )
497               p_tauj(ji,jj) = zcoef_wnorm2 * ( z_wnds_t(ji,jj+1  ) + z_wnds_t(ji,jj) )                          &
498                  &          * ( 0.5 * (sf(jp_wndj)%fnow(ji,jj+1,1) + sf(jp_wndj)%fnow(ji,jj,1) ) - pvi(ji,jj) )
499            END DO
500         END DO
501         CALL lbc_lnk( p_taui  , 'U', -1. )
502         CALL lbc_lnk( p_tauj  , 'V', -1. )
503         CALL lbc_lnk( z_wnds_t, 'T',  1. )
504         !
505      END SELECT
506
507      !                                     ! ========================== !
508      DO jl = 1, ijpl                       !  Loop over ice categories  !
509         !                                  ! ========================== !
510!CDIR NOVERRCHK
511!CDIR COLLAPSE
512         DO jj = 1 , jpj
513!CDIR NOVERRCHK
514            DO ji = 1, jpi
515               ! ----------------------------!
516               !      I   Radiative FLUXES   !
517               ! ----------------------------!
518               zst2 = pst(ji,jj,jl) * pst(ji,jj,jl)
519               zst3 = pst(ji,jj,jl) * zst2
520               ! Short Wave (sw)
521               p_qsr(ji,jj,jl) = ( 1. - palb(ji,jj,jl) ) * sf(jp_qsr)%fnow(ji,jj,1) * tmask(ji,jj,1)
522               ! Long  Wave (lw)
523               z_qlw(ji,jj,jl) = 0.95 * (  sf(jp_qlw)%fnow(ji,jj,1) - Stef * pst(ji,jj,jl) * zst3  ) * tmask(ji,jj,1)
524               ! lw sensitivity
525               z_dqlw(ji,jj,jl) = zcoef_dqlw * zst3                                               
526
527               ! ----------------------------!
528               !     II    Turbulent FLUXES  !
529               ! ----------------------------!
530
531               ! ... turbulent heat fluxes
532               ! Sensible Heat
533               z_qsb(ji,jj,jl) = rhoa * cpa * Cice * z_wnds_t(ji,jj) * ( pst(ji,jj,jl) - sf(jp_tair)%fnow(ji,jj,1) )
534               ! Latent Heat
535               p_qla(ji,jj,jl) = MAX( 0.e0, rhoa * Ls  * Cice * z_wnds_t(ji,jj)   &                           
536                  &                    * (  11637800. * EXP( -5897.8 / pst(ji,jj,jl) ) / rhoa - sf(jp_humi)%fnow(ji,jj,1)  ) )
537               ! Latent heat sensitivity for ice (Dqla/Dt)
538               p_dqla(ji,jj,jl) = zcoef_dqla * z_wnds_t(ji,jj) / ( zst2 ) * EXP( -5897.8 / pst(ji,jj,jl) )
539               ! Sensible heat sensitivity (Dqsb_ice/Dtn_ice)
540               z_dqsb(ji,jj,jl) = zcoef_dqsb * z_wnds_t(ji,jj)
541
542               ! ----------------------------!
543               !     III    Total FLUXES     !
544               ! ----------------------------!
545               ! Downward Non Solar flux
546               p_qns (ji,jj,jl) =     z_qlw (ji,jj,jl) - z_qsb (ji,jj,jl) - p_qla (ji,jj,jl)     
547               ! Total non solar heat flux sensitivity for ice
548               p_dqns(ji,jj,jl) = - ( z_dqlw(ji,jj,jl) + z_dqsb(ji,jj,jl) + p_dqla(ji,jj,jl) )   
549            END DO
550            !
551         END DO
552         !
553      END DO
554      !
555      !--------------------------------------------------------------------
556      ! FRACTIONs of net shortwave radiation which is not absorbed in the
557      ! thin surface layer and penetrates inside the ice cover
558      ! ( Maykut and Untersteiner, 1971 ; Ebert and Curry, 1993 )
559   
560!CDIR COLLAPSE
561      p_fr1(:,:) = ( 0.18 * ( 1.0 - zcoef_frca ) + 0.35 * zcoef_frca )
562!CDIR COLLAPSE
563      p_fr2(:,:) = ( 0.82 * ( 1.0 - zcoef_frca ) + 0.65 * zcoef_frca )
564       
565!CDIR COLLAPSE
566      p_tpr(:,:) = sf(jp_prec)%fnow(:,:,1) * rn_pfac      ! total precipitation [kg/m2/s]
567!CDIR COLLAPSE
568      p_spr(:,:) = sf(jp_snow)%fnow(:,:,1) * rn_pfac      ! solid precipitation [kg/m2/s]
569      CALL iom_put( 'snowpre', p_spr )                  ! Snow precipitation
570      !
571      IF(ln_ctl) THEN
572         CALL prt_ctl(tab3d_1=p_qla   , clinfo1=' blk_ice_core: p_qla  : ', tab3d_2=z_qsb   , clinfo2=' z_qsb  : ', kdim=ijpl)
573         CALL prt_ctl(tab3d_1=z_qlw   , clinfo1=' blk_ice_core: z_qlw  : ', tab3d_2=p_dqla  , clinfo2=' p_dqla : ', kdim=ijpl)
574         CALL prt_ctl(tab3d_1=z_dqsb  , clinfo1=' blk_ice_core: z_dqsb : ', tab3d_2=z_dqlw  , clinfo2=' z_dqlw : ', kdim=ijpl)
575         CALL prt_ctl(tab3d_1=p_dqns  , clinfo1=' blk_ice_core: p_dqns : ', tab3d_2=p_qsr   , clinfo2=' p_qsr  : ', kdim=ijpl)
576         CALL prt_ctl(tab3d_1=pst     , clinfo1=' blk_ice_core: pst    : ', tab3d_2=p_qns   , clinfo2=' p_qns  : ', kdim=ijpl)
577         CALL prt_ctl(tab2d_1=p_tpr   , clinfo1=' blk_ice_core: p_tpr  : ', tab2d_2=p_spr   , clinfo2=' p_spr  : ')
578         CALL prt_ctl(tab2d_1=p_taui  , clinfo1=' blk_ice_core: p_taui : ', tab2d_2=p_tauj  , clinfo2=' p_tauj : ')
579         CALL prt_ctl(tab2d_1=z_wnds_t, clinfo1=' blk_ice_core: z_wnds_t : ')
580      ENDIF
581
582   END SUBROUTINE blk_ice_core
583 
584
585   SUBROUTINE TURB_CORE_1Z(zu, sst, T_a, q_sat, q_a,   &
586      &                        dU, Cd, Ch, Ce   )
587      !!----------------------------------------------------------------------
588      !!                      ***  ROUTINE  turb_core  ***
589      !!
590      !! ** Purpose :   Computes turbulent transfert coefficients of surface
591      !!                fluxes according to Large & Yeager (2004)
592      !!
593      !! ** Method  :   I N E R T I A L   D I S S I P A T I O N   M E T H O D
594      !!      Momentum, Latent and sensible heat exchange coefficients
595      !!      Caution: this procedure should only be used in cases when air
596      !!      temperature (T_air), air specific humidity (q_air) and wind (dU)
597      !!      are provided at the same height 'zzu'!
598      !!
599      !! References :
600      !!      Large & Yeager, 2004 : ???
601      !! History :
602      !!        !  XX-XX  (???     )  Original code
603      !!   9.0  !  05-08  (L. Brodeau) Rewriting and optimization
604      !!----------------------------------------------------------------------
605      !! * Arguments
606
607      REAL(wp), INTENT(in) :: zu                 ! altitude of wind measurement       [m]
608      REAL(wp), INTENT(in), DIMENSION(jpi,jpj) ::  &
609         sst,       &       ! sea surface temperature         [Kelvin]
610         T_a,       &       ! potential air temperature       [Kelvin]
611         q_sat,     &       ! sea surface specific humidity   [kg/kg]
612         q_a,       &       ! specific air humidity           [kg/kg]
613         dU                 ! wind module |U(zu)-U(0)|        [m/s]
614      REAL(wp), intent(out), DIMENSION(jpi,jpj)  :: &
615         Cd,    &                ! transfert coefficient for momentum       (tau)
616         Ch,    &                ! transfert coefficient for temperature (Q_sens)
617         Ce                      ! transfert coefficient for evaporation  (Q_lat)
618
619      !! * Local declarations
620      REAL(wp), DIMENSION(jpi,jpj)  ::   &
621         dU10,        &       ! dU                                   [m/s]
622         dT,          &       ! air/sea temperature differeence      [K]
623         dq,          &       ! air/sea humidity difference          [K]
624         Cd_n10,      &       ! 10m neutral drag coefficient
625         Ce_n10,      &       ! 10m neutral latent coefficient
626         Ch_n10,      &       ! 10m neutral sensible coefficient
627         sqrt_Cd_n10, &       ! root square of Cd_n10
628         sqrt_Cd,     &       ! root square of Cd
629         T_vpot,      &       ! virtual potential temperature        [K]
630         T_star,      &       ! turbulent scale of tem. fluct.
631         q_star,      &       ! turbulent humidity of temp. fluct.
632         U_star,      &       ! turb. scale of velocity fluct.
633         L,           &       ! Monin-Obukov length                  [m]
634         zeta,        &       ! stability parameter at height zu
635         U_n10,       &       ! neutral wind velocity at 10m         [m]   
636         xlogt, xct, zpsi_h, zpsi_m
637      !!
638      INTEGER :: j_itt
639      INTEGER, PARAMETER :: nb_itt = 3
640      INTEGER, DIMENSION(jpi,jpj)  ::   &
641         stab         ! 1st guess stability test integer
642
643      REAL(wp), PARAMETER ::                        &
644         grav   = 9.8,          &  ! gravity                       
645         kappa  = 0.4              ! von Karman s constant
646
647      !! * Start
648      !! Air/sea differences
649      dU10 = max(0.5, dU)     ! we don't want to fall under 0.5 m/s
650      dT = T_a - sst          ! assuming that T_a is allready the potential temp. at zzu
651      dq = q_a - q_sat
652      !!   
653      !! Virtual potential temperature
654      T_vpot = T_a*(1. + 0.608*q_a)
655      !!
656      !! Neutral Drag Coefficient
657      stab    = 0.5 + sign(0.5,dT)    ! stable : stab = 1 ; unstable : stab = 0
658      Cd_n10  = 1E-3 * ( 2.7/dU10 + 0.142 + dU10/13.09 )    !   L & Y eq. (6a)
659      sqrt_Cd_n10 = sqrt(Cd_n10)
660      Ce_n10  = 1E-3 * ( 34.6 * sqrt_Cd_n10 )               !   L & Y eq. (6b)
661      Ch_n10  = 1E-3*sqrt_Cd_n10*(18*stab + 32.7*(1-stab)) !   L & Y eq. (6c), (6d)
662      !!
663      !! Initializing transfert coefficients with their first guess neutral equivalents :
664      Cd = Cd_n10 ;  Ce = Ce_n10 ;  Ch = Ch_n10 ;  sqrt_Cd = sqrt(Cd)
665
666      !! * Now starting iteration loop
667      DO j_itt=1, nb_itt
668         !! Turbulent scales :
669         U_star  = sqrt_Cd*dU10                !   L & Y eq. (7a)
670         T_star  = Ch/sqrt_Cd*dT               !   L & Y eq. (7b)
671         q_star  = Ce/sqrt_Cd*dq               !   L & Y eq. (7c)
672
673         !! Estimate the Monin-Obukov length :
674         L  = (U_star**2)/( kappa*grav*(T_star/T_vpot + q_star/(q_a + 1./0.608)) )
675
676         !! Stability parameters :
677         zeta = zu/L ;  zeta   = sign( min(abs(zeta),10.0), zeta )
678         zpsi_h = psi_h(zeta)
679         zpsi_m = psi_m(zeta)
680
681         !! Shifting the wind speed to 10m and neutral stability :
682         U_n10 = dU10*1./(1. + sqrt_Cd_n10/kappa*(log(zu/10.) - zpsi_m)) !  L & Y eq. (9a)
683
684         !! Updating the neutral 10m transfer coefficients :
685         Cd_n10  = 1E-3 * (2.7/U_n10 + 0.142 + U_n10/13.09)              !  L & Y eq. (6a)
686         sqrt_Cd_n10 = sqrt(Cd_n10)
687         Ce_n10  = 1E-3 * (34.6 * sqrt_Cd_n10)                           !  L & Y eq. (6b)
688         stab    = 0.5 + sign(0.5,zeta)
689         Ch_n10  = 1E-3*sqrt_Cd_n10*(18.*stab + 32.7*(1-stab))           !  L & Y eq. (6c), (6d)
690
691         !! Shifting the neutral  10m transfer coefficients to ( zu , zeta ) :
692         !!
693         xct = 1. + sqrt_Cd_n10/kappa*(log(zu/10) - zpsi_m)
694         Cd  = Cd_n10/(xct*xct) ;  sqrt_Cd = sqrt(Cd)
695         !!
696         xlogt = log(zu/10.) - zpsi_h
697         !!
698         xct = 1. + Ch_n10*xlogt/kappa/sqrt_Cd_n10
699         Ch  = Ch_n10*sqrt_Cd/sqrt_Cd_n10/xct
700         !!
701         xct = 1. + Ce_n10*xlogt/kappa/sqrt_Cd_n10
702         Ce  = Ce_n10*sqrt_Cd/sqrt_Cd_n10/xct
703         !!
704      END DO
705      !!
706    END SUBROUTINE TURB_CORE_1Z
707
708
709    SUBROUTINE TURB_CORE_2Z(zt, zu, sst, T_zt, q_sat, q_zt, dU, Cd, Ch, Ce, T_zu, q_zu)
710      !!----------------------------------------------------------------------
711      !!                      ***  ROUTINE  turb_core  ***
712      !!
713      !! ** Purpose :   Computes turbulent transfert coefficients of surface
714      !!                fluxes according to Large & Yeager (2004).
715      !!
716      !! ** Method  :   I N E R T I A L   D I S S I P A T I O N   M E T H O D
717      !!      Momentum, Latent and sensible heat exchange coefficients
718      !!      Caution: this procedure should only be used in cases when air
719      !!      temperature (T_air) and air specific humidity (q_air) are at 2m
720      !!      whereas wind (dU) is at 10m.
721      !!
722      !! References :
723      !!      Large & Yeager, 2004 : ???
724      !! History :
725      !!   9.0  !  06-12  (L. Brodeau) Original code for 2Z
726      !!----------------------------------------------------------------------
727      REAL(wp), INTENT(in)   :: &
728         zt,      &     ! height for T_zt and q_zt                   [m]
729         zu             ! height for dU                              [m]
730      REAL(wp), INTENT(in), DIMENSION(jpi,jpj) ::  &
731         sst,      &     ! sea surface temperature              [Kelvin]
732         T_zt,     &     ! potential air temperature            [Kelvin]
733         q_sat,    &     ! sea surface specific humidity         [kg/kg]
734         q_zt,     &     ! specific air humidity                 [kg/kg]
735         dU              ! relative wind module |U(zu)-U(0)|       [m/s]
736      REAL(wp), INTENT(out), DIMENSION(jpi,jpj)  ::  &
737         Cd,       &     ! transfer coefficient for momentum         (tau)
738         Ch,       &     ! transfer coefficient for sensible heat (Q_sens)
739         Ce,       &     ! transfert coefficient for evaporation   (Q_lat)
740         T_zu,     &     ! air temp. shifted at zu                     [K]
741         q_zu            ! spec. hum.  shifted at zu               [kg/kg]
742
743      !! * Local declarations
744      REAL(wp), DIMENSION(jpi,jpj) ::  &
745         dU10,        &     ! dU                                [m/s]
746         dT,          &     ! air/sea temperature differeence   [K]
747         dq,          &     ! air/sea humidity difference       [K]
748         Cd_n10,      &     ! 10m neutral drag coefficient
749         Ce_n10,      &     ! 10m neutral latent coefficient
750         Ch_n10,      &     ! 10m neutral sensible coefficient
751         sqrt_Cd_n10, &     ! root square of Cd_n10
752         sqrt_Cd,     &     ! root square of Cd
753         T_vpot_u,    &     ! virtual potential temperature        [K]
754         T_star,      &     ! turbulent scale of tem. fluct.
755         q_star,      &     ! turbulent humidity of temp. fluct.
756         U_star,      &     ! turb. scale of velocity fluct.
757         L,           &     ! Monin-Obukov length                  [m]
758         zeta_u,      &     ! stability parameter at height zu
759         zeta_t,      &     ! stability parameter at height zt
760         U_n10,       &     ! neutral wind velocity at 10m        [m]
761         xlogt, xct, zpsi_hu, zpsi_ht, zpsi_m
762
763      INTEGER :: j_itt
764      INTEGER, PARAMETER :: nb_itt = 3   ! number of itterations
765      INTEGER, DIMENSION(jpi,jpj) :: &
766           &     stab                ! 1st stability test integer
767      REAL(wp), PARAMETER ::                        &
768         grav   = 9.8,      &  ! gravity                       
769         kappa  = 0.4          ! von Karman's constant
770
771      !!  * Start
772
773      !! Initial air/sea differences
774      dU10 = max(0.5, dU)      !  we don't want to fall under 0.5 m/s
775      dT = T_zt - sst 
776      dq = q_zt - q_sat
777
778      !! Neutral Drag Coefficient :
779      stab = 0.5 + sign(0.5,dT)                 ! stab = 1  if dT > 0  -> STABLE
780      Cd_n10  = 1E-3*( 2.7/dU10 + 0.142 + dU10/13.09 ) 
781      sqrt_Cd_n10 = sqrt(Cd_n10)
782      Ce_n10  = 1E-3*( 34.6 * sqrt_Cd_n10 )
783      Ch_n10  = 1E-3*sqrt_Cd_n10*(18*stab + 32.7*(1 - stab))
784
785      !! Initializing transf. coeff. with their first guess neutral equivalents :
786      Cd = Cd_n10 ;  Ce = Ce_n10 ;  Ch = Ch_n10 ;  sqrt_Cd = sqrt(Cd)
787
788      !! Initializing z_u values with z_t values :
789      T_zu = T_zt ;  q_zu = q_zt
790
791      !!  * Now starting iteration loop
792      DO j_itt=1, nb_itt
793         dT = T_zu - sst ;  dq = q_zu - q_sat ! Updating air/sea differences
794         T_vpot_u = T_zu*(1. + 0.608*q_zu)    ! Updating virtual potential temperature at zu
795         U_star = sqrt_Cd*dU10                ! Updating turbulent scales :   (L & Y eq. (7))
796         T_star  = Ch/sqrt_Cd*dT              !
797         q_star  = Ce/sqrt_Cd*dq              !
798         !!
799         L = (U_star*U_star) &                ! Estimate the Monin-Obukov length at height zu
800              & / (kappa*grav/T_vpot_u*(T_star*(1.+0.608*q_zu) + 0.608*T_zu*q_star))
801         !! Stability parameters :
802         zeta_u  = zu/L  ;  zeta_u = sign( min(abs(zeta_u),10.0), zeta_u )
803         zeta_t  = zt/L  ;  zeta_t = sign( min(abs(zeta_t),10.0), zeta_t )
804         zpsi_hu = psi_h(zeta_u)
805         zpsi_ht = psi_h(zeta_t)
806         zpsi_m  = psi_m(zeta_u)
807         !!
808         !! Shifting the wind speed to 10m and neutral stability : (L & Y eq.(9a))
809!        U_n10 = dU10/(1. + sqrt_Cd_n10/kappa*(log(zu/10.) - psi_m(zeta_u)))
810         U_n10 = dU10/(1. + sqrt_Cd_n10/kappa*(log(zu/10.) - zpsi_m))
811         !!
812         !! Shifting temperature and humidity at zu :          (L & Y eq. (9b-9c))
813!        T_zu = T_zt - T_star/kappa*(log(zt/zu) + psi_h(zeta_u) - psi_h(zeta_t))
814         T_zu = T_zt - T_star/kappa*(log(zt/zu) + zpsi_hu - zpsi_ht)
815!        q_zu = q_zt - q_star/kappa*(log(zt/zu) + psi_h(zeta_u) - psi_h(zeta_t))
816         q_zu = q_zt - q_star/kappa*(log(zt/zu) + zpsi_hu - zpsi_ht)
817         !!
818         !! q_zu cannot have a negative value : forcing 0
819         stab = 0.5 + sign(0.5,q_zu) ;  q_zu = stab*q_zu
820         !!
821         !! Updating the neutral 10m transfer coefficients :
822         Cd_n10  = 1E-3 * (2.7/U_n10 + 0.142 + U_n10/13.09)    ! L & Y eq. (6a)
823         sqrt_Cd_n10 = sqrt(Cd_n10)
824         Ce_n10  = 1E-3 * (34.6 * sqrt_Cd_n10)                 ! L & Y eq. (6b)
825         stab    = 0.5 + sign(0.5,zeta_u)
826         Ch_n10  = 1E-3*sqrt_Cd_n10*(18.*stab + 32.7*(1-stab)) ! L & Y eq. (6c-6d)
827         !!
828         !!
829         !! Shifting the neutral 10m transfer coefficients to (zu,zeta_u) :
830!        xct = 1. + sqrt_Cd_n10/kappa*(log(zu/10.) - psi_m(zeta_u))
831         xct = 1. + sqrt_Cd_n10/kappa*(log(zu/10.) - zpsi_m)
832         Cd = Cd_n10/(xct*xct) ; sqrt_Cd = sqrt(Cd)
833         !!
834!        xlogt = log(zu/10.) - psi_h(zeta_u)
835         xlogt = log(zu/10.) - zpsi_hu
836         !!
837         xct = 1. + Ch_n10*xlogt/kappa/sqrt_Cd_n10
838         Ch  = Ch_n10*sqrt_Cd/sqrt_Cd_n10/xct
839         !!
840         xct = 1. + Ce_n10*xlogt/kappa/sqrt_Cd_n10
841         Ce  = Ce_n10*sqrt_Cd/sqrt_Cd_n10/xct
842         !!
843         !!
844      END DO
845      !!
846    END SUBROUTINE TURB_CORE_2Z
847
848
849    FUNCTION psi_m(zta)   !! Psis, L & Y eq. (8c), (8d), (8e)
850      REAL(wp), DIMENSION(jpi,jpj), INTENT(in) :: zta
851
852      REAL(wp), PARAMETER :: pi = 3.141592653589793_wp
853      REAL(wp), DIMENSION(jpi,jpj)             :: psi_m
854      REAL(wp), DIMENSION(jpi,jpj)             :: X2, X, stabit
855      X2 = sqrt(abs(1. - 16.*zta))  ;  X2 = max(X2 , 1.0) ;  X  = sqrt(X2)
856      stabit    = 0.5 + sign(0.5,zta)
857      psi_m = -5.*zta*stabit  &                                                  ! Stable
858           & + (1. - stabit)*(2*log((1. + X)/2) + log((1. + X2)/2) - 2*atan(X) + pi/2)  ! Unstable
859    END FUNCTION psi_m
860
861    FUNCTION psi_h(zta)    !! Psis, L & Y eq. (8c), (8d), (8e)
862      REAL(wp), DIMENSION(jpi,jpj), INTENT(in) :: zta
863
864      REAL(wp), DIMENSION(jpi,jpj)             :: psi_h
865      REAL(wp), DIMENSION(jpi,jpj)             :: X2, X, stabit
866      X2 = sqrt(abs(1. - 16.*zta))  ;  X2 = max(X2 , 1.) ;  X  = sqrt(X2)
867      stabit    = 0.5 + sign(0.5,zta)
868      psi_h = -5.*zta*stabit  &                                       ! Stable
869           & + (1. - stabit)*(2.*log( (1. + X2)/2. ))                 ! Unstable
870    END FUNCTION psi_h
871 
872   !!======================================================================
873END MODULE sbcblk_core
Note: See TracBrowser for help on using the repository browser.