source: branches/UKMO/dev_r5518_GO6_package/NEMOGCM/NEMO/OPA_SRC/ICB/icbthm.F90 @ 6491

Last change on this file since 6491 was 6491, checked in by davestorkey, 5 years ago

Commit remaining changes to UKMO/r5518_GO6_package branch from following branches:
UKMO/dev_r5021_nn_etau_revision@6238
UKMO/dev_r5107_mld_zint@5534
UKMO/dev_r5107_eorca025_closea@6390
UKMO/restart_datestamp@5539
UKMO/icebergs_latent_heat@5821
UKMO/icebergs_restart_single_file_corrected@6480
UKMO/product_diagnostics@5971
UKMO/antarctic_partial_slip@5961
Custom merge into /branches/UKMO/dev_r5518_GO6_package/NEMOGCM: r5961 cf. r5958 of /branches/UKMO/antarctic_partial_slip/NEMOGCM@6490

Custom merge into /branches/UKMO/dev_r5518_GO6_package/NEMOGCM: r6349 cf. r5962 of /branches/UKMO/product_diagnostics/NEMOGCM@6490

Custom merge into /branches/UKMO/dev_r5518_GO6_package/NEMOGCM: r6480 cf. r6479 of /branches/UKMO/icebergs_restart_single_file_corrected/NEMOGCM@6490

Custom merge into /branches/UKMO/dev_r5518_GO6_package/NEMOGCM: r5986 cf. r5852 of /branches/UKMO/icebergs_restart_single_file/NEMOGCM@6490

Custom merge into /branches/UKMO/dev_r5518_GO6_package/NEMOGCM: r5821 cf. r5808 of /branches/UKMO/icebergs_latent_heat/NEMOGCM@6490

