New URL for NEMO forge! http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.

sbcrnf.F90 in branches/UKMO/dev_r5518_GO6_package/NEMOGCM/NEMO/OPA_SRC/SBC – NEMO

Context Navigation

source: branches/UKMO/dev_r5518_GO6_package/NEMOGCM/NEMO/OPA_SRC/SBC/sbcrnf.F90 @ 10269

Last change on this file since 10269 was 9321, checked in by davestorkey, 6 years ago
UKMO/dev_r5518_GO6_package branch: allow timing of I/O and coupling only. See GMED ticket 374.
File size: 29.2 KB

Rev	Line
[888]	1	MODULE sbcrnf
	2	!!======================================================================
	3	!! * MODULE sbcrnf *
	4	!! Ocean forcing: river runoff
	5	!!=====================================================================
[2528]	6	!! History : OPA ! 2000-11 (R. Hordoir, E. Durand) NetCDF FORMAT
	7	!! NEMO 1.0 ! 2002-09 (G. Madec) F90: Free form and module
[3764]	8	!! 3.0 ! 2006-07 (G. Madec) Surface module
[2528]	9	!! 3.2 ! 2009-04 (B. Lemaire) Introduce iom_put
	10	!! 3.3 ! 2010-10 (R. Furner, G. Madec) runoff distributed over ocean levels
[888]	11	!!----------------------------------------------------------------------
	12
	13	!!----------------------------------------------------------------------
	14	!! sbc_rnf : monthly runoffs read in a NetCDF file
[1116]	15	!! sbc_rnf_init : runoffs initialisation
[888]	16	!! rnf_mouth : set river mouth mask
	17	!!----------------------------------------------------------------------
	18	USE dom_oce ! ocean space and time domain
	19	USE phycst ! physical constants
	20	USE sbc_oce ! surface boundary condition variables
[4990]	21	USE sbcisf ! PM we could remove it I think
[2715]	22	USE closea ! closed seas
[2528]	23	USE fldread ! read input field at current time step
[888]	24	USE in_out_manager ! I/O manager
	25	USE iom ! I/O module
[2715]	26	USE lib_mpp ! MPP library
[4990]	27	USE eosbn2
	28	USE wrk_nemo ! Memory allocation
[9321]	29	USE timing
[888]	30
	31	IMPLICIT NONE
	32	PRIVATE
	33
[2528]	34	PUBLIC sbc_rnf ! routine call in sbcmod module
[5407]	35	PUBLIC sbc_rnf_div ! routine called in divcurl module
[2715]	36	PUBLIC sbc_rnf_alloc ! routine call in sbcmod module
[3764]	37	PUBLIC sbc_rnf_init ! (PUBLIC for TAM)
[2715]	38	! !!* namsbc_rnf namelist *
[5431]	39	CHARACTER(len=100) :: cn_dir !: Root directory for location of rnf files
	40	LOGICAL :: ln_rnf_depth !: depth river runoffs attribute specified in a file
[5385]	41	LOGICAL :: ln_rnf_depth_ini !: depth river runoffs computed at the initialisation
	42	REAL(wp) :: rn_rnf_max !: maximum value of the runoff climatologie ( ln_rnf_depth_ini = .true )
	43	REAL(wp) :: rn_dep_max !: depth over which runoffs is spread ( ln_rnf_depth_ini = .true )
	44	INTEGER :: nn_rnf_depth_file !: create (=1) a runoff depth file or not (=0)
[5431]	45	LOGICAL :: ln_rnf_tem !: temperature river runoffs attribute specified in a file
[4147]	46	LOGICAL , PUBLIC :: ln_rnf_sal !: salinity river runoffs attribute specified in a file
	47	TYPE(FLD_N) , PUBLIC :: sn_rnf !: information about the runoff file to be read
[5431]	48	TYPE(FLD_N) :: sn_cnf !: information about the runoff mouth file to be read
[4147]	49	TYPE(FLD_N) :: sn_s_rnf !: information about the salinities of runoff file to be read
	50	TYPE(FLD_N) :: sn_t_rnf !: information about the temperatures of runoff file to be read
	51	TYPE(FLD_N) :: sn_dep_rnf !: information about the depth which river inflow affects
	52	LOGICAL , PUBLIC :: ln_rnf_mouth !: specific treatment in mouths vicinity
[5431]	53	REAL(wp) :: rn_hrnf !: runoffs, depth over which enhanced vertical mixing is used
[4147]	54	REAL(wp) , PUBLIC :: rn_avt_rnf !: runoffs, value of the additional vertical mixing coef. [m2/s]
[6498]	55	REAL(wp) , PUBLIC :: rn_rfact !: multiplicative factor for runoff
[888]	56
[5407]	57	LOGICAL , PUBLIC :: l_rnfcpl = .false. ! runoffs recieved from oasis
	58
