1 | MODULE nemogcm |
---|
2 | !!====================================================================== |
---|
3 | !! *** MODULE nemogcm *** |
---|
4 | !! Off-line Ocean : passive tracer evolution, dynamics read in files |
---|
5 | !!====================================================================== |
---|
6 | !! History : 3.3 ! 2010-05 (C. Ethe) Full reorganization of the off-line: phasing with the on-line |
---|
7 | !! 3.4 ! 2011-01 (C. Ethe, A. R. Porter, STFC Daresbury) dynamical allocation |
---|
8 | !! 4.0 ! 2016-10 (C. Ethe, G. Madec, S. Flavoni) domain configuration / user defined interface |
---|
9 | !!---------------------------------------------------------------------- |
---|
10 | |
---|
11 | !!---------------------------------------------------------------------- |
---|
12 | !! nemo_gcm : off-line: solve ocean tracer only |
---|
13 | !! nemo_gcm : solve ocean dynamics, tracer, biogeochemistry and/or sea-ice |
---|
14 | !! nemo_init : initialization of the NEMO system |
---|
15 | !! nemo_ctl : initialisation of the contol print |
---|
16 | !! nemo_closefile: close remaining open files |
---|
17 | !! nemo_alloc : dynamical allocation |
---|
18 | !! istate_init : simple initialization to zero of ocean fields |
---|
19 | !! stp_ctl : reduced step control (no dynamics in off-line) |
---|
20 | !!---------------------------------------------------------------------- |
---|
21 | USE dom_oce ! ocean space domain variables |
---|
22 | USE oce ! dynamics and tracers variables |
---|
23 | USE trc_oce ! Shared ocean/passive tracers variables |
---|
24 | USE c1d ! 1D configuration |
---|
25 | USE domain ! domain initialization from coordinate & bathymetry (dom_init routine) |
---|
26 | USE closea ! treatment of closed seas (for ln_closea) |
---|
27 | USE usrdef_nam ! user defined configuration |
---|
28 | USE eosbn2 ! equation of state (eos bn2 routine) |
---|
29 | ! ! ocean physics |
---|
30 | USE ldftra ! lateral diffusivity setting (ldf_tra_init routine) |
---|
31 | USE ldfslp ! slopes of neutral surfaces (ldf_slp_init routine) |
---|
32 | USE traqsr ! solar radiation penetration (tra_qsr_init routine) |
---|
33 | USE trabbl ! bottom boundary layer (tra_bbl_init routine) |
---|
34 | USE traldf ! lateral physics (tra_ldf_init routine) |
---|
35 | USE sbcmod ! surface boundary condition (sbc_init routine) |
---|
36 | USE phycst ! physical constant (par_cst routine) |
---|
37 | USE dtadyn ! Lecture and Interpolation of the dynamical fields |
---|
38 | USE trcini ! Initilization of the passive tracers |
---|
39 | USE daymod ! calendar (day routine) |
---|
40 | USE trcstp ! passive tracer time-stepping (trc_stp routine) |
---|
41 | USE dtadyn ! Lecture and interpolation of the dynamical fields |
---|
42 | ! ! Passive tracers needs |
---|
43 | USE trc ! passive tracer : variables |
---|
44 | USE trcnam ! passive tracer : namelist |
---|
45 | USE trcrst ! passive tracer restart |
---|
46 | USE diaptr ! Need to initialise this as some variables are used in if statements later |
---|
47 | USE sbc_oce , ONLY : ln_rnf |
---|
48 | USE sbcrnf ! surface boundary condition : runoffs |
---|
49 | ! ! I/O & MPP |
---|
50 | USE iom ! I/O library |
---|
51 | USE in_out_manager ! I/O manager |
---|
52 | USE mppini ! shared/distributed memory setting (mpp_init routine) |
---|
53 | USE lib_mpp ! distributed memory computing |
---|
54 | #if defined key_iomput |
---|
55 | USE xios ! xIOserver |
---|
56 | #endif |
---|
57 | USE prtctl ! Print control (prt_ctl_init routine) |
---|
58 | USE timing ! Timing |
---|
59 | USE lib_fortran ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) |
---|
60 | USE lbcnfd , ONLY : isendto, nsndto, nfsloop, nfeloop ! Setup of north fold exchanges |
---|
61 | |
---|
62 | IMPLICIT NONE |
---|
63 | PRIVATE |
---|
64 | |
---|
65 | PUBLIC nemo_gcm ! called by nemo.F90 |
---|
66 | |
---|
67 | CHARACTER (len=64) :: cform_aaa="( /, 'AAAAAAAA', / ) " ! flag for output listing |
---|
68 | |
---|
69 | !!---------------------------------------------------------------------- |
---|
70 | !! NEMO/OFF 4.0 , NEMO Consortium (2018) |
---|
71 | !! $Id$ |
---|
72 | !! Software governed by the CeCILL licence (./LICENSE) |
---|
73 | !!---------------------------------------------------------------------- |
---|
74 | CONTAINS |
---|
75 | |
---|
76 | SUBROUTINE nemo_gcm |
---|
77 | !!---------------------------------------------------------------------- |
---|
78 | !! *** ROUTINE nemo_gcm *** |
---|
79 | !! |
---|
80 | !! ** Purpose : NEMO solves the primitive equations on an orthogonal |
---|
81 | !! curvilinear mesh on the sphere. |
---|
82 | !! |
---|
83 | !! ** Method : - model general initialization |
---|
84 | !! - launch the time-stepping (dta_dyn and trc_stp) |
---|
85 | !! - finalize the run by closing files and communications |
---|
86 | !! |
---|
87 | !! References : Madec, Delecluse,Imbard, and Levy, 1997: internal report, IPSL. |
---|
88 | !! Madec, 2008, internal report, IPSL. |
---|
89 | !!---------------------------------------------------------------------- |
---|
90 | INTEGER :: istp, indic ! time step index |
---|
91 | !!---------------------------------------------------------------------- |
---|
92 | |
---|
93 | CALL nemo_init ! Initializations |
---|
94 | |
---|
95 | ! check that all process are still there... If some process have an error, |
---|
96 | ! they will never enter in step and other processes will wait until the end of the cpu time! |
---|
97 | IF( lk_mpp ) CALL mpp_max( nstop ) |
---|
98 | |
---|
99 | ! !-----------------------! |
---|
100 | ! !== time stepping ==! |
---|
101 | ! !-----------------------! |
---|
102 | istp = nit000 |
---|
103 | ! |
---|
104 | IF( ln_rnf ) CALL sbc_rnf(istp) ! runoffs initialization |
---|
105 | ! |
---|
106 | CALL iom_init( cxios_context ) ! iom_put initialization (must be done after nemo_init for AGRIF+XIOS+OASIS) |
---|
107 | ! |
---|
108 | DO WHILE ( istp <= nitend .AND. nstop == 0 ) !== OFF time-stepping ==! |
---|
109 | ! |
---|
110 | IF( istp /= nit000 ) CALL day ( istp ) ! Calendar (day was already called at nit000 in day_init) |
---|
111 | CALL iom_setkt ( istp - nit000 + 1, cxios_context ) ! say to iom that we are at time step kstp |
---|
112 | CALL dta_dyn ( istp ) ! Interpolation of the dynamical fields |
---|
113 | IF( .NOT.ln_linssh ) CALL dta_dyn_swp( istp ) ! swap of sea surface height and vertical scale factors |
---|
114 | |
---|
115 | CALL trc_stp ( istp ) ! time-stepping |
---|
116 | CALL stp_ctl ( istp, indic ) ! Time loop: control and print |
---|
117 | istp = istp + 1 |
---|
118 | END DO |
---|
119 | ! |
---|
120 | #if defined key_iomput |
---|
121 | CALL iom_context_finalize( cxios_context ) ! needed for XIOS+AGRIF |
---|
122 | #endif |
---|
123 | |
---|
124 | ! !------------------------! |
---|
125 | ! !== finalize the run ==! |
---|
126 | ! !------------------------! |
---|
127 | IF(lwp) WRITE(numout,cform_aaa) ! Flag AAAAAAA |
---|
128 | |
---|
129 | IF( nstop /= 0 .AND. lwp ) THEN ! error print |
---|
130 | WRITE(numout,cform_err) |
---|
131 | WRITE(numout,*) ' ==>>> nemo_gcm: a total of ', nstop, ' errors have been found' |
---|
132 | WRITE(numout,*) |
---|
133 | ENDIF |
---|
134 | ! |
---|
135 | IF( ln_timing ) CALL timing_finalize |
---|
136 | ! |
---|
137 | CALL nemo_closefile |
---|
138 | ! |
---|
139 | #if defined key_iomput |
---|
140 | CALL xios_finalize ! end mpp communications with xios |
---|
141 | #else |
---|
142 | IF( lk_mpp ) CALL mppstop ! end mpp communications |
---|
143 | #endif |
---|
144 | ! |
---|
145 | END SUBROUTINE nemo_gcm |
---|
146 | |
---|
147 | |
---|
148 | SUBROUTINE nemo_init |
---|
149 | !!---------------------------------------------------------------------- |
---|
150 | !! *** ROUTINE nemo_init *** |
---|
151 | !! |
---|
152 | !! ** Purpose : initialization of the nemo model in off-line mode |
---|
153 | !!---------------------------------------------------------------------- |
---|
154 | INTEGER :: ji ! dummy loop indices |
---|
155 | INTEGER :: ios, ilocal_comm ! local integers |
---|
156 | CHARACTER(len=120), DIMENSION(30) :: cltxt, cltxt2, clnam |
---|
157 | !! |
---|
158 | NAMELIST/namctl/ ln_ctl , nn_print, nn_ictls, nn_ictle, & |
---|
159 | & nn_isplt , nn_jsplt, nn_jctls, nn_jctle, & |
---|
160 | & ln_timing, ln_diacfl |
---|
161 | NAMELIST/namcfg/ ln_read_cfg, cn_domcfg, ln_closea, ln_write_cfg, cn_domcfg_out, ln_use_jattr |
---|
162 | !!---------------------------------------------------------------------- |
---|
163 | ! |
---|
164 | cltxt = '' |
---|
165 | cltxt2 = '' |
---|
166 | clnam = '' |
---|
167 | cxios_context = 'nemo' |
---|
168 | ! |
---|
169 | ! ! Open reference namelist and configuration namelist files |
---|
170 | CALL ctl_opn( numnam_ref, 'namelist_ref', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. ) |
---|
171 | CALL ctl_opn( numnam_cfg, 'namelist_cfg', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. ) |
---|
172 | ! |
---|
173 | REWIND( numnam_ref ) ! Namelist namctl in reference namelist |
---|
174 | READ ( numnam_ref, namctl, IOSTAT = ios, ERR = 901 ) |
---|
175 | 901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namctl in reference namelist', .TRUE. ) |
---|
176 | REWIND( numnam_cfg ) ! Namelist namctl in confguration namelist |
---|
177 | READ ( numnam_cfg, namctl, IOSTAT = ios, ERR = 902 ) |
---|
178 | 902 IF( ios > 0 ) CALL ctl_nam ( ios , 'namctl in configuration namelist', .TRUE. ) |
---|
179 | ! |
---|
180 | REWIND( numnam_ref ) ! Namelist namcfg in reference namelist |
---|
181 | READ ( numnam_ref, namcfg, IOSTAT = ios, ERR = 903 ) |
---|
182 | 903 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namcfg in reference namelist', .TRUE. ) |
---|
183 | REWIND( numnam_cfg ) ! Namelist namcfg in confguration namelist |
---|
184 | READ ( numnam_cfg, namcfg, IOSTAT = ios, ERR = 904 ) |
---|
185 | 904 IF( ios > 0 ) CALL ctl_nam ( ios , 'namcfg in configuration namelist', .TRUE. ) |
---|
186 | |
---|
187 | ! !--------------------------! |
---|
188 | ! ! Set global domain size ! (control print return in cltxt2) |
---|
189 | ! !--------------------------! |
---|
190 | IF( ln_read_cfg ) THEN ! Read sizes in domain configuration file |
---|
191 | CALL domain_cfg ( cltxt2, cn_cfg, nn_cfg, jpiglo, jpjglo, jpkglo, jperio ) |
---|
192 | ! |
---|
193 | ELSE ! user-defined namelist |
---|
194 | CALL usr_def_nam( cltxt2, clnam, cn_cfg, nn_cfg, jpiglo, jpjglo, jpkglo, jperio ) |
---|
195 | ENDIF |
---|
196 | ! |
---|
197 | l_offline = .true. ! passive tracers are run offline |
---|
198 | ! |
---|
199 | ! !--------------------------------------------! |
---|
200 | ! ! set communicator & select the local node ! |
---|
201 | ! ! NB: mynode also opens output.namelist.dyn ! |
---|
202 | ! ! on unit number numond on first proc ! |
---|
203 | ! !--------------------------------------------! |
---|
204 | #if defined key_iomput |
---|
205 | CALL xios_initialize( "for_xios_mpi_id",return_comm=ilocal_comm ) |
---|
206 | narea = mynode( cltxt, 'output.namelist.dyn', numnam_ref, numnam_cfg, numond , nstop, ilocal_comm ) ! Nodes selection |
---|
207 | #else |
---|
208 | ilocal_comm = 0 |
---|
209 | narea = mynode( cltxt, 'output.namelist.dyn', numnam_ref, numnam_cfg, numond , nstop ) ! Nodes selection (control print return in cltxt) |
---|
210 | #endif |
---|
211 | |
---|
212 | narea = narea + 1 ! mynode return the rank of proc (0 --> jpnij -1 ) |
---|
213 | |
---|
214 | lwm = (narea == 1) ! control of output namelists |
---|
215 | lwp = (narea == 1) .OR. ln_ctl ! control of all listing output print |
---|
216 | |
---|
217 | IF(lwm) THEN ! write merged namelists from earlier to output namelist |
---|
218 | ! ! now that the file has been opened in call to mynode. |
---|
219 | ! ! NB: nammpp has already been written in mynode (if lk_mpp_mpi) |
---|
220 | WRITE( numond, namctl ) |
---|
221 | WRITE( numond, namcfg ) |
---|
222 | IF( .NOT.ln_read_cfg ) THEN |
---|
223 | DO ji = 1, SIZE(clnam) |
---|
224 | IF( TRIM(clnam(ji)) /= '' ) WRITE(numond, * ) clnam(ji) ! namusr_def print |
---|
225 | END DO |
---|
226 | ENDIF |
---|
227 | ENDIF |
---|
228 | |
---|
229 | IF(lwp) THEN ! open listing units |
---|
230 | ! |
---|
231 | CALL ctl_opn( numout, 'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE., narea ) |
---|
232 | ! |
---|
233 | WRITE(numout,*) |
---|
234 | WRITE(numout,*) ' CNRS - NERC - Met OFFICE - MERCATOR-ocean - INGV - CMCC' |
---|
235 | WRITE(numout,*) ' NEMO team' |
---|
236 | WRITE(numout,*) ' Off-line TOP Model' |
---|
237 | WRITE(numout,*) ' NEMO version 4.0 (2017) ' |
---|
238 | WRITE(numout,*) |
---|
239 | WRITE(numout,*) |
---|
240 | DO ji = 1, SIZE(cltxt) |
---|
241 | IF( TRIM(cltxt (ji)) /= '' ) WRITE(numout,*) cltxt(ji) ! control print of mynode |
---|
242 | END DO |
---|
243 | WRITE(numout,*) |
---|
244 | WRITE(numout,*) |
---|
245 | DO ji = 1, SIZE(cltxt2) |
---|
246 | IF( TRIM(cltxt2(ji)) /= '' ) WRITE(numout,*) cltxt2(ji) ! control print of domain size |
---|
247 | END DO |
---|
248 | ! |
---|
249 | WRITE(numout,cform_aaa) ! Flag AAAAAAA |
---|
250 | ! |
---|
251 | ENDIF |
---|
252 | ! ! Domain decomposition |
---|
253 | CALL mpp_init ! MPP |
---|
254 | |
---|
255 | ! Now we know the dimensions of the grid and numout has been set: we can allocate arrays |
---|
256 | CALL nemo_alloc() |
---|
257 | |
---|
258 | ! !-------------------------------! |
---|
259 | ! ! NEMO general initialization ! |
---|
260 | ! !-------------------------------! |
---|
261 | |
---|
262 | CALL nemo_ctl ! Control prints |
---|
263 | ! |
---|
264 | ! ! General initialization |
---|
265 | IF( ln_timing ) CALL timing_init |
---|
266 | IF( ln_timing ) CALL timing_start( 'nemo_init') |
---|
267 | ! |
---|
268 | CALL phy_cst ! Physical constants |
---|
269 | CALL eos_init ! Equation of state |
---|
270 | IF( lk_c1d ) CALL c1d_init ! 1D column configuration |
---|
271 | CALL dom_init("OPA") ! Domain |
---|
272 | IF( ln_ctl ) CALL prt_ctl_init ! Print control |
---|
273 | |
---|
274 | CALL istate_init ! ocean initial state (Dynamics and tracers) |
---|
275 | |
---|
276 | CALL sbc_init ! Forcings : surface module |
---|
277 | |
---|
278 | ! ! Tracer physics |
---|
279 | CALL ldf_tra_init ! Lateral ocean tracer physics |
---|
280 | CALL ldf_eiv_init ! Eddy induced velocity param |
---|
281 | CALL tra_ldf_init ! lateral mixing |
---|
282 | IF( l_ldfslp ) CALL ldf_slp_init ! slope of lateral mixing |
---|
283 | IF( ln_traqsr ) CALL tra_qsr_init ! penetrative solar radiation |
---|
284 | IF( ln_trabbl ) CALL tra_bbl_init ! advective (and/or diffusive) bottom boundary layer scheme |
---|
285 | |
---|
286 | ! ! Passive tracers |
---|
287 | CALL trc_nam_run ! Needed to get restart parameters for passive tracers |
---|
288 | CALL trc_rst_cal( nit000, 'READ' ) ! calendar |
---|
289 | CALL dta_dyn_init ! Initialization for the dynamics |
---|
290 | |
---|
291 | CALL trc_init ! Passive tracers initialization |
---|
292 | CALL dia_ptr_init ! Poleward TRansports initialization |
---|
293 | |
---|
294 | IF(lwp) WRITE(numout,cform_aaa) ! Flag AAAAAAA |
---|
295 | ! |
---|
296 | IF( ln_timing ) CALL timing_stop( 'nemo_init') |
---|
297 | ! |
---|
298 | END SUBROUTINE nemo_init |
---|
299 | |
---|
300 | |
---|
301 | SUBROUTINE nemo_ctl |
---|
302 | !!---------------------------------------------------------------------- |
---|
303 | !! *** ROUTINE nemo_ctl *** |
---|
304 | !! |
---|
305 | !! ** Purpose : control print setting |
---|
306 | !! |
---|
307 | !! ** Method : - print namctl information and check some consistencies |
---|
308 | !!---------------------------------------------------------------------- |
---|
309 | ! |
---|
310 | IF(lwp) THEN ! control print |
---|
311 | WRITE(numout,*) |
---|
312 | WRITE(numout,*) 'nemo_ctl: Control prints' |
---|
313 | WRITE(numout,*) '~~~~~~~~' |
---|
314 | WRITE(numout,*) ' Namelist namctl' |
---|
315 | WRITE(numout,*) ' run control (for debugging) ln_ctl = ', ln_ctl |
---|
316 | WRITE(numout,*) ' level of print nn_print = ', nn_print |
---|
317 | WRITE(numout,*) ' Start i indice for SUM control nn_ictls = ', nn_ictls |
---|
318 | WRITE(numout,*) ' End i indice for SUM control nn_ictle = ', nn_ictle |
---|
319 | WRITE(numout,*) ' Start j indice for SUM control nn_jctls = ', nn_jctls |
---|
320 | WRITE(numout,*) ' End j indice for SUM control nn_jctle = ', nn_jctle |
---|
321 | WRITE(numout,*) ' number of proc. following i nn_isplt = ', nn_isplt |
---|
322 | WRITE(numout,*) ' number of proc. following j nn_jsplt = ', nn_jsplt |
---|
323 | WRITE(numout,*) ' timing by routine ln_timing = ', ln_timing |
---|
324 | WRITE(numout,*) ' CFL diagnostics ln_diacfl = ', ln_diacfl |
---|
325 | ENDIF |
---|
326 | ! |
---|
327 | nprint = nn_print ! convert DOCTOR namelist names into OLD names |
---|
328 | nictls = nn_ictls |
---|
329 | nictle = nn_ictle |
---|
330 | njctls = nn_jctls |
---|
331 | njctle = nn_jctle |
---|
332 | isplt = nn_isplt |
---|
333 | jsplt = nn_jsplt |
---|
334 | |
---|
335 | IF(lwp) THEN ! control print |
---|
336 | WRITE(numout,*) |
---|
337 | WRITE(numout,*) ' Namelist namcfg' |
---|
338 | WRITE(numout,*) ' read domain configuration file ln_read_cfg = ', ln_read_cfg |
---|
339 | WRITE(numout,*) ' filename to be read cn_domcfg = ', TRIM(cn_domcfg) |
---|
340 | WRITE(numout,*) ' keep closed seas in the domain (if exist) ln_closea = ', ln_closea |
---|
341 | WRITE(numout,*) ' create a configuration definition file ln_write_cfg = ', ln_write_cfg |
---|
342 | WRITE(numout,*) ' filename to be written cn_domcfg_out = ', TRIM(cn_domcfg_out) |
---|
343 | WRITE(numout,*) ' use file attribute if exists as i/p j-start ln_use_jattr = ', ln_use_jattr |
---|
344 | ENDIF |
---|
345 | IF( .NOT.ln_read_cfg ) ln_closea = .false. ! dealing possible only with a domcfg file |
---|
346 | ! |
---|
347 | ! ! Parameter control |
---|
348 | ! |
---|
349 | IF( ln_ctl ) THEN ! sub-domain area indices for the control prints |
---|
350 | IF( lk_mpp .AND. jpnij > 1 ) THEN |
---|
351 | isplt = jpni ; jsplt = jpnj ; ijsplt = jpni*jpnj ! the domain is forced to the real split domain |
---|
352 | ELSE |
---|
353 | IF( isplt == 1 .AND. jsplt == 1 ) THEN |
---|
354 | CALL ctl_warn( ' - isplt & jsplt are equal to 1', & |
---|
355 | & ' - the print control will be done over the whole domain' ) |
---|
356 | ENDIF |
---|
357 | ijsplt = isplt * jsplt ! total number of processors ijsplt |
---|
358 | ENDIF |
---|
359 | IF(lwp) WRITE(numout,*)' - The total number of processors over which the' |
---|
360 | IF(lwp) WRITE(numout,*)' print control will be done is ijsplt : ', ijsplt |
---|
361 | ! |
---|
362 | ! ! indices used for the SUM control |
---|
363 | IF( nictls+nictle+njctls+njctle == 0 ) THEN ! print control done over the default area |
---|
364 | lsp_area = .FALSE. |
---|
365 | ELSE ! print control done over a specific area |
---|
366 | lsp_area = .TRUE. |
---|
367 | IF( nictls < 1 .OR. nictls > jpiglo ) THEN |
---|
368 | CALL ctl_warn( ' - nictls must be 1<=nictls>=jpiglo, it is forced to 1' ) |
---|
369 | nictls = 1 |
---|
370 | ENDIF |
---|
371 | IF( nictle < 1 .OR. nictle > jpiglo ) THEN |
---|
372 | CALL ctl_warn( ' - nictle must be 1<=nictle>=jpiglo, it is forced to jpiglo' ) |
---|
373 | nictle = jpiglo |
---|
374 | ENDIF |
---|
375 | IF( njctls < 1 .OR. njctls > jpjglo ) THEN |
---|
376 | CALL ctl_warn( ' - njctls must be 1<=njctls>=jpjglo, it is forced to 1' ) |
---|
377 | njctls = 1 |
---|
378 | ENDIF |
---|
379 | IF( njctle < 1 .OR. njctle > jpjglo ) THEN |
---|
380 | CALL ctl_warn( ' - njctle must be 1<=njctle>=jpjglo, it is forced to jpjglo' ) |
---|
381 | njctle = jpjglo |
---|
382 | ENDIF |
---|
383 | ENDIF |
---|
384 | ENDIF |
---|
385 | ! |
---|
386 | IF( 1._wp /= SIGN(1._wp,-0._wp) ) CALL ctl_stop( 'nemo_ctl: The intrinsec SIGN function follows f2003 standard.', & |
---|
387 | & 'Compile with key_nosignedzero enabled' ) |
---|
388 | ! |
---|
389 | END SUBROUTINE nemo_ctl |
---|
390 | |
---|
391 | |
---|
392 | SUBROUTINE nemo_closefile |
---|
393 | !!---------------------------------------------------------------------- |
---|
394 | !! *** ROUTINE nemo_closefile *** |
---|
395 | !! |
---|
396 | !! ** Purpose : Close the files |
---|
397 | !!---------------------------------------------------------------------- |
---|
398 | ! |
---|
399 | IF( lk_mpp ) CALL mppsync |
---|
400 | ! |
---|
401 | CALL iom_close ! close all input/output files managed by iom_* |
---|
402 | ! |
---|
403 | IF( numstp /= -1 ) CLOSE( numstp ) ! time-step file |
---|
404 | IF( numnam_ref /= -1 ) CLOSE( numnam_ref ) ! oce reference namelist |
---|
405 | IF( numnam_cfg /= -1 ) CLOSE( numnam_cfg ) ! oce configuration namelist |
---|
406 | IF( numout /= 6 ) CLOSE( numout ) ! standard model output file |
---|
407 | IF( lwm.AND.numond /= -1 ) CLOSE( numond ) ! oce output namelist |
---|
408 | ! |
---|
409 | numout = 6 ! redefine numout in case it is used after this point... |
---|
410 | ! |
---|
411 | END SUBROUTINE nemo_closefile |
---|
412 | |
---|
413 | |
---|
414 | SUBROUTINE nemo_alloc |
---|
415 | !!---------------------------------------------------------------------- |
---|
416 | !! *** ROUTINE nemo_alloc *** |
---|
417 | !! |
---|
418 | !! ** Purpose : Allocate all the dynamic arrays of the OPA modules |
---|
419 | !! |
---|
420 | !! ** Method : |
---|
421 | !!---------------------------------------------------------------------- |
---|
422 | USE diawri , ONLY : dia_wri_alloc |
---|
423 | USE dom_oce, ONLY : dom_oce_alloc |
---|
424 | USE zdf_oce, ONLY : zdf_oce_alloc |
---|
425 | USE trc_oce, ONLY : trc_oce_alloc |
---|
426 | ! |
---|
427 | INTEGER :: ierr |
---|
428 | !!---------------------------------------------------------------------- |
---|
429 | ! |
---|
430 | ierr = oce_alloc () ! ocean |
---|
431 | ierr = ierr + dia_wri_alloc() |
---|
432 | ierr = ierr + dom_oce_alloc() ! ocean domain |
---|
433 | ierr = ierr + zdf_oce_alloc() ! ocean vertical physics |
---|
434 | ierr = ierr + trc_oce_alloc() ! shared TRC / TRA arrays |
---|
435 | ! |
---|
436 | IF( lk_mpp ) CALL mpp_sum( ierr ) |
---|
437 | IF( ierr /= 0 ) CALL ctl_stop( 'STOP', 'nemo_alloc: unable to allocate standard ocean arrays' ) |
---|
438 | ! |
---|
439 | END SUBROUTINE nemo_alloc |
---|
440 | |
---|
441 | SUBROUTINE istate_init |
---|
442 | !!---------------------------------------------------------------------- |
---|
443 | !! *** ROUTINE istate_init *** |
---|
444 | !! |
---|
445 | !! ** Purpose : Initialization to zero of the dynamics and tracers. |
---|
446 | !!---------------------------------------------------------------------- |
---|
447 | ! |
---|
448 | ! now fields ! after fields ! |
---|
449 | un (:,:,:) = 0._wp ; ua(:,:,:) = 0._wp ! |
---|
450 | vn (:,:,:) = 0._wp ; va(:,:,:) = 0._wp ! |
---|
451 | wn (:,:,:) = 0._wp ! ! |
---|
452 | hdivn(:,:,:) = 0._wp ! ! |
---|
453 | tsn (:,:,:,:) = 0._wp ! ! |
---|
454 | ! |
---|
455 | rhd (:,:,:) = 0.e0 |
---|
456 | rhop (:,:,:) = 0.e0 |
---|
457 | rn2 (:,:,:) = 0.e0 |
---|
458 | ! |
---|
459 | END SUBROUTINE istate_init |
---|
460 | |
---|
461 | |
---|
462 | SUBROUTINE stp_ctl( kt, kindic ) |
---|
463 | !!---------------------------------------------------------------------- |
---|
464 | !! *** ROUTINE stp_ctl *** |
---|
465 | !! |
---|
466 | !! ** Purpose : Control the run |
---|
467 | !! |
---|
468 | !! ** Method : - Save the time step in numstp |
---|
469 | !! |
---|
470 | !! ** Actions : 'time.step' file containing the last ocean time-step |
---|
471 | !!---------------------------------------------------------------------- |
---|
472 | INTEGER, INTENT(in ) :: kt ! ocean time-step index |
---|
473 | INTEGER, INTENT(inout) :: kindic ! indicator of solver convergence |
---|
474 | !!---------------------------------------------------------------------- |
---|
475 | ! |
---|
476 | IF( kt == nit000 .AND. lwp ) THEN |
---|
477 | WRITE(numout,*) |
---|
478 | WRITE(numout,*) 'stp_ctl : time-stepping control' |
---|
479 | WRITE(numout,*) '~~~~~~~' |
---|
480 | ! open time.step file |
---|
481 | CALL ctl_opn( numstp, 'time.step', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, numout, lwp, narea ) |
---|
482 | ENDIF |
---|
483 | ! |
---|
484 | IF(lwp) WRITE ( numstp, '(1x, i8)' ) kt !* save the current time step in numstp |
---|
485 | IF(lwp) REWIND( numstp ) ! -------------------------- |
---|
486 | ! |
---|
487 | END SUBROUTINE stp_ctl |
---|
488 | !!====================================================================== |
---|
489 | END MODULE nemogcm |
---|