New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
cpl_oasis3.F90 in branches/UKMO/dev_3841_sbc/NEMOGCM/NEMO/OPA_SRC/SBC – NEMO

source: branches/UKMO/dev_3841_sbc/NEMOGCM/NEMO/OPA_SRC/SBC/cpl_oasis3.F90 @ 4827

Last change on this file since 4827 was 4827, checked in by charris, 9 years ago

Some demonstration code changes.
  • Property svn:keywords set to Id
File size: 16.9 KB
Line 
1MODULE cpl_oasis3
2   !!======================================================================
3   !!                    ***  MODULE cpl_oasis  ***
4   !! Coupled O/A : coupled ocean-atmosphere case using OASIS3 V. prism_2_4
5   !!               special case: NEMO OPA/LIM coupled to ECHAM5
6   !!=====================================================================
7   !! History :   
8   !!   9.0  !  04-06  (R. Redler, NEC Laboratories Europe, Germany) Original code
9   !!   " "  !  04-11  (R. Redler, NEC Laboratories Europe; N. Keenlyside, W. Park, IFM-GEOMAR, Germany) revision
10   !!   " "  !  04-11  (V. Gayler, MPI M&D) Grid writing
11   !!   " "  !  05-08  (R. Redler, W. Park) frld initialization, paral(2) revision
12   !!   " "  !  05-09  (R. Redler) extended to allow for communication over root only
13   !!   " "  !  06-01  (W. Park) modification of physical part
14   !!   " "  !  06-02  (R. Redler, W. Park) buffer array fix for root exchange
15   !!   3.4  !  11-11  (C. Harris) Changes to allow mutiple category fields
16   !!----------------------------------------------------------------------
17#if defined key_oasis3
18   !!----------------------------------------------------------------------
19   !!   'key_oasis3'                    coupled Ocean/Atmosphere via OASIS3
20   !!----------------------------------------------------------------------
21   !!   cpl_prism_init     : initialization of coupled mode communication
22   !!   cpl_prism_define   : definition of grid and fields
23   !!   cpl_prism_snd     : snd out fields in coupled mode
24   !!   cpl_prism_rcv     : receive fields in coupled mode
25   !!   cpl_prism_finalize : finalize the coupled mode communication
26   !!----------------------------------------------------------------------
27   USE mod_prism_proto              ! OASIS3 prism module
28   USE mod_prism_def_partition_proto! OASIS3 prism module for partitioning
29   USE mod_prism_put_proto          ! OASIS3 prism module for snding
30   USE mod_prism_get_proto          ! OASIS3 prism module for receiving
31   USE mod_comprism_proto           ! OASIS3 prism module to get coupling frequency
32   USE par_oce                      ! ocean parameters
33   USE dom_oce                      ! ocean space and time domain
34   USE in_out_manager               ! I/O manager
35   USE lbclnk                       ! ocean lateral boundary conditions (or mpp link)
36   USE fld_def
37
38   IMPLICIT NONE
39   PRIVATE
40
41   PUBLIC   cpl_prism_init
42   PUBLIC   cpl_prism_define
43   PUBLIC   cpl_prism_snd
44   PUBLIC   cpl_prism_rcv
45   PUBLIC   cpl_prism_freq
46   PUBLIC   cpl_prism_finalize
47
48   LOGICAL, PUBLIC, PARAMETER ::   lk_cpl = .TRUE.   !: coupled flag
49   INTEGER                    ::   ncomp_id          ! id returned by prism_init_comp
50   INTEGER                    ::   nerror            ! return error code
51
52   INTEGER, PARAMETER ::   nmaxfld=40    ! Maximum number of coupling fields
53   
54   TYPE, PUBLIC ::   FLD_CPL               !: Type for coupling field information
55      LOGICAL               ::   laction   ! To be coupled or not
56      CHARACTER(len = 8)    ::   clname    ! Name of the coupling field   
57      CHARACTER(len = 1)    ::   clgrid    ! Grid type 
58      REAL(wp)              ::   nsgn      ! Control of the sign change
59      INTEGER, DIMENSION(9) ::   nid       ! Id of the field (no more than 9 categories)
60      INTEGER               ::   nct       ! Number of categories in field
61   END TYPE FLD_CPL
62
63   TYPE(FLD_CPL), DIMENSION(nmaxfld), PUBLIC ::   ssnd   !: Coupling fields
64
65   REAL(wp), DIMENSION(:,:), ALLOCATABLE ::   exfld   ! Temporary buffer for receiving
66   INTEGER, PUBLIC :: localComm
67
68   !!----------------------------------------------------------------------
69   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
70   !! $Id$
71   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
72   !!----------------------------------------------------------------------
73CONTAINS
74
75   SUBROUTINE cpl_prism_init( kl_comm )
76      !!-------------------------------------------------------------------
77      !!             ***  ROUTINE cpl_prism_init  ***
78      !!
79      !! ** Purpose :   Initialize coupled mode communication for ocean
80      !!    exchange between AGCM, OGCM and COUPLER. (OASIS3 software)
81      !!
82      !! ** Method  :   OASIS3 MPI communication
83      !!--------------------------------------------------------------------
84      INTEGER, INTENT(out) ::   kl_comm   ! local communicator of the model
85      !!--------------------------------------------------------------------
86
87      ! WARNING: No write in numout in this routine
88      !============================================
89
90      !------------------------------------------------------------------
91      ! 1st Initialize the PRISM system for the application
92      !------------------------------------------------------------------
93      CALL prism_init_comp_proto ( ncomp_id, 'oceanx', nerror )
94      IF ( nerror /= PRISM_Ok ) &
95         CALL prism_abort_proto (ncomp_id, 'cpl_prism_init', 'Failure in prism_init_comp_proto')
96
97      !------------------------------------------------------------------
98      ! 3rd Get an MPI communicator for OPA local communication
99      !------------------------------------------------------------------
100
101      CALL prism_get_localcomm_proto ( kl_comm, nerror )
102      IF ( nerror /= PRISM_Ok ) &
103         CALL prism_abort_proto (ncomp_id, 'cpl_prism_init','Failure in prism_get_localcomm_proto' )
104      !
105   END SUBROUTINE cpl_prism_init
106
107
108   SUBROUTINE cpl_prism_define( krcv, ksnd, sd )
109      !!-------------------------------------------------------------------
110      !!             ***  ROUTINE cpl_prism_define  ***
111      !!
112      !! ** Purpose :   Define grid and field information for ocean
113      !!    exchange between AGCM, OGCM and COUPLER. (OASIS3 software)
114      !!
115      !! ** Method  :   OASIS3 MPI communication
116      !!--------------------------------------------------------------------
117      INTEGER, INTENT(in)                  ::   krcv, ksnd  ! Number of received and sent coupling fields
118      TYPE(FLD), INTENT(in), DIMENSION(:)  ::   sd          ! input field related variables
119      !
120      INTEGER :: id_part
121      INTEGER :: paral(5)       ! OASIS3 box partition
122      INTEGER :: ishape(2,2)    ! shape of arrays passed to PSMILe
123      INTEGER :: ji,jc          ! local loop indicees
124      CHARACTER(LEN=8) :: zclname
125      !!--------------------------------------------------------------------
126
127      IF(lwp) WRITE(numout,*)
128      IF(lwp) WRITE(numout,*) 'cpl_prism_define : initialization in coupled ocean/atmosphere case'
129      IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~~~~~~'
130      IF(lwp) WRITE(numout,*)
131
132      !
133      ! ... Define the shape for the area that excludes the halo
134      !     For serial configuration (key_mpp_mpi not being active)
135      !     nl* is set to the global values 1 and jp*glo.
136      !
137      ishape(:,1) = (/ 1, nlei-nldi+1 /)
138      ishape(:,2) = (/ 1, nlej-nldj+1 /)
139      !
140      ! ... Allocate memory for data exchange
141      !
142      ALLOCATE(exfld(nlei-nldi+1, nlej-nldj+1), stat = nerror)
143      IF( nerror > 0 ) THEN
144         CALL prism_abort_proto ( ncomp_id, 'cpl_prism_define', 'Failure in allocating exfld')   ;   RETURN
145      ENDIF
146      !
147      ! -----------------------------------------------------------------
148      ! ... Define the partition
149      ! -----------------------------------------------------------------
150     
151      paral(1) = 2                                              ! box partitioning
152      paral(2) = jpiglo * (nldj-1+njmpp-1) + (nldi-1+nimpp-1)   ! NEMO lower left corner global offset   
153      paral(3) = nlei-nldi+1                                    ! local extent in i
154      paral(4) = nlej-nldj+1                                    ! local extent in j
155      paral(5) = jpiglo                                         ! global extent in x
156     
157      IF( ln_ctl ) THEN
158         WRITE(numout,*) ' multiexchg: paral (1:5)', paral
159         WRITE(numout,*) ' multiexchg: jpi, jpj =', jpi, jpj
160         WRITE(numout,*) ' multiexchg: nldi, nlei, nimpp =', nldi, nlei, nimpp
161         WRITE(numout,*) ' multiexchg: nldj, nlej, njmpp =', nldj, nlej, njmpp
162      ENDIF
163     
164      CALL prism_def_partition_proto ( id_part, paral, nerror )
165      !
166      ! ... Announce send variables.
167      !
168      DO ji = 1, ksnd
169         IF ( ssnd(ji)%laction ) THEN
170            DO jc = 1, ssnd(ji)%nct
171               IF ( ssnd(ji)%nct .gt. 1 ) THEN
172                  WRITE(zclname,'( a7, i1)') ssnd(ji)%clname,jc
173               ELSE
174                  zclname=ssnd(ji)%clname
175               ENDIF
176               WRITE(numout,*) "Define",ji,jc,zclname," for",PRISM_Out
177               CALL prism_def_var_proto (ssnd(ji)%nid(jc), zclname, id_part, (/ 2, 0/),   &
178                    PRISM_Out, ishape, PRISM_REAL, nerror)
179               IF ( nerror /= PRISM_Ok ) THEN
180                  WRITE(numout,*) 'Failed to define transient ', ji, TRIM(zclname)
181                  CALL prism_abort_proto ( ssnd(ji)%nid(jc), 'cpl_prism_define', 'Failure in prism_def_var')
182               ENDIF
183            END DO
184         ENDIF
185      END DO
186      !
187      ! ... Announce received variables.
188      !
189      DO ji = 1, krcv
190         IF ( sd(ji)%loasis ) THEN
191            DO jc = 1, sd(ji)%nct
192               IF ( sd(ji)%nct .gt. 1 ) THEN
193                  WRITE(zclname,'( a7, i1)') sd(ji)%clvar,jc
194               ELSE
195                  zclname=sd(ji)%clvar
196               ENDIF
197               WRITE(numout,*) "Define",ji,jc,zclname," for",PRISM_In
198               CALL prism_def_var_proto ( sd(ji)%nid(jc), zclname, id_part, (/ 2, 0/),   &
199                    &                      PRISM_In    , ishape   , PRISM_REAL, nerror)
200               IF ( nerror /= PRISM_Ok ) THEN
201                  WRITE(numout,*) 'Failed to define transient ', ji, TRIM(zclname)
202                  CALL prism_abort_proto ( sd(ji)%nid(jc), 'cpl_prism_define', 'Failure in prism_def_var')
203               ENDIF
204            END DO
205         ENDIF
206      END DO
207     
208      !------------------------------------------------------------------
209      ! End of definition phase
210      !------------------------------------------------------------------
211     
212      CALL prism_enddef_proto(nerror)
213      IF( nerror /= PRISM_Ok )   CALL prism_abort_proto ( ncomp_id, 'cpl_prism_define', 'Failure in prism_enddef')
214      !
215   END SUBROUTINE cpl_prism_define
216   
217   
218   SUBROUTINE cpl_prism_snd( kid, kstep, pdata, kinfo )
219      !!---------------------------------------------------------------------
220      !!              ***  ROUTINE cpl_prism_snd  ***
221      !!
222      !! ** Purpose : - At each coupling time-step,this routine sends fields
223      !!      like sst or ice cover to the coupler or remote application.
224      !!----------------------------------------------------------------------
225      INTEGER                   , INTENT(in   ) ::   kid       ! variable index in the array
226      INTEGER                   , INTENT(  out) ::   kinfo     ! OASIS3 info argument
227      INTEGER                   , INTENT(in   ) ::   kstep     ! ocean time-step in seconds
228      REAL(wp), DIMENSION(:,:,:), INTENT(in   ) ::   pdata
229      !!
230      INTEGER                                   ::   jc        ! local loop index
231      !!--------------------------------------------------------------------
232      !
233      ! snd data to OASIS3
234      !
235      DO jc = 1, ssnd(kid)%nct
236
237         CALL prism_put_proto ( ssnd(kid)%nid(jc), kstep, pdata(nldi:nlei, nldj:nlej,jc), kinfo )
238         
239         IF ( ln_ctl ) THEN       
240            IF ( kinfo == PRISM_Sent     .OR. kinfo == PRISM_ToRest .OR.   &
241                 & kinfo == PRISM_SentOut  .OR. kinfo == PRISM_ToRestOut ) THEN
242               WRITE(numout,*) '****************'
243               WRITE(numout,*) 'prism_put_proto: Outgoing ', ssnd(kid)%clname
244               WRITE(numout,*) 'prism_put_proto: ivarid ', ssnd(kid)%nid(jc)
245               WRITE(numout,*) 'prism_put_proto:  kstep ', kstep
246               WRITE(numout,*) 'prism_put_proto:   info ', kinfo
247               WRITE(numout,*) '     - Minimum value is ', MINVAL(pdata(:,:,jc))
248               WRITE(numout,*) '     - Maximum value is ', MAXVAL(pdata(:,:,jc))
249               WRITE(numout,*) '     -     Sum value is ', SUM(pdata(:,:,jc))
250               WRITE(numout,*) '****************'
251            ENDIF
252         ENDIF
253
254      ENDDO
255      !
256    END SUBROUTINE cpl_prism_snd
257
258
259   SUBROUTINE cpl_prism_rcv( kstep, sd )
260      !!---------------------------------------------------------------------
261      !!              ***  ROUTINE cpl_prism_rcv  ***
262      !!
263      !! ** Purpose : - At each coupling time-step,this routine receives fields
264      !!      like stresses and fluxes from the coupler or remote application.
265      !!----------------------------------------------------------------------
266      INTEGER                   , INTENT(in   ) ::   kstep     ! ocean time-step in seconds
267      TYPE(FLD), INTENT(inout)                  ::   sd        ! input field related variables
268      !!
269      INTEGER                                   ::   jc        ! local loop index
270      LOGICAL                                   ::   llaction
271      !!--------------------------------------------------------------------
272      !
273      ! receive local data from OASIS3 on every process
274      !
275      DO jc = 1, sd%nct
276
277         CALL prism_get_proto ( sd%nid(jc), kstep, exfld, sd%ninfo )         
278         
279         llaction = .false.
280         IF( sd%ninfo == PRISM_Recvd   .OR. sd%ninfo == PRISM_FromRest .OR.   &
281              sd%ninfo == PRISM_RecvOut .OR. sd%ninfo == PRISM_FromRestOut )   llaction = .TRUE.
282         
283         IF ( ln_ctl )   WRITE(numout,*) "llaction, info, kstep, ivarid: " , llaction, sd%ninfo, kstep, sd%nid(jc)
284         
285         IF ( llaction ) THEN
286           
287            sd%ninfo = OASIS_Rcv
288            sd%fnow(nldi:nlei, nldj:nlej,jc) = exfld(:,:)
289           
290            !--- Fill the overlap areas and extra hallows (mpp)
291            !--- check periodicity conditions (all cases)
292            CALL lbc_lnk( sd%fnow(:,:,jc), sd%clvgrd, sd%nsgn )   
293           
294            IF ( ln_ctl ) THEN       
295               WRITE(numout,*) '****************'
296               WRITE(numout,*) 'prism_get_proto: Incoming ', sd%clvar
297               WRITE(numout,*) 'prism_get_proto: ivarid '  , sd%nid(jc)
298               WRITE(numout,*) 'prism_get_proto:   kstep', kstep
299               WRITE(numout,*) 'prism_get_proto:   info ', sd%ninfo
300               WRITE(numout,*) '     - Minimum value is ', MINVAL(sd%fnow(:,:,jc))
301               WRITE(numout,*) '     - Maximum value is ', MAXVAL(sd%fnow(:,:,jc))
302               WRITE(numout,*) '     -     Sum value is ', SUM(sd%fnow(:,:,jc))
303               WRITE(numout,*) '****************'
304            ENDIF
305           
306         ELSE
307            sd%ninfo = OASIS_idle     
308         ENDIF
309         
310      ENDDO
311      !
312   END SUBROUTINE cpl_prism_rcv
313
314
315   INTEGER FUNCTION cpl_prism_freq( kid ) 
316      !!---------------------------------------------------------------------
317      !!              ***  ROUTINE cpl_prism_freq  ***
318      !!
319      !! ** Purpose : - send back the coupling frequency for a particular field
320      !!----------------------------------------------------------------------
321      INTEGER,INTENT(in) ::   kid   ! variable index
322      !!----------------------------------------------------------------------
323      cpl_prism_freq = ig_def_freq( kid )
324      !
325   END FUNCTION cpl_prism_freq
326
327
328   SUBROUTINE cpl_prism_finalize
329      !!---------------------------------------------------------------------
330      !!              ***  ROUTINE cpl_prism_finalize  ***
331      !!
332      !! ** Purpose : - Finalizes the coupling. If MPI_init has not been
333      !!      called explicitly before cpl_prism_init it will also close
334      !!      MPI communication.
335      !!----------------------------------------------------------------------
336      !
337      DEALLOCATE( exfld )
338      CALL prism_terminate_proto( nerror )         
339      !
340   END SUBROUTINE cpl_prism_finalize
341
342#else
343   !!----------------------------------------------------------------------
344   !!   Default case          Dummy module          Forced Ocean/Atmosphere
345   !!----------------------------------------------------------------------
346   USE in_out_manager               ! I/O manager
347   USE fld_def
348   LOGICAL, PUBLIC, PARAMETER :: lk_cpl = .FALSE.   !: coupled flag
349   PUBLIC cpl_prism_init
350   PUBLIC cpl_prism_rcv
351   PUBLIC cpl_prism_finalize
352CONTAINS
353   SUBROUTINE cpl_prism_init (kl_comm) 
354      INTEGER, INTENT(out)   :: kl_comm       ! local communicator of the model
355      kl_comm = -1
356      WRITE(numout,*) 'cpl_prism_init: Error you sould not be there...'
357   END SUBROUTINE cpl_prism_init
358   SUBROUTINE cpl_prism_rcv ( kstep, sd )
359      INTEGER, INTENT(in   )   ::   kstep     ! ocean time-step in seconds
360      TYPE(FLD), INTENT(inout) ::   sd        ! input field related variables
361      WRITE(numout,*) 'cpl_prism_rcv: Error you sould not be there...'
362   END SUBROUTINE cpl_prism_rcv
363   SUBROUTINE cpl_prism_finalize
364      WRITE(numout,*) 'cpl_prism_finalize: Error you sould not be there...'
365   END SUBROUTINE cpl_prism_finalize
366#endif
367
368   !!=====================================================================
369END MODULE cpl_oasis3
Note: See TracBrowser for help on using the repository browser.