source: branches/UKMO/AMM15_v3_6_STABLE_package_FABM/NEMOGCM/NEMO/TOP_SRC/trcstp.F90 @ 10156

Last change on this file since 10156 was 10156, checked in by dford, 2 years ago

Apply patch fabm_patch_e3284ca_889163b.diff from Jim Clark.

File size: 8.6 KB
Line 
1MODULE trcstp
2   !!======================================================================
3   !!                       ***  MODULE trcstp  ***
4   !! Time-stepping    : time loop of opa for passive tracer
5   !!======================================================================
6   !! History :  1.0  !  2004-03  (C. Ethe)  Original
7   !!----------------------------------------------------------------------
8#if defined key_top
9   !!----------------------------------------------------------------------
10   !!   trc_stp      : passive tracer system time-stepping
11   !!----------------------------------------------------------------------
12   USE oce_trc          ! ocean dynamics and active tracers variables
13   USE sbc_oce
14   USE trc
15   USE trctrp           ! passive tracers transport
16   USE trcsms           ! passive tracers sources and sinks
17   USE prtctl_trc       ! Print control for debbuging
18   USE trcdia
19   USE trcwri
20   USE trcrst
21   USE trdtrc_oce
22   USE trdmxl_trc
23   USE iom
24   USE in_out_manager
25   USE trcsub
26
27   IMPLICIT NONE
28   PRIVATE
29
30   PUBLIC   trc_stp    ! called by step
31
32   REAL(wp), DIMENSION(:,:,:), SAVE, ALLOCATABLE ::   qsr_arr ! save qsr during TOP time-step
33   REAL(wp) :: rdt_sampl
34   INTEGER  :: nb_rec_per_day
35   INTEGER  :: isecfst, iseclast
36   LOGICAL  :: llnew
37
38   !! * Substitutions
39#  include "domzgr_substitute.h90"
40   !!----------------------------------------------------------------------
41   !! NEMO/TOP 3.3 , NEMO Consortium (2010)
42   !! $Id$
43   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
44   !!----------------------------------------------------------------------
45CONTAINS
46
47   SUBROUTINE trc_stp( kt )
48      !!-------------------------------------------------------------------
49      !!                     ***  ROUTINE trc_stp  ***
50      !!                     
51      !! ** Purpose : Time loop of opa for passive tracer
52      !!
53      !! ** Method  :
54      !!              Compute the passive tracers trends
55      !!              Update the passive tracers
56      !!-------------------------------------------------------------------
57      INTEGER, INTENT( in ) ::  kt      ! ocean time-step index
58      INTEGER               ::  jk, jn  ! dummy loop indices
59      REAL(wp)              ::  ztrai
60      CHARACTER (len=25)    ::  charout 
61
62      !!-------------------------------------------------------------------
63      !
64      IF( nn_timing == 1 )   CALL timing_start('trc_stp')
65      !
66      IF( kt == nittrc000 .AND. lk_trdmxl_trc )  CALL trd_mxl_trc_init    ! trends: Mixed-layer
67      !
68      IF( lk_vvl ) THEN                                                   ! update ocean volume due to ssh temporal evolution
69         DO jk = 1, jpk
70            cvol(:,:,jk) = e1e2t(:,:) * fse3t(:,:,jk) * tmask(:,:,jk)
71         END DO
72         IF( lk_degrad )  cvol(:,:,:) = cvol(:,:,:) * facvol(:,:,:)       ! degrad option: reduction by facvol
73         areatot         = glob_sum( cvol(:,:,:) )
74      ENDIF
75      !
76      IF( l_trcdm2dc )   CALL trc_mean_qsr( kt )
77      !   
78      IF( nn_dttrc /= 1 )   CALL trc_sub_stp( kt )  ! averaging physical variables for sub-stepping
79      !   
80      IF( MOD( kt , nn_dttrc ) == 0 ) THEN      ! only every nn_dttrc time step
81         !
82         IF(ln_ctl) THEN
83            WRITE(charout,FMT="('kt =', I4,'  d/m/y =',I2,I2,I4)") kt, nday, nmonth, nyear
84            CALL prt_ctl_trc_info(charout)
85         ENDIF
86         !
87         tra(:,:,:,:) = 0.e0
88         !
89                                   CALL trc_rst_opn  ( kt )       ! Open tracer restart file
90         IF( lrst_trc )            CALL trc_rst_cal  ( kt, 'WRITE' )   ! calendar
91         IF( lk_iomput ) THEN  ;   CALL trc_wri      ( kt )       ! output of passive tracers with iom I/O manager
92         ELSE                  ;   CALL trc_dia      ( kt )       ! output of passive tracers with old I/O manager
93         ENDIF
94                                   CALL trc_sms      ( kt )       ! tracers: sinks and sources
95                                   CALL trc_trp      ( kt )       ! transport of passive tracers
96         IF( kt == nittrc000 ) THEN
97            CALL iom_close( numrtr )       ! close input tracer restart file
98            IF(lwm) CALL FLUSH( numont )   ! flush namelist output
99         ENDIF
100         IF( lrst_trc )            CALL trc_rst_wri  ( kt )       ! write tracer restart file
101         IF( lk_trdmxl_trc  )      CALL trd_mxl_trc  ( kt )       ! trends: Mixed-layer
102#if defined key_tracer_budget
103!slwa tracer budget
104         IF( lk_iomput ) CALL trc_wri (kt, 2) 
105#endif
106         !
107         IF( nn_dttrc /= 1   )     CALL trc_sub_reset( kt )       ! resetting physical variables when sub-stepping
108         !
109      ENDIF
110      !
111      ztrai = 0._wp                                                   !  content of all tracers
112      DO jn = 1, jptra
113         ztrai = ztrai + glob_sum( trn(:,:,:,jn) * cvol(:,:,:)   )
114      END DO
115      IF( lwp ) WRITE(numstr,9300) kt,  ztrai / areatot
1169300  FORMAT(i10,e18.10)
117      !
118      IF( nn_timing == 1 )   CALL timing_stop('trc_stp')
119      !
120   END SUBROUTINE trc_stp
121
122   SUBROUTINE trc_mean_qsr( kt )
123      !!----------------------------------------------------------------------
124      !!             ***  ROUTINE trc_mean_qsr  ***
125      !!
126      !! ** Purpose :  Compute daily mean qsr for biogeochemical model in case
127      !!               of diurnal cycle
128      !!
129      !! ** Method  : store in TOP the qsr every hour ( or every time-step if the latter
130      !!              is greater than 1 hour ) and then, compute the  mean with
131      !!              a moving average over 24 hours.
132      !!              In coupled mode, the sampling is done at every coupling frequency
133      !!----------------------------------------------------------------------
134      INTEGER, INTENT(in) ::   kt
135      INTEGER  :: jn
136
137      IF( kt == nittrc000 ) THEN
138         IF( ln_cpl )  THEN 
139            rdt_sampl = 86400. / ncpl_qsr_freq
140            nb_rec_per_day = ncpl_qsr_freq
141         ELSE 
142            rdt_sampl = MAX( 3600., rdt * nn_dttrc )
143            nb_rec_per_day = INT( 86400 / rdt_sampl )
144         ENDIF
145         !
146         IF( lwp ) THEN
147            WRITE(numout,*) 
148            WRITE(numout,*) ' Sampling frequency dt = ', rdt_sampl, 's','   Number of sampling per day  nrec = ', nb_rec_per_day
149            WRITE(numout,*) 
150         ENDIF
151         !
152         !                                            !* Restart: read in restart file
153         IF( ln_rsttr .AND. iom_varid( numrtr, 'qsr_mean', ldstop = .FALSE. ) > 0 ) THEN
154            IF(lwp) WRITE(numout,*) 'trc_qsr_mean:   qsr_mean read in the restart file'
155            CALL iom_get( numrtr, jpdom_autoglo, 'qsr_mean', qsr_mean )   !  A mean of qsr
156         ELSE                                         !* no restart: set from nit000 values
157            IF(lwp) WRITE(numout,*) 'trc_qsr_mean:   qsr_mean set to nit000 values'
158            qsr_mean(:,:) = qsr(:,:)
159         ENDIF
160         !
161         ALLOCATE( qsr_arr(jpi,jpj,nb_rec_per_day ) )
162         DO jn = 1, nb_rec_per_day
163             qsr_arr(:,:,jn) = qsr_mean(:,:)
164         ENDDO
165         !
166         isecfst  = nsec_year + nsec1jan000   !   number of seconds between Jan. 1st 00h of nit000 year and the middle of time step
167         iseclast = isecfst
168         !
169      ENDIF
170      !
171      iseclast = nsec_year + nsec1jan000
172      llnew   = ( iseclast - isecfst )  > INT( rdt_sampl )   !   new shortwave to store
173      IF( kt /= nittrc000 .AND. llnew ) THEN
174          IF( lwp ) WRITE(numout,*) ' New shortwave to sample for TOP at time kt = ', kt, &
175             &                      ' time = ', (iseclast+rdt*nn_dttrc/2.)/3600.,'hours '
176          isecfst = iseclast
177          DO jn = 1, nb_rec_per_day - 1
178             qsr_arr(:,:,jn) = qsr_arr(:,:,jn+1)
179          ENDDO
180          qsr_arr (:,:,nb_rec_per_day) = qsr(:,:)
181          qsr_mean(:,:                ) = SUM( qsr_arr(:,:,:), 3 ) / nb_rec_per_day
182      ENDIF
183      !
184      IF( lrst_trc ) THEN    !* Write the mean of qsr in restart file
185         IF(lwp) WRITE(numout,*)
186         IF(lwp) WRITE(numout,*) 'trc_mean_qsr : write qsr_mean in restart file  kt =', kt
187         IF(lwp) WRITE(numout,*) '~~~~~~~'
188         CALL iom_rstput( kt, nitrst, numrtw, 'qsr_mean', qsr_mean(:,:) )
189      ENDIF
190     !
191   END SUBROUTINE trc_mean_qsr
192
193#else
194   !!----------------------------------------------------------------------
195   !!   Default key                                     NO passive tracers
196   !!----------------------------------------------------------------------
197CONTAINS
198   SUBROUTINE trc_stp( kt )        ! Empty routine
199      WRITE(*,*) 'trc_stp: You should not have seen this print! error?', kt
200   END SUBROUTINE trc_stp
201#endif
202
203   !!======================================================================
204END MODULE trcstp
Note: See TracBrowser for help on using the repository browser.