source: branches/NERC/dev_r5518_GO6_package_trdtrc/NEMOGCM/NEMO/TOP_SRC/TRP/trcsbc.F90 @ 8560

Last change on this file since 8560 was 8560, checked in by jpalmier, 3 years ago

JPALM — trdtrc — Silly! SBC trend is 2D but trends routines are written for 3D variables only — So make SBC trend 3D again : all 0 but surface layer

File size: 10.9 KB
Line 
1MODULE trcsbc
2   !!==============================================================================
3   !!                       ***  MODULE  trcsbc  ***
4   !! Ocean passive tracers:  surface boundary condition
5   !!======================================================================
6   !! History :  8.2  !  1998-10  (G. Madec, G. Roullet, M. Imbard)  Original code
7   !!            8.2  !  2001-02  (D. Ludicone)  sea ice and free surface
8   !!            8.5  !  2002-06  (G. Madec)  F90: Free form and module
9   !!            9.0  !  2004-03  (C. Ethe)  adapted for passive tracers
10   !!                 !  2006-08  (C. Deltel) Diagnose ML trends for passive tracers
11   !!==============================================================================
12#if defined key_top
13   !!----------------------------------------------------------------------
14   !!   'key_top'                                                TOP models
15   !!----------------------------------------------------------------------
16   !!   trc_sbc      : update the tracer trend at ocean surface
17   !!----------------------------------------------------------------------
18   USE oce_trc         ! ocean dynamics and active tracers variables
19   USE trc             ! ocean  passive tracers variables
20   USE prtctl_trc      ! Print control for debbuging
21   USE iom
22   USE trd_oce
23   USE trdtra
24
25   IMPLICIT NONE
26   PRIVATE
27
28   PUBLIC   trc_sbc   ! routine called by step.F90
29
30   REAL(wp) ::   r2dt  !  time-step at surface
31
32   !! * Substitutions
33#  include "top_substitute.h90"
34   !!----------------------------------------------------------------------
35   !! NEMO/TOP 3.3 , NEMO Consortium (2010)
36   !! $Id$
37   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
38   !!----------------------------------------------------------------------
39CONTAINS
40
41   SUBROUTINE trc_sbc ( kt )
42      !!----------------------------------------------------------------------
43      !!                  ***  ROUTINE trc_sbc  ***
44      !!                   
45      !! ** Purpose :   Compute the tracer surface boundary condition trend of
46      !!      (concentration/dilution effect) and add it to the general
47      !!       trend of tracer equations.
48      !!
49      !! ** Method :
50      !!      * concentration/dilution effect:
51      !!            The surface freshwater flux modify the ocean volume
52      !!         and thus the concentration of a tracer as :
53      !!            tra = tra + emp * trn / e3t   for k=1
54      !!         where emp, the surface freshwater budget (evaporation minus
55      !!         precipitation ) given in kg/m2/s is divided
56      !!         by 1035 kg/m3 (density of ocean water) to obtain m/s.
57      !!
58      !! ** Action  : - Update the 1st level of tra with the trend associated
59      !!                with the tracer surface boundary condition
60      !!
61      !!----------------------------------------------------------------------
62      !
63      INTEGER, INTENT( in ) ::   kt          ! ocean time-step index
64      !
65      INTEGER  ::   ji, jj, jn                                     ! dummy loop indices
66      REAL(wp) ::   zse3t, zrtrn, zratio, zfact                    ! temporary scalars
67      REAL(wp) ::   zswitch, zftra, zcd, zdtra, ztfx, ztra         ! temporary scalars
68      CHARACTER (len=22) :: charout
69      REAL(wp), POINTER, DIMENSION(:,:  ) :: zsfx
70      REAL(wp), POINTER, DIMENSION(:,:,:) :: ztrtrd
71
72      !!---------------------------------------------------------------------
73      !
74      IF( nn_timing == 1 )  CALL timing_start('trc_sbc')
75      !
76      ! Allocate temporary workspace
77                      CALL wrk_alloc( jpi, jpj,      zsfx   )
78      IF( l_trdtrc )  CALL wrk_alloc( jpi, jpj, jpk, ztrtrd )
79      !
80      zrtrn = 1.e-15_wp
81
82      SELECT CASE( nn_ice_embd )         ! levitating or embedded sea-ice option
83         CASE( 0    )   ;   zswitch = 1  ! (0) standard levitating sea-ice : salt exchange only
84         CASE( 1, 2 )   ;   zswitch = 0  ! (1) levitating sea-ice: salt and volume exchange but no pressure effect                               
85                                         ! (2) embedded sea-ice : salt and volume fluxes and pressure
86      END SELECT
87
88      IF( ln_top_euler) THEN
89         r2dt =  rdttrc(1)              ! = rdttrc (use Euler time stepping)
90      ELSE
91         IF( neuler == 0 .AND. kt == nittrc000 ) THEN     ! at nittrc000
92            r2dt = rdttrc(1)           ! = rdttrc (restarting with Euler time stepping)
93         ELSEIF( kt <= nittrc000 + nn_dttrc ) THEN          ! at nittrc000 or nittrc000+1
94            r2dt = 2. * rdttrc(1)       ! = 2 rdttrc (leapfrog)
95         ENDIF
96      ENDIF
97
98
99      IF( kt == nittrc000 ) THEN
100         IF(lwp) WRITE(numout,*)
101         IF(lwp) WRITE(numout,*) 'trc_sbc : Passive tracers surface boundary condition'
102         IF(lwp) WRITE(numout,*) '~~~~~~~ '
103
104         !! JPALM -- 12-01-2016 -- problem after restart, maybe because of this...
105         !!                     -- set sbc_trc_b to 0 after restart, first, to check.
106         !!------------------------------------------------------------------------------
107        ! IF( ln_rsttr .AND. .NOT.ln_top_euler .AND.   &                     ! Restart: read in restart  file
108        !    iom_varid( numrtr, 'sbc_'//TRIM(ctrcnm(1))//'_b', ldstop = .FALSE. ) > 0 ) THEN
109        !    IF(lwp) WRITE(numout,*) '          nittrc000-nn_dttrc surface tracer content forcing fields red in the restart file'
110        !    zfact = 0.5_wp
111        !    DO jn = 1, jptra
112        !       CALL iom_get( numrtr, jpdom_autoglo, 'sbc_'//TRIM(ctrcnm(jn))//'_b', sbc_trc_b(:,:,jn) )   ! before tracer content sbc
113        !    END DO
114        ! ELSE                                         ! No restart or restart not found: Euler forward time stepping
115           zfact = 1._wp
116           sbc_trc_b(:,:,:) = 0._wp
117        ! ENDIF
118      ELSE                                         ! Swap of forcing fields
119         IF( ln_top_euler ) THEN
120            zfact = 1._wp
121            sbc_trc_b(:,:,:) = 0._wp
122         ELSE
123            zfact = 0.5_wp
124            sbc_trc_b(:,:,:) = sbc_trc(:,:,:)
125         ENDIF
126         !
127      ENDIF
128
129      ! Coupling online : river runoff is added to the horizontal divergence (hdivn) in the subroutine sbc_rnf_div
130      ! one only consider the concentration/dilution effect due to evaporation minus precipitation + freezing/melting of sea-ice
131      ! Coupling offline : runoff are in emp which contains E-P-R
132      !
133      IF( .NOT. lk_offline .AND. lk_vvl ) THEN  ! online coupling with vvl
134         zsfx(:,:) = 0._wp
135      ELSE                                      ! online coupling free surface or offline with free surface
136         zsfx(:,:) = emp(:,:)
137      ENDIF
138
139      ! 0. initialization
140      DO jn = 1, jptra
141         !
142         IF( l_trdtrc ) THEN
143            ztrtrd(:,:,:) = 0.0
144            ztrtrd(:,:,1) = tra(:,:,1,jn)  ! save surface trends
145         !                                 ! add the trend to the general tracer trend
146         ENDIF
147
148         IF ( nn_ice_tr == -1 ) THEN  ! No tracers in sea ice (null concentration in sea ice)
149
150            DO jj = 2, jpj
151               DO ji = fs_2, fs_jpim1   ! vector opt.
152                  sbc_trc(ji,jj,jn) = zsfx(ji,jj) * r1_rau0 * trn(ji,jj,1,jn)
153               END DO
154            END DO
155
156         ELSE
157
158            DO jj = 2, jpj
159               DO ji = fs_2, fs_jpim1   ! vector opt.
160                  zse3t = 1. / fse3t(ji,jj,1)
161                  ! tracer flux at the ice/ocean interface (tracer/m2/s)
162                  zftra = - trc_i(ji,jj,jn) * fmmflx(ji,jj) ! uptake of tracer in the sea ice
163                  zcd   =   trc_o(ji,jj,jn) * fmmflx(ji,jj) ! concentration dilution due to freezing-melting,
164                                                               ! only used in the levitating sea ice case
165                  ! tracer flux only       : add concentration dilution term in net tracer flux, no F-M in volume flux
166                  ! tracer and mass fluxes : no concentration dilution term in net tracer flux, F-M term in volume flux
167                  ztfx  = zftra + zswitch * zcd                ! net tracer flux (+C/D if no ice/ocean mass exchange)
168   
169                  zdtra = r1_rau0 * ( ztfx + zsfx(ji,jj) * trn(ji,jj,1,jn) ) 
170                  IF ( zdtra < 0. ) THEN
171                     zratio = -zdtra * zse3t * r2dt / ( trn(ji,jj,1,jn) + zrtrn )
172                     zdtra = MIN(1.0, zratio) * zdtra ! avoid negative concentrations to arise
173                  ENDIF
174                  sbc_trc(ji,jj,jn) =  zdtra 
175               END DO
176            END DO
177         ENDIF
178         !
179         CALL lbc_lnk( sbc_trc(:,:,jn), 'T', 1. )
180         !                                       Concentration dilution effect on tracers due to evaporation & precipitation
181         DO jj = 2, jpj
182            DO ji = fs_2, fs_jpim1   ! vector opt.
183               zse3t = zfact / fse3t(ji,jj,1)
184               tra(ji,jj,1,jn) = tra(ji,jj,1,jn) + ( sbc_trc_b(ji,jj,jn) + sbc_trc(ji,jj,jn) ) * zse3t
185            END DO
186         END DO
187         !
188         IF( l_trdtrc ) THEN
189            ztrtrd(:,:,1) = tra(:,:,1,jn) - ztrtrd(:,:,1)
190            CALL trd_tra( kt, 'TRC', jn, jptra_nsr, ztrtrd )
191         END IF
192         !                                                       ! ===========
193      END DO                                                     ! tracer loop
194      !                                                          ! ===========
195
196      !                                           Write in the tracer restar  file
197      !                                          *******************************
198      IF( lrst_trc .AND. .NOT.ln_top_euler ) THEN
199         IF(lwp) WRITE(numout,*)
200         IF(lwp) WRITE(numout,*) 'sbc : ocean surface tracer content forcing fields written in tracer restart file ',   &
201            &                    'at it= ', kt,' date= ', ndastp
202         IF(lwp) WRITE(numout,*) '~~~~'
203         DO jn = 1, jptra
204            CALL iom_rstput( kt, nitrst, numrtw, 'sbc_'//TRIM(ctrcnm(jn))//'_b', sbc_trc(:,:,jn) )
205         END DO
206      ENDIF
207      !
208      IF( ln_ctl )   THEN
209         WRITE(charout, FMT="('sbc ')") ;  CALL prt_ctl_trc_info(charout)
210                                           CALL prt_ctl_trc( tab4d=tra, mask=tmask, clinfo=ctrcnm, clinfo2='trd' )
211      ENDIF
212                      CALL wrk_dealloc( jpi, jpj,      zsfx   )
213      IF( l_trdtrc )  CALL wrk_dealloc( jpi, jpj, jpk, ztrtrd )
214      !
215      IF( nn_timing == 1 )  CALL timing_stop('trc_sbc')
216      !
217   END SUBROUTINE trc_sbc
218
219#else
220   !!----------------------------------------------------------------------
221   !!   Dummy module :                      NO passive tracer
222   !!----------------------------------------------------------------------
223CONTAINS
224   SUBROUTINE trc_sbc (kt)              ! Empty routine
225      INTEGER, INTENT(in) :: kt
226      WRITE(*,*) 'trc_sbc: You should not have seen this print! error?', kt
227   END SUBROUTINE trc_sbc
228#endif
229   
230   !!======================================================================
231END MODULE trcsbc
Note: See TracBrowser for help on using the repository browser.