source: branches/UKMO/dev_r5518_GO6_package_inc_asm/NEMOGCM/NEMO/OPA_SRC/step.F90 @ 8036

Last change on this file since 8036 was 8036, checked in by jwhile, 3 years ago

Further merge of r5518_pcbias

File size: 24.9 KB
Line 
1MODULE step
2   !!======================================================================
3   !!                       ***  MODULE step  ***
4   !! Time-stepping    : manager of the ocean, tracer and ice time stepping
5   !!======================================================================
6   !! History :  OPA  !  1991-03  (G. Madec)  Original code
7   !!             -   !  1991-11  (G. Madec)
8   !!             -   !  1992-06  (M. Imbard)  add a first output record
9   !!             -   !  1996-04  (G. Madec)  introduction of dynspg
10   !!             -   !  1996-04  (M.A. Foujols)  introduction of passive tracer
11   !!            8.0  !  1997-06  (G. Madec)  new architecture of call
12   !!            8.2  !  1997-06  (G. Madec, M. Imbard, G. Roullet)  free surface
13   !!             -   !  1999-02  (G. Madec, N. Grima)  hpg implicit
14   !!             -   !  2000-07  (J-M Molines, M. Imbard)  Open Bondary Conditions
15   !!   NEMO     1.0  !  2002-06  (G. Madec)  free form, suppress macro-tasking
16   !!             -   !  2004-08  (C. Talandier) New trends organization
17   !!             -   !  2005-01  (C. Ethe) Add the KPP closure scheme
18   !!             -   !  2005-11  (G. Madec)  Reorganisation of tra and dyn calls
19   !!             -   !  2006-01  (L. Debreu, C. Mazauric)  Agrif implementation
20   !!             -   !  2006-07  (S. Masson)  restart using iom
21   !!            3.2  !  2009-02  (G. Madec, R. Benshila)  reintroduicing z*-coordinate
22   !!             -   !  2009-06  (S. Masson, G. Madec)  TKE restart compatible with key_cpl
23   !!            3.3  !  2010-05  (K. Mogensen, A. Weaver, M. Martin, D. Lea) Assimilation interface
24   !!             -   !  2010-10  (C. Ethe, G. Madec) reorganisation of initialisation phase + merge TRC-TRA
25   !!            3.4  !  2011-04  (G. Madec, C. Ethe) Merge of dtatem and dtasal
26   !!                 !  2012-07  (J. Simeon, G. Madec, C. Ethe) Online coarsening of outputs
27   !!            3.7  !  2014-04  (F. Roquet, G. Madec) New equations of state
28   !!----------------------------------------------------------------------
29
30   !!----------------------------------------------------------------------
31   !!   stp             : OPA system time-stepping
32   !!----------------------------------------------------------------------
33   USE step_oce         ! time stepping definition modules
34   USE iom
35   USE lbclnk
36
37   IMPLICIT NONE
38   PRIVATE
39
40   PUBLIC   stp   ! called by opa.F90
41
42   !! * Substitutions
43#  include "domzgr_substitute.h90"
44!!gm   #  include "zdfddm_substitute.h90"
45   !!----------------------------------------------------------------------
46   !! NEMO/OPA 3.7 , NEMO Consortium (2014)
47   !! $Id$
48   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
49   !!----------------------------------------------------------------------
50CONTAINS
51
52#if defined key_agrif
53   RECURSIVE SUBROUTINE stp( )
54      INTEGER             ::   kstp   ! ocean time-step index
55#else
56   SUBROUTINE stp( kstp )
57      INTEGER, INTENT(in) ::   kstp   ! ocean time-step index
58#endif
59      !!----------------------------------------------------------------------
60      !!                     ***  ROUTINE stp  ***
61      !!
62      !! ** Purpose : - Time stepping of OPA (momentum and active tracer eqs.)
63      !!              - Time stepping of LIM (dynamic and thermodynamic eqs.)
64      !!              - Tme stepping  of TRC (passive tracer eqs.)
65      !!
66      !! ** Method  : -1- Update forcings and data
67      !!              -2- Update ocean physics
68      !!              -3- Compute the t and s trends
69      !!              -4- Update t and s
70      !!              -5- Compute the momentum trends
71      !!              -6- Update the horizontal velocity
72      !!              -7- Compute the diagnostics variables (rd,N2, div,cur,w)
73      !!              -8- Outputs and diagnostics
74      !!----------------------------------------------------------------------
75      INTEGER ::   jk       ! dummy loop indice
76      INTEGER ::   tind     ! tracer loop index
77      INTEGER ::   indic    ! error indicator if < 0
78      INTEGER ::   kcall    ! optional integer argument (dom_vvl_sf_nxt)
79      !! ---------------------------------------------------------------------
80
81#if defined key_agrif
82      kstp = nit000 + Agrif_Nb_Step()
83      IF ( lk_agrif_debug ) THEN
84         IF ( Agrif_Root() .and. lwp) Write(*,*) '---'
85         IF (lwp) Write(*,*) 'Grid Number',Agrif_Fixed(),' time step ',kstp, 'int tstep',Agrif_NbStepint()
86      ENDIF
87
88      IF ( kstp == (nit000 + 1) ) lk_agrif_fstep = .FALSE.
89
90# if defined key_iomput
91      IF( Agrif_Nbstepint() == 0 )   CALL iom_swap( cxios_context )
92# endif
93#endif
94                             indic = 0           ! reset to no error condition
95      IF( kstp == nit000 ) THEN
96         ! must be done after nemo_init for AGRIF+XIOS+OASIS
97                      CALL iom_init(      cxios_context          )  ! iom_put initialization
98         IF( ln_crs ) CALL iom_init( TRIM(cxios_context)//"_crs" )  ! initialize context for coarse grid
99      ENDIF
100
101      IF( kstp /= nit000 )   CALL day( kstp )         ! Calendar (day was already called at nit000 in day_init)
102                             CALL iom_setkt( kstp - nit000 + 1,      cxios_context          )   ! tell iom we are at time step kstp
103      IF( ln_crs     )       CALL iom_setkt( kstp - nit000 + 1, TRIM(cxios_context)//"_crs" )   ! tell iom we are at time step kstp
104
105      IF( ln_bias )          CALL bias_opn( kstp )
106
107      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
108      ! Update data, open boundaries, surface boundary condition (including sea-ice)
109      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
110      IF( lk_tide    )   CALL sbc_tide( kstp )
111      IF( lk_bdy     )  THEN
112         IF( ln_apr_dyn) CALL sbc_apr( kstp )   ! bdy_dta needs ssh_ib
113                         CALL bdy_dta ( kstp, time_offset=+1 )   ! update dynamic & tracer data at open boundaries
114      ENDIF
115
116      ! We must ensure that tsb halos are up to date on EVERY timestep.
117      DO tind = 1, jpts
118         CALL lbc_lnk( tsb(:,:,:,tind), 'T', 1. )
119      END DO
120
121      IF( ln_seaiceinc ) &
122         &               CALL seaice_asm_inc ( kstp ) ! setup sea ice concentration increment
123                         CALL sbc    ( kstp )         ! Sea Boundary Condition (including sea-ice)
124                                                      ! clem: moved here for bdy ice purpose
125      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
126      ! Update stochastic parameters and random T/S fluctuations
127      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
128       IF( ln_sto_eos ) CALL sto_par( kstp )          ! Stochastic parameters
129       IF( ln_sto_eos ) CALL sto_pts( tsn  )          ! Random T/S fluctuations
130
131      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
132      ! Ocean physics update                (ua, va, tsa used as workspace)
133      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
134      !  THERMODYNAMICS
135                         CALL eos_rab( tsb, rab_b )       ! before local thermal/haline expension ratio at T-points
136                         CALL eos_rab( tsn, rab_n )       ! now    local thermal/haline expension ratio at T-points
137                         CALL bn2    ( tsb, rab_b, rn2b ) ! before Brunt-Vaisala frequency
138                         CALL bn2    ( tsn, rab_n, rn2  ) ! now    Brunt-Vaisala frequency
139      !
140      !  VERTICAL PHYSICS
141                         CALL zdf_bfr( kstp )         ! bottom friction (if quadratic)
142      !                                               ! Vertical eddy viscosity and diffusivity coefficients
143      IF( lk_zdfric  )   CALL zdf_ric( kstp )            ! Richardson number dependent Kz
144      IF( lk_zdftke  )   CALL zdf_tke( kstp )            ! TKE closure scheme for Kz
145      IF( lk_zdfgls  )   CALL zdf_gls( kstp )            ! GLS closure scheme for Kz
146      IF( lk_zdfkpp  )   CALL zdf_kpp( kstp )            ! KPP closure scheme for Kz
147      IF( lk_zdfcst  ) THEN                              ! Constant Kz (reset avt, avm[uv] to the background value)
148         avt (:,:,:) = rn_avt0 * wmask (:,:,:)
149         avmu(:,:,:) = rn_avm0 * wumask(:,:,:)
150         avmv(:,:,:) = rn_avm0 * wvmask(:,:,:)
151      ENDIF
152      IF( ln_rnf_mouth ) THEN                         ! increase diffusivity at rivers mouths
153         DO jk = 2, nkrnf   ;   avt(:,:,jk) = avt(:,:,jk) + 2.e0 * rn_avt_rnf * rnfmsk(:,:) * tmask(:,:,jk)   ;   END DO
154      ENDIF
155      IF( ln_zdfevd  )   CALL zdf_evd( kstp )         ! enhanced vertical eddy diffusivity
156
157      IF( lk_zdftmx  )   CALL zdf_tmx( kstp )         ! tidal vertical mixing
158
159      IF( lk_zdfddm .AND. .NOT. lk_zdfkpp )   &
160         &               CALL zdf_ddm( kstp )         ! double diffusive mixing
161
162                         CALL zdf_mxl( kstp )         ! mixed layer depth
163
164                                                      ! write TKE or GLS information in the restart file
165      IF( lrst_oce .AND. lk_zdftke )   CALL tke_rst( kstp, 'WRITE' )
166      IF( lrst_oce .AND. lk_zdfgls )   CALL gls_rst( kstp, 'WRITE' )
167      !
168      !  LATERAL  PHYSICS
169      !
170      IF( lk_ldfslp ) THEN                            ! slope of lateral mixing
171                         CALL eos( tsb, rhd, gdept_0(:,:,:) )               ! before in situ density
172         IF( ln_zps .AND. .NOT. ln_isfcav)                               &
173            &            CALL zps_hde    ( kstp, jpts, tsb, gtsu, gtsv,  &  ! Partial steps: before horizontal gradient
174            &                                          rhd, gru , grv    )  ! of t, s, rd at the last ocean level
175         IF( ln_zps .AND.       ln_isfcav)                               &
176            &            CALL zps_hde_isf( kstp, jpts, tsb, gtsu, gtsv,  &    ! Partial steps for top cell (ISF)
177            &                                          rhd, gru , grv , aru , arv , gzu , gzv , ge3ru , ge3rv ,   &
178            &                                   gtui, gtvi, grui, grvi, arui, arvi, gzui, gzvi, ge3rui, ge3rvi    ) ! of t, s, rd at the first ocean level
179         IF( ln_traldf_grif ) THEN                           ! before slope for Griffies operator
180                         CALL ldf_slp_grif( kstp )
181         ELSE
182                         CALL ldf_slp( kstp, rhd, rn2b )     ! before slope for Madec operator
183         ENDIF
184      ENDIF
185#if defined key_traldf_c2d
186      IF( lk_traldf_eiv )   CALL ldf_eiv( kstp )      ! eddy induced velocity coefficient
187#endif
188#if defined key_traldf_c3d && defined key_traldf_smag
189                          CALL ldf_tra_smag( kstp )      ! eddy induced velocity coefficient
190#  endif
191#if defined key_dynldf_c3d && defined key_dynldf_smag
192                          CALL ldf_dyn_smag( kstp )      ! eddy induced velocity coefficient
193#  endif
194
195      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
196      !  Ocean dynamics : hdiv, rot, ssh, e3, wn
197      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
198                         CALL ssh_nxt       ( kstp )  ! after ssh (includes call to div_cur)
199      IF( lk_vvl     )   CALL dom_vvl_sf_nxt( kstp )  ! after vertical scale factors
200                         CALL wzv           ( kstp )  ! now cross-level velocity
201
202      IF( lk_dynspg_ts ) THEN 
203          ! In case the time splitting case, update almost all momentum trends here:
204          ! Note that the computation of vertical velocity above, hence "after" sea level
205          ! is necessary to compute momentum advection for the rhs of barotropic loop:
206                            CALL eos    ( tsn, rhd, rhop, fsdept_n(:,:,:) ) ! now in situ density for hpg computation
207            IF( ln_zps .AND. .NOT. ln_isfcav)                               &
208               &            CALL zps_hde    ( kstp, jpts, tsn, gtsu, gtsv,  &    ! Partial steps: before horizontal gradient
209               &                                          rhd, gru , grv    )  ! of t, s, rd at the last ocean level
210            IF( ln_zps .AND.       ln_isfcav)                               &
211               &            CALL zps_hde_isf( kstp, jpts, tsn, gtsu, gtsv,  &    ! Partial steps for top cell (ISF)
212               &                                          rhd, gru , grv , aru , arv , gzu , gzv , ge3ru , ge3rv ,   &
213               &                                   gtui, gtvi, grui, grvi, arui, arvi, gzui, gzvi, ge3rui, ge3rvi    ) ! of t, s, rd at the last ocean level
214
215                                  ua(:,:,:) = 0.e0             ! set dynamics trends to zero
216                                  va(:,:,:) = 0.e0
217          IF(  lk_asminc .AND. ln_asmiau .AND. &
218             & ln_dyninc       )  CALL dyn_asm_inc  ( kstp )   ! apply dynamics assimilation increment
219          IF( ln_neptsimp )       CALL dyn_nept_cor ( kstp )   ! subtract Neptune velocities (simplified)
220          IF( lk_bdy           )  CALL bdy_dyn3d_dmp( kstp )   ! bdy damping trends
221                                  CALL dyn_adv      ( kstp )   ! advection (vector or flux form)
222                                  CALL dyn_vor      ( kstp )   ! vorticity term including Coriolis
223                                  CALL dyn_ldf      ( kstp )   ! lateral mixing
224          IF( ln_neptsimp )       CALL dyn_nept_cor ( kstp )   ! add Neptune velocities (simplified)
225#if defined key_agrif
226          IF(.NOT. Agrif_Root())  CALL Agrif_Sponge_dyn        ! momentum sponge
227#endif
228                                  CALL dyn_hpg( kstp )         ! horizontal gradient of Hydrostatic pressure
229                                  CALL dyn_spg( kstp, indic )  ! surface pressure gradient
230
231                                  ua_sv(:,:,:) = ua(:,:,:)     ! Save trends (barotropic trend has been fully updated at this stage)
232                                  va_sv(:,:,:) = va(:,:,:)
233
234                                  CALL div_cur( kstp )         ! Horizontal divergence & Relative vorticity (2nd call in time-split case)
235          IF( lk_vvl     )        CALL dom_vvl_sf_nxt( kstp, kcall=2 )  ! after vertical scale factors (update depth average component)
236                                  CALL wzv           ( kstp )  ! now cross-level velocity
237      ENDIF
238
239      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
240      ! diagnostics and outputs             (ua, va, tsa used as workspace)
241      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
242      IF( lk_floats  )      CALL flo_stp( kstp )         ! drifting Floats
243      IF( lk_diahth  )      CALL dia_hth( kstp )         ! Thermocline depth (20 degres isotherm depth)
244      IF( .NOT. ln_cpl )    CALL dia_fwb( kstp )         ! Fresh water budget diagnostics
245      IF( lk_diadct  )      CALL dia_dct( kstp )         ! Transports
246      IF( lk_diaar5  )      CALL dia_ar5( kstp )         ! ar5 diag
247      IF( lk_diaharm )      CALL dia_harm( kstp )        ! Tidal harmonic analysis
248                            CALL dia_prod( kstp )        ! ocean model: product diagnostics
249                            CALL dia_wri( kstp )         ! ocean model: outputs
250      !
251      IF( ln_crs     )      CALL crs_fld( kstp )         ! ocean model: online field coarsening & output
252
253#if defined key_top
254      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
255      ! Passive Tracer Model
256      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
257                         CALL trc_stp( kstp )         ! time-stepping
258#endif
259
260
261      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
262      ! Active tracers                              (ua, va used as workspace)
263      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
264                             tsa(:,:,:,:) = 0.e0            ! set tracer trends to zero
265
266      IF(  lk_asminc .AND. ln_asmiau .AND. &
267         & ln_trainc     )   CALL tra_asm_inc( kstp )       ! apply tracer assimilation increment
268                             CALL tra_sbc    ( kstp )       ! surface boundary condition
269      IF( ln_traqsr      )   CALL tra_qsr    ( kstp )       ! penetrative solar radiation qsr
270      IF( ln_trabbc      )   CALL tra_bbc    ( kstp )       ! bottom heat flux
271      IF( lk_trabbl      )   CALL tra_bbl    ( kstp )       ! advective (and/or diffusive) bottom boundary layer scheme
272      IF( ln_tradmp      )   CALL tra_dmp    ( kstp )       ! internal damping trends
273      IF( ln_bias        )   CALL tra_bias   ( kstp )
274      IF( lk_bdy         )   CALL bdy_tra_dmp( kstp )       ! bdy damping trends
275                             CALL tra_adv    ( kstp )       ! horizontal & vertical advection
276      IF( lk_zdfkpp      )   CALL tra_kpp    ( kstp )       ! KPP non-local tracer fluxes
277                             CALL tra_ldf    ( kstp )       ! lateral mixing
278
279      IF( ln_diaptr      )   CALL dia_ptr                   ! Poleward adv/ldf TRansports diagnostics
280
281#if defined key_agrif
282      IF(.NOT. Agrif_Root()) CALL Agrif_Sponge_tra          ! tracers sponge
283#endif
284                             CALL tra_zdf    ( kstp )       ! vertical mixing and after tracer fields
285
286      IF( ln_dynhpg_imp  ) THEN                             ! semi-implicit hpg (time stepping then eos)
287         IF( ln_zdfnpc   )   CALL tra_npc( kstp )                ! update after fields by non-penetrative convection
288                             CALL tra_nxt( kstp )                ! tracer fields at next time step
289                             CALL eos    ( tsa, rhd, rhop, fsdept_n(:,:,:) )  ! Time-filtered in situ density for hpg computation
290                             CALL lbc_lnk( rhd, 'T', 1.0_wp )
291            IF( ln_zps .AND. .NOT. ln_isfcav)                                &
292               &             CALL zps_hde    ( kstp, jpts, tsa, gtsu, gtsv,  &    ! Partial steps: before horizontal gradient
293               &                                           rhd, gru , grv    )  ! of t, s, rd at the last ocean level
294            IF( ln_zps .AND.       ln_isfcav)                                &
295               &             CALL zps_hde_isf( kstp, jpts, tsa, gtsu, gtsv,  &    ! Partial steps for top cell (ISF)
296               &                                           rhd, gru , grv , aru , arv , gzu , gzv , ge3ru , ge3rv ,   &
297               &                                    gtui, gtvi, grui, grvi, arui, arvi, gzui, gzvi, ge3rui, ge3rvi    ) ! of t, s, rd at the last ocean level
298            IF( ln_bias )    CALL dyn_bias( kstp )
299      ELSE                                                  ! centered hpg  (eos then time stepping)
300         IF ( .NOT. lk_dynspg_ts ) THEN                     ! eos already called in time-split case
301                             CALL eos    ( tsn, rhd, rhop, fsdept_n(:,:,:) )  ! now in situ density for hpg computation
302                             CALL lbc_lnk( rhd, 'T', 1.0_wp )
303         IF( ln_zps .AND. .NOT. ln_isfcav)                                   &
304               &             CALL zps_hde    ( kstp, jpts, tsn, gtsu, gtsv,  &    ! Partial steps: before horizontal gradient
305               &                                           rhd, gru , grv    )  ! of t, s, rd at the last ocean level
306         IF( ln_zps .AND.       ln_isfcav)                                   & 
307               &             CALL zps_hde_isf( kstp, jpts, tsn, gtsu, gtsv,  &    ! Partial steps for top cell (ISF)
308               &                                           rhd, gru , grv , aru , arv , gzu , gzv , ge3ru , ge3rv ,   &
309               &                                    gtui, gtvi, grui, grvi, arui, arvi, gzui, gzvi, ge3rui, ge3rvi    ) ! of t, s, rd at the last ocean level
310         ENDIF
311         IF( ln_zdfnpc   )   CALL tra_npc( kstp )                ! update after fields by non-penetrative convection
312                             CALL tra_nxt( kstp )                ! tracer fields at next time step
313         IF( ln_bias )       CALL dyn_bias( kstp )
314      ENDIF
315
316      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
317      ! Dynamics                                    (tsa used as workspace)
318      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
319      IF( lk_dynspg_ts   )  THEN
320                                                             ! revert to previously computed momentum tendencies
321                                                             ! (not using ua, va as temporary arrays during tracers' update could avoid that)
322                               ua(:,:,:) = ua_sv(:,:,:)
323                               va(:,:,:) = va_sv(:,:,:)
324                                                             ! Revert now divergence and rotational to previously computed ones
325                                                             !(needed because of the time swap in div_cur, at the beginning of each time step)
326                               hdivn(:,:,:) = hdivb(:,:,:)
327                               rotn(:,:,:)  = rotb(:,:,:) 
328
329                               CALL dyn_bfr( kstp )         ! bottom friction
330                               CALL dyn_zdf( kstp )         ! vertical diffusion
331      ELSE
332                               ua(:,:,:) = 0.e0             ! set dynamics trends to zero
333                               va(:,:,:) = 0.e0
334
335        IF(  lk_asminc .AND. ln_asmiau .AND. &
336           & ln_dyninc      )  CALL dyn_asm_inc( kstp )     ! apply dynamics assimilation increment
337        IF( ln_bkgwri )        CALL asm_bkg_wri( kstp )     ! output background fields
338        IF( ln_neptsimp )      CALL dyn_nept_cor( kstp )    ! subtract Neptune velocities (simplified)
339        IF( lk_bdy          )  CALL bdy_dyn3d_dmp(kstp )    ! bdy damping trends
340                               CALL dyn_adv( kstp )         ! advection (vector or flux form)
341                               CALL dyn_vor( kstp )         ! vorticity term including Coriolis
342                               CALL dyn_ldf( kstp )         ! lateral mixing
343        IF( ln_neptsimp )      CALL dyn_nept_cor( kstp )    ! add Neptune velocities (simplified)
344#if defined key_agrif
345        IF(.NOT. Agrif_Root()) CALL Agrif_Sponge_dyn        ! momemtum sponge
346#endif
347                               CALL dyn_hpg( kstp )         ! horizontal gradient of Hydrostatic pressure
348                               CALL dyn_bfr( kstp )         ! bottom friction
349                               CALL dyn_zdf( kstp )         ! vertical diffusion
350                               CALL dyn_spg( kstp, indic )  ! surface pressure gradient
351      ENDIF
352                               CALL dyn_nxt( kstp )         ! lateral velocity at next time step
353
354                               CALL ssh_swp( kstp )         ! swap of sea surface height
355      IF( lk_vvl           )   CALL dom_vvl_sf_swp( kstp )  ! swap of vertical scale factors
356      !
357      IF( lrst_oce         )   CALL rst_write( kstp )       ! write output ocean restart file
358      IF( ln_sto_eos       )   CALL sto_rst_write( kstp )   ! write restart file for stochastic parameters
359
360#if defined key_agrif
361      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
362      ! AGRIF
363      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<     
364                               CALL Agrif_Integrate_ChildGrids( stp ) 
365
366      IF ( Agrif_NbStepint().EQ.0 ) THEN
367                               CALL Agrif_Update_Tra()      ! Update active tracers
368                               CALL Agrif_Update_Dyn()      ! Update momentum
369      ENDIF
370#endif
371      IF( ln_diahsb        )   CALL dia_hsb( kstp )         ! - ML - global conservation diagnostics
372      IF( lk_diaobs  )         CALL dia_obs( kstp )         ! obs-minus-model (assimilation) diagnostics (call after dynamics update)
373
374      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
375      ! Control
376      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
377                               CALL stp_ctl( kstp, indic )
378      IF( indic < 0        )   THEN
379                               CALL ctl_stop( 'step: indic < 0' )
380                               CALL dia_wri_state( 'output.abort', kstp )
381      ENDIF
382      IF( kstp == nit000   )   THEN
383                 CALL iom_close( numror )     ! close input  ocean restart file
384         IF(lwm) CALL FLUSH    ( numond )     ! flush output namelist oce
385         IF( lwm.AND.numoni /= -1 ) CALL FLUSH    ( numoni )     ! flush output namelist ice
386      ENDIF
387
388
389      IF( lrst_bias )          CALL bias_wrt     ( kstp )
390
391      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
392      ! Coupled mode
393      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
394      IF( lk_oasis         )   CALL sbc_cpl_snd( kstp )     ! coupled mode : field exchanges
395      !
396#if defined key_iomput
397      IF( kstp == nitend .OR. indic < 0 ) THEN
398                      CALL iom_context_finalize(      cxios_context          ) ! needed for XIOS+AGRIF
399         IF( ln_crs ) CALL iom_context_finalize( trim(cxios_context)//"_crs" ) !
400      ENDIF
401#endif
402      !
403      IF( nn_timing == 1 .AND.  kstp == nit000  )   CALL timing_reset
404      !     
405      !
406   END SUBROUTINE stp
407
408   !!======================================================================
409END MODULE step
Note: See TracBrowser for help on using the repository browser.