New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
trasbc.F90 in branches/UKMO/ROMS_WAD_7832/NEMOGCM/CONFIG/CS15mini/MY_SRC – NEMO

source: branches/UKMO/ROMS_WAD_7832/NEMOGCM/CONFIG/CS15mini/MY_SRC/trasbc.F90 @ 8777

Last change on this file since 8777 was 8777, checked in by deazer, 6 years ago

Includes Bug fix for asseling filter and 3d rivers
Includes limiter in surface fluxesin shallow water near WAD points as a temporary measure.

File size: 12.7 KB
Line 
1MODULE trasbc
2   !!==============================================================================
3   !!                       ***  MODULE  trasbc  ***
4   !! Ocean active tracers:  surface boundary condition
5   !!==============================================================================
6   !! History :  OPA  !  1998-10  (G. Madec, G. Roullet, M. Imbard)  Original code
7   !!            8.2  !  2001-02  (D. Ludicone)  sea ice and free surface
8   !!  NEMO      1.0  !  2002-06  (G. Madec)  F90: Free form and module
9   !!            3.3  !  2010-04  (M. Leclair, G. Madec)  Forcing averaged over 2 time steps
10   !!             -   !  2010-09  (C. Ethe, G. Madec) Merge TRA-TRC
11   !!            3.6  !  2014-11  (P. Mathiot) isf melting forcing
12   !!----------------------------------------------------------------------
13
14   !!----------------------------------------------------------------------
15   !!   tra_sbc       : update the tracer trend at ocean surface
16   !!----------------------------------------------------------------------
17   USE oce            ! ocean dynamics and active tracers
18   USE sbc_oce        ! surface boundary condition: ocean
19   USE dom_oce        ! ocean space domain variables
20   USE phycst         ! physical constant
21   USE eosbn2         ! Equation Of State
22   USE sbcmod         ! ln_rnf 
23   USE sbcrnf         ! River runoff 
24   USE sbcisf         ! Ice shelf   
25   USE iscplini       ! Ice sheet coupling
26   USE traqsr         ! solar radiation penetration
27   USE trd_oce        ! trends: ocean variables
28   USE trdtra         ! trends manager: tracers
29   !
30   USE in_out_manager ! I/O manager
31   USE prtctl         ! Print control
32   USE iom            ! xIOS server
33   USE lbclnk         ! ocean lateral boundary conditions (or mpp link)
34   USE wrk_nemo       ! Memory Allocation
35   USE timing         ! Timing
36   !
37   USE wet_dry
38
39   IMPLICIT NONE
40   PRIVATE
41
42   PUBLIC   tra_sbc   ! routine called by step.F90
43
44   !! * Substitutions
45#  include "vectopt_loop_substitute.h90"
46   !!----------------------------------------------------------------------
47   !! NEMO/OPA 3.7 , NEMO Consortium (2014)
48   !! $Id: trasbc.F90 7788 2017-03-11 09:40:59Z cetlod $
49   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
50   !!----------------------------------------------------------------------
51CONTAINS
52
53   SUBROUTINE tra_sbc ( kt )
54      !!----------------------------------------------------------------------
55      !!                  ***  ROUTINE tra_sbc  ***
56      !!                   
57      !! ** Purpose :   Compute the tracer surface boundary condition trend of
58      !!      (flux through the interface, concentration/dilution effect)
59      !!      and add it to the general trend of tracer equations.
60      !!
61      !! ** Method :   The (air+ice)-sea flux has two components:
62      !!      (1) Fext, external forcing (i.e. flux through the (air+ice)-sea interface);
63      !!      (2) Fwe , tracer carried with the water that is exchanged with air+ice.
64      !!               The input forcing fields (emp, rnf, sfx, isf) contain Fext+Fwe,
65      !!             they are simply added to the tracer trend (tsa).
66      !!               In linear free surface case (ln_linssh=T), the volume of the
67      !!             ocean does not change with the water exchanges at the (air+ice)-sea
68      !!             interface. Therefore another term has to be added, to mimic the
69      !!             concentration/dilution effect associated with water exchanges.
70      !!
71      !! ** Action  : - Update tsa with the surface boundary condition trend
72      !!              - send trends to trdtra module for further diagnostics(l_trdtra=T)
73      !!----------------------------------------------------------------------
74      INTEGER, INTENT(in) ::   kt   ! ocean time-step index
75      !
76      INTEGER  ::   ji, jj, jk, jn        ! dummy loop indices 
77      INTEGER  ::   ikt, ikb              ! local integers
78      REAL(wp) ::   zfact, z1_e3t, zdep   ! local scalar
79      REAL(wp), POINTER, DIMENSION(:,:,:) ::  ztrdt, ztrds
80      !!----------------------------------------------------------------------
81      !
82      IF( nn_timing == 1 )  CALL timing_start('tra_sbc')
83      !
84      IF( kt == nit000 ) THEN
85         IF(lwp) WRITE(numout,*)
86         IF(lwp) WRITE(numout,*) 'tra_sbc : TRAcer Surface Boundary Condition'
87         IF(lwp) WRITE(numout,*) '~~~~~~~ '
88      ENDIF
89      !
90      IF( l_trdtra ) THEN                    !* Save ta and sa trends
91         CALL wrk_alloc( jpi, jpj, jpk, ztrdt, ztrds ) 
92         ztrdt(:,:,:) = tsa(:,:,:,jp_tem)
93         ztrds(:,:,:) = tsa(:,:,:,jp_sal)
94      ENDIF
95      !
96!!gm  This should be moved into sbcmod.F90 module ? (especially now that ln_traqsr is read in namsbc namelist)
97      IF( .NOT.ln_traqsr ) THEN     ! no solar radiation penetration
98         qns(:,:) = qns(:,:) + qsr(:,:)      ! total heat flux in qns
99         qsr(:,:) = 0._wp                     ! qsr set to zero
100      ENDIF
101
102      !----------------------------------------
103      !        EMP, SFX and QNS effects
104      !----------------------------------------
105      !                             !==  Set before sbc tracer content fields  ==!
106      IF( kt == nit000 ) THEN             !* 1st time-step
107         IF( ln_rstart .AND.    &               ! Restart: read in restart file
108              & iom_varid( numror, 'sbc_hc_b', ldstop = .FALSE. ) > 0 ) THEN
109            IF(lwp) WRITE(numout,*) '          nit000-1 sbc tracer content field read in the restart file'
110            zfact = 0.5_wp
111            sbc_tsc(:,:,:) = 0._wp
112            CALL iom_get( numror, jpdom_autoglo, 'sbc_hc_b', sbc_tsc_b(:,:,jp_tem) )   ! before heat content sbc trend
113            CALL iom_get( numror, jpdom_autoglo, 'sbc_sc_b', sbc_tsc_b(:,:,jp_sal) )   ! before salt content sbc trend
114         ELSE                                   ! No restart or restart not found: Euler forward time stepping
115            zfact = 1._wp
116            sbc_tsc(:,:,:) = 0._wp
117            sbc_tsc_b(:,:,:) = 0._wp
118         ENDIF
119      ELSE                                !* other time-steps: swap of forcing fields
120         zfact = 0.5_wp
121         sbc_tsc_b(:,:,:) = sbc_tsc(:,:,:)
122      ENDIF
123      !                             !==  Now sbc tracer content fields  ==!
124      DO jj = 2, jpj
125         DO ji = fs_2, fs_jpim1   ! vector opt.
126!CEOD Temproary measure to limit Surface fluxes in shallow water, needs
127!improvement
128            IF ( ln_rwd_rmp ) THEN
129               IF ( sshn(ji,jj) + ht_0(ji,jj) >  2._wp * rn_wdmin1 ) THEN
130                  sbc_tsc(ji,jj,jp_tem) = r1_rau0_rcp * qns(ji,jj)   ! non solar heat flux
131               ELSE IF ( sshn(ji,jj) + ht_0(ji,jj) >  rn_wdmin1 ) THEN
132                  sbc_tsc(ji,jj,jp_tem) = r1_rau0_rcp * qns(ji,jj) * (tanh(5._wp*( ( sshn(ji,jj) + ht_0(ji,jj) -  rn_wdmin1 )/rn_wdmin1)) )
133               ELSE
134                  sbc_tsc(ji,jj,jp_tem) = 0._wp
135               ENDIF
136            else
137               sbc_tsc(ji,jj,jp_tem) = r1_rau0_rcp * qns(ji,jj)   ! non solar heat flux
138            endif
139!CEODEND
140
141            sbc_tsc(ji,jj,jp_sal) = r1_rau0     * sfx(ji,jj)   ! salt flux due to freezing/melting
142         END DO
143      END DO
144      IF( ln_linssh ) THEN                !* linear free surface 
145         DO jj = 2, jpj                         !==>> add concentration/dilution effect due to constant volume cell
146            DO ji = fs_2, fs_jpim1   ! vector opt.
147               sbc_tsc(ji,jj,jp_tem) = sbc_tsc(ji,jj,jp_tem) + r1_rau0 * emp(ji,jj) * tsn(ji,jj,1,jp_tem)
148               sbc_tsc(ji,jj,jp_sal) = sbc_tsc(ji,jj,jp_sal) + r1_rau0 * emp(ji,jj) * tsn(ji,jj,1,jp_sal)
149            END DO
150         END DO                                 !==>> output c./d. term
151         IF( iom_use('emp_x_sst') )   CALL iom_put( "emp_x_sst", emp (:,:) * tsn(:,:,1,jp_tem) )
152         IF( iom_use('emp_x_sss') )   CALL iom_put( "emp_x_sss", emp (:,:) * tsn(:,:,1,jp_sal) )
153      ENDIF
154      !
155      DO jn = 1, jpts               !==  update tracer trend  ==!
156         DO jj = 2, jpj
157            DO ji = fs_2, fs_jpim1   ! vector opt. 
158               tsa(ji,jj,1,jn) = tsa(ji,jj,1,jn) + zfact * ( sbc_tsc_b(ji,jj,jn) + sbc_tsc(ji,jj,jn) ) / e3t_n(ji,jj,1)
159            END DO
160         END DO
161      END DO
162      !                 
163      IF( lrst_oce ) THEN           !==  write sbc_tsc in the ocean restart file  ==!
164         CALL iom_rstput( kt, nitrst, numrow, 'sbc_hc_b', sbc_tsc(:,:,jp_tem) )
165         CALL iom_rstput( kt, nitrst, numrow, 'sbc_sc_b', sbc_tsc(:,:,jp_sal) )
166      ENDIF
167      !
168      !----------------------------------------
169      !       Ice Shelf effects (ISF)
170      !     tbl treated as in Losh (2008) JGR
171      !----------------------------------------
172      !
173!!gm BUG ?   Why no differences between non-linear and linear free surface ?
174!!gm         probably taken into account in r1_hisf_tbl : to be verified
175      IF( ln_isf ) THEN
176         zfact = 0.5_wp
177         DO jj = 2, jpj
178            DO ji = fs_2, fs_jpim1
179               !
180               ikt = misfkt(ji,jj)
181               ikb = misfkb(ji,jj)
182               !
183               ! level fully include in the ice shelf boundary layer
184               ! sign - because fwf sign of evapo (rnf sign of precip)
185               DO jk = ikt, ikb - 1
186               ! compute trend
187                  tsa(ji,jj,jk,jp_tem) = tsa(ji,jj,jk,jp_tem)                                                &
188                     &           + zfact * ( risf_tsc_b(ji,jj,jp_tem) + risf_tsc(ji,jj,jp_tem) )             &
189                     &           * r1_hisf_tbl(ji,jj)
190               END DO
191   
192               ! level partially include in ice shelf boundary layer
193               ! compute trend
194               tsa(ji,jj,ikb,jp_tem) = tsa(ji,jj,ikb,jp_tem)                                                 &
195                  &              + zfact * ( risf_tsc_b(ji,jj,jp_tem) + risf_tsc(ji,jj,jp_tem) )             &
196                  &              * r1_hisf_tbl(ji,jj) * ralpha(ji,jj)
197
198            END DO
199         END DO
200      END IF
201      !
202      !----------------------------------------
203      !        River Runoff effects
204      !----------------------------------------
205      !
206      IF( ln_rnf ) THEN         ! input of heat and salt due to river runoff
207         zfact = 0.5_wp
208         DO jj = 2, jpj 
209            DO ji = fs_2, fs_jpim1
210               IF( rnf(ji,jj) /= 0._wp ) THEN
211                  zdep = zfact / h_rnf(ji,jj)
212                  DO jk = 1, nk_rnf(ji,jj)
213                                        tsa(ji,jj,jk,jp_tem) = tsa(ji,jj,jk,jp_tem)                                 &
214                                           &                 +  ( rnf_tsc_b(ji,jj,jp_tem) + rnf_tsc(ji,jj,jp_tem) ) * zdep
215                     IF( ln_rnf_sal )   tsa(ji,jj,jk,jp_sal) = tsa(ji,jj,jk,jp_sal)                                 &
216                                           &                 +  ( rnf_tsc_b(ji,jj,jp_sal) + rnf_tsc(ji,jj,jp_sal) ) * zdep 
217                  END DO
218               ENDIF
219            END DO 
220         END DO 
221      ENDIF
222
223      IF( iom_use('rnf_x_sst') )   CALL iom_put( "rnf_x_sst", rnf*tsn(:,:,1,jp_tem) )   ! runoff term on sst
224      IF( iom_use('rnf_x_sss') )   CALL iom_put( "rnf_x_sss", rnf*tsn(:,:,1,jp_sal) )   ! runoff term on sss
225
226      !
227      !----------------------------------------
228      !        Ice Sheet coupling imbalance correction to have conservation
229      !----------------------------------------
230      !
231      IF( ln_iscpl .AND. ln_hsb) THEN         ! input of heat and salt due to river runoff
232         DO jk = 1,jpk
233            DO jj = 2, jpj 
234               DO ji = fs_2, fs_jpim1
235                  zdep = 1._wp / e3t_n(ji,jj,jk) 
236                  tsa(ji,jj,jk,jp_tem) = tsa(ji,jj,jk,jp_tem) - htsc_iscpl(ji,jj,jk,jp_tem)                       &
237                      &                                         * zdep
238                  tsa(ji,jj,jk,jp_sal) = tsa(ji,jj,jk,jp_sal) - htsc_iscpl(ji,jj,jk,jp_sal)                       &
239                      &                                         * zdep 
240               END DO 
241            END DO 
242         END DO
243      ENDIF
244
245      IF( l_trdtra )   THEN                      ! save the horizontal diffusive trends for further diagnostics
246         ztrdt(:,:,:) = tsa(:,:,:,jp_tem) - ztrdt(:,:,:)
247         ztrds(:,:,:) = tsa(:,:,:,jp_sal) - ztrds(:,:,:)
248         CALL trd_tra( kt, 'TRA', jp_tem, jptra_nsr, ztrdt )
249         CALL trd_tra( kt, 'TRA', jp_sal, jptra_nsr, ztrds )
250         CALL wrk_dealloc( jpi, jpj, jpk, ztrdt, ztrds ) 
251      ENDIF
252      !
253      IF(ln_ctl)   CALL prt_ctl( tab3d_1=tsa(:,:,:,jp_tem), clinfo1=' sbc  - Ta: ', mask1=tmask,   &
254         &                       tab3d_2=tsa(:,:,:,jp_sal), clinfo2=       ' Sa: ', mask2=tmask, clinfo3='tra' )
255      !
256      IF( nn_timing == 1 )  CALL timing_stop('tra_sbc')
257      !
258   END SUBROUTINE tra_sbc
259
260   !!======================================================================
261END MODULE trasbc
Note: See TracBrowser for help on using the repository browser.