| 1 | MODULE iom_nf90 |
|---|
| 2 | !!===================================================================== |
|---|
| 3 | !! *** MODULE iom_nf90 *** |
|---|
| 4 | !! Input/Output manager : Library to read input files with NF90 (only fliocom module) |
|---|
| 5 | !!==================================================================== |
|---|
| 6 | !! History : 9.0 ! 05 12 (J. Belier) Original code |
|---|
| 7 | !! 9.0 ! 06 02 (S. Masson) Adaptation to NEMO |
|---|
| 8 | !! " ! 07 07 (D. Storkey) Changes to iom_nf90_gettime |
|---|
| 9 | !! ! 13 04 (J. Harle) Additions to iom_nf90_getatt |
|---|
| 10 | !!-------------------------------------------------------------------- |
|---|
| 11 | !!gm caution add !DIR nec: improved performance to be checked as well as no result changes |
|---|
| 12 | |
|---|
| 13 | !!-------------------------------------------------------------------- |
|---|
| 14 | !! iom_open : open a file read only |
|---|
| 15 | !! iom_close : close a file or all files opened by iom |
|---|
| 16 | !! iom_get : read a field (interfaced to several routines) |
|---|
| 17 | !! iom_gettime : read the time axis kvid in the file |
|---|
| 18 | !! iom_varid : get the id of a variable in a file |
|---|
| 19 | !! iom_rstput : write a field in a restart file (interfaced to several routines) |
|---|
| 20 | !!-------------------------------------------------------------------- |
|---|
| 21 | USE dom_oce ! ocean space and time domain |
|---|
| 22 | USE lbclnk ! lateal boundary condition / mpp exchanges |
|---|
| 23 | USE iom_def ! iom variables definitions |
|---|
| 24 | USE netcdf ! NetCDF library |
|---|
| 25 | USE in_out_manager ! I/O manager |
|---|
| 26 | USE lib_mpp ! MPP library |
|---|
| 27 | |
|---|
| 28 | IMPLICIT NONE |
|---|
| 29 | PRIVATE |
|---|
| 30 | |
|---|
| 31 | PUBLIC iom_nf90_open, iom_nf90_close, iom_nf90_varid, iom_nf90_get, iom_nf90_gettime, iom_nf90_rstput |
|---|
| 32 | PUBLIC iom_nf90_getatt |
|---|
| 33 | |
|---|
| 34 | INTERFACE iom_nf90_get |
|---|
| 35 | MODULE PROCEDURE iom_nf90_g0d, iom_nf90_g123d |
|---|
| 36 | END INTERFACE |
|---|
| 37 | INTERFACE iom_nf90_getatt |
|---|
| 38 | MODULE PROCEDURE iom_nf90_att |
|---|
| 39 | END INTERFACE |
|---|
| 40 | INTERFACE iom_nf90_rstput |
|---|
| 41 | MODULE PROCEDURE iom_nf90_rp0123d |
|---|
| 42 | END INTERFACE |
|---|
| 43 | |
|---|
| 44 | !!---------------------------------------------------------------------- |
|---|
| 45 | !! NEMO/OPA 3.3 , NEMO Consortium (2010) |
|---|
| 46 | !! $Id$ |
|---|
| 47 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
|---|
| 48 | !!---------------------------------------------------------------------- |
|---|
| 49 | |
|---|
| 50 | CONTAINS |
|---|
| 51 | |
|---|
| 52 | SUBROUTINE iom_nf90_open( cdname, kiomid, ldwrt, ldok, kdompar ) |
|---|
| 53 | !!--------------------------------------------------------------------- |
|---|
| 54 | !! *** SUBROUTINE iom_open *** |
|---|
| 55 | !! |
|---|
| 56 | !! ** Purpose : open an input file with NF90 |
|---|
| 57 | !!--------------------------------------------------------------------- |
|---|
| 58 | CHARACTER(len=*) , INTENT(inout) :: cdname ! File name |
|---|
| 59 | INTEGER , INTENT( out) :: kiomid ! nf90 identifier of the opened file |
|---|
| 60 | LOGICAL , INTENT(in ) :: ldwrt ! read or write the file? |
|---|
| 61 | LOGICAL , INTENT(in ) :: ldok ! check the existence |
|---|
| 62 | INTEGER, DIMENSION(2,5), INTENT(in ), OPTIONAL :: kdompar ! domain parameters: |
|---|
| 63 | |
|---|
| 64 | CHARACTER(LEN=100) :: clinfo ! info character |
|---|
| 65 | CHARACTER(LEN=100) :: cltmp ! temporary character |
|---|
| 66 | INTEGER :: iln ! lengths of character |
|---|
| 67 | INTEGER :: istop ! temporary storage of nstop |
|---|
| 68 | INTEGER :: if90id ! nf90 identifier of the opened file |
|---|
| 69 | INTEGER :: idmy ! dummy variable |
|---|
| 70 | INTEGER :: jl ! loop variable |
|---|
| 71 | INTEGER :: ichunk ! temporary storage of nn_chunksz |
|---|
| 72 | INTEGER :: imode ! creation mode flag: NF90_CLOBBER or NF90_NOCLOBBER or NF90_HDF5 |
|---|
| 73 | INTEGER :: ihdf5 ! local variable for retrieval of value for NF90_HDF5 |
|---|
| 74 | LOGICAL :: llclobber ! local definition of ln_clobber |
|---|
| 75 | !--------------------------------------------------------------------- |
|---|
| 76 | |
|---|
| 77 | clinfo = ' iom_nf90_open ~~~ ' |
|---|
| 78 | istop = nstop ! store the actual value of nstop |
|---|
| 79 | IF( nn_chunksz > 0 ) THEN ; ichunk = nn_chunksz |
|---|
| 80 | ELSE ; ichunk = NF90_SIZEHINT_DEFAULT |
|---|
| 81 | ENDIF |
|---|
| 82 | ! |
|---|
| 83 | llclobber = ldwrt .AND. ln_clobber |
|---|
| 84 | IF( ldok .AND. .NOT. llclobber ) THEN ! Open existing file... |
|---|
| 85 | ! ! ============= |
|---|
| 86 | IF( ldwrt ) THEN ! ... in write mode |
|---|
| 87 | IF(lwp) WRITE(numout,*) TRIM(clinfo)//' open existing file: '//TRIM(cdname)//' in WRITE mode' |
|---|
| 88 | IF( snc4set%luse ) THEN |
|---|
| 89 | CALL iom_nf90_check(NF90_OPEN( TRIM(cdname), NF90_WRITE , if90id ), clinfo) |
|---|
| 90 | ELSE |
|---|
| 91 | CALL iom_nf90_check(NF90_OPEN( TRIM(cdname), NF90_WRITE , if90id, chunksize = ichunk ), clinfo) |
|---|
| 92 | ENDIF |
|---|
| 93 | CALL iom_nf90_check(NF90_SET_FILL( if90id, NF90_NOFILL, idmy ), clinfo) |
|---|
| 94 | ELSE ! ... in read mode |
|---|
| 95 | IF(lwp) WRITE(numout,*) TRIM(clinfo)//' open existing file: '//TRIM(cdname)//' in READ mode' |
|---|
| 96 | CALL iom_nf90_check(NF90_OPEN( TRIM(cdname), NF90_NOWRITE, if90id, chunksize = ichunk ), clinfo) |
|---|
| 97 | ENDIF |
|---|
| 98 | ELSE ! the file does not exist (or we overwrite it) |
|---|
| 99 | ! ! ============= |
|---|
| 100 | iln = INDEX( cdname, '.nc' ) |
|---|
| 101 | IF( ldwrt ) THEN ! the file should be open in write mode so we create it... |
|---|
| 102 | IF( jpnij > 1 ) THEN |
|---|
| 103 | WRITE(cltmp,'(a,a,i4.4,a)') cdname(1:iln-1), '_', narea-1, '.nc' |
|---|
| 104 | cdname = TRIM(cltmp) |
|---|
| 105 | ENDIF |
|---|
| 106 | IF(lwp) WRITE(numout,*) TRIM(clinfo)//' create new file: '//TRIM(cdname)//' in WRITE mode' |
|---|
| 107 | |
|---|
| 108 | IF( llclobber ) THEN ; imode = IOR( NF90_64BIT_OFFSET, NF90_CLOBBER ) |
|---|
| 109 | ELSE ; imode = IOR( NF90_64BIT_OFFSET, NF90_NOCLOBBER ) |
|---|
| 110 | ENDIF |
|---|
| 111 | IF( snc4set%luse ) THEN |
|---|
| 112 | IF(lwp) WRITE(numout,*) TRIM(clinfo)//' creating file: '//TRIM(cdname)//' in hdf5 (netcdf4) mode' |
|---|
| 113 | CALL GET_NF90_SYMBOL("NF90_HDF5", ihdf5) |
|---|
| 114 | IF( llclobber ) THEN ; imode = IOR(ihdf5, NF90_CLOBBER) |
|---|
| 115 | ELSE ; imode = IOR(ihdf5, NF90_NOCLOBBER) |
|---|
| 116 | ENDIF |
|---|
| 117 | CALL iom_nf90_check(NF90_CREATE( TRIM(cdname), imode, if90id ), clinfo) |
|---|
| 118 | ELSE |
|---|
| 119 | CALL iom_nf90_check(NF90_CREATE( TRIM(cdname), imode, if90id, chunksize = ichunk ), clinfo) |
|---|
| 120 | ENDIF |
|---|
| 121 | CALL iom_nf90_check(NF90_SET_FILL( if90id, NF90_NOFILL, idmy ), clinfo) |
|---|
| 122 | ! define dimensions |
|---|
| 123 | CALL iom_nf90_check(NF90_DEF_DIM( if90id, 'x', kdompar(1,1) , idmy ), clinfo) |
|---|
| 124 | CALL iom_nf90_check(NF90_DEF_DIM( if90id, 'y', kdompar(2,1) , idmy ), clinfo) |
|---|
| 125 | CALL iom_nf90_check(NF90_DEF_DIM( if90id, 'z', jpk , idmy ), clinfo) |
|---|
| 126 | CALL iom_nf90_check(NF90_DEF_DIM( if90id, 't', NF90_UNLIMITED, idmy ), clinfo) |
|---|
| 127 | ! global attributes |
|---|
| 128 | CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_number_total' , jpnij ), clinfo) |
|---|
| 129 | CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_number' , narea-1 ), clinfo) |
|---|
| 130 | CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_dimensions_ids' , (/1 , 2 /) ), clinfo) |
|---|
| 131 | CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_size_global' , (/jpiglo, jpjglo/) ), clinfo) |
|---|
| 132 | CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_size_local' , kdompar(:,1) ), clinfo) |
|---|
| 133 | CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_position_first' , kdompar(:,2) ), clinfo) |
|---|
| 134 | CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_position_last' , kdompar(:,3) ), clinfo) |
|---|
| 135 | CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_halo_size_start', kdompar(:,4) ), clinfo) |
|---|
| 136 | CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_halo_size_end' , kdompar(:,5) ), clinfo) |
|---|
| 137 | CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_type' , 'BOX' ), clinfo) |
|---|
| 138 | ELSE ! the file should be open for read mode so it must exist... |
|---|
| 139 | CALL ctl_stop( TRIM(clinfo), ' should be impossible case...' ) |
|---|
| 140 | ENDIF |
|---|
| 141 | ENDIF |
|---|
| 142 | ! start to fill file informations |
|---|
| 143 | ! ============= |
|---|
| 144 | IF( istop == nstop ) THEN ! no error within this routine |
|---|
| 145 | !does not work with some compilers kiomid = MINLOC(iom_file(:)%nfid, dim = 1) |
|---|
| 146 | kiomid = 0 |
|---|
| 147 | DO jl = jpmax_files, 1, -1 |
|---|
| 148 | IF( iom_file(jl)%nfid == 0 ) kiomid = jl |
|---|
| 149 | ENDDO |
|---|
| 150 | iom_file(kiomid)%name = TRIM(cdname) |
|---|
| 151 | iom_file(kiomid)%nfid = if90id |
|---|
| 152 | iom_file(kiomid)%iolib = jpnf90 |
|---|
| 153 | iom_file(kiomid)%nvars = 0 |
|---|
| 154 | iom_file(kiomid)%irec = -1 ! useless for NetCDF files, used to know if the file is in define mode |
|---|
| 155 | CALL iom_nf90_check(NF90_Inquire(if90id, unlimitedDimId = iom_file(kiomid)%iduld), clinfo) |
|---|
| 156 | IF ( iom_file(kiomid)%iduld .GE. 0 ) THEN |
|---|
| 157 | CALL iom_nf90_check(NF90_Inquire_Dimension(if90id, iom_file(kiomid)%iduld, & |
|---|
| 158 | & name = iom_file(kiomid)%uldname), clinfo) |
|---|
| 159 | ENDIF |
|---|
| 160 | IF(lwp) WRITE(numout,*) ' ---> '//TRIM(cdname)//' OK' |
|---|
| 161 | ELSE |
|---|
| 162 | kiomid = 0 ! return error flag |
|---|
| 163 | ENDIF |
|---|
| 164 | ! |
|---|
| 165 | END SUBROUTINE iom_nf90_open |
|---|
| 166 | |
|---|
| 167 | |
|---|
| 168 | SUBROUTINE iom_nf90_close( kiomid ) |
|---|
| 169 | !!-------------------------------------------------------------------- |
|---|
| 170 | !! *** SUBROUTINE iom_nf90_close *** |
|---|
| 171 | !! |
|---|
| 172 | !! ** Purpose : close an input file with NF90 |
|---|
| 173 | !!-------------------------------------------------------------------- |
|---|
| 174 | INTEGER, INTENT(in) :: kiomid ! iom identifier of the file to be closed |
|---|
| 175 | CHARACTER(LEN=100) :: clinfo ! info character |
|---|
| 176 | !--------------------------------------------------------------------- |
|---|
| 177 | ! |
|---|
| 178 | clinfo = ' iom_nf90_close , file: '//TRIM(iom_file(kiomid)%name) |
|---|
| 179 | CALL iom_nf90_check(NF90_CLOSE(iom_file(kiomid)%nfid), clinfo) |
|---|
| 180 | ! |
|---|
| 181 | END SUBROUTINE iom_nf90_close |
|---|
| 182 | |
|---|
| 183 | |
|---|
| 184 | FUNCTION iom_nf90_varid ( kiomid, cdvar, kiv, kdimsz ) |
|---|
| 185 | !!----------------------------------------------------------------------- |
|---|
| 186 | !! *** FUNCTION iom_varid *** |
|---|
| 187 | !! |
|---|
| 188 | !! ** Purpose : get the id of a variable in a file with NF90 |
|---|
| 189 | !!----------------------------------------------------------------------- |
|---|
| 190 | INTEGER , INTENT(in ) :: kiomid ! file Identifier |
|---|
| 191 | CHARACTER(len=*) , INTENT(in ) :: cdvar ! name of the variable |
|---|
| 192 | INTEGER , INTENT(in ) :: kiv ! |
|---|
| 193 | INTEGER, DIMENSION(:), INTENT( out), OPTIONAL :: kdimsz ! size of the dimensions |
|---|
| 194 | ! |
|---|
| 195 | INTEGER :: iom_nf90_varid ! iom variable Id |
|---|
| 196 | INTEGER :: if90id ! nf90 file identifier |
|---|
| 197 | INTEGER :: ji ! dummy loop index |
|---|
| 198 | INTEGER :: ivarid ! NetCDF variable Id |
|---|
| 199 | INTEGER :: i_nvd ! number of dimension of the variable |
|---|
| 200 | INTEGER, DIMENSION(jpmax_dims) :: idimid ! dimension ids of the variable |
|---|
| 201 | LOGICAL :: llok ! ok test |
|---|
| 202 | CHARACTER(LEN=100) :: clinfo ! info character |
|---|
| 203 | !!----------------------------------------------------------------------- |
|---|
| 204 | clinfo = ' iom_nf90_varid, file: '//TRIM(iom_file(kiomid)%name)//', var: '//TRIM(cdvar) |
|---|
| 205 | iom_nf90_varid = 0 ! default definition |
|---|
| 206 | IF( PRESENT(kdimsz) ) kdimsz(:) = 0 ! default definition |
|---|
| 207 | if90id = iom_file(kiomid)%nfid ! get back NetCDF file id |
|---|
| 208 | ! |
|---|
| 209 | llok = NF90_INQ_VARID( if90id, TRIM(cdvar), ivarid ) == nf90_noerr ! does the variable exist in the file |
|---|
| 210 | IF( llok ) THEN |
|---|
| 211 | iom_nf90_varid = kiv |
|---|
| 212 | iom_file(kiomid)%nvars = kiv |
|---|
| 213 | iom_file(kiomid)%nvid(kiv) = ivarid |
|---|
| 214 | iom_file(kiomid)%cn_var(kiv) = TRIM(cdvar) |
|---|
| 215 | CALL iom_nf90_check(NF90_Inquire_Variable(if90id, ivarid, ndims = i_nvd), clinfo) ! number of dimensions |
|---|
| 216 | iom_file(kiomid)%ndims(kiv) = i_nvd |
|---|
| 217 | CALL iom_nf90_check(NF90_Inquire_Variable(if90id, ivarid, dimids = idimid(1:i_nvd)), clinfo) ! dimensions ids |
|---|
| 218 | iom_file(kiomid)%luld(kiv) = .FALSE. ! default value |
|---|
| 219 | DO ji = 1, i_nvd ! dimensions size |
|---|
| 220 | CALL iom_nf90_check(NF90_Inquire_Dimension(if90id, idimid(ji), len = iom_file(kiomid)%dimsz(ji,kiv)), clinfo) |
|---|
| 221 | IF( idimid(ji) == iom_file(kiomid)%iduld ) iom_file(kiomid)%luld(kiv) = .TRUE. ! unlimited dimension? |
|---|
| 222 | END DO |
|---|
| 223 | !---------- Deal with scale_factor and add_offset |
|---|
| 224 | llok = NF90_Inquire_attribute(if90id, ivarid, 'scale_factor') == nf90_noerr |
|---|
| 225 | IF( llok) THEN |
|---|
| 226 | CALL iom_nf90_check(NF90_GET_ATT(if90id, ivarid, 'scale_factor', iom_file(kiomid)%scf(kiv)), clinfo) |
|---|
| 227 | ELSE |
|---|
| 228 | iom_file(kiomid)%scf(kiv) = 1. |
|---|
| 229 | END IF |
|---|
| 230 | llok = NF90_Inquire_attribute(if90id, ivarid, 'add_offset') == nf90_noerr |
|---|
| 231 | IF( llok ) THEN |
|---|
| 232 | CALL iom_nf90_check(NF90_GET_ATT(if90id, ivarid, 'add_offset', iom_file(kiomid)%ofs(kiv)), clinfo) |
|---|
| 233 | ELSE |
|---|
| 234 | iom_file(kiomid)%ofs(kiv) = 0. |
|---|
| 235 | END IF |
|---|
| 236 | ! return the simension size |
|---|
| 237 | IF( PRESENT(kdimsz) ) THEN |
|---|
| 238 | IF( i_nvd == SIZE(kdimsz) ) THEN |
|---|
| 239 | kdimsz(:) = iom_file(kiomid)%dimsz(1:i_nvd,kiv) |
|---|
| 240 | ELSE |
|---|
| 241 | WRITE(ctmp1,*) i_nvd, SIZE(kdimsz) |
|---|
| 242 | CALL ctl_stop( TRIM(clinfo), 'error in kdimsz size'//TRIM(ctmp1) ) |
|---|
| 243 | ENDIF |
|---|
| 244 | ENDIF |
|---|
| 245 | ELSE |
|---|
| 246 | iom_nf90_varid = -1 ! variable not found, return error code: -1 |
|---|
| 247 | ENDIF |
|---|
| 248 | ! |
|---|
| 249 | END FUNCTION iom_nf90_varid |
|---|
| 250 | |
|---|
| 251 | |
|---|
| 252 | SUBROUTINE iom_nf90_g0d( kiomid, kvid, pvar ) |
|---|
| 253 | !!----------------------------------------------------------------------- |
|---|
| 254 | !! *** ROUTINE iom_nf90_g0d *** |
|---|
| 255 | !! |
|---|
| 256 | !! ** Purpose : read a scalar with NF90 |
|---|
| 257 | !!----------------------------------------------------------------------- |
|---|
| 258 | INTEGER , INTENT(in ) :: kiomid ! Identifier of the file |
|---|
| 259 | INTEGER , INTENT(in ) :: kvid ! variable id |
|---|
| 260 | REAL(wp), INTENT( out) :: pvar ! read field |
|---|
| 261 | ! |
|---|
| 262 | CHARACTER(LEN=100) :: clinfo ! info character |
|---|
| 263 | !--------------------------------------------------------------------- |
|---|
| 264 | clinfo = 'iom_nf90_g0d , file: '//TRIM(iom_file(kiomid)%name)//', var: '//TRIM(iom_file(kiomid)%cn_var(kvid)) |
|---|
| 265 | CALL iom_nf90_check(NF90_GET_VAR(iom_file(kiomid)%nfid, iom_file(kiomid)%nvid(kvid), pvar), clinfo ) |
|---|
| 266 | ! |
|---|
| 267 | END SUBROUTINE iom_nf90_g0d |
|---|
| 268 | |
|---|
| 269 | |
|---|
| 270 | SUBROUTINE iom_nf90_g123d( kiomid, kvid, knbdim, kstart, kcount, kx1, kx2, ky1, ky2, & |
|---|
| 271 | & pv_r1d, pv_r2d, pv_r3d ) |
|---|
| 272 | !!----------------------------------------------------------------------- |
|---|
| 273 | !! *** ROUTINE iom_nf90_g123d *** |
|---|
| 274 | !! |
|---|
| 275 | !! ** Purpose : read a 1D/2D/3D variable with NF90 |
|---|
| 276 | !! |
|---|
| 277 | !! ** Method : read ONE record at each CALL |
|---|
| 278 | !!----------------------------------------------------------------------- |
|---|
| 279 | INTEGER , INTENT(in ) :: kiomid ! iom identifier of the file |
|---|
| 280 | INTEGER , INTENT(in ) :: kvid ! Name of the variable |
|---|
| 281 | INTEGER , INTENT(in ) :: knbdim ! number of dimensions of the variable |
|---|
| 282 | INTEGER , DIMENSION(:) , INTENT(in ) :: kstart ! start position of the reading in each axis |
|---|
| 283 | INTEGER , DIMENSION(:) , INTENT(in ) :: kcount ! number of points to be read in each axis |
|---|
| 284 | INTEGER , INTENT(in ) :: kx1, kx2, ky1, ky2 ! subdomain indexes |
|---|
| 285 | REAL(wp), DIMENSION(:) , INTENT( out), OPTIONAL :: pv_r1d ! read field (1D case) |
|---|
| 286 | REAL(wp), DIMENSION(:,:) , INTENT( out), OPTIONAL :: pv_r2d ! read field (2D case) |
|---|
| 287 | REAL(wp), DIMENSION(:,:,:) , INTENT( out), OPTIONAL :: pv_r3d ! read field (3D case) |
|---|
| 288 | ! |
|---|
| 289 | CHARACTER(LEN=100) :: clinfo ! info character |
|---|
| 290 | INTEGER :: if90id ! nf90 identifier of the opened file |
|---|
| 291 | INTEGER :: ivid ! nf90 variable id |
|---|
| 292 | !--------------------------------------------------------------------- |
|---|
| 293 | clinfo = 'iom_nf90_g123d , file: '//TRIM(iom_file(kiomid)%name)//', var: '//TRIM(iom_file(kiomid)%cn_var(kvid)) |
|---|
| 294 | if90id = iom_file(kiomid)%nfid ! get back NetCDF file id |
|---|
| 295 | ivid = iom_file(kiomid)%nvid(kvid) ! get back NetCDF var id |
|---|
| 296 | ! |
|---|
| 297 | IF( PRESENT(pv_r1d) ) THEN |
|---|
| 298 | CALL iom_nf90_check( NF90_GET_VAR(if90id, ivid, pv_r1d(: ), start = kstart(1:knbdim), & |
|---|
| 299 | & count = kcount(1:knbdim)), clinfo ) |
|---|
| 300 | ELSEIF( PRESENT(pv_r2d) ) THEN |
|---|
| 301 | CALL iom_nf90_check( NF90_GET_VAR(if90id, ivid, pv_r2d(kx1:kx2,ky1:ky2 ), start = kstart(1:knbdim), & |
|---|
| 302 | & count = kcount(1:knbdim)), clinfo ) |
|---|
| 303 | ELSEIF( PRESENT(pv_r3d) ) THEN |
|---|
| 304 | CALL iom_nf90_check( NF90_GET_VAR(if90id, ivid, pv_r3d(kx1:kx2,ky1:ky2,:), start = kstart(1:knbdim), & |
|---|
| 305 | & count = kcount(1:knbdim)), clinfo ) |
|---|
| 306 | ENDIF |
|---|
| 307 | ! |
|---|
| 308 | END SUBROUTINE iom_nf90_g123d |
|---|
| 309 | |
|---|
| 310 | |
|---|
| 311 | SUBROUTINE iom_nf90_att( kiomid, cdatt, pv_i0d, pv_r0d, cdvar) |
|---|
| 312 | !!----------------------------------------------------------------------- |
|---|
| 313 | !! *** ROUTINE iom_nf90_att *** |
|---|
| 314 | !! |
|---|
| 315 | !! ** Purpose : read an integer attribute with NF90 |
|---|
| 316 | !!----------------------------------------------------------------------- |
|---|
| 317 | INTEGER , INTENT(in ) :: kiomid ! Identifier of the file |
|---|
| 318 | CHARACTER(len=*), INTENT(in ) :: cdatt ! attribute name |
|---|
| 319 | INTEGER , INTENT( out), OPTIONAL :: pv_i0d ! read field |
|---|
| 320 | REAL(wp), INTENT( out), OPTIONAL :: pv_r0d ! read field |
|---|
| 321 | CHARACTER(len=*), INTENT(in ), OPTIONAL :: cdvar ! name of the variable |
|---|
| 322 | ! |
|---|
| 323 | INTEGER :: if90id ! temporary integer |
|---|
| 324 | INTEGER :: ivarid ! NetCDF variable Id |
|---|
| 325 | LOGICAL :: llok ! temporary logical |
|---|
| 326 | CHARACTER(LEN=100) :: clinfo ! info character |
|---|
| 327 | !--------------------------------------------------------------------- |
|---|
| 328 | ! |
|---|
| 329 | if90id = iom_file(kiomid)%nfid |
|---|
| 330 | IF( PRESENT(cdvar) ) THEN |
|---|
| 331 | llok = NF90_INQ_VARID( if90id, TRIM(cdvar), ivarid ) == nf90_noerr ! does the variable exist in the file |
|---|
| 332 | IF( llok ) THEN |
|---|
| 333 | llok = NF90_Inquire_attribute(if90id, ivarid, cdatt) == nf90_noerr |
|---|
| 334 | ELSE |
|---|
| 335 | CALL ctl_warn('iom_nf90_getatt: no variable '//cdvar//' found') |
|---|
| 336 | ENDIF |
|---|
| 337 | ELSE |
|---|
| 338 | llok = NF90_Inquire_attribute(if90id, NF90_GLOBAL, cdatt) == nf90_noerr |
|---|
| 339 | ENDIF |
|---|
| 340 | ! |
|---|
| 341 | IF( llok) THEN |
|---|
| 342 | clinfo = 'iom_nf90_getatt, file: '//TRIM(iom_file(kiomid)%name)//', att: '//TRIM(cdatt) |
|---|
| 343 | IF( PRESENT(pv_r0d) ) THEN |
|---|
| 344 | IF( PRESENT(cdvar) ) THEN |
|---|
| 345 | CALL iom_nf90_check(NF90_GET_ATT(if90id, ivarid, cdatt, values=pv_r0d), clinfo) |
|---|
| 346 | ELSE |
|---|
| 347 | CALL iom_nf90_check(NF90_GET_ATT(if90id, NF90_GLOBAL, cdatt, values=pv_r0d), clinfo) |
|---|
| 348 | ENDIF |
|---|
| 349 | ELSE |
|---|
| 350 | IF( PRESENT(cdvar) ) THEN |
|---|
| 351 | CALL iom_nf90_check(NF90_GET_ATT(if90id, ivarid, cdatt, values=pv_i0d), clinfo) |
|---|
| 352 | ELSE |
|---|
| 353 | CALL iom_nf90_check(NF90_GET_ATT(if90id, NF90_GLOBAL, cdatt, values=pv_i0d), clinfo) |
|---|
| 354 | ENDIF |
|---|
| 355 | ENDIF |
|---|
| 356 | ELSE |
|---|
| 357 | CALL ctl_warn('iom_nf90_getatt: no attribute '//cdatt//' found') |
|---|
| 358 | IF( PRESENT(pv_r0d) ) THEN |
|---|
| 359 | pv_r0d = -999._wp |
|---|
| 360 | ELSE |
|---|
| 361 | pv_i0d = -999 |
|---|
| 362 | ENDIF |
|---|
| 363 | ENDIF |
|---|
| 364 | ! |
|---|
| 365 | END SUBROUTINE iom_nf90_att |
|---|
| 366 | |
|---|
| 367 | |
|---|
| 368 | SUBROUTINE iom_nf90_gettime( kiomid, kvid, ptime, cdunits, cdcalendar ) |
|---|
| 369 | !!-------------------------------------------------------------------- |
|---|
| 370 | !! *** SUBROUTINE iom_gettime *** |
|---|
| 371 | !! |
|---|
| 372 | !! ** Purpose : read the time axis kvid in the file with NF90 |
|---|
| 373 | !!-------------------------------------------------------------------- |
|---|
| 374 | INTEGER , INTENT(in ) :: kiomid ! file Identifier |
|---|
| 375 | INTEGER , INTENT(in ) :: kvid ! variable id |
|---|
| 376 | REAL(wp), DIMENSION(:) , INTENT( out) :: ptime ! the time axis |
|---|
| 377 | CHARACTER(len=*), OPTIONAL, INTENT( out) :: cdunits ! units attribute |
|---|
| 378 | CHARACTER(len=*), OPTIONAL, INTENT( out) :: cdcalendar ! calendar attribute |
|---|
| 379 | ! |
|---|
| 380 | CHARACTER(LEN=100) :: clinfo ! info character |
|---|
| 381 | !--------------------------------------------------------------------- |
|---|
| 382 | clinfo = 'iom_nf90_gettime, file: '//TRIM(iom_file(kiomid)%name)//', var: '//TRIM(iom_file(kiomid)%cn_var(kvid)) |
|---|
| 383 | CALL iom_nf90_check(NF90_GET_VAR(iom_file(kiomid)%nfid, iom_file(kiomid)%nvid(kvid), ptime(:), & |
|---|
| 384 | & start=(/ 1 /), count=(/ iom_file(kiomid)%dimsz(1, kvid) /)), clinfo) |
|---|
| 385 | IF ( PRESENT(cdunits) ) THEN |
|---|
| 386 | CALL iom_nf90_check(NF90_GET_ATT(iom_file(kiomid)%nfid, iom_file(kiomid)%nvid(kvid), "units", & |
|---|
| 387 | & values=cdunits), clinfo) |
|---|
| 388 | ENDIF |
|---|
| 389 | IF ( PRESENT(cdcalendar) ) THEN |
|---|
| 390 | CALL iom_nf90_check(NF90_GET_ATT(iom_file(kiomid)%nfid, iom_file(kiomid)%nvid(kvid), "calendar", & |
|---|
| 391 | & values=cdcalendar), clinfo) |
|---|
| 392 | ENDIF |
|---|
| 393 | ! |
|---|
| 394 | END SUBROUTINE iom_nf90_gettime |
|---|
| 395 | |
|---|
| 396 | |
|---|
| 397 | SUBROUTINE iom_nf90_rp0123d( kt, kwrite, kiomid, cdvar , kvid , ktype, & |
|---|
| 398 | & pv_r0d, pv_r1d, pv_r2d, pv_r3d ) |
|---|
| 399 | !!-------------------------------------------------------------------- |
|---|
| 400 | !! *** SUBROUTINE iom_nf90_rstput *** |
|---|
| 401 | !! |
|---|
| 402 | !! ** Purpose : read the time axis cdvar in the file |
|---|
| 403 | !!-------------------------------------------------------------------- |
|---|
| 404 | INTEGER , INTENT(in) :: kt ! ocean time-step |
|---|
| 405 | INTEGER , INTENT(in) :: kwrite ! writing time-step |
|---|
| 406 | INTEGER , INTENT(in) :: kiomid ! Identifier of the file |
|---|
| 407 | CHARACTER(len=*) , INTENT(in) :: cdvar ! variable name |
|---|
| 408 | INTEGER , INTENT(in) :: kvid ! variable id |
|---|
| 409 | INTEGER , INTENT(in), OPTIONAL :: ktype ! variable type (default R8) |
|---|
| 410 | REAL(wp) , INTENT(in), OPTIONAL :: pv_r0d ! written Od field |
|---|
| 411 | REAL(wp), DIMENSION( :), INTENT(in), OPTIONAL :: pv_r1d ! written 1d field |
|---|
| 412 | REAL(wp), DIMENSION(:, : ), INTENT(in), OPTIONAL :: pv_r2d ! written 2d field |
|---|
| 413 | REAL(wp), DIMENSION(:, :, :), INTENT(in), OPTIONAL :: pv_r3d ! written 3d field |
|---|
| 414 | ! |
|---|
| 415 | INTEGER :: idims ! number of dimension |
|---|
| 416 | INTEGER :: idvar ! variable id |
|---|
| 417 | INTEGER :: jd ! dimension loop counter |
|---|
| 418 | INTEGER :: ix1, ix2, iy1, iy2 ! subdomain indexes |
|---|
| 419 | INTEGER, DIMENSION(4) :: idimsz ! dimensions size |
|---|
| 420 | INTEGER, DIMENSION(4) :: idimid ! dimensions id |
|---|
| 421 | CHARACTER(LEN=100) :: clinfo ! info character |
|---|
| 422 | CHARACTER(LEN= 12), DIMENSION(4) :: cltmp ! temporary character |
|---|
| 423 | INTEGER :: if90id ! nf90 file identifier |
|---|
| 424 | INTEGER :: idmy ! dummy variable |
|---|
| 425 | INTEGER :: itype ! variable type |
|---|
| 426 | INTEGER, DIMENSION(4) :: ichunksz ! NetCDF4 chunk sizes. Will be computed using |
|---|
| 427 | ! nn_nchunks_[i,j,k,t] namelist parameters |
|---|
| 428 | INTEGER :: ichunkalg, ishuffle,& |
|---|
| 429 | ideflate, ideflate_level |
|---|
| 430 | ! NetCDF4 internally fixed parameters |
|---|
| 431 | LOGICAL :: lchunk ! logical switch to activate chunking and compression |
|---|
| 432 | ! when appropriate (currently chunking is applied to 4d fields only) |
|---|
| 433 | !--------------------------------------------------------------------- |
|---|
| 434 | ! |
|---|
| 435 | clinfo = ' iom_nf90_rp0123d, file: '//TRIM(iom_file(kiomid)%name)//', var: '//TRIM(cdvar) |
|---|
| 436 | if90id = iom_file(kiomid)%nfid |
|---|
| 437 | ! |
|---|
| 438 | ! define dimension variables if it is not already done |
|---|
| 439 | ! ========================== |
|---|
| 440 | IF( iom_file(kiomid)%nvars == 0 ) THEN |
|---|
| 441 | ! are we in define mode? |
|---|
| 442 | IF( iom_file(kiomid)%irec /= -1 ) THEN ! trick: irec used to know if the file is in define mode or not |
|---|
| 443 | CALL iom_nf90_check(NF90_REDEF( if90id ), clinfo) ; iom_file(kiomid)%irec = -1 |
|---|
| 444 | ENDIF |
|---|
| 445 | ! define the dimension variables if it is not already done |
|---|
| 446 | cltmp = (/ 'nav_lon ', 'nav_lat ', 'nav_lev ', 'time_counter' /) |
|---|
| 447 | CALL iom_nf90_check(NF90_DEF_VAR( if90id, TRIM(cltmp(1)), NF90_FLOAT , (/ 1, 2 /), iom_file(kiomid)%nvid(1) ), clinfo) |
|---|
| 448 | CALL iom_nf90_check(NF90_DEF_VAR( if90id, TRIM(cltmp(2)), NF90_FLOAT , (/ 1, 2 /), iom_file(kiomid)%nvid(2) ), clinfo) |
|---|
| 449 | CALL iom_nf90_check(NF90_DEF_VAR( if90id, TRIM(cltmp(3)), NF90_FLOAT , (/ 3 /), iom_file(kiomid)%nvid(3) ), clinfo) |
|---|
| 450 | CALL iom_nf90_check(NF90_DEF_VAR( if90id, TRIM(cltmp(4)), NF90_DOUBLE, (/ 4 /), iom_file(kiomid)%nvid(4) ), clinfo) |
|---|
| 451 | ! update informations structure related the dimension variable we just added... |
|---|
| 452 | iom_file(kiomid)%nvars = 4 |
|---|
| 453 | iom_file(kiomid)%luld(1:4) = (/ .FALSE., .FALSE., .FALSE., .TRUE. /) |
|---|
| 454 | iom_file(kiomid)%cn_var(1:4) = cltmp |
|---|
| 455 | iom_file(kiomid)%ndims(1:4) = (/ 2, 2, 1, 1 /) |
|---|
| 456 | ! trick: defined to 0 to say that dimension variables are defined but not yet written |
|---|
| 457 | iom_file(kiomid)%dimsz(1, 1) = 0 |
|---|
| 458 | IF(lwp) WRITE(numout,*) TRIM(clinfo)//' define dimension variables done' |
|---|
| 459 | ENDIF |
|---|
| 460 | ! define the data if it is not already done |
|---|
| 461 | ! =============== |
|---|
| 462 | IF( kvid <= 0 ) THEN |
|---|
| 463 | ! |
|---|
| 464 | ! NetCDF4 chunking and compression fixed settings |
|---|
| 465 | ichunkalg = 0 |
|---|
| 466 | ishuffle = 1 |
|---|
| 467 | ideflate = 1 |
|---|
| 468 | ideflate_level = 1 |
|---|
| 469 | ! |
|---|
| 470 | idvar = iom_file(kiomid)%nvars + 1 |
|---|
| 471 | ! are we in define mode? |
|---|
| 472 | IF( iom_file(kiomid)%irec /= -1 ) THEN ! trick: irec used to know if the file is in define mode or not |
|---|
| 473 | CALL iom_nf90_check(NF90_REDEF( if90id ), clinfo) ; iom_file(kiomid)%irec = -1 |
|---|
| 474 | ENDIF |
|---|
| 475 | ! variable definition |
|---|
| 476 | IF( PRESENT(pv_r0d) ) THEN ; idims = 0 |
|---|
| 477 | ELSEIF( PRESENT(pv_r1d) ) THEN ; idims = 2 ; idimid(1:idims) = (/ 3,4/) |
|---|
| 478 | ELSEIF( PRESENT(pv_r2d) ) THEN ; idims = 3 ; idimid(1:idims) = (/1,2 ,4/) |
|---|
| 479 | ELSEIF( PRESENT(pv_r3d) ) THEN ; idims = 4 ; idimid(1:idims) = (/1,2,3,4/) |
|---|
| 480 | ENDIF |
|---|
| 481 | IF( PRESENT(ktype) ) THEN ! variable external type |
|---|
| 482 | SELECT CASE (ktype) |
|---|
| 483 | CASE (jp_r8) ; itype = NF90_DOUBLE |
|---|
| 484 | CASE (jp_r4) ; itype = NF90_FLOAT |
|---|
| 485 | CASE (jp_i4) ; itype = NF90_INT |
|---|
| 486 | CASE (jp_i2) ; itype = NF90_SHORT |
|---|
| 487 | CASE (jp_i1) ; itype = NF90_BYTE |
|---|
| 488 | CASE DEFAULT ; CALL ctl_stop( TRIM(clinfo)//' unknown variable type' ) |
|---|
| 489 | END SELECT |
|---|
| 490 | ELSE |
|---|
| 491 | itype = NF90_DOUBLE |
|---|
| 492 | ENDIF |
|---|
| 493 | IF( PRESENT(pv_r0d) ) THEN |
|---|
| 494 | CALL iom_nf90_check(NF90_DEF_VAR( if90id, TRIM(cdvar), itype, & |
|---|
| 495 | & iom_file(kiomid)%nvid(idvar) ), clinfo) |
|---|
| 496 | ELSE |
|---|
| 497 | CALL iom_nf90_check(NF90_DEF_VAR( if90id, TRIM(cdvar), itype, idimid(1:idims), & |
|---|
| 498 | & iom_file(kiomid)%nvid(idvar) ), clinfo) |
|---|
| 499 | ENDIF |
|---|
| 500 | lchunk = .false. |
|---|
| 501 | IF( snc4set%luse .AND. idims.eq.4 ) lchunk = .true. |
|---|
| 502 | ! update informations structure related the new variable we want to add... |
|---|
| 503 | iom_file(kiomid)%nvars = idvar |
|---|
| 504 | iom_file(kiomid)%cn_var(idvar) = TRIM(cdvar) |
|---|
| 505 | iom_file(kiomid)%scf(idvar) = 1. |
|---|
| 506 | iom_file(kiomid)%ofs(idvar) = 0. |
|---|
| 507 | iom_file(kiomid)%ndims(idvar) = idims |
|---|
| 508 | IF( .NOT. PRESENT(pv_r0d) ) THEN ; iom_file(kiomid)%luld(idvar) = .TRUE. |
|---|
| 509 | ELSE ; iom_file(kiomid)%luld(idvar) = .FALSE. |
|---|
| 510 | ENDIF |
|---|
| 511 | DO jd = 1, idims |
|---|
| 512 | CALL iom_nf90_check(NF90_INQUIRE_DIMENSION( if90id, idimid(jd), len = iom_file(kiomid)%dimsz(jd,idvar) ), clinfo) |
|---|
| 513 | IF ( lchunk ) ichunksz(jd) = iom_file(kiomid)%dimsz(jd,idvar) |
|---|
| 514 | END DO |
|---|
| 515 | IF ( lchunk ) THEN |
|---|
| 516 | ! Calculate chunk sizes by partitioning each dimension as requested in namnc4 namelist |
|---|
| 517 | ! Disallow very small chunk sizes and prevent chunk sizes larger than each individual dimension |
|---|
| 518 | ichunksz(1) = MIN( ichunksz(1),MAX( (ichunksz(1)-1)/snc4set%ni + 1 ,16 ) ) ! Suggested default nc4set%ni=4 |
|---|
| 519 | ichunksz(2) = MIN( ichunksz(2),MAX( (ichunksz(2)-1)/snc4set%nj + 1 ,16 ) ) ! Suggested default nc4set%nj=2 |
|---|
| 520 | ichunksz(3) = MIN( ichunksz(3),MAX( (ichunksz(3)-1)/snc4set%nk + 1 , 1 ) ) ! Suggested default nc4set%nk=6 |
|---|
| 521 | ichunksz(4) = 1 ! Do not allow chunks to span the |
|---|
| 522 | ! unlimited dimension |
|---|
| 523 | CALL iom_nf90_check(SET_NF90_DEF_VAR_CHUNKING(if90id, idvar, ichunkalg, ichunksz), clinfo) |
|---|
| 524 | CALL iom_nf90_check(SET_NF90_DEF_VAR_DEFLATE(if90id, idvar, ishuffle, ideflate, ideflate_level), clinfo) |
|---|
| 525 | IF(lwp) WRITE(numout,*) TRIM(clinfo)//' chunked ok. Chunks sizes: ', ichunksz |
|---|
| 526 | ENDIF |
|---|
| 527 | IF(lwp) WRITE(numout,*) TRIM(clinfo)//' defined ok' |
|---|
| 528 | ELSE |
|---|
| 529 | idvar = kvid |
|---|
| 530 | ENDIF |
|---|
| 531 | |
|---|
| 532 | ! time step kwrite : write the variable |
|---|
| 533 | IF( kt == kwrite ) THEN |
|---|
| 534 | ! are we in write mode? |
|---|
| 535 | IF( iom_file(kiomid)%irec == -1 ) THEN ! trick: irec used to know if the file is in define mode or not |
|---|
| 536 | CALL iom_nf90_check(NF90_ENDDEF( if90id ), clinfo) ; iom_file(kiomid)%irec = 0 |
|---|
| 537 | ENDIF |
|---|
| 538 | ! on what kind of domain must the data be written? |
|---|
| 539 | IF( PRESENT(pv_r2d) .OR. PRESENT(pv_r3d) ) THEN |
|---|
| 540 | idimsz(1:2) = iom_file(kiomid)%dimsz(1:2,idvar) |
|---|
| 541 | IF( idimsz(1) == (nlei - nldi + 1) .AND. idimsz(2) == (nlej - nldj + 1) ) THEN |
|---|
| 542 | ix1 = nldi ; ix2 = nlei ; iy1 = nldj ; iy2 = nlej |
|---|
| 543 | ELSEIF( idimsz(1) == nlci .AND. idimsz(2) == nlcj ) THEN |
|---|
| 544 | ix1 = 1 ; ix2 = nlci ; iy1 = 1 ; iy2 = nlcj |
|---|
| 545 | ELSEIF( idimsz(1) == jpi .AND. idimsz(2) == jpj ) THEN |
|---|
| 546 | ix1 = 1 ; ix2 = jpi ; iy1 = 1 ; iy2 = jpj |
|---|
| 547 | ELSE |
|---|
| 548 | CALL ctl_stop( 'iom_nf90_rp0123d: should have been an impossible case...' ) |
|---|
| 549 | ENDIF |
|---|
| 550 | |
|---|
| 551 | ! write dimension variables if it is not already done |
|---|
| 552 | ! ============= |
|---|
| 553 | ! trick: is defined to 0 => dimension variable are defined but not yet written |
|---|
| 554 | IF( iom_file(kiomid)%dimsz(1, 1) == 0 ) THEN |
|---|
| 555 | CALL iom_nf90_check(NF90_INQ_VARID( if90id, 'nav_lon' , idmy ), clinfo) |
|---|
| 556 | CALL iom_nf90_check(NF90_PUT_VAR( if90id, idmy, glamt(ix1:ix2, iy1:iy2) ), clinfo) |
|---|
| 557 | CALL iom_nf90_check(NF90_INQ_VARID( if90id, 'nav_lat' , idmy ), clinfo) |
|---|
| 558 | CALL iom_nf90_check(NF90_PUT_VAR( if90id, idmy, gphit(ix1:ix2, iy1:iy2) ), clinfo) |
|---|
| 559 | CALL iom_nf90_check(NF90_INQ_VARID( if90id, 'nav_lev' , idmy ), clinfo) |
|---|
| 560 | CALL iom_nf90_check(NF90_PUT_VAR( if90id, idmy, gdept_0 ), clinfo) |
|---|
| 561 | ! +++ WRONG VALUE: to be improved but not really useful... |
|---|
| 562 | CALL iom_nf90_check(NF90_INQ_VARID( if90id, 'time_counter', idmy ), clinfo) |
|---|
| 563 | CALL iom_nf90_check(NF90_PUT_VAR( if90id, idmy, kt ), clinfo) |
|---|
| 564 | ! update the values of the variables dimensions size |
|---|
| 565 | CALL iom_nf90_check(NF90_INQUIRE_DIMENSION( if90id, 1, len = iom_file(kiomid)%dimsz(1,1) ), clinfo) |
|---|
| 566 | CALL iom_nf90_check(NF90_INQUIRE_DIMENSION( if90id, 2, len = iom_file(kiomid)%dimsz(2,1) ), clinfo) |
|---|
| 567 | iom_file(kiomid)%dimsz(1:2, 2) = iom_file(kiomid)%dimsz(1:2, 1) |
|---|
| 568 | CALL iom_nf90_check(NF90_INQUIRE_DIMENSION( if90id, 3, len = iom_file(kiomid)%dimsz(1,3) ), clinfo) |
|---|
| 569 | iom_file(kiomid)%dimsz(1 , 4) = 1 ! unlimited dimension |
|---|
| 570 | IF(lwp) WRITE(numout,*) TRIM(clinfo)//' write dimension variables done' |
|---|
| 571 | ENDIF |
|---|
| 572 | ENDIF |
|---|
| 573 | |
|---|
| 574 | ! write the data |
|---|
| 575 | ! ============= |
|---|
| 576 | IF( PRESENT(pv_r0d) ) THEN |
|---|
| 577 | CALL iom_nf90_check(NF90_PUT_VAR( if90id, idvar, pv_r0d ), clinfo) |
|---|
| 578 | ELSEIF( PRESENT(pv_r1d) ) THEN |
|---|
| 579 | CALL iom_nf90_check(NF90_PUT_VAR( if90id, idvar, pv_r1d( :) ), clinfo) |
|---|
| 580 | ELSEIF( PRESENT(pv_r2d) ) THEN |
|---|
| 581 | CALL iom_nf90_check(NF90_PUT_VAR( if90id, idvar, pv_r2d(ix1:ix2, iy1:iy2 ) ), clinfo) |
|---|
| 582 | ELSEIF( PRESENT(pv_r3d) ) THEN |
|---|
| 583 | CALL iom_nf90_check(NF90_PUT_VAR( if90id, idvar, pv_r3d(ix1:ix2, iy1:iy2, :) ), clinfo) |
|---|
| 584 | ENDIF |
|---|
| 585 | ! add 1 to the size of the temporal dimension (not really useful...) |
|---|
| 586 | IF( iom_file(kiomid)%luld(idvar) ) iom_file(kiomid)%dimsz(iom_file(kiomid)%ndims(idvar), idvar) & |
|---|
| 587 | & = iom_file(kiomid)%dimsz(iom_file(kiomid)%ndims(idvar), idvar) + 1 |
|---|
| 588 | IF(lwp) WRITE(numout,*) TRIM(clinfo)//' written ok' |
|---|
| 589 | ENDIF |
|---|
| 590 | ! |
|---|
| 591 | END SUBROUTINE iom_nf90_rp0123d |
|---|
| 592 | |
|---|
| 593 | |
|---|
| 594 | SUBROUTINE iom_nf90_check( kstatus, cdinfo ) |
|---|
| 595 | !!-------------------------------------------------------------------- |
|---|
| 596 | !! *** SUBROUTINE iom_nf90_check *** |
|---|
| 597 | !! |
|---|
| 598 | !! ** Purpose : check nf90 errors |
|---|
| 599 | !!-------------------------------------------------------------------- |
|---|
| 600 | INTEGER, INTENT(in) :: kstatus |
|---|
| 601 | CHARACTER(LEN=*), INTENT(in) :: cdinfo |
|---|
| 602 | !--------------------------------------------------------------------- |
|---|
| 603 | IF(kstatus /= nf90_noerr) CALL ctl_stop( 'iom_nf90_check : '//TRIM(nf90_strerror(kstatus)), TRIM(cdinfo) ) |
|---|
| 604 | END SUBROUTINE iom_nf90_check |
|---|
| 605 | |
|---|
| 606 | !!====================================================================== |
|---|
| 607 | END MODULE iom_nf90 |
|---|
