| 1 | MODULE limhdf_2 |
|---|
| 2 | !!====================================================================== |
|---|
| 3 | !! *** MODULE limhdf_2 *** |
|---|
| 4 | !! LIM 2.0 ice model : horizontal diffusion of sea-ice quantities |
|---|
| 5 | !!====================================================================== |
|---|
| 6 | !! History : LIM ! 2000-01 (LIM) Original code |
|---|
| 7 | !! - ! 2001-05 (G. Madec, R. Hordoir) opa norm |
|---|
| 8 | !! 1.0 ! 2002-08 (C. Ethe) F90, free form |
|---|
| 9 | !!---------------------------------------------------------------------- |
|---|
| 10 | #if defined key_lim2 |
|---|
| 11 | !!---------------------------------------------------------------------- |
|---|
| 12 | !! 'key_lim2' LIM 2.0 sea-ice model |
|---|
| 13 | !!---------------------------------------------------------------------- |
|---|
| 14 | !! lim_hdf_2 : diffusion trend on sea-ice variable |
|---|
| 15 | !!---------------------------------------------------------------------- |
|---|
| 16 | USE dom_oce ! ocean domain |
|---|
| 17 | USE ice_2 ! LIM-2: ice variables |
|---|
| 18 | USE lbclnk ! lateral boundary condition - MPP exchanges |
|---|
| 19 | USE lib_mpp ! MPP library |
|---|
| 20 | USE wrk_nemo ! work arrays |
|---|
| 21 | USE prtctl ! Print control |
|---|
| 22 | USE in_out_manager ! I/O manager |
|---|
| 23 | |
|---|
| 24 | IMPLICIT NONE |
|---|
| 25 | PRIVATE |
|---|
| 26 | |
|---|
| 27 | PUBLIC lim_hdf_2 ! called by limtrp_2.F90 |
|---|
| 28 | |
|---|
| 29 | LOGICAL :: linit = .TRUE. ! ! initialization flag (set to flase after the 1st call) |
|---|
| 30 | REAL(wp) :: epsi04 = 1e-04 ! constant |
|---|
| 31 | |
|---|
| 32 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) :: efact ! metric coefficient |
|---|
| 33 | |
|---|
| 34 | !! * Substitution |
|---|
| 35 | # include "vectopt_loop_substitute.h90" |
|---|
| 36 | !!---------------------------------------------------------------------- |
|---|
| 37 | !! NEMO/LIM2 4.0 , UCL - NEMO Consortium (2010) |
|---|
| 38 | !! $Id$ |
|---|
| 39 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
|---|
| 40 | !!---------------------------------------------------------------------- |
|---|
| 41 | CONTAINS |
|---|
| 42 | |
|---|
| 43 | SUBROUTINE lim_hdf_2( ptab ) |
|---|
| 44 | !!------------------------------------------------------------------- |
|---|
| 45 | !! *** ROUTINE lim_hdf_2 *** |
|---|
| 46 | !! |
|---|
| 47 | !! ** purpose : Compute and add the diffusive trend on sea-ice variables |
|---|
| 48 | !! |
|---|
| 49 | !! ** method : Second order diffusive operator evaluated using a |
|---|
| 50 | !! Cranck-Nicholson time Scheme. |
|---|
| 51 | !! |
|---|
| 52 | !! ** Action : update ptab with the diffusive contribution |
|---|
| 53 | !!------------------------------------------------------------------- |
|---|
| 54 | REAL(wp), DIMENSION(jpi,jpj), INTENT( inout ) :: ptab ! Field on which the diffusion is applied |
|---|
| 55 | ! |
|---|
| 56 | INTEGER :: ji, jj ! dummy loop indices |
|---|
| 57 | INTEGER :: its, iter, ierr ! local integers |
|---|
| 58 | REAL(wp) :: zalfa, zrlxint, zconv, zeps ! local scalars |
|---|
| 59 | REAL(wp), DIMENSION(:,:), POINTER :: zrlx, zflu, zflv, zdiv0, zdiv, ztab0 |
|---|
| 60 | CHARACTER (len=55) :: charout |
|---|
| 61 | !!------------------------------------------------------------------- |
|---|
| 62 | |
|---|
| 63 | CALL wrk_alloc( jpi, jpj, zrlx, zflu, zflv, zdiv0, zdiv, ztab0 ) |
|---|
| 64 | |
|---|
| 65 | ! !== Initialisation ==! |
|---|
| 66 | ! |
|---|
| 67 | IF( linit ) THEN ! Metric coefficient (compute at the first call and saved in efact) |
|---|
| 68 | ALLOCATE( efact(jpi,jpj) , STAT=ierr ) |
|---|
| 69 | IF( lk_mpp ) CALL mpp_sum( ierr ) |
|---|
| 70 | IF( ierr /= 0 ) CALL ctl_stop( 'STOP', 'lim_hdf_2 : unable to allocate standard arrays' ) |
|---|
| 71 | DO jj = 2, jpjm1 |
|---|
| 72 | DO ji = fs_2 , fs_jpim1 ! vector opt. |
|---|
| 73 | efact(ji,jj) = ( e2u(ji,jj) + e2u(ji-1,jj) + e1v(ji,jj) + e1v(ji,jj-1) ) / ( e1t(ji,jj) * e2t(ji,jj) ) |
|---|
| 74 | END DO |
|---|
| 75 | END DO |
|---|
| 76 | linit = .FALSE. |
|---|
| 77 | ENDIF |
|---|
| 78 | ! |
|---|
| 79 | ! ! Time integration parameters |
|---|
| 80 | zalfa = 0.5_wp ! =1.0/0.5/0.0 = implicit/Cranck-Nicholson/explicit |
|---|
| 81 | its = 100 ! Maximum number of iteration |
|---|
| 82 | zeps = 2._wp * epsi04 |
|---|
| 83 | ! |
|---|
| 84 | ztab0(:, : ) = ptab(:,:) ! Arrays initialization |
|---|
| 85 | zdiv0(:, 1 ) = 0._wp |
|---|
| 86 | zdiv0(:,jpj) = 0._wp |
|---|
| 87 | IF( .NOT.lk_vopt_loop ) THEN |
|---|
| 88 | zflu (jpi,:) = 0._wp |
|---|
| 89 | zflv (jpi,:) = 0._wp |
|---|
| 90 | zdiv0(1, :) = 0._wp |
|---|
| 91 | zdiv0(jpi,:) = 0._wp |
|---|
| 92 | ENDIF |
|---|
| 93 | |
|---|
| 94 | zconv = 1._wp !== horizontal diffusion using a Crant-Nicholson scheme ==! |
|---|
| 95 | iter = 0 |
|---|
| 96 | ! |
|---|
| 97 | DO WHILE ( zconv > zeps .AND. iter <= its ) ! Sub-time step loop |
|---|
| 98 | ! |
|---|
| 99 | iter = iter + 1 ! incrementation of the sub-time step number |
|---|
| 100 | ! |
|---|
| 101 | DO jj = 1, jpjm1 ! diffusive fluxes in U- and V- direction |
|---|
| 102 | DO ji = 1 , fs_jpim1 ! vector opt. |
|---|
| 103 | zflu(ji,jj) = pahu(ji,jj) * e2u(ji,jj) / e1u(ji,jj) * ( ptab(ji+1,jj) - ptab(ji,jj) ) |
|---|
| 104 | zflv(ji,jj) = pahv(ji,jj) * e1v(ji,jj) / e2v(ji,jj) * ( ptab(ji,jj+1) - ptab(ji,jj) ) |
|---|
| 105 | END DO |
|---|
| 106 | END DO |
|---|
| 107 | ! |
|---|
| 108 | DO jj= 2, jpjm1 ! diffusive trend : divergence of the fluxes |
|---|
| 109 | DO ji = fs_2 , fs_jpim1 ! vector opt. |
|---|
| 110 | zdiv (ji,jj) = ( zflu(ji,jj) - zflu(ji-1,jj ) & |
|---|
| 111 | & + zflv(ji,jj) - zflv(ji ,jj-1) ) / ( e1t (ji,jj) * e2t (ji,jj) ) |
|---|
| 112 | END DO |
|---|
| 113 | END DO |
|---|
| 114 | ! |
|---|
| 115 | IF( iter == 1 ) zdiv0(:,:) = zdiv(:,:) ! save the 1st evaluation of the diffusive trend in zdiv0 |
|---|
| 116 | ! |
|---|
| 117 | DO jj = 2, jpjm1 ! iterative evaluation |
|---|
| 118 | DO ji = fs_2 , fs_jpim1 ! vector opt. |
|---|
| 119 | zrlxint = ( ztab0(ji,jj) & |
|---|
| 120 | & + rdt_ice * ( zalfa * ( zdiv(ji,jj) + efact(ji,jj) * ptab(ji,jj) ) & |
|---|
| 121 | & + ( 1.0 - zalfa ) * zdiv0(ji,jj) ) ) & |
|---|
| 122 | & / ( 1.0 + zalfa * rdt_ice * efact(ji,jj) ) |
|---|
| 123 | zrlx(ji,jj) = ptab(ji,jj) + om * ( zrlxint - ptab(ji,jj) ) |
|---|
| 124 | END DO |
|---|
| 125 | END DO |
|---|
| 126 | CALL lbc_lnk( zrlx, 'T', 1. ) ! lateral boundary condition |
|---|
| 127 | |
|---|
| 128 | zconv = 0._wp ! convergence test |
|---|
| 129 | |
|---|
| 130 | DO jj = 2, jpjm1 |
|---|
| 131 | DO ji = 2, jpim1 |
|---|
| 132 | zconv = MAX( zconv, ABS( zrlx(ji,jj) - ptab(ji,jj) ) ) |
|---|
| 133 | END DO |
|---|
| 134 | END DO |
|---|
| 135 | IF( lk_mpp ) CALL mpp_max( zconv ) ! max over the global domain |
|---|
| 136 | |
|---|
| 137 | ptab(:,:) = zrlx(:,:) |
|---|
| 138 | ! |
|---|
| 139 | END DO ! end of sub-time step loop |
|---|
| 140 | |
|---|
| 141 | IF(ln_ctl) THEN |
|---|
| 142 | zrlx(:,:) = ptab(:,:) - ztab0(:,:) |
|---|
| 143 | WRITE(charout,FMT="(' lim_hdf : zconv =',D23.16, ' iter =',I4,2X)") zconv, iter |
|---|
| 144 | CALL prt_ctl( tab2d_1=zrlx, clinfo1=charout ) |
|---|
| 145 | ENDIF |
|---|
| 146 | ! |
|---|
| 147 | CALL wrk_dealloc( jpi, jpj, zrlx, zflu, zflv, zdiv0, zdiv, ztab0 ) |
|---|
| 148 | ! |
|---|
| 149 | END SUBROUTINE lim_hdf_2 |
|---|
| 150 | |
|---|
| 151 | #else |
|---|
| 152 | !!---------------------------------------------------------------------- |
|---|
| 153 | !! Default option Dummy module NO LIM 2.0 sea-ice model |
|---|
| 154 | !!---------------------------------------------------------------------- |
|---|
| 155 | CONTAINS |
|---|
| 156 | SUBROUTINE lim_hdf_2 ! Empty routine |
|---|
| 157 | END SUBROUTINE lim_hdf_2 |
|---|
| 158 | #endif |
|---|
| 159 | |
|---|
| 160 | !!====================================================================== |
|---|
| 161 | END MODULE limhdf_2 |
|---|