[2715]	59	INTEGER , PUBLIC :: nkrnf = 0 !: nb of levels over which Kz is increased at river mouths
	60	REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:) :: rnfmsk !: river mouth mask (hori.)
	61	REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:) :: rnfmsk_z !: river mouth mask (vert.)
	62	REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:) :: h_rnf !: depth of runoff in m
	63	INTEGER, PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:) :: nk_rnf !: depth of runoff in model levels
[3764]	64	REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: rnf_tsc_b, rnf_tsc !: before and now T & S runoff contents [K.m/s & PSU.m/s]
[888]	65
[5431]	66	TYPE(FLD), ALLOCATABLE, DIMENSION(:) :: sf_rnf ! structure: river runoff (file information, fields read)
	67	TYPE(FLD), ALLOCATABLE, DIMENSION(:) :: sf_s_rnf ! structure: river runoff salinity (file information, fields read)
	68	TYPE(FLD), ALLOCATABLE, DIMENSION(:) :: sf_t_rnf ! structure: river runoff temperature (file information, fields read)
[2528]	69
	70	!! * Substitutions
	71	# include "domzgr_substitute.h90"
[888]	72	!!----------------------------------------------------------------------
[2528]	73	!! NEMO/OPA 3.3 , NEMO Consortium (2010)
[1146]	74	!! $Id$
[2528]	75	!! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
[888]	76	!!----------------------------------------------------------------------
	77	CONTAINS
	78
[2715]	79	INTEGER FUNCTION sbc_rnf_alloc()
	80	!!----------------------------------------------------------------------
	81	!! * ROUTINE sbc_rnf_alloc *
	82	!!----------------------------------------------------------------------
	83	ALLOCATE( rnfmsk(jpi,jpj) , rnfmsk_z(jpk) , &
	84	& h_rnf (jpi,jpj) , nk_rnf (jpi,jpj) , &
	85	& rnf_tsc_b(jpi,jpj,jpts) , rnf_tsc (jpi,jpj,jpts) , STAT=sbc_rnf_alloc )
	86	!
	87	IF( lk_mpp ) CALL mpp_sum ( sbc_rnf_alloc )
	88	IF( sbc_rnf_alloc > 0 ) CALL ctl_warn('sbc_rnf_alloc: allocation of arrays failed')
	89	END FUNCTION sbc_rnf_alloc
	90
[3625]	91
[888]	92	SUBROUTINE sbc_rnf( kt )
	93	!!----------------------------------------------------------------------
	94	!! * ROUTINE sbc_rnf *
[3764]	95	!!
[888]	96	!! ** Purpose : Introduce a climatological run off forcing
	97	!!
[3764]	98	!! ** Method : Set each river mouth with a monthly climatology
[888]	99	!! provided from different data.
	100	!! CAUTION : upward water flux, runoff forced to be < 0
	101	!!
	102	!! ** Action : runoff updated runoff field at time-step kt
	103	!!----------------------------------------------------------------------
	104	INTEGER, INTENT(in) :: kt ! ocean time step
[3625]	105	!
[3832]	106	INTEGER :: ji, jj ! dummy loop indices
	107	INTEGER :: z_err = 0 ! dummy integer for error handling
[888]	108	!!----------------------------------------------------------------------
[4990]	109	REAL(wp), DIMENSION(:,:), POINTER :: ztfrz ! freezing point used for temperature correction
[3764]	110	!
[4990]	111	CALL wrk_alloc( jpi,jpj, ztfrz)
[7993]	112	!
[5407]	113	! !-------------------!
	114	! ! Update runoff !
	115	! !-------------------!
	116	!
	117	IF( .NOT. l_rnfcpl ) CALL fld_read ( kt, nn_fsbc, sf_rnf ) ! Read Runoffs data and provide it at kt
	118	IF( ln_rnf_tem ) CALL fld_read ( kt, nn_fsbc, sf_t_rnf ) ! idem for runoffs temperature if required
	119	IF( ln_rnf_sal ) CALL fld_read ( kt, nn_fsbc, sf_s_rnf ) ! idem for runoffs salinity if required
	120	!
	121	IF( MOD( kt - 1, nn_fsbc ) == 0 ) THEN
