New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
trcopt.F90 in branches/UKMO/CO5_package_branch/NEMOGCM/NEMO/TOP_SRC/LOBSTER – NEMO

source: branches/UKMO/CO5_package_branch/NEMOGCM/NEMO/TOP_SRC/LOBSTER/trcopt.F90 @ 7363

Last change on this file since 7363 was 7363, checked in by deazer, 7 years ago

Removed Keywords
File size: 6.9 KB
Line 
1MODULE trcopt
2   !!======================================================================
3   !!                         ***  MODULE trcopt  ***
4   !! TOP :   LOBSTER Compute the light availability in the water column
5   !!======================================================================
6   !! History :    -   !  1995-05  (M. Levy) Original code
7   !!              -   !  1999-09  (J.-M. Andre, M. Levy)
8   !!              -   !  1999-11  (C. Menkes, M.-A. Foujols) itabe initial
9   !!              -   !  2000-02  (M.A. Foujols) change x**y par exp(y*log(x))
10   !!   NEMO      2.0  !  2007-12  (C. Deltel, G. Madec)  F90
11   !!             3.2  !  2009-04  (C. Ethe, G. Madec)  minor optimisation + style
12   !!----------------------------------------------------------------------
13#if defined key_lobster
14   !!----------------------------------------------------------------------
15   !!   'key_lobster'                                     LOBSTER bio-model
16   !!----------------------------------------------------------------------
17   !!   trc_opt        :   Compute the light availability in the water column
18   !!----------------------------------------------------------------------
19   USE oce_trc         !
20   USE trc
21   USE sms_lobster
22   USE prtctl_trc      ! Print control for debbuging
23
24   IMPLICIT NONE
25   PRIVATE
26
27   PUBLIC   trc_opt   ! called in trcprg.F90
28
29   !!* Substitution
30#  include "top_substitute.h90"
31   !!----------------------------------------------------------------------
32   !! NEMO/TOP 3.3 , NEMO Consortium (2010)
33   !! $Id$
34   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
35   !!----------------------------------------------------------------------
36
37CONTAINS
38
39   SUBROUTINE trc_opt( kt )
40      !!---------------------------------------------------------------------
41      !!                     ***  ROUTINE trc_opt  ***
42      !!
43      !! ** Purpose :   computes the light propagation in the water column
44      !!              and the euphotic layer depth
45      !!
46      !! ** Method  :   local par is computed in w layers using light propagation
47      !!              mean par in t layers are computed by integration
48      !!
49!!gm please remplace the '???' by true comments
50      !! ** Action  :   xpar   ???
51      !!                neln   ???
52      !!                xze    ???
53      !!---------------------------------------------------------------------
54      !!
55      INTEGER, INTENT( in ) ::   kt   ! index of the time stepping
56      !!
57      INTEGER  ::   ji, jj, jk          ! dummy loop indices
58      CHARACTER (len=25) ::   charout   ! temporary character
59      REAL(wp) ::   zpig                ! log of the total pigment
60      REAL(wp) ::   zkr, zkg            ! total absorption coefficient in red and green
61      REAL(wp) ::   zcoef               ! temporary scalar
62      REAL(wp), POINTER, DIMENSION(:,:  ) :: zpar100, zpar0m 
63      REAL(wp), POINTER, DIMENSION(:,:,:) :: zparr, zparg
64      !!---------------------------------------------------------------------
65      !
66      IF( nn_timing == 1 )  CALL timing_start('trc_opt')
67      !
68      ! Allocate temporary workspace
69      CALL wrk_alloc( jpi, jpj,      zpar100, zpar0m )
70      CALL wrk_alloc( jpi, jpj, jpk, zparr, zparg    )
71
72      IF( kt == nittrc000 ) THEN
73         IF(lwp) WRITE(numout,*)
74         IF(lwp) WRITE(numout,*) ' trc_opt : LOBSTER optic-model'
75         IF(lwp) WRITE(numout,*) ' ~~~~~~~ '
76      ENDIF
77
78      !                                          ! surface irradiance
79      zpar0m (:,:)   = qsr   (:,:) * 0.43        ! ------------------
80      zpar100(:,:)   = zpar0m(:,:) * 0.01
81      xpar   (:,:,1) = zpar0m(:,:)
82      zparr  (:,:,1) = zpar0m(:,:) * 0.5
83      zparg  (:,:,1) = zpar0m(:,:) * 0.5
84
85      !                                          ! Photosynthetically Available Radiation (PAR)
86      zcoef = 12 * redf / rcchl / rpig           ! --------------------------------------
87      DO jk = 2, jpk                                  ! local par at w-levels
88         DO jj = 1, jpj
89            DO ji = 1, jpi
90               zpig = LOG(  MAX( TINY(0.), trn(ji,jj,jk-1,jp_lob_phy) ) * zcoef  )
91               zkr  = xkr0 + xkrp * EXP( xlr * zpig )
92               zkg  = xkg0 + xkgp * EXP( xlg * zpig )
93               zparr(ji,jj,jk) = zparr(ji,jj,jk-1) * EXP( -zkr * fse3t(ji,jj,jk-1) )
94               zparg(ji,jj,jk) = zparg(ji,jj,jk-1) * EXP( -zkg * fse3t(ji,jj,jk-1) )
95            END DO
96        END DO
97      END DO
98      DO jk = 1, jpkm1                                ! mean par at t-levels
99         DO jj = 1, jpj
100            DO ji = 1, jpi
101               zpig = LOG(  MAX( TINY(0.), trn(ji,jj,jk,jp_lob_phy) ) * zcoef  )
102               zkr  = xkr0 + xkrp * EXP( xlr * zpig )
103               zkg  = xkg0 + xkgp * EXP( xlg * zpig )
104               zparr(ji,jj,jk) = zparr(ji,jj,jk) / ( zkr * fse3t(ji,jj,jk) ) * ( 1 - EXP( -zkr * fse3t(ji,jj,jk) ) )
105               zparg(ji,jj,jk) = zparg(ji,jj,jk) / ( zkg * fse3t(ji,jj,jk) ) * ( 1 - EXP( -zkg * fse3t(ji,jj,jk) ) )
106               xpar (ji,jj,jk) = MAX( zparr(ji,jj,jk) + zparg(ji,jj,jk), 1.e-15 )
107            END DO
108         END DO
109      END DO
110
111      !                                          ! Euphotic layer
112      !                                          ! --------------
113      neln(:,:) = 1                                   ! euphotic layer level
114      DO jk = 1, jpk                                  ! (i.e. 1rst T-level strictly below EL bottom)
115         DO jj = 1, jpj
116           DO ji = 1, jpi
117              IF( xpar(ji,jj,jk) >= zpar100(ji,jj) )   neln(ji,jj) = jk + 1 
118              !                                       ! nb. this is to ensure compatibility with
119              !                                       ! nmld_trc definition in trd_mld_trc_zint
120           END DO
121         END DO
122      END DO
123      !                                               ! Euphotic layer depth
124      DO jj = 1, jpj
125         DO ji = 1, jpi
126            xze(ji,jj) = fsdepw(ji,jj,neln(ji,jj))
127         END DO
128      END DO
129
130
131      IF(ln_ctl) THEN      ! print mean trends (used for debugging)
132         WRITE(charout, FMT="('opt')")
133         CALL prt_ctl_trc_info( charout )
134         CALL prt_ctl_trc( tab4d=trn, mask=tmask, clinfo=ctrcnm )
135      ENDIF
136      !
137      CALL wrk_dealloc( jpi, jpj,      zpar100, zpar0m )
138      CALL wrk_dealloc( jpi, jpj, jpk, zparr, zparg    )
139      !
140      IF( nn_timing == 1 )  CALL timing_stop('trc_opt')
141      !
142   END SUBROUTINE trc_opt
143
144#else
145   !!======================================================================
146   !!  Dummy module :                                   No PISCES bio-model
147   !!======================================================================
148CONTAINS
149   SUBROUTINE trc_opt( kt )                   ! Empty routine
150      INTEGER, INTENT( in ) ::   kt
151      WRITE(*,*) 'trc_opt: You should not have seen this print! error?', kt
152   END SUBROUTINE trc_opt
153#endif 
154
155   !!======================================================================
156END MODULE  trcopt
Note: See TracBrowser for help on using the repository browser.