source: branches/UKMO/dev_r5518_GO6_package/NEMOGCM/NEMO/OPA_SRC/DYN/dynhpg.F90 @ 8400

Last change on this file since 8400 was 8400, checked in by timgraham, 3 years ago

GMED ticket 335:

  • Merge dev_r5518_GO6_package_inc_asm into package branch to make everything easier for data assimilation
  • No effect on configs without data assimilation
File size: 71.2 KB
Line 
1MODULE dynhpg
2   !!======================================================================
3   !!                       ***  MODULE  dynhpg  ***
4   !! Ocean dynamics:  hydrostatic pressure gradient trend
5   !!======================================================================
6   !! History :  OPA  !  1987-09  (P. Andrich, M.-A. Foujols)  hpg_zco: Original code
7   !!            5.0  !  1991-11  (G. Madec)
8   !!            7.0  !  1996-01  (G. Madec)  hpg_sco: Original code for s-coordinates
9   !!            8.0  !  1997-05  (G. Madec)  split dynber into dynkeg and dynhpg
10   !!            8.5  !  2002-07  (G. Madec)  F90: Free form and module
11   !!            8.5  !  2002-08  (A. Bozec)  hpg_zps: Original code
12   !!   NEMO     1.0  !  2005-10  (A. Beckmann, B.W. An)  various s-coordinate options
13   !!                 !         Original code for hpg_ctl, hpg_hel hpg_wdj, hpg_djc, hpg_rot
14   !!             -   !  2005-11  (G. Madec) style & small optimisation
15   !!            3.3  !  2010-10  (C. Ethe, G. Madec) reorganisation of initialisation phase
16   !!            3.4  !  2011-11  (H. Liu) hpg_prj: Original code for s-coordinates
17   !!                 !           (A. Coward) suppression of hel, wdj and rot options
18   !!            3.6  !  2014-11  (P. Mathiot) hpg_isf: original code for ice shelf cavity
19   !!----------------------------------------------------------------------
20
21   !!----------------------------------------------------------------------
22   !!   dyn_hpg      : update the momentum trend with the now horizontal
23   !!                  gradient of the hydrostatic pressure
24   !!   dyn_hpg_init : initialisation and control of options
25   !!       hpg_zco  : z-coordinate scheme
26   !!       hpg_zps  : z-coordinate plus partial steps (interpolation)
27   !!       hpg_sco  : s-coordinate (standard jacobian formulation)
28   !!       hpg_isf  : s-coordinate (sco formulation) adapted to ice shelf
29   !!       hpg_djc  : s-coordinate (Density Jacobian with Cubic polynomial)
30   !!       hpg_prj  : s-coordinate (Pressure Jacobian with Cubic polynomial)
31   !!----------------------------------------------------------------------
32   USE oce             ! ocean dynamics and tracers
33   USE sbc_oce         ! surface variable (only for the flag with ice shelf)
34   USE dom_oce         ! ocean space and time domain
35   USE phycst          ! physical constants
36   USE trd_oce         ! trends: ocean variables
37   USE trddyn          ! trend manager: dynamics
38   !
39   USE in_out_manager  ! I/O manager
40   USE prtctl          ! Print control
41   USE lbclnk          ! lateral boundary condition
42   USE lib_mpp         ! MPP library
43   USE eosbn2          ! compute density
44   USE wrk_nemo        ! Memory Allocation
45   USE timing          ! Timing
46   USE biaspar         ! bias correction variables
47
48   IMPLICIT NONE
49   PRIVATE
50
51   PUBLIC   dyn_hpg        ! routine called by step module
52   PUBLIC   dyn_hpg_init   ! routine called by opa module
53
54   !                                    !!* Namelist namdyn_hpg : hydrostatic pressure gradient
55   LOGICAL , PUBLIC ::   ln_hpg_zco      !: z-coordinate - full steps
56   LOGICAL , PUBLIC ::   ln_hpg_zps      !: z-coordinate - partial steps (interpolation)
57   LOGICAL , PUBLIC ::   ln_hpg_sco      !: s-coordinate (standard jacobian formulation)
58   LOGICAL , PUBLIC ::   ln_hpg_djc      !: s-coordinate (Density Jacobian with Cubic polynomial)
59   LOGICAL , PUBLIC ::   ln_hpg_prj      !: s-coordinate (Pressure Jacobian scheme)
60   LOGICAL , PUBLIC ::   ln_hpg_isf      !: s-coordinate similar to sco modify for isf
61   LOGICAL , PUBLIC ::   ln_dynhpg_imp   !: semi-implicite hpg flag
62
63   INTEGER , PUBLIC ::   nhpg  =  0   ! = 0 to 7, type of pressure gradient scheme used ! (deduced from ln_hpg_... flags) (PUBLIC for TAM)
64
65   !! * Substitutions
66#  include "domzgr_substitute.h90"
67#  include "vectopt_loop_substitute.h90"
68   !!----------------------------------------------------------------------
69   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
70   !! $Id$
71   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
72   !!----------------------------------------------------------------------
73CONTAINS
74
75   SUBROUTINE dyn_hpg( kt )
76      !!---------------------------------------------------------------------
77      !!                  ***  ROUTINE dyn_hpg  ***
78      !!
79      !! ** Method  :   Call the hydrostatic pressure gradient routine
80      !!              using the scheme defined in the namelist
81      !!
82      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
83      !!             - send trends to trd_dyn for futher diagnostics (l_trddyn=T)
84      !!----------------------------------------------------------------------
85      INTEGER, INTENT(in) ::   kt   ! ocean time-step index
86      REAL(wp), POINTER, DIMENSION(:,:,:) ::  ztrdu, ztrdv
87      REAL(wp), ALLOCATABLE, DIMENSION(:,:,:)   ::   z_rhd_st  ! tmp density storage for pressure corr
88      REAL(wp), ALLOCATABLE, DIMENSION(:,:)     ::   z_gru_st  ! tmp ua trends storage for pressure corr
89      REAL(wp), ALLOCATABLE, DIMENSION(:,:)     ::   z_grv_st  ! tmp va trends storage for pressure corr
90      !!----------------------------------------------------------------------
91      !
92      IF( nn_timing == 1 )  CALL timing_start('dyn_hpg')
93      !
94      IF( l_trddyn ) THEN                    ! Temporary saving of ua and va trends (l_trddyn)
95         CALL wrk_alloc( jpi,jpj,jpk, ztrdu, ztrdv )
96         ztrdu(:,:,:) = ua(:,:,:)
97         ztrdv(:,:,:) = va(:,:,:)
98      ENDIF
99      !
100      IF ( ln_bias .AND. ln_bias_pc_app ) THEN
101
102         !Allocate space for tempory variables
103         ALLOCATE( z_rhd_st(jpi,jpj,jpk), &
104            &      z_gru_st(jpi,jpj),     &
105            &      z_grv_st(jpi,jpj)      )
106
107         z_rhd_st(:,:,:) = rhd(:,:,:)     ! store orig density
108         rhd(:,:,:)      = rhd_pc(:,:,:)  ! use pressure corrected density
109         z_gru_st(:,:)   = gru(:,:)
110         gru(:,:)        = gru_pc(:,:)
111         z_grv_st(:,:)   = grv(:,:)
112         grv(:,:)        = grv_pc(:,:)
113
114      ENDIF
115      !
116      SELECT CASE ( nhpg )      ! Hydrostatic pressure gradient computation
117      CASE (  0 )   ;   CALL hpg_zco    ( kt )      ! z-coordinate
118      CASE (  1 )   ;   CALL hpg_zps    ( kt )      ! z-coordinate plus partial steps (interpolation)
119      CASE (  2 )   ;   CALL hpg_sco    ( kt )      ! s-coordinate (standard jacobian formulation)
120      CASE (  3 )   ;   CALL hpg_djc    ( kt )      ! s-coordinate (Density Jacobian with Cubic polynomial)
121      CASE (  4 )   ;   CALL hpg_prj    ( kt )      ! s-coordinate (Pressure Jacobian scheme)
122      CASE (  5 )   ;   CALL hpg_isf    ( kt )      ! s-coordinate similar to sco modify for ice shelf
123      END SELECT
124      !
125      IF( l_trddyn ) THEN      ! save the hydrostatic pressure gradient trends for momentum trend diagnostics
126         ztrdu(:,:,:) = ua(:,:,:) - ztrdu(:,:,:)
127         ztrdv(:,:,:) = va(:,:,:) - ztrdv(:,:,:)
128         CALL trd_dyn( ztrdu, ztrdv, jpdyn_hpg, kt )
129         CALL wrk_dealloc( jpi,jpj,jpk, ztrdu, ztrdv )
130      ENDIF
131      !
132      IF(ln_ctl)   CALL prt_ctl( tab3d_1=ua, clinfo1=' hpg  - Ua: ', mask1=umask,   &
133         &                       tab3d_2=va, clinfo2=       ' Va: ', mask2=vmask, clinfo3='dyn' )
134      !
135      IF ( ln_bias .AND. ln_bias_pc_app )  THEN
136         rhd(:,:,:) = z_rhd_st(:,:,:)     ! restore original density
137         gru(:,:)   = z_gru_st(:,:)
138         grv(:,:)   = z_grv_st(:,:)
139
140         !Deallocate tempory variables
141         DEALLOCATE( z_rhd_st,     &
142            &        z_gru_st,     &
143            &        z_grv_st      )
144      ENDIF
145      !
146      IF( nn_timing == 1 )  CALL timing_stop('dyn_hpg')
147      !
148   END SUBROUTINE dyn_hpg
149
150
151   SUBROUTINE dyn_hpg_init
152      !!----------------------------------------------------------------------
153      !!                 ***  ROUTINE dyn_hpg_init  ***
154      !!
155      !! ** Purpose :   initializations for the hydrostatic pressure gradient
156      !!              computation and consistency control
157      !!
158      !! ** Action  :   Read the namelist namdyn_hpg and check the consistency
159      !!      with the type of vertical coordinate used (zco, zps, sco)
160      !!----------------------------------------------------------------------
161      INTEGER ::   ioptio = 0      ! temporary integer
162      INTEGER ::   ios             ! Local integer output status for namelist read
163      !!
164      NAMELIST/namdyn_hpg/ ln_hpg_zco, ln_hpg_zps, ln_hpg_sco,     &
165         &                 ln_hpg_djc, ln_hpg_prj, ln_hpg_isf, ln_dynhpg_imp
166      !!----------------------------------------------------------------------
167      !
168      REWIND( numnam_ref )              ! Namelist namdyn_hpg in reference namelist : Hydrostatic pressure gradient
169      READ  ( numnam_ref, namdyn_hpg, IOSTAT = ios, ERR = 901)
170901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namdyn_hpg in reference namelist', lwp )
171
172      REWIND( numnam_cfg )              ! Namelist namdyn_hpg in configuration namelist : Hydrostatic pressure gradient
173      READ  ( numnam_cfg, namdyn_hpg, IOSTAT = ios, ERR = 902 )
174902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namdyn_hpg in configuration namelist', lwp )
175      IF(lwm) WRITE ( numond, namdyn_hpg )
176      !
177      IF(lwp) THEN                   ! Control print
178         WRITE(numout,*)
179         WRITE(numout,*) 'dyn_hpg_init : hydrostatic pressure gradient initialisation'
180         WRITE(numout,*) '~~~~~~~~~~~~'
181         WRITE(numout,*) '   Namelist namdyn_hpg : choice of hpg scheme'
182         WRITE(numout,*) '      z-coord. - full steps                             ln_hpg_zco    = ', ln_hpg_zco
183         WRITE(numout,*) '      z-coord. - partial steps (interpolation)          ln_hpg_zps    = ', ln_hpg_zps
184         WRITE(numout,*) '      s-coord. (standard jacobian formulation)          ln_hpg_sco    = ', ln_hpg_sco
185         WRITE(numout,*) '      s-coord. (standard jacobian formulation) for isf  ln_hpg_isf    = ', ln_hpg_isf
186         WRITE(numout,*) '      s-coord. (Density Jacobian: Cubic polynomial)     ln_hpg_djc    = ', ln_hpg_djc
187         WRITE(numout,*) '      s-coord. (Pressure Jacobian: Cubic polynomial)    ln_hpg_prj    = ', ln_hpg_prj
188         WRITE(numout,*) '      time stepping: centered (F) or semi-implicit (T)  ln_dynhpg_imp = ', ln_dynhpg_imp
189      ENDIF
190      !
191      IF( ln_hpg_djc )   &
192         &   CALL ctl_stop('dyn_hpg_init : Density Jacobian: Cubic polynominal method &
193                           & currently disabled (bugs under investigation). Please select &
194                           & either  ln_hpg_sco or  ln_hpg_prj instead')
195      !
196      IF( lk_vvl .AND. .NOT. (ln_hpg_sco.OR.ln_hpg_prj.OR.ln_hpg_isf) )   &
197         &   CALL ctl_stop('dyn_hpg_init : variable volume key_vvl requires:&
198                           & the standard jacobian formulation hpg_sco or &
199                           & the pressure jacobian formulation hpg_prj')
200
201      IF(       ln_hpg_isf .AND. .NOT. ln_isfcav )   &
202         &   CALL ctl_stop( ' hpg_isf not available if ln_isfcav = false ' )
203      IF( .NOT. ln_hpg_isf .AND.       ln_isfcav )   &
204         &   CALL ctl_stop( 'Only hpg_isf has been corrected to work with ice shelf cavity.' )
205      !
206      !                               ! Set nhpg from ln_hpg_... flags
207      IF( ln_hpg_zco )   nhpg = 0
208      IF( ln_hpg_zps )   nhpg = 1
209      IF( ln_hpg_sco )   nhpg = 2
210      IF( ln_hpg_djc )   nhpg = 3
211      IF( ln_hpg_prj )   nhpg = 4
212      IF( ln_hpg_isf )   nhpg = 5
213      !
214      !                               ! Consistency check
215      ioptio = 0
216      IF( ln_hpg_zco )   ioptio = ioptio + 1
217      IF( ln_hpg_zps )   ioptio = ioptio + 1
218      IF( ln_hpg_sco )   ioptio = ioptio + 1
219      IF( ln_hpg_djc )   ioptio = ioptio + 1
220      IF( ln_hpg_prj )   ioptio = ioptio + 1
221      IF( ln_hpg_isf )   ioptio = ioptio + 1
222      IF( ioptio /= 1 )   CALL ctl_stop( 'NO or several hydrostatic pressure gradient options used' )
223      !
224      ! initialisation of ice load
225      riceload(:,:)=0.0
226      !
227   END SUBROUTINE dyn_hpg_init
228
229
230   SUBROUTINE hpg_zco( kt )
231      !!---------------------------------------------------------------------
232      !!                  ***  ROUTINE hpg_zco  ***
233      !!
234      !! ** Method  :   z-coordinate case, levels are horizontal surfaces.
235      !!      The now hydrostatic pressure gradient at a given level, jk,
236      !!      is computed by taking the vertical integral of the in-situ
237      !!      density gradient along the model level from the suface to that
238      !!      level:    zhpi = grav .....
239      !!                zhpj = grav .....
240      !!      add it to the general momentum trend (ua,va).
241      !!            ua = ua - 1/e1u * zhpi
242      !!            va = va - 1/e2v * zhpj
243      !!
244      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
245      !!----------------------------------------------------------------------
246      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
247      !!
248      INTEGER  ::   ji, jj, jk       ! dummy loop indices
249      REAL(wp) ::   zcoef0, zcoef1   ! temporary scalars
250      REAL(wp), POINTER, DIMENSION(:,:,:) ::  zhpi, zhpj
251      !!----------------------------------------------------------------------
252      !
253      CALL wrk_alloc( jpi,jpj,jpk, zhpi, zhpj )
254      !
255      IF( kt == nit000 ) THEN
256         IF(lwp) WRITE(numout,*)
257         IF(lwp) WRITE(numout,*) 'dyn:hpg_zco : hydrostatic pressure gradient trend'
258         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   z-coordinate case '
259      ENDIF
260
261      zcoef0 = - grav * 0.5_wp      ! Local constant initialization
262
263      ! Surface value
264      DO jj = 2, jpjm1
265         DO ji = fs_2, fs_jpim1   ! vector opt.
266            zcoef1 = zcoef0 * fse3w(ji,jj,1)
267            ! hydrostatic pressure gradient
268            zhpi(ji,jj,1) = zcoef1 * ( rhd(ji+1,jj,1) - rhd(ji,jj,1) ) / e1u(ji,jj)
269            zhpj(ji,jj,1) = zcoef1 * ( rhd(ji,jj+1,1) - rhd(ji,jj,1) ) / e2v(ji,jj)
270            ! add to the general momentum trend
271            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
272            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
273         END DO
274      END DO
275
276      !
277      ! interior value (2=<jk=<jpkm1)
278      DO jk = 2, jpkm1
279         DO jj = 2, jpjm1
280            DO ji = fs_2, fs_jpim1   ! vector opt.
281               zcoef1 = zcoef0 * fse3w(ji,jj,jk)
282               ! hydrostatic pressure gradient
283               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1)   &
284                  &           + zcoef1 * (  ( rhd(ji+1,jj,jk)+rhd(ji+1,jj,jk-1) )   &
285                  &                       - ( rhd(ji  ,jj,jk)+rhd(ji  ,jj,jk-1) )  ) / e1u(ji,jj)
286
287               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1)   &
288                  &           + zcoef1 * (  ( rhd(ji,jj+1,jk)+rhd(ji,jj+1,jk-1) )   &
289                  &                       - ( rhd(ji,jj,  jk)+rhd(ji,jj  ,jk-1) )  ) / e2v(ji,jj)
290               ! add to the general momentum trend
291               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
292               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
293            END DO
294         END DO
295      END DO
296      !
297      CALL wrk_dealloc( jpi,jpj,jpk, zhpi, zhpj )
298      !
299   END SUBROUTINE hpg_zco
300
301
302   SUBROUTINE hpg_zps( kt )
303      !!---------------------------------------------------------------------
304      !!                 ***  ROUTINE hpg_zps  ***
305      !!
306      !! ** Method  :   z-coordinate plus partial steps case.  blahblah...
307      !!
308      !! ** Action  : - Update (ua,va) with the now hydrastatic pressure trend
309      !!----------------------------------------------------------------------
310      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
311      !!
312      INTEGER  ::   ji, jj, jk                       ! dummy loop indices
313      INTEGER  ::   iku, ikv                         ! temporary integers
314      REAL(wp) ::   zcoef0, zcoef1, zcoef2, zcoef3   ! temporary scalars
315      REAL(wp), POINTER, DIMENSION(:,:,:) ::  zhpi, zhpj
316      !!----------------------------------------------------------------------
317      !
318      CALL wrk_alloc( jpi,jpj,jpk, zhpi, zhpj )
319      !
320      IF( kt == nit000 ) THEN
321         IF(lwp) WRITE(numout,*)
322         IF(lwp) WRITE(numout,*) 'dyn:hpg_zps : hydrostatic pressure gradient trend'
323         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   z-coordinate with partial steps - vector optimization'
324      ENDIF
325
326
327      ! Local constant initialization
328      zcoef0 = - grav * 0.5_wp
329
330      !  Surface value (also valid in partial step case)
331      DO jj = 2, jpjm1
332         DO ji = fs_2, fs_jpim1   ! vector opt.
333            zcoef1 = zcoef0 * fse3w(ji,jj,1)
334            ! hydrostatic pressure gradient
335            zhpi(ji,jj,1) = zcoef1 * ( rhd(ji+1,jj  ,1) - rhd(ji,jj,1) ) / e1u(ji,jj)
336            zhpj(ji,jj,1) = zcoef1 * ( rhd(ji  ,jj+1,1) - rhd(ji,jj,1) ) / e2v(ji,jj)
337            ! add to the general momentum trend
338            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
339            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
340         END DO
341      END DO
342
343
344      ! interior value (2=<jk=<jpkm1)
345      DO jk = 2, jpkm1
346         DO jj = 2, jpjm1
347            DO ji = fs_2, fs_jpim1   ! vector opt.
348               zcoef1 = zcoef0 * fse3w(ji,jj,jk)
349               ! hydrostatic pressure gradient
350               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1)   &
351                  &           + zcoef1 * (  ( rhd(ji+1,jj,jk) + rhd(ji+1,jj,jk-1) )   &
352                  &                       - ( rhd(ji  ,jj,jk) + rhd(ji  ,jj,jk-1) )  ) / e1u(ji,jj)
353
354               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1)   &
355                  &           + zcoef1 * (  ( rhd(ji,jj+1,jk) + rhd(ji,jj+1,jk-1) )   &
356                  &                       - ( rhd(ji,jj,  jk) + rhd(ji,jj  ,jk-1) )  ) / e2v(ji,jj)
357               ! add to the general momentum trend
358               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
359               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
360            END DO
361         END DO
362      END DO
363
364
365      ! partial steps correction at the last level  (use gru & grv computed in zpshde.F90)
366      DO jj = 2, jpjm1
367         DO ji = 2, jpim1
368            iku = mbku(ji,jj)
369            ikv = mbkv(ji,jj)
370            zcoef2 = zcoef0 * MIN( fse3w(ji,jj,iku), fse3w(ji+1,jj  ,iku) )
371            zcoef3 = zcoef0 * MIN( fse3w(ji,jj,ikv), fse3w(ji  ,jj+1,ikv) )
372            IF( iku > 1 ) THEN            ! on i-direction (level 2 or more)
373               ua  (ji,jj,iku) = ua(ji,jj,iku) - zhpi(ji,jj,iku)         ! subtract old value
374               zhpi(ji,jj,iku) = zhpi(ji,jj,iku-1)                   &   ! compute the new one
375                  &            + zcoef2 * ( rhd(ji+1,jj,iku-1) - rhd(ji,jj,iku-1) + gru(ji,jj) ) / e1u(ji,jj)
376               ua  (ji,jj,iku) = ua(ji,jj,iku) + zhpi(ji,jj,iku)         ! add the new one to the general momentum trend
377            ENDIF
378            IF( ikv > 1 ) THEN            ! on j-direction (level 2 or more)
379               va  (ji,jj,ikv) = va(ji,jj,ikv) - zhpj(ji,jj,ikv)         ! subtract old value
380               zhpj(ji,jj,ikv) = zhpj(ji,jj,ikv-1)                   &   ! compute the new one
381                  &            + zcoef3 * ( rhd(ji,jj+1,ikv-1) - rhd(ji,jj,ikv-1) + grv(ji,jj) ) / e2v(ji,jj)
382               va  (ji,jj,ikv) = va(ji,jj,ikv) + zhpj(ji,jj,ikv)         ! add the new one to the general momentum trend
383            ENDIF
384         END DO
385      END DO
386      !
387      CALL wrk_dealloc( jpi,jpj,jpk, zhpi, zhpj )
388      !
389   END SUBROUTINE hpg_zps
390
391   SUBROUTINE hpg_sco( kt )
392      !!---------------------------------------------------------------------
393      !!                  ***  ROUTINE hpg_sco  ***
394      !!
395      !! ** Method  :   s-coordinate case. Jacobian scheme.
396      !!      The now hydrostatic pressure gradient at a given level, jk,
397      !!      is computed by taking the vertical integral of the in-situ
398      !!      density gradient along the model level from the suface to that
399      !!      level. s-coordinates (ln_sco): a corrective term is added
400      !!      to the horizontal pressure gradient :
401      !!         zhpi = grav .....  + 1/e1u mi(rhd) di[ grav dep3w ]
402      !!         zhpj = grav .....  + 1/e2v mj(rhd) dj[ grav dep3w ]
403      !!      add it to the general momentum trend (ua,va).
404      !!         ua = ua - 1/e1u * zhpi
405      !!         va = va - 1/e2v * zhpj
406      !!
407      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
408      !!----------------------------------------------------------------------
409      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
410      !!
411      INTEGER  ::   ji, jj, jk                 ! dummy loop indices
412      REAL(wp) ::   zcoef0, zuap, zvap, znad   ! temporary scalars
413      REAL(wp), POINTER, DIMENSION(:,:,:) ::  zhpi, zhpj
414      !!----------------------------------------------------------------------
415      !
416      CALL wrk_alloc( jpi,jpj,jpk, zhpi, zhpj )
417      !
418      IF( kt == nit000 ) THEN
419         IF(lwp) WRITE(numout,*)
420         IF(lwp) WRITE(numout,*) 'dyn:hpg_sco : hydrostatic pressure gradient trend'
421         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, OPA original scheme used'
422      ENDIF
423
424      ! Local constant initialization
425      zcoef0 = - grav * 0.5_wp
426      ! To use density and not density anomaly
427      IF ( lk_vvl ) THEN   ;     znad = 1._wp          ! Variable volume
428      ELSE                 ;     znad = 0._wp         ! Fixed volume
429      ENDIF
430
431      ! Surface value
432      DO jj = 2, jpjm1
433         DO ji = fs_2, fs_jpim1   ! vector opt.
434            ! hydrostatic pressure gradient along s-surfaces
435            zhpi(ji,jj,1) = zcoef0 / e1u(ji,jj) * ( fse3w(ji+1,jj  ,1) * ( znad + rhd(ji+1,jj  ,1) )   &
436               &                                  - fse3w(ji  ,jj  ,1) * ( znad + rhd(ji  ,jj  ,1) ) )
437            zhpj(ji,jj,1) = zcoef0 / e2v(ji,jj) * ( fse3w(ji  ,jj+1,1) * ( znad + rhd(ji  ,jj+1,1) )   &
438               &                                  - fse3w(ji  ,jj  ,1) * ( znad + rhd(ji  ,jj  ,1) ) )
439            ! s-coordinate pressure gradient correction
440            zuap = -zcoef0 * ( rhd   (ji+1,jj,1) + rhd   (ji,jj,1) + 2._wp * znad )   &
441               &           * ( fsde3w(ji+1,jj,1) - fsde3w(ji,jj,1) ) / e1u(ji,jj)
442            zvap = -zcoef0 * ( rhd   (ji,jj+1,1) + rhd   (ji,jj,1) + 2._wp * znad )   &
443               &           * ( fsde3w(ji,jj+1,1) - fsde3w(ji,jj,1) ) / e2v(ji,jj)
444            ! add to the general momentum trend
445            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1) + zuap
446            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1) + zvap
447         END DO
448      END DO
449
450      ! interior value (2=<jk=<jpkm1)
451      DO jk = 2, jpkm1
452         DO jj = 2, jpjm1
453            DO ji = fs_2, fs_jpim1   ! vector opt.
454               ! hydrostatic pressure gradient along s-surfaces
455               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) + zcoef0 / e1u(ji,jj)   &
456                  &           * (  fse3w(ji+1,jj,jk) * ( rhd(ji+1,jj,jk) + rhd(ji+1,jj,jk-1) + 2*znad )   &
457                  &              - fse3w(ji  ,jj,jk) * ( rhd(ji  ,jj,jk) + rhd(ji  ,jj,jk-1) + 2*znad )  )
458               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1) + zcoef0 / e2v(ji,jj)   &
459                  &           * (  fse3w(ji,jj+1,jk) * ( rhd(ji,jj+1,jk) + rhd(ji,jj+1,jk-1) + 2*znad )   &
460                  &              - fse3w(ji,jj  ,jk) * ( rhd(ji,jj,  jk) + rhd(ji,jj  ,jk-1) + 2*znad )  )
461               ! s-coordinate pressure gradient correction
462               zuap = -zcoef0 * ( rhd   (ji+1,jj  ,jk) + rhd   (ji,jj,jk) + 2._wp * znad )   &
463                  &           * ( fsde3w(ji+1,jj  ,jk) - fsde3w(ji,jj,jk) ) / e1u(ji,jj)
464               zvap = -zcoef0 * ( rhd   (ji  ,jj+1,jk) + rhd   (ji,jj,jk) + 2._wp * znad )   &
465                  &           * ( fsde3w(ji  ,jj+1,jk) - fsde3w(ji,jj,jk) ) / e2v(ji,jj)
466               ! add to the general momentum trend
467               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk) + zuap
468               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk) + zvap
469            END DO
470         END DO
471      END DO
472      !
473      CALL wrk_dealloc( jpi,jpj,jpk, zhpi, zhpj )
474      !
475   END SUBROUTINE hpg_sco
476
477   SUBROUTINE hpg_isf( kt )
478      !!---------------------------------------------------------------------
479      !!                  ***  ROUTINE hpg_sco  ***
480      !!
481      !! ** Method  :   s-coordinate case. Jacobian scheme.
482      !!      The now hydrostatic pressure gradient at a given level, jk,
483      !!      is computed by taking the vertical integral of the in-situ
484      !!      density gradient along the model level from the suface to that
485      !!      level. s-coordinates (ln_sco): a corrective term is added
486      !!      to the horizontal pressure gradient :
487      !!         zhpi = grav .....  + 1/e1u mi(rhd) di[ grav dep3w ]
488      !!         zhpj = grav .....  + 1/e2v mj(rhd) dj[ grav dep3w ]
489      !!      add it to the general momentum trend (ua,va).
490      !!         ua = ua - 1/e1u * zhpi
491      !!         va = va - 1/e2v * zhpj
492      !!      iceload is added and partial cell case are added to the top and bottom
493      !!     
494      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
495      !!----------------------------------------------------------------------
496      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
497      !!
498      INTEGER  ::   ji, jj, jk, iku, ikv, ikt, iktp1i, iktp1j                 ! dummy loop indices
499      REAL(wp) ::   zcoef0, zuap, zvap, znad, ze3wu, ze3wv, zuapint, zvapint, zhpjint, zhpiint, zdzwt, zdzwtjp1, zdzwtip1             ! temporary scalars
500      REAL(wp), POINTER, DIMENSION(:,:,:)   ::  zhpi, zhpj, zrhd
501      REAL(wp), POINTER, DIMENSION(:,:,:)   ::  ztstop
502      REAL(wp), POINTER, DIMENSION(:,:)     ::  ze3w, zp, zrhdtop_isf, zrhdtop_oce, ziceload, zdept, zpshpi, zpshpj
503      !!----------------------------------------------------------------------
504      !
505      CALL wrk_alloc( jpi,jpj, 2, ztstop) 
506      CALL wrk_alloc( jpi,jpj,jpk, zhpi, zhpj, zrhd)
507      CALL wrk_alloc( jpi,jpj, ze3w, zp, zrhdtop_isf, zrhdtop_oce, ziceload, zdept, zpshpi, zpshpj) 
508      !
509     IF( kt == nit000 ) THEN
510         IF(lwp) WRITE(numout,*)
511         IF(lwp) WRITE(numout,*) 'dyn:hpg_isf : hydrostatic pressure gradient trend for ice shelf'
512         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, OPA original scheme used'
513      ENDIF
514
515      ! Local constant initialization
516      zcoef0 = - grav * 0.5_wp
517      ! To use density and not density anomaly
518!      IF ( lk_vvl ) THEN   ;     znad = 1._wp          ! Variable volume
519!      ELSE                 ;     znad = 0._wp         ! Fixed volume
520!      ENDIF
521      znad=1._wp
522      ! iniitialised to 0. zhpi zhpi
523      zhpi(:,:,:)=0._wp ; zhpj(:,:,:)=0._wp
524
525!==================================================================================     
526!=====Compute iceload and contribution of the half first wet layer =================
527!===================================================================================
528
529      ! assume water displaced by the ice shelf is at T=-1.9 and S=34.4 (rude)
530      ztstop(:,:,1)=-1.9_wp ; ztstop(:,:,2)=34.4_wp
531
532      ! compute density of the water displaced by the ice shelf
533      zrhd = rhd ! save rhd
534      DO jk = 1, jpk
535           zdept(:,:)=gdept_1d(jk)
536           CALL eos(ztstop(:,:,:),zdept(:,:),rhd(:,:,jk))
537      END DO
538      WHERE ( tmask(:,:,:) == 1._wp)
539        rhd(:,:,:) = zrhd(:,:,:) ! replace wet cell by the saved rhd
540      END WHERE
541     
542      ! compute rhd at the ice/oce interface (ice shelf side)
543      CALL eos(ztstop,risfdep,zrhdtop_isf)
544
545      ! compute rhd at the ice/oce interface (ocean side)
546      DO ji=1,jpi
547        DO jj=1,jpj
548          ikt=mikt(ji,jj)
549          ztstop(ji,jj,1)=tsn(ji,jj,ikt,1)
550          ztstop(ji,jj,2)=tsn(ji,jj,ikt,2)
551        END DO
552      END DO
553      CALL eos(ztstop,risfdep,zrhdtop_oce)
554      !
555      ! Surface value + ice shelf gradient
556      ! compute pressure due to ice shelf load (used to compute hpgi/j for all the level from 1 to miku/v)
557      ziceload = 0._wp
558      DO jj = 1, jpj
559         DO ji = 1, jpi   ! vector opt.
560            ikt=mikt(ji,jj)
561            ziceload(ji,jj) = ziceload(ji,jj) + (znad + rhd(ji,jj,1) ) * fse3w(ji,jj,1) * (1._wp - tmask(ji,jj,1))
562            DO jk=2,ikt-1
563               ziceload(ji,jj) = ziceload(ji,jj) + (2._wp * znad + rhd(ji,jj,jk-1) + rhd(ji,jj,jk)) * fse3w(ji,jj,jk) &
564                  &                              * (1._wp - tmask(ji,jj,jk))
565            END DO
566            IF (ikt .GE. 2) ziceload(ji,jj) = ziceload(ji,jj) + (2._wp * znad + zrhdtop_isf(ji,jj) + rhd(ji,jj,ikt-1)) &
567                               &                              * ( risfdep(ji,jj) - gdept_1d(ikt-1) )
568         END DO
569      END DO
570      riceload(:,:) = 0.0_wp ; riceload(:,:)=ziceload(:,:)  ! need to be saved for diaar5
571      ! compute zp from z=0 to first T wet point (correction due to zps not yet applied)
572      DO jj = 2, jpjm1
573         DO ji = fs_2, fs_jpim1   ! vector opt.
574            ikt=mikt(ji,jj) ; iktp1i=mikt(ji+1,jj); iktp1j=mikt(ji,jj+1)
575            ! hydrostatic pressure gradient along s-surfaces and ice shelf pressure
576            ! we assume ISF is in isostatic equilibrium
577            zhpi(ji,jj,1) = zcoef0 / e1u(ji,jj) * ( 0.5_wp * fse3w(ji+1,jj  ,iktp1i)                                    &
578               &                                  * ( 2._wp * znad + rhd(ji+1,jj  ,iktp1i) + zrhdtop_oce(ji+1,jj  ) )   &
579               &                                  - 0.5_wp * fse3w(ji  ,jj  ,ikt   )                                    &
580               &                                  * ( 2._wp * znad + rhd(ji  ,jj  ,ikt   ) + zrhdtop_oce(ji  ,jj  ) )   &
581               &                                  + ( ziceload(ji+1,jj) - ziceload(ji,jj))                              ) 
582            zhpj(ji,jj,1) = zcoef0 / e2v(ji,jj) * ( 0.5_wp * fse3w(ji  ,jj+1,iktp1j)                                    &
583               &                                  * ( 2._wp * znad + rhd(ji  ,jj+1,iktp1j) + zrhdtop_oce(ji  ,jj+1) )   &
584               &                                  - 0.5_wp * fse3w(ji  ,jj  ,ikt   )                                    & 
585               &                                  * ( 2._wp * znad + rhd(ji  ,jj  ,ikt   ) + zrhdtop_oce(ji  ,jj  ) )   &
586               &                                  + ( ziceload(ji,jj+1) - ziceload(ji,jj) )                             ) 
587            ! s-coordinate pressure gradient correction (=0 if z coordinate)
588            zuap = -zcoef0 * ( rhd   (ji+1,jj,1) + rhd   (ji,jj,1) + 2._wp * znad )   &
589               &           * ( fsde3w(ji+1,jj,1) - fsde3w(ji,jj,1) ) / e1u(ji,jj)
590            zvap = -zcoef0 * ( rhd   (ji,jj+1,1) + rhd   (ji,jj,1) + 2._wp * znad )   &
591               &           * ( fsde3w(ji,jj+1,1) - fsde3w(ji,jj,1) ) / e2v(ji,jj)
592            ! add to the general momentum trend
593            ua(ji,jj,1) = ua(ji,jj,1) + (zhpi(ji,jj,1) + zuap) * umask(ji,jj,1)
594            va(ji,jj,1) = va(ji,jj,1) + (zhpj(ji,jj,1) + zvap) * vmask(ji,jj,1)
595         END DO
596      END DO
597!==================================================================================     
598!===== Compute partial cell contribution for the top cell =========================
599!==================================================================================
600      DO jj = 2, jpjm1
601         DO ji = fs_2, fs_jpim1   ! vector opt.
602            iku = miku(ji,jj) ; 
603            zpshpi(ji,jj)=0.0_wp ; zpshpj(ji,jj)=0.0_wp
604            ze3wu  = (gdepw_0(ji+1,jj,iku+1) - gdept_0(ji+1,jj,iku)) - (gdepw_0(ji,jj,iku+1) - gdept_0(ji,jj,iku))
605            ! u direction
606            IF ( iku .GT. 1 ) THEN
607               ! case iku
608               zhpi(ji,jj,iku)   =  zcoef0 / e1u(ji,jj) * ze3wu                                            &
609                      &                                 * ( rhd    (ji+1,jj,iku) + rhd   (ji,jj,iku)       &
610                      &                                   + SIGN(1._wp,ze3wu) * grui(ji,jj) + 2._wp * znad )
611               ! corrective term ( = 0 if z coordinate )
612               zuap              = -zcoef0 * ( arui(ji,jj) + 2._wp * znad ) * gzui(ji,jj) / e1u(ji,jj)
613               ! zhpi will be added in interior loop
614               ua(ji,jj,iku)     = ua(ji,jj,iku) + zuap
615               ! in case of 2 cell water column, need to save the pressure gradient to compute the bottom pressure 
616               IF (mbku(ji,jj) == iku + 1) zpshpi(ji,jj)  = zhpi(ji,jj,iku)
617
618               ! case iku + 1 (remove the zphi term added in the interior loop and compute the one corrected for zps)
619               zhpiint        =  zcoef0 / e1u(ji,jj)                                                               &   
620                  &           * (  fse3w(ji+1,jj  ,iku+1) * ( (rhd(ji+1,jj,iku+1) + znad)                          &
621                  &                                         + (rhd(ji+1,jj,iku  ) + znad) ) * tmask(ji+1,jj,iku)   &
622                  &              - fse3w(ji  ,jj  ,iku+1) * ( (rhd(ji  ,jj,iku+1) + znad)                          &
623                  &                                         + (rhd(ji  ,jj,iku  ) + znad) ) * tmask(ji  ,jj,iku)   )
624               zhpi(ji,jj,iku+1) =  zcoef0 / e1u(ji,jj) * ge3rui(ji,jj) - zhpiint 
625            END IF
626               
627            ! v direction
628            ikv = mikv(ji,jj)
629            ze3wv  = (gdepw_0(ji,jj+1,ikv+1) - gdept_0(ji,jj+1,ikv)) - (gdepw_0(ji,jj,ikv+1) - gdept_0(ji,jj,ikv))
630            IF ( ikv .GT. 1 ) THEN
631               ! case ikv
632               zhpj(ji,jj,ikv)   =  zcoef0 / e2v(ji,jj) * ze3wv                                            &
633                     &                                  * ( rhd(ji,jj+1,ikv) + rhd   (ji,jj,ikv)           &
634                     &                                    + SIGN(1._wp,ze3wv) * grvi(ji,jj) + 2._wp * znad )
635               ! corrective term ( = 0 if z coordinate )
636               zvap              = -zcoef0 * ( arvi(ji,jj) + 2._wp * znad ) * gzvi(ji,jj) / e2v(ji,jj)
637               ! zhpi will be added in interior loop
638               va(ji,jj,ikv)      = va(ji,jj,ikv) + zvap
639               ! in case of 2 cell water column, need to save the pressure gradient to compute the bottom pressure 
640               IF (mbkv(ji,jj) == ikv + 1)  zpshpj(ji,jj)  =  zhpj(ji,jj,ikv) 
641               
642               ! case ikv + 1 (remove the zphj term added in the interior loop and compute the one corrected for zps)
643               zhpjint        =  zcoef0 / e2v(ji,jj)                                                              &
644                  &           * (  fse3w(ji  ,jj+1,ikv+1) * ( (rhd(ji,jj+1,ikv+1) + znad)                         &
645                  &                                       + (rhd(ji,jj+1,ikv  ) + znad) ) * tmask(ji,jj+1,ikv)    &
646                  &              - fse3w(ji  ,jj  ,ikv+1) * ( (rhd(ji,jj  ,ikv+1) + znad)                         &
647                  &                                       + (rhd(ji,jj  ,ikv  ) + znad) ) * tmask(ji,jj  ,ikv)  )
648               zhpj(ji,jj,ikv+1) =  zcoef0 / e2v(ji,jj) * ge3rvi(ji,jj) - zhpjint
649            END IF
650         END DO
651      END DO
652
653!==================================================================================     
654!===== Compute interior value =====================================================
655!==================================================================================
656
657      DO jj = 2, jpjm1
658         DO ji = fs_2, fs_jpim1   ! vector opt.
659            iku=miku(ji,jj); ikv=mikv(ji,jj)
660            DO jk = 2, jpkm1
661               ! hydrostatic pressure gradient along s-surfaces
662               ! zhpi is masked for the first wet cell  (contribution already done in the upper bloc)
663               zhpi(ji,jj,jk) = zhpi(ji,jj,jk) + zhpi(ji,jj,jk-1)                                                              &
664                  &                            + zcoef0 / e1u(ji,jj)                                                           &
665                  &                                     * ( fse3w(ji+1,jj  ,jk) * ( (rhd(ji+1,jj,jk  ) + znad)                 &
666                  &                                                     + (rhd(ji+1,jj,jk-1) + znad) ) * tmask(ji+1,jj,jk-1)   &
667                  &                                       - fse3w(ji  ,jj  ,jk) * ( (rhd(ji  ,jj,jk  ) + znad)                 &
668                  &                                                     + (rhd(ji  ,jj,jk-1) + znad) ) * tmask(ji  ,jj,jk-1)   ) 
669               ! s-coordinate pressure gradient correction
670               ! corrective term, we mask this term for the first wet level beneath the ice shelf (contribution done in the upper bloc)
671               zuap = - zcoef0 * ( rhd   (ji+1,jj  ,jk) + rhd   (ji,jj,jk) + 2._wp * znad )                    &
672                  &            * ( fsde3w(ji+1,jj  ,jk) - fsde3w(ji,jj,jk) ) / e1u(ji,jj) * umask(ji,jj,jk-1)
673               ua(ji,jj,jk) = ua(ji,jj,jk) + ( zhpi(ji,jj,jk) + zuap) * umask(ji,jj,jk)
674
675               ! hydrostatic pressure gradient along s-surfaces
676               ! zhpi is masked for the first wet cell  (contribution already done in the upper bloc)
677               zhpj(ji,jj,jk) = zhpj(ji,jj,jk) + zhpj(ji,jj,jk-1)                                                              &
678                  &                            + zcoef0 / e2v(ji,jj)                                                           &
679                  &                                     * ( fse3w(ji  ,jj+1,jk) * ( (rhd(ji,jj+1,jk  ) + znad)                 &
680                  &                                                     + (rhd(ji,jj+1,jk-1) + znad) ) * tmask(ji,jj+1,jk-1)   &
681                  &                                       - fse3w(ji  ,jj  ,jk) * ( (rhd(ji,jj  ,jk  ) + znad)                 &
682                  &                                                     + (rhd(ji,jj  ,jk-1) + znad) ) * tmask(ji,jj  ,jk-1)   )
683               ! s-coordinate pressure gradient correction
684               ! corrective term, we mask this term for the first wet level beneath the ice shelf (contribution done in the upper bloc)
685               zvap = - zcoef0 * ( rhd   (ji  ,jj+1,jk) + rhd   (ji,jj,jk) + 2._wp * znad )                     &
686                  &            * ( fsde3w(ji  ,jj+1,jk) - fsde3w(ji,jj,jk) ) / e2v(ji,jj) * vmask(ji,jj,jk-1)
687               ! add to the general momentum trend
688               va(ji,jj,jk) = va(ji,jj,jk) + ( zhpj(ji,jj,jk) + zvap ) * vmask(ji,jj,jk)
689            END DO
690         END DO
691      END DO
692
693!==================================================================================     
694!===== Compute bottom cell contribution (partial cell) ============================
695!==================================================================================
696
697      DO jj = 2, jpjm1
698         DO ji = 2, jpim1
699            iku = mbku(ji,jj)
700            ikv = mbkv(ji,jj)
701
702            IF (iku .GT. 1) THEN
703               ! remove old value (interior case)
704               zuap            = -zcoef0 * ( rhd   (ji+1,jj  ,iku) + rhd   (ji,jj,iku) + 2._wp * znad )   &
705                     &                   * ( fsde3w(ji+1,jj  ,iku) - fsde3w(ji,jj,iku) ) / e1u(ji,jj)
706               ua(ji,jj,iku)   = ua(ji,jj,iku) - zhpi(ji,jj,iku) - zuap
707               ! put new value
708               ! -zpshpi to avoid double contribution of the partial step in the top layer
709               zuap            = -zcoef0 * ( aru(ji,jj) + 2._wp * znad ) * gzu(ji,jj)  / e1u(ji,jj)
710               zhpi(ji,jj,iku) =  zhpi(ji,jj,iku-1) + zcoef0 / e1u(ji,jj) * ge3ru(ji,jj) - zpshpi(ji,jj) 
711               ua(ji,jj,iku)   =  ua(ji,jj,iku) + zhpi(ji,jj,iku) + zuap
712            END IF
713            ! v direction
714            IF (ikv .GT. 1) THEN
715               ! remove old value (interior case)
716               zvap            = -zcoef0 * ( rhd   (ji  ,jj+1,ikv) + rhd   (ji,jj,ikv) + 2._wp * znad )   &
717                     &                   * ( fsde3w(ji  ,jj+1,ikv) - fsde3w(ji,jj,ikv) )   / e2v(ji,jj)
718               va(ji,jj,ikv)   = va(ji,jj,ikv) - zhpj(ji,jj,ikv) - zvap
719               ! put new value
720               ! -zpshpj to avoid double contribution of the partial step in the top layer
721               zvap            = -zcoef0 * ( arv(ji,jj) + 2._wp * znad ) * gzv(ji,jj)     / e2v(ji,jj)
722               zhpj(ji,jj,ikv) =  zhpj(ji,jj,ikv-1) + zcoef0 / e2v(ji,jj) * ge3rv(ji,jj) - zpshpj(ji,jj)   
723               va(ji,jj,ikv)   =  va(ji,jj,ikv) + zhpj(ji,jj,ikv) + zvap
724            END IF
725         END DO
726      END DO
727     
728      ! set back to original density value into the ice shelf cell (maybe useless because it is masked)
729      rhd = zrhd
730      !
731      CALL wrk_dealloc( jpi,jpj,2, ztstop)
732      CALL wrk_dealloc( jpi,jpj,jpk, zhpi, zhpj, zrhd)
733      CALL wrk_dealloc( jpi,jpj, ze3w, zp, zrhdtop_isf, zrhdtop_oce, ziceload, zdept, zpshpi, zpshpj)
734      !
735   END SUBROUTINE hpg_isf
736
737
738   SUBROUTINE hpg_djc( kt )
739      !!---------------------------------------------------------------------
740      !!                  ***  ROUTINE hpg_djc  ***
741      !!
742      !! ** Method  :   Density Jacobian with Cubic polynomial scheme
743      !!
744      !! Reference: Shchepetkin and McWilliams, J. Geophys. Res., 108(C3), 3090, 2003
745      !!----------------------------------------------------------------------
746      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
747      !!
748      INTEGER  ::   ji, jj, jk          ! dummy loop indices
749      REAL(wp) ::   zcoef0, zep, cffw   ! temporary scalars
750      REAL(wp) ::   z1_10, cffu, cffx   !    "         "
751      REAL(wp) ::   z1_12, cffv, cffy   !    "         "
752      REAL(wp), POINTER, DIMENSION(:,:,:) ::  zhpi, zhpj
753      REAL(wp), POINTER, DIMENSION(:,:,:) ::  dzx, dzy, dzz, dzu, dzv, dzw
754      REAL(wp), POINTER, DIMENSION(:,:,:) ::  drhox, drhoy, drhoz, drhou, drhov, drhow
755      REAL(wp), POINTER, DIMENSION(:,:,:) ::  rho_i, rho_j, rho_k
756      !!----------------------------------------------------------------------
757      !
758      CALL wrk_alloc( jpi, jpj, jpk, dzx  , dzy  , dzz  , dzu  , dzv  , dzw   )
759      CALL wrk_alloc( jpi, jpj, jpk, drhox, drhoy, drhoz, drhou, drhov, drhow )
760      CALL wrk_alloc( jpi, jpj, jpk, rho_i, rho_j, rho_k,  zhpi,  zhpj        )
761      !
762
763      IF( kt == nit000 ) THEN
764         IF(lwp) WRITE(numout,*)
765         IF(lwp) WRITE(numout,*) 'dyn:hpg_djc : hydrostatic pressure gradient trend'
766         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, density Jacobian with cubic polynomial scheme'
767      ENDIF
768
769      ! Local constant initialization
770      zcoef0 = - grav * 0.5_wp
771      z1_10  = 1._wp / 10._wp
772      z1_12  = 1._wp / 12._wp
773
774      !----------------------------------------------------------------------------------------
775      !  compute and store in provisional arrays elementary vertical and horizontal differences
776      !----------------------------------------------------------------------------------------
777
778!!bug gm   Not a true bug, but... dzz=e3w  for dzx, dzy verify what it is really
779
780      DO jk = 2, jpkm1
781         DO jj = 2, jpjm1
782            DO ji = fs_2, fs_jpim1   ! vector opt.
783               drhoz(ji,jj,jk) = rhd   (ji  ,jj  ,jk) - rhd   (ji,jj,jk-1)
784               dzz  (ji,jj,jk) = fsde3w(ji  ,jj  ,jk) - fsde3w(ji,jj,jk-1)
785               drhox(ji,jj,jk) = rhd   (ji+1,jj  ,jk) - rhd   (ji,jj,jk  )
786               dzx  (ji,jj,jk) = fsde3w(ji+1,jj  ,jk) - fsde3w(ji,jj,jk  )
787               drhoy(ji,jj,jk) = rhd   (ji  ,jj+1,jk) - rhd   (ji,jj,jk  )
788               dzy  (ji,jj,jk) = fsde3w(ji  ,jj+1,jk) - fsde3w(ji,jj,jk  )
789            END DO
790         END DO
791      END DO
792
793      !-------------------------------------------------------------------------
794      ! compute harmonic averages using eq. 5.18
795      !-------------------------------------------------------------------------
796      zep = 1.e-15
797
798!!bug  gm  drhoz not defined at level 1 and used (jk-1 with jk=2)
799!!bug  gm  idem for drhox, drhoy et ji=jpi and jj=jpj
800
801      DO jk = 2, jpkm1
802         DO jj = 2, jpjm1
803            DO ji = fs_2, fs_jpim1   ! vector opt.
804               cffw = 2._wp * drhoz(ji  ,jj  ,jk) * drhoz(ji,jj,jk-1)
805
806               cffu = 2._wp * drhox(ji+1,jj  ,jk) * drhox(ji,jj,jk  )
807               cffx = 2._wp * dzx  (ji+1,jj  ,jk) * dzx  (ji,jj,jk  )
808
809               cffv = 2._wp * drhoy(ji  ,jj+1,jk) * drhoy(ji,jj,jk  )
810               cffy = 2._wp * dzy  (ji  ,jj+1,jk) * dzy  (ji,jj,jk  )
811
812               IF( cffw > zep) THEN
813                  drhow(ji,jj,jk) = 2._wp *   drhoz(ji,jj,jk) * drhoz(ji,jj,jk-1)   &
814                     &                    / ( drhoz(ji,jj,jk) + drhoz(ji,jj,jk-1) )
815               ELSE
816                  drhow(ji,jj,jk) = 0._wp
817               ENDIF
818
819               dzw(ji,jj,jk) = 2._wp *   dzz(ji,jj,jk) * dzz(ji,jj,jk-1)   &
820                  &                  / ( dzz(ji,jj,jk) + dzz(ji,jj,jk-1) )
821
822               IF( cffu > zep ) THEN
823                  drhou(ji,jj,jk) = 2._wp *   drhox(ji+1,jj,jk) * drhox(ji,jj,jk)   &
824                     &                    / ( drhox(ji+1,jj,jk) + drhox(ji,jj,jk) )
825               ELSE
826                  drhou(ji,jj,jk ) = 0._wp
827               ENDIF
828
829               IF( cffx > zep ) THEN
830                  dzu(ji,jj,jk) = 2._wp *   dzx(ji+1,jj,jk) * dzx(ji,jj,jk)   &
831                     &                  / ( dzx(ji+1,jj,jk) + dzx(ji,jj,jk) )
832               ELSE
833                  dzu(ji,jj,jk) = 0._wp
834               ENDIF
835
836               IF( cffv > zep ) THEN
837                  drhov(ji,jj,jk) = 2._wp *   drhoy(ji,jj+1,jk) * drhoy(ji,jj,jk)   &
838                     &                    / ( drhoy(ji,jj+1,jk) + drhoy(ji,jj,jk) )
839               ELSE
840                  drhov(ji,jj,jk) = 0._wp
841               ENDIF
842
843               IF( cffy > zep ) THEN
844                  dzv(ji,jj,jk) = 2._wp *   dzy(ji,jj+1,jk) * dzy(ji,jj,jk)   &
845                     &                  / ( dzy(ji,jj+1,jk) + dzy(ji,jj,jk) )
846               ELSE
847                  dzv(ji,jj,jk) = 0._wp
848               ENDIF
849
850            END DO
851         END DO
852      END DO
853
854      !----------------------------------------------------------------------------------
855      ! apply boundary conditions at top and bottom using 5.36-5.37
856      !----------------------------------------------------------------------------------
857      drhow(:,:, 1 ) = 1.5_wp * ( drhoz(:,:, 2 ) - drhoz(:,:,  1  ) ) - 0.5_wp * drhow(:,:,  2  )
858      drhou(:,:, 1 ) = 1.5_wp * ( drhox(:,:, 2 ) - drhox(:,:,  1  ) ) - 0.5_wp * drhou(:,:,  2  )
859      drhov(:,:, 1 ) = 1.5_wp * ( drhoy(:,:, 2 ) - drhoy(:,:,  1  ) ) - 0.5_wp * drhov(:,:,  2  )
860
861      drhow(:,:,jpk) = 1.5_wp * ( drhoz(:,:,jpk) - drhoz(:,:,jpkm1) ) - 0.5_wp * drhow(:,:,jpkm1)
862      drhou(:,:,jpk) = 1.5_wp * ( drhox(:,:,jpk) - drhox(:,:,jpkm1) ) - 0.5_wp * drhou(:,:,jpkm1)
863      drhov(:,:,jpk) = 1.5_wp * ( drhoy(:,:,jpk) - drhoy(:,:,jpkm1) ) - 0.5_wp * drhov(:,:,jpkm1)
864
865
866      !--------------------------------------------------------------
867      ! Upper half of top-most grid box, compute and store
868      !-------------------------------------------------------------
869
870!!bug gm   :  e3w-de3w = 0.5*e3w  ....  and de3w(2)-de3w(1)=e3w(2) ....   to be verified
871!          true if de3w is really defined as the sum of the e3w scale factors as, it seems to me, it should be
872
873      DO jj = 2, jpjm1
874         DO ji = fs_2, fs_jpim1   ! vector opt.
875            rho_k(ji,jj,1) = -grav * ( fse3w(ji,jj,1) - fsde3w(ji,jj,1) )               &
876               &                   * (  rhd(ji,jj,1)                                    &
877               &                     + 0.5_wp * ( rhd(ji,jj,2) - rhd(ji,jj,1) )         &
878               &                              * ( fse3w (ji,jj,1) - fsde3w(ji,jj,1) )   &
879               &                              / ( fsde3w(ji,jj,2) - fsde3w(ji,jj,1) )  )
880         END DO
881      END DO
882
883!!bug gm    : here also, simplification is possible
884!!bug gm    : optimisation: 1/10 and 1/12 the division should be done before the loop
885
886      DO jk = 2, jpkm1
887         DO jj = 2, jpjm1
888            DO ji = fs_2, fs_jpim1   ! vector opt.
889
890               rho_k(ji,jj,jk) = zcoef0 * ( rhd   (ji,jj,jk) + rhd   (ji,jj,jk-1) )                                   &
891                  &                     * ( fsde3w(ji,jj,jk) - fsde3w(ji,jj,jk-1) )                                   &
892                  &            - grav * z1_10 * (                                                                     &
893                  &     ( drhow (ji,jj,jk) - drhow (ji,jj,jk-1) )                                                     &
894                  &   * ( fsde3w(ji,jj,jk) - fsde3w(ji,jj,jk-1) - z1_12 * ( dzw  (ji,jj,jk) + dzw  (ji,jj,jk-1) ) )   &
895                  &   - ( dzw   (ji,jj,jk) - dzw   (ji,jj,jk-1) )                                                     &
896                  &   * ( rhd   (ji,jj,jk) - rhd   (ji,jj,jk-1) - z1_12 * ( drhow(ji,jj,jk) + drhow(ji,jj,jk-1) ) )   &
897                  &                             )
898
899               rho_i(ji,jj,jk) = zcoef0 * ( rhd   (ji+1,jj,jk) + rhd   (ji,jj,jk) )                                   &
900                  &                     * ( fsde3w(ji+1,jj,jk) - fsde3w(ji,jj,jk) )                                   &
901                  &            - grav* z1_10 * (                                                                      &
902                  &     ( drhou (ji+1,jj,jk) - drhou (ji,jj,jk) )                                                     &
903                  &   * ( fsde3w(ji+1,jj,jk) - fsde3w(ji,jj,jk) - z1_12 * ( dzu  (ji+1,jj,jk) + dzu  (ji,jj,jk) ) )   &
904                  &   - ( dzu   (ji+1,jj,jk) - dzu   (ji,jj,jk) )                                                     &
905                  &   * ( rhd   (ji+1,jj,jk) - rhd   (ji,jj,jk) - z1_12 * ( drhou(ji+1,jj,jk) + drhou(ji,jj,jk) ) )   &
906                  &                            )
907
908               rho_j(ji,jj,jk) = zcoef0 * ( rhd   (ji,jj+1,jk) + rhd   (ji,jj,jk) )                                   &
909                  &                     * ( fsde3w(ji,jj+1,jk) - fsde3w(ji,jj,jk) )                                   &
910                  &            - grav* z1_10 * (                                                                      &
911                  &     ( drhov (ji,jj+1,jk) - drhov (ji,jj,jk) )                                                     &
912                  &   * ( fsde3w(ji,jj+1,jk) - fsde3w(ji,jj,jk) - z1_12 * ( dzv  (ji,jj+1,jk) + dzv  (ji,jj,jk) ) )   &
913                  &   - ( dzv   (ji,jj+1,jk) - dzv   (ji,jj,jk) )                                                     &
914                  &   * ( rhd   (ji,jj+1,jk) - rhd   (ji,jj,jk) - z1_12 * ( drhov(ji,jj+1,jk) + drhov(ji,jj,jk) ) )   &
915                  &                            )
916
917            END DO
918         END DO
919      END DO
920      CALL lbc_lnk(rho_k,'W',1.)
921      CALL lbc_lnk(rho_i,'U',1.)
922      CALL lbc_lnk(rho_j,'V',1.)
923
924
925      ! ---------------
926      !  Surface value
927      ! ---------------
928      DO jj = 2, jpjm1
929         DO ji = fs_2, fs_jpim1   ! vector opt.
930            zhpi(ji,jj,1) = ( rho_k(ji+1,jj  ,1) - rho_k(ji,jj,1) - rho_i(ji,jj,1) ) / e1u(ji,jj)
931            zhpj(ji,jj,1) = ( rho_k(ji  ,jj+1,1) - rho_k(ji,jj,1) - rho_j(ji,jj,1) ) / e2v(ji,jj)
932            ! add to the general momentum trend
933            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
934            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
935         END DO
936      END DO
937
938      ! ----------------
939      !  interior value   (2=<jk=<jpkm1)
940      ! ----------------
941      DO jk = 2, jpkm1
942         DO jj = 2, jpjm1
943            DO ji = fs_2, fs_jpim1   ! vector opt.
944               ! hydrostatic pressure gradient along s-surfaces
945               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1)                                &
946                  &           + (  ( rho_k(ji+1,jj,jk) - rho_k(ji,jj,jk  ) )    &
947                  &              - ( rho_i(ji  ,jj,jk) - rho_i(ji,jj,jk-1) )  ) / e1u(ji,jj)
948               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1)                                &
949                  &           + (  ( rho_k(ji,jj+1,jk) - rho_k(ji,jj,jk  ) )    &
950                  &               -( rho_j(ji,jj  ,jk) - rho_j(ji,jj,jk-1) )  ) / e2v(ji,jj)
951               ! add to the general momentum trend
952               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
953               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
954            END DO
955         END DO
956      END DO
957      !
958      CALL wrk_dealloc( jpi, jpj, jpk, dzx  , dzy  , dzz  , dzu  , dzv  , dzw   )
959      CALL wrk_dealloc( jpi, jpj, jpk, drhox, drhoy, drhoz, drhou, drhov, drhow )
960      CALL wrk_dealloc( jpi, jpj, jpk, rho_i, rho_j, rho_k,  zhpi,  zhpj        )
961      !
962   END SUBROUTINE hpg_djc
963
964
965   SUBROUTINE hpg_prj( kt )
966      !!---------------------------------------------------------------------
967      !!                  ***  ROUTINE hpg_prj  ***
968      !!
969      !! ** Method  :   s-coordinate case.
970      !!      A Pressure-Jacobian horizontal pressure gradient method
971      !!      based on the constrained cubic-spline interpolation for
972      !!      all vertical coordinate systems
973      !!
974      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
975      !!----------------------------------------------------------------------
976      INTEGER, PARAMETER  :: polynomial_type = 1    ! 1: cubic spline, 2: linear
977      INTEGER, INTENT(in) ::   kt                   ! ocean time-step index
978      !!
979      INTEGER  ::   ji, jj, jk, jkk                 ! dummy loop indices
980      REAL(wp) ::   zcoef0, znad                    ! temporary scalars
981      !!
982      !! The local variables for the correction term
983      INTEGER  :: jk1, jis, jid, jjs, jjd
984      REAL(wp) :: zuijk, zvijk, zpwes, zpwed, zpnss, zpnsd, zdeps
985      REAL(wp) :: zrhdt1
986      REAL(wp) :: zdpdx1, zdpdx2, zdpdy1, zdpdy2
987      REAL(wp), POINTER, DIMENSION(:,:,:) ::   zdept, zrhh
988      REAL(wp), POINTER, DIMENSION(:,:,:) ::   zhpi, zu, zv, fsp, xsp, asp, bsp, csp, dsp
989      REAL(wp), POINTER, DIMENSION(:,:)   ::   zsshu_n, zsshv_n
990      !!----------------------------------------------------------------------
991      !
992      CALL wrk_alloc( jpi,jpj,jpk, zhpi, zu, zv, fsp, xsp, asp, bsp, csp, dsp )
993      CALL wrk_alloc( jpi,jpj,jpk, zdept, zrhh )
994      CALL wrk_alloc( jpi,jpj, zsshu_n, zsshv_n )
995      !
996      IF( kt == nit000 ) THEN
997         IF(lwp) WRITE(numout,*)
998         IF(lwp) WRITE(numout,*) 'dyn:hpg_prj : hydrostatic pressure gradient trend'
999         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, cubic spline pressure Jacobian'
1000      ENDIF
1001
1002      !!----------------------------------------------------------------------
1003      ! Local constant initialization
1004      zcoef0 = - grav
1005      znad = 0.0_wp
1006      IF( lk_vvl ) znad = 1._wp
1007
1008      ! Clean 3-D work arrays
1009      zhpi(:,:,:) = 0._wp
1010      zrhh(:,:,:) = rhd(:,:,:)
1011
1012      ! Preparing vertical density profile "zrhh(:,:,:)" for hybrid-sco coordinate
1013      DO jj = 1, jpj
1014        DO ji = 1, jpi
1015          jk = mbathy(ji,jj)
1016          IF( jk <= 0 ) THEN; zrhh(ji,jj,:) = 0._wp
1017          ELSE IF(jk == 1) THEN; zrhh(ji,jj, jk+1:jpk) = rhd(ji,jj,jk)
1018          ELSE IF(jk < jpkm1) THEN
1019             DO jkk = jk+1, jpk
1020                zrhh(ji,jj,jkk) = interp1(fsde3w(ji,jj,jkk),   fsde3w(ji,jj,jkk-1), &
1021                                         fsde3w(ji,jj,jkk-2), rhd(ji,jj,jkk-1), rhd(ji,jj,jkk-2))
1022             END DO
1023          ENDIF
1024        END DO
1025      END DO
1026
1027      ! Transfer the depth of "T(:,:,:)" to vertical coordinate "zdept(:,:,:)"
1028      DO jj = 1, jpj
1029         DO ji = 1, jpi
1030            zdept(ji,jj,1) = 0.5_wp * fse3w(ji,jj,1) - sshn(ji,jj) * znad
1031         END DO
1032      END DO
1033
1034      DO jk = 2, jpk
1035         DO jj = 1, jpj
1036            DO ji = 1, jpi
1037               zdept(ji,jj,jk) = zdept(ji,jj,jk-1) + fse3w(ji,jj,jk)
1038            END DO
1039         END DO
1040      END DO
1041
1042      fsp(:,:,:) = zrhh (:,:,:)
1043      xsp(:,:,:) = zdept(:,:,:)
1044
1045      ! Construct the vertical density profile with the
1046      ! constrained cubic spline interpolation
1047      ! rho(z) = asp + bsp*z + csp*z^2 + dsp*z^3
1048      CALL cspline(fsp,xsp,asp,bsp,csp,dsp,polynomial_type)
1049
1050      ! Integrate the hydrostatic pressure "zhpi(:,:,:)" at "T(ji,jj,1)"
1051      DO jj = 2, jpj
1052        DO ji = 2, jpi
1053          zrhdt1 = zrhh(ji,jj,1) - interp3(zdept(ji,jj,1),asp(ji,jj,1), &
1054                                         bsp(ji,jj,1),   csp(ji,jj,1), &
1055                                         dsp(ji,jj,1) ) * 0.25_wp * fse3w(ji,jj,1)
1056
1057          ! assuming linear profile across the top half surface layer
1058          zhpi(ji,jj,1) =  0.5_wp * fse3w(ji,jj,1) * zrhdt1
1059        END DO
1060      END DO
1061
1062      ! Calculate the pressure "zhpi(:,:,:)" at "T(ji,jj,2:jpkm1)"
1063      DO jk = 2, jpkm1
1064        DO jj = 2, jpj
1065          DO ji = 2, jpi
1066            zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) +                          &
1067                             integ_spline(zdept(ji,jj,jk-1), zdept(ji,jj,jk),&
1068                                    asp(ji,jj,jk-1),    bsp(ji,jj,jk-1), &
1069                                    csp(ji,jj,jk-1),    dsp(ji,jj,jk-1))
1070          END DO
1071        END DO
1072      END DO
1073
1074      ! Z coordinate of U(ji,jj,1:jpkm1) and V(ji,jj,1:jpkm1)
1075
1076      ! Prepare zsshu_n and zsshv_n
1077      DO jj = 2, jpjm1
1078        DO ji = 2, jpim1
1079          zsshu_n(ji,jj) = (e12u(ji,jj) * sshn(ji,jj) + e12u(ji+1, jj) * sshn(ji+1,jj)) * &
1080                         & r1_e12u(ji,jj) * umask(ji,jj,1) * 0.5_wp 
1081          zsshv_n(ji,jj) = (e12v(ji,jj) * sshn(ji,jj) + e12v(ji+1, jj) * sshn(ji,jj+1)) * &
1082                         & r1_e12v(ji,jj) * vmask(ji,jj,1) * 0.5_wp 
1083        END DO
1084      END DO
1085
1086      DO jj = 2, jpjm1
1087        DO ji = 2, jpim1
1088          zu(ji,jj,1) = - ( fse3u(ji,jj,1) - zsshu_n(ji,jj) * znad) 
1089          zv(ji,jj,1) = - ( fse3v(ji,jj,1) - zsshv_n(ji,jj) * znad)
1090        END DO
1091      END DO
1092
1093      DO jk = 2, jpkm1
1094        DO jj = 2, jpjm1
1095          DO ji = 2, jpim1
1096            zu(ji,jj,jk) = zu(ji,jj,jk-1)- fse3u(ji,jj,jk)
1097            zv(ji,jj,jk) = zv(ji,jj,jk-1)- fse3v(ji,jj,jk)
1098          END DO
1099        END DO
1100      END DO
1101
1102      DO jk = 1, jpkm1
1103        DO jj = 2, jpjm1
1104          DO ji = 2, jpim1
1105            zu(ji,jj,jk) = zu(ji,jj,jk) + 0.5_wp * fse3u(ji,jj,jk)
1106            zv(ji,jj,jk) = zv(ji,jj,jk) + 0.5_wp * fse3v(ji,jj,jk)
1107          END DO
1108        END DO
1109      END DO
1110
1111      DO jk = 1, jpkm1
1112        DO jj = 2, jpjm1
1113          DO ji = 2, jpim1
1114            zu(ji,jj,jk) = min(zu(ji,jj,jk), max(-zdept(ji,jj,jk), -zdept(ji+1,jj,jk)))
1115            zu(ji,jj,jk) = max(zu(ji,jj,jk), min(-zdept(ji,jj,jk), -zdept(ji+1,jj,jk)))
1116            zv(ji,jj,jk) = min(zv(ji,jj,jk), max(-zdept(ji,jj,jk), -zdept(ji,jj+1,jk)))
1117            zv(ji,jj,jk) = max(zv(ji,jj,jk), min(-zdept(ji,jj,jk), -zdept(ji,jj+1,jk)))
1118          END DO
1119        END DO
1120      END DO
1121
1122
1123      DO jk = 1, jpkm1
1124        DO jj = 2, jpjm1
1125          DO ji = 2, jpim1
1126            zpwes = 0._wp; zpwed = 0._wp
1127            zpnss = 0._wp; zpnsd = 0._wp
1128            zuijk = zu(ji,jj,jk)
1129            zvijk = zv(ji,jj,jk)
1130
1131            !!!!!     for u equation
1132            IF( jk <= mbku(ji,jj) ) THEN
1133               IF( -zdept(ji+1,jj,jk) >= -zdept(ji,jj,jk) ) THEN
1134                 jis = ji + 1; jid = ji
1135               ELSE
1136                 jis = ji;     jid = ji +1
1137               ENDIF
1138
1139               ! integrate the pressure on the shallow side
1140               jk1 = jk
1141               DO WHILE ( -zdept(jis,jj,jk1) > zuijk )
1142                 IF( jk1 == mbku(ji,jj) ) THEN
1143                   zuijk = -zdept(jis,jj,jk1)
1144                   EXIT
1145                 ENDIF
1146                 zdeps = MIN(zdept(jis,jj,jk1+1), -zuijk)
1147                 zpwes = zpwes +                                    &
1148                      integ_spline(zdept(jis,jj,jk1), zdeps,            &
1149                             asp(jis,jj,jk1),    bsp(jis,jj,jk1), &
1150                             csp(jis,jj,jk1),    dsp(jis,jj,jk1))
1151                 jk1 = jk1 + 1
1152               END DO
1153
1154               ! integrate the pressure on the deep side
1155               jk1 = jk
1156               DO WHILE ( -zdept(jid,jj,jk1) < zuijk )
1157                 IF( jk1 == 1 ) THEN
1158                   zdeps = zdept(jid,jj,1) + MIN(zuijk, sshn(jid,jj)*znad)
1159                   zrhdt1 = zrhh(jid,jj,1) - interp3(zdept(jid,jj,1), asp(jid,jj,1), &
1160                                                     bsp(jid,jj,1),   csp(jid,jj,1), &
1161                                                     dsp(jid,jj,1)) * zdeps
1162                   zpwed  = zpwed + 0.5_wp * (zrhh(jid,jj,1) + zrhdt1) * zdeps
1163                   EXIT
1164                 ENDIF
1165                 zdeps = MAX(zdept(jid,jj,jk1-1), -zuijk)
1166                 zpwed = zpwed +                                        &
1167                        integ_spline(zdeps,              zdept(jid,jj,jk1), &
1168                               asp(jid,jj,jk1-1), bsp(jid,jj,jk1-1),  &
1169                               csp(jid,jj,jk1-1), dsp(jid,jj,jk1-1) )
1170                 jk1 = jk1 - 1
1171               END DO
1172
1173               ! update the momentum trends in u direction
1174
1175               zdpdx1 = zcoef0 / e1u(ji,jj) * (zhpi(ji+1,jj,jk) - zhpi(ji,jj,jk))
1176               IF( lk_vvl ) THEN
1177                 zdpdx2 = zcoef0 / e1u(ji,jj) * &
1178                         ( REAL(jis-jid, wp) * (zpwes + zpwed) + (sshn(ji+1,jj)-sshn(ji,jj)) )
1179                ELSE
1180                 zdpdx2 = zcoef0 / e1u(ji,jj) * REAL(jis-jid, wp) * (zpwes + zpwed)
1181               ENDIF
1182
1183               ua(ji,jj,jk) = ua(ji,jj,jk) + (zdpdx1 + zdpdx2) * &
1184               &           umask(ji,jj,jk) * tmask(ji,jj,jk) * tmask(ji+1,jj,jk)
1185            ENDIF
1186
1187            !!!!!     for v equation
1188            IF( jk <= mbkv(ji,jj) ) THEN
1189               IF( -zdept(ji,jj+1,jk) >= -zdept(ji,jj,jk) ) THEN
1190                 jjs = jj + 1; jjd = jj
1191               ELSE
1192                 jjs = jj    ; jjd = jj + 1
1193               ENDIF
1194
1195               ! integrate the pressure on the shallow side
1196               jk1 = jk
1197               DO WHILE ( -zdept(ji,jjs,jk1) > zvijk )
1198                 IF( jk1 == mbkv(ji,jj) ) THEN
1199                   zvijk = -zdept(ji,jjs,jk1)
1200                   EXIT
1201                 ENDIF
1202                 zdeps = MIN(zdept(ji,jjs,jk1+1), -zvijk)
1203                 zpnss = zpnss +                                      &
1204                        integ_spline(zdept(ji,jjs,jk1), zdeps,            &
1205                               asp(ji,jjs,jk1),    bsp(ji,jjs,jk1), &
1206                               csp(ji,jjs,jk1),    dsp(ji,jjs,jk1) )
1207                 jk1 = jk1 + 1
1208               END DO
1209
1210               ! integrate the pressure on the deep side
1211               jk1 = jk
1212               DO WHILE ( -zdept(ji,jjd,jk1) < zvijk )
1213                 IF( jk1 == 1 ) THEN
1214                   zdeps = zdept(ji,jjd,1) + MIN(zvijk, sshn(ji,jjd)*znad)
1215                   zrhdt1 = zrhh(ji,jjd,1) - interp3(zdept(ji,jjd,1), asp(ji,jjd,1), &
1216                                                     bsp(ji,jjd,1),   csp(ji,jjd,1), &
1217                                                     dsp(ji,jjd,1) ) * zdeps
1218                   zpnsd  = zpnsd + 0.5_wp * (zrhh(ji,jjd,1) + zrhdt1) * zdeps
1219                   EXIT
1220                 ENDIF
1221                 zdeps = MAX(zdept(ji,jjd,jk1-1), -zvijk)
1222                 zpnsd = zpnsd +                                        &
1223                        integ_spline(zdeps,              zdept(ji,jjd,jk1), &
1224                               asp(ji,jjd,jk1-1), bsp(ji,jjd,jk1-1), &
1225                               csp(ji,jjd,jk1-1), dsp(ji,jjd,jk1-1) )
1226                 jk1 = jk1 - 1
1227               END DO
1228
1229
1230               ! update the momentum trends in v direction
1231
1232               zdpdy1 = zcoef0 / e2v(ji,jj) * (zhpi(ji,jj+1,jk) - zhpi(ji,jj,jk))
1233               IF( lk_vvl ) THEN
1234                   zdpdy2 = zcoef0 / e2v(ji,jj) * &
1235                           ( REAL(jjs-jjd, wp) * (zpnss + zpnsd) + (sshn(ji,jj+1)-sshn(ji,jj)) )
1236               ELSE
1237                   zdpdy2 = zcoef0 / e2v(ji,jj) * REAL(jjs-jjd, wp) * (zpnss + zpnsd )
1238               ENDIF
1239
1240               va(ji,jj,jk) = va(ji,jj,jk) + (zdpdy1 + zdpdy2)*&
1241               &              vmask(ji,jj,jk)*tmask(ji,jj,jk)*tmask(ji,jj+1,jk)
1242            ENDIF
1243
1244
1245           END DO
1246        END DO
1247      END DO
1248      !
1249      CALL wrk_dealloc( jpi,jpj,jpk, zhpi, zu, zv, fsp, xsp, asp, bsp, csp, dsp )
1250      CALL wrk_dealloc( jpi,jpj,jpk, zdept, zrhh )
1251      CALL wrk_dealloc( jpi,jpj, zsshu_n, zsshv_n )
1252      !
1253   END SUBROUTINE hpg_prj
1254
1255
1256   SUBROUTINE cspline(fsp, xsp, asp, bsp, csp, dsp, polynomial_type)
1257      !!----------------------------------------------------------------------
1258      !!                 ***  ROUTINE cspline  ***
1259      !!
1260      !! ** Purpose :   constrained cubic spline interpolation
1261      !!
1262      !! ** Method  :   f(x) = asp + bsp*x + csp*x^2 + dsp*x^3
1263      !!
1264      !! Reference: CJC Kruger, Constrained Cubic Spline Interpoltation
1265      !!----------------------------------------------------------------------
1266      IMPLICIT NONE
1267      REAL(wp), DIMENSION(:,:,:), INTENT(in)  :: fsp, xsp           ! value and coordinate
1268      REAL(wp), DIMENSION(:,:,:), INTENT(out) :: asp, bsp, csp, dsp ! coefficients of
1269                                                                    ! the interpoated function
1270      INTEGER, INTENT(in) :: polynomial_type                        ! 1: cubic spline
1271                                                                    ! 2: Linear
1272      !
1273      INTEGER  ::   ji, jj, jk                 ! dummy loop indices
1274      INTEGER  ::   jpi, jpj, jpkm1
1275      REAL(wp) ::   zdf1, zdf2, zddf1, zddf2, ztmp1, ztmp2, zdxtmp
1276      REAL(wp) ::   zdxtmp1, zdxtmp2, zalpha
1277      REAL(wp) ::   zdf(size(fsp,3))
1278      !!----------------------------------------------------------------------
1279
1280      jpi   = size(fsp,1)
1281      jpj   = size(fsp,2)
1282      jpkm1 = size(fsp,3) - 1
1283
1284
1285      IF (polynomial_type == 1) THEN     ! Constrained Cubic Spline
1286         DO ji = 1, jpi
1287            DO jj = 1, jpj
1288           !!Fritsch&Butland's method, 1984 (preferred, but more computation)
1289           !    DO jk = 2, jpkm1-1
1290           !       zdxtmp1 = xsp(ji,jj,jk)   - xsp(ji,jj,jk-1)
1291           !       zdxtmp2 = xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
1292           !       zdf1    = ( fsp(ji,jj,jk)   - fsp(ji,jj,jk-1) ) / zdxtmp1
1293           !       zdf2    = ( fsp(ji,jj,jk+1) - fsp(ji,jj,jk)   ) / zdxtmp2
1294           !
1295           !       zalpha = ( zdxtmp1 + 2._wp * zdxtmp2 ) / ( zdxtmp1 + zdxtmp2 ) / 3._wp
1296           !
1297           !       IF(zdf1 * zdf2 <= 0._wp) THEN
1298           !           zdf(jk) = 0._wp
1299           !       ELSE
1300           !         zdf(jk) = zdf1 * zdf2 / ( ( 1._wp - zalpha ) * zdf1 + zalpha * zdf2 )
1301           !       ENDIF
1302           !    END DO
1303
1304           !!Simply geometric average
1305               DO jk = 2, jpkm1-1
1306                  zdf1 = (fsp(ji,jj,jk) - fsp(ji,jj,jk-1)) / (xsp(ji,jj,jk) - xsp(ji,jj,jk-1))
1307                  zdf2 = (fsp(ji,jj,jk+1) - fsp(ji,jj,jk)) / (xsp(ji,jj,jk+1) - xsp(ji,jj,jk))
1308
1309                  IF(zdf1 * zdf2 <= 0._wp) THEN
1310                     zdf(jk) = 0._wp
1311                  ELSE
1312                     zdf(jk) = 2._wp * zdf1 * zdf2 / (zdf1 + zdf2)
1313                  ENDIF
1314               END DO
1315
1316               zdf(1)     = 1.5_wp * ( fsp(ji,jj,2) - fsp(ji,jj,1) ) / &
1317                          &          ( xsp(ji,jj,2) - xsp(ji,jj,1) ) -  0.5_wp * zdf(2)
1318               zdf(jpkm1) = 1.5_wp * ( fsp(ji,jj,jpkm1) - fsp(ji,jj,jpkm1-1) ) / &
1319                          &          ( xsp(ji,jj,jpkm1) - xsp(ji,jj,jpkm1-1) ) - &
1320                          & 0.5_wp * zdf(jpkm1 - 1)
1321
1322               DO jk = 1, jpkm1 - 1
1323                 zdxtmp = xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
1324                 ztmp1  = (zdf(jk+1) + 2._wp * zdf(jk)) / zdxtmp
1325                 ztmp2  =  6._wp * (fsp(ji,jj,jk+1) - fsp(ji,jj,jk)) / zdxtmp / zdxtmp
1326                 zddf1  = -2._wp * ztmp1 + ztmp2
1327                 ztmp1  = (2._wp * zdf(jk+1) + zdf(jk)) / zdxtmp
1328                 zddf2  =  2._wp * ztmp1 - ztmp2
1329
1330                 dsp(ji,jj,jk) = (zddf2 - zddf1) / 6._wp / zdxtmp
1331                 csp(ji,jj,jk) = ( xsp(ji,jj,jk+1) * zddf1 - xsp(ji,jj,jk)*zddf2 ) / 2._wp / zdxtmp
1332                 bsp(ji,jj,jk) = ( fsp(ji,jj,jk+1) - fsp(ji,jj,jk) ) / zdxtmp - &
1333                               & csp(ji,jj,jk) * ( xsp(ji,jj,jk+1) + xsp(ji,jj,jk) ) - &
1334                               & dsp(ji,jj,jk) * ((xsp(ji,jj,jk+1) + xsp(ji,jj,jk))**2 - &
1335                               &                   xsp(ji,jj,jk+1) * xsp(ji,jj,jk))
1336                 asp(ji,jj,jk) = fsp(ji,jj,jk) - xsp(ji,jj,jk) * (bsp(ji,jj,jk) + &
1337                               &                (xsp(ji,jj,jk) * (csp(ji,jj,jk) + &
1338                               &                 dsp(ji,jj,jk) * xsp(ji,jj,jk))))
1339               END DO
1340            END DO
1341         END DO
1342
1343      ELSE IF (polynomial_type == 2) THEN     ! Linear
1344         DO ji = 1, jpi
1345            DO jj = 1, jpj
1346               DO jk = 1, jpkm1-1
1347                  zdxtmp =xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
1348                  ztmp1 = fsp(ji,jj,jk+1) - fsp(ji,jj,jk)
1349
1350                  dsp(ji,jj,jk) = 0._wp
1351                  csp(ji,jj,jk) = 0._wp
1352                  bsp(ji,jj,jk) = ztmp1 / zdxtmp
1353                  asp(ji,jj,jk) = fsp(ji,jj,jk) - bsp(ji,jj,jk) * xsp(ji,jj,jk)
1354               END DO
1355            END DO
1356         END DO
1357
1358      ELSE
1359           CALL ctl_stop( 'invalid polynomial type in cspline' )
1360      ENDIF
1361
1362   END SUBROUTINE cspline
1363
1364
1365   FUNCTION interp1(x, xl, xr, fl, fr)  RESULT(f)
1366      !!----------------------------------------------------------------------
1367      !!                 ***  ROUTINE interp1  ***
1368      !!
1369      !! ** Purpose :   1-d linear interpolation
1370      !!
1371      !! ** Method  :   interpolation is straight forward
1372      !!                extrapolation is also permitted (no value limit)
1373      !!----------------------------------------------------------------------
1374      IMPLICIT NONE
1375      REAL(wp), INTENT(in) ::  x, xl, xr, fl, fr
1376      REAL(wp)             ::  f ! result of the interpolation (extrapolation)
1377      REAL(wp)             ::  zdeltx
1378      !!----------------------------------------------------------------------
1379
1380      zdeltx = xr - xl
1381      IF(abs(zdeltx) <= 10._wp * EPSILON(x)) THEN
1382        f = 0.5_wp * (fl + fr)
1383      ELSE
1384        f = ( (x - xl ) * fr - ( x - xr ) * fl ) / zdeltx
1385      ENDIF
1386
1387   END FUNCTION interp1
1388
1389
1390   FUNCTION interp2(x, a, b, c, d)  RESULT(f)
1391      !!----------------------------------------------------------------------
1392      !!                 ***  ROUTINE interp1  ***
1393      !!
1394      !! ** Purpose :   1-d constrained cubic spline interpolation
1395      !!
1396      !! ** Method  :  cubic spline interpolation
1397      !!
1398      !!----------------------------------------------------------------------
1399      IMPLICIT NONE
1400      REAL(wp), INTENT(in) ::  x, a, b, c, d
1401      REAL(wp)             ::  f ! value from the interpolation
1402      !!----------------------------------------------------------------------
1403
1404      f = a + x* ( b + x * ( c + d * x ) )
1405
1406   END FUNCTION interp2
1407
1408
1409   FUNCTION interp3(x, a, b, c, d)  RESULT(f)
1410      !!----------------------------------------------------------------------
1411      !!                 ***  ROUTINE interp1  ***
1412      !!
1413      !! ** Purpose :   Calculate the first order of deriavtive of
1414      !!                a cubic spline function y=a+b*x+c*x^2+d*x^3
1415      !!
1416      !! ** Method  :   f=dy/dx=b+2*c*x+3*d*x^2
1417      !!
1418      !!----------------------------------------------------------------------
1419      IMPLICIT NONE
1420      REAL(wp), INTENT(in) ::  x, a, b, c, d
1421      REAL(wp)             ::  f ! value from the interpolation
1422      !!----------------------------------------------------------------------
1423
1424      f = b + x * ( 2._wp * c + 3._wp * d * x)
1425
1426   END FUNCTION interp3
1427
1428
1429   FUNCTION integ_spline(xl, xr, a, b, c, d)  RESULT(f)
1430      !!----------------------------------------------------------------------
1431      !!                 ***  ROUTINE interp1  ***
1432      !!
1433      !! ** Purpose :   1-d constrained cubic spline integration
1434      !!
1435      !! ** Method  :  integrate polynomial a+bx+cx^2+dx^3 from xl to xr
1436      !!
1437      !!----------------------------------------------------------------------
1438      IMPLICIT NONE
1439      REAL(wp), INTENT(in) ::  xl, xr, a, b, c, d
1440      REAL(wp)             ::  za1, za2, za3
1441      REAL(wp)             ::  f                   ! integration result
1442      !!----------------------------------------------------------------------
1443
1444      za1 = 0.5_wp * b
1445      za2 = c / 3.0_wp
1446      za3 = 0.25_wp * d
1447
1448      f  = xr * ( a + xr * ( za1 + xr * ( za2 + za3 * xr ) ) ) - &
1449         & xl * ( a + xl * ( za1 + xl * ( za2 + za3 * xl ) ) )
1450
1451   END FUNCTION integ_spline
1452
1453   !!======================================================================
1454END MODULE dynhpg
1455
Note: See TracBrowser for help on using the repository browser.