File size: 11.2 KB
Line 
1MODULE icbthm
2
3   !!======================================================================
4   !!                       ***  MODULE  icbthm  ***
5   !! Icebergs:  thermodynamics routines for icebergs
6   !!======================================================================
7   !! History : 3.3.1 !  2010-01  (Martin&Adcroft) Original code
8   !!            -    !  2011-03  (Madec)          Part conversion to NEMO form
9   !!            -    !                            Removal of mapping from another grid
10   !!            -    !  2011-04  (Alderson)       Split into separate modules
11   !!            -    !  2011-05  (Alderson)       Use tmask instead of tmask_i
12   !!----------------------------------------------------------------------
13   !!----------------------------------------------------------------------
14   !!   icb_thm : initialise
15   !!             reference for equations - M = Martin + Adcroft, OM 34, 2010
16   !!----------------------------------------------------------------------
17   USE par_oce        ! NEMO parameters
18   USE dom_oce        ! NEMO domain
19   USE in_out_manager ! NEMO IO routines, numout in particular
20   USE iom
21   USE lib_mpp        ! NEMO MPI routines, ctl_stop in particular
22   USE phycst         ! NEMO physical constants
23   USE sbc_oce
24
25   USE icb_oce        ! define iceberg arrays
26   USE icbutl         ! iceberg utility routines
27   USE icbdia         ! iceberg budget routines
28
29   IMPLICIT NONE
30   PRIVATE
31
32   PUBLIC   icb_thm ! routine called in icbstp.F90 module
33
34   !! $Id$
35CONTAINS
36
37   SUBROUTINE icb_thm( kt )
38      !!----------------------------------------------------------------------
39      !!                  ***  ROUTINE icb_thm  ***
40      !!
41      !! ** Purpose :   compute the iceberg thermodynamics.
42      !!
43      !! ** Method  : - See Martin & Adcroft, Ocean Modelling 34, 2010
44      !!----------------------------------------------------------------------
45      INTEGER, INTENT(in) ::   kt   ! timestep number, just passed to icb_utl_print_berg
46      !
47      INTEGER  ::   ii, ij
48      REAL(wp) ::   zM, zT, zW, zL, zSST, zVol, zLn, zWn, zTn, znVol, zIC, zDn
49      REAL(wp) ::   zMv, zMe, zMb, zmelt, zdvo, zdva, zdM, zSs, zdMe, zdMb, zdMv
50      REAL(wp) ::   zMnew, zMnew1, zMnew2, zheat
51      REAL(wp) ::   zMbits, znMbits, zdMbitsE, zdMbitsM, zLbits, zAbits, zMbb
52      REAL(wp) ::   zxi, zyj, zff, z1_rday, z1_e1e2, zdt, z1_dt, z1_dt_e1e2
53      TYPE(iceberg), POINTER ::   this, next
54      TYPE(point)  , POINTER ::   pt
55      !!----------------------------------------------------------------------
56      !
57      z1_rday = 1._wp / rday
58     
59      ! we're either going to ignore berg fresh water melt flux and associated heat
60      ! or we pass it into the ocean, so at this point we set them both to zero,
61      ! accumulate the contributions to them from each iceberg in the while loop following
62      ! and then pass them (or not) to the ocean
63      !
64      berg_grid%floating_melt(:,:) = 0._wp
65      berg_grid%calving_hflx(:,:)  = 0._wp
66   
67      this => first_berg
68      DO WHILE( associated(this) )
69         !
70         pt => this%current_point
71         nknberg = this%number(1)
72         CALL icb_utl_interp( pt%xi, pt%e1, pt%uo, pt%ui, pt%ua, pt%ssh_x, &
73         &                    pt%yj, pt%e2, pt%vo, pt%vi, pt%va, pt%ssh_y, &
74         &                 pt%sst, pt%cn, pt%hi, zff )
75         !
76         zSST = pt%sst
77         zIC  = MIN( 1._wp, pt%cn + rn_sicn_shift )     ! Shift sea-ice concentration       !!gm ???
78         zM   = pt%mass
79         zT   = pt%thickness                               ! total thickness
80       ! D   = (rn_rho_bergs/pp_rho_seawater)*zT ! draught (keel depth)
81       ! F   = zT - D ! freeboard
82         zW   = pt%width
83         zL   = pt%length
84         zxi  = pt%xi                                      ! position in (i,j) referential
85         zyj  = pt%yj
86         ii  = INT( zxi + 0.5 )                            ! T-cell of the berg
87         ii  = mi1( ii )
88         ij  = INT( zyj + 0.5 )             
89         ij  = mj1( ij )
90         zVol = zT * zW * zL
91         zdt = berg_dt   ;   z1_dt = 1._wp / zdt
92
93         ! Environment
94         zdvo = SQRT( (pt%uvel-pt%uo)**2 + (pt%vvel-pt%vo)**2 )
95         zdva = SQRT( (pt%ua  -pt%uo)**2 + (pt%va  -pt%vo)**2 )
96         zSs  = 1.5 * SQRT( zdva ) + 0.1 * zdva                ! Sea state      (eqn M.A9)
97
98         ! Melt rates in m/s (i.e. division by rday)
99         zMv = MAX( 7.62e-3*zSST+1.29e-3*(zSST**2)            , 0._wp ) * z1_rday   ! Buoyant convection at sides (eqn M.A10)
100         zMb = MAX( 0.58*(zdvo**0.8)*(zSST+4.0)/(zL**0.2)      , 0._wp ) * z1_rday   ! Basal turbulent melting     (eqn M.A7 )
101         zMe = MAX( 1./12.*(zSST+2.)*zSs*(1+cos(rpi*(zIC**3))) , 0._wp ) * z1_rday   ! Wave erosion                (eqn M.A8 )
102
103         IF( ln_operator_splitting ) THEN      ! Operator split update of volume/mass
104            zTn    = MAX( zT - zMb*zdt , 0._wp )         ! new total thickness (m)
105            znVol  = zTn * zW * zL                        ! new volume (m^3)
106            zMnew1 = (znVol/zVol) * zM                    ! new mass (kg)
107            zdMb   = zM - zMnew1                         ! mass lost to basal melting (>0) (kg)
108            !
109            zLn    = MAX( zL - zMv*zdt , 0._wp )         ! new length (m)
110            zWn    = MAX( zW - zMv*zdt , 0._wp )         ! new width (m)
111            znVol  = zTn * zWn * zLn                      ! new volume (m^3)
112            zMnew2 = (znVol/zVol) * zM                    ! new mass (kg)
113            zdMv   = zMnew1 - zMnew2                     ! mass lost to buoyant convection (>0) (kg)
114            !
115            zLn    = MAX( zLn - zMe*zdt , 0._wp )        ! new length (m)
116            zWn    = MAX( zWn - zMe*zdt , 0._wp )        ! new width (m)
117            znVol  = zTn * zWn * zLn                      ! new volume (m^3)
118            zMnew  = ( znVol / zVol ) * zM                ! new mass (kg)
119            zdMe   = zMnew2 - zMnew                      ! mass lost to erosion (>0) (kg)
120            zdM    = zM - zMnew                          ! mass lost to all erosion and melting (>0) (kg)
121            !
122         ELSE                                         ! Update dimensions of berg
123            zLn = MAX( zL -(zMv+zMe)*zdt ,0._wp )         ! (m)
124            zWn = MAX( zW -(zMv+zMe)*zdt ,0._wp )         ! (m)
125            zTn = MAX( zT - zMb    *zdt ,0._wp )         ! (m)
126            ! Update volume and mass of berg
127            znVol = zTn*zWn*zLn                           ! (m^3)
128            zMnew = (znVol/zVol)*zM                       ! (kg)
129            zdM   = zM - zMnew                           ! (kg)
130            zdMb = (zM/zVol) * (zW*   zL ) *zMb*zdt         ! approx. mass loss to basal melting (kg)
131            zdMe = (zM/zVol) * (zT*(zW+zL)) *zMe*zdt         ! approx. mass lost to erosion (kg)
132            zdMv = (zM/zVol) * (zT*(zW+zL)) *zMv*zdt         ! approx. mass loss to buoyant convection (kg)
133         ENDIF
134
135         IF( rn_bits_erosion_fraction > 0._wp ) THEN      ! Bergy bits
136            !
137            zMbits   = pt%mass_of_bits                                               ! mass of bergy bits (kg)
138            zdMbitsE = rn_bits_erosion_fraction * zdMe                        ! change in mass of bits (kg)
139            znMbits  = zMbits + zdMbitsE                                               ! add new bergy bits to mass (kg)
140            zLbits   = MIN( zL, zW, zT, 40._wp )                                        ! assume bergy bits are smallest dimension or 40 meters
141            zAbits   = ( zMbits / rn_rho_bergs ) / zLbits                           ! Effective bottom area (assuming T=Lbits)
142            zMbb     = MAX( 0.58*(zdvo**0.8)*(zSST+2.0)/(zLbits**0.2), 0.) * z1_rday    ! Basal turbulent melting (for bits)
143            zMbb     = rn_rho_bergs * zAbits * zMbb                                 ! in kg/s
144            zdMbitsM = MIN( zMbb*zdt , znMbits )                                       ! bergy bits mass lost to melting (kg)
145            znMbits  = znMbits-zdMbitsM                                                ! remove mass lost to bergy bits melt
146            IF( zMnew == 0._wp ) THEN                                                ! if parent berg has completely melted then
147               zdMbitsM = zdMbitsM + znMbits                                           ! instantly melt all the bergy bits
148               znMbits  = 0._wp
149            ENDIF
150         ELSE                                                     ! No bergy bits
151            zAbits   = 0._wp
152            zdMbitsE = 0._wp
153            zdMbitsM = 0._wp
154            znMbits  = pt%mass_of_bits                             ! retain previous value incase non-zero
155         ENDIF
156
157         ! use tmask rather than tmask_i when dealing with icebergs
158         IF( tmask(ii,ij,1) /= 0._wp ) THEN    ! Add melting to the grid and field diagnostics
159            z1_e1e2    = 1._wp / e1e2t(ii,ij) * this%mass_scaling
160            z1_dt_e1e2 = z1_dt * z1_e1e2
161            zmelt    = ( zdM - ( zdMbitsE - zdMbitsM ) ) * z1_dt   ! kg/s
162            berg_grid%floating_melt(ii,ij) = berg_grid%floating_melt(ii,ij) + zmelt    * z1_e1e2    ! kg/m2/s
163!            zheat = zmelt * pt%heat_density              ! kg/s x J/kg = J/s
164            zheat = zmelt * lfus                           !rma kg/s x J/kg (latent heat of fusion) = J/s
165            berg_grid%calving_hflx (ii,ij) = berg_grid%calving_hflx (ii,ij) + zheat    * z1_e1e2    ! W/m2
166            CALL icb_dia_melt( ii, ij, zMnew, zheat, this%mass_scaling,       &
167            &                          zdM, zdMbitsE, zdMbitsM, zdMb, zdMe,   &
168            &                          zdMv, z1_dt_e1e2 )
169         ELSE
170            WRITE(numout,*) 'icb_thm: berg ',this%number(:),' appears to have grounded  at ',narea,ii,ij
171            CALL icb_utl_print_berg( this, kt )
172            WRITE(numout,*) 'msk=',tmask(ii,ij,1), e1e2t(ii,ij)
173            CALL ctl_stop('icb_thm', 'berg appears to have grounded!')
174         ENDIF
175
176         ! Rolling
177         zDn = ( rn_rho_bergs / pp_rho_seawater ) * zTn       ! draught (keel depth)
178         IF( zDn > 0._wp .AND. MAX(zWn,zLn) < SQRT( 0.92*(zDn**2) + 58.32*zDn ) ) THEN
179            zT  = zTn
180            zTn = zWn
181            zWn = zT
182         endif
183
184         ! Store the new state of iceberg (with L>W)
185         pt%mass         = zMnew
186         pt%mass_of_bits = znMbits
187         pt%thickness    = zTn
188         pt%width        = min(zWn,zLn)
189         pt%length       = max(zWn,zLn)
190
191         next=>this%next
192
193!!gm  add a test to avoid over melting ?
194
195         IF( zMnew <= 0._wp ) THEN       ! Delete the berg if completely melted
196            CALL icb_utl_delete( first_berg, this )
197            !
198         ELSE                            ! Diagnose mass distribution on grid
199            z1_e1e2 = 1._wp / e1e2t(ii,ij) * this%mass_scaling
200            CALL icb_dia_size( ii, ij, zWn, zLn, zAbits,   &
201            &                  this%mass_scaling, zMnew, znMbits, z1_e1e2)
202         ENDIF
203         !
204         this=>next
205         !
206      END DO
207     
208      ! now use melt and associated heat flux in ocean (or not)
209      !
210      IF(.NOT. ln_passive_mode ) THEN
211         emp (:,:) = emp (:,:) - berg_grid%floating_melt(:,:)
212         qns (:,:) = qns (:,:) - berg_grid%calving_hflx (:,:) 
213      ENDIF
214      !
215   END SUBROUTINE icb_thm
216
217   !!======================================================================
218END MODULE icbthm
Note: See TracBrowser for help on using the repository browser.