| 1 | MODULE zdftmx |
|---|
| 2 | !!======================================================================== |
|---|
| 3 | !! *** MODULE zdftmx *** |
|---|
| 4 | !! Ocean physics: vertical tidal mixing coefficient |
|---|
| 5 | !!======================================================================== |
|---|
| 6 | !! History : 1.0 ! 2004-04 (L. Bessieres, G. Madec) Original code |
|---|
| 7 | !! - ! 2006-08 (A. Koch-Larrouy) Indonesian strait |
|---|
| 8 | !! 3.3 ! 2010-10 (C. Ethe, G. Madec) reorganisation of initialisation phase |
|---|
| 9 | !!---------------------------------------------------------------------- |
|---|
| 10 | #if defined key_zdftmx || defined key_esopa |
|---|
| 11 | !!---------------------------------------------------------------------- |
|---|
| 12 | !! 'key_zdftmx' Tidal vertical mixing |
|---|
| 13 | !!---------------------------------------------------------------------- |
|---|
| 14 | !! zdf_tmx : global momentum & tracer Kz with tidal induced Kz |
|---|
| 15 | !! tmx_itf : Indonesian momentum & tracer Kz with tidal induced Kz |
|---|
| 16 | !!---------------------------------------------------------------------- |
|---|
| 17 | USE oce ! ocean dynamics and tracers variables |
|---|
| 18 | USE dom_oce ! ocean space and time domain variables |
|---|
| 19 | USE zdf_oce ! ocean vertical physics variables |
|---|
| 20 | USE lbclnk ! ocean lateral boundary conditions (or mpp link) |
|---|
| 21 | USE eosbn2 ! ocean equation of state |
|---|
| 22 | USE phycst ! physical constants |
|---|
| 23 | USE prtctl ! Print control |
|---|
| 24 | USE in_out_manager ! I/O manager |
|---|
| 25 | USE iom ! I/O Manager |
|---|
| 26 | USE lib_mpp ! MPP library |
|---|
| 27 | USE wrk_nemo ! work arrays |
|---|
| 28 | USE timing ! Timing |
|---|
| 29 | USE lib_fortran ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) |
|---|
| 30 | |
|---|
| 31 | IMPLICIT NONE |
|---|
| 32 | PRIVATE |
|---|
| 33 | |
|---|
| 34 | PUBLIC zdf_tmx ! called in step module |
|---|
| 35 | PUBLIC zdf_tmx_init ! called in opa module |
|---|
| 36 | PUBLIC zdf_tmx_alloc ! called in nemogcm module |
|---|
| 37 | |
|---|
| 38 | LOGICAL, PUBLIC, PARAMETER :: lk_zdftmx = .TRUE. !: tidal mixing flag |
|---|
| 39 | |
|---|
| 40 | ! !!* Namelist namzdf_tmx : tidal mixing * |
|---|
| 41 | REAL(wp) :: rn_htmx ! vertical decay scale for turbulence (meters) |
|---|
| 42 | REAL(wp) :: rn_n2min ! threshold of the Brunt-Vaisala frequency (s-1) |
|---|
| 43 | REAL(wp) :: rn_tfe ! tidal dissipation efficiency (St Laurent et al. 2002) |
|---|
| 44 | REAL(wp) :: rn_me ! mixing efficiency (Osborn 1980) |
|---|
| 45 | LOGICAL :: ln_tmx_itf ! Indonesian Through Flow (ITF): Koch-Larrouy et al. (2007) parameterization |
|---|
| 46 | REAL(wp) :: rn_tfe_itf ! ITF tidal dissipation efficiency (St Laurent et al. 2002) |
|---|
| 47 | |
|---|
| 48 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) :: en_tmx ! energy available for tidal mixing (W/m2) |
|---|
| 49 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) :: mask_itf ! mask to use over Indonesian area |
|---|
| 50 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: az_tmx ! coefficient used to evaluate the tidal induced Kz |
|---|
| 51 | |
|---|
| 52 | !! * Substitutions |
|---|
| 53 | # include "domzgr_substitute.h90" |
|---|
| 54 | # include "vectopt_loop_substitute.h90" |
|---|
| 55 | !!---------------------------------------------------------------------- |
|---|
| 56 | !! NEMO/OPA 4.0 , NEMO Consortium (2011) |
|---|
| 57 | !! $Id$ |
|---|
| 58 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
|---|
| 59 | !!---------------------------------------------------------------------- |
|---|
| 60 | CONTAINS |
|---|
| 61 | |
|---|
| 62 | INTEGER FUNCTION zdf_tmx_alloc() |
|---|
| 63 | !!---------------------------------------------------------------------- |
|---|
| 64 | !! *** FUNCTION zdf_tmx_alloc *** |
|---|
| 65 | !!---------------------------------------------------------------------- |
|---|
| 66 | ALLOCATE(en_tmx(jpi,jpj), mask_itf(jpi,jpj), az_tmx(jpi,jpj,jpk), STAT=zdf_tmx_alloc ) |
|---|
| 67 | ! |
|---|
| 68 | IF( lk_mpp ) CALL mpp_sum ( zdf_tmx_alloc ) |
|---|
| 69 | IF( zdf_tmx_alloc /= 0 ) CALL ctl_warn('zdf_tmx_alloc: failed to allocate arrays') |
|---|
| 70 | END FUNCTION zdf_tmx_alloc |
|---|
| 71 | |
|---|
| 72 | |
|---|
| 73 | SUBROUTINE zdf_tmx( kt ) |
|---|
| 74 | !!---------------------------------------------------------------------- |
|---|
| 75 | !! *** ROUTINE zdf_tmx *** |
|---|
| 76 | !! |
|---|
| 77 | !! ** Purpose : add to the vertical mixing coefficients the effect of |
|---|
| 78 | !! tidal mixing (Simmons et al 2004). |
|---|
| 79 | !! |
|---|
| 80 | !! ** Method : - tidal-induced vertical mixing is given by: |
|---|
| 81 | !! Kz_tides = az_tmx / max( rn_n2min, N^2 ) |
|---|
| 82 | !! where az_tmx is a coefficient that specified the 3D space |
|---|
| 83 | !! distribution of the faction of tidal energy taht is used |
|---|
| 84 | !! for mixing. Its expression is set in zdf_tmx_init routine, |
|---|
| 85 | !! following Simmons et al. 2004. |
|---|
| 86 | !! NB: a specific bounding procedure is performed on av_tide |
|---|
| 87 | !! so that the input tidal energy is actually almost used. The |
|---|
| 88 | !! basic maximum value is 60 cm2/s, but values of 300 cm2/s |
|---|
| 89 | !! can be reached in area where bottom stratification is too |
|---|
| 90 | !! weak. |
|---|
| 91 | !! |
|---|
| 92 | !! - update av_tide in the Indonesian Through Flow area |
|---|
| 93 | !! following Koch-Larrouy et al. (2007) parameterisation |
|---|
| 94 | !! (see tmx_itf routine). |
|---|
| 95 | !! |
|---|
| 96 | !! - update the model vertical eddy viscosity and diffusivity: |
|---|
| 97 | !! avt = avt + av_tides |
|---|
| 98 | !! avm = avm + av_tides |
|---|
| 99 | !! avmu = avmu + mi(av_tides) |
|---|
| 100 | !! avmv = avmv + mj(av_tides) |
|---|
| 101 | !! |
|---|
| 102 | !! ** Action : avt, avm, avmu, avmv increased by tidal mixing |
|---|
| 103 | !! |
|---|
| 104 | !! References : Simmons et al. 2004, Ocean Modelling, 6, 3-4, 245-263. |
|---|
| 105 | !! Koch-Larrouy et al. 2007, GRL. |
|---|
| 106 | !!---------------------------------------------------------------------- |
|---|
| 107 | USE oce, zav_tide => ua ! use ua as workspace |
|---|
| 108 | !! |
|---|
| 109 | INTEGER, INTENT(in) :: kt ! ocean time-step |
|---|
| 110 | !! |
|---|
| 111 | INTEGER :: ji, jj, jk ! dummy loop indices |
|---|
| 112 | REAL(wp) :: ztpc ! scalar workspace |
|---|
| 113 | REAL(wp), DIMENSION(jpi,jpj) :: zkz |
|---|
| 114 | !!---------------------------------------------------------------------- |
|---|
| 115 | ! |
|---|
| 116 | IF( nn_timing == 1 ) CALL timing_start('zdf_tmx') |
|---|
| 117 | ! |
|---|
| 118 | ! CALL wrk_alloc( jpi,jpj, zkz ) |
|---|
| 119 | |
|---|
| 120 | ! ! ----------------------- ! |
|---|
| 121 | ! ! Standard tidal mixing ! (compute zav_tide) |
|---|
| 122 | ! ! ----------------------- ! |
|---|
| 123 | ! !* First estimation (with n2 bound by rn_n2min) bounded by 60 cm2/s |
|---|
| 124 | zav_tide(:,:,:) = MIN( 60.e-4, az_tmx(:,:,:) / MAX( rn_n2min, rn2(:,:,:) ) ) |
|---|
| 125 | |
|---|
| 126 | zkz(:,:) = 0.e0 !* Associated potential energy consummed over the whole water column |
|---|
| 127 | DO jk = 2, jpkm1 |
|---|
| 128 | zkz(:,:) = zkz(:,:) + fse3w(:,:,jk) * MAX( 0.e0, rn2(:,:,jk) ) * rau0 * zav_tide(:,:,jk) * wmask(:,:,jk) |
|---|
| 129 | END DO |
|---|
| 130 | DO jj = 1, jpj !* Here zkz should be equal to en_tmx ==> multiply by en_tmx/zkz to recover en_tmx |
|---|
| 131 | DO ji = 1, jpi |
|---|
| 132 | IF( zkz(ji,jj) /= 0.e0 ) zkz(ji,jj) = en_tmx(ji,jj) / zkz(ji,jj) |
|---|
| 133 | END DO |
|---|
| 134 | END DO |
|---|
| 135 | DO jk = 2, jpkm1 !* Mutiply by zkz to recover en_tmx, BUT bound by 30/6 ==> zav_tide bound by 300 cm2/s |
|---|
| 136 | DO jj = 1, jpj !* Here zkz should be equal to en_tmx ==> multiply by en_tmx/zkz to recover en_tmx |
|---|
| 137 | DO ji = 1, jpi |
|---|
| 138 | zav_tide(ji,jj,jk) = zav_tide(ji,jj,jk) * MIN( zkz(ji,jj), 30./6. ) * wmask(ji,jj,jk) !kz max = 300 cm2/s |
|---|
| 139 | END DO |
|---|
| 140 | END DO |
|---|
| 141 | END DO |
|---|
| 142 | IF( kt == nit000 ) THEN !* check at first time-step: diagnose the energy consumed by zav_tide |
|---|
| 143 | ztpc = 0.e0 |
|---|
| 144 | DO jk= 1, jpk |
|---|
| 145 | DO jj= 1, jpj |
|---|
| 146 | DO ji= 1, jpi |
|---|
| 147 | ztpc = ztpc + fse3w(ji,jj,jk) * e1t(ji,jj) * e2t(ji,jj) & |
|---|
| 148 | & * MAX( 0.e0, rn2(ji,jj,jk) ) * zav_tide(ji,jj,jk) * tmask(ji,jj,jk) * tmask_i(ji,jj) |
|---|
| 149 | END DO |
|---|
| 150 | END DO |
|---|
| 151 | END DO |
|---|
| 152 | ztpc= rau0 / ( rn_tfe * rn_me ) * ztpc |
|---|
| 153 | IF(lwp) WRITE(numout,*) |
|---|
| 154 | IF(lwp) WRITE(numout,*) ' N Total power consumption by av_tide : ztpc = ', ztpc * 1.e-12 ,'TW' |
|---|
| 155 | ENDIF |
|---|
| 156 | |
|---|
| 157 | ! ! ----------------------- ! |
|---|
| 158 | ! ! ITF tidal mixing ! (update zav_tide) |
|---|
| 159 | ! ! ----------------------- ! |
|---|
| 160 | IF( ln_tmx_itf ) CALL tmx_itf( kt, zav_tide ) |
|---|
| 161 | |
|---|
| 162 | ! ! ----------------------- ! |
|---|
| 163 | ! ! Update mixing coefs ! |
|---|
| 164 | ! ! ----------------------- ! |
|---|
| 165 | !$OMP PARALLEL DO |
|---|
| 166 | DO jk = 2, jpkm1 !* update momentum & tracer diffusivity with tidal mixing |
|---|
| 167 | DO jj = 1, jpj !* Here zkz should be equal to en_tmx ==> multiply by en_tmx/zkz to recover en_tmx |
|---|
| 168 | DO ji = 1, jpi |
|---|
| 169 | avt(ji,jj,jk) = avt(ji,jj,jk) + zav_tide(ji,jj,jk) * wmask(ji,jj,jk) |
|---|
| 170 | avm(ji,jj,jk) = avm(ji,jj,jk) + zav_tide(ji,jj,jk) * wmask(ji,jj,jk) |
|---|
| 171 | END DO |
|---|
| 172 | END DO |
|---|
| 173 | END DO |
|---|
| 174 | !$OMP PARALLEL DO |
|---|
| 175 | DO jk = 2, jpkm1 !* update momentum & tracer diffusivity with tidal mixing |
|---|
| 176 | DO jj = 2, jpjm1 |
|---|
| 177 | DO ji = fs_2, fs_jpim1 ! vector opt. |
|---|
| 178 | avmu(ji,jj,jk) = avmu(ji,jj,jk) + 0.5 * ( zav_tide(ji,jj,jk) + zav_tide(ji+1,jj ,jk) ) * wumask(ji,jj,jk) |
|---|
| 179 | avmv(ji,jj,jk) = avmv(ji,jj,jk) + 0.5 * ( zav_tide(ji,jj,jk) + zav_tide(ji ,jj+1,jk) ) * wvmask(ji,jj,jk) |
|---|
| 180 | END DO |
|---|
| 181 | END DO |
|---|
| 182 | END DO |
|---|
| 183 | CALL lbc_lnk( avmu, 'U', 1. ) ; CALL lbc_lnk( avmv, 'V', 1. ) ! lateral boundary condition |
|---|
| 184 | |
|---|
| 185 | ! !* output tidal mixing coefficient |
|---|
| 186 | CALL iom_put( "av_tide", zav_tide ) |
|---|
| 187 | |
|---|
| 188 | IF(ln_ctl) CALL prt_ctl(tab3d_1=zav_tide , clinfo1=' tmx - av_tide: ', tab3d_2=avt, clinfo2=' avt: ', ovlap=1, kdim=jpk) |
|---|
| 189 | ! |
|---|
| 190 | ! CALL wrk_dealloc( jpi,jpj, zkz ) |
|---|
| 191 | ! |
|---|
| 192 | IF( nn_timing == 1 ) CALL timing_stop('zdf_tmx') |
|---|
| 193 | ! |
|---|
| 194 | END SUBROUTINE zdf_tmx |
|---|
| 195 | |
|---|
| 196 | |
|---|
| 197 | SUBROUTINE tmx_itf( kt, pav ) |
|---|
| 198 | !!---------------------------------------------------------------------- |
|---|
| 199 | !! *** ROUTINE tmx_itf *** |
|---|
| 200 | !! |
|---|
| 201 | !! ** Purpose : modify the vertical eddy diffusivity coefficients |
|---|
| 202 | !! (pav) in the Indonesian Through Flow area (ITF). |
|---|
| 203 | !! |
|---|
| 204 | !! ** Method : - Following Koch-Larrouy et al. (2007), in the ITF defined |
|---|
| 205 | !! by msk_itf (read in a file, see tmx_init), the tidal |
|---|
| 206 | !! mixing coefficient is computed with : |
|---|
| 207 | !! * q=1 (i.e. all the tidal energy remains trapped in |
|---|
| 208 | !! the area and thus is used for mixing) |
|---|
| 209 | !! * the vertical distribution of the tifal energy is a |
|---|
| 210 | !! proportional to N above the thermocline (d(N^2)/dz > 0) |
|---|
| 211 | !! and to N^2 below the thermocline (d(N^2)/dz < 0) |
|---|
| 212 | !! |
|---|
| 213 | !! ** Action : av_tide updated in the ITF area (msk_itf) |
|---|
| 214 | !! |
|---|
| 215 | !! References : Koch-Larrouy et al. 2007, GRL |
|---|
| 216 | !!---------------------------------------------------------------------- |
|---|
| 217 | INTEGER , INTENT(in ) :: kt ! ocean time-step |
|---|
| 218 | REAL(wp), INTENT(inout), DIMENSION(jpi,jpj,jpk) :: pav ! Tidal mixing coef. |
|---|
| 219 | !! |
|---|
| 220 | INTEGER :: ji, jj, jk ! dummy loop indices |
|---|
| 221 | REAL(wp) :: zcoef, ztpc ! temporary scalar |
|---|
| 222 | REAL(wp), DIMENSION(jpi, jpj) :: zkz ! 2D workspace |
|---|
| 223 | REAL(wp), DIMENSION(jpi, jpj) :: zsum1 , zsum2 , zsum ! - - |
|---|
| 224 | REAL(wp), DIMENSION(:,:,:), POINTER :: zempba_3d_1, zempba_3d_2 ! 3D workspace |
|---|
| 225 | REAL(wp), DIMENSION(:,:,:), POINTER :: zempba_3d , zdn2dz ! - - |
|---|
| 226 | REAL(wp), DIMENSION(:,:,:), POINTER :: zavt_itf ! - - |
|---|
| 227 | !!---------------------------------------------------------------------- |
|---|
| 228 | ! |
|---|
| 229 | IF( nn_timing == 1 ) CALL timing_start('tmx_itf') |
|---|
| 230 | ! |
|---|
| 231 | ! CALL wrk_alloc( jpi,jpj, zkz, zsum1 , zsum2 , zsum ) |
|---|
| 232 | CALL wrk_alloc( jpi,jpj,jpk, zempba_3d_1, zempba_3d_2, zempba_3d, zdn2dz, zavt_itf ) |
|---|
| 233 | |
|---|
| 234 | ! ! compute the form function using N2 at each time step |
|---|
| 235 | zempba_3d_1(:,:,jpk) = 0.e0 |
|---|
| 236 | zempba_3d_2(:,:,jpk) = 0.e0 |
|---|
| 237 | !$OMP PARALLEL DO |
|---|
| 238 | DO jk = 1, jpkm1 |
|---|
| 239 | zdn2dz (:,:,jk) = rn2(:,:,jk) - rn2(:,:,jk+1) ! Vertical profile of dN2/dz |
|---|
| 240 | zempba_3d_1(:,:,jk) = SQRT( MAX( 0.e0, rn2(:,:,jk) ) ) ! - - of N |
|---|
| 241 | zempba_3d_2(:,:,jk) = MAX( 0.e0, rn2(:,:,jk) ) ! - - of N^2 |
|---|
| 242 | END DO |
|---|
| 243 | ! |
|---|
| 244 | zsum (:,:) = 0.e0 |
|---|
| 245 | zsum1(:,:) = 0.e0 |
|---|
| 246 | zsum2(:,:) = 0.e0 |
|---|
| 247 | DO jk= 2, jpk |
|---|
| 248 | zsum1(:,:) = zsum1(:,:) + zempba_3d_1(:,:,jk) * fse3w(:,:,jk) * tmask(:,:,jk) * tmask(:,:,jk-1) |
|---|
| 249 | zsum2(:,:) = zsum2(:,:) + zempba_3d_2(:,:,jk) * fse3w(:,:,jk) * tmask(:,:,jk) * tmask(:,:,jk-1) |
|---|
| 250 | END DO |
|---|
| 251 | DO jj = 1, jpj |
|---|
| 252 | DO ji = 1, jpi |
|---|
| 253 | IF( zsum1(ji,jj) /= 0.e0 ) zsum1(ji,jj) = 1.e0 / zsum1(ji,jj) |
|---|
| 254 | IF( zsum2(ji,jj) /= 0.e0 ) zsum2(ji,jj) = 1.e0 / zsum2(ji,jj) |
|---|
| 255 | END DO |
|---|
| 256 | END DO |
|---|
| 257 | DO jk= 1, jpk |
|---|
| 258 | DO jj = 1, jpj |
|---|
| 259 | DO ji = 1, jpi |
|---|
| 260 | zcoef = 0.5 - SIGN( 0.5, zdn2dz(ji,jj,jk) ) ! =0 if dN2/dz > 0, =1 otherwise |
|---|
| 261 | ztpc = zempba_3d_1(ji,jj,jk) * zsum1(ji,jj) * zcoef & |
|---|
| 262 | & + zempba_3d_2(ji,jj,jk) * zsum2(ji,jj) * ( 1. - zcoef ) |
|---|
| 263 | ! |
|---|
| 264 | zempba_3d(ji,jj,jk) = ztpc |
|---|
| 265 | zsum (ji,jj) = zsum(ji,jj) + ztpc * fse3w(ji,jj,jk) |
|---|
| 266 | END DO |
|---|
| 267 | END DO |
|---|
| 268 | END DO |
|---|
| 269 | DO jj = 1, jpj |
|---|
| 270 | DO ji = 1, jpi |
|---|
| 271 | IF( zsum(ji,jj) > 0.e0 ) zsum(ji,jj) = 1.e0 / zsum(ji,jj) |
|---|
| 272 | END DO |
|---|
| 273 | END DO |
|---|
| 274 | |
|---|
| 275 | ! ! first estimation bounded by 10 cm2/s (with n2 bounded by rn_n2min) |
|---|
| 276 | zcoef = rn_tfe_itf / ( rn_tfe * rau0 ) |
|---|
| 277 | DO jk = 1, jpk |
|---|
| 278 | zavt_itf(:,:,jk) = MIN( 10.e-4, zcoef * en_tmx(:,:) * zsum(:,:) * zempba_3d(:,:,jk) & |
|---|
| 279 | & / MAX( rn_n2min, rn2(:,:,jk) ) * tmask(:,:,jk) ) |
|---|
| 280 | END DO |
|---|
| 281 | |
|---|
| 282 | zkz(:,:) = 0.e0 ! Associated potential energy consummed over the whole water column |
|---|
| 283 | DO jk = 2, jpkm1 |
|---|
| 284 | zkz(:,:) = zkz(:,:) + fse3w(:,:,jk) * MAX( 0.e0, rn2(:,:,jk) ) * rau0 * zavt_itf(:,:,jk) * tmask(:,:,jk) * tmask(:,:,jk-1) |
|---|
| 285 | END DO |
|---|
| 286 | |
|---|
| 287 | DO jj = 1, jpj ! Here zkz should be equal to en_tmx ==> multiply by en_tmx/zkz to recover en_tmx |
|---|
| 288 | DO ji = 1, jpi |
|---|
| 289 | IF( zkz(ji,jj) /= 0.e0 ) zkz(ji,jj) = en_tmx(ji,jj) * rn_tfe_itf / rn_tfe / zkz(ji,jj) |
|---|
| 290 | END DO |
|---|
| 291 | END DO |
|---|
| 292 | |
|---|
| 293 | DO jk = 2, jpkm1 ! Mutiply by zkz to recover en_tmx, BUT bound by 30/6 ==> zavt_itf bound by 300 cm2/s |
|---|
| 294 | zavt_itf(:,:,jk) = zavt_itf(:,:,jk) * MIN( zkz(:,:), 120./10. ) * tmask(:,:,jk) * tmask(:,:,jk-1) ! kz max = 120 cm2/s |
|---|
| 295 | END DO |
|---|
| 296 | |
|---|
| 297 | IF( kt == nit000 ) THEN ! diagnose the nergy consumed by zavt_itf |
|---|
| 298 | ztpc = 0.e0 |
|---|
| 299 | DO jk= 1, jpk |
|---|
| 300 | DO jj= 1, jpj |
|---|
| 301 | DO ji= 1, jpi |
|---|
| 302 | ztpc = ztpc + e1t(ji,jj) * e2t(ji,jj) * fse3w(ji,jj,jk) * MAX( 0.e0, rn2(ji,jj,jk) ) & |
|---|
| 303 | & * zavt_itf(ji,jj,jk) * tmask(ji,jj,jk) * tmask_i(ji,jj) |
|---|
| 304 | END DO |
|---|
| 305 | END DO |
|---|
| 306 | END DO |
|---|
| 307 | ztpc= rau0 * ztpc / ( rn_me * rn_tfe_itf ) |
|---|
| 308 | IF(lwp) WRITE(numout,*) ' N Total power consumption by zavt_itf: ztpc = ', ztpc * 1.e-12 ,'TW' |
|---|
| 309 | ENDIF |
|---|
| 310 | |
|---|
| 311 | ! ! Update pav with the ITF mixing coefficient |
|---|
| 312 | !$OMP PARALLEL DO |
|---|
| 313 | DO jk = 2, jpkm1 |
|---|
| 314 | pav(:,:,jk) = pav (:,:,jk) * ( 1.e0 - mask_itf(:,:) ) & |
|---|
| 315 | & + zavt_itf(:,:,jk) * mask_itf(:,:) |
|---|
| 316 | END DO |
|---|
| 317 | ! |
|---|
| 318 | ! CALL wrk_dealloc( jpi,jpj, zkz, zsum1 , zsum2 , zsum ) |
|---|
| 319 | CALL wrk_dealloc( jpi,jpj,jpk, zempba_3d_1, zempba_3d_2, zempba_3d, zdn2dz, zavt_itf ) |
|---|
| 320 | ! |
|---|
| 321 | IF( nn_timing == 1 ) CALL timing_stop('tmx_itf') |
|---|
| 322 | ! |
|---|
| 323 | END SUBROUTINE tmx_itf |
|---|
| 324 | |
|---|
| 325 | |
|---|
| 326 | SUBROUTINE zdf_tmx_init |
|---|
| 327 | !!---------------------------------------------------------------------- |
|---|
| 328 | !! *** ROUTINE zdf_tmx_init *** |
|---|
| 329 | !! |
|---|
| 330 | !! ** Purpose : Initialization of the vertical tidal mixing, Reading |
|---|
| 331 | !! of M2 and K1 tidal energy in nc files |
|---|
| 332 | !! |
|---|
| 333 | !! ** Method : - Read the namtmx namelist and check the parameters |
|---|
| 334 | !! |
|---|
| 335 | !! - Read the input data in NetCDF files : |
|---|
| 336 | !! M2 and K1 tidal energy. The total tidal energy, en_tmx, |
|---|
| 337 | !! is the sum of M2, K1 and S2 energy where S2 is assumed |
|---|
| 338 | !! to be: S2=(1/2)^2 * M2 |
|---|
| 339 | !! mask_itf, a mask array that determine where substituing |
|---|
| 340 | !! the standard Simmons et al. (2005) formulation with the |
|---|
| 341 | !! one of Koch_Larrouy et al. (2007). |
|---|
| 342 | !! |
|---|
| 343 | !! - Compute az_tmx, a 3D coefficient that allows to compute |
|---|
| 344 | !! the standard tidal-induced vertical mixing as follows: |
|---|
| 345 | !! Kz_tides = az_tmx / max( rn_n2min, N^2 ) |
|---|
| 346 | !! with az_tmx a bottom intensified coefficient is given by: |
|---|
| 347 | !! az_tmx(z) = en_tmx / ( rau0 * rn_htmx ) * EXP( -(H-z)/rn_htmx ) |
|---|
| 348 | !! / ( 1. - EXP( - H /rn_htmx ) ) |
|---|
| 349 | !! where rn_htmx the characteristic length scale of the bottom |
|---|
| 350 | !! intensification, en_tmx the tidal energy, and H the ocean depth |
|---|
| 351 | !! |
|---|
| 352 | !! ** input : - Namlist namtmx |
|---|
| 353 | !! - NetCDF file : M2_ORCA2.nc, K1_ORCA2.nc, and mask_itf.nc |
|---|
| 354 | !! |
|---|
| 355 | !! ** Action : - Increase by 1 the nstop flag is setting problem encounter |
|---|
| 356 | !! - defined az_tmx used to compute tidal-induced mixing |
|---|
| 357 | !! |
|---|
| 358 | !! References : Simmons et al. 2004, Ocean Modelling, 6, 3-4, 245-263. |
|---|
| 359 | !! Koch-Larrouy et al. 2007, GRL. |
|---|
| 360 | !!---------------------------------------------------------------------- |
|---|
| 361 | USE oce , zav_tide => ua ! ua used as workspace |
|---|
| 362 | !! |
|---|
| 363 | INTEGER :: ji, jj, jk ! dummy loop indices |
|---|
| 364 | INTEGER :: inum ! local integer |
|---|
| 365 | INTEGER :: ios |
|---|
| 366 | REAL(wp) :: ztpc, ze_z ! local scalars |
|---|
| 367 | REAL(wp), DIMENSION(:,:) , POINTER :: zem2, zek1 ! read M2 and K1 tidal energy |
|---|
| 368 | REAL(wp), DIMENSION(:,:) , POINTER :: zkz ! total M2, K1 and S2 tidal energy |
|---|
| 369 | REAL(wp), DIMENSION(:,:) , POINTER :: zfact ! used for vertical structure function |
|---|
| 370 | REAL(wp), DIMENSION(:,:) , POINTER :: zhdep ! Ocean depth |
|---|
| 371 | REAL(wp), DIMENSION(:,:,:), POINTER :: zpc ! power consumption |
|---|
| 372 | !! |
|---|
| 373 | NAMELIST/namzdf_tmx/ rn_htmx, rn_n2min, rn_tfe, rn_me, ln_tmx_itf, rn_tfe_itf |
|---|
| 374 | !!---------------------------------------------------------------------- |
|---|
| 375 | ! |
|---|
| 376 | IF( nn_timing == 1 ) CALL timing_start('zdf_tmx_init') |
|---|
| 377 | ! |
|---|
| 378 | CALL wrk_alloc( jpi,jpj, zem2, zek1, zkz, zfact, zhdep ) |
|---|
| 379 | CALL wrk_alloc( jpi,jpj,jpk, zpc ) |
|---|
| 380 | |
|---|
| 381 | REWIND( numnam_ref ) ! Namelist namzdf_tmx in reference namelist : Tidal Mixing |
|---|
| 382 | READ ( numnam_ref, namzdf_tmx, IOSTAT = ios, ERR = 901) |
|---|
| 383 | 901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namzdf_tmx in reference namelist', lwp ) |
|---|
| 384 | |
|---|
| 385 | REWIND( numnam_cfg ) ! Namelist namzdf_tmx in configuration namelist : Tidal Mixing |
|---|
| 386 | READ ( numnam_cfg, namzdf_tmx, IOSTAT = ios, ERR = 902 ) |
|---|
| 387 | 902 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namzdf_tmx in configuration namelist', lwp ) |
|---|
| 388 | IF(lwm) WRITE ( numond, namzdf_tmx ) |
|---|
| 389 | |
|---|
| 390 | IF(lwp) THEN ! Control print |
|---|
| 391 | WRITE(numout,*) |
|---|
| 392 | WRITE(numout,*) 'zdf_tmx_init : tidal mixing' |
|---|
| 393 | WRITE(numout,*) '~~~~~~~~~~~~' |
|---|
| 394 | WRITE(numout,*) ' Namelist namzdf_tmx : set tidal mixing parameters' |
|---|
| 395 | WRITE(numout,*) ' Vertical decay scale for turbulence = ', rn_htmx |
|---|
| 396 | WRITE(numout,*) ' Brunt-Vaisala frequency threshold = ', rn_n2min |
|---|
| 397 | WRITE(numout,*) ' Tidal dissipation efficiency = ', rn_tfe |
|---|
| 398 | WRITE(numout,*) ' Mixing efficiency = ', rn_me |
|---|
| 399 | WRITE(numout,*) ' ITF specific parameterisation = ', ln_tmx_itf |
|---|
| 400 | WRITE(numout,*) ' ITF tidal dissipation efficiency = ', rn_tfe_itf |
|---|
| 401 | ENDIF |
|---|
| 402 | |
|---|
| 403 | ! ! allocate tmx arrays |
|---|
| 404 | IF( zdf_tmx_alloc() /= 0 ) CALL ctl_stop( 'STOP', 'zdf_tmx_init : unable to allocate tmx arrays' ) |
|---|
| 405 | |
|---|
| 406 | IF( ln_tmx_itf ) THEN ! read the Indonesian Through Flow mask |
|---|
| 407 | CALL iom_open('mask_itf',inum) |
|---|
| 408 | CALL iom_get (inum, jpdom_data, 'tmaskitf',mask_itf,1) ! |
|---|
| 409 | CALL iom_close(inum) |
|---|
| 410 | ENDIF |
|---|
| 411 | |
|---|
| 412 | ! read M2 tidal energy flux : W/m2 ( zem2 < 0 ) |
|---|
| 413 | CALL iom_open('M2rowdrg',inum) |
|---|
| 414 | CALL iom_get (inum, jpdom_data, 'field',zem2,1) ! |
|---|
| 415 | CALL iom_close(inum) |
|---|
| 416 | |
|---|
| 417 | ! read K1 tidal energy flux : W/m2 ( zek1 < 0 ) |
|---|
| 418 | CALL iom_open('K1rowdrg',inum) |
|---|
| 419 | CALL iom_get (inum, jpdom_data, 'field',zek1,1) ! |
|---|
| 420 | CALL iom_close(inum) |
|---|
| 421 | |
|---|
| 422 | ! Total tidal energy ( M2, S2 and K1 with S2=(1/2)^2 * M2 ) |
|---|
| 423 | ! only the energy available for mixing is taken into account, |
|---|
| 424 | ! (mixing efficiency tidal dissipation efficiency) |
|---|
| 425 | en_tmx(:,:) = - rn_tfe * rn_me * ( zem2(:,:) * 1.25 + zek1(:,:) ) * ssmask(:,:) |
|---|
| 426 | |
|---|
| 427 | !============ |
|---|
| 428 | !TG: Bug for VVL? Should this section be moved out of _init and be updated at every timestep? |
|---|
| 429 | ! Vertical structure (az_tmx) |
|---|
| 430 | DO jj = 1, jpj ! part independent of the level |
|---|
| 431 | DO ji = 1, jpi |
|---|
| 432 | zhdep(ji,jj) = gdepw_0(ji,jj,mbkt(ji,jj)+1) ! depth of the ocean |
|---|
| 433 | zfact(ji,jj) = rau0 * rn_htmx * ( 1. - EXP( -zhdep(ji,jj) / rn_htmx ) ) |
|---|
| 434 | IF( zfact(ji,jj) /= 0 ) zfact(ji,jj) = en_tmx(ji,jj) / zfact(ji,jj) |
|---|
| 435 | END DO |
|---|
| 436 | END DO |
|---|
| 437 | DO jk= 1, jpk ! complete with the level-dependent part |
|---|
| 438 | DO jj = 1, jpj |
|---|
| 439 | DO ji = 1, jpi |
|---|
| 440 | az_tmx(ji,jj,jk) = zfact(ji,jj) * EXP( -( zhdep(ji,jj)-gdepw_0(ji,jj,jk) ) / rn_htmx ) * tmask(ji,jj,jk) |
|---|
| 441 | END DO |
|---|
| 442 | END DO |
|---|
| 443 | END DO |
|---|
| 444 | !=========== |
|---|
| 445 | |
|---|
| 446 | IF( nprint == 1 .AND. lwp ) THEN |
|---|
| 447 | ! Control print |
|---|
| 448 | ! Total power consumption due to vertical mixing |
|---|
| 449 | ! zpc = rau0 * 1/rn_me * rn2 * zav_tide |
|---|
| 450 | zav_tide(:,:,:) = 0.e0 |
|---|
| 451 | DO jk = 2, jpkm1 |
|---|
| 452 | zav_tide(:,:,jk) = az_tmx(:,:,jk) / MAX( rn_n2min, rn2(:,:,jk) ) |
|---|
| 453 | END DO |
|---|
| 454 | |
|---|
| 455 | ztpc = 0.e0 |
|---|
| 456 | zpc(:,:,:) = MAX(rn_n2min,rn2(:,:,:)) * zav_tide(:,:,:) |
|---|
| 457 | DO jk= 2, jpkm1 |
|---|
| 458 | DO jj = 1, jpj |
|---|
| 459 | DO ji = 1, jpi |
|---|
| 460 | ztpc = ztpc + fse3w(ji,jj,jk) * e1t(ji,jj) * e2t(ji,jj) * zpc(ji,jj,jk) * wmask(ji,jj,jk) * tmask_i(ji,jj) |
|---|
| 461 | END DO |
|---|
| 462 | END DO |
|---|
| 463 | END DO |
|---|
| 464 | ztpc= rau0 * 1/(rn_tfe * rn_me) * ztpc |
|---|
| 465 | |
|---|
| 466 | WRITE(numout,*) |
|---|
| 467 | WRITE(numout,*) ' Total power consumption of the tidally driven part of Kz : ztpc = ', ztpc * 1.e-12 ,'TW' |
|---|
| 468 | |
|---|
| 469 | |
|---|
| 470 | ! control print 2 |
|---|
| 471 | zav_tide(:,:,:) = MIN( zav_tide(:,:,:), 60.e-4 ) |
|---|
| 472 | zkz(:,:) = 0.e0 |
|---|
| 473 | DO jk = 2, jpkm1 |
|---|
| 474 | DO jj = 1, jpj |
|---|
| 475 | DO ji = 1, jpi |
|---|
| 476 | zkz(ji,jj) = zkz(ji,jj) + fse3w(ji,jj,jk) * MAX(0.e0, rn2(ji,jj,jk)) * rau0 * zav_tide(ji,jj,jk) * wmask(ji,jj,jk) |
|---|
| 477 | END DO |
|---|
| 478 | END DO |
|---|
| 479 | END DO |
|---|
| 480 | ! Here zkz should be equal to en_tmx ==> multiply by en_tmx/zkz |
|---|
| 481 | DO jj = 1, jpj |
|---|
| 482 | DO ji = 1, jpi |
|---|
| 483 | IF( zkz(ji,jj) /= 0.e0 ) THEN |
|---|
| 484 | zkz(ji,jj) = en_tmx(ji,jj) / zkz(ji,jj) |
|---|
| 485 | ENDIF |
|---|
| 486 | END DO |
|---|
| 487 | END DO |
|---|
| 488 | ztpc = 1.e50 |
|---|
| 489 | DO jj = 1, jpj |
|---|
| 490 | DO ji = 1, jpi |
|---|
| 491 | IF( zkz(ji,jj) /= 0.e0 ) THEN |
|---|
| 492 | ztpc = Min( zkz(ji,jj), ztpc) |
|---|
| 493 | ENDIF |
|---|
| 494 | END DO |
|---|
| 495 | END DO |
|---|
| 496 | WRITE(numout,*) ' Min de zkz ', ztpc, ' Max = ', maxval(zkz(:,:) ) |
|---|
| 497 | |
|---|
| 498 | DO jk = 2, jpkm1 |
|---|
| 499 | DO jj = 1, jpj |
|---|
| 500 | DO ji = 1, jpi |
|---|
| 501 | zav_tide(ji,jj,jk) = zav_tide(ji,jj,jk) * MIN( zkz(ji,jj), 30./6. ) * wmask(ji,jj,jk) !kz max = 300 cm2/s |
|---|
| 502 | END DO |
|---|
| 503 | END DO |
|---|
| 504 | END DO |
|---|
| 505 | ztpc = 0.e0 |
|---|
| 506 | zpc(:,:,:) = Max(0.e0,rn2(:,:,:)) * zav_tide(:,:,:) |
|---|
| 507 | DO jk= 1, jpk |
|---|
| 508 | DO jj = 1, jpj |
|---|
| 509 | DO ji = 1, jpi |
|---|
| 510 | ztpc = ztpc + fse3w(ji,jj,jk) * e1t(ji,jj) * e2t(ji,jj) * zpc(ji,jj,jk) * wmask(ji,jj,jk) * tmask_i(ji,jj) |
|---|
| 511 | END DO |
|---|
| 512 | END DO |
|---|
| 513 | END DO |
|---|
| 514 | ztpc= rau0 * 1/(rn_tfe * rn_me) * ztpc |
|---|
| 515 | WRITE(numout,*) ' 2 Total power consumption of the tidally driven part of Kz : ztpc = ', ztpc * 1.e-12 ,'TW' |
|---|
| 516 | |
|---|
| 517 | DO jk = 1, jpk |
|---|
| 518 | ze_z = SUM( e1t(:,:) * e2t(:,:) * zav_tide(:,:,jk) * tmask_i(:,:) ) & |
|---|
| 519 | & / MAX( 1.e-20, SUM( e1t(:,:) * e2t(:,:) * wmask (:,:,jk) * tmask_i(:,:) ) ) |
|---|
| 520 | ztpc = 1.E50 |
|---|
| 521 | DO jj = 1, jpj |
|---|
| 522 | DO ji = 1, jpi |
|---|
| 523 | IF( zav_tide(ji,jj,jk) /= 0.e0 ) ztpc =Min( ztpc, zav_tide(ji,jj,jk) ) |
|---|
| 524 | END DO |
|---|
| 525 | END DO |
|---|
| 526 | WRITE(numout,*) ' N2 min - jk= ', jk,' ', ze_z * 1.e4,' cm2/s min= ',ztpc*1.e4, & |
|---|
| 527 | & 'max= ', MAXVAL(zav_tide(:,:,jk) )*1.e4, ' cm2/s' |
|---|
| 528 | END DO |
|---|
| 529 | |
|---|
| 530 | WRITE(numout,*) ' e_tide : ', SUM( e1t*e2t*en_tmx ) / ( rn_tfe * rn_me ) * 1.e-12, 'TW' |
|---|
| 531 | WRITE(numout,*) |
|---|
| 532 | WRITE(numout,*) ' Initial profile of tidal vertical mixing' |
|---|
| 533 | DO jk = 1, jpk |
|---|
| 534 | DO jj = 1,jpj |
|---|
| 535 | DO ji = 1,jpi |
|---|
| 536 | zkz(ji,jj) = az_tmx(ji,jj,jk) /MAX( rn_n2min, rn2(ji,jj,jk) ) |
|---|
| 537 | END DO |
|---|
| 538 | END DO |
|---|
| 539 | ze_z = SUM( e1t(:,:) * e2t(:,:) * zkz(:,:) * tmask_i(:,:) ) & |
|---|
| 540 | & / MAX( 1.e-20, SUM( e1t(:,:) * e2t(:,:) * wmask (:,:,jk) * tmask_i(:,:) ) ) |
|---|
| 541 | WRITE(numout,*) ' jk= ', jk,' ', ze_z * 1.e4,' cm2/s' |
|---|
| 542 | END DO |
|---|
| 543 | DO jk = 1, jpk |
|---|
| 544 | zkz(:,:) = az_tmx(:,:,jk) /rn_n2min |
|---|
| 545 | ze_z = SUM( e1t(:,:) * e2t(:,:) * zkz(:,:) * tmask_i(:,:) ) & |
|---|
| 546 | & / MAX( 1.e-20, SUM( e1t(:,:) * e2t(:,:) * wmask (:,:,jk) * tmask_i(:,:) ) ) |
|---|
| 547 | WRITE(numout,*) |
|---|
| 548 | WRITE(numout,*) ' N2 min - jk= ', jk,' ', ze_z * 1.e4,' cm2/s min= ',MINVAL(zkz)*1.e4, & |
|---|
| 549 | & 'max= ', MAXVAL(zkz)*1.e4, ' cm2/s' |
|---|
| 550 | END DO |
|---|
| 551 | ! |
|---|
| 552 | ENDIF |
|---|
| 553 | ! |
|---|
| 554 | CALL wrk_dealloc( jpi,jpj, zem2, zek1, zkz, zfact, zhdep ) |
|---|
| 555 | CALL wrk_dealloc( jpi,jpj,jpk, zpc ) |
|---|
| 556 | ! |
|---|
| 557 | IF( nn_timing == 1 ) CALL timing_stop('zdf_tmx_init') |
|---|
| 558 | ! |
|---|
| 559 | END SUBROUTINE zdf_tmx_init |
|---|
| 560 | |
|---|
| 561 | #elif defined key_zdftmx_new |
|---|
| 562 | !!---------------------------------------------------------------------- |
|---|
| 563 | !! 'key_zdftmx_new' Internal wave-driven vertical mixing |
|---|
| 564 | !!---------------------------------------------------------------------- |
|---|
| 565 | !! zdf_tmx : global momentum & tracer Kz with wave induced Kz |
|---|
| 566 | !! zdf_tmx_init : global momentum & tracer Kz with wave induced Kz |
|---|
| 567 | !!---------------------------------------------------------------------- |
|---|
| 568 | USE oce ! ocean dynamics and tracers variables |
|---|
| 569 | USE dom_oce ! ocean space and time domain variables |
|---|
| 570 | USE zdf_oce ! ocean vertical physics variables |
|---|
| 571 | USE zdfddm ! ocean vertical physics: double diffusive mixing |
|---|
| 572 | USE lbclnk ! ocean lateral boundary conditions (or mpp link) |
|---|
| 573 | USE eosbn2 ! ocean equation of state |
|---|
| 574 | USE phycst ! physical constants |
|---|
| 575 | USE prtctl ! Print control |
|---|
| 576 | USE in_out_manager ! I/O manager |
|---|
| 577 | USE iom ! I/O Manager |
|---|
| 578 | USE lib_mpp ! MPP library |
|---|
| 579 | USE wrk_nemo ! work arrays |
|---|
| 580 | USE timing ! Timing |
|---|
| 581 | USE lib_fortran ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) |
|---|
| 582 | |
|---|
| 583 | IMPLICIT NONE |
|---|
| 584 | PRIVATE |
|---|
| 585 | |
|---|
| 586 | PUBLIC zdf_tmx ! called in step module |
|---|
| 587 | PUBLIC zdf_tmx_init ! called in nemogcm module |
|---|
| 588 | PUBLIC zdf_tmx_alloc ! called in nemogcm module |
|---|
| 589 | |
|---|
| 590 | LOGICAL, PUBLIC, PARAMETER :: lk_zdftmx = .TRUE. !: wave-driven mixing flag |
|---|
| 591 | |
|---|
| 592 | ! !!* Namelist namzdf_tmx : internal wave-driven mixing * |
|---|
| 593 | INTEGER :: nn_zpyc ! pycnocline-intensified mixing energy proportional to N (=1) or N^2 (=2) |
|---|
| 594 | LOGICAL :: ln_mevar ! variable (=T) or constant (=F) mixing efficiency |
|---|
| 595 | LOGICAL :: ln_tsdiff ! account for differential T/S wave-driven mixing (=T) or not (=F) |
|---|
| 596 | |
|---|
| 597 | REAL(wp) :: r1_6 = 1._wp / 6._wp |
|---|
| 598 | |
|---|
| 599 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) :: ebot_tmx ! power available from high-mode wave breaking (W/m2) |
|---|
| 600 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) :: epyc_tmx ! power available from low-mode, pycnocline-intensified wave breaking (W/m2) |
|---|
| 601 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) :: ecri_tmx ! power available from low-mode, critical slope wave breaking (W/m2) |
|---|
| 602 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) :: hbot_tmx ! WKB decay scale for high-mode energy dissipation (m) |
|---|
| 603 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) :: hcri_tmx ! decay scale for low-mode critical slope dissipation (m) |
|---|
| 604 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: emix_tmx ! local energy density available for mixing (W/kg) |
|---|
| 605 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: bflx_tmx ! buoyancy flux Kz * N^2 (W/kg) |
|---|
| 606 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) :: pcmap_tmx ! vertically integrated buoyancy flux (W/m2) |
|---|
| 607 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: zav_ratio ! S/T diffusivity ratio (only for ln_tsdiff=T) |
|---|
| 608 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: zav_wave ! Internal wave-induced diffusivity |
|---|
| 609 | |
|---|
| 610 | !! * Substitutions |
|---|
| 611 | # include "zdfddm_substitute.h90" |
|---|
| 612 | # include "domzgr_substitute.h90" |
|---|
| 613 | # include "vectopt_loop_substitute.h90" |
|---|
| 614 | !!---------------------------------------------------------------------- |
|---|
| 615 | !! NEMO/OPA 4.0 , NEMO Consortium (2016) |
|---|
| 616 | !! $Id$ |
|---|
| 617 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
|---|
| 618 | !!---------------------------------------------------------------------- |
|---|
| 619 | CONTAINS |
|---|
| 620 | |
|---|
| 621 | INTEGER FUNCTION zdf_tmx_alloc() |
|---|
| 622 | !!---------------------------------------------------------------------- |
|---|
| 623 | !! *** FUNCTION zdf_tmx_alloc *** |
|---|
| 624 | !!---------------------------------------------------------------------- |
|---|
| 625 | ALLOCATE( ebot_tmx(jpi,jpj), epyc_tmx(jpi,jpj), ecri_tmx(jpi,jpj) , & |
|---|
| 626 | & hbot_tmx(jpi,jpj), hcri_tmx(jpi,jpj), emix_tmx(jpi,jpj,jpk), & |
|---|
| 627 | & bflx_tmx(jpi,jpj,jpk), pcmap_tmx(jpi,jpj), zav_ratio(jpi,jpj,jpk), & |
|---|
| 628 | & zav_wave(jpi,jpj,jpk), STAT=zdf_tmx_alloc ) |
|---|
| 629 | ! |
|---|
| 630 | IF( lk_mpp ) CALL mpp_sum ( zdf_tmx_alloc ) |
|---|
| 631 | IF( zdf_tmx_alloc /= 0 ) CALL ctl_warn('zdf_tmx_alloc: failed to allocate arrays') |
|---|
| 632 | END FUNCTION zdf_tmx_alloc |
|---|
| 633 | |
|---|
| 634 | |
|---|
| 635 | SUBROUTINE zdf_tmx( kt ) |
|---|
| 636 | !!---------------------------------------------------------------------- |
|---|
| 637 | !! *** ROUTINE zdf_tmx *** |
|---|
| 638 | !! |
|---|
| 639 | !! ** Purpose : add to the vertical mixing coefficients the effect of |
|---|
| 640 | !! breaking internal waves. |
|---|
| 641 | !! |
|---|
| 642 | !! ** Method : - internal wave-driven vertical mixing is given by: |
|---|
| 643 | !! Kz_wave = min( 100 cm2/s, f( Reb = emix_tmx /( Nu * N^2 ) ) |
|---|
| 644 | !! where emix_tmx is the 3D space distribution of the wave-breaking |
|---|
| 645 | !! energy and Nu the molecular kinematic viscosity. |
|---|
| 646 | !! The function f(Reb) is linear (constant mixing efficiency) |
|---|
| 647 | !! if the namelist parameter ln_mevar = F and nonlinear if ln_mevar = T. |
|---|
| 648 | !! |
|---|
| 649 | !! - Compute emix_tmx, the 3D power density that allows to compute |
|---|
| 650 | !! Reb and therefrom the wave-induced vertical diffusivity. |
|---|
| 651 | !! This is divided into three components: |
|---|
| 652 | !! 1. Bottom-intensified low-mode dissipation at critical slopes |
|---|
| 653 | !! emix_tmx(z) = ( ecri_tmx / rau0 ) * EXP( -(H-z)/hcri_tmx ) |
|---|
| 654 | !! / ( 1. - EXP( - H/hcri_tmx ) ) * hcri_tmx |
|---|
| 655 | !! where hcri_tmx is the characteristic length scale of the bottom |
|---|
| 656 | !! intensification, ecri_tmx a map of available power, and H the ocean depth. |
|---|
| 657 | !! 2. Pycnocline-intensified low-mode dissipation |
|---|
| 658 | !! emix_tmx(z) = ( epyc_tmx / rau0 ) * ( sqrt(rn2(z))^nn_zpyc ) |
|---|
| 659 | !! / SUM( sqrt(rn2(z))^nn_zpyc * e3w(z) ) |
|---|
| 660 | !! where epyc_tmx is a map of available power, and nn_zpyc |
|---|
| 661 | !! is the chosen stratification-dependence of the internal wave |
|---|
| 662 | !! energy dissipation. |
|---|
| 663 | !! 3. WKB-height dependent high mode dissipation |
|---|
| 664 | !! emix_tmx(z) = ( ebot_tmx / rau0 ) * rn2(z) * EXP(-z_wkb(z)/hbot_tmx) |
|---|
| 665 | !! / SUM( rn2(z) * EXP(-z_wkb(z)/hbot_tmx) * e3w(z) ) |
|---|
| 666 | !! where hbot_tmx is the characteristic length scale of the WKB bottom |
|---|
| 667 | !! intensification, ebot_tmx is a map of available power, and z_wkb is the |
|---|
| 668 | !! WKB-stretched height above bottom defined as |
|---|
| 669 | !! z_wkb(z) = H * SUM( sqrt(rn2(z'>=z)) * e3w(z'>=z) ) |
|---|
| 670 | !! / SUM( sqrt(rn2(z')) * e3w(z') ) |
|---|
| 671 | !! |
|---|
| 672 | !! - update the model vertical eddy viscosity and diffusivity: |
|---|
| 673 | !! avt = avt + av_wave |
|---|
| 674 | !! avm = avm + av_wave |
|---|
| 675 | !! avmu = avmu + mi(av_wave) |
|---|
| 676 | !! avmv = avmv + mj(av_wave) |
|---|
| 677 | !! |
|---|
| 678 | !! - if namelist parameter ln_tsdiff = T, account for differential mixing: |
|---|
| 679 | !! avs = avt + av_wave * diffusivity_ratio(Reb) |
|---|
| 680 | !! |
|---|
| 681 | !! ** Action : - Define emix_tmx used to compute internal wave-induced mixing |
|---|
| 682 | !! - avt, avs, avm, avmu, avmv increased by internal wave-driven mixing |
|---|
| 683 | !! |
|---|
| 684 | !! References : de Lavergne et al. 2015, JPO; 2016, in prep. |
|---|
| 685 | !!---------------------------------------------------------------------- |
|---|
| 686 | INTEGER, INTENT(in) :: kt ! ocean time-step |
|---|
| 687 | ! |
|---|
| 688 | INTEGER :: ji, jj, jk ! dummy loop indices |
|---|
| 689 | REAL(wp) :: ztpc ! scalar workspace |
|---|
| 690 | REAL(wp), DIMENSION(:,:) , POINTER :: zfact ! Used for vertical structure |
|---|
| 691 | REAL(wp), DIMENSION(:,:) , POINTER :: zhdep ! Ocean depth |
|---|
| 692 | REAL(wp), DIMENSION(:,:,:), POINTER :: zwkb ! WKB-stretched height above bottom |
|---|
| 693 | REAL(wp), DIMENSION(:,:,:), POINTER :: zweight ! Weight for high mode vertical distribution |
|---|
| 694 | REAL(wp), DIMENSION(:,:,:), POINTER :: znu_t ! Molecular kinematic viscosity (T grid) |
|---|
| 695 | REAL(wp), DIMENSION(:,:,:), POINTER :: znu_w ! Molecular kinematic viscosity (W grid) |
|---|
| 696 | REAL(wp), DIMENSION(:,:,:), POINTER :: zReb ! Turbulence intensity parameter |
|---|
| 697 | !!---------------------------------------------------------------------- |
|---|
| 698 | ! |
|---|
| 699 | IF( nn_timing == 1 ) CALL timing_start('zdf_tmx') |
|---|
| 700 | ! |
|---|
| 701 | CALL wrk_alloc( jpi,jpj, zfact, zhdep ) |
|---|
| 702 | CALL wrk_alloc( jpi,jpj,jpk, zwkb, zweight, znu_t, znu_w, zReb ) |
|---|
| 703 | |
|---|
| 704 | ! ! ----------------------------- ! |
|---|
| 705 | ! ! Internal wave-driven mixing ! (compute zav_wave) |
|---|
| 706 | ! ! ----------------------------- ! |
|---|
| 707 | ! |
|---|
| 708 | ! !* Critical slope mixing: distribute energy over the time-varying ocean depth, |
|---|
| 709 | ! using an exponential decay from the seafloor. |
|---|
| 710 | DO jj = 1, jpj ! part independent of the level |
|---|
| 711 | DO ji = 1, jpi |
|---|
| 712 | zhdep(ji,jj) = fsdepw(ji,jj,mbkt(ji,jj)+1) ! depth of the ocean |
|---|
| 713 | zfact(ji,jj) = rau0 * ( 1._wp - EXP( -zhdep(ji,jj) / hcri_tmx(ji,jj) ) ) |
|---|
| 714 | IF( zfact(ji,jj) /= 0 ) zfact(ji,jj) = ecri_tmx(ji,jj) / zfact(ji,jj) |
|---|
| 715 | END DO |
|---|
| 716 | END DO |
|---|
| 717 | |
|---|
| 718 | DO jk = 2, jpkm1 ! complete with the level-dependent part |
|---|
| 719 | emix_tmx(:,:,jk) = zfact(:,:) * ( EXP( ( fsde3w(:,:,jk ) - zhdep(:,:) ) / hcri_tmx(:,:) ) & |
|---|
| 720 | & - EXP( ( fsde3w(:,:,jk-1) - zhdep(:,:) ) / hcri_tmx(:,:) ) ) * wmask(:,:,jk) & |
|---|
| 721 | & / ( fsde3w(:,:,jk) - fsde3w(:,:,jk-1) ) |
|---|
| 722 | END DO |
|---|
| 723 | |
|---|
| 724 | ! !* Pycnocline-intensified mixing: distribute energy over the time-varying |
|---|
| 725 | ! !* ocean depth as proportional to sqrt(rn2)^nn_zpyc |
|---|
| 726 | |
|---|
| 727 | SELECT CASE ( nn_zpyc ) |
|---|
| 728 | |
|---|
| 729 | CASE ( 1 ) ! Dissipation scales as N (recommended) |
|---|
| 730 | |
|---|
| 731 | zfact(:,:) = 0._wp |
|---|
| 732 | DO jk = 2, jpkm1 ! part independent of the level |
|---|
| 733 | zfact(:,:) = zfact(:,:) + fse3w(:,:,jk) * SQRT( MAX( 0._wp, rn2(:,:,jk) ) ) * wmask(:,:,jk) |
|---|
| 734 | END DO |
|---|
| 735 | |
|---|
| 736 | DO jj = 1, jpj |
|---|
| 737 | DO ji = 1, jpi |
|---|
| 738 | IF( zfact(ji,jj) /= 0 ) zfact(ji,jj) = epyc_tmx(ji,jj) / ( rau0 * zfact(ji,jj) ) |
|---|
| 739 | END DO |
|---|
| 740 | END DO |
|---|
| 741 | |
|---|
| 742 | DO jk = 2, jpkm1 ! complete with the level-dependent part |
|---|
| 743 | emix_tmx(:,:,jk) = emix_tmx(:,:,jk) + zfact(:,:) * SQRT( MAX( 0._wp, rn2(:,:,jk) ) ) * wmask(:,:,jk) |
|---|
| 744 | END DO |
|---|
| 745 | |
|---|
| 746 | CASE ( 2 ) ! Dissipation scales as N^2 |
|---|
| 747 | |
|---|
| 748 | zfact(:,:) = 0._wp |
|---|
| 749 | DO jk = 2, jpkm1 ! part independent of the level |
|---|
| 750 | zfact(:,:) = zfact(:,:) + fse3w(:,:,jk) * MAX( 0._wp, rn2(:,:,jk) ) * wmask(:,:,jk) |
|---|
| 751 | END DO |
|---|
| 752 | |
|---|
| 753 | DO jj= 1, jpj |
|---|
| 754 | DO ji = 1, jpi |
|---|
| 755 | IF( zfact(ji,jj) /= 0 ) zfact(ji,jj) = epyc_tmx(ji,jj) / ( rau0 * zfact(ji,jj) ) |
|---|
| 756 | END DO |
|---|
| 757 | END DO |
|---|
| 758 | |
|---|
| 759 | DO jk = 2, jpkm1 ! complete with the level-dependent part |
|---|
| 760 | emix_tmx(:,:,jk) = emix_tmx(:,:,jk) + zfact(:,:) * MAX( 0._wp, rn2(:,:,jk) ) * wmask(:,:,jk) |
|---|
| 761 | END DO |
|---|
| 762 | |
|---|
| 763 | END SELECT |
|---|
| 764 | |
|---|
| 765 | ! !* WKB-height dependent mixing: distribute energy over the time-varying |
|---|
| 766 | ! !* ocean depth as proportional to rn2 * exp(-z_wkb/rn_hbot) |
|---|
| 767 | |
|---|
| 768 | zwkb(:,:,:) = 0._wp |
|---|
| 769 | zfact(:,:) = 0._wp |
|---|
| 770 | DO jk = 2, jpkm1 |
|---|
| 771 | zfact(:,:) = zfact(:,:) + fse3w(:,:,jk) * SQRT( MAX( 0._wp, rn2(:,:,jk) ) ) * wmask(:,:,jk) |
|---|
| 772 | zwkb(:,:,jk) = zfact(:,:) |
|---|
| 773 | END DO |
|---|
| 774 | |
|---|
| 775 | DO jk = 2, jpkm1 |
|---|
| 776 | DO jj = 1, jpj |
|---|
| 777 | DO ji = 1, jpi |
|---|
| 778 | IF( zfact(ji,jj) /= 0 ) zwkb(ji,jj,jk) = zhdep(ji,jj) * ( zfact(ji,jj) - zwkb(ji,jj,jk) ) & |
|---|
| 779 | & * tmask(ji,jj,jk) / zfact(ji,jj) |
|---|
| 780 | END DO |
|---|
| 781 | END DO |
|---|
| 782 | END DO |
|---|
| 783 | zwkb(:,:,1) = zhdep(:,:) * tmask(:,:,1) |
|---|
| 784 | |
|---|
| 785 | zweight(:,:,:) = 0._wp |
|---|
| 786 | DO jk = 2, jpkm1 |
|---|
| 787 | zweight(:,:,jk) = MAX( 0._wp, rn2(:,:,jk) ) * hbot_tmx(:,:) * wmask(:,:,jk) & |
|---|
| 788 | & * ( EXP( -zwkb(:,:,jk) / hbot_tmx(:,:) ) - EXP( -zwkb(:,:,jk-1) / hbot_tmx(:,:) ) ) |
|---|
| 789 | END DO |
|---|
| 790 | |
|---|
| 791 | zfact(:,:) = 0._wp |
|---|
| 792 | DO jk = 2, jpkm1 ! part independent of the level |
|---|
| 793 | zfact(:,:) = zfact(:,:) + zweight(:,:,jk) |
|---|
| 794 | END DO |
|---|
| 795 | |
|---|
| 796 | DO jj = 1, jpj |
|---|
| 797 | DO ji = 1, jpi |
|---|
| 798 | IF( zfact(ji,jj) /= 0 ) zfact(ji,jj) = ebot_tmx(ji,jj) / ( rau0 * zfact(ji,jj) ) |
|---|
| 799 | END DO |
|---|
| 800 | END DO |
|---|
| 801 | |
|---|
| 802 | DO jk = 2, jpkm1 ! complete with the level-dependent part |
|---|
| 803 | emix_tmx(:,:,jk) = emix_tmx(:,:,jk) + zweight(:,:,jk) * zfact(:,:) * wmask(:,:,jk) & |
|---|
| 804 | & / ( fsde3w(:,:,jk) - fsde3w(:,:,jk-1) ) |
|---|
| 805 | END DO |
|---|
| 806 | |
|---|
| 807 | |
|---|
| 808 | ! Calculate molecular kinematic viscosity |
|---|
| 809 | znu_t(:,:,:) = 1.e-4_wp * ( 17.91_wp - 0.53810_wp * tsn(:,:,:,jp_tem) + 0.00694_wp * tsn(:,:,:,jp_tem) * tsn(:,:,:,jp_tem) & |
|---|
| 810 | & + 0.02305_wp * tsn(:,:,:,jp_sal) ) * tmask(:,:,:) * r1_rau0 |
|---|
| 811 | DO jk = 2, jpkm1 |
|---|
| 812 | znu_w(:,:,jk) = 0.5_wp * ( znu_t(:,:,jk-1) + znu_t(:,:,jk) ) * wmask(:,:,jk) |
|---|
| 813 | END DO |
|---|
| 814 | |
|---|
| 815 | ! Calculate turbulence intensity parameter Reb |
|---|
| 816 | DO jk = 2, jpkm1 |
|---|
| 817 | zReb(:,:,jk) = emix_tmx(:,:,jk) / MAX( 1.e-20_wp, znu_w(:,:,jk) * rn2(:,:,jk) ) |
|---|
| 818 | END DO |
|---|
| 819 | |
|---|
| 820 | ! Define internal wave-induced diffusivity |
|---|
| 821 | DO jk = 2, jpkm1 |
|---|
| 822 | zav_wave(:,:,jk) = znu_w(:,:,jk) * zReb(:,:,jk) * r1_6 ! This corresponds to a constant mixing efficiency of 1/6 |
|---|
| 823 | END DO |
|---|
| 824 | |
|---|
| 825 | IF( ln_mevar ) THEN ! Variable mixing efficiency case : modify zav_wave in the |
|---|
| 826 | DO jk = 2, jpkm1 ! energetic (Reb > 480) and buoyancy-controlled (Reb <10.224 ) regimes |
|---|
| 827 | DO jj = 1, jpj |
|---|
| 828 | DO ji = 1, jpi |
|---|
| 829 | IF( zReb(ji,jj,jk) > 480.00_wp ) THEN |
|---|
| 830 | zav_wave(ji,jj,jk) = 3.6515_wp * znu_w(ji,jj,jk) * SQRT( zReb(ji,jj,jk) ) |
|---|
| 831 | ELSEIF( zReb(ji,jj,jk) < 10.224_wp ) THEN |
|---|
| 832 | zav_wave(ji,jj,jk) = 0.052125_wp * znu_w(ji,jj,jk) * zReb(ji,jj,jk) * SQRT( zReb(ji,jj,jk) ) |
|---|
| 833 | ENDIF |
|---|
| 834 | END DO |
|---|
| 835 | END DO |
|---|
| 836 | END DO |
|---|
| 837 | ENDIF |
|---|
| 838 | |
|---|
| 839 | DO jk = 2, jpkm1 ! Bound diffusivity by molecular value and 100 cm2/s |
|---|
| 840 | zav_wave(:,:,jk) = MIN( MAX( 1.4e-7_wp, zav_wave(:,:,jk) ), 1.e-2_wp ) * wmask(:,:,jk) |
|---|
| 841 | END DO |
|---|
| 842 | |
|---|
| 843 | IF( kt == nit000 ) THEN !* Control print at first time-step: diagnose the energy consumed by zav_wave |
|---|
| 844 | ztpc = 0._wp |
|---|
| 845 | DO jk = 2, jpkm1 |
|---|
| 846 | DO jj = 1, jpj |
|---|
| 847 | DO ji = 1, jpi |
|---|
| 848 | ztpc = ztpc + fse3w(ji,jj,jk) * e1e2t(ji,jj) & |
|---|
| 849 | & * MAX( 0._wp, rn2(ji,jj,jk) ) * zav_wave(ji,jj,jk) * wmask(ji,jj,jk) * tmask_i(ji,jj) |
|---|
| 850 | END DO |
|---|
| 851 | END DO |
|---|
| 852 | END DO |
|---|
| 853 | IF( lk_mpp ) CALL mpp_sum( ztpc ) |
|---|
| 854 | ztpc = rau0 * ztpc ! Global integral of rauo * Kz * N^2 = power contributing to mixing |
|---|
| 855 | |
|---|
| 856 | IF(lwp) THEN |
|---|
| 857 | WRITE(numout,*) |
|---|
| 858 | WRITE(numout,*) 'zdf_tmx : Internal wave-driven mixing (tmx)' |
|---|
| 859 | WRITE(numout,*) '~~~~~~~ ' |
|---|
| 860 | WRITE(numout,*) |
|---|
| 861 | WRITE(numout,*) ' Total power consumption by av_wave: ztpc = ', ztpc * 1.e-12_wp, 'TW' |
|---|
| 862 | ENDIF |
|---|
| 863 | ENDIF |
|---|
| 864 | |
|---|
| 865 | ! ! ----------------------- ! |
|---|
| 866 | ! ! Update mixing coefs ! |
|---|
| 867 | ! ! ----------------------- ! |
|---|
| 868 | ! |
|---|
| 869 | IF( ln_tsdiff ) THEN !* Option for differential mixing of salinity and temperature |
|---|
| 870 | DO jk = 2, jpkm1 ! Calculate S/T diffusivity ratio as a function of Reb |
|---|
| 871 | DO jj = 1, jpj |
|---|
| 872 | DO ji = 1, jpi |
|---|
| 873 | zav_ratio(ji,jj,jk) = ( 0.505_wp + 0.495_wp * & |
|---|
| 874 | & TANH( 0.92_wp * ( LOG10( MAX( 1.e-20_wp, zReb(ji,jj,jk) * 5._wp * r1_6 ) ) - 0.60_wp ) ) & |
|---|
| 875 | & ) * wmask(ji,jj,jk) |
|---|
| 876 | END DO |
|---|
| 877 | END DO |
|---|
| 878 | END DO |
|---|
| 879 | CALL iom_put( "av_ratio", zav_ratio ) |
|---|
| 880 | DO jk = 2, jpkm1 !* update momentum & tracer diffusivity with wave-driven mixing |
|---|
| 881 | fsavs(:,:,jk) = avt(:,:,jk) + zav_wave(:,:,jk) * zav_ratio(:,:,jk) |
|---|
| 882 | avt (:,:,jk) = avt(:,:,jk) + zav_wave(:,:,jk) |
|---|
| 883 | avm (:,:,jk) = avm(:,:,jk) + zav_wave(:,:,jk) |
|---|
| 884 | END DO |
|---|
| 885 | ! |
|---|
| 886 | ELSE !* update momentum & tracer diffusivity with wave-driven mixing |
|---|
| 887 | DO jk = 2, jpkm1 |
|---|
| 888 | fsavs(:,:,jk) = avt(:,:,jk) + zav_wave(:,:,jk) |
|---|
| 889 | avt (:,:,jk) = avt(:,:,jk) + zav_wave(:,:,jk) |
|---|
| 890 | avm (:,:,jk) = avm(:,:,jk) + zav_wave(:,:,jk) |
|---|
| 891 | END DO |
|---|
| 892 | ENDIF |
|---|
| 893 | |
|---|
| 894 | DO jk = 2, jpkm1 !* update momentum diffusivity at wu and wv points |
|---|
| 895 | DO jj = 2, jpjm1 |
|---|
| 896 | DO ji = fs_2, fs_jpim1 ! vector opt. |
|---|
| 897 | avmu(ji,jj,jk) = avmu(ji,jj,jk) + 0.5_wp * ( zav_wave(ji,jj,jk) + zav_wave(ji+1,jj ,jk) ) * wumask(ji,jj,jk) |
|---|
| 898 | avmv(ji,jj,jk) = avmv(ji,jj,jk) + 0.5_wp * ( zav_wave(ji,jj,jk) + zav_wave(ji ,jj+1,jk) ) * wvmask(ji,jj,jk) |
|---|
| 899 | END DO |
|---|
| 900 | END DO |
|---|
| 901 | END DO |
|---|
| 902 | CALL lbc_lnk( avmu, 'U', 1. ) ; CALL lbc_lnk( avmv, 'V', 1. ) ! lateral boundary condition |
|---|
| 903 | |
|---|
| 904 | ! !* output internal wave-driven mixing coefficient |
|---|
| 905 | CALL iom_put( "av_wave", zav_wave ) |
|---|
| 906 | !* output useful diagnostics: N^2, Kz * N^2 (bflx_tmx), |
|---|
| 907 | ! vertical integral of rau0 * Kz * N^2 (pcmap_tmx), energy density (emix_tmx) |
|---|
| 908 | IF( iom_use("bflx_tmx") .OR. iom_use("pcmap_tmx") ) THEN |
|---|
| 909 | bflx_tmx(:,:,:) = MAX( 0._wp, rn2(:,:,:) ) * zav_wave(:,:,:) |
|---|
| 910 | pcmap_tmx(:,:) = 0._wp |
|---|
| 911 | DO jk = 2, jpkm1 |
|---|
| 912 | pcmap_tmx(:,:) = pcmap_tmx(:,:) + fse3w(:,:,jk) * bflx_tmx(:,:,jk) * wmask(:,:,jk) |
|---|
| 913 | END DO |
|---|
| 914 | pcmap_tmx(:,:) = rau0 * pcmap_tmx(:,:) |
|---|
| 915 | CALL iom_put( "bflx_tmx", bflx_tmx ) |
|---|
| 916 | CALL iom_put( "pcmap_tmx", pcmap_tmx ) |
|---|
| 917 | ENDIF |
|---|
| 918 | CALL iom_put( "bn2", rn2 ) |
|---|
| 919 | CALL iom_put( "emix_tmx", emix_tmx ) |
|---|
| 920 | |
|---|
| 921 | CALL wrk_dealloc( jpi,jpj, zfact, zhdep ) |
|---|
| 922 | CALL wrk_dealloc( jpi,jpj,jpk, zwkb, zweight, znu_t, znu_w, zReb ) |
|---|
| 923 | |
|---|
| 924 | IF(ln_ctl) CALL prt_ctl(tab3d_1=zav_wave , clinfo1=' tmx - av_wave: ', tab3d_2=avt, clinfo2=' avt: ', ovlap=1, kdim=jpk) |
|---|
| 925 | ! |
|---|
| 926 | IF( nn_timing == 1 ) CALL timing_stop('zdf_tmx') |
|---|
| 927 | ! |
|---|
| 928 | END SUBROUTINE zdf_tmx |
|---|
| 929 | |
|---|
| 930 | |
|---|
| 931 | SUBROUTINE zdf_tmx_init |
|---|
| 932 | !!---------------------------------------------------------------------- |
|---|
| 933 | !! *** ROUTINE zdf_tmx_init *** |
|---|
| 934 | !! |
|---|
| 935 | !! ** Purpose : Initialization of the wave-driven vertical mixing, reading |
|---|
| 936 | !! of input power maps and decay length scales in netcdf files. |
|---|
| 937 | !! |
|---|
| 938 | !! ** Method : - Read the namzdf_tmx namelist and check the parameters |
|---|
| 939 | !! |
|---|
| 940 | !! - Read the input data in NetCDF files : |
|---|
| 941 | !! power available from high-mode wave breaking (mixing_power_bot.nc) |
|---|
| 942 | !! power available from pycnocline-intensified wave-breaking (mixing_power_pyc.nc) |
|---|
| 943 | !! power available from critical slope wave-breaking (mixing_power_cri.nc) |
|---|
| 944 | !! WKB decay scale for high-mode wave-breaking (decay_scale_bot.nc) |
|---|
| 945 | !! decay scale for critical slope wave-breaking (decay_scale_cri.nc) |
|---|
| 946 | !! |
|---|
| 947 | !! ** input : - Namlist namzdf_tmx |
|---|
| 948 | !! - NetCDF files : mixing_power_bot.nc, mixing_power_pyc.nc, mixing_power_cri.nc, |
|---|
| 949 | !! decay_scale_bot.nc decay_scale_cri.nc |
|---|
| 950 | !! |
|---|
| 951 | !! ** Action : - Increase by 1 the nstop flag is setting problem encounter |
|---|
| 952 | !! - Define ebot_tmx, epyc_tmx, ecri_tmx, hbot_tmx, hcri_tmx |
|---|
| 953 | !! |
|---|
| 954 | !! References : de Lavergne et al. 2015, JPO; 2016, in prep. |
|---|
| 955 | !! |
|---|
| 956 | !!---------------------------------------------------------------------- |
|---|
| 957 | INTEGER :: ji, jj, jk ! dummy loop indices |
|---|
| 958 | INTEGER :: inum ! local integer |
|---|
| 959 | INTEGER :: ios |
|---|
| 960 | REAL(wp) :: zbot, zpyc, zcri ! local scalars |
|---|
| 961 | !! |
|---|
| 962 | NAMELIST/namzdf_tmx_new/ nn_zpyc, ln_mevar, ln_tsdiff |
|---|
| 963 | !!---------------------------------------------------------------------- |
|---|
| 964 | ! |
|---|
| 965 | IF( nn_timing == 1 ) CALL timing_start('zdf_tmx_init') |
|---|
| 966 | ! |
|---|
| 967 | REWIND( numnam_ref ) ! Namelist namzdf_tmx in reference namelist : Wave-driven mixing |
|---|
| 968 | READ ( numnam_ref, namzdf_tmx_new, IOSTAT = ios, ERR = 901) |
|---|
| 969 | 901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namzdf_tmx in reference namelist', lwp ) |
|---|
| 970 | ! |
|---|
| 971 | REWIND( numnam_cfg ) ! Namelist namzdf_tmx in configuration namelist : Wave-driven mixing |
|---|
| 972 | READ ( numnam_cfg, namzdf_tmx_new, IOSTAT = ios, ERR = 902 ) |
|---|
| 973 | 902 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namzdf_tmx in configuration namelist', lwp ) |
|---|
| 974 | IF(lwm) WRITE ( numond, namzdf_tmx_new ) |
|---|
| 975 | ! |
|---|
| 976 | IF(lwp) THEN ! Control print |
|---|
| 977 | WRITE(numout,*) |
|---|
| 978 | WRITE(numout,*) 'zdf_tmx_init : internal wave-driven mixing' |
|---|
| 979 | WRITE(numout,*) '~~~~~~~~~~~~' |
|---|
| 980 | WRITE(numout,*) ' Namelist namzdf_tmx_new : set wave-driven mixing parameters' |
|---|
| 981 | WRITE(numout,*) ' Pycnocline-intensified diss. scales as N (=1) or N^2 (=2) = ', nn_zpyc |
|---|
| 982 | WRITE(numout,*) ' Variable (T) or constant (F) mixing efficiency = ', ln_mevar |
|---|
| 983 | WRITE(numout,*) ' Differential internal wave-driven mixing (T) or not (F) = ', ln_tsdiff |
|---|
| 984 | ENDIF |
|---|
| 985 | |
|---|
| 986 | ! The new wave-driven mixing parameterization elevates avt and avm in the interior, and |
|---|
| 987 | ! ensures that avt remains larger than its molecular value (=1.4e-7). Therefore, avtb should |
|---|
| 988 | ! be set here to a very small value, and avmb to its (uniform) molecular value (=1.4e-6). |
|---|
| 989 | avmb(:) = 1.4e-6_wp ! viscous molecular value |
|---|
| 990 | avtb(:) = 1.e-10_wp ! very small diffusive minimum (background avt is specified in zdf_tmx) |
|---|
| 991 | avtb_2d(:,:) = 1.e0_wp ! uniform |
|---|
| 992 | IF(lwp) THEN ! Control print |
|---|
| 993 | WRITE(numout,*) |
|---|
| 994 | WRITE(numout,*) ' Force the background value applied to avm & avt in TKE to be everywhere ', & |
|---|
| 995 | & 'the viscous molecular value & a very small diffusive value, resp.' |
|---|
| 996 | ENDIF |
|---|
| 997 | |
|---|
| 998 | IF( .NOT.lk_zdfddm ) CALL ctl_stop( 'STOP', 'zdf_tmx_init_new : key_zdftmx_new requires key_zdfddm' ) |
|---|
| 999 | |
|---|
| 1000 | ! ! allocate tmx arrays |
|---|
| 1001 | IF( zdf_tmx_alloc() /= 0 ) CALL ctl_stop( 'STOP', 'zdf_tmx_init : unable to allocate tmx arrays' ) |
|---|
| 1002 | ! |
|---|
| 1003 | ! ! read necessary fields |
|---|
| 1004 | CALL iom_open('mixing_power_bot',inum) ! energy flux for high-mode wave breaking [W/m2] |
|---|
| 1005 | CALL iom_get (inum, jpdom_data, 'field', ebot_tmx, 1 ) |
|---|
| 1006 | CALL iom_close(inum) |
|---|
| 1007 | ! |
|---|
| 1008 | CALL iom_open('mixing_power_pyc',inum) ! energy flux for pynocline-intensified wave breaking [W/m2] |
|---|
| 1009 | CALL iom_get (inum, jpdom_data, 'field', epyc_tmx, 1 ) |
|---|
| 1010 | CALL iom_close(inum) |
|---|
| 1011 | ! |
|---|
| 1012 | CALL iom_open('mixing_power_cri',inum) ! energy flux for critical slope wave breaking [W/m2] |
|---|
| 1013 | CALL iom_get (inum, jpdom_data, 'field', ecri_tmx, 1 ) |
|---|
| 1014 | CALL iom_close(inum) |
|---|
| 1015 | ! |
|---|
| 1016 | CALL iom_open('decay_scale_bot',inum) ! spatially variable decay scale for high-mode wave breaking [m] |
|---|
| 1017 | CALL iom_get (inum, jpdom_data, 'field', hbot_tmx, 1 ) |
|---|
| 1018 | CALL iom_close(inum) |
|---|
| 1019 | ! |
|---|
| 1020 | CALL iom_open('decay_scale_cri',inum) ! spatially variable decay scale for critical slope wave breaking [m] |
|---|
| 1021 | CALL iom_get (inum, jpdom_data, 'field', hcri_tmx, 1 ) |
|---|
| 1022 | CALL iom_close(inum) |
|---|
| 1023 | |
|---|
| 1024 | ebot_tmx(:,:) = ebot_tmx(:,:) * ssmask(:,:) |
|---|
| 1025 | epyc_tmx(:,:) = epyc_tmx(:,:) * ssmask(:,:) |
|---|
| 1026 | ecri_tmx(:,:) = ecri_tmx(:,:) * ssmask(:,:) |
|---|
| 1027 | |
|---|
| 1028 | ! Set once for all to zero the first and last vertical levels of appropriate variables |
|---|
| 1029 | emix_tmx (:,:, 1 ) = 0._wp |
|---|
| 1030 | emix_tmx (:,:,jpk) = 0._wp |
|---|
| 1031 | zav_ratio(:,:, 1 ) = 0._wp |
|---|
| 1032 | zav_ratio(:,:,jpk) = 0._wp |
|---|
| 1033 | zav_wave (:,:, 1 ) = 0._wp |
|---|
| 1034 | zav_wave (:,:,jpk) = 0._wp |
|---|
| 1035 | |
|---|
| 1036 | zbot = glob_sum( e1e2t(:,:) * ebot_tmx(:,:) ) |
|---|
| 1037 | zpyc = glob_sum( e1e2t(:,:) * epyc_tmx(:,:) ) |
|---|
| 1038 | zcri = glob_sum( e1e2t(:,:) * ecri_tmx(:,:) ) |
|---|
| 1039 | IF(lwp) THEN |
|---|
| 1040 | WRITE(numout,*) ' High-mode wave-breaking energy: ', zbot * 1.e-12_wp, 'TW' |
|---|
| 1041 | WRITE(numout,*) ' Pycnocline-intensifed wave-breaking energy: ', zpyc * 1.e-12_wp, 'TW' |
|---|
| 1042 | WRITE(numout,*) ' Critical slope wave-breaking energy: ', zcri * 1.e-12_wp, 'TW' |
|---|
| 1043 | ENDIF |
|---|
| 1044 | ! |
|---|
| 1045 | IF( nn_timing == 1 ) CALL timing_stop('zdf_tmx_init') |
|---|
| 1046 | ! |
|---|
| 1047 | END SUBROUTINE zdf_tmx_init |
|---|
| 1048 | |
|---|
| 1049 | #else |
|---|
| 1050 | !!---------------------------------------------------------------------- |
|---|
| 1051 | !! Default option Dummy module NO Tidal MiXing |
|---|
| 1052 | !!---------------------------------------------------------------------- |
|---|
| 1053 | LOGICAL, PUBLIC, PARAMETER :: lk_zdftmx = .FALSE. !: tidal mixing flag |
|---|
| 1054 | CONTAINS |
|---|
| 1055 | SUBROUTINE zdf_tmx_init ! Dummy routine |
|---|
| 1056 | WRITE(*,*) 'zdf_tmx: You should not have seen this print! error?' |
|---|
| 1057 | END SUBROUTINE zdf_tmx_init |
|---|
| 1058 | SUBROUTINE zdf_tmx( kt ) ! Dummy routine |
|---|
| 1059 | WRITE(*,*) 'zdf_tmx: You should not have seen this print! error?', kt |
|---|
| 1060 | END SUBROUTINE zdf_tmx |
|---|
| 1061 | #endif |
|---|
| 1062 | |
|---|
| 1063 | !!====================================================================== |
|---|
| 1064 | END MODULE zdftmx |
|---|
