source: branches/DEV_r2191_3partymerge2010/NEMO/TOP_SRC/LOBSTER/trcctl_lobster.F90 @ 2208

MODULE trcctl_lobster
   !!======================================================================
   !!                         ***  trcctl_lobster.F90  ***
   !! TOP :                Control of LOBSTER biological model
   !!======================================================================
   !!----------------------------------------------------------------------
   !! History :   1.0  !  2000-12 (E. Kestenare) assign a parameter to name individual tracers
   !!----------------------------------------------------------------------

#if defined key_lobster

   USE oce_trc
   USE trc


   IMPLICIT NONE
   PRIVATE

   PUBLIC trc_ctl_lobster     ! called by ???

   !!----------------------------------------------------------------------
   !! NEMO/TOP 1.0 , LOCEAN-IPSL (2005) 
   !! $Id$ 
   !! Software governed by the CeCILL licence  (NEMOGCM/License_CeCILL.txt)
   !!----------------------------------------------------------------------

CONTAINS

   SUBROUTINE trc_ctl_lobster
      !!----------------------------------------------------------------------
      !!                     ***  ROUTINE trc_ctl_lobster  ***
      !!
      !! ** Purpose :   control the cpp options, namelist and files 
      !!----------------------------------------------------------------------
      INTEGER :: jl, jn

      IF(lwp) WRITE(numout,*)
      IF(lwp) WRITE(numout,*) ' use LOBSTER biological model '

      ! Check number of tracers
      ! -----------------------
      IF (jp_lobster /= 6) THEN 
          IF (lwp) THEN 
              WRITE (numout,*) ' ===>>>> : w a r n i n g '
              WRITE (numout,*) ' =======   ============= '
              WRITE (numout,*)                             &
              &   ' STOP, change jp_lobster to 6 in '           &
              &   ,'par_lobster.F90 '  
          END IF 
          STOP 'TRC_CTL'
      END IF 

      ! Check tracer names
      ! ------------------
      IF(   ctrcnm(jpdet) /= 'DET' .OR. ctrcnm(jpzoo) /= 'ZOO' .OR.   &
         &  ctrcnm(jpphy) /= 'PHY' .OR. ctrcnm(jpno3) /= 'NO3' .OR.   &
         &  ctrcnm(jpnh4) /= 'NH4' .OR. ctrcnm(jpdom) /= 'DOM' .OR.   & 
         &  ctrcnl(jpdet) /= 'Detritus'                        .OR.   &
         &  ctrcnl(jpzoo) /= 'Zooplankton concentration'       .OR.   &
         &  ctrcnl(jpphy) /= 'Phytoplankton concentration'     .OR.   &
         &  ctrcnl(jpno3) /= 'Nitrate concentration'           .OR.   &
         &  ctrcnl(jpnh4) /= 'Ammonium concentration'          .OR.   &
         &  ctrcnl(jpdom) /= 'Dissolved organic matter' ) THEN 
         ctrcnm(jpdet)='DET'
         ctrcnl(jpdet)='Detritus'
         ctrcnm(jpzoo)='ZOO'
         ctrcnl(jpzoo)='Zooplankton concentration'
         ctrcnm(jpphy)='PHY'
         ctrcnl(jpphy)='Phytoplankton concentration'
         ctrcnm(jpno3)='NO3'
         ctrcnl(jpno3)='Nitrate concentration'
         ctrcnm(jpnh4)='NH4'
         ctrcnl(jpnh4)='Ammonium concentration'
         ctrcnm(jpdom)='DOM'
         ctrcnl(jpdom)='Dissolved organic matter'          
         IF(lwp) THEN
            WRITE (numout,*) ' ===>>>> : w a r n i n g '
            WRITE (numout,*) ' =======   ============= '
            WRITE (numout,*) ' we force tracer names'
            DO jl = 1, jp_lobster
               jn = jp_lob0 + jl - 1
               WRITE(numout,*) ' tracer nb: ',jn,' name = ',ctrcnm(jn), ctrcnl(jn)
            END DO
            WRITE(numout,*) ' '
         ENDIF 
      ENDIF 

      ! Check tracer units
      DO jl = 1, jp_lobster
         jn = jp_lob0 + jl - 1
         IF( ctrcun(jn) /= 'mmole-N/m3') THEN
            ctrcun(jn) = 'mmole-N/m3'
            IF(lwp) THEN
               WRITE (numout,*) ' ===>>>> : w a r n i n g '
               WRITE (numout,*) ' =======   ============= '
               WRITE (numout,*) ' we force tracer unit'
               WRITE(numout,*) ' tracer  ',ctrcnm(jn), 'UNIT= ',ctrcun(jn)
            ENDIF 
         ENDIF 
      END DO              
   END SUBROUTINE trc_ctl_lobster

#else
   !!----------------------------------------------------------------------
   !!  Empty module :                                          No LOBSTER
   !!----------------------------------------------------------------------
CONTAINS
   SUBROUTINE trc_ctl_lobster                 ! Dummy routine
   END SUBROUTINE trc_ctl_lobster
#endif

   !!======================================================================
END MODULE trcctl_lobster