New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
dynkeg.F90 in branches/UKMO/dev_r5518_GO6_under_ice_relax_dr_hook/NEMOGCM/NEMO/OPA_SRC/DYN – NEMO

source: branches/UKMO/dev_r5518_GO6_under_ice_relax_dr_hook/NEMOGCM/NEMO/OPA_SRC/DYN/dynkeg.F90 @ 11738

Last change on this file since 11738 was 11738, checked in by marc, 5 years ago

The Dr Hook changes from my perl code.
File size: 7.8 KB
RevLine 
[3]1MODULE dynkeg
2   !!======================================================================
3   !!                       ***  MODULE  dynkeg  ***
4   !! Ocean dynamics:  kinetic energy gradient trend
5   !!======================================================================
[5321]6   !! History :  1.0  !  1987-09  (P. Andrich, M.-A. Foujols)  Original code
7   !!            7.0  !  1997-05  (G. Madec)  Split dynber into dynkeg and dynhpg
8   !!  NEMO      1.0  !  2002-07  (G. Madec)  F90: Free form and module
[5328]9   !!            3.6  !  2015-05  (N. Ducousso, G. Madec)  add Hollingsworth scheme as an option
[503]10   !!----------------------------------------------------------------------
[5328]11   
[3]12   !!----------------------------------------------------------------------
13   !!   dyn_keg      : update the momentum trend with the horizontal tke
14   !!----------------------------------------------------------------------
15   USE oce             ! ocean dynamics and tracers
16   USE dom_oce         ! ocean space and time domain
[4990]17   USE trd_oce         ! trends: ocean variables
18   USE trddyn          ! trend manager: dynamics
19   !
[2715]20   USE in_out_manager  ! I/O manager
[5321]21   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
[2715]22   USE lib_mpp         ! MPP library
[258]23   USE prtctl          ! Print control
[3294]24   USE wrk_nemo        ! Memory Allocation
25   USE timing          ! Timing
[3]26
[11738]27   USE yomhook, ONLY: lhook, dr_hook
28   USE parkind1, ONLY: jprb, jpim
29
[3]30   IMPLICIT NONE
31   PRIVATE
32
[503]33   PUBLIC   dyn_keg    ! routine called by step module
[5328]34   
[5321]35   INTEGER, PARAMETER, PUBLIC  ::   nkeg_C2  = 0   !: 2nd order centered scheme (standard scheme)
36   INTEGER, PARAMETER, PUBLIC  ::   nkeg_HW  = 1   !: Hollingsworth et al., QJRMS, 1983
37   !
38   REAL(wp) ::   r1_48 = 1._wp / 48._wp   !: =1/(4*2*6)
[5328]39   
[3]40   !! * Substitutions
41#  include "vectopt_loop_substitute.h90"
[503]42   !!----------------------------------------------------------------------
[5321]43   !! NEMO/OPA 3.6 , NEMO Consortium (2015)
[6486]44   !! $Id$
[2715]45   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
[503]46   !!----------------------------------------------------------------------
[3]47CONTAINS
48
[5321]49   SUBROUTINE dyn_keg( kt, kscheme )
[3]50      !!----------------------------------------------------------------------
51      !!                  ***  ROUTINE dyn_keg  ***
52      !!
53      !! ** Purpose :   Compute the now momentum trend due to the horizontal
[5328]54      !!      gradient of the horizontal kinetic energy and add it to the
[3]55      !!      general momentum trend.
56      !!
[5328]57      !! ** Method  : * kscheme = nkeg_C2 : 2nd order centered scheme that
58      !!      conserve kinetic energy. Compute the now horizontal kinetic energy
[3]59      !!         zhke = 1/2 [ mi-1( un^2 ) + mj-1( vn^2 ) ]
[5321]60      !!              * kscheme = nkeg_HW : Hollingsworth correction following
61      !!      Arakawa (2001). The now horizontal kinetic energy is given by:
62      !!         zhke = 1/6 [ mi-1(  2 * un^2 + ((un(j+1)+un(j-1))/2)^2  )
63      !!                    + mj-1(  2 * vn^2 + ((vn(i+1)+vn(i-1))/2)^2  ) ]
[5328]64      !!     
[3]65      !!      Take its horizontal gradient and add it to the general momentum
66      !!      trend (ua,va).
67      !!         ua = ua - 1/e1u di[ zhke ]
68      !!         va = va - 1/e2v dj[ zhke ]
69      !!
70      !! ** Action : - Update the (ua, va) with the hor. ke gradient trend
[4990]71      !!             - send this trends to trd_dyn (l_trddyn=T) for post-processing
[5321]72      !!
73      !! ** References : Arakawa, A., International Geophysics 2001.
74      !!                 Hollingsworth et al., Quart. J. Roy. Meteor. Soc., 1983.
[503]75      !!----------------------------------------------------------------------
[5321]76      INTEGER, INTENT( in ) ::   kt        ! ocean time-step index
[5328]77      INTEGER, INTENT( in ) ::   kscheme   ! =0/1   type of KEG scheme
[4990]78      !
[503]79      INTEGER  ::   ji, jj, jk   ! dummy loop indices
80      REAL(wp) ::   zu, zv       ! temporary scalars
[5328]81      REAL(wp), POINTER, DIMENSION(:,:,:) :: zhke
82      REAL(wp), POINTER, DIMENSION(:,:,:) :: ztrdu, ztrdv 
[11738]83      INTEGER(KIND=jpim), PARAMETER :: zhook_in = 0
84      INTEGER(KIND=jpim), PARAMETER :: zhook_out = 1
85      REAL(KIND=jprb)               :: zhook_handle
86
87      CHARACTER(LEN=*), PARAMETER :: RoutineName='DYN_KEG'
88
89      IF (lhook) CALL dr_hook(RoutineName,zhook_in,zhook_handle)
90
[3]91      !!----------------------------------------------------------------------
[3294]92      !
[5321]93      IF( nn_timing == 1 )   CALL timing_start('dyn_keg')
[3294]94      !
[5328]95      CALL wrk_alloc( jpi,jpj,jpk,   zhke )
[3294]96      !
[3]97      IF( kt == nit000 ) THEN
98         IF(lwp) WRITE(numout,*)
[5321]99         IF(lwp) WRITE(numout,*) 'dyn_keg : kinetic energy gradient trend, scheme number=', kscheme
[3]100         IF(lwp) WRITE(numout,*) '~~~~~~~'
101      ENDIF
[216]102
[503]103      IF( l_trddyn ) THEN           ! Save ua and va trends
[5321]104         CALL wrk_alloc( jpi,jpj,jpk,   ztrdu, ztrdv )
[5328]105         ztrdu(:,:,:) = ua(:,:,:) 
106         ztrdv(:,:,:) = va(:,:,:) 
[216]107      ENDIF
[5328]108     
109      zhke(:,:,jpk) = 0._wp
110     
111      SELECT CASE ( kscheme )             !== Horizontal kinetic energy at T-point  ==!
112      !
113      CASE ( nkeg_C2 )                          !--  Standard scheme  --!
114         DO jk = 1, jpkm1
[5321]115            DO jj = 2, jpj
116               DO ji = fs_2, jpi   ! vector opt.
117                  zu =    un(ji-1,jj  ,jk) * un(ji-1,jj  ,jk)   &
118                     &  + un(ji  ,jj  ,jk) * un(ji  ,jj  ,jk)
119                  zv =    vn(ji  ,jj-1,jk) * vn(ji  ,jj-1,jk)   &
120                     &  + vn(ji  ,jj  ,jk) * vn(ji  ,jj  ,jk)
[5328]121                  zhke(ji,jj,jk) = 0.25_wp * ( zv + zu )
122               END DO 
[5321]123            END DO
[5328]124         END DO
[5321]125         !
[5328]126      CASE ( nkeg_HW )                          !--  Hollingsworth scheme  --!
127         DO jk = 1, jpkm1
128            DO jj = 2, jpjm1       
[5321]129               DO ji = fs_2, jpim1   ! vector opt.
130                  zu = 8._wp * ( un(ji-1,jj  ,jk) * un(ji-1,jj  ,jk)    &
131                     &         + un(ji  ,jj  ,jk) * un(ji  ,jj  ,jk) )  &
132                     &   +     ( un(ji-1,jj-1,jk) + un(ji-1,jj+1,jk) ) * ( un(ji-1,jj-1,jk) + un(ji-1,jj+1,jk) )   &
133                     &   +     ( un(ji  ,jj-1,jk) + un(ji  ,jj+1,jk) ) * ( un(ji  ,jj-1,jk) + un(ji  ,jj+1,jk) )
134                     !
135                  zv = 8._wp * ( vn(ji  ,jj-1,jk) * vn(ji  ,jj-1,jk)    &
136                     &         + vn(ji  ,jj  ,jk) * vn(ji  ,jj  ,jk) )  &
137                     &  +      ( vn(ji-1,jj-1,jk) + vn(ji+1,jj-1,jk) ) * ( vn(ji-1,jj-1,jk) + vn(ji+1,jj-1,jk) )   &
138                     &  +      ( vn(ji-1,jj  ,jk) + vn(ji+1,jj  ,jk) ) * ( vn(ji-1,jj  ,jk) + vn(ji+1,jj  ,jk) )
[5328]139                  zhke(ji,jj,jk) = r1_48 * ( zv + zu )
140               END DO 
[5321]141            END DO
[5328]142         END DO
143         CALL lbc_lnk( zhke, 'T', 1. )
[5321]144         !
[5328]145      END SELECT
146      !
147      DO jk = 1, jpkm1                    !==  grad( KE ) added to the general momentum trends  ==!
[5321]148         DO jj = 2, jpjm1
[3]149            DO ji = fs_2, fs_jpim1   ! vector opt.
[5328]150               ua(ji,jj,jk) = ua(ji,jj,jk) - ( zhke(ji+1,jj  ,jk) - zhke(ji,jj,jk) ) / e1u(ji,jj)
151               va(ji,jj,jk) = va(ji,jj,jk) - ( zhke(ji  ,jj+1,jk) - zhke(ji,jj,jk) ) / e2v(ji,jj)
152            END DO
[3]153         END DO
[5321]154      END DO
155      !
156      IF( l_trddyn ) THEN                 ! save the Kinetic Energy trends for diagnostic
[503]157         ztrdu(:,:,:) = ua(:,:,:) - ztrdu(:,:,:)
158         ztrdv(:,:,:) = va(:,:,:) - ztrdv(:,:,:)
[4990]159         CALL trd_dyn( ztrdu, ztrdv, jpdyn_keg, kt )
[5321]160         CALL wrk_dealloc( jpi,jpj,jpk,   ztrdu, ztrdv )
[216]161      ENDIF
[503]162      !
163      IF(ln_ctl)   CALL prt_ctl( tab3d_1=ua, clinfo1=' keg  - Ua: ', mask1=umask,   &
164         &                       tab3d_2=va, clinfo2=       ' Va: ', mask2=vmask, clinfo3='dyn' )
165      !
[5328]166      CALL wrk_dealloc( jpi,jpj,jpk,   zhke )
[2715]167      !
[5321]168      IF( nn_timing == 1 )   CALL timing_stop('dyn_keg')
[3294]169      !
[11738]170      IF (lhook) CALL dr_hook(RoutineName,zhook_out,zhook_handle)
[3]171   END SUBROUTINE dyn_keg
172
173   !!======================================================================
174END MODULE dynkeg
Note: See TracBrowser for help on using the repository browser.