[888]	122	!
[5407]	123	IF( .NOT. l_rnfcpl ) rnf(:,:) = rn_rfact * ( sf_rnf(1)%fnow(:,:,1) ) ! updated runoff value at time step kt
[8302]	124	CALL lbc_lnk(rnf(:,:), 'T', 1._wp)
[2528]	125	!
[5407]	126	! ! set temperature & salinity content of runoffs
	127	IF( ln_rnf_tem ) THEN ! use runoffs temperature data
	128	rnf_tsc(:,:,jp_tem) = ( sf_t_rnf(1)%fnow(:,:,1) ) * rnf(:,:) * r1_rau0
	129	WHERE( sf_t_rnf(1)%fnow(:,:,1) == -999._wp ) ! if missing data value use SST as runoffs temperature
	130	rnf_tsc(:,:,jp_tem) = sst_m(:,:) * rnf(:,:) * r1_rau0
[2528]	131	END WHERE
[5407]	132	WHERE( sf_t_rnf(1)%fnow(:,:,1) == -222._wp ) ! where fwf comes from melting of ice shelves or iceberg
	133	ztfrz(:,:) = -1.9 !tfreez( sss_m(:,:) ) !PM to be discuss (trouble if sensitivity study)
	134	rnf_tsc(:,:,jp_tem) = ztfrz(:,:) * rnf(:,:) * r1_rau0 - rnf(:,:) * lfusisf * r1_rau0_rcp
	135	END WHERE
	136	ELSE ! use SST as runoffs temperature
	137	rnf_tsc(:,:,jp_tem) = sst_m(:,:) * rnf(:,:) * r1_rau0
[2528]	138	ENDIF
[5407]	139	! ! use runoffs salinity data
	140	IF( ln_rnf_sal ) rnf_tsc(:,:,jp_sal) = ( sf_s_rnf(1)%fnow(:,:,1) ) * rnf(:,:) * r1_rau0
	141	! ! else use S=0 for runoffs (done one for all in the init)
	142	CALL iom_put( "runoffs", rnf ) ! output runoffs arrays
[2528]	143	ENDIF
	144	!
[5407]	145	! ! ---------------------------------------- !
[2528]	146	IF( kt == nit000 ) THEN ! set the forcing field at nit000 - 1 !
	147	! ! ---------------------------------------- !
	148	IF( ln_rstart .AND. & !* Restart: read in restart file
[3764]	149	& iom_varid( numror, 'rnf_b', ldstop = .FALSE. ) > 0 ) THEN
[2528]	150	IF(lwp) WRITE(numout,*) ' nit000-1 runoff forcing fields red in the restart file'
[9321]	151	IF(nn_timing == 2) CALL timing_start('iom_rstget')
[2528]	152	CALL iom_get( numror, jpdom_autoglo, 'rnf_b', rnf_b ) ! before runoff
	153	CALL iom_get( numror, jpdom_autoglo, 'rnf_hc_b', rnf_tsc_b(:,:,jp_tem) ) ! before heat content of runoff
	154	CALL iom_get( numror, jpdom_autoglo, 'rnf_sc_b', rnf_tsc_b(:,:,jp_sal) ) ! before salinity content of runoff
[9321]	155	IF(nn_timing == 2) CALL timing_stop('iom_rstget')
[2528]	156	ELSE !* no restart: set from nit000 values
	157	IF(lwp) WRITE(numout,*) ' nit000-1 runoff forcing fields set to nit000'
[5407]	158	rnf_b (:,: ) = rnf (:,: )
	159	rnf_tsc_b(:,:,:) = rnf_tsc(:,:,:)
[2528]	160	ENDIF
	161	ENDIF
	162	! ! ---------------------------------------- !
	163	IF( lrst_oce ) THEN ! Write in the ocean restart file !
	164	! ! ---------------------------------------- !
	165	IF(lwp) WRITE(numout,*)
	166	IF(lwp) WRITE(numout,*) 'sbcrnf : runoff forcing fields written in ocean restart file ', &
	167	& 'at it= ', kt,' date= ', ndastp
	168	IF(lwp) WRITE(numout,*) '~~~~'
[9321]	169	IF(nn_timing == 2) CALL timing_start('iom_rstput')
[2528]	170	CALL iom_rstput( kt, nitrst, numrow, 'rnf_b' , rnf )
	171	CALL iom_rstput( kt, nitrst, numrow, 'rnf_hc_b', rnf_tsc(:,:,jp_tem) )
	172	CALL iom_rstput( kt, nitrst, numrow, 'rnf_sc_b', rnf_tsc(:,:,jp_sal) )
[9321]	173	IF(nn_timing == 2) CALL timing_stop('iom_rstput')
[2528]	174	ENDIF
[5407]	175	!
[4990]	176	CALL wrk_dealloc( jpi,jpj, ztfrz)
[2528]	177	!
	178	END SUBROUTINE sbc_rnf
	179
	180
	181	SUBROUTINE sbc_rnf_div( phdivn )
	182	!!----------------------------------------------------------------------
	183	!! * ROUTINE sbc_rnf *
