New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
sbcfwb.F90 in branches/UKMO/dev_r5021_nn_etau_revision/NEMOGCM/NEMO/OPA_SRC/SBC – NEMO

source: branches/UKMO/dev_r5021_nn_etau_revision/NEMOGCM/NEMO/OPA_SRC/SBC/sbcfwb.F90 @ 5239

Last change on this file since 5239 was 5239, checked in by davestorkey, 9 years ago

Commit changes to UKMO nn_etau revision branch (including clearing
SVN keywords).

File size: 11.5 KB
Line 
1MODULE sbcfwb
2   !!======================================================================
3   !!                       ***  MODULE  sbcfwb  ***
4   !! Ocean fluxes   : domain averaged freshwater budget
5   !!======================================================================
6   !! History :  OPA  ! 2001-02  (E. Durand)  Original code
7   !!   NEMO     1.0  ! 2002-06  (G. Madec)  F90: Free form and module
8   !!            3.0  ! 2006-08  (G. Madec)  Surface module
9   !!            3.2  ! 2009-07  (C. Talandier) emp mean s spread over erp area
10   !!----------------------------------------------------------------------
11
12   !!----------------------------------------------------------------------
13   !!   sbc_fwb      : freshwater budget for global ocean configurations
14   !!                  in free surface and forced mode
15   !!----------------------------------------------------------------------
16   USE oce             ! ocean dynamics and tracers
17   USE dom_oce         ! ocean space and time domain
18   USE sbc_oce         ! surface ocean boundary condition
19   USE phycst          ! physical constants
20   USE sbcrnf          ! ocean runoffs
21   USE sbcisf          ! ice shelf melting contribution
22   USE sbcssr          ! SS damping terms
23   USE in_out_manager  ! I/O manager
24   USE lib_mpp         ! distribued memory computing library
25   USE wrk_nemo        ! work arrays
26   USE timing          ! Timing
27   USE lbclnk          ! ocean lateral boundary conditions
28   USE lib_fortran
29
30   IMPLICIT NONE
31   PRIVATE
32
33   PUBLIC   sbc_fwb    ! routine called by step
34
35   REAL(wp) ::   a_fwb_b   ! annual domain averaged freshwater budget
36   REAL(wp) ::   a_fwb     ! for 2 year before (_b) and before year.
37   REAL(wp) ::   fwfold    ! fwfold to be suppressed
38   REAL(wp) ::   area      ! global mean ocean surface (interior domain)
39
40   !! * Substitutions
41#  include "domzgr_substitute.h90"
42#  include "vectopt_loop_substitute.h90"
43   !!----------------------------------------------------------------------
44   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
45   !! $Id$
46   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
47   !!----------------------------------------------------------------------
48CONTAINS
49
50   SUBROUTINE sbc_fwb( kt, kn_fwb, kn_fsbc )
51      !!---------------------------------------------------------------------
52      !!                  ***  ROUTINE sbc_fwb  ***
53      !!
54      !! ** Purpose :   Control the mean sea surface drift
55      !!
56      !! ** Method  :   several ways  depending on kn_fwb
57      !!                =0 no control
58      !!                =1 global mean of emp set to zero at each nn_fsbc time step
59      !!                =2 annual global mean corrected from previous year
60      !!                =3 global mean of emp set to zero at each nn_fsbc time step
61      !!                   & spread out over erp area depending its sign
62      !! Note: if sea ice is embedded it is taken into account when computing the budget
63      !!----------------------------------------------------------------------
64      INTEGER, INTENT( in ) ::   kt       ! ocean time-step index
65      INTEGER, INTENT( in ) ::   kn_fsbc  !
66      INTEGER, INTENT( in ) ::   kn_fwb   ! ocean time-step index
67      !
68      INTEGER  ::   inum, ikty, iyear     ! local integers
69      REAL(wp) ::   z_fwf, z_fwf_nsrf, zsum_fwf, zsum_erp                ! local scalars
70      REAL(wp) ::   zsurf_neg, zsurf_pos, zsurf_tospread, zcoef          !   -      -
71      REAL(wp), POINTER, DIMENSION(:,:) ::   ztmsk_neg, ztmsk_pos, z_wgt ! 2D workspaces
72      REAL(wp), POINTER, DIMENSION(:,:) ::   ztmsk_tospread, zerp_cor    !   -      -
73      !!----------------------------------------------------------------------
74      !
75      IF( nn_timing == 1 )  CALL timing_start('sbc_fwb')
76      !
77      CALL wrk_alloc( jpi,jpj, ztmsk_neg, ztmsk_pos, ztmsk_tospread, z_wgt, zerp_cor )
78      !
79      IF( kt == nit000 ) THEN
80         IF(lwp) THEN
81            WRITE(numout,*)
82            WRITE(numout,*) 'sbc_fwb : FreshWater Budget correction'
83            WRITE(numout,*) '~~~~~~~'
84            IF( kn_fwb == 1 )   WRITE(numout,*) '          instantaneously set to zero'
85            IF( kn_fwb == 2 )   WRITE(numout,*) '          adjusted from previous year budget'
86            IF( kn_fwb == 3 )   WRITE(numout,*) '          fwf set to zero and spread out over erp area'
87         ENDIF
88         !
89         IF( kn_fwb == 3 .AND. nn_sssr /= 2 )   CALL ctl_stop( 'sbc_fwb: nn_fwb = 3 requires nn_sssr = 2, we stop ' )
90         !
91         area = glob_sum( e1e2t(:,:) )           ! interior global domain surface
92         !
93#if ! defined key_lim2 &&  ! defined key_lim3 && ! defined key_cice
94         snwice_mass_b(:,:) = 0.e0               ! no sea-ice model is being used : no snow+ice mass
95         snwice_mass  (:,:) = 0.e0
96#endif
97         !
98      ENDIF
99     
100
101      SELECT CASE ( kn_fwb )
102      !
103      CASE ( 1 )                             !==  global mean fwf set to zero  ==!
104         !
105         IF( MOD( kt-1, kn_fsbc ) == 0 ) THEN
106            z_fwf = glob_sum( e1e2t(:,:) * ( emp(:,:) - rnf(:,:) + rdivisf * fwfisf(:,:) -  snwice_fmass(:,:) ) ) / area   ! sum over the global domain
107            zcoef = z_fwf * rcp
108            emp(:,:) = emp(:,:) - z_fwf 
109            qns(:,:) = qns(:,:) + zcoef * sst_m(:,:)  ! account for change to the heat budget due to fw correction
110         ENDIF
111         !
112      CASE ( 2 )                             !==  fwf budget adjusted from the previous year  ==!
113         !
114         IF( kt == nit000 ) THEN                      ! initialisation
115            !                                         ! Read the corrective factor on precipitations (fwfold)
116            CALL ctl_opn( inum, 'EMPave_old.dat', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, numout, .FALSE. )
117            READ ( inum, "(24X,I8,2ES24.16)" ) iyear, a_fwb_b, a_fwb
118            CLOSE( inum )
119            fwfold = a_fwb                            ! current year freshwater budget correction
120            !                                         ! estimate from the previous year budget
121            IF(lwp)WRITE(numout,*)
122            IF(lwp)WRITE(numout,*)'sbc_fwb : year = ',iyear  , ' freshwater budget correction = ', fwfold
123            IF(lwp)WRITE(numout,*)'          year = ',iyear-1, ' freshwater budget read       = ', a_fwb
124            IF(lwp)WRITE(numout,*)'          year = ',iyear-2, ' freshwater budget read       = ', a_fwb_b
125         ENDIF   
126         !                                         ! Update fwfold if new year start
127         ikty = 365 * 86400 / rdttra(1)    !!bug  use of 365 days leap year or 360d year !!!!!!!
128         IF( MOD( kt, ikty ) == 0 ) THEN
129            a_fwb_b = a_fwb                           ! mean sea level taking into account the ice+snow
130                                                      ! sum over the global domain
131            a_fwb   = glob_sum( e1e2t(:,:) * ( sshn(:,:) + snwice_mass(:,:) * r1_rau0 ) )
132            a_fwb   = a_fwb * 1.e+3 / ( area * rday * 365. )     ! convert in Kg/m3/s = mm/s
133!!gm        !                                                      !!bug 365d year
134            fwfold =  a_fwb                           ! current year freshwater budget correction
135            !                                         ! estimate from the previous year budget
136         ENDIF
137         !
138         IF( MOD( kt-1, kn_fsbc ) == 0 ) THEN         ! correct the freshwater fluxes
139            zcoef = fwfold * rcp
140            emp(:,:) = emp(:,:) + fwfold
141            qns(:,:) = qns(:,:) - zcoef * sst_m(:,:)  ! account for change to the heat budget due to fw correction
142         ENDIF
143         !
144         IF( kt == nitend .AND. lwp ) THEN            ! save fwfold value in a file
145            CALL ctl_opn( inum, 'EMPave.dat', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, numout, .FALSE., narea )
146            WRITE( inum, "(24X,I8,2ES24.16)" ) nyear, a_fwb_b, a_fwb
147            CLOSE( inum )
148         ENDIF
149         !
150      CASE ( 3 )                             !==  global fwf set to zero and spread out over erp area  ==!
151         !
152         IF( MOD( kt-1, kn_fsbc ) == 0 ) THEN
153            ztmsk_pos(:,:) = tmask_i(:,:)                      ! Select <0 and >0 area of erp
154            WHERE( erp < 0._wp )   ztmsk_pos = 0._wp
155            ztmsk_neg(:,:) = tmask_i(:,:) - ztmsk_pos(:,:)
156            !
157            zsurf_neg = glob_sum( e1e2t(:,:)*ztmsk_neg(:,:) )  ! Area filled by <0 and >0 erp
158            zsurf_pos = glob_sum( e1e2t(:,:)*ztmsk_pos(:,:) )
159            !                                                  ! fwf global mean (excluding ocean to ice/snow exchanges)
160            z_fwf     = glob_sum( e1e2t(:,:) * ( emp(:,:) - rnf(:,:) - snwice_fmass(:,:) ) ) / area
161            !           
162            IF( z_fwf < 0._wp ) THEN         ! spread out over >0 erp area to increase evaporation
163                zsurf_tospread      = zsurf_pos
164                ztmsk_tospread(:,:) = ztmsk_pos(:,:)
165            ELSE                             ! spread out over <0 erp area to increase precipitation
166                zsurf_tospread      = zsurf_neg
167                ztmsk_tospread(:,:) = ztmsk_neg(:,:)
168            ENDIF
169            !
170            zsum_fwf   = glob_sum( e1e2t(:,:) * z_fwf )         ! fwf global mean over <0 or >0 erp area
171!!gm :  zsum_fwf   = z_fwf * area   ???  it is right?  I think so....
172            z_fwf_nsrf =  zsum_fwf / ( zsurf_tospread + rsmall )
173            !                                                  ! weight to respect erp field 2D structure
174            zsum_erp   = glob_sum( ztmsk_tospread(:,:) * erp(:,:) * e1e2t(:,:) )
175            z_wgt(:,:) = ztmsk_tospread(:,:) * erp(:,:) / ( zsum_erp + rsmall )
176            !                                                  ! final correction term to apply
177            zerp_cor(:,:) = -1. * z_fwf_nsrf * zsurf_tospread * z_wgt(:,:)
178            !
179!!gm   ===>>>>  lbc_lnk should be useless as all the computation is done over the whole domain !
180            CALL lbc_lnk( zerp_cor, 'T', 1. )
181            !
182            emp(:,:) = emp(:,:) + zerp_cor(:,:)
183            qns(:,:) = qns(:,:) - zerp_cor(:,:) * rcp * sst_m(:,:)  ! account for change to the heat budget due to fw correction
184            erp(:,:) = erp(:,:) + zerp_cor(:,:)
185            !
186            IF( nprint == 1 .AND. lwp ) THEN                   ! control print
187               IF( z_fwf < 0._wp ) THEN
188                  WRITE(numout,*)'   z_fwf < 0'
189                  WRITE(numout,*)'   SUM(erp+)     = ', SUM( ztmsk_tospread(:,:)*erp(:,:)*e1e2t(:,:) )*1.e-9,' Sv'
190               ELSE
191                  WRITE(numout,*)'   z_fwf >= 0'
192                  WRITE(numout,*)'   SUM(erp-)     = ', SUM( ztmsk_tospread(:,:)*erp(:,:)*e1e2t(:,:) )*1.e-9,' Sv'
193               ENDIF
194               WRITE(numout,*)'   SUM(empG)     = ', SUM( z_fwf*e1e2t(:,:) )*1.e-9,' Sv'
195               WRITE(numout,*)'   z_fwf         = ', z_fwf      ,' Kg/m2/s'
196               WRITE(numout,*)'   z_fwf_nsrf    = ', z_fwf_nsrf ,' Kg/m2/s'
197               WRITE(numout,*)'   MIN(zerp_cor) = ', MINVAL(zerp_cor) 
198               WRITE(numout,*)'   MAX(zerp_cor) = ', MAXVAL(zerp_cor) 
199            ENDIF
200         ENDIF
201         !
202      CASE DEFAULT                           !==  you should never be there  ==!
203         CALL ctl_stop( 'sbc_fwb : wrong nn_fwb value for the FreshWater Budget correction, choose either 1, 2 or 3' )
204         !
205      END SELECT
206      !
207      CALL wrk_dealloc( jpi,jpj, ztmsk_neg, ztmsk_pos, ztmsk_tospread, z_wgt, zerp_cor )
208      !
209      IF( nn_timing == 1 )  CALL timing_stop('sbc_fwb')
210      !
211   END SUBROUTINE sbc_fwb
212
213   !!======================================================================
214END MODULE sbcfwb
Note: See TracBrowser for help on using the repository browser.