| 1 | MODULE ldfslp_crs |
|---|
| 2 | !!====================================================================== |
|---|
| 3 | !! *** MODULE ldfslp *** |
|---|
| 4 | !! Ocean physics: slopes of neutral surfaces |
|---|
| 5 | !!====================================================================== |
|---|
| 6 | !! History : OPA ! 1994-12 (G. Madec, M. Imbard) Original code |
|---|
| 7 | !! 8.0 ! 1997-06 (G. Madec) optimization, lbc |
|---|
| 8 | !! 8.1 ! 1999-10 (A. Jouzeau) NEW profile in the mixed layer |
|---|
| 9 | !! NEMO 1.0 ! 2002-10 (G. Madec) Free form, F90 |
|---|
| 10 | !! - ! 2005-10 (A. Beckmann) correction for s-coordinates |
|---|
| 11 | !! 3.3 ! 2010-10 (G. Nurser, C. Harris, G. Madec) add Griffies operator |
|---|
| 12 | !! - ! 2010-11 (F. Dupond, G. Madec) bug correction in slopes just below the ML |
|---|
| 13 | !!---------------------------------------------------------------------- |
|---|
| 14 | #if defined key_ldfslp || defined key_esopa |
|---|
| 15 | !!---------------------------------------------------------------------- |
|---|
| 16 | !! 'key_ldfslp' Rotation of lateral mixing tensor |
|---|
| 17 | !!---------------------------------------------------------------------- |
|---|
| 18 | !! ldf_slp_grif : calculates the triads of isoneutral slopes (Griffies operator) |
|---|
| 19 | !! ldf_slp : calculates the slopes of neutral surface (Madec operator) |
|---|
| 20 | !! ldf_slp_mxl : calculates the slopes at the base of the mixed layer (Madec operator) |
|---|
| 21 | !! ldf_slp_init : initialization of the slopes computation |
|---|
| 22 | !!---------------------------------------------------------------------- |
|---|
| 23 | !USE oce ! ocean dynamics and tracers |
|---|
| 24 | !USE dom_oce ! ocean space and time domain |
|---|
| 25 | USE ldftra_oce ! lateral diffusion: traceur |
|---|
| 26 | USE ldfdyn_oce ! lateral diffusion: dynamics |
|---|
| 27 | USE phycst ! physical constants |
|---|
| 28 | USE eosbn2_crs ! equation of states |
|---|
| 29 | USE crslbclnk ! ocean lateral boundary conditions (or mpp link) |
|---|
| 30 | USE in_out_manager ! I/O manager |
|---|
| 31 | USE prtctl ! Print control |
|---|
| 32 | USE wrk_nemo ! work arrays |
|---|
| 33 | USE timing ! Timing |
|---|
| 34 | USE crs |
|---|
| 35 | USE iom |
|---|
| 36 | USE ieee_arithmetic |
|---|
| 37 | |
|---|
| 38 | IMPLICIT NONE |
|---|
| 39 | PRIVATE |
|---|
| 40 | |
|---|
| 41 | PUBLIC ldf_slp_crs ! routine called by step.F90 |
|---|
| 42 | PUBLIC ldf_slp_grif_crs ! routine called by step.F90 |
|---|
| 43 | PUBLIC ldf_slp_init_crs ! routine called by opa.F90 |
|---|
| 44 | |
|---|
| 45 | ! LOGICAL , PUBLIC, PARAMETER :: lk_ldfslp_crs = .TRUE. !: slopes flag |
|---|
| 46 | ! !! Madec operator |
|---|
| 47 | ! Arrays allocated in ldf_slp_init() routine once we know whether we're using the Griffies or Madec operator |
|---|
| 48 | ! !! Griffies operator |
|---|
| 49 | REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: wslp2 !: wslp**2 from Griffies quarter cells |
|---|
| 50 | REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:,:,:) :: triadi_g, triadj_g !: skew flux slopes relative to geopotentials |
|---|
| 51 | REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:,:,:) :: triadi , triadj !: isoneutral slopes relative to model-coordinate |
|---|
| 52 | |
|---|
| 53 | ! !! Madec operator |
|---|
| 54 | ! Arrays allocated in ldf_slp_init() routine once we know whether we're using the Griffies or Madec operator |
|---|
| 55 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: omlmask ! mask of the surface mixed layer at T-pt |
|---|
| 56 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) :: uslpml, wslpiml ! i_slope at U- and W-points just below the mixed layer |
|---|
| 57 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) :: vslpml, wslpjml ! j_slope at V- and W-points just below the mixed layer |
|---|
| 58 | |
|---|
| 59 | REAL(wp) :: repsln = 1.e-25_wp ! tiny value used as minium of di(rho), dj(rho) and dk(rho) |
|---|
| 60 | |
|---|
| 61 | !! * Substitutions |
|---|
| 62 | # include "domzgr_substitute.h90" |
|---|
| 63 | # include "ldftra_substitute.h90" |
|---|
| 64 | # include "ldfeiv_substitute.h90" |
|---|
| 65 | # include "vectopt_loop_substitute.h90" |
|---|
| 66 | !!---------------------------------------------------------------------- |
|---|
| 67 | !! NEMO/OPA 4.0 , NEMO Consortium (2011) |
|---|
| 68 | !! $Id$ |
|---|
| 69 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
|---|
| 70 | !!---------------------------------------------------------------------- |
|---|
| 71 | CONTAINS |
|---|
| 72 | |
|---|
| 73 | SUBROUTINE ldf_slp_crs( kt, prd, pn2 ) |
|---|
| 74 | !!---------------------------------------------------------------------- |
|---|
| 75 | !! *** ROUTINE ldf_slp *** |
|---|
| 76 | !! |
|---|
| 77 | !! ** Purpose : Compute the slopes of neutral surface (slope of isopycnal |
|---|
| 78 | !! surfaces referenced locally) (ln_traldf_iso=T). |
|---|
| 79 | !! |
|---|
| 80 | !! ** Method : The slope in the i-direction is computed at U- and |
|---|
| 81 | !! W-points (uslp, wslpi) and the slope in the j-direction is |
|---|
| 82 | !! computed at V- and W-points (vslp, wslpj). |
|---|
| 83 | !! They are bounded by 1/100 over the whole ocean, and within the |
|---|
| 84 | !! surface layer they are bounded by the distance to the surface |
|---|
| 85 | !! ( slope<= depth/l where l is the length scale of horizontal |
|---|
| 86 | !! diffusion (here, aht=2000m2/s ==> l=20km with a typical velocity |
|---|
| 87 | !! of 10cm/s) |
|---|
| 88 | !! A horizontal shapiro filter is applied to the slopes |
|---|
| 89 | !! ln_sco=T, s-coordinate, add to the previously computed slopes |
|---|
| 90 | !! the slope of the model level surface. |
|---|
| 91 | !! macro-tasked on horizontal slab (jk-loop) (2, jpk-1) |
|---|
| 92 | !! [slopes already set to zero at level 1, and to zero or the ocean |
|---|
| 93 | !! bottom slope (ln_sco=T) at level jpk in inildf] |
|---|
| 94 | !! |
|---|
| 95 | !! ** Action : - uslp, wslpi, and vslp, wslpj, the i- and j-slopes |
|---|
| 96 | !! of now neutral surfaces at u-, w- and v- w-points, resp. |
|---|
| 97 | !!---------------------------------------------------------------------- |
|---|
| 98 | INTEGER , INTENT(in) :: kt ! ocean time-step index |
|---|
| 99 | REAL(wp), INTENT(in), DIMENSION(:,:,:) :: prd ! in situ density |
|---|
| 100 | REAL(wp), INTENT(in), DIMENSION(:,:,:) :: pn2 ! Brunt-Vaisala frequency (locally ref.) |
|---|
| 101 | !! |
|---|
| 102 | INTEGER :: ji , jj , jk ! dummy loop indices |
|---|
| 103 | INTEGER :: ii0, ii1, iku ! temporary integer |
|---|
| 104 | INTEGER :: ij0, ij1, ikv ! temporary integer |
|---|
| 105 | REAL(wp) :: zeps, zm1_g, zm1_2g, z1_16, zcofw ! local scalars |
|---|
| 106 | REAL(wp) :: zci, zfi, zau, zbu, zai, zbi ! - - |
|---|
| 107 | REAL(wp) :: zcj, zfj, zav, zbv, zaj, zbj ! - - |
|---|
| 108 | REAL(wp) :: zck, zfk, zbw ! - - |
|---|
| 109 | REAL(wp), POINTER, DIMENSION(:,:,:) :: zwz, zww |
|---|
| 110 | REAL(wp), POINTER, DIMENSION(:,:,:) :: zdzr |
|---|
| 111 | REAL(wp), POINTER, DIMENSION(:,:,:) :: zgru, zgrv |
|---|
| 112 | !!---------------------------------------------------------------------- |
|---|
| 113 | ! |
|---|
| 114 | IF( nn_timing == 1 ) CALL timing_start('ldf_slp_crs') |
|---|
| 115 | ! |
|---|
| 116 | CALL wrk_alloc( jpi_crs,jpj_crs,jpk, zwz, zww, zdzr, zgru, zgrv ) |
|---|
| 117 | |
|---|
| 118 | zeps = 1.e-20_wp !== Local constant initialization ==! |
|---|
| 119 | z1_16 = 1.0_wp / 16._wp |
|---|
| 120 | zm1_g = -1.0_wp / grav |
|---|
| 121 | zm1_2g = -0.5_wp / grav |
|---|
| 122 | ! |
|---|
| 123 | zww(:,:,:) = 0._wp |
|---|
| 124 | zwz(:,:,:) = 0._wp |
|---|
| 125 | ! |
|---|
| 126 | DO jk = 1, jpk !== i- & j-gradient of density ==! |
|---|
| 127 | DO jj = 1, jpj_crsm1 |
|---|
| 128 | DO ji = 1, jpi_crsm1 ! vector opt. |
|---|
| 129 | zgru(ji,jj,jk) = umask_crs(ji,jj,jk) * ( prd(ji+1,jj ,jk) - prd(ji,jj,jk) ) |
|---|
| 130 | zgrv(ji,jj,jk) = vmask_crs(ji,jj,jk) * ( prd(ji ,jj+1,jk) - prd(ji,jj,jk) ) |
|---|
| 131 | END DO |
|---|
| 132 | END DO |
|---|
| 133 | END DO |
|---|
| 134 | IF( ln_zps ) THEN ! partial steps correction at the bottom ocean level |
|---|
| 135 | DO jj = 1, jpj_crsm1 |
|---|
| 136 | DO ji = 1, jpi_crsm1 |
|---|
| 137 | zgru(ji,jj,mbku_crs(ji,jj)) = gru_crs(ji,jj) |
|---|
| 138 | zgrv(ji,jj,mbkv_crs(ji,jj)) = grv_crs(ji,jj) |
|---|
| 139 | END DO |
|---|
| 140 | END DO |
|---|
| 141 | ENDIF |
|---|
| 142 | ! |
|---|
| 143 | zdzr(:,:,1) = 0._wp !== Local vertical density gradient at T-point == ! (evaluated from N^2) |
|---|
| 144 | DO jk = 2, jpkm1 |
|---|
| 145 | ! ! trick: tmask(ik ) = 0 => all pn2 = 0 => zdzr = 0 |
|---|
| 146 | ! ! else tmask(ik+1) = 0 => pn2(ik+1) = 0 => zdzr divides by 1 |
|---|
| 147 | ! ! zdzr = d/dz(prd)= - ( prd ) / grav * mk(pn2) -- at t point |
|---|
| 148 | ! ! umask(ik+1) /= 0 => all pn2 /= 0 => zdzr divides by 2 |
|---|
| 149 | ! ! NB: 1/(tmask+1) = (1-.5*tmask) substitute a / by a * ==> faster |
|---|
| 150 | zdzr(:,:,jk) = zm1_g * ( prd(:,:,jk) + 1._wp ) & |
|---|
| 151 | & * ( pn2(:,:,jk) + pn2(:,:,jk+1) ) * ( 1._wp - 0.5_wp * tmask_crs(:,:,jk+1) ) |
|---|
| 152 | END DO |
|---|
| 153 | ! |
|---|
| 154 | ! !== Slopes just below the mixed layer ==! |
|---|
| 155 | CALL ldf_slp_mxl_crs( prd, pn2, zgru, zgrv, zdzr ) ! output: uslpml, vslpml, wslpiml, wslpjml |
|---|
| 156 | |
|---|
| 157 | ! I. slopes at u and v point | uslp = d/di( prd ) / d/dz( prd ) |
|---|
| 158 | ! =========================== | vslp = d/dj( prd ) / d/dz( prd ) |
|---|
| 159 | ! |
|---|
| 160 | DO jk = 2, jpkm1 !* Slopes at u and v points |
|---|
| 161 | DO jj = 2, jpj_crsm1 |
|---|
| 162 | DO ji = 2, jpi_crsm1 ! vector opt. |
|---|
| 163 | ! ! horizontal and vertical density gradient at u- and v-points |
|---|
| 164 | zau = zgru(ji,jj,jk) / e1u_crs(ji,jj) |
|---|
| 165 | zav = zgrv(ji,jj,jk) / e2v_crs(ji,jj) |
|---|
| 166 | zbu = 0.5_wp * ( zdzr(ji,jj,jk) + zdzr(ji+1,jj ,jk) ) |
|---|
| 167 | zbv = 0.5_wp * ( zdzr(ji,jj,jk) + zdzr(ji ,jj+1,jk) ) |
|---|
| 168 | ! ! bound the slopes: abs(zw.)<= 1/100 and zb..<0 |
|---|
| 169 | ! ! + kxz max= ah slope max =< e1 e3 /(pi**2 2 dt) |
|---|
| 170 | zbu = MIN( zbu, -100._wp* ABS( zau ) , -7.e+3_wp/fse3u_max_crs(ji,jj,jk)* ABS( zau ) ) |
|---|
| 171 | zbv = MIN( zbv, -100._wp* ABS( zav ) , -7.e+3_wp/fse3v_max_crs(ji,jj,jk)* ABS( zav ) ) |
|---|
| 172 | ! ! uslp and vslp output in zwz and zww, resp. |
|---|
| 173 | zfi = MAX( omlmask(ji,jj,jk), omlmask(ji+1,jj,jk) ) |
|---|
| 174 | zfj = MAX( omlmask(ji,jj,jk), omlmask(ji,jj+1,jk) ) |
|---|
| 175 | zwz(ji,jj,jk) = ( ( 1. - zfi) * zau / ( zbu - zeps ) & |
|---|
| 176 | & + zfi * uslpml(ji,jj) & |
|---|
| 177 | & * 0.5_wp * ( fsdept_crs(ji+1,jj,jk)+fsdept_crs(ji,jj,jk) - fse3u_max_crs(ji,jj,1) ) & |
|---|
| 178 | & / MAX( hmlpt_crs(ji,jj), hmlpt_crs(ji+1,jj), 5._wp ) ) * umask_crs(ji,jj,jk) |
|---|
| 179 | zww(ji,jj,jk) = ( ( 1. - zfj) * zav / ( zbv - zeps ) & |
|---|
| 180 | & + zfj * vslpml(ji,jj) & |
|---|
| 181 | & * 0.5_wp * ( fsdept_crs(ji,jj+1,jk)+ fsdept_crs(ji,jj,jk)-fse3v_max_crs(ji,jj,1) ) & |
|---|
| 182 | & / MAX( hmlpt_crs(ji,jj), hmlpt_crs(ji,jj+1), 5. ) ) * vmask_crs(ji,jj,jk) |
|---|
| 183 | !!gm modif to suppress omlmask.... (as in Griffies case) |
|---|
| 184 | ! ! ! jk must be >= ML level for zf=1. otherwise zf=0. |
|---|
| 185 | ! zfi = REAL( 1 - 1/(1 + jk / MAX( nmln(ji+1,jj), nmln(ji,jj) ) ), wp ) |
|---|
| 186 | ! zfj = REAL( 1 - 1/(1 + jk / MAX( nmln(ji,jj+1), nmln(ji,jj) ) ), wp ) |
|---|
| 187 | ! zci = 0.5 * ( fsdept(ji+1,jj,jk)+fsdept(ji,jj,jk) ) / MAX( hmlpt(ji,jj), hmlpt(ji+1,jj), 10. ) ) |
|---|
| 188 | ! zcj = 0.5 * ( fsdept(ji,jj+1,jk)+fsdept(ji,jj,jk) ) / MAX( hmlpt(ji,jj), hmlpt(ji,jj+1), 10. ) ) |
|---|
| 189 | ! zwz(ji,jj,jk) = ( zfi * zai / ( zbi - zeps ) + ( 1._wp - zfi ) * wslpiml(ji,jj) * zci ) * tmask(ji,jj,jk) |
|---|
| 190 | ! zww(ji,jj,jk) = ( zfj * zaj / ( zbj - zeps ) + ( 1._wp - zfj ) * wslpjml(ji,jj) * zcj ) * tmask(ji,jj,jk) |
|---|
| 191 | !!gm end modif |
|---|
| 192 | END DO |
|---|
| 193 | END DO |
|---|
| 194 | END DO |
|---|
| 195 | CALL crs_lbc_lnk( zwz, 'U', -1. ) ; CALL crs_lbc_lnk( zww, 'V', -1. ) ! lateral boundary conditions |
|---|
| 196 | ! |
|---|
| 197 | ! !* horizontal Shapiro filter |
|---|
| 198 | DO jk = 2, jpkm1 |
|---|
| 199 | DO jj = 2, jpj_crsm1, MAX(1, jpj_crs-3) ! rows jj=2 and =jpjm1 only |
|---|
| 200 | DO ji = 2, jpi_crsm1 |
|---|
| 201 | uslp_crs(ji,jj,jk) = z1_16 * ( zwz(ji-1,jj-1,jk) + zwz(ji+1,jj-1,jk) & |
|---|
| 202 | & + zwz(ji-1,jj+1,jk) + zwz(ji+1,jj+1,jk) & |
|---|
| 203 | & + 2.*( zwz(ji ,jj-1,jk) + zwz(ji-1,jj ,jk) & |
|---|
| 204 | & + zwz(ji+1,jj ,jk) + zwz(ji ,jj+1,jk) ) & |
|---|
| 205 | & + 4.* zwz(ji ,jj ,jk) ) |
|---|
| 206 | vslp_crs(ji,jj,jk) = z1_16 * ( zww(ji-1,jj-1,jk) + zww(ji+1,jj-1,jk) & |
|---|
| 207 | & + zww(ji-1,jj+1,jk) + zww(ji+1,jj+1,jk) & |
|---|
| 208 | & + 2.*( zww(ji ,jj-1,jk) + zww(ji-1,jj ,jk) & |
|---|
| 209 | & + zww(ji+1,jj ,jk) + zww(ji ,jj+1,jk) ) & |
|---|
| 210 | & + 4.* zww(ji,jj ,jk) ) |
|---|
| 211 | END DO |
|---|
| 212 | END DO |
|---|
| 213 | DO jj = 3, jpj_crs-2 ! other rows |
|---|
| 214 | DO ji = 2, jpi_crsm1 ! vector opt. |
|---|
| 215 | uslp_crs(ji,jj,jk) = z1_16 * ( zwz(ji-1,jj-1,jk) + zwz(ji+1,jj-1,jk) & |
|---|
| 216 | & + zwz(ji-1,jj+1,jk) + zwz(ji+1,jj+1,jk) & |
|---|
| 217 | & + 2.*( zwz(ji ,jj-1,jk) + zwz(ji-1,jj ,jk) & |
|---|
| 218 | & + zwz(ji+1,jj ,jk) + zwz(ji ,jj+1,jk) ) & |
|---|
| 219 | & + 4.* zwz(ji ,jj ,jk) ) |
|---|
| 220 | vslp_crs(ji,jj,jk) = z1_16 * ( zww(ji-1,jj-1,jk) + zww(ji+1,jj-1,jk) & |
|---|
| 221 | & + zww(ji-1,jj+1,jk) + zww(ji+1,jj+1,jk) & |
|---|
| 222 | & + 2.*( zww(ji ,jj-1,jk) + zww(ji-1,jj ,jk) & |
|---|
| 223 | & + zww(ji+1,jj ,jk) + zww(ji ,jj+1,jk) ) & |
|---|
| 224 | & + 4.* zww(ji,jj ,jk) ) |
|---|
| 225 | END DO |
|---|
| 226 | END DO |
|---|
| 227 | ! !* decrease along coastal boundaries |
|---|
| 228 | DO jj = 2, jpj_crsm1 |
|---|
| 229 | DO ji = 2, jpi_crsm1 ! vector opt. |
|---|
| 230 | uslp_crs(ji,jj,jk) = uslp_crs(ji,jj,jk) * ( umask_crs(ji,jj+1,jk) + umask_crs(ji,jj-1,jk ) ) * 0.5_wp & |
|---|
| 231 | & * ( umask_crs(ji,jj ,jk) + umask_crs(ji,jj ,jk+1) ) * 0.5_wp |
|---|
| 232 | vslp_crs(ji,jj,jk) = vslp_crs(ji,jj,jk) * ( vmask_crs(ji+1,jj,jk) + vmask_crs(ji-1,jj,jk ) ) * 0.5_wp & |
|---|
| 233 | & * ( vmask_crs(ji ,jj,jk) + vmask_crs(ji ,jj,jk+1) ) * 0.5_wp |
|---|
| 234 | END DO |
|---|
| 235 | END DO |
|---|
| 236 | END DO |
|---|
| 237 | |
|---|
| 238 | |
|---|
| 239 | ! II. slopes at w point | wslpi = mij( d/di( prd ) / d/dz( prd ) |
|---|
| 240 | ! =========================== | wslpj = mij( d/dj( prd ) / d/dz( prd ) |
|---|
| 241 | ! |
|---|
| 242 | DO jk = 2, jpkm1 |
|---|
| 243 | DO jj = 2, jpj_crsm1 |
|---|
| 244 | DO ji = 2, jpi_crsm1 ! vector opt. |
|---|
| 245 | ! !* Local vertical density gradient evaluated from N^2 |
|---|
| 246 | zbw = zm1_2g * pn2 (ji,jj,jk) * ( prd (ji,jj,jk) + prd (ji,jj,jk-1) + 2. ) |
|---|
| 247 | ! !* Slopes at w point |
|---|
| 248 | ! ! i- & j-gradient of density at w-points |
|---|
| 249 | zci = MAX( umask_crs(ji-1,jj,jk ) + umask_crs(ji,jj,jk ) & |
|---|
| 250 | & + umask_crs(ji-1,jj,jk-1) + umask_crs(ji,jj,jk-1) , zeps ) * e1t_crs(ji,jj) |
|---|
| 251 | zcj = MAX( vmask_crs(ji,jj-1,jk ) + vmask_crs(ji,jj,jk-1) & |
|---|
| 252 | & + vmask_crs(ji,jj-1,jk-1) + vmask_crs(ji,jj,jk ) , zeps ) * e2t_crs(ji,jj) |
|---|
| 253 | zai = ( zgru (ji-1,jj,jk ) + zgru (ji,jj,jk-1) & |
|---|
| 254 | & + zgru (ji-1,jj,jk-1) + zgru (ji,jj,jk ) ) / zci * tmask_crs (ji,jj,jk) |
|---|
| 255 | zaj = ( zgrv (ji,jj-1,jk ) + zgrv (ji,jj,jk-1) & |
|---|
| 256 | & + zgrv (ji,jj-1,jk-1) + zgrv (ji,jj,jk ) ) / zcj * tmask_crs (ji,jj,jk) |
|---|
| 257 | |
|---|
| 258 | ! ! bound the slopes: abs(zw.)<= 1/100 and zb..<0. |
|---|
| 259 | ! ! + kxz max= ah slope max =< e1 e3 /(pi**2 2 dt) |
|---|
| 260 | zbi = MIN( zbw ,- 100._wp* ABS( zai ) , -7.e+3_wp/fse3w_max_crs(ji,jj,jk)* ABS( zai ) ) |
|---|
| 261 | zbj = MIN( zbw , -100._wp* ABS( zaj ) , -7.e+3_wp/fse3w_max_crs(ji,jj,jk)* ABS( zaj ) ) |
|---|
| 262 | ! ! wslpi and wslpj with ML flattening (output in zwz and zww, resp.) |
|---|
| 263 | zfk = MAX( omlmask(ji,jj,jk), omlmask(ji,jj,jk-1) ) ! zfk=1 in the ML otherwise zfk=0 |
|---|
| 264 | zck = fsdepw_crs(ji,jj,jk) / MAX( hmlp_crs(ji,jj), 10._wp ) |
|---|
| 265 | zwz(ji,jj,jk) = ( zai / ( zbi - zeps ) * ( 1._wp - zfk ) + zck * wslpiml(ji,jj) * zfk ) * tmask_crs(ji,jj,jk) |
|---|
| 266 | zww(ji,jj,jk) = ( zaj / ( zbj - zeps ) * ( 1._wp - zfk ) + zck * wslpjml(ji,jj) * zfk ) * tmask_crs(ji,jj,jk) |
|---|
| 267 | !!gm modif to suppress omlmask.... (as in Griffies operator) |
|---|
| 268 | ! ! ! jk must be >= ML level for zfk=1. otherwise zfk=0. |
|---|
| 269 | ! zfk = REAL( 1 - 1/(1 + jk / nmln(ji+1,jj)), wp ) |
|---|
| 270 | ! zck = fsdepw(ji,jj,jk) / MAX( hmlp(ji,jj), 10. ) |
|---|
| 271 | ! zwz(ji,jj,jk) = ( zfk * zai / ( zbi - zeps ) + ( 1._wp - zfk ) * wslpiml(ji,jj) * zck ) * tmask(ji,jj,jk) |
|---|
| 272 | ! zww(ji,jj,jk) = ( zfk * zaj / ( zbj - zeps ) + ( 1._wp - zfk ) * wslpjml(ji,jj) * zck ) * tmask(ji,jj,jk) |
|---|
| 273 | !!gm end modif |
|---|
| 274 | END DO |
|---|
| 275 | END DO |
|---|
| 276 | END DO |
|---|
| 277 | CALL crs_lbc_lnk( zwz, 'T', -1. ) ; CALL crs_lbc_lnk( zww, 'T', -1. ) ! lateral boundary conditions |
|---|
| 278 | ! |
|---|
| 279 | ! !* horizontal Shapiro filter |
|---|
| 280 | DO jk = 2, jpkm1 |
|---|
| 281 | DO jj = 2, jpj_crsm1, MAX(1, jpj-3) ! rows jj=2 and =jpjm1 only |
|---|
| 282 | DO ji = 2, jpi_crsm1 |
|---|
| 283 | zcofw = tmask_crs(ji,jj,jk) * z1_16 |
|---|
| 284 | wslpi_crs(ji,jj,jk) = ( zwz(ji-1,jj-1,jk) + zwz(ji+1,jj-1,jk) & |
|---|
| 285 | & + zwz(ji-1,jj+1,jk) + zwz(ji+1,jj+1,jk) & |
|---|
| 286 | & + 2.*( zwz(ji ,jj-1,jk) + zwz(ji-1,jj ,jk) & |
|---|
| 287 | & + zwz(ji+1,jj ,jk) + zwz(ji ,jj+1,jk) ) & |
|---|
| 288 | & + 4.* zwz(ji ,jj ,jk) ) * zcofw |
|---|
| 289 | |
|---|
| 290 | wslpj_crs(ji,jj,jk) = ( zww(ji-1,jj-1,jk) + zww(ji+1,jj-1,jk) & |
|---|
| 291 | & + zww(ji-1,jj+1,jk) + zww(ji+1,jj+1,jk) & |
|---|
| 292 | & + 2.*( zww(ji ,jj-1,jk) + zww(ji-1,jj ,jk) & |
|---|
| 293 | & + zww(ji+1,jj ,jk) + zww(ji ,jj+1,jk) ) & |
|---|
| 294 | & + 4.* zww(ji ,jj ,jk) ) * zcofw |
|---|
| 295 | END DO |
|---|
| 296 | END DO |
|---|
| 297 | DO jj = 3, jpj_crs-2 ! other rows |
|---|
| 298 | DO ji = 2, jpi_crsm1 ! vector opt. |
|---|
| 299 | zcofw = tmask_crs(ji,jj,jk) * z1_16 |
|---|
| 300 | wslpi_crs(ji,jj,jk) = ( zwz(ji-1,jj-1,jk) + zwz(ji+1,jj-1,jk) & |
|---|
| 301 | & + zwz(ji-1,jj+1,jk) + zwz(ji+1,jj+1,jk) & |
|---|
| 302 | & + 2.*( zwz(ji ,jj-1,jk) + zwz(ji-1,jj ,jk) & |
|---|
| 303 | & + zwz(ji+1,jj ,jk) + zwz(ji ,jj+1,jk) ) & |
|---|
| 304 | & + 4.* zwz(ji ,jj ,jk) ) * zcofw |
|---|
| 305 | |
|---|
| 306 | wslpj_crs(ji,jj,jk) = ( zww(ji-1,jj-1,jk) + zww(ji+1,jj-1,jk) & |
|---|
| 307 | & + zww(ji-1,jj+1,jk) + zww(ji+1,jj+1,jk) & |
|---|
| 308 | & + 2.*( zww(ji ,jj-1,jk) + zww(ji-1,jj ,jk) & |
|---|
| 309 | & + zww(ji+1,jj ,jk) + zww(ji ,jj+1,jk) ) & |
|---|
| 310 | & + 4.* zww(ji ,jj ,jk) ) * zcofw |
|---|
| 311 | END DO |
|---|
| 312 | END DO |
|---|
| 313 | ! !* decrease along coastal boundaries |
|---|
| 314 | DO jj = 2, jpj_crsm1 |
|---|
| 315 | DO ji = 2, jpi_crsm1 ! vector opt. |
|---|
| 316 | zck = ( umask_crs(ji,jj,jk) + umask_crs(ji-1,jj,jk) ) & |
|---|
| 317 | & * ( vmask_crs(ji,jj,jk) + vmask_crs(ji,jj-1,jk) ) * 0.25 |
|---|
| 318 | wslpi_crs(ji,jj,jk) = wslpi_crs(ji,jj,jk) * zck |
|---|
| 319 | wslpj_crs(ji,jj,jk) = wslpj_crs(ji,jj,jk) * zck |
|---|
| 320 | END DO |
|---|
| 321 | END DO |
|---|
| 322 | END DO |
|---|
| 323 | |
|---|
| 324 | ! IV. Lateral boundary conditions |
|---|
| 325 | ! =============================== |
|---|
| 326 | CALL crs_lbc_lnk( uslp_crs , 'U', -1. ) |
|---|
| 327 | CALL crs_lbc_lnk( vslp_crs , 'V', -1. ) |
|---|
| 328 | CALL crs_lbc_lnk( wslpi_crs, 'W', -1. ) ; CALL crs_lbc_lnk( wslpj_crs, 'W', -1. ) |
|---|
| 329 | ! |
|---|
| 330 | !CALL iom_swap( "nemo_crs" ) ! swap on the coarse grid |
|---|
| 331 | !CALL iom_put("uslp_crs",uslp_crs) |
|---|
| 332 | !CALL iom_put("vslp_crs",vslp_crs) |
|---|
| 333 | !CALL iom_swap( "nemo" ) ! swap on the coarse grid |
|---|
| 334 | ! |
|---|
| 335 | CALL wrk_dealloc( jpi_crs,jpj_crs,jpk, zwz, zww, zdzr, zgru, zgrv ) |
|---|
| 336 | ! |
|---|
| 337 | IF( nn_timing == 1 ) CALL timing_stop('ldf_slp_crs') |
|---|
| 338 | ! |
|---|
| 339 | END SUBROUTINE ldf_slp_crs |
|---|
| 340 | |
|---|
| 341 | SUBROUTINE ldf_slp_mxl_crs( prd, pn2, p_gru, p_grv, p_dzr ) |
|---|
| 342 | !!---------------------------------------------------------------------- |
|---|
| 343 | !! *** ROUTINE ldf_slp_mxl *** |
|---|
| 344 | !! |
|---|
| 345 | !! ** Purpose : Compute the slopes of iso-neutral surface just below |
|---|
| 346 | !! the mixed layer. |
|---|
| 347 | !! |
|---|
| 348 | !! ** Method : The slope in the i-direction is computed at u- & w-points |
|---|
| 349 | !! (uslpml, wslpiml) and the slope in the j-direction is computed |
|---|
| 350 | !! at v- and w-points (vslpml, wslpjml) with the same bounds as |
|---|
| 351 | !! in ldf_slp. |
|---|
| 352 | !! |
|---|
| 353 | !! ** Action : uslpml, wslpiml : i- & j-slopes of neutral surfaces |
|---|
| 354 | !! vslpml, wslpjml just below the mixed layer |
|---|
| 355 | !! omlmask : mixed layer mask |
|---|
| 356 | !!---------------------------------------------------------------------- |
|---|
| 357 | REAL(wp), DIMENSION(:,:,:), INTENT(in) :: prd ! in situ density |
|---|
| 358 | REAL(wp), DIMENSION(:,:,:), INTENT(in) :: pn2 ! Brunt-Vaisala frequency (locally ref.) |
|---|
| 359 | REAL(wp), DIMENSION(:,:,:), INTENT(in) :: p_gru, p_grv ! i- & j-gradient of density (u- & v-pts) |
|---|
| 360 | REAL(wp), DIMENSION(:,:,:), INTENT(in) :: p_dzr ! z-gradient of density (T-point) |
|---|
| 361 | !! |
|---|
| 362 | INTEGER :: ji , jj , jk ! dummy loop indices |
|---|
| 363 | INTEGER :: iku, ikv, ik, ikm1 ! local integers |
|---|
| 364 | REAL(wp) :: zeps, zm1_g, zm1_2g ! local scalars |
|---|
| 365 | REAL(wp) :: zci, zfi, zau, zbu, zai, zbi ! - - |
|---|
| 366 | REAL(wp) :: zcj, zfj, zav, zbv, zaj, zbj ! - - |
|---|
| 367 | REAL(wp) :: zck, zfk, zbw ! - - |
|---|
| 368 | !!---------------------------------------------------------------------- |
|---|
| 369 | ! |
|---|
| 370 | IF( nn_timing == 1 ) CALL timing_start('ldf_slp_mxl') |
|---|
| 371 | ! |
|---|
| 372 | zeps = 1.e-20_wp !== Local constant initialization ==! |
|---|
| 373 | zm1_g = -1.0_wp / grav |
|---|
| 374 | zm1_2g = -0.5_wp / grav |
|---|
| 375 | ! |
|---|
| 376 | uslpml (1,:) = 0._wp ; uslpml (jpi_crs,:) = 0._wp |
|---|
| 377 | vslpml (1,:) = 0._wp ; vslpml (jpi_crs,:) = 0._wp |
|---|
| 378 | wslpiml(1,:) = 0._wp ; wslpiml(jpi_crs,:) = 0._wp |
|---|
| 379 | wslpjml(1,:) = 0._wp ; wslpjml(jpi_crs,:) = 0._wp |
|---|
| 380 | ! |
|---|
| 381 | ! !== surface mixed layer mask ! |
|---|
| 382 | DO jk = 1, jpk ! =1 inside the mixed layer, =0 otherwise |
|---|
| 383 | DO jj = 1, jpj_crs |
|---|
| 384 | DO ji = 1, jpi_crs |
|---|
| 385 | ik = nmln_crs(ji,jj) - 1 |
|---|
| 386 | IF( jk <= ik ) THEN ; omlmask(ji,jj,jk) = 1._wp |
|---|
| 387 | ELSE ; omlmask(ji,jj,jk) = 0._wp |
|---|
| 388 | ENDIF |
|---|
| 389 | END DO |
|---|
| 390 | END DO |
|---|
| 391 | END DO |
|---|
| 392 | |
|---|
| 393 | |
|---|
| 394 | ! Slopes of isopycnal surfaces just before bottom of mixed layer |
|---|
| 395 | ! -------------------------------------------------------------- |
|---|
| 396 | ! The slope are computed as in the 3D case. |
|---|
| 397 | ! A key point here is the definition of the mixed layer at u- and v-points. |
|---|
| 398 | ! It is assumed to be the maximum of the two neighbouring T-point mixed layer depth. |
|---|
| 399 | ! Otherwise, a n2 value inside the mixed layer can be involved in the computation |
|---|
| 400 | ! of the slope, resulting in a too steep diagnosed slope and thus a spurious eddy |
|---|
| 401 | ! induce velocity field near the base of the mixed layer. |
|---|
| 402 | !----------------------------------------------------------------------- |
|---|
| 403 | ! |
|---|
| 404 | DO jj = 2, nldi_crs |
|---|
| 405 | DO ji = 2, nldj_crs |
|---|
| 406 | ! !== Slope at u- & v-points just below the Mixed Layer ==! |
|---|
| 407 | ! |
|---|
| 408 | ! !- vertical density gradient for u- and v-slopes (from dzr at T-point) |
|---|
| 409 | iku = MIN( MAX( 1, nmln_crs(ji,jj) , nmln_crs(ji+1,jj) ) , jpkm1 ) ! ML (MAX of T-pts, bound by jpkm1) |
|---|
| 410 | ikv = MIN( MAX( 1, nmln_crs(ji,jj) , nmln_crs(ji,jj+1) ) , jpkm1 ) ! |
|---|
| 411 | zbu = 0.5_wp * ( p_dzr(ji,jj,iku) + p_dzr(ji+1,jj ,iku) ) |
|---|
| 412 | zbv = 0.5_wp * ( p_dzr(ji,jj,ikv) + p_dzr(ji ,jj+1,ikv) ) |
|---|
| 413 | ! !- horizontal density gradient at u- & v-points |
|---|
| 414 | zau = p_gru(ji,jj,iku) / e1u_crs(ji,jj) |
|---|
| 415 | zav = p_grv(ji,jj,ikv) / e2v_crs(ji,jj) |
|---|
| 416 | ! !- bound the slopes: abs(zw.)<= 1/100 and zb..<0 |
|---|
| 417 | ! kxz max= ah slope max =< e1 e3 /(pi**2 2 dt) |
|---|
| 418 | zbu = MIN( zbu , -100._wp* ABS( zau ) , -7.e+3_wp/fse3u_max_crs(ji,jj,iku)* ABS( zau ) ) |
|---|
| 419 | zbv = MIN( zbv , -100._wp* ABS( zav ) , -7.e+3_wp/fse3v_max_crs(ji,jj,ikv)* ABS( zav ) ) |
|---|
| 420 | ! !- Slope at u- & v-points (uslpml, vslpml) |
|---|
| 421 | uslpml(ji,jj) = zau / ( zbu - zeps ) * umask_crs(ji,jj,iku) |
|---|
| 422 | vslpml(ji,jj) = zav / ( zbv - zeps ) * vmask_crs(ji,jj,ikv) |
|---|
| 423 | ! |
|---|
| 424 | ! !== i- & j-slopes at w-points just below the Mixed Layer ==! |
|---|
| 425 | ! |
|---|
| 426 | ik = MIN( nmln_crs(ji,jj) + 1, jpk ) |
|---|
| 427 | ikm1 = MAX( 1, ik-1 ) |
|---|
| 428 | ! !- vertical density gradient for w-slope (from N^2) |
|---|
| 429 | zbw = zm1_2g * pn2 (ji,jj,ik) * ( prd (ji,jj,ik) + prd (ji,jj,ikm1) + 2. ) |
|---|
| 430 | ! !- horizontal density i- & j-gradient at w-points |
|---|
| 431 | zci = MAX( umask_crs(ji-1,jj,ik ) + umask_crs(ji,jj,ik ) & |
|---|
| 432 | & + umask_crs(ji-1,jj,ikm1) + umask_crs(ji,jj,ikm1) , zeps ) * e1t_crs(ji,jj) |
|---|
| 433 | zcj = MAX( vmask_crs(ji,jj-1,ik ) + vmask_crs(ji,jj,ik ) & |
|---|
| 434 | & + vmask_crs(ji,jj-1,ikm1) + vmask_crs(ji,jj,ikm1) , zeps ) * e2t_crs(ji,jj) |
|---|
| 435 | zai = ( p_gru(ji-1,jj,ik ) + p_gru(ji,jj,ik) & |
|---|
| 436 | & + p_gru(ji-1,jj,ikm1) + p_gru(ji,jj,ikm1 ) ) / zci * tmask_crs(ji,jj,ik) |
|---|
| 437 | zaj = ( p_grv(ji,jj-1,ik ) + p_grv(ji,jj,ik ) & |
|---|
| 438 | & + p_grv(ji,jj-1,ikm1) + p_grv(ji,jj,ikm1) ) / zcj * tmask_crs(ji,jj,ik) |
|---|
| 439 | ! !- bound the slopes: abs(zw.)<= 1/100 and zb..<0. |
|---|
| 440 | ! kxz max= ah slope max =< e1 e3 /(pi**2 2 dt) |
|---|
| 441 | zbi = MIN( zbw , -100._wp* ABS( zai ) , -7.e+3_wp/fse3w_max_crs(ji,jj,ik)* ABS( zai ) ) |
|---|
| 442 | zbj = MIN( zbw , -100._wp* ABS( zaj ) , -7.e+3_wp/fse3w_max_crs(ji,jj,ik)* ABS( zaj ) ) |
|---|
| 443 | ! !- i- & j-slope at w-points (wslpiml, wslpjml) |
|---|
| 444 | wslpiml(ji,jj) = zai / ( zbi - zeps ) * tmask_crs (ji,jj,ik) |
|---|
| 445 | wslpjml(ji,jj) = zaj / ( zbj - zeps ) * tmask_crs (ji,jj,ik) |
|---|
| 446 | END DO |
|---|
| 447 | END DO |
|---|
| 448 | !!gm this lbc_lnk should be useless.... |
|---|
| 449 | CALL crs_lbc_lnk( uslpml , 'U', -1. ) ; CALL crs_lbc_lnk( vslpml , 'V', -1. ) ! lateral boundary cond. (sign change) |
|---|
| 450 | CALL crs_lbc_lnk( wslpiml, 'W', -1. ) ; CALL crs_lbc_lnk( wslpjml, 'W', -1. ) ! lateral boundary conditions |
|---|
| 451 | ! |
|---|
| 452 | IF( nn_timing == 1 ) CALL timing_stop('ldf_slp_mxl') |
|---|
| 453 | ! |
|---|
| 454 | END SUBROUTINE ldf_slp_mxl_crs |
|---|
| 455 | |
|---|
| 456 | |
|---|
| 457 | SUBROUTINE ldf_slp_init_crs |
|---|
| 458 | !!---------------------------------------------------------------------- |
|---|
| 459 | !! *** ROUTINE ldf_slp_init *** |
|---|
| 460 | !! |
|---|
| 461 | !! ** Purpose : Initialization for the isopycnal slopes computation |
|---|
| 462 | !! |
|---|
| 463 | !! ** Method : read the nammbf namelist and check the parameter |
|---|
| 464 | !! values called by tra_dmp at the first timestep (nit000) |
|---|
| 465 | !!---------------------------------------------------------------------- |
|---|
| 466 | INTEGER :: ji, jj, jk ! dummy loop indices |
|---|
| 467 | INTEGER :: ierr ! local integer |
|---|
| 468 | !!---------------------------------------------------------------------- |
|---|
| 469 | ! |
|---|
| 470 | IF( nn_timing == 1 ) CALL timing_start('ldf_slp_init') |
|---|
| 471 | ! |
|---|
| 472 | IF(lwp) THEN |
|---|
| 473 | WRITE(numout,*) |
|---|
| 474 | WRITE(numout,*) 'ldf_slp_init_crs : direction of lateral mixing' |
|---|
| 475 | WRITE(numout,*) '~~~~~~~~~~~~' |
|---|
| 476 | ENDIF |
|---|
| 477 | |
|---|
| 478 | IF( ln_traldf_grif ) THEN ! Griffies operator : triad of slopes |
|---|
| 479 | ALLOCATE( triadi_g(jpi_crs,jpj_crs,jpk,0:1,0:1) , triadj_g(jpi_crs,jpj_crs,jpk,0:1,0:1) , wslp2(jpi_crs,jpj_crs,jpk) , STAT=ierr ) |
|---|
| 480 | ALLOCATE( triadi (jpi_crs,jpj_crs,jpk,0:1,0:1) , triadj (jpi_crs,jpj_crs,jpk,0:1,0:1) , STAT=ierr ) |
|---|
| 481 | IF( ierr > 0 ) CALL ctl_stop( 'STOP', 'ldf_slp_init : unable to allocate Griffies operator slope' ) |
|---|
| 482 | ! |
|---|
| 483 | IF( ln_dynldf_iso ) CALL ctl_stop( 'ldf_slp_init: Griffies operator on momentum not supported' ) |
|---|
| 484 | ! |
|---|
| 485 | ELSE ! Madec operator : slopes at u-, v-, and w-points |
|---|
| 486 | ALLOCATE( uslp_crs(jpi_crs,jpj_crs,jpk) , vslp_crs(jpi_crs,jpj_crs,jpk) , wslpi_crs(jpi_crs,jpj_crs,jpk) , wslpj_crs(jpi_crs,jpj_crs,jpk) , & |
|---|
| 487 | & omlmask(jpi_crs,jpj_crs,jpk) , uslpml(jpi_crs,jpj_crs) , vslpml(jpi_crs,jpj_crs) , wslpiml(jpi_crs,jpj_crs) , wslpjml(jpi_crs,jpj_crs) , STAT=ierr ) |
|---|
| 488 | IF( ierr > 0 ) CALL ctl_stop( 'STOP', 'ldf_slp_init : unable to allocate Madec operator slope ' ) |
|---|
| 489 | |
|---|
| 490 | ! Direction of lateral diffusion (tracers and/or momentum) |
|---|
| 491 | ! ------------------------------ |
|---|
| 492 | uslp_crs (:,:,:) = 0._wp ; uslpml (:,:) = 0._wp ! set the slope to zero (even in s-coordinates) |
|---|
| 493 | vslp_crs (:,:,:) = 0._wp ; vslpml (:,:) = 0._wp |
|---|
| 494 | wslpi_crs(:,:,:) = 0._wp ; wslpiml(:,:) = 0._wp |
|---|
| 495 | wslpj_crs(:,:,:) = 0._wp ; wslpjml(:,:) = 0._wp |
|---|
| 496 | |
|---|
| 497 | !!gm I no longer understand this..... |
|---|
| 498 | IF( (ln_traldf_hor .OR. ln_dynldf_hor) .AND. .NOT. (lk_vvl .AND. ln_rstart) ) THEN |
|---|
| 499 | IF(lwp) WRITE(numout,*) ' Horizontal mixing in s-coordinate: slope = slope of s-surfaces' |
|---|
| 500 | |
|---|
| 501 | ! geopotential diffusion in s-coordinates on tracers and/or momentum |
|---|
| 502 | ! The slopes of s-surfaces are computed once (no call to ldfslp in step) |
|---|
| 503 | ! The slopes for momentum diffusion are i- or j- averaged of those on tracers |
|---|
| 504 | |
|---|
| 505 | ! set the slope of diffusion to the slope of s-surfaces |
|---|
| 506 | ! ( c a u t i o n : minus sign as fsdep has positive value ) |
|---|
| 507 | DO jk = 1, jpk |
|---|
| 508 | DO jj = 2, jpj_crsm1 |
|---|
| 509 | DO ji = 2, jpi_crsm1 ! vector opt. |
|---|
| 510 | uslp_crs (ji,jj,jk) = -1. * ( fsdept_crs(ji+1,jj,jk) - fsdept_crs(ji ,jj ,jk) ) * umask_crs(ji,jj,jk) |
|---|
| 511 | IF( e1u_crs(ji,jj) .NE. 0._wp ) uslp_crs (ji,jj,jk) = uslp_crs (ji,jj,jk) / e1u_crs(ji,jj) |
|---|
| 512 | vslp_crs (ji,jj,jk) = -1. * ( fsdept_crs(ji,jj+1,jk) - fsdept_crs(ji ,jj ,jk) ) * vmask_crs(ji,jj,jk) |
|---|
| 513 | IF( e2v_crs(ji,jj) .NE. 0._wp ) vslp_crs (ji,jj,jk) = vslp_crs (ji,jj,jk) / e2v_crs(ji,jj) |
|---|
| 514 | wslpi_crs(ji,jj,jk) = -1. * ( fsdepw_crs(ji+1,jj,jk) - fsdepw_crs(ji-1,jj,jk) ) * tmask_crs(ji,jj,jk) * 0.5 |
|---|
| 515 | IF( e1t_crs(ji,jj) .NE. 0._wp ) wslpi_crs(ji,jj,jk) = wslpi_crs(ji,jj,jk) / e1t_crs(ji,jj) |
|---|
| 516 | wslpj_crs(ji,jj,jk) = -1. * ( fsdepw_crs(ji,jj+1,jk) - fsdepw_crs(ji,jj-1,jk) ) * tmask_crs(ji,jj,jk) * 0.5 |
|---|
| 517 | IF( e2t_crs(ji,jj) .NE. 0._wp ) wslpj_crs(ji,jj,jk) = wslpj_crs(ji,jj,jk) / e2t_crs(ji,jj) |
|---|
| 518 | END DO |
|---|
| 519 | END DO |
|---|
| 520 | END DO |
|---|
| 521 | CALL crs_lbc_lnk( uslp_crs , 'U', -1. ) ; CALL crs_lbc_lnk( vslp_crs , 'V', -1. ) ! Lateral boundary conditions |
|---|
| 522 | CALL crs_lbc_lnk( wslpi_crs, 'W', -1. ) ; CALL crs_lbc_lnk( wslpj_crs, 'W', -1. ) |
|---|
| 523 | ENDIF |
|---|
| 524 | ENDIF |
|---|
| 525 | ! |
|---|
| 526 | IF( nn_timing == 1 ) CALL timing_stop('ldf_slp_init') |
|---|
| 527 | ! |
|---|
| 528 | END SUBROUTINE ldf_slp_init_crs |
|---|
| 529 | |
|---|
| 530 | #else |
|---|
| 531 | !!------------------------------------------------------------------------ |
|---|
| 532 | !! Dummy module : NO Rotation of lateral mixing tensor |
|---|
| 533 | !!------------------------------------------------------------------------ |
|---|
| 534 | LOGICAL, PUBLIC, PARAMETER :: lk_ldfslp_crs = .FALSE. !: slopes flag |
|---|
| 535 | CONTAINS |
|---|
| 536 | SUBROUTINE ldf_slp_crs( kt, prd, pn2 ) ! Dummy routine |
|---|
| 537 | INTEGER, INTENT(in) :: kt |
|---|
| 538 | REAL, DIMENSION(:,:,:), INTENT(in) :: prd, pn2 |
|---|
| 539 | WRITE(*,*) 'ldf_slp: You should not have seen this print! error?', kt, prd(1,1,1), pn2(1,1,1) |
|---|
| 540 | END SUBROUTINE ldf_slp_crs |
|---|
| 541 | SUBROUTINE ldf_slp_init_crs ! Dummy routine |
|---|
| 542 | END SUBROUTINE ldf_slp_init_crs |
|---|
| 543 | #endif |
|---|
| 544 | |
|---|
| 545 | SUBROUTINE ldf_slp_grif_crs( kt ) ! Dummy routine |
|---|
| 546 | INTEGER, INTENT(in) :: kt |
|---|
| 547 | WRITE(*,*) 'ldf_slp_grif: You should not have seen this print! error?', kt |
|---|
| 548 | END SUBROUTINE ldf_slp_grif_crs |
|---|
| 549 | |
|---|
| 550 | !!====================================================================== |
|---|
| 551 | END MODULE ldfslp_crs |
|---|