[3764]	184	!!
[2528]	185	!! ** Purpose : update the horizontal divergence with the runoff inflow
	186	!!
[3764]	187	!! ** Method :
	188	!! CAUTION : rnf is positive (inflow) decreasing the
[2528]	189	!! divergence and expressed in m/s
	190	!!
	191	!! ** Action : phdivn decreased by the runoff inflow
	192	!!----------------------------------------------------------------------
[2715]	193	REAL(wp), DIMENSION(:,:,:), INTENT(inout) :: phdivn ! horizontal divergence
[2528]	194	!!
	195	INTEGER :: ji, jj, jk ! dummy loop indices
	196	REAL(wp) :: zfact ! local scalar
	197	!!----------------------------------------------------------------------
	198	!
	199	zfact = 0.5_wp
	200	!
[5503]	201	IF( ln_rnf_depth .OR. ln_rnf_depth_ini ) THEN !== runoff distributed over several levels ==!
[3764]	202	IF( lk_vvl ) THEN ! variable volume case
[2528]	203	DO jj = 1, jpj ! update the depth over which runoffs are distributed
	204	DO ji = 1, jpi
[3764]	205	h_rnf(ji,jj) = 0._wp
[2528]	206	DO jk = 1, nk_rnf(ji,jj) ! recalculates h_rnf to be the depth in metres
[3764]	207	h_rnf(ji,jj) = h_rnf(ji,jj) + fse3t(ji,jj,jk) ! to the bottom of the relevant grid box
	208	END DO
[2528]	209	! ! apply the runoff input flow
	210	DO jk = 1, nk_rnf(ji,jj)
	211	phdivn(ji,jj,jk) = phdivn(ji,jj,jk) - ( rnf(ji,jj) + rnf_b(ji,jj) ) * zfact * r1_rau0 / h_rnf(ji,jj)
	212	END DO
	213	END DO
	214	END DO
	215	ELSE ! constant volume case : just apply the runoff input flow
[888]	216	DO jj = 1, jpj
	217	DO ji = 1, jpi
[2528]	218	DO jk = 1, nk_rnf(ji,jj)
	219	phdivn(ji,jj,jk) = phdivn(ji,jj,jk) - ( rnf(ji,jj) + rnf_b(ji,jj) ) * zfact * r1_rau0 / h_rnf(ji,jj)
	220	END DO
[888]	221	END DO
	222	END DO
	223	ENDIF
[2528]	224	ELSE !== runoff put only at the surface ==!
	225	IF( lk_vvl ) THEN ! variable volume case
	226	h_rnf(:,:) = fse3t(:,:,1) ! recalculate h_rnf to be depth of top box
[1303]	227	ENDIF
[2528]	228	phdivn(:,:,1) = phdivn(:,:,1) - ( rnf(:,:) + rnf_b(:,:) ) * zfact * r1_rau0 / fse3t(:,:,1)
[888]	229	ENDIF
	230	!
[2528]	231	END SUBROUTINE sbc_rnf_div
[888]	232
	233
[2528]	234	SUBROUTINE sbc_rnf_init
[1116]	235	!!----------------------------------------------------------------------
	236	!! * ROUTINE sbc_rnf_init *
	237	!!
	238	!! ** Purpose : Initialisation of the runoffs if (ln_rnf=T)
	239	!!
	240	!! ** Method : - read the runoff namsbc_rnf namelist
	241	!!
	242	!! ** Action : - read parameters
	243	!!----------------------------------------------------------------------
[3764]	244	CHARACTER(len=32) :: rn_dep_file ! runoff file name
[5385]	245	INTEGER :: ji, jj, jk, jm ! dummy loop indices
[2528]	246	INTEGER :: ierror, inum ! temporary integer
[4147]	247	INTEGER :: ios ! Local integer output status for namelist read
[5385]	248	INTEGER :: nbrec ! temporary integer
	249	REAL(wp) :: zacoef
	250	REAL(wp), DIMENSION(12) :: zrec ! times records
	251	REAL(wp), DIMENSION(:,:,:), ALLOCATABLE :: zrnfcl
	252	REAL(wp), DIMENSION(:,: ), ALLOCATABLE :: zrnf
[3625]	253	!
[5407]	254	NAMELIST/namsbc_rnf/ cn_dir , ln_rnf_depth, ln_rnf_tem, ln_rnf_sal, &
[3764]	255	& sn_rnf, sn_cnf , sn_s_rnf , sn_t_rnf , sn_dep_rnf, &
[5385]	256	& ln_rnf_mouth , rn_hrnf , rn_avt_rnf, rn_rfact, &
	257	& ln_rnf_depth_ini , rn_dep_max , rn_rnf_max, nn_rnf_depth_file
