New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
trcini.F90 in branches/NERC/dev_r5518_GO6_conserv_Check/NEMOGCM/NEMO/TOP_SRC – NEMO

source: branches/NERC/dev_r5518_GO6_conserv_Check/NEMOGCM/NEMO/TOP_SRC/trcini.F90 @ 8926

Last change on this file since 8926 was 8926, checked in by jpalmier, 6 years ago

JPALM -- add conservation checks inside MEDUSA
File size: 20.7 KB
Line 
1MODULE trcini
2   !!======================================================================
3   !!                         ***  MODULE trcini  ***
4   !! TOP :   Manage the passive tracer initialization
5   !!======================================================================
6   !! History :   -   ! 1991-03 (O. Marti)  original code
7   !!            1.0  ! 2005-03 (O. Aumont, A. El Moussaoui) F90
8   !!            2.0  ! 2005-10 (C. Ethe, G. Madec) revised architecture
9   !!            4.0  ! 2011-01 (A. R. Porter, STFC Daresbury) dynamical allocation
10   !!             -   ! 2014-06 (A. Yool, J. Palmieri) adding MEDUSA-2
11   !!----------------------------------------------------------------------
12#if defined key_top
13   !!----------------------------------------------------------------------
14   !!   'key_top'                                                TOP models
15   !!----------------------------------------------------------------------
16   !!   trc_init  :   Initialization for passive tracer
17   !!   top_alloc :   allocate the TOP arrays
18   !!----------------------------------------------------------------------
19   USE oce_trc         ! shared variables between ocean and passive tracers
20   USE trc             ! passive tracers common variables
21   USE trcrst          ! passive tracers restart
22   USE trcnam          ! Namelist read
23   USE trcini_cfc      ! CFC      initialisation
24   USE trcini_pisces   ! PISCES   initialisation
25   USE trcini_c14b     ! C14 bomb initialisation
26   USE trcini_age      ! AGE      initialisation
27   USE trcini_my_trc   ! MY_TRC   initialisation
28   USE trcini_idtra    ! idealize tracer initialisation
29   USE trcini_medusa   ! MEDUSA   initialisation
30   USE par_medusa      ! MEDUSA   parameters (needed for elemental cycles)
31   USE trcdta          ! initialisation from files
32   USE daymod          ! calendar manager
33   USE prtctl_trc      ! Print control passive tracers (prt_ctl_trc_init routine)
34   USE trcsub          ! variables to substep passive tracers
35   USE lib_mpp         ! distribued memory computing library
36   USE sbc_oce
37   USE trcice          ! tracers in sea ice
38   USE sms_medusa      ! MEDUSA   initialisation
39   IMPLICIT NONE
40   PRIVATE
41   
42   PUBLIC   trc_init   ! called by opa
43
44    !! * Substitutions
45#  include "domzgr_substitute.h90"
46   !!----------------------------------------------------------------------
47   !! NEMO/TOP 4.0 , NEMO Consortium (2011)
48   !! $Id$
49   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
50   !!----------------------------------------------------------------------
51CONTAINS
52   
53   SUBROUTINE trc_init
54      !!---------------------------------------------------------------------
55      !!                     ***  ROUTINE trc_init  ***
56      !!
57      !! ** Purpose :   Initialization of the passive tracer fields
58      !!
59      !! ** Method  : - read namelist
60      !!              - control the consistancy
61      !!              - compute specific initialisations
62      !!              - set initial tracer fields (either read restart
63      !!                or read data or analytical formulation
64      !!---------------------------------------------------------------------
65      INTEGER ::   ji, jj, jk, jn, jl    ! dummy loop indices
66# if defined key_medusa && defined key_roam
67      !! AXY (23/11/2017)
68      REAL(wp)                         :: zsum3d, zsum2d
69      REAL(wp)                         :: zq1, zq2, loc_vol, loc_area
70      REAL(wp), DIMENSION(6)           :: loc_cycletot3, loc_cycletot2
71      REAL(wp), DIMENSION(jpi,jpj,jpk) :: ztot3d
72      REAL(wp), DIMENSION(jpi,jpj)     :: ztot2d, carea
73# endif
74      CHARACTER (len=25) :: charout
75      !!---------------------------------------------------------------------
76      !
77      IF( nn_timing == 1 )   CALL timing_start('trc_init')
78      !
79      IF(lwp) WRITE(numout,*)
80      IF(lwp) WRITE(numout,*) 'trc_init : initial set up of the passive tracers'
81      IF(lwp) WRITE(numout,*) '~~~~~~~'
82
83      CALL top_alloc()              ! allocate TOP arrays
84
85      l_trcdm2dc = ln_dm2dc .OR. ( ln_cpl .AND. ncpl_qsr_freq /= 1 )
86      l_trcdm2dc = l_trcdm2dc  .AND. .NOT. lk_offline
87      IF( l_trcdm2dc .AND. lwp ) &
88         &   CALL ctl_warn(' Coupling with passive tracers and used of diurnal cycle. &
89         & Computation of a daily mean shortwave for some biogeochemical models) ')
90
91      IF( nn_cla == 1 )   &
92         &  CALL ctl_stop( ' Cross Land Advection not yet implemented with passive tracer ; nn_cla must be 0' )
93
94      CALL trc_nam      ! read passive tracers namelists
95      !
96      IF(lwp) WRITE(numout,*)
97      !
98      IF( ln_rsttr .AND. .NOT. lk_offline ) CALL trc_rst_cal( nit000, 'READ' )   ! calendar
99      !
100      IF(lwp) WRITE(numout,*)
101                                                              ! masked grid volume
102      !                                                              ! masked grid volume
103      DO jk = 1, jpk
104         cvol(:,:,jk) = e1e2t(:,:) * fse3t(:,:,jk) * tmask(:,:,jk)
105      END DO
106      IF( lk_degrad ) cvol(:,:,:) = cvol(:,:,:) * facvol(:,:,:)      ! degrad option: reduction by facvol
107      !                                                              ! total volume of the ocean
108      areatot = glob_sum( cvol(:,:,:) )
109      carea(:,:) = e1e2t(:,:) * tmask(:,:,1) 
110
111      IF( lk_pisces  )       CALL trc_ini_pisces       ! PISCES  bio-model
112      IF( lk_cfc     )       CALL trc_ini_cfc          ! CFC     tracers
113      IF( lk_c14b    )       CALL trc_ini_c14b         ! C14 bomb  tracer
114      IF( lk_age     )       CALL trc_ini_age          ! AGE       tracer
115      IF( lk_my_trc  )       CALL trc_ini_my_trc       ! MY_TRC  tracers
116      IF( lk_idtra   )       CALL trc_ini_idtra        ! Idealize tracers
117      IF( lk_medusa  )       CALL trc_ini_medusa       ! MEDUSA  tracers
118
119      CALL trc_ice_ini                                 ! Tracers in sea ice
120
121      IF( ln_ctl ) THEN
122         !
123         IF (narea == 1) THEN 
124            ! The tracer.stat file only contains global tracer sum values, if
125            ! it contains anything at all. Hence it only needs to be opened
126            ! and written to on the master PE, not on all PEs. 
127            CALL ctl_opn( numstr, 'tracer.stat', 'REPLACE','FORMATTED',  & 
128                          'SEQUENTIAL', -1, numout, lwp , narea ) 
129         ENDIF 
130         !
131      ENDIF
132
133      IF( ln_trcdta ) THEN
134         CALL trc_dta_init(jptra)
135      ENDIF
136
137      IF( ln_rsttr ) THEN
138        !
139        CALL trc_rst_read              ! restart from a file
140        !
141      ELSE
142        !
143        IF( ln_trcdta .AND. nb_trcdta > 0 ) THEN  ! Initialisation of tracer from a file that may also be used for damping
144            !
145            DO jn = 1, jptra
146               IF( ln_trc_ini(jn) ) THEN      ! update passive tracers arrays with input data read from file
147                  jl = n_trc_index(jn) 
148                  CALL trc_dta( nit000, sf_trcdta(jl), rf_trfac(jl) )   ! read tracer data at nit000
149                  trn(:,:,:,jn) = sf_trcdta(jl)%fnow(:,:,:) 
150                  IF( .NOT.ln_trcdmp .AND. .NOT.ln_trcdmp_clo ) THEN      !== deallocate data structure   ==!
151                     !                                                    (data used only for initialisation)
152                     IF(lwp) WRITE(numout,*) 'trc_dta: deallocate data arrays as they are only used to initialize the run'
153                                                  DEALLOCATE( sf_trcdta(jl)%fnow )     !  arrays in the structure
154                     IF( sf_trcdta(jl)%ln_tint )  DEALLOCATE( sf_trcdta(jl)%fdta )
155                     !
156                  ENDIF
157               ENDIF
158            ENDDO
159            !
160        ENDIF
161        !
162        trb(:,:,:,:) = trn(:,:,:,:)
163        !
164      ENDIF
165 
166      tra(:,:,:,:) = 0._wp
167      !
168      IF( nn_dttrc /= 1 )        CALL trc_sub_ini      ! Initialize variables for substepping passive tracers
169      !
170
171      trai(:) = 0._wp                                                   ! initial content of all tracers
172      DO jn = 1, jptra
173         trai(jn) = trai(jn) + glob_sum( trn(:,:,:,jn) * cvol(:,:,:)   )
174      END DO
175
176      IF(lwp) THEN               ! control print
177         WRITE(numout,*)
178         WRITE(numout,*)
179         WRITE(numout,*) '          *** Total number of passive tracer jptra = ', jptra
180         WRITE(numout,*) '          *** Total volume of ocean                = ', areatot
181         WRITE(numout,*) '          *** Total inital content of all tracers '
182         WRITE(numout,*)
183# if defined key_debug_medusa
184         CALL flush(numout)
185# endif
186         !
187# if defined key_debug_medusa
188         WRITE(numout,*) ' litle check :  ', ctrcnm(1)
189         CALL flush(numout)
190# endif
191         DO jn = 1, jptra
192            WRITE(numout,9000) jn, TRIM( ctrcnm(jn) ), trai(jn)
193         ENDDO
194         WRITE(numout,*)
195      ENDIF
196      IF(lwp) WRITE(numout,*)
197      IF(ln_ctl) THEN            ! print mean trends (used for debugging)
198         CALL prt_ctl_trc_init
199         WRITE(charout, FMT="('ini ')")
200         CALL prt_ctl_trc_info( charout )
201         CALL prt_ctl_trc( tab4d=trn, mask=tmask, clinfo=ctrcnm )
202      ENDIF
203
204# if defined key_medusa && defined key_roam
205      ! AXY (17/11/2017): calculate initial totals of elemental cycles
206      !
207      ! This is done in a very hard-wired way here; in future, this could be
208      ! replaced with loops and using a 2D array; one dimension would cover
209      ! the tracers, the other would be for the elements; each tracer would
210      ! have a factor for each element to say how much of that element was
211      ! in that tracer; for example, PHN would be 1.0 for N, xrfn for Fe and
212      ! xthetapn for C, with the other elements 0.0; the array entry for PHN
213      ! would then be (1. 0. xrfn xthetapn 0. 0.) for (N, Si, Fe, C, A, O2);
214      ! saving this for the next iteration
215      !
216      cycletot(:) = 0._wp
217      ! report elemental totals at initialisation as we go along
218      IF ( lwp ) WRITE(numout,*)
219      IF ( lwp ) WRITE(numout,*)    ' Elemental cycle totals: '
220      IF ( lwp ) CALL flush(numout)
221      ! nitrogen
222      ztot3d(:,:,:) = trn(:,:,:,jpphn) + trn(:,:,:,jpphd) + trn(:,:,:,jpzmi) + &
223                      trn(:,:,:,jpzme) + trn(:,:,:,jpdet) + trn(:,:,:,jpdin)
224      ztot2d(:,:)   = zn_sed_n(:,:)
225      zsum3d        = glob_sum( ztot3d(:,:,:) * cvol(:,:,:) )
226      zsum2d        = glob_sum( ztot2d(:,:) * carea(:,:) )
227      cycletot(1)   = zsum3d + zsum2d
228      IF ( lwp ) WRITE(numout,9010) 'nitrogen', zsum3d, zsum2d, cycletot(1)
229      IF ( lwp ) CALL flush(numout)
230      ! silicon
231      ztot3d(:,:,:) = trn(:,:,:,jppds) + trn(:,:,:,jpsil)
232      ztot2d(:,:)   = zn_sed_si(:,:)
233      zsum3d        = glob_sum( ztot3d(:,:,:) * cvol(:,:,:) )
234      zsum2d        = glob_sum( ztot2d(:,:) * carea(:,:) )
235      cycletot(2)   = zsum3d + zsum2d
236      IF ( lwp ) WRITE(numout,9010) 'silicon', zsum3d, zsum2d, cycletot(2)
237      IF ( lwp ) CALL flush(numout)
238      ! iron
239      ztot3d(:,:,:) = ((trn(:,:,:,jpphn) + trn(:,:,:,jpphd) + trn(:,:,:,jpzmi) + &
240                      trn(:,:,:,jpzme) + trn(:,:,:,jpdet)) * xrfn) + trn(:,:,:,jpfer)
241      ztot2d(:,:)   = zn_sed_fe(:,:)
242      zsum3d        = glob_sum( ztot3d(:,:,:) * cvol(:,:,:) )
243      zsum2d        = glob_sum( ztot2d(:,:) * carea(:,:) )
244      cycletot(3)   = zsum3d + zsum2d
245      IF ( lwp ) WRITE(numout,9010) 'iron', zsum3d, zsum2d, cycletot(3)
246      IF ( lwp ) CALL flush(numout)
247      ! carbon (uses fixed C:N ratios on plankton tracers)
248      ztot3d(:,:,:) = (trn(:,:,:,jpphn) * xthetapn)  + (trn(:,:,:,jpphd) * xthetapd)  +  &
249                      (trn(:,:,:,jpzmi) * xthetazmi) + (trn(:,:,:,jpzme) * xthetazme) +  &
250                      trn(:,:,:,jpdtc) + trn(:,:,:,jpdic)
251      ztot2d(:,:)   = zn_sed_c(:,:) + zn_sed_ca(:,:)
252      zsum3d        = glob_sum( ztot3d(:,:,:) * cvol(:,:,:) )
253      zsum2d        = glob_sum( ztot2d(:,:) * carea(:,:) )
254      cycletot(4)   = zsum3d + zsum2d
255      IF ( lwp ) WRITE(numout,9010) 'carbon', zsum3d, zsum2d, cycletot(4)
256      IF ( lwp ) CALL flush(numout)
257      ! alkalinity (note benthic correction)
258      ztot3d(:,:,:) = trn(:,:,:,jpalk)
259      ztot2d(:,:)   = zn_sed_ca(:,:) * 2._wp
260      zsum3d        = glob_sum( ztot3d(:,:,:) * cvol(:,:,:) )
261      zsum2d        = glob_sum( ztot2d(:,:) * carea(:,:) )
262      cycletot(5)   = zsum3d + zsum2d
263      IF ( lwp ) WRITE(numout,9010) 'alkalinity', zsum3d, zsum2d, cycletot(5)
264      IF ( lwp ) CALL flush(numout)
265      ! oxygen (note no benthic)
266      ztot3d(:,:,:) = trn(:,:,:,jpoxy)
267      ztot2d(:,:)   = 0._wp
268      zsum3d        = glob_sum( ztot3d(:,:,:) * cvol(:,:,:) )
269      zsum2d        = glob_sum( ztot2d(:,:) * carea(:,:) )
270      cycletot(6)   = zsum3d + zsum2d
271      IF ( lwp ) WRITE(numout,9010) 'oxygen', zsum3d, zsum2d, cycletot(6)
272      IF ( lwp ) CALL flush(numout)
273      ! Check
274      zsum3d        = glob_sum( cvol(:,:,:) )
275      zsum2d        = glob_sum( carea(:,:) )     
276      IF ( lwp ) WRITE(numout,*)
277      IF ( lwp ) WRITE(numout,*) ' check : cvol    : ', zsum3d
278      IF ( lwp ) WRITE(numout,*) ' check : carea   : ', zsum2d
279      IF ( lwp ) WRITE(numout,*)
280      IF ( lwp ) CALL flush(numout)
281      !
282      ! This second check dodges around the halo points in the grid
283      ! to check that glob_sum is doing what it's supposed to be
284      ! doing; note that the loop ordering here is the "correct" way
285      ! (according to Dr. Google)
286      !
287      IF ( lwp ) WRITE(numout,*)
288      IF ( lwp ) WRITE(numout,*)    ' Elemental cycle totals (check): '
289      ! ocean cells
290      loc_cycletot3(:) = 0._wp
291      loc_vol          = 0._wp
292      DO jk = 1, jpk
293         DO jj = nldj,nlej
294            DO ji = nldi,nlei
295               loc_vol = loc_vol + cvol(ji,jj,jk)
296               ! nitrogen
297               zq1 = trn(ji,jj,jk,jpphn) + trn(ji,jj,jk,jpphd) + trn(ji,jj,jk,jpzmi) + &
298                     trn(ji,jj,jk,jpzme) + trn(ji,jj,jk,jpdet) + trn(ji,jj,jk,jpdin)
299               loc_cycletot3(1) = loc_cycletot3(1) + ( zq1 * cvol(ji,jj,jk) )
300               ! silicon
301               zq1 = trn(ji,jj,jk,jppds) + trn(ji,jj,jk,jpsil)
302               loc_cycletot3(2) = loc_cycletot3(2) + ( zq1 * cvol(ji,jj,jk) )
303               ! iron
304               zq1 = ((trn(ji,jj,jk,jpphn) + trn(ji,jj,jk,jpphd) + trn(ji,jj,jk,jpzmi) + &
305                     trn(ji,jj,jk,jpzme) + trn(ji,jj,jk,jpdet)) * xrfn) + trn(ji,jj,jk,jpfer)
306               loc_cycletot3(3) = loc_cycletot3(3) + ( zq1 * cvol(ji,jj,jk) )
307               ! carbon
308               zq1 = (trn(ji,jj,jk,jpphn) * xthetapn)  + (trn(ji,jj,jk,jpphd) * xthetapd)  +  &
309                     (trn(ji,jj,jk,jpzmi) * xthetazmi) + (trn(ji,jj,jk,jpzme) * xthetazme) +  &
310                     trn(ji,jj,jk,jpdtc) + trn(ji,jj,jk,jpdic)
311               loc_cycletot3(4) = loc_cycletot3(4) + ( zq1 * cvol(ji,jj,jk) )
312               ! alkalinity
313               zq1 = trn(ji,jj,jk,jpalk)
314               loc_cycletot3(5) = loc_cycletot3(5) + ( zq1 * cvol(ji,jj,jk) )
315               ! oxygen
316               zq1 = trn(ji,jj,jk,jpoxy)
317               loc_cycletot3(6) = loc_cycletot3(6) + ( zq1 * cvol(ji,jj,jk) )
318            ENDDO
319         ENDDO
320      ENDDO
321      !
322      ! sediment cells
323      loc_cycletot2(:) = 0._wp
324      loc_area         = 0._wp
325      jk = 1
326      DO jj = nldj,nlej
327         DO ji = nldi,nlei
328            loc_area = loc_area + (e1e2t(ji,jj) * tmask(ji,jj,jk))
329            ! nitrogen
330            zq1 = zn_sed_n(ji,jj)
331            loc_cycletot2(1) = loc_cycletot2(1) + (zq1 * e1e2t(ji,jj) * tmask(ji,jj,jk))
332            ! silicon
333            zq1 = zn_sed_si(ji,jj)
334            loc_cycletot2(2) = loc_cycletot2(2) + (zq1 * e1e2t(ji,jj) * tmask(ji,jj,jk))
335            ! iron
336            zq1 = zn_sed_fe(ji,jj)
337            loc_cycletot2(3) = loc_cycletot2(3) + (zq1 * e1e2t(ji,jj) * tmask(ji,jj,jk))
338            ! carbon
339            zq1 = zn_sed_c(ji,jj) + zn_sed_ca(ji,jj)
340            loc_cycletot2(4) = loc_cycletot2(4) + (zq1 * e1e2t(ji,jj) * tmask(ji,jj,jk))
341            ! alkalinity
342            zq1 = zn_sed_ca(ji,jj) * 2._wp
343            loc_cycletot2(5) = loc_cycletot2(5) + (zq1 * e1e2t(ji,jj) * tmask(ji,jj,jk))
344            ! skip oxygen
345         ENDDO
346      ENDDO
347      !
348      ! report back
349      zq1 = loc_cycletot3(1)
350      zq2 = loc_cycletot2(1) 
351      IF( lk_mpp )   CALL mpp_sum( zq1 )
352      IF( lk_mpp )   CALL mpp_sum( zq2 )
353      cycletot2(1) = zq1 + zq2
354      IF ( lwp ) WRITE(numout,9010) 'nitrogen',   zq1, zq2, cycletot2(1)
355      zq1 = loc_cycletot3(2) 
356      zq2 = loc_cycletot2(2) 
357      IF( lk_mpp )   CALL mpp_sum( zq1 )
358      IF( lk_mpp )   CALL mpp_sum( zq2 )
359      cycletot2(2) = zq1 + zq2
360      IF ( lwp ) WRITE(numout,9010) 'silicon',    zq1, zq2, cycletot2(2)
361      zq1 = loc_cycletot3(3) 
362      zq2 = loc_cycletot2(3) 
363      IF( lk_mpp )   CALL mpp_sum( zq1 )
364      IF( lk_mpp )   CALL mpp_sum( zq2 )
365      cycletot2(3) = zq1 + zq2
366      IF ( lwp ) WRITE(numout,9010) 'iron',       zq1, zq2, cycletot2(3)
367      zq1 = loc_cycletot3(4) 
368      zq2 = loc_cycletot2(4) 
369      IF( lk_mpp )   CALL mpp_sum( zq1 )
370      IF( lk_mpp )   CALL mpp_sum( zq2 )
371      cycletot2(4) = zq1 + zq2
372      IF ( lwp ) WRITE(numout,9010) 'carbon',     zq1, zq2, cycletot2(4)
373      zq1 = loc_cycletot3(5) 
374      zq2 = loc_cycletot2(5) 
375      IF( lk_mpp )   CALL mpp_sum( zq1 )
376      IF( lk_mpp )   CALL mpp_sum( zq2 )
377      cycletot2(5) = zq1 + zq2
378      IF ( lwp ) WRITE(numout,9010) 'alkalinity', zq1, zq2, cycletot2(5)
379      zq1 = loc_cycletot3(6) 
380      zq2 = loc_cycletot2(6) 
381      IF( lk_mpp )   CALL mpp_sum( zq1 )
382      IF( lk_mpp )   CALL mpp_sum( zq2 )
383      cycletot2(6) = zq1 + zq2
384      IF ( lwp ) WRITE(numout,9010) 'oxygen',     zq1, zq2, cycletot2(6)
385      zq1 = loc_vol 
386      zq2 = loc_area       
387      IF( lk_mpp )   CALL mpp_sum( zq1 )
388      IF( lk_mpp )   CALL mpp_sum( zq2 )
389      IF ( lwp ) WRITE(numout,*)
390      IF ( lwp ) WRITE(numout,*) ' check : cvol    : ', zq1
391      IF ( lwp ) WRITE(numout,*) ' check : carea   : ', zq2
392      IF ( lwp ) WRITE(numout,*)
393      IF ( lwp ) CALL flush(numout)
394      !
395      ! report back
396      ! nitrogen
397      ztot3d(:,:,:) = trn(:,:,:,jpphn) + trn(:,:,:,jpphd) + trn(:,:,:,jpzmi) + &
398                      trn(:,:,:,jpzme) + trn(:,:,:,jpdet) + trn(:,:,:,jpdin)
399      ztot2d(:,:)   = zn_sed_n(:,:)
400      zsum3d        = glob_sum( ztot3d(nldi:nlei,nldj:nlej,:) * cvol(nldi:nlei,nldj:nlej,:) )
401      zsum2d        = glob_sum( ztot2d(nldi:nlei,nldj:nlej) * carea(nldi:nlei,nldj:nlej) )
402      cycletot(1)   = zsum3d + zsum2d
403      IF ( lwp ) WRITE(numout,9010) 'nitrogen', zsum3d, zsum2d, cycletot(1)
404      IF ( lwp ) CALL flush(numout)
405
406      !
407
408# endif
409
410      IF(lwp) WRITE(numout,*)
411      IF(lwp) WRITE(numout,*) 'trc_init : passive tracer set up completed'
412      IF(lwp) WRITE(numout,*) '~~~~~~~'
413      IF(lwp) CALL flush(numout)
414# if defined key_debug_medusa
415         CALL trc_rst_stat
416         CALL flush(numout)
417# endif
418
4199000  FORMAT(' tracer nb : ',i2,'      name :',a10,'      initial content :',e18.10)
4209010  FORMAT(' element:',a10,                     &
421             ' 3d sum:',e18.10,' 2d sum:',e18.10, &
422             ' total:',e18.10)
423      !
424      IF( nn_timing == 1 )   CALL timing_stop('trc_init')
425      !
426   END SUBROUTINE trc_init
427
428
429   SUBROUTINE top_alloc
430      !!----------------------------------------------------------------------
431      !!                     ***  ROUTINE top_alloc  ***
432      !!
433      !! ** Purpose :   Allocate all the dynamic arrays of the OPA modules
434      !!----------------------------------------------------------------------
435      USE trcadv        , ONLY:   trc_adv_alloc          ! TOP-related alloc routines...
436      USE trc           , ONLY:   trc_alloc
437      USE trcnxt        , ONLY:   trc_nxt_alloc
438      USE trczdf        , ONLY:   trc_zdf_alloc
439      USE trdtrc_oce    , ONLY:   trd_trc_oce_alloc
440#if defined key_trdmxl_trc 
441      USE trdmxl_trc    , ONLY:   trd_mxl_trc_alloc
442#endif
443# if defined key_medusa
444      USE bio_medusa_mod, ONLY:   bio_medusa_alloc
445# endif
446
447      !
448      INTEGER :: ierr
449      !!----------------------------------------------------------------------
450      !
451      ierr =        trc_adv_alloc()          ! Start of TOP-related alloc routines...
452      ierr = ierr + trc_alloc    ()
453      ierr = ierr + trc_nxt_alloc()
454      ierr = ierr + trc_zdf_alloc()
455      ierr = ierr + trd_trc_oce_alloc()
456#if defined key_trdmxl_trc 
457      ierr = ierr + trd_mxl_trc_alloc()
458#endif
459#if defined key_medusa
460      ierr = ierr + bio_medusa_alloc()
461#endif
462      !
463      IF( lk_mpp    )   CALL mpp_sum( ierr )
464      IF( ierr /= 0 )   CALL ctl_stop( 'STOP', 'top_alloc : unable to allocate standard ocean arrays' )
465      !
466   END SUBROUTINE top_alloc
467
468#else
469   !!----------------------------------------------------------------------
470   !!  Empty module :                                     No passive tracer
471   !!----------------------------------------------------------------------
472CONTAINS
473   SUBROUTINE trc_init                      ! Dummy routine   
474   END SUBROUTINE trc_init
475#endif
476
477   !!======================================================================
478END MODULE trcini
Note: See TracBrowser for help on using the repository browser.