| 1 | MODULE p4zflx |
|---|
| 2 | !!====================================================================== |
|---|
| 3 | !! *** MODULE p4zflx *** |
|---|
| 4 | !! TOP : PISCES CALCULATES GAS EXCHANGE AND CHEMISTRY AT SEA SURFACE |
|---|
| 5 | !!====================================================================== |
|---|
| 6 | !! History : - ! 1988-07 (E. MAIER-REIMER) Original code |
|---|
| 7 | !! - ! 1998 (O. Aumont) additions |
|---|
| 8 | !! - ! 1999 (C. Le Quere) modifications |
|---|
| 9 | !! 1.0 ! 2004 (O. Aumont) modifications |
|---|
| 10 | !! 2.0 ! 2007-12 (C. Ethe, G. Madec) F90 |
|---|
| 11 | !! ! 2011-02 (J. Simeon, J. Orr) Include total atm P correction |
|---|
| 12 | !!---------------------------------------------------------------------- |
|---|
| 13 | #if defined key_pisces |
|---|
| 14 | !!---------------------------------------------------------------------- |
|---|
| 15 | !! 'key_pisces' PISCES bio-model |
|---|
| 16 | !!---------------------------------------------------------------------- |
|---|
| 17 | !! p4z_flx : CALCULATES GAS EXCHANGE AND CHEMISTRY AT SEA SURFACE |
|---|
| 18 | !! p4z_flx_init : Read the namelist |
|---|
| 19 | !! p4z_patm : Read sfc atm pressure [atm] for each grid cell |
|---|
| 20 | !!---------------------------------------------------------------------- |
|---|
| 21 | USE oce_trc ! shared variables between ocean and passive tracers |
|---|
| 22 | USE sms_pisces ! PISCES Source Minus Sink variables |
|---|
| 23 | USE p4zche ! Chemical model |
|---|
| 24 | USE prtctl_trc , ONLY : prt_ctl_trc_info,prt_ctl_trc ! print control for debugging |
|---|
| 25 | USE fldread ! read input fields |
|---|
| 26 | #if defined key_cpl_carbon_cycle |
|---|
| 27 | USE sbc_oce, ONLY : atm_co2 ! atmospheric pCO2 |
|---|
| 28 | #endif |
|---|
| 29 | |
|---|
| 30 | IMPLICIT NONE |
|---|
| 31 | PRIVATE |
|---|
| 32 | |
|---|
| 33 | PUBLIC p4z_flx |
|---|
| 34 | PUBLIC p4z_flx_init |
|---|
| 35 | PUBLIC p4z_flx_alloc |
|---|
| 36 | |
|---|
| 37 | ! !!** Namelist nampisext ** |
|---|
| 38 | REAL(wp) :: atcco2 !: pre-industrial atmospheric [co2] (ppm) |
|---|
| 39 | LOGICAL :: ln_co2int !: flag to read in a file and interpolate atmospheric pco2 or not |
|---|
| 40 | CHARACTER(len=34) :: clname !: filename of pco2 values |
|---|
| 41 | INTEGER :: nn_offset !: Offset model-data start year (default = 0) |
|---|
| 42 | |
|---|
| 43 | !! Variables related to reading atmospheric CO2 time history |
|---|
| 44 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:) :: atcco2h, years |
|---|
| 45 | INTEGER :: nmaxrec, numco2 |
|---|
| 46 | |
|---|
| 47 | ! !!* nampisatm namelist (Atmospheric PRessure) * |
|---|
| 48 | LOGICAL, PUBLIC :: ln_presatm !: ref. pressure: global mean Patm (F) or a constant (F) |
|---|
| 49 | |
|---|
| 50 | REAL(wp) , ALLOCATABLE, SAVE, DIMENSION(:,:) :: patm ! atmospheric pressure at kt [N/m2] |
|---|
| 51 | TYPE(FLD), ALLOCATABLE, DIMENSION(:) :: sf_patm ! structure of input fields (file informations, fields read) |
|---|
| 52 | |
|---|
| 53 | |
|---|
| 54 | REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:) :: oce_co2 !: ocean carbon flux |
|---|
| 55 | REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:) :: satmco2 !: atmospheric pco2 |
|---|
| 56 | |
|---|
| 57 | REAL(wp) :: xconv = 0.01_wp / 3600._wp !: coefficients for conversion |
|---|
| 58 | |
|---|
| 59 | !!* Substitution |
|---|
| 60 | # include "top_substitute.h90" |
|---|
| 61 | !!---------------------------------------------------------------------- |
|---|
| 62 | !! NEMO/TOP 3.3 , NEMO Consortium (2010) |
|---|
| 63 | !! $Id$ |
|---|
| 64 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
|---|
| 65 | !!---------------------------------------------------------------------- |
|---|
| 66 | CONTAINS |
|---|
| 67 | |
|---|
| 68 | SUBROUTINE p4z_flx ( kt, knt ) |
|---|
| 69 | !!--------------------------------------------------------------------- |
|---|
| 70 | !! *** ROUTINE p4z_flx *** |
|---|
| 71 | !! |
|---|
| 72 | !! ** Purpose : CALCULATES GAS EXCHANGE AND CHEMISTRY AT SEA SURFACE |
|---|
| 73 | !! |
|---|
| 74 | !! ** Method : |
|---|
| 75 | !! - Include total atm P correction via Esbensen & Kushnir (1981) |
|---|
| 76 | !! - Pressure correction NOT done for key_cpl_carbon_cycle |
|---|
| 77 | !! - Remove Wanninkhof chemical enhancement; |
|---|
| 78 | !! - Add option for time-interpolation of atcco2.txt |
|---|
| 79 | !!--------------------------------------------------------------------- |
|---|
| 80 | ! |
|---|
| 81 | INTEGER, INTENT(in) :: kt, knt ! |
|---|
| 82 | ! |
|---|
| 83 | INTEGER :: ji, jj, jm, iind, iindm1 |
|---|
| 84 | REAL(wp) :: ztc, ztc2, ztc3, ztc4, zws, zkgwan |
|---|
| 85 | REAL(wp) :: zfld, zflu, zfld16, zflu16, zfact |
|---|
| 86 | REAL(wp) :: zvapsw, zsal, zfco2, zxc2, xCO2approx, ztkel, zfugcoeff |
|---|
| 87 | REAL(wp) :: zph, zdic, zsch_o2, zsch_co2 |
|---|
| 88 | REAL(wp) :: zyr_dec, zdco2dt |
|---|
| 89 | CHARACTER (len=25) :: charout |
|---|
| 90 | REAL(wp), POINTER, DIMENSION(:,:) :: zkgco2, zkgo2, zh2co3, zoflx, zw2d, zpco2atm |
|---|
| 91 | !!--------------------------------------------------------------------- |
|---|
| 92 | ! |
|---|
| 93 | IF( nn_timing == 1 ) CALL timing_start('p4z_flx') |
|---|
| 94 | ! |
|---|
| 95 | CALL wrk_alloc( jpi, jpj, zkgco2, zkgo2, zh2co3, zoflx, zpco2atm ) |
|---|
| 96 | ! |
|---|
| 97 | |
|---|
| 98 | ! SURFACE CHEMISTRY (PCO2 AND [H+] IN |
|---|
| 99 | ! SURFACE LAYER); THE RESULT OF THIS CALCULATION |
|---|
| 100 | ! IS USED TO COMPUTE AIR-SEA FLUX OF CO2 |
|---|
| 101 | |
|---|
| 102 | IF( kt /= nit000 .AND. knt == 1 ) CALL p4z_patm( kt ) ! Get sea-level pressure (E&K [1981] climatology) for use in flux calcs |
|---|
| 103 | |
|---|
| 104 | IF( ln_co2int ) THEN |
|---|
| 105 | ! Linear temporal interpolation of atmospheric pco2. atcco2.txt has annual values. |
|---|
| 106 | ! Caveats: First column of .txt must be in years, decimal years preferably. |
|---|
| 107 | ! For nn_offset, if your model year is iyy, nn_offset=(years(1)-iyy) |
|---|
| 108 | ! then the first atmospheric CO2 record read is at years(1) |
|---|
| 109 | zyr_dec = REAL( nyear + nn_offset, wp ) + REAL( nday_year, wp ) / REAL( nyear_len(1), wp ) |
|---|
| 110 | jm = 1 |
|---|
| 111 | DO WHILE( jm <= nmaxrec .AND. years(jm) < zyr_dec ) ; jm = jm + 1 ; END DO |
|---|
| 112 | iind = jm ; iindm1 = jm - 1 |
|---|
| 113 | zdco2dt = ( atcco2h(iind) - atcco2h(iindm1) ) / ( years(iind) - years(iindm1) + rtrn ) |
|---|
| 114 | atcco2 = zdco2dt * ( zyr_dec - years(iindm1) ) + atcco2h(iindm1) |
|---|
| 115 | satmco2(:,:) = atcco2 |
|---|
| 116 | ENDIF |
|---|
| 117 | |
|---|
| 118 | #if defined key_cpl_carbon_cycle |
|---|
| 119 | satmco2(:,:) = atm_co2(:,:) |
|---|
| 120 | #endif |
|---|
| 121 | |
|---|
| 122 | DO jj = 1, jpj |
|---|
| 123 | DO ji = 1, jpi |
|---|
| 124 | ! DUMMY VARIABLES FOR DIC, H+, AND BORATE |
|---|
| 125 | zfact = rhop(ji,jj,1) / 1000. + rtrn |
|---|
| 126 | zdic = trb(ji,jj,1,jpdic) |
|---|
| 127 | zph = MAX( hi(ji,jj,1), 1.e-10 ) / zfact |
|---|
| 128 | ! CALCULATE [H2CO3] |
|---|
| 129 | zh2co3(ji,jj) = zdic/(1. + ak13(ji,jj,1)/zph + ak13(ji,jj,1)*ak23(ji,jj,1)/zph**2) |
|---|
| 130 | END DO |
|---|
| 131 | END DO |
|---|
| 132 | |
|---|
| 133 | ! -------------- |
|---|
| 134 | ! COMPUTE FLUXES |
|---|
| 135 | ! -------------- |
|---|
| 136 | |
|---|
| 137 | ! FIRST COMPUTE GAS EXCHANGE COEFFICIENTS |
|---|
| 138 | ! ------------------------------------------- |
|---|
| 139 | |
|---|
| 140 | !CDIR NOVERRCHK |
|---|
| 141 | DO jj = 1, jpj |
|---|
| 142 | !CDIR NOVERRCHK |
|---|
| 143 | DO ji = 1, jpi |
|---|
| 144 | ztc = MIN( 35., tsn(ji,jj,1,jp_tem) ) |
|---|
| 145 | ztc2 = ztc * ztc |
|---|
| 146 | ztc3 = ztc * ztc2 |
|---|
| 147 | ztc4 = ztc2 * ztc2 |
|---|
| 148 | ! Compute the schmidt Number both O2 and CO2 |
|---|
| 149 | zsch_co2 = 2116.8 - 136.25 * ztc + 4.7353 * ztc2 - 0.092307 * ztc3 + 0.0007555 * ztc4 |
|---|
| 150 | zsch_o2 = 1920.4 - 135.6 * ztc + 5.2122 * ztc2 - 0.109390 * ztc3 + 0.0009377 * ztc4 |
|---|
| 151 | ! wind speed |
|---|
| 152 | zws = wndm(ji,jj) * wndm(ji,jj) |
|---|
| 153 | ! Compute the piston velocity for O2 and CO2 |
|---|
| 154 | zkgwan = 0.251 * zws |
|---|
| 155 | zkgwan = zkgwan * xconv * ( 1.- fr_i(ji,jj) ) * tmask(ji,jj,1) |
|---|
| 156 | # if defined key_degrad |
|---|
| 157 | zkgwan = zkgwan * facvol(ji,jj,1) |
|---|
| 158 | #endif |
|---|
| 159 | ! compute gas exchange for CO2 and O2 |
|---|
| 160 | zkgco2(ji,jj) = zkgwan * SQRT( 660./ zsch_co2 ) |
|---|
| 161 | zkgo2 (ji,jj) = zkgwan * SQRT( 660./ zsch_o2 ) |
|---|
| 162 | END DO |
|---|
| 163 | END DO |
|---|
| 164 | |
|---|
| 165 | DO jj = 1, jpj |
|---|
| 166 | DO ji = 1, jpi |
|---|
| 167 | ztkel = tsn(ji,jj,1,jp_tem) + 273.15 |
|---|
| 168 | zsal = tsn(ji,jj,1,jp_sal) + ( 1.- tmask(ji,jj,1) ) * 35. |
|---|
| 169 | zvapsw = EXP(24.4543 - 67.4509*(100.0/ztkel) - 4.8489*LOG(ztkel/100) - 0.000544*zsal) |
|---|
| 170 | zpco2atm(ji,jj) = satmco2(ji,jj) * ( patm(ji,jj) - zvapsw ) |
|---|
| 171 | zxc2 = (1.0 - zpco2atm(ji,jj) * 1E-6 )**2 |
|---|
| 172 | zfugcoeff = EXP(patm(ji,jj) * (chemc(ji,jj,2) + 2.0 * zxc2 * chemc(ji,jj,3) ) & |
|---|
| 173 | & / (82.05736 * ztkel)) |
|---|
| 174 | zfco2 = zpco2atm(ji,jj) * zfugcoeff |
|---|
| 175 | |
|---|
| 176 | ! Compute CO2 flux for the sea and air |
|---|
| 177 | zfld = zfco2 * chemc(ji,jj,1) * zkgco2(ji,jj) ! (mol/L) * (m/s) |
|---|
| 178 | zflu = zh2co3(ji,jj) * zkgco2(ji,jj) ! (mol/L) (m/s) ? |
|---|
| 179 | oce_co2(ji,jj) = ( zfld - zflu ) * rfact2 * e1e2t(ji,jj) * tmask(ji,jj,1) * 1000. |
|---|
| 180 | ! compute the trend |
|---|
| 181 | #if defined key_crs |
|---|
| 182 | tra(ji,jj,1,jpdic) = tra(ji,jj,1,jpdic) + ( zfld - zflu ) * rfact2 / e3t_max_crs(ji,jj,1) |
|---|
| 183 | #else |
|---|
| 184 | tra(ji,jj,1,jpdic) = tra(ji,jj,1,jpdic) + ( zfld - zflu ) * rfact2 / fse3t(ji,jj,1) * tmask(ji,jj,1) |
|---|
| 185 | #endif |
|---|
| 186 | |
|---|
| 187 | ! Compute O2 flux |
|---|
| 188 | zfld16 = patm(ji,jj) * chemo2(ji,jj,1) * zkgo2(ji,jj) ! (mol/L) * (m/s) |
|---|
| 189 | zflu16 = trb(ji,jj,1,jpoxy) * zkgo2(ji,jj) |
|---|
| 190 | zoflx(ji,jj) = ( zfld16 - zflu16 ) * tmask(ji,jj,1) |
|---|
| 191 | #if defined key_crs |
|---|
| 192 | tra(ji,jj,1,jpoxy) = tra(ji,jj,1,jpoxy) + zoflx(ji,jj) * rfact2 / e3t_max_crs(ji,jj,1) |
|---|
| 193 | #else |
|---|
| 194 | tra(ji,jj,1,jpoxy) = tra(ji,jj,1,jpoxy) + zoflx(ji,jj) * rfact2 / fse3t(ji,jj,1) |
|---|
| 195 | #endif |
|---|
| 196 | END DO |
|---|
| 197 | END DO |
|---|
| 198 | |
|---|
| 199 | t_oce_co2_flx = glob_sum( oce_co2(:,:) ) ! Total Flux of Carbon |
|---|
| 200 | t_oce_co2_flx_cum = t_oce_co2_flx_cum + t_oce_co2_flx ! Cumulative Total Flux of Carbon |
|---|
| 201 | ! t_atm_co2_flx = glob_sum( satmco2(:,:) * e1e2t(:,:) ) ! Total atmospheric pCO2 |
|---|
| 202 | t_atm_co2_flx = atcco2 ! Total atmospheric pCO2 |
|---|
| 203 | |
|---|
| 204 | #if ! defined key_crs |
|---|
| 205 | IF(ln_ctl) THEN ! print mean trends (used for debugging) |
|---|
| 206 | WRITE(charout, FMT="('flx ')") |
|---|
| 207 | CALL prt_ctl_trc_info(charout) |
|---|
| 208 | CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm) |
|---|
| 209 | ENDIF |
|---|
| 210 | #endif |
|---|
| 211 | |
|---|
| 212 | IF( lk_iomput .AND. knt == nrdttrc ) THEN |
|---|
| 213 | CALL wrk_alloc( jpi, jpj, zw2d ) |
|---|
| 214 | IF( iom_use( "Cflx" ) ) THEN |
|---|
| 215 | zw2d(:,:) = oce_co2(:,:) / e1e2t(:,:) * rfact2r |
|---|
| 216 | CALL iom_put( "Cflx" , zw2d ) |
|---|
| 217 | ENDIF |
|---|
| 218 | IF( iom_use( "Oflx" ) ) THEN |
|---|
| 219 | zw2d(:,:) = zoflx(:,:) * 1000 * tmask(:,:,1) |
|---|
| 220 | CALL iom_put( "Oflx" , zw2d ) |
|---|
| 221 | ENDIF |
|---|
| 222 | IF( iom_use( "Kg" ) ) THEN |
|---|
| 223 | zw2d(:,:) = zkgco2(:,:) * tmask(:,:,1) |
|---|
| 224 | CALL iom_put( "Kg" , zw2d ) |
|---|
| 225 | ENDIF |
|---|
| 226 | IF( iom_use( "Dpco2" ) ) THEN |
|---|
| 227 | zw2d(:,:) = ( zpco2atm(:,:) - zh2co3(:,:) / ( chemc(:,:,1) + rtrn ) ) * tmask(:,:,1) |
|---|
| 228 | CALL iom_put( "Dpco2" , zw2d ) |
|---|
| 229 | ENDIF |
|---|
| 230 | IF( iom_use( "Dpo2" ) ) THEN |
|---|
| 231 | zw2d(:,:) = ( atcox * patm(:,:) - atcox * trn(:,:,1,jpoxy) / ( chemo2(:,:,1) + rtrn ) ) * tmask(:,:,1) |
|---|
| 232 | CALL iom_put( "Dpo2" , zw2d ) |
|---|
| 233 | ENDIF |
|---|
| 234 | IF( iom_use( "tcflx" ) ) CALL iom_put( "tcflx" , t_oce_co2_flx * rfact2r ) ! molC/s |
|---|
| 235 | CALL iom_put( "tcflxcum" , t_oce_co2_flx_cum ) ! molC |
|---|
| 236 | ! |
|---|
| 237 | CALL wrk_dealloc( jpi, jpj, zw2d ) |
|---|
| 238 | ELSE |
|---|
| 239 | IF( ln_diatrc ) THEN |
|---|
| 240 | trc2d(:,:,jp_pcs0_2d ) = oce_co2(:,:) / e1e2t(:,:) * rfact2r |
|---|
| 241 | trc2d(:,:,jp_pcs0_2d + 1) = zoflx(:,:) * 1000 * tmask(:,:,1) |
|---|
| 242 | trc2d(:,:,jp_pcs0_2d + 2) = zkgco2(:,:) * tmask(:,:,1) |
|---|
| 243 | trc2d(:,:,jp_pcs0_2d + 3) = ( zpco2atm(:,:) - zh2co3(:,:) / ( chemc(:,:,1) + rtrn ) ) * tmask(:,:,1) |
|---|
| 244 | ENDIF |
|---|
| 245 | ENDIF |
|---|
| 246 | ! |
|---|
| 247 | #if defined key_cpl_carbon_cycle |
|---|
| 248 | ! change units for carbon cycle coupling |
|---|
| 249 | oce_co2(:,:) = oce_co2(:,:) / e1e2t(:,:) * rfact2r ! in molC/m2/s |
|---|
| 250 | #endif |
|---|
| 251 | ! |
|---|
| 252 | CALL wrk_dealloc( jpi, jpj, zkgco2, zkgo2, zh2co3, zoflx, zpco2atm ) |
|---|
| 253 | ! |
|---|
| 254 | IF( nn_timing == 1 ) CALL timing_stop('p4z_flx') |
|---|
| 255 | ! |
|---|
| 256 | END SUBROUTINE p4z_flx |
|---|
| 257 | |
|---|
| 258 | |
|---|
| 259 | SUBROUTINE p4z_flx_init |
|---|
| 260 | !!---------------------------------------------------------------------- |
|---|
| 261 | !! *** ROUTINE p4z_flx_init *** |
|---|
| 262 | !! |
|---|
| 263 | !! ** Purpose : Initialization of atmospheric conditions |
|---|
| 264 | !! |
|---|
| 265 | !! ** Method : Read the nampisext namelist and check the parameters |
|---|
| 266 | !! called at the first timestep (nittrc000) |
|---|
| 267 | !! ** input : Namelist nampisext |
|---|
| 268 | !!---------------------------------------------------------------------- |
|---|
| 269 | NAMELIST/nampisext/ln_co2int, atcco2, clname, nn_offset |
|---|
| 270 | INTEGER :: jm |
|---|
| 271 | INTEGER :: ios ! Local integer output status for namelist read |
|---|
| 272 | !!---------------------------------------------------------------------- |
|---|
| 273 | ! |
|---|
| 274 | |
|---|
| 275 | REWIND( numnatp_ref ) ! Namelist nampisext in reference namelist : Pisces atm. conditions |
|---|
| 276 | READ ( numnatp_ref, nampisext, IOSTAT = ios, ERR = 901) |
|---|
| 277 | 901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampisext in reference namelist', lwp ) |
|---|
| 278 | |
|---|
| 279 | REWIND( numnatp_cfg ) ! Namelist nampisext in configuration namelist : Pisces atm. conditions |
|---|
| 280 | READ ( numnatp_cfg, nampisext, IOSTAT = ios, ERR = 902 ) |
|---|
| 281 | 902 IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampisext in configuration namelist', lwp ) |
|---|
| 282 | IF(lwm) WRITE ( numonp, nampisext ) |
|---|
| 283 | ! |
|---|
| 284 | IF(lwp) THEN ! control print |
|---|
| 285 | WRITE(numout,*) ' ' |
|---|
| 286 | WRITE(numout,*) ' Namelist parameters for air-sea exchange, nampisext' |
|---|
| 287 | WRITE(numout,*) ' ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~' |
|---|
| 288 | WRITE(numout,*) ' Choice for reading in the atm pCO2 file or constant value, ln_co2int =', ln_co2int |
|---|
| 289 | WRITE(numout,*) ' ' |
|---|
| 290 | ENDIF |
|---|
| 291 | IF( .NOT.ln_co2int ) THEN |
|---|
| 292 | IF(lwp) THEN ! control print |
|---|
| 293 | WRITE(numout,*) ' Constant Atmospheric pCO2 value atcco2 =', atcco2 |
|---|
| 294 | WRITE(numout,*) ' ' |
|---|
| 295 | ENDIF |
|---|
| 296 | satmco2(:,:) = atcco2 ! Initialisation of atmospheric pco2 |
|---|
| 297 | ELSE |
|---|
| 298 | IF(lwp) THEN |
|---|
| 299 | WRITE(numout,*) ' Atmospheric pCO2 value from file clname =', TRIM( clname ) |
|---|
| 300 | WRITE(numout,*) ' Offset model-data start year nn_offset =', nn_offset |
|---|
| 301 | WRITE(numout,*) ' ' |
|---|
| 302 | ENDIF |
|---|
| 303 | CALL ctl_opn( numco2, TRIM( clname) , 'OLD', 'FORMATTED', 'SEQUENTIAL', -1 , numout, lwp ) |
|---|
| 304 | jm = 0 ! Count the number of record in co2 file |
|---|
| 305 | DO |
|---|
| 306 | READ(numco2,*,END=100) |
|---|
| 307 | jm = jm + 1 |
|---|
| 308 | END DO |
|---|
| 309 | 100 nmaxrec = jm - 1 |
|---|
| 310 | ALLOCATE( years (nmaxrec) ) ; years (:) = 0._wp |
|---|
| 311 | ALLOCATE( atcco2h(nmaxrec) ) ; atcco2h(:) = 0._wp |
|---|
| 312 | |
|---|
| 313 | REWIND(numco2) |
|---|
| 314 | DO jm = 1, nmaxrec ! get xCO2 data |
|---|
| 315 | READ(numco2, *) years(jm), atcco2h(jm) |
|---|
| 316 | IF(lwp) WRITE(numout, '(f6.0,f7.2)') years(jm), atcco2h(jm) |
|---|
| 317 | END DO |
|---|
| 318 | CLOSE(numco2) |
|---|
| 319 | ENDIF |
|---|
| 320 | ! |
|---|
| 321 | oce_co2(:,:) = 0._wp ! Initialization of Flux of Carbon |
|---|
| 322 | t_oce_co2_flx = 0._wp |
|---|
| 323 | t_atm_co2_flx = 0._wp |
|---|
| 324 | ! |
|---|
| 325 | CALL p4z_patm( nit000 ) |
|---|
| 326 | ! |
|---|
| 327 | END SUBROUTINE p4z_flx_init |
|---|
| 328 | |
|---|
| 329 | SUBROUTINE p4z_patm( kt ) |
|---|
| 330 | |
|---|
| 331 | !!---------------------------------------------------------------------- |
|---|
| 332 | !! *** ROUTINE p4z_atm *** |
|---|
| 333 | !! |
|---|
| 334 | !! ** Purpose : Read and interpolate the external atmospheric sea-levl pressure |
|---|
| 335 | !! ** Method : Read the files and interpolate the appropriate variables |
|---|
| 336 | !! |
|---|
| 337 | !!---------------------------------------------------------------------- |
|---|
| 338 | !! * arguments |
|---|
| 339 | INTEGER, INTENT( in ) :: kt ! ocean time step |
|---|
| 340 | ! |
|---|
| 341 | INTEGER :: ierr |
|---|
| 342 | INTEGER :: ios ! Local integer output status for namelist read |
|---|
| 343 | CHARACTER(len=100) :: cn_dir ! Root directory for location of ssr files |
|---|
| 344 | TYPE(FLD_N) :: sn_patm ! informations about the fields to be read |
|---|
| 345 | !! |
|---|
| 346 | NAMELIST/nampisatm/ ln_presatm, sn_patm, cn_dir |
|---|
| 347 | |
|---|
| 348 | ! ! ----------------------- ! |
|---|
| 349 | IF( kt == nit000 ) THEN ! First call kt=nittrc000 ! |
|---|
| 350 | |
|---|
| 351 | REWIND( numnatp_ref ) ! Namelist nampisatm in reference namelist : Pisces atm. sea level pressure file |
|---|
| 352 | READ ( numnatp_ref, nampisatm, IOSTAT = ios, ERR = 901) |
|---|
| 353 | 901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampisatm in reference namelist', lwp ) |
|---|
| 354 | |
|---|
| 355 | REWIND( numnatp_cfg ) ! Namelist nampisatm in configuration namelist : Pisces atm. sea level pressure file |
|---|
| 356 | READ ( numnatp_cfg, nampisatm, IOSTAT = ios, ERR = 902 ) |
|---|
| 357 | 902 IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampisatm in configuration namelist', lwp ) |
|---|
| 358 | IF(lwm) WRITE ( numonp, nampisatm ) |
|---|
| 359 | ! |
|---|
| 360 | ! |
|---|
| 361 | IF(lwp) THEN !* control print |
|---|
| 362 | WRITE(numout,*) |
|---|
| 363 | WRITE(numout,*) ' Namelist nampisatm : Atmospheric Pressure as external forcing' |
|---|
| 364 | WRITE(numout,*) ' constant atmopsheric pressure (F) or from a file (T) ln_presatm = ', ln_presatm |
|---|
| 365 | WRITE(numout,*) |
|---|
| 366 | ENDIF |
|---|
| 367 | ! |
|---|
| 368 | IF( ln_presatm ) THEN |
|---|
| 369 | ALLOCATE( sf_patm(1), STAT=ierr ) !* allocate and fill sf_patm (forcing structure) with sn_patm |
|---|
| 370 | IF( ierr > 0 ) CALL ctl_stop( 'STOP', 'p4z_flx: unable to allocate sf_patm structure' ) |
|---|
| 371 | ! |
|---|
| 372 | CALL fld_fill( sf_patm, (/ sn_patm /), cn_dir, 'p4z_flx', 'Atmospheric pressure ', 'nampisatm' ) |
|---|
| 373 | ALLOCATE( sf_patm(1)%fnow(jpi,jpj,1) ) |
|---|
| 374 | IF( sn_patm%ln_tint ) ALLOCATE( sf_patm(1)%fdta(jpi,jpj,1,2) ) |
|---|
| 375 | ENDIF |
|---|
| 376 | ! |
|---|
| 377 | IF( .NOT.ln_presatm ) patm(:,:) = 1.e0 ! Initialize patm if no reading from a file |
|---|
| 378 | ! |
|---|
| 379 | ENDIF |
|---|
| 380 | ! |
|---|
| 381 | IF( ln_presatm ) THEN |
|---|
| 382 | CALL fld_read( kt, 1, sf_patm ) !* input Patm provided at kt + 1/2 |
|---|
| 383 | patm(:,:) = sf_patm(1)%fnow(:,:,1) ! atmospheric pressure |
|---|
| 384 | ENDIF |
|---|
| 385 | ! |
|---|
| 386 | END SUBROUTINE p4z_patm |
|---|
| 387 | |
|---|
| 388 | INTEGER FUNCTION p4z_flx_alloc() |
|---|
| 389 | !!---------------------------------------------------------------------- |
|---|
| 390 | !! *** ROUTINE p4z_flx_alloc *** |
|---|
| 391 | !!---------------------------------------------------------------------- |
|---|
| 392 | ALLOCATE( oce_co2(jpi,jpj), satmco2(jpi,jpj), patm(jpi,jpj), STAT=p4z_flx_alloc ) |
|---|
| 393 | ! |
|---|
| 394 | IF( p4z_flx_alloc /= 0 ) CALL ctl_warn('p4z_flx_alloc : failed to allocate arrays') |
|---|
| 395 | ! |
|---|
| 396 | END FUNCTION p4z_flx_alloc |
|---|
| 397 | |
|---|
| 398 | #else |
|---|
| 399 | !!====================================================================== |
|---|
| 400 | !! Dummy module : No PISCES bio-model |
|---|
| 401 | !!====================================================================== |
|---|
| 402 | CONTAINS |
|---|
| 403 | SUBROUTINE p4z_flx( kt ) ! Empty routine |
|---|
| 404 | INTEGER, INTENT( in ) :: kt |
|---|
| 405 | WRITE(*,*) 'p4z_flx: You should not have seen this print! error?', kt |
|---|
| 406 | END SUBROUTINE p4z_flx |
|---|
| 407 | #endif |
|---|
| 408 | |
|---|
| 409 | !!====================================================================== |
|---|
| 410 | END MODULE p4zflx |
|---|