[1116]	258	!!----------------------------------------------------------------------
[3625]	259	!
[5431]	260	! !== allocate runoff arrays
	261	IF( sbc_rnf_alloc() /= 0 ) CALL ctl_stop( 'STOP', 'sbc_rnf_alloc : unable to allocate arrays' )
	262	!
	263	IF( .NOT. ln_rnf ) THEN ! no specific treatment in vicinity of river mouths
	264	ln_rnf_mouth = .FALSE. ! default definition needed for example by sbc_ssr or by tra_adv_muscl
	265	nkrnf = 0
	266	rnf (:,:) = 0.0_wp
	267	rnf_b (:,:) = 0.0_wp
	268	rnfmsk (:,:) = 0.0_wp
	269	rnfmsk_z(:) = 0.0_wp
	270	RETURN
	271	ENDIF
	272	!
[1116]	273	! ! ============
	274	! ! Namelist
	275	! ! ============
[4147]	276	!
	277	REWIND( numnam_ref ) ! Namelist namsbc_rnf in reference namelist : Runoffs
	278	READ ( numnam_ref, namsbc_rnf, IOSTAT = ios, ERR = 901)
	279	901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc_rnf in reference namelist', lwp )
[1116]	280
[4147]	281	REWIND( numnam_cfg ) ! Namelist namsbc_rnf in configuration namelist : Runoffs
	282	READ ( numnam_cfg, namsbc_rnf, IOSTAT = ios, ERR = 902 )
	283	902 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc_rnf in configuration namelist', lwp )
[4624]	284	IF(lwm) WRITE ( numond, namsbc_rnf )
[1116]	285	!
	286	! ! Control print
	287	IF(lwp) THEN
	288	WRITE(numout,*)
	289	WRITE(numout,*) 'sbc_rnf : runoff '
	290	WRITE(numout,*) '~~~~~~~ '
	291	WRITE(numout,*) ' Namelist namsbc_rnf'
	292	WRITE(numout,*) ' specific river mouths treatment ln_rnf_mouth = ', ln_rnf_mouth
	293	WRITE(numout,*) ' river mouth additional Kz rn_avt_rnf = ', rn_avt_rnf
	294	WRITE(numout,*) ' depth of river mouth additional mixing rn_hrnf = ', rn_hrnf
[3764]	295	WRITE(numout,*) ' multiplicative factor for runoff rn_rfact = ', rn_rfact
[1116]	296	ENDIF
	297	! ! ==================
	298	! ! Type of runoff
	299	! ! ==================
	300	!
[5407]	301	IF( .NOT. l_rnfcpl ) THEN
[2528]	302	ALLOCATE( sf_rnf(1), STAT=ierror ) ! Create sf_rnf structure (runoff inflow)
	303	IF(lwp) WRITE(numout,*)
	304	IF(lwp) WRITE(numout,*) ' runoffs inflow read in a file'
	305	IF( ierror > 0 ) THEN
	306	CALL ctl_stop( 'sbc_rnf: unable to allocate sf_rnf structure' ) ; RETURN
	307	ENDIF
	308	ALLOCATE( sf_rnf(1)%fnow(jpi,jpj,1) )
	309	IF( sn_rnf%ln_tint ) ALLOCATE( sf_rnf(1)%fdta(jpi,jpj,1,2) )
[1133]	310	CALL fld_fill( sf_rnf, (/ sn_rnf /), cn_dir, 'sbc_rnf_init', 'read runoffs data', 'namsbc_rnf' )
[5407]	311	ENDIF
	312	!
	313	IF( ln_rnf_tem ) THEN ! Create (if required) sf_t_rnf structure
	314	IF(lwp) WRITE(numout,*)
	315	IF(lwp) WRITE(numout,*) ' runoffs temperatures read in a file'
	316	ALLOCATE( sf_t_rnf(1), STAT=ierror )
	317	IF( ierror > 0 ) THEN
	318	CALL ctl_stop( 'sbc_rnf_init: unable to allocate sf_t_rnf structure' ) ; RETURN
