New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
domngb.F90 in branches/NERC/dev_r5589_is_oce_cpl/NEMOGCM/NEMO/OPA_SRC/DOM – NEMO

source: branches/NERC/dev_r5589_is_oce_cpl/NEMOGCM/NEMO/OPA_SRC/DOM/domngb.F90 @ 5945

Last change on this file since 5945 was 5945, checked in by mathiot, 8 years ago

ice sheet coupling: changes based on reviewer comments
  • Property svn:keywords set to Id
File size: 4.3 KB
Line 
1MODULE domngb
2   !!======================================================================
3   !!                       ***  MODULE  domngb  ***
4   !! Grid search:  find the closest grid point from a given on/lat position
5   !!======================================================================
6   !! History : 3.2  !  2009-11  (S. Masson)  Original code
7   !!----------------------------------------------------------------------
8
9   !!----------------------------------------------------------------------
10   !!   dom_ngb       : find the closest grid point from a given lon/lat position
11   !!----------------------------------------------------------------------
12   USE dom_oce        ! ocean space and time domain
13   USE in_out_manager ! I/O manager
14   USE lib_mpp        ! for mppsum
15   USE wrk_nemo       ! Memory allocation
16   USE timing         ! Timing
17
18   IMPLICIT NONE
19   PRIVATE
20
21   PUBLIC   dom_ngb   ! routine called in iom.F90 module
22
23   !!----------------------------------------------------------------------
24   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
25   !! $Id$
26   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
27   !!----------------------------------------------------------------------
28CONTAINS
29
30   SUBROUTINE dom_ngb( plon, plat, kii, kjj, cdgrid, kkk )
31      !!----------------------------------------------------------------------
32      !!                    ***  ROUTINE dom_ngb  ***
33      !!
34      !! ** Purpose :   find the closest grid point from a given lon/lat position
35      !!
36      !! ** Method  :   look for minimum distance in cylindrical projection
37      !!                -> not good if located at too high latitude...
38      !!----------------------------------------------------------------------
39      !
40      REAL(wp)        , INTENT(in   ) ::   plon, plat   ! longitude,latitude of the point
41      INTEGER         , INTENT(  out) ::   kii, kjj     ! i-,j-index of the closes grid point
42      INTEGER         , INTENT(in   ), OPTIONAL :: kkk  ! k-index of the mask level used
43      CHARACTER(len=1), INTENT(in   ) ::   cdgrid       ! grid name 'T', 'U', 'V', 'W'
44      !
45      INTEGER :: ik         ! working level
46      INTEGER , DIMENSION(2) ::   iloc
47      REAL(wp)               ::   zlon, zmini
48      REAL(wp), POINTER, DIMENSION(:,:) ::  zglam, zgphi, zmask, zdist
49      !!--------------------------------------------------------------------
50      !
51      IF( nn_timing == 1 )  CALL timing_start('dom_ngb')
52      !
53      CALL wrk_alloc( jpi, jpj, zglam, zgphi, zmask, zdist )
54      !
55      zmask(:,:) = 0._wp
56      ik = 1
57      IF ( PRESENT(kkk) ) ik=kkk
58      SELECT CASE( cdgrid )
59      CASE( 'U' )  ; zglam(:,:) = glamu(:,:) ; zgphi(:,:) = gphiu(:,:) ; zmask(nldi:nlei,nldj:nlej) = umask(nldi:nlei,nldj:nlej,ik)
60      CASE( 'V' )  ; zglam(:,:) = glamv(:,:) ; zgphi(:,:) = gphiv(:,:) ; zmask(nldi:nlei,nldj:nlej) = vmask(nldi:nlei,nldj:nlej,ik)
61      CASE( 'F' )  ; zglam(:,:) = glamf(:,:) ; zgphi(:,:) = gphif(:,:) ; zmask(nldi:nlei,nldj:nlej) = fmask(nldi:nlei,nldj:nlej,ik)
62      CASE DEFAULT ; zglam(:,:) = glamt(:,:) ; zgphi(:,:) = gphit(:,:) ; zmask(nldi:nlei,nldj:nlej) = tmask(nldi:nlei,nldj:nlej,ik)
63      END SELECT
64
65      IF (jphgr_msh /= 2 .AND. jphgr_msh /= 3) THEN
66         zlon       = MOD( plon       + 720., 360. )                                     ! plon between    0 and 360
67         zglam(:,:) = MOD( zglam(:,:) + 720., 360. )                                     ! glam between    0 and 360
68         IF( zlon > 270. )   zlon = zlon - 360.                                          ! zlon between  -90 and 270
69         IF( zlon <  90. )   WHERE( zglam(:,:) > 180. ) zglam(:,:) = zglam(:,:) - 360.   ! glam between -180 and 180
70         zglam(:,:) = zglam(:,:) - zlon
71      ELSE
72         zglam(:,:) = zglam(:,:) - plon
73      END IF
74
75      zgphi(:,:) = zgphi(:,:) - plat
76      zdist(:,:) = zglam(:,:) * zglam(:,:) + zgphi(:,:) * zgphi(:,:)
77     
78      IF( lk_mpp ) THEN 
79         CALL mpp_minloc( zdist(:,:), zmask, zmini, kii, kjj)
80      ELSE
81         iloc(:) = MINLOC( zdist(:,:), mask = zmask(:,:) == 1.e0 )
82         kii = iloc(1) + nimpp - 1
83         kjj = iloc(2) + njmpp - 1
84      ENDIF
85      !
86      CALL wrk_dealloc( jpi, jpj, zglam, zgphi, zmask, zdist )
87      !
88      IF( nn_timing == 1 )  CALL timing_stop('dom_ngb')
89      !
90   END SUBROUTINE dom_ngb
91
92   !!======================================================================
93END MODULE domngb
Note: See TracBrowser for help on using the repository browser.