New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
sbcssm.F90 in branches/UKMO/2014_Surge_Modelling/NEMOGCM/NEMO/OPA_SRC/SBC – NEMO

source: branches/UKMO/2014_Surge_Modelling/NEMOGCM/NEMO/OPA_SRC/SBC/sbcssm.F90 @ 5728

Last change on this file since 5728 was 4292, checked in by cetlod, 10 years ago

dev_MERGE_2013 : 1st step of the merge, see ticket #1185
  • Property svn:keywords set to Id
File size: 10.9 KB
Line 
1MODULE sbcssm
2   !!======================================================================
3   !!                       ***  MODULE  sbcssm  ***
4   !! Surface module :  provide time-mean ocean surface variables
5   !!======================================================================
6   !! History :  9.0  ! 2006-07  (G. Madec)  Original code
7   !!            3.3  ! 2010-10  (C. Bricaud, G. Madec)  add the Patm forcing for sea-ice
8   !!----------------------------------------------------------------------
9
10   !!----------------------------------------------------------------------
11   !!   sbc_ssm        : calculate sea surface mean currents, temperature, 
12   !!                    and salinity over nn_fsbc time-step
13   !!----------------------------------------------------------------------
14   USE oce             ! ocean dynamics and tracers
15   USE dom_oce         ! ocean space and time domain
16   USE sbc_oce         ! Surface boundary condition: ocean fields
17   USE sbc_oce         ! surface boundary condition: ocean fields
18   USE sbcapr          ! surface boundary condition: atmospheric pressure
19   USE prtctl          ! Print control                    (prt_ctl routine)
20   USE iom
21   USE in_out_manager  ! I/O manager
22
23   IMPLICIT NONE
24   PRIVATE
25
26   PUBLIC   sbc_ssm         ! routine called by step.F90
27   PUBLIC   sbc_ssm_init    ! routine called by sbcmod.F90
28
29   LOGICAL, SAVE  ::   l_ssm_mean = .FALSE.       ! keep track of whether means have been read
30                                                  ! from restart file
31   
32   !! * Substitutions
33#  include "domzgr_substitute.h90"
34   !!----------------------------------------------------------------------
35   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
36   !! $Id$
37   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
38   !!----------------------------------------------------------------------
39CONTAINS
40
41   SUBROUTINE sbc_ssm( kt )
42      !!---------------------------------------------------------------------
43      !!                     ***  ROUTINE sbc_oce  ***
44      !!                     
45      !! ** Purpose :   provide ocean surface variable to sea-surface boundary
46      !!                condition computation
47      !!               
48      !! ** Method  :   compute mean surface velocity (2 components at U and
49      !!      V-points) [m/s], temperature [Celcius] and salinity [psu] over
50      !!      the periode (kt - nn_fsbc) to kt
51      !!         Note that the inverse barometer ssh (i.e. ssh associated with Patm)
52      !!      is add to ssh_m when ln_apr_dyn = T. Required for sea-ice dynamics.
53      !!---------------------------------------------------------------------
54      INTEGER, INTENT(in) ::   kt   ! ocean time step
55      !
56      REAL(wp) ::   zcoef, zf_sbc       ! local scalar
57      !!---------------------------------------------------------------------
58      !                                                   ! ---------------------------------------- !
59      IF( nn_fsbc == 1 ) THEN                             !   Instantaneous surface fields        !
60         !                                                ! ---------------------------------------- !
61         ssu_m(:,:) = ub(:,:,1)
62         ssv_m(:,:) = vb(:,:,1)
63         sst_m(:,:) = tsn(:,:,1,jp_tem)
64         sss_m(:,:) = tsn(:,:,1,jp_sal)
65         !                          ! removed inverse barometer ssh when Patm forcing is used (for sea-ice dynamics)
66         IF( ln_apr_dyn ) THEN   ;   ssh_m(:,:) = sshn(:,:) - 0.5 * ( ssh_ib(:,:) + ssh_ibb(:,:) )
67         ELSE                    ;   ssh_m(:,:) = sshn(:,:)
68         ENDIF
69         !
70         IF( lk_vvl )   fse3t_m(:,:) = fse3t_n(:,:,1)
71         !
72      ELSE
73         !                                                ! ----------------------------------------------- !
74         IF( kt == nit000 .AND. .NOT. l_ssm_mean ) THEN   !   Initialisation: 1st time-step, no input means !
75            !                                             ! ----------------------------------------------- !
76            IF(lwp) WRITE(numout,*)
77            IF(lwp) WRITE(numout,*) '~~~~~~~   mean fields initialised to instantaneous values'
78            zcoef = REAL( nn_fsbc - 1, wp )
79            ssu_m(:,:) = zcoef * ub(:,:,1)
80            ssv_m(:,:) = zcoef * vb(:,:,1)
81            sst_m(:,:) = zcoef * tsn(:,:,1,jp_tem)
82            sss_m(:,:) = zcoef * tsn(:,:,1,jp_sal)
83            !                          ! removed inverse barometer ssh when Patm forcing is used
84            IF( ln_apr_dyn ) THEN   ;   ssh_m(:,:) = zcoef * ( sshn(:,:) - 0.5 * ( ssh_ib(:,:) + ssh_ibb(:,:) ) )
85            ELSE                    ;   ssh_m(:,:) = zcoef *   sshn(:,:)
86            ENDIF
87            IF( lk_vvl )   fse3t_m(:,:) = zcoef * fse3t_n(:,:,1)
88            !                                             ! ---------------------------------------- !
89         ELSEIF( MOD( kt - 2 , nn_fsbc ) == 0 ) THEN      !   Initialisation: New mean computation   !
90            !                                             ! ---------------------------------------- !
91            ssu_m(:,:) = 0.e0      ! reset to zero ocean mean sbc fields
92            ssv_m(:,:) = 0.e0
93            sst_m(:,:) = 0.e0
94            sss_m(:,:) = 0.e0
95            ssh_m(:,:) = 0.e0
96            IF( lk_vvl )   fse3t_m(:,:) = 0.e0
97         ENDIF
98         !                                                ! ---------------------------------------- !
99         !                                                !        Cumulate at each time step        !
100         !                                                ! ---------------------------------------- !
101         ssu_m(:,:) = ssu_m(:,:) + ub(:,:,1)
102         ssv_m(:,:) = ssv_m(:,:) + vb(:,:,1)
103         sst_m(:,:) = sst_m(:,:) + tsn(:,:,1,jp_tem)
104         sss_m(:,:) = sss_m(:,:) + tsn(:,:,1,jp_sal)
105         !                          ! removed inverse barometer ssh when Patm forcing is used (for sea-ice dynamics)
106         IF( ln_apr_dyn ) THEN   ;   ssh_m(:,:) = ssh_m(:,:) + sshn(:,:) - 0.5 *  ( ssh_ib(:,:) + ssh_ibb(:,:) )
107         ELSE                    ;   ssh_m(:,:) = ssh_m(:,:) + sshn(:,:)
108         ENDIF
109         IF( lk_vvl )   fse3t_m(:,:) = fse3t_m(:,:) + fse3t_n(:,:,1)
110
111         !                                                ! ---------------------------------------- !
112         IF( MOD( kt - 1 , nn_fsbc ) == 0 ) THEN          !   Mean value at each nn_fsbc time-step   !
113            !                                             ! ---------------------------------------- !
114            zcoef = 1. / REAL( nn_fsbc, wp )
115            sst_m(:,:) = sst_m(:,:) * zcoef           ! mean SST             [Celcius]
116            sss_m(:,:) = sss_m(:,:) * zcoef           ! mean SSS             [psu]
117            ssu_m(:,:) = ssu_m(:,:) * zcoef           ! mean suface current  [m/s]
118            ssv_m(:,:) = ssv_m(:,:) * zcoef           !
119            ssh_m(:,:) = ssh_m(:,:) * zcoef           ! mean SSH             [m]
120            IF( lk_vvl )   fse3t_m(:,:) = fse3t_m(:,:) * zcoef   ! mean vertical scale factor [m]
121            !
122         ENDIF
123         !                                                ! ---------------------------------------- !
124         IF( lrst_oce ) THEN                              !      Write in the ocean restart file     !
125            !                                             ! ---------------------------------------- !
126            IF(lwp) WRITE(numout,*)
127            IF(lwp) WRITE(numout,*) 'sbc_ssm : sea surface mean fields written in ocean restart file ',   &
128               &                    'at it= ', kt,' date= ', ndastp
129            IF(lwp) WRITE(numout,*) '~~~~~~~'
130            zf_sbc = REAL( nn_fsbc, wp )
131            CALL iom_rstput( kt, nitrst, numrow, 'nn_fsbc', zf_sbc )    ! sbc frequency
132            CALL iom_rstput( kt, nitrst, numrow, 'ssu_m'  , ssu_m  )    ! sea surface mean fields
133            CALL iom_rstput( kt, nitrst, numrow, 'ssv_m'  , ssv_m  )
134            CALL iom_rstput( kt, nitrst, numrow, 'sst_m'  , sst_m  )
135            CALL iom_rstput( kt, nitrst, numrow, 'sss_m'  , sss_m  )
136            CALL iom_rstput( kt, nitrst, numrow, 'ssh_m'  , ssh_m  )
137            IF( lk_vvl ) THEN
138               CALL iom_rstput( kt, nitrst, numrow, 'fse3t_m'  , fse3t_m(:,:)  )
139            END IF
140            !
141         ENDIF
142         !
143      ENDIF
144      !
145   END SUBROUTINE sbc_ssm
146
147   SUBROUTINE sbc_ssm_init
148      !!----------------------------------------------------------------------
149      !!                  ***  ROUTINE sbc_ssm_init  ***
150      !!
151      !! ** Purpose :   Initialisation of the sbc data
152      !!
153      !! ** Action  : - read parameters
154      !!----------------------------------------------------------------------
155      REAL(wp) ::   zcoef, zf_sbc       ! local scalar
156      !!----------------------------------------------------------------------
157
158      IF( nn_fsbc == 1 ) THEN
159         !
160         IF(lwp) WRITE(numout,*)
161         IF(lwp) WRITE(numout,*) 'sbc_ssm : sea surface mean fields, nn_fsbc=1 : instantaneous values'
162         IF(lwp) WRITE(numout,*) '~~~~~~~ '
163         !
164      ELSE
165         !               
166         IF(lwp) WRITE(numout,*)
167         IF(lwp) WRITE(numout,*) 'sbc_ssm : sea surface mean fields'
168         IF(lwp) WRITE(numout,*) '~~~~~~~ '
169         !
170         IF( ln_rstart .AND. iom_varid( numror, 'nn_fsbc', ldstop = .FALSE. ) > 0 ) THEN
171            l_ssm_mean = .TRUE.
172            CALL iom_get( numror               , 'nn_fsbc', zf_sbc )   ! sbc frequency of previous run
173            CALL iom_get( numror, jpdom_autoglo, 'ssu_m'  , ssu_m  )   ! sea surface mean velocity    (T-point)
174            CALL iom_get( numror, jpdom_autoglo, 'ssv_m'  , ssv_m  )   !   "         "    velocity    (V-point)
175            CALL iom_get( numror, jpdom_autoglo, 'sst_m'  , sst_m  )   !   "         "    temperature (T-point)
176            CALL iom_get( numror, jpdom_autoglo, 'sss_m'  , sss_m  )   !   "         "    salinity    (T-point)
177            CALL iom_get( numror, jpdom_autoglo, 'ssh_m'  , ssh_m  )   !   "         "    height      (T-point)
178            IF( lk_vvl ) CALL iom_get( numror, jpdom_autoglo, 'fse3t_m', fse3t_m(:,:) )
179            !
180            IF( zf_sbc /= REAL( nn_fsbc, wp ) ) THEN      ! nn_fsbc has changed between 2 runs
181               IF(lwp) WRITE(numout,*) '~~~~~~~   restart with a change in the frequency of mean ',   &
182                  &                    'from ', zf_sbc, ' to ', nn_fsbc 
183               zcoef = REAL( nn_fsbc - 1, wp ) / zf_sbc 
184               ssu_m(:,:) = zcoef * ssu_m(:,:) 
185               ssv_m(:,:) = zcoef * ssv_m(:,:)
186               sst_m(:,:) = zcoef * sst_m(:,:)
187               sss_m(:,:) = zcoef * sss_m(:,:)
188               ssh_m(:,:) = zcoef * ssh_m(:,:)
189               IF( lk_vvl ) fse3t_m(:,:) = zcoef * fse3t_m(:,:)
190            ELSE
191               IF(lwp) WRITE(numout,*) '~~~~~~~   mean fields read in the ocean restart file'
192            ENDIF
193         ENDIF
194      ENDIF
195      !
196   END SUBROUTINE sbc_ssm_init
197
198   !!======================================================================
199END MODULE sbcssm
Note: See TracBrowser for help on using the repository browser.