[2528]	319	ENDIF
[5407]	320	ALLOCATE( sf_t_rnf(1)%fnow(jpi,jpj,1) )
	321	IF( sn_t_rnf%ln_tint ) ALLOCATE( sf_t_rnf(1)%fdta(jpi,jpj,1,2) )
	322	CALL fld_fill (sf_t_rnf, (/ sn_t_rnf /), cn_dir, 'sbc_rnf_init', 'read runoff temperature data', 'namsbc_rnf' )
	323	ENDIF
	324	!
	325	IF( ln_rnf_sal ) THEN ! Create (if required) sf_s_rnf and sf_t_rnf structures
	326	IF(lwp) WRITE(numout,*)
	327	IF(lwp) WRITE(numout,*) ' runoffs salinities read in a file'
	328	ALLOCATE( sf_s_rnf(1), STAT=ierror )
	329	IF( ierror > 0 ) THEN
	330	CALL ctl_stop( 'sbc_rnf_init: unable to allocate sf_s_rnf structure' ) ; RETURN
[2528]	331	ENDIF
[5407]	332	ALLOCATE( sf_s_rnf(1)%fnow(jpi,jpj,1) )
	333	IF( sn_s_rnf%ln_tint ) ALLOCATE( sf_s_rnf(1)%fdta(jpi,jpj,1,2) )
	334	CALL fld_fill (sf_s_rnf, (/ sn_s_rnf /), cn_dir, 'sbc_rnf_init', 'read runoff salinity data', 'namsbc_rnf' )
	335	ENDIF
	336	!
	337	IF( ln_rnf_depth ) THEN ! depth of runoffs set from a file
	338	IF(lwp) WRITE(numout,*)
	339	IF(lwp) WRITE(numout,*) ' runoffs depth read in a file'
	340	rn_dep_file = TRIM( cn_dir )//TRIM( sn_dep_rnf%clname )
	341	IF( .NOT. sn_dep_rnf%ln_clim ) THEN ; WRITE(rn_dep_file, '(a,"_y",i4)' ) TRIM( rn_dep_file ), nyear ! add year
	342	IF( sn_dep_rnf%cltype == 'monthly' ) WRITE(rn_dep_file, '(a,"m",i2)' ) TRIM( rn_dep_file ), nmonth ! add month
	343	ENDIF
	344	CALL iom_open ( rn_dep_file, inum ) ! open file
	345	CALL iom_get ( inum, jpdom_data, sn_dep_rnf%clvar, h_rnf ) ! read the river mouth array
	346	CALL iom_close( inum ) ! close file
[2528]	347	!
[5407]	348	nk_rnf(:,:) = 0 ! set the number of level over which river runoffs are applied
	349	DO jj = 1, jpj
	350	DO ji = 1, jpi
	351	IF( h_rnf(ji,jj) > 0._wp ) THEN
	352	jk = 2
	353	DO WHILE ( jk /= mbkt(ji,jj) .AND. gdept_0(ji,jj,jk) < h_rnf(ji,jj) ) ; jk = jk + 1
	354	END DO
	355	nk_rnf(ji,jj) = jk
	356	ELSEIF( h_rnf(ji,jj) == -1._wp ) THEN ; nk_rnf(ji,jj) = 1
	357	ELSEIF( h_rnf(ji,jj) == -999._wp ) THEN ; nk_rnf(ji,jj) = mbkt(ji,jj)
	358	ELSE
	359	CALL ctl_stop( 'sbc_rnf_init: runoff depth not positive, and not -999 or -1, rnf value in file fort.999' )
	360	WRITE(999,*) 'ji, jj, h_rnf(ji,jj) :', ji, jj, h_rnf(ji,jj)
	361	ENDIF
[3764]	362	END DO
[5407]	363	END DO
	364	DO jj = 1, jpj ! set the associated depth
	365	DO ji = 1, jpi
	366	h_rnf(ji,jj) = 0._wp
	367	DO jk = 1, nk_rnf(ji,jj)
	368	h_rnf(ji,jj) = h_rnf(ji,jj) + fse3t(ji,jj,jk)
[2528]	369	END DO
	370	END DO
[5407]	371	END DO
	372	!
	373	ELSE IF( ln_rnf_depth_ini ) THEN ! runoffs applied at the surface
	374	!
	375	IF(lwp) WRITE(numout,*)
	376	IF(lwp) WRITE(numout,*) ' depth of runoff computed once from max value of runoff'
	377	IF(lwp) WRITE(numout,*) ' max value of the runoff climatologie (over global domain) rn_rnf_max = ', rn_rnf_max
	378	IF(lwp) WRITE(numout,*) ' depth over which runoffs is spread rn_dep_max = ', rn_dep_max
	379	IF(lwp) WRITE(numout,*) ' create (=1) a runoff depth file or not (=0) nn_rnf_depth_file = ', nn_rnf_depth_file
[5385]	380
[5407]	381	CALL iom_open( TRIM( sn_rnf%clname ), inum ) ! open runoff file
	382	CALL iom_gettime( inum, zrec, kntime=nbrec)
	383	ALLOCATE( zrnfcl(jpi,jpj,nbrec) ) ; ALLOCATE( zrnf(jpi,jpj) )
	384	DO jm = 1, nbrec
	385	CALL iom_get( inum, jpdom_data, TRIM( sn_rnf%clvar ), zrnfcl(:,:,jm), jm )
	386	END DO
	387	CALL iom_close( inum )
	388	zrnf(:,:) = MAXVAL( zrnfcl(:,:,:), DIM=3 ) ! maximum value in time
	389	DEALLOCATE( zrnfcl )
	390	!
	391	h_rnf(:,:) = 1.
	392	!
	393	zacoef = rn_dep_max / rn_rnf_max ! coef of linear relation between runoff and its depth (150m for max of runoff)
	394	!
	395	WHERE( zrnf(:,:) > 0._wp ) h_rnf(:,:) = zacoef * zrnf(:,:) ! compute depth for all runoffs
	396	!
	397	DO jj = 1, jpj ! take in account min depth of ocean rn_hmin
	398	DO ji = 1, jpi
	399	IF( zrnf(ji,jj) > 0._wp ) THEN
	400	jk = mbkt(ji,jj)
	401	h_rnf(ji,jj) = MIN( h_rnf(ji,jj), gdept_0(ji,jj,jk ) )
	402	ENDIF
[5385]	403	END DO
[5407]	404	END DO
	405	!
	406	nk_rnf(:,:) = 0 ! number of levels on which runoffs are distributed
	407	DO jj = 1, jpj
	408	DO ji = 1, jpi
	409	IF( zrnf(ji,jj) > 0._wp ) THEN
	410	jk = 2
	411	DO WHILE ( jk /= mbkt(ji,jj) .AND. gdept_0(ji,jj,jk) < h_rnf(ji,jj) ) ; jk = jk + 1
	412	END DO
	413	nk_rnf(ji,jj) = jk
	414	ELSE
	415	nk_rnf(ji,jj) = 1
	416	ENDIF
[5385]	417	END DO
[5407]	418	END DO
	419	!
	420	DEALLOCATE( zrnf )
	421	!
	422	DO jj = 1, jpj ! set the associated depth
	423	DO ji = 1, jpi
	424	h_rnf(ji,jj) = 0._wp
	425	DO jk = 1, nk_rnf(ji,jj)
	426	h_rnf(ji,jj) = h_rnf(ji,jj) + fse3t(ji,jj,jk)
[5385]	427	END DO
	428	END DO
[5407]	429	END DO
	430	!
	431	IF( nn_rnf_depth_file == 1 ) THEN ! save output nb levels for runoff
	432	IF(lwp) WRITE(numout,*) ' create runoff depht file'
	433	CALL iom_open ( TRIM( sn_dep_rnf%clname ), inum, ldwrt = .TRUE., kiolib = jprstlib )
	434	CALL iom_rstput( 0, 0, inum, 'rodepth', h_rnf )
	435	CALL iom_close ( inum )
[3764]	436	ENDIF
[5407]	437	ELSE ! runoffs applied at the surface
	438	nk_rnf(:,:) = 1
	439	h_rnf (:,:) = fse3t(:,:,1)
[1116]	440	ENDIF
[2528]	441	!
[3294]	442	rnf(:,:) = 0._wp ! runoff initialisation
[2528]	443	rnf_tsc(:,:,:) = 0._wp ! runoffs temperature & salinty contents initilisation
	444	!
[1116]	445	! ! ========================
	446	! ! River mouth vicinity
	447	! ! ========================
	448	!
	449	IF( ln_rnf_mouth ) THEN ! Specific treatment in vicinity of river mouths :
	450	! ! - Increase Kz in surface layers ( rn_hrnf > 0 )
	451	! ! - set to zero SSS damping (ln_ssr=T)
	452	! ! - mixed upstream-centered (ln_traadv_cen2=T)
	453	!
[2528]	454	IF ( ln_rnf_depth ) CALL ctl_warn( 'sbc_rnf_init: increased mixing turned on but effects may already', &
[3764]	455	& 'be spread through depth by ln_rnf_depth' )
[2528]	456	!
	457	nkrnf = 0 ! Number of level over which Kz increase
	458	IF( rn_hrnf > 0._wp ) THEN
[1116]	459	nkrnf = 2
[5407]	460	DO WHILE( nkrnf /= jpkm1 .AND. gdepw_1d(nkrnf+1) < rn_hrnf ) ; nkrnf = nkrnf + 1
	461	END DO
