New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
zdfevd.F90 in branches/UKMO/dev_r5518_GO6_starthour_obsoper/NEMOGCM/NEMO/OPA_SRC/ZDF – NEMO

source: branches/UKMO/dev_r5518_GO6_starthour_obsoper/NEMOGCM/NEMO/OPA_SRC/ZDF/zdfevd.F90 @ 15603

Last change on this file since 15603 was 15603, checked in by mattmartin, 2 years ago

Updated NEMO branch for coupled NWP at GO6 to include stochastic model perturbations.
For more info see ticket: ​https://code.metoffice.gov.uk/trac/nwpscience/ticket/1125.
File size: 6.7 KB
Line 
1MODULE zdfevd
2   !!======================================================================
3   !!                       ***  MODULE  zdfevd  ***
4   !! Ocean physics: parameterization of convection through an enhancement
5   !!                of vertical eddy mixing coefficient
6   !!======================================================================
7   !! History :  OPA  !  1997-06  (G. Madec, A. Lazar)  Original code
8   !!   NEMO     1.0  !  2002-06  (G. Madec)  F90: Free form and module
9   !!             -   !  2005-06  (C. Ethe) KPP parameterization
10   !!            3.2  !  2009-03  (M. Leclair, G. Madec, R. Benshila) test on both before & after
11   !!----------------------------------------------------------------------
12
13   !!----------------------------------------------------------------------
14   !!   zdf_evd      : increase the momentum and tracer Kz at the location of
15   !!                  statically unstable portion of the water column (ln_zdfevd=T)
16   !!----------------------------------------------------------------------
17   USE oce             ! ocean dynamics and tracers variables
18   USE dom_oce         ! ocean space and time domain variables
19   USE zdf_oce         ! ocean vertical physics variables
20   USE zdfkpp          ! KPP vertical mixing
21   USE trd_oce         ! trends: ocean variables
22   USE trdtra          ! trends manager: tracers
23   USE in_out_manager  ! I/O manager
24   USE iom             ! for iom_put
25   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
26   USE timing          ! Timing
27   USE stopack
28
29   IMPLICIT NONE
30   PRIVATE
31
32   PUBLIC   zdf_evd    ! called by step.F90
33   REAL(wp), SAVE, ALLOCATABLE, DIMENSION(:,:) :: rn_avevd0
34
35   !! * Substitutions
36#  include "domzgr_substitute.h90"
37   !!----------------------------------------------------------------------
38   !! NEMO/OPA 4.0 , NEMO Consortium (2011)
39   !! $Id$
40   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
41   !!----------------------------------------------------------------------
42CONTAINS
43
44   SUBROUTINE zdf_evd( kt )
45      !!----------------------------------------------------------------------
46      !!                  ***  ROUTINE zdf_evd  ***
47      !!
48      !! ** Purpose :   Local increased the vertical eddy viscosity and diffu-
49      !!      sivity coefficients when a static instability is encountered.
50      !!
51      !! ** Method  :   avt, avm, and the 4 neighbouring avmu, avmv coefficients
52      !!      are set to avevd (namelist parameter) if the water column is
53      !!      statically unstable (i.e. if rn2 < -1.e-12 )
54      !!
55      !! ** Action  :   avt, avm, avmu, avmv updted in static instability cases
56      !!
57      !! References :   Lazar, A., these de l'universite Paris VI, France, 1997
58      !!----------------------------------------------------------------------
59      USE oce,   zavt_evd => ua , zavm_evd => va  ! (ua,va) used ua workspace
60      !
61      INTEGER, INTENT( in ) ::   kt   ! ocean time-step indexocean time step
62      !
63      INTEGER ::   ji, jj, jk   ! dummy loop indices
64      !!----------------------------------------------------------------------
65      !
66      IF( nn_timing == 1 )  CALL timing_start('zdf_evd')
67      !
68      IF( kt == nit000 ) THEN
69         IF(lwp) WRITE(numout,*)
70         IF(lwp) WRITE(numout,*) 'zdf_evd : Enhanced Vertical Diffusion (evd)'
71         IF(lwp) WRITE(numout,*) '~~~~~~~ '
72         IF(lwp) WRITE(numout,*)
73         IF(lwp .AND. lflush) CALL flush(numout)
74         ALLOCATE ( rn_avevd0(jpi,jpj) )
75         rn_avevd0(:,:) = rn_avevd
76      ENDIF
77
78      zavt_evd(:,:,:) = avt(:,:,:)           ! set avt prior to evd application
79
80#if defined key_traldf_c2d || key_traldf_c3d
81      IF( ln_stopack .AND. ( nn_spp_aevd > 0 ) ) THEN
82         rn_avevd0(:,:) = rn_avevd
83         CALL spp_gen(kt, rn_avevd0, nn_spp_aevd, rn_aevd_sd, jk_spp_aevd)
84      ENDIF
85#else
86      IF ( ln_stopack .AND. ( nn_spp_aevd > 0 ) ) &
87         & CALL ctl_stop( 'zdf_evd: parameter perturbation will only work with '// &
88                          'key_traldf_c2d or key_traldf_c3d')
89#endif
90
91      SELECT CASE ( nn_evdm )
92      !
93      CASE ( 1 )           ! enhance vertical eddy viscosity and diffusivity (if rn2<-1.e-12)
94         !
95         zavm_evd(:,:,:) = avm(:,:,:)           ! set avm prior to evd application
96         !
97         DO jk = 1, jpkm1
98            DO jj = 2, jpj             ! no vector opt.
99               DO ji = 2, jpi
100#if defined key_zdfkpp
101                  ! no evd mixing in the boundary layer with KPP
102                  IF(  MIN( rn2(ji,jj,jk), rn2b(ji,jj,jk) ) <= -1.e-12  .AND.  fsdepw(ji,jj,jk) > hkpp(ji,jj)  ) THEN
103#else
104                  IF(  MIN( rn2(ji,jj,jk), rn2b(ji,jj,jk) ) <= -1.e-12 ) THEN
105#endif
106                     avt (ji  ,jj  ,jk) = rn_avevd0(ji,jj) * tmask(ji  ,jj  ,jk)
107                     avm (ji  ,jj  ,jk) = rn_avevd0(ji,jj) * tmask(ji  ,jj  ,jk)
108                     avmu(ji  ,jj  ,jk) = rn_avevd0(ji,jj) * umask(ji  ,jj  ,jk)
109                     avmu(ji-1,jj  ,jk) = rn_avevd0(ji,jj) * umask(ji-1,jj  ,jk)
110                     avmv(ji  ,jj  ,jk) = rn_avevd0(ji,jj) * vmask(ji  ,jj  ,jk)
111                     avmv(ji  ,jj-1,jk) = rn_avevd0(ji,jj) * vmask(ji  ,jj-1,jk)
112                  ENDIF
113               END DO
114            END DO
115         END DO
116         CALL lbc_lnk( avt , 'W', 1. )   ;   CALL lbc_lnk( avm , 'W', 1. )   ! Lateral boundary conditions
117         CALL lbc_lnk( avmu, 'U', 1. )   ;   CALL lbc_lnk( avmv, 'V', 1. )
118         !
119         zavm_evd(:,:,:) = avm(:,:,:) - zavm_evd(:,:,:)   ! change in avm due to evd
120         CALL iom_put( "avm_evd", zavm_evd )              ! output this change
121         !
122      CASE DEFAULT         ! enhance vertical eddy diffusivity only (if rn2<-1.e-12)
123         DO jk = 1, jpkm1
124!!!         WHERE( rn2(:,:,jk) <= -1.e-12 ) avt(:,:,jk) = tmask(:,:,jk) * avevd   ! agissant sur T SEUL!
125            DO jj = 1, jpj             ! loop over the whole domain (no lbc_lnk call)
126               DO ji = 1, jpi
127#if defined key_zdfkpp
128                  ! no evd mixing in the boundary layer with KPP
129                  IF(  MIN( rn2(ji,jj,jk), rn2b(ji,jj,jk) ) <= -1.e-12  .AND.  fsdepw(ji,jj,jk) > hkpp(ji,jj)  )   &
130#else
131                  IF(  MIN( rn2(ji,jj,jk), rn2b(ji,jj,jk) ) <= -1.e-12 )   &
132#endif
133                     avt(ji,jj,jk) = rn_avevd0(ji,jj) * tmask(ji,jj,jk)
134               END DO
135            END DO
136         END DO
137         !
138      END SELECT
139
140      zavt_evd(:,:,:) = avt(:,:,:) - zavt_evd(:,:,:)   ! change in avt due to evd
141      CALL iom_put( "avt_evd", zavt_evd )              ! output this change
142      IF( l_trdtra ) CALL trd_tra( kt, 'TRA', jp_tem, jptra_evd, zavt_evd )
143      !
144      IF( nn_timing == 1 )  CALL timing_stop('zdf_evd')
145      !
146   END SUBROUTINE zdf_evd
147
148   !!======================================================================
149END MODULE zdfevd
Note: See TracBrowser for help on using the repository browser.