New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
daymod.F90 in branches/UKMO/dev_r5518_GO6_package_STARTHOUR/NEMOGCM/NEMO/OPA_SRC/DOM – NEMO

source: branches/UKMO/dev_r5518_GO6_package_STARTHOUR/NEMOGCM/NEMO/OPA_SRC/DOM/daymod.F90 @ 11883

Last change on this file since 11883 was 10113, checked in by timgraham, 6 years ago

Bug fix for case where start time is within half a time step of midnight.
File size: 20.7 KB
RevLine 
[3]1MODULE daymod
2   !!======================================================================
3   !!                       ***  MODULE  daymod  ***
[3764]4   !! Ocean        :  calendar
[3]5   !!=====================================================================
[1559]6   !! History :  OPA  ! 1994-09  (M. Pontaud M. Imbard)  Original code
7   !!                 ! 1997-03  (O. Marti)
[3764]8   !!                 ! 1997-05  (G. Madec)
[1559]9   !!                 ! 1997-08  (M. Imbard)
10   !!   NEMO     1.0  ! 2003-09  (G. Madec)  F90 + nyear, nmonth, nday
11   !!                 ! 2004-01  (A.M. Treguier) new calculation based on adatrj
12   !!                 ! 2006-08  (G. Madec)  surface module major update
[3764]13   !!----------------------------------------------------------------------
[3]14
15   !!----------------------------------------------------------------------
16   !!   day        : calendar
[3764]17   !!
[1130]18   !!           -------------------------------
19   !!           ----------- WARNING -----------
20   !!
21   !!   we suppose that the time step is deviding the number of second of in a day
22   !!             ---> MOD( rday, rdttra(1) ) == 0
23   !!
24   !!           ----------- WARNING -----------
25   !!           -------------------------------
[3764]26   !!
[3]27   !!----------------------------------------------------------------------
28   USE dom_oce         ! ocean space and time domain
29   USE phycst          ! physical constants
30   USE in_out_manager  ! I/O manager
[3764]31   USE iom             !
[1559]32   USE ioipsl, ONLY :   ymds2ju   ! for calendar
[258]33   USE prtctl          ! Print control
[2528]34   USE trc_oce, ONLY : lk_offline ! offline flag
[3294]35   USE timing          ! Timing
[3680]36   USE restart         ! restart
[3]37
38   IMPLICIT NONE
39   PRIVATE
40
[1559]41   PUBLIC   day        ! called by step.F90
42   PUBLIC   day_init   ! called by istate.F90
[3764]43   PUBLIC   day_mth    ! Needed by TAM
[3]44
[3764]45   INTEGER, PUBLIC ::   nsecd, nsecd05, ndt, ndt05 ! (PUBLIC for TAM)
[1730]46
[3]47   !!----------------------------------------------------------------------
[2528]48   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
[888]49   !! $Id$
[2715]50   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
[15]51   !!----------------------------------------------------------------------
[3]52CONTAINS
53
[1130]54   SUBROUTINE day_init
55      !!----------------------------------------------------------------------
56      !!                   ***  ROUTINE day_init  ***
[3764]57      !!
58      !! ** Purpose :   Initialization of the calendar values to their values 1 time step before nit000
[1130]59      !!                because day will be called at the beginning of step
60      !!
61      !! ** Action  : - nyear        : current year
62      !!              - nmonth       : current month of the year nyear
63      !!              - nday         : current day of the month nmonth
64      !!              - nday_year    : current day of the year nyear
[1730]65      !!              - nsec_year    : current time step counted in second since 00h jan 1st of the current year
66      !!              - nsec_month   : current time step counted in second since 00h 1st day of the current month
67      !!              - nsec_day     : current time step counted in second since 00h of the current day
68      !!              - nsec1jan000  : second since Jan. 1st 00h of nit000 year and Jan. 1st 00h of the current year
69      !!              - nmonth_len, nyear_len, nmonth_half, nmonth_end through day_mth
[1130]70      !!----------------------------------------------------------------------
[2715]71      INTEGER  ::   inbday, idweek
72      REAL(wp) ::   zjul
[2528]73      !!----------------------------------------------------------------------
[3294]74      !
[6487]75      ! max number of seconds between each restart
76      IF( REAL( nitend - nit000 + 1 ) * rdt > REAL( HUGE( nsec1jan000 ) ) ) THEN
77         CALL ctl_stop( 'The number of seconds between each restart exceeds the integer 4 max value: 2^31-1. ',   &
78            &           'You must do a restart at higher frequency (or remove this stop and recompile the code in I8)' )
79      ENDIF
[1130]80      ! all calendar staff is based on the fact that MOD( rday, rdttra(1) ) == 0
[1730]81      IF( MOD( rday     , rdttra(1) ) /= 0. )   CALL ctl_stop( 'the time step must devide the number of second of in a day' )
82      IF( MOD( rday     , 2.        ) /= 0. )   CALL ctl_stop( 'the number of second of in a day must be an even number'    )
83      IF( MOD( rdttra(1), 2.        ) /= 0. )   CALL ctl_stop( 'the time step (in second) must be an even number'           )
84      nsecd   = NINT(rday           )
85      nsecd05 = NINT(0.5 * rday     )
86      ndt     = NINT(      rdttra(1))
87      ndt05   = NINT(0.5 * rdttra(1))
[1130]88
[3764]89      IF( .NOT. lk_offline ) CALL day_rst( nit000, 'READ' )
[1130]90
91      ! set the calandar from ndastp (read in restart file and namelist)
92
93      nyear   =   ndastp / 10000
94      nmonth  = ( ndastp - (nyear * 10000) ) / 100
[3764]95      nday    =   ndastp - (nyear * 10000) - ( nmonth * 100 )
[1130]96
[10005]97      nhour   =   nn_time0 / 100
98      nminute = ( nn_time0 - nhour * 100 )
99
100      CALL ymds2ju( nyear, nmonth, nday, nhour*3600._wp+nminute*60._wp, fjulday ) 
[1730]101      IF( ABS(fjulday - REAL(NINT(fjulday),wp)) < 0.1 / rday )   fjulday = REAL(NINT(fjulday),wp)   ! avoid truncation error
[10113]102      IF(nhour*3600 + nminute*60 - ndt05 .lt. 0)   fjulday = fjulday + 1.                    ! move back to the day at nit000 (and not at nit000 - 1)
[1359]103
[1730]104      nsec1jan000 = 0
[1130]105      CALL day_mth
[3764]106
[1130]107      IF ( nday == 0 ) THEN     !   for ex if ndastp = ndate0 - 1
[3764]108         nmonth = nmonth - 1
[1130]109         nday = nmonth_len(nmonth)
110      ENDIF
111      IF ( nmonth == 0 ) THEN   ! go at the end of previous year
112         nmonth = 12
113         nyear = nyear - 1
[1730]114         nsec1jan000 = nsec1jan000 - nsecd * nyear_len(0)
[1130]115         IF( nleapy == 1 )   CALL day_mth
116      ENDIF
[3764]117
[1130]118      ! day since january 1st
119      nday_year = nday + SUM( nmonth_len(1:nmonth - 1) )
[2528]120
[3764]121      !compute number of days between last monday and today
[2528]122      CALL ymds2ju( 1900, 01, 01, 0.0, zjul )  ! compute julian day value of 01.01.1900 (our reference that was a Monday)
[10005]123      inbday = FLOOR(fjulday - zjul)            ! compute nb day between  01.01.1900 and start of current day
[3764]124      idweek = MOD(inbday, 7)                  ! compute nb day between last monday and current day
[10005]125      IF (idweek .lt. 0) idweek=idweek+7       ! Avoid negative values for dates before 01.01.1900
[2528]126
127      ! number of seconds since the beginning of current year/month/week/day at the middle of the time-step
[10005]128      IF (nhour*3600+nminute*60-ndt05 .gt. 0) THEN
129         ! 1 timestep before current middle of first time step is still the same day
130         nsec_year  = (nday_year-1) * nsecd + nhour*3600+nminute*60 - ndt05 
131         nsec_month = (nday-1)      * nsecd + nhour*3600+nminute*60 - ndt05   
132      ELSE
133         ! 1 time step before the middle of the first time step is the previous day
134         nsec_year  = nday_year * nsecd + nhour*3600+nminute*60 - ndt05 
135         nsec_month = nday      * nsecd + nhour*3600+nminute*60 - ndt05   
136      ENDIF
137      nsec_week  = idweek    * nsecd + nhour*3600+nminute*60 - ndt05
138      nsec_day   =             nhour*3600+nminute*60 - ndt05 
139      IF( nsec_day .lt. 0 ) nsec_day = nsec_day + nsecd
140      IF( nsec_week .lt. 0 ) nsec_week = nsec_week + nsecd*7
[1130]141
142      ! control print
[10005]143      IF(lwp) WRITE(numout,'(a,i6,a,i2,a,i2,a,i8,a,i8,a,i8,a,i8)')' =======>> 1/2 time step before the start of the run DATE Y/M/D = ',   &
144           &                   nyear, '/', nmonth, '/', nday, '  nsec_day:', nsec_day, '  nsec_week:', nsec_week, '  &
145           &                   nsec_month:', nsec_month , '  nsec_year:' , nsec_year
[1725]146
147      ! Up to now, calendar parameters are related to the end of previous run (nit000-1)
148      ! call day to set the calendar parameters at the begining of the current simulaton. needed by iom_init
149      CALL day( nit000 )
[3294]150      !
[1130]151   END SUBROUTINE day_init
152
153
154   SUBROUTINE day_mth
155      !!----------------------------------------------------------------------
156      !!                   ***  ROUTINE day_init  ***
[3764]157      !!
[1130]158      !! ** Purpose :   calendar values related to the months
159      !!
160      !! ** Action  : - nmonth_len    : length in days of the months of the current year
161      !!              - nyear_len     : length in days of the previous/current year
[1730]162      !!              - nmonth_half   : second since the beginning of the year and the halft of the months
163      !!              - nmonth_end    : second since the beginning of the year and the end of the months
[1130]164      !!----------------------------------------------------------------------
165      INTEGER  ::   jm               ! dummy loop indice
166      !!----------------------------------------------------------------------
167
168      ! length of the month of the current year (from nleapy, read in namelist)
[3764]169      IF ( nleapy < 2 ) THEN
[1130]170         nmonth_len(:) = (/ 31, 31, 28, 31, 30, 31, 30, 31, 31, 30, 31, 30, 31, 31 /)
171         nyear_len(:) = 365
172         IF ( nleapy == 1 ) THEN   ! we are using calandar with leap years
173            IF ( MOD(nyear-1, 4) == 0 .AND. ( MOD(nyear-1, 400) == 0 .OR. MOD(nyear-1, 100) /= 0 ) ) THEN
[3851]174               nyear_len(0)  = 366
[1130]175            ENDIF
[3851]176            IF ( MOD(nyear  , 4) == 0 .AND. ( MOD(nyear  , 400) == 0 .OR. MOD(nyear  , 100) /= 0 ) ) THEN
[1130]177               nmonth_len(2) = 29
[3851]178               nyear_len(1)  = 366
[1130]179            ENDIF
[3851]180            IF ( MOD(nyear+1, 4) == 0 .AND. ( MOD(nyear+1, 400) == 0 .OR. MOD(nyear+1, 100) /= 0 ) ) THEN
181               nyear_len(2)  = 366
182            ENDIF
[1130]183         ENDIF
184      ELSE
185         nmonth_len(:) = nleapy   ! all months with nleapy days per year
186         nyear_len(:) = 12 * nleapy
187      ENDIF
188
189      ! half month in second since the begining of the year:
190      ! time since Jan 1st   0     1     2    ...    11    12    13
191      !          ---------*--|--*--|--*--| ... |--*--|--*--|--*--|--------------------------------------
[3764]192      !                 <---> <---> <--->  ...  <---> <---> <--->
[1130]193      ! month number      0     1     2    ...    11    12    13
194      !
[1730]195      ! nmonth_half(jm) = rday * REAL( 0.5 * nmonth_len(jm) + SUM(nmonth_len(1:jm-1)) )
196      nmonth_half(0) = - nsecd05 * nmonth_len(0)
[1130]197      DO jm = 1, 13
[1730]198         nmonth_half(jm) = nmonth_half(jm-1) + nsecd05 * ( nmonth_len(jm-1) + nmonth_len(jm) )
[1130]199      END DO
200
[1730]201      nmonth_end(0) = 0
[1130]202      DO jm = 1, 13
[1730]203         nmonth_end(jm) = nmonth_end(jm-1) + nsecd * nmonth_len(jm)
[1130]204      END DO
[3764]205      !
206   END SUBROUTINE
[1130]207
208
[15]209   SUBROUTINE day( kt )
[3]210      !!----------------------------------------------------------------------
[15]211      !!                      ***  ROUTINE day  ***
[3764]212      !!
[3]213      !! ** Purpose :   Compute the date with a day iteration IF necessary.
214      !!
215      !! ** Method  : - ???
216      !!
217      !! ** Action  : - nyear     : current year
218      !!              - nmonth    : current month of the year nyear
219      !!              - nday      : current day of the month nmonth
220      !!              - nday_year : current day of the year nyear
[1130]221      !!              - ndastp    : = nyear*10000 + nmonth*100 + nday
[15]222      !!              - adatrj    : date in days since the beginning of the run
[1730]223      !!              - nsec_year : current time of the year (in second since 00h, jan 1st)
[3764]224      !!----------------------------------------------------------------------
[888]225      INTEGER, INTENT(in) ::   kt        ! ocean time-step indices
226      !
227      CHARACTER (len=25) ::   charout
[1730]228      REAL(wp)           ::   zprec      ! fraction of day corresponding to 0.1 second
[3]229      !!----------------------------------------------------------------------
[3294]230      !
231      IF( nn_timing == 1 )  CALL timing_start('day')
232      !
[1730]233      zprec = 0.1 / rday
[1130]234      !                                                 ! New time-step
[3764]235      nsec_year  = nsec_year  + ndt
236      nsec_month = nsec_month + ndt
[2528]237      nsec_week  = nsec_week  + ndt
[3764]238      nsec_day   = nsec_day   + ndt
[1359]239      adatrj  = adatrj  + rdttra(1) / rday
240      fjulday = fjulday + rdttra(1) / rday
[1730]241      IF( ABS(fjulday - REAL(NINT(fjulday),wp)) < zprec )   fjulday = REAL(NINT(fjulday),wp)   ! avoid truncation error
242      IF( ABS(adatrj  - REAL(NINT(adatrj ),wp)) < zprec )   adatrj  = REAL(NINT(adatrj ),wp)   ! avoid truncation error
[3764]243
[2528]244      IF( nsec_day > nsecd ) THEN                       ! New day
[888]245         !
[1130]246         nday      = nday + 1
247         nday_year = nday_year + 1
[1730]248         nsec_day  = ndt05
[1130]249         !
[2528]250         IF( nday == nmonth_len(nmonth) + 1 ) THEN      ! New month
[1130]251            nday   = 1
252            nmonth = nmonth + 1
[1730]253            nsec_month = ndt05
[2528]254            IF( nmonth == 13 ) THEN                     ! New year
[1130]255               nyear     = nyear + 1
256               nmonth    = 1
257               nday_year = 1
[1730]258               nsec_year = ndt05
259               nsec1jan000 = nsec1jan000 + nsecd * nyear_len(1)
[1130]260               IF( nleapy == 1 )   CALL day_mth
[3]261            ENDIF
[888]262         ENDIF
[1130]263         !
[2528]264         ndastp = nyear * 10000 + nmonth * 100 + nday   ! New date
[1130]265         !
[2528]266         !compute first day of the year in julian days
267         CALL ymds2ju( nyear, 01, 01, 0.0, fjulstartyear )
268         !
[1191]269         IF(lwp) WRITE(numout,'(a,i8,a,i4.4,a,i2.2,a,i2.2,a,i3.3)') '======>> time-step =', kt,   &
[1130]270              &   '      New day, DATE Y/M/D = ', nyear, '/', nmonth, '/', nday, '      nday_year = ', nday_year
[1730]271         IF(lwp) WRITE(numout,'(a,i8,a,i7,a,i5)') '         nsec_year = ', nsec_year,   &
[2528]272              &   '   nsec_month = ', nsec_month, '   nsec_day = ', nsec_day, '   nsec_week = ', nsec_week
[1130]273      ENDIF
[2528]274
275      IF( nsec_week > 7*nsecd )   nsec_week = ndt05     ! New week
[3764]276
[1130]277      IF(ln_ctl) THEN
278         WRITE(charout,FMT="('kt =', I4,'  d/m/y =',I2,I2,I4)") kt, nday, nmonth, nyear
279         CALL prt_ctl_info(charout)
280      ENDIF
[3]281
[2528]282      IF( .NOT. lk_offline ) CALL rst_opn( kt )               ! Open the restart file if needed and control lrst_oce
283      IF( lrst_oce         ) CALL day_rst( kt, 'WRITE' )      ! write day restart information
[1130]284      !
[3294]285      IF( nn_timing == 1 )  CALL timing_stop('day')
286      !
[1130]287   END SUBROUTINE day
[3]288
289
[1130]290   SUBROUTINE day_rst( kt, cdrw )
291      !!---------------------------------------------------------------------
292      !!                   ***  ROUTINE ts_rst  ***
[3764]293      !!
[1130]294      !!  ** Purpose : Read or write calendar in restart file:
[3764]295      !!
[1130]296      !!  WRITE(READ) mode:
[3764]297      !!       kt        : number of time step since the begining of the experiment at the
[1130]298      !!                   end of the current(previous) run
[3764]299      !!       adatrj(0) : number of elapsed days since the begining of the experiment at the
[1130]300      !!                   end of the current(previous) run (REAL -> keep fractions of day)
301      !!       ndastp    : date at the end of the current(previous) run (coded as yyyymmdd integer)
[3764]302      !!
[1130]303      !!   According to namelist parameter nrstdt,
304      !!       nrstdt = 0  no control on the date (nit000 is  arbitrary).
305      !!       nrstdt = 1  we verify that nit000 is equal to the last
306      !!                   time step of previous run + 1.
307      !!       In both those options, the  exact duration of the experiment
308      !!       since the beginning (cumulated duration of all previous restart runs)
309      !!       is not stored in the restart and is assumed to be (nit000-1)*rdt.
310      !!       This is valid is the time step has remained constant.
311      !!
312      !!       nrstdt = 2  the duration of the experiment in days (adatrj)
313      !!                    has been stored in the restart file.
314      !!----------------------------------------------------------------------
315      INTEGER         , INTENT(in) ::   kt         ! ocean time-step
316      CHARACTER(len=*), INTENT(in) ::   cdrw       ! "READ"/"WRITE" flag
317      !
[10005]318      REAL(wp) ::   zkt, zndastp, zdayfrac, ksecs, ktime
319      INTEGER  ::   ihour, iminute
[1130]320      !!----------------------------------------------------------------------
[3764]321
[1130]322      IF( TRIM(cdrw) == 'READ' ) THEN
[3]323
[1130]324         IF( iom_varid( numror, 'kt', ldstop = .FALSE. ) > 0 ) THEN
325            ! Get Calendar informations
[9321]326            IF(nn_timing == 2)  CALL timing_start('iom_rstget')
[1130]327            CALL iom_get( numror, 'kt', zkt )   ! last time-step of previous run
[9321]328            IF(nn_timing == 2)  CALL timing_stop('iom_rstget')
[1130]329            IF(lwp) THEN
330               WRITE(numout,*) ' *** Info read in restart : '
331               WRITE(numout,*) '   previous time-step                               : ', NINT( zkt )
332               WRITE(numout,*) ' *** restart option'
333               SELECT CASE ( nrstdt )
334               CASE ( 0 )   ;   WRITE(numout,*) ' nrstdt = 0 : no control of nit000'
335               CASE ( 1 )   ;   WRITE(numout,*) ' nrstdt = 1 : no control the date at nit000 (use ndate0 read in the namelist)'
336               CASE ( 2 )   ;   WRITE(numout,*) ' nrstdt = 2 : calendar parameters read in restart'
337               END SELECT
338               WRITE(numout,*)
[888]339            ENDIF
[3764]340            ! Control of date
341            IF( nit000 - NINT( zkt ) /= 1 .AND. nrstdt /= 0 )                                         &
342                 &   CALL ctl_stop( ' ===>>>> : problem with nit000 for the restart',                 &
[1130]343                 &                  ' verify the restart file or rerun with nrstdt = 0 (namelist)' )
344            ! define ndastp and adatrj
[3764]345            IF ( nrstdt == 2 ) THEN
[9321]346               IF(nn_timing == 2)  CALL timing_start('iom_rstget')
[1359]347               ! read the parameters correspondting to nit000 - 1 (last time step of previous run)
[1130]348               CALL iom_get( numror, 'ndastp', zndastp )
349               ndastp = NINT( zndastp )
350               CALL iom_get( numror, 'adatrj', adatrj  )
[10005]351          CALL iom_get( numror, 'ntime', ktime )
[9321]352               IF(nn_timing == 2)  CALL timing_stop('iom_rstget')
[10005]353          nn_time0=INT(ktime)
354               ! calculate start time in hours and minutes
355          zdayfrac=adatrj-INT(adatrj)
356          ksecs = NINT(zdayfrac*86400)        ! Nearest second to catch rounding errors in adatrj         
357          ihour = INT(ksecs/3600)
358          iminute = ksecs/60-ihour*60
359           
360               ! Add to nn_time0
361               nhour   =   nn_time0 / 100
362               nminute = ( nn_time0 - nhour * 100 )
363          nminute=nminute+iminute
364         
365          IF( nminute >= 60 ) THEN
366             nminute=nminute-60
367        nhour=nhour+1
368          ENDIF
369          nhour=nhour+ihour
370          IF( nhour >= 24 ) THEN
371        nhour=nhour-24
372             adatrj=adatrj+1
373          ENDIF         
374          nn_time0 = nhour * 100 + nminute
375          adatrj = INT(adatrj)                    ! adatrj set to integer as nn_time0 updated         
[3764]376            ELSE
[10005]377               ! parameters corresponding to nit000 - 1 (as we start the step loop with a call to day)
378               ndastp = ndate0        ! ndate0 read in the namelist in dom_nam
379               nhour   =   nn_time0 / 100
380               nminute = ( nn_time0 - nhour * 100 )
381               IF( nhour*3600+nminute*60-ndt05 .lt. 0 )  ndastp=ndastp-1      ! Start hour is specified in the namelist (default 0)
[3764]382               adatrj = ( REAL( nit000-1, wp ) * rdttra(1) ) / rday
383               ! note this is wrong if time step has changed during run
[1130]384            ENDIF
385         ELSE
[10005]386            ! parameters corresponding to nit000 - 1 (as we start the step loop with a call to day)
387            ndastp = ndate0           ! ndate0 read in the namelist in dom_nam
388            nhour   =   nn_time0 / 100
389            nminute = ( nn_time0 - nhour * 100 )
390            IF( nhour*3600+nminute*60-ndt05 .lt. 0 )  ndastp=ndastp-1      ! Start hour is specified in the namelist (default 0)
[3764]391            adatrj = ( REAL( nit000-1, wp ) * rdttra(1) ) / rday
[3]392         ENDIF
[1730]393         IF( ABS(adatrj  - REAL(NINT(adatrj),wp)) < 0.1 / rday )   adatrj = REAL(NINT(adatrj),wp)   ! avoid truncation error
[1130]394         !
395         IF(lwp) THEN
396            WRITE(numout,*) ' *** Info used values : '
397            WRITE(numout,*) '   date ndastp                                      : ', ndastp
398            WRITE(numout,*) '   number of elapsed days since the begining of run : ', adatrj
[10005]399            WRITE(numout,*) '   nn_time0                                         : ',nn_time0
[1130]400            WRITE(numout,*)
[719]401         ENDIF
[888]402         !
[1130]403      ELSEIF( TRIM(cdrw) == 'WRITE' ) THEN
404         !
405         IF( kt == nitrst ) THEN
406            IF(lwp) WRITE(numout,*)
407            IF(lwp) WRITE(numout,*) 'rst_write : write oce restart file  kt =', kt
[3764]408            IF(lwp) WRITE(numout,*) '~~~~~~~'
[1130]409         ENDIF
410         ! calendar control
[9321]411         IF(nn_timing == 2)  CALL timing_start('iom_rstput')
[3764]412         CALL iom_rstput( kt, nitrst, numrow, 'kt'     , REAL( kt    , wp) )   ! time-step
[1130]413         CALL iom_rstput( kt, nitrst, numrow, 'ndastp' , REAL( ndastp, wp) )   ! date
414         CALL iom_rstput( kt, nitrst, numrow, 'adatrj' , adatrj            )   ! number of elapsed days since
415         !                                                                     ! the begining of the run [s]
[10005]416         CALL iom_rstput( kt, nitrst, numrow, 'ntime'  , REAL( nn_time0, wp) ) ! time
[9321]417         IF(nn_timing == 2)  CALL timing_stop('iom_rstput')
[3]418      ENDIF
[1130]419      !
420   END SUBROUTINE day_rst
[3]421
422   !!======================================================================
423END MODULE daymod
Note: See TracBrowser for help on using the repository browser.