[3625]	462	IF( ln_sco ) CALL ctl_warn( 'sbc_rnf: number of levels over which Kz is increased is computed for zco...' )
[1116]	463	ENDIF
	464	IF(lwp) WRITE(numout,*)
	465	IF(lwp) WRITE(numout,*) ' Specific treatment used in vicinity of river mouths :'
	466	IF(lwp) WRITE(numout,*) ' - Increase Kz in surface layers (if rn_hrnf > 0 )'
	467	IF(lwp) WRITE(numout,*) ' by ', rn_avt_rnf,' m2/s over ', nkrnf, ' w-levels'
	468	IF(lwp) WRITE(numout,*) ' - set to zero SSS damping (if ln_ssr=T)'
	469	IF(lwp) WRITE(numout,*) ' - mixed upstream-centered (if ln_traadv_cen2=T)'
	470	!
	471	CALL rnf_mouth ! set river mouth mask
	472	!
	473	ELSE ! No treatment at river mouths
	474	IF(lwp) WRITE(numout,*)
	475	IF(lwp) WRITE(numout,*) ' No specific treatment at river mouths'
[3764]	476	rnfmsk (:,:) = 0._wp
[2528]	477	rnfmsk_z(:) = 0._wp
[1116]	478	nkrnf = 0
	479	ENDIF
[3625]	480	!
[1116]	481	END SUBROUTINE sbc_rnf_init
	482
	483
[888]	484	SUBROUTINE rnf_mouth
	485	!!----------------------------------------------------------------------
	486	!! * ROUTINE rnf_mouth *
[3764]	487	!!
[888]	488	!! ** Purpose : define the river mouths mask
	489	!!
	490	!! ** Method : read the river mouth mask (=0/1) in the river runoff
[3764]	491	!! climatological file. Defined a given vertical structure.
	492	!! CAUTION, the vertical structure is hard coded on the
[888]	493	!! first 5 levels.
	494	!! This fields can be used to:
[3764]	495	!! - set an upstream advection scheme
[1116]	496	!! (ln_rnf_mouth=T and ln_traadv_cen2=T)
[3764]	497	!! - increase vertical on the top nn_krnf vertical levels
[888]	498	!! at river runoff input grid point (nn_krnf>=2, see step.F90)
	499	!! - set to zero SSS restoring flux at river mouth grid points
	500	!!
	501	!! ** Action : rnfmsk set to 1 at river runoff input, 0 elsewhere
	502	!! rnfmsk_z vertical structure
	503	!!----------------------------------------------------------------------
[2784]	504	INTEGER :: inum ! temporary integers
	505	CHARACTER(len=140) :: cl_rnfile ! runoff file name
[888]	506	!!----------------------------------------------------------------------
[3764]	507	!
[888]	508	IF(lwp) WRITE(numout,*)
	509	IF(lwp) WRITE(numout,*) 'rnf_mouth : river mouth mask'
	510	IF(lwp) WRITE(numout,*) '~~~~~~~~~ '
[3625]	511	!
[1133]	512	cl_rnfile = TRIM( cn_dir )//TRIM( sn_cnf%clname )
	513	IF( .NOT. sn_cnf%ln_clim ) THEN ; WRITE(cl_rnfile, '(a,"_y",i4)' ) TRIM( cl_rnfile ), nyear ! add year
	514	IF( sn_cnf%cltype == 'monthly' ) WRITE(cl_rnfile, '(a,"m",i2)' ) TRIM( cl_rnfile ), nmonth ! add month
	515	ENDIF
[3625]	516	!
[888]	517	! horizontal mask (read in NetCDF file)
	518	CALL iom_open ( cl_rnfile, inum ) ! open file
	519	CALL iom_get ( inum, jpdom_data, sn_cnf%clvar, rnfmsk ) ! read the river mouth array
	520	CALL iom_close( inum ) ! close file
[3625]	521	!
[3632]	522	IF( nn_closea == 1 ) CALL clo_rnf( rnfmsk ) ! closed sea inflow set as ruver mouth
[3625]	523	!
[3764]	524	rnfmsk_z(:) = 0._wp ! vertical structure
[888]	525	rnfmsk_z(1) = 1.0
	526	rnfmsk_z(2) = 1.0 ! **********
	527	rnfmsk_z(3) = 0.5 ! HARD CODED on the 5 first levels
	528	rnfmsk_z(4) = 0.25 ! **********
	529	rnfmsk_z(5) = 0.125
[3764]	530	!
[888]	531	END SUBROUTINE rnf_mouth
[3764]	532
[888]	533	!!======================================================================
	534	END MODULE sbcrnf

Note: See TracBrowser for help on using the repository browser.

Download in